         TITLE  '''IEDQCU'' - START LINE'                               00100020
IEDQCU   CSECT                                                          00200020
*********************************************************************** 00300020
*                                                                     * 00400020
*TITLE 'IEDQCU' PROCESSOR OF VARY ONTP OPERATOR CONTROL COMMANDS      * 00500020
*                                                                     * 00600020
*STATUS -- CHANGE LEVEL 0                                             * 00700020
*                                                                     * 00800020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS         * 00900020
*   WHICH REQUEST START OF A LINE OR LINE GROUP.                      * 01000020
*                                                                     * 01100020
*   THE STARTLINE ROUTINE EXAMINES THE COMMON INPUT BLOCK TO          * 01200020
*   DETERMINE THE INPUT FORMAT.  IF IT IS DCB ADDRESS, THE DEB IS     * 01300020
*   ACCESSED FROM DCBDEBAD AND CONTROL BRANCHES TO PROCESS THE DCB.   * 01400020
*   IF IT IS TERMINAL NAME, THE TERMNAME TABLE IS SERIALLY SEARCHED   * 01500020
*   FOR AN ENTRY MATCHING THE ONE SPECIFIED.  IF THE END OF TABLE     * 01600020
*   IS REACHED BEFORE A MATCH IS FOUND AN ERROR CODE IS SET AND THE   * 01700020
*   ROUTINE RETURNS TO THE CONTROL MODULE.  OTHERWISE THE ENTRY IS    * 01800020
*   USED TO ACCESS THE QCB (TRMDESTQ) WHICH PROVIDES THE DCB AND      * 01900020
*   DEB ADDRESSES.  CONTROL BRANCHES TO PROCESS THE DCB.              * 02000020
*                                                                     * 02100020
*   IF THE INPUT FORMAT IS DDNAME/RLN AND THE RLN IS NOT ALL OR       * 02200020
*   ALREADY HEXADECIMAL, IT IS CONVERTED TO HEXADECIMAL AND TESTED    * 02300020
*   FOR ZERO OR GREATER THAN 255.  IF EITHER, AN ERROR RESPONSE IS    * 02400020
*   BUILT AND CONTROL EXITS TO THE CONTROL MODULE.  THE TIOT IS       * 02500020
*   ACCESSED FROM THE TCB AND SERIALLY SEARCHED FOR AN ENTRY WHICH    * 02600020
*   MATCHES THE SPECIFIED DDNAME.  IF END OF TABLE IS REACHED AND     * 02700020
*   NO MATCH HAS BEEN FOUND AN ERROR MESSAGE IS BUILT AND CONTROL     * 02800020
*   RETURNS TO THE CONTROL MODULE.  WHEN THE NAME IS FOUND ITS        * 02900020
*   OFFSET INTO THE TIOT IS SAVED.  THE DEB CHAIN IS ACCESSED AND     * 03000020
*   EACH DCB IS TESTED FOR A TCAM LINE DCB (DSORG OF X'40') AND THE   * 03100020
*   SAME OFFSET INTO THE TIOT (DCBTIOT) AS THAT DETERMINED ABOVE.     * 03200020
*   IF THE END OF THE DEB CHAIN IS REACHED BEFORE THE PROPER DCB IS   * 03300020
*   FOUND, AN ERROR RESPONSE IS BUILT AND CONTROL RETURNS TO THE      * 03400020
*   CONTROL MODULE.  WHEN FOUND, CONTROL BRANCHES TO PROCESS THE      * 03500020
*   DCB.                                                              * 03600020
*                                                                     * 03700020
*   IF LINE ADDRESS IS SPECIFIED, THE DEB CHAIN IS LOCATED AND EACH   * 03800020
*   UCB ASSOCIATED WITH A DEB IS TESTED FOR AN ID MATCHING THE        * 03900020
*   SPECIFIED ADDRESS.  IF THE END OF THE DEB CHAIN IS REACHED AND    * 04000020
*   NO MATCH HAS BEEN FOUND, AN ERROR MESSAGE IS BUILT AND CONTROL    * 04100020
*   RETURNS TO THE CONTROL MODULE.                                    * 04200020
*                                                                     * 04300020
*   NOW THAT THE PROPER DCB HAS BEEN FOUND FOR ALL INPUT FORMATS,     * 04400020
*   IT IS CHECKED FOR OPEN STATUS.  IF IT IS NOT OPEN, AN ERROR       * 04500020
*   RESPONSE IS BUILT AND CONTROL EXITS TO THE CONTROL MODULE.  IF    * 04600020
*   A SINGLE LINE IS TO BE STARTED, ITS RLN IS COMPARED TO THE        * 04700020
*   NUMBER OF LINES IN THE GROUP.  IF HIGH, AN ERROR MESSAGE IS       * 04800020
*   BUILT AND THE ROUTINE RETURNS TO THE CONTROL MODULE.  THE LINE    * 04900020
*   IS TESTED FOR DD DUMMY.  IF IT IS AND WE ARE STARTING A SINGLE    * 05000020
*   LINE AN ERROR RESPONSE IS BUILT AND CONTROL RETURNS TO THE        * 05100020
*   CONTROL MODULE, IF STARTING A GROUP THE NEXT LINE IS TESTED.      * 05200020
*   IF ALL LINES IN THE GROUP ARE OPEN DD DUMMY AN ERROR MESSAGE IS   * 05300020
*   BUILT AND CONTROL EXITS TO THE CONTROL MODULE.                    * 05400020
*                                                                     * 05500020
*   THE LCB ADDRESS IS OBTAINED FROM DCBIOBAD.  IF IT IS NOT          * 05600020
*   STOPPED AND THE REQUEST IS FROM TOTE, THE LINE IS POSTED TO       * 05700020
*   ITSELF VIA SVC 102 (AQCTL) TO RETURN IT FROM TOTE TO TCAM AND     * 05800020
*   CONTROL RETURNS TO THE CONTROL MODULE.  IF IT IS NOT FROM TOTE,   * 05900020
*   THE NEXT LCB IF ANY IS ACCESSED.  WHEN ALL LCBS HAVE BEEN         * 06000020
*   PROCESSED, IF ANY HAVE BEEN STARTED A RESPONSE IS BUILT AND       * 06100020
*   CONTROL RETURNS TO THE CONTROL MODULE, OTHERWISE AN ALREADY       * 06200020
*   STARTED MESSAGE IS BUILT AND THE ROUTINE EXITS TO THE CONTROL     * 06300020
*   MODULE.                                                           * 06400020
*                                                                     * 06500020
*   IF THE LINE IS STOPPED, ITS RECEIVE BIT IS SET ON, A NOP          * 06600020
*   COMMAND IS BUILT IF IT IS A DIAL LINE, A SAD IF 2702 CONTROL      * 06700020
*   UNIT, AN ENABLE FOR A NON-DIAL LINE, AND THE CHANNEL PROGRAM      * 06800020
*   IS COMPLETED.  SVC 0 (EXCP) IS ISSUED TO START THE LINE, AND      * 06900020
*   A LINE-STARTED BIT IS SET ON.  THE NEXT LCB IS ACCESSED AND       * 07000020
*   PROCESSING CONTINUES UNTIL ALL LINES HAVE BEEN PROCESSED, AS      * 07100020
*   ABOVE.                                                            * 07200020
*                                                                     * 07300020
*ENTRY POINTS --                                                      * 07400020
*        'IEDQCU' TO PROCESS VARY ONTP OPERATOR CONTROL COMMANDS.     * 07500020
*   CALLING SEQUENCE IS                                               * 07600020
*                        LOAD EPLOC=LOADPRFX                          * 07700020
*                        LR   R1,ROPC                                 * 07800020
*                        LR   R15,R0                                  * 07900020
*                        BALR R14,R15                                 * 08000020
*                                                                     * 08100020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  COMMON       * 08200020
*   INPUT BLOCK AT LOCATION OPCCKELE.  RELEVANT FIELDS ARE            * 08300020
*                   +4   OPCLEN    X'80' NO RLN                       * 08400020
*                                  X'40' RLN IS HEXADECIMAL           * 08500020
*                                  X'00' RLN ALL                      * 08600020
*                                  1 - 3 LENGTH OF RLN                * 08700020
*                   +5   OPCRLN    RELATIVE LINE NUMBER               * 08800020
*                   +8   OPCTNME   DCB ADDRESS OR                     * 08900020
*                                  TERMINAL NAME OR                   * 09000020
*                                  DDNAME OR                          * 09100020
*                                  LINE ADDRESS                       * 09200020
*                                                                     * 09300020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 09400020
*                                                                     * 09500020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 09600020
*                                                                     * 09700020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 09800020
*                   0              LINE STARTED OR ALREADY STARTED    * 09900020
*                   4              TERMINAL NOT FOUND, LINE NOT       * 10000020
*                                  OPEN OR OPEN DD DUMMY, RLN         * 10100020
*                                  INVALID                            * 10200020
*                                                                     * 10300020
*EXTERNAL ROUTINES --                                                 * 10400020
*        'AQCTL' (SVC 102) TO RETURN LINE FROM TOTE TO TCAM           * 10500020
*                                                                     * 10600020
*        'EXCP' (SVC 0) TO START LINE                                 * 10700020
*                                                                     * 10800020
*EXITS-NORMAL -- LINE STARTED OR ALREADY ACTIVE.  APPROPRIATE         * 10900020
*   RESPONSE BUILT, X'00' RETURN CODE SET.                            * 11000020
*                                                                     * 11100020
*EXITS-ERROR -- TERMINAL NOT FOUND, RLN INVALID, LINE OR LINE GROUP   * 11200020
*   NOT OPEN OR OPEN DD DUMMY.  ERROR RESPONSE BUILT, X'04' RETURN    * 11300020
*   CODE SET.                                                         * 11400020
*                                                                     * 11500020
*TABLES/WORK AREAS -- TERMINAL ENTRY, TERMNAME TABLE, QCB, DEB,       * 11600020
*   OPERATOR CONTROL AVT, DCB, LCB, AVT.                              * 11700020
*                                                                     * 11800020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 11900020
*   PROBLEM PROGRAM MODE.                                             * 12000020
*                                                                     * 12100020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 12200020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 12300020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 12400020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 12500020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 12600020
*   DEFINITIONS.                                                      * 12700020
*                                                                     * 12800020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 12900020
*              IED017I, IED018I, IED019I, IED020I, IED092I            * 13000020
*                                                                     * 13100020
*********************************************************************** 13200020
*                                                                       13300020
*                                                                       13400020
R0       EQU   0                                                        13500020
R1       EQU   1                        PARAMETER                       13600020
ROPC     EQU   2                        OP CTL AVT BASE                 13700020
RCIB     EQU   3                                                        13800020
RAVT     EQU   4                        AVT BASE                        13900020
RWORK    EQU   5                        WORK                            14000020
RTCB     EQU   6                        BASE FOR TCB                    14100020
RDEB     EQU   6                        DEB BASE                        14200020
RDCB     EQU   7                        DCB BASE                        14300020
RWORK3   EQU   8                        WORK                            14400020
RLCB     EQU   9                        LCB BASE                        14500020
RDD      EQU   10                       DDNAME                          14600020
RUCB     EQU   10                        UCB BASE                       14700020
ROFF     EQU   11                       OFFSET TO DDNAME                14800020
RCTR     EQU   11                       COUNTER FOR RLNS                14900020
RBASE    EQU   12                       BASE OF ROUTINE                 15000020
R13      EQU   13                       SAVE AREA                       15100020
R14      EQU   14                       RETURN                          15200020
R15      EQU   15                       ENTRY                           15300020
RWORK2   EQU   15                       WORK                            15400020
         USING IEDQCU,RBASE             ADDRESSABILITY FOR ROUTINE      15500020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          15600020
         USING IEDQLCB,RLCB             ADDRESSABILITY FOR LCB          15700020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          15800020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          15900020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       16000020
         SAVE  (14,12),,IEDQCU-03/10/71                                 16100020
         LR    RBASE,R15                SET UP BASE                     16200020
         LR    ROPC,R1                                                  16300020
         L      RCIB,OPCINPUT                                           16400020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 16500020
         TM    AVTBIT1,AVTDLAYN         INA A SYSTEM DELAY              16530020
         BO    DLAYERR                  YES REJECT THE COMMAND          16560020
         SR    RWORK,RWORK                                              16600020
         L     RTCB,AVTTCB              GET TCB ADDR                    16700020
         CLI   OPCTNME,AVTEZERO         DCB ADDR FORM                   16800020
         BNE   TRM                      NO                              16900020
*                                                                       17000020
         L     RDCB,OPCTNME             GET DCB ADDR                    17100020
         L     RDEB,12(RTCB)             ADDRESS OF TIOT                17200020
         LA    RDEB,0(RDEB)              CLEAR HIGH ORDER BYTE          17300020
         AH    RDEB,40(RDCB)             OFF SET TO DD ENTRY            17400020
         MVC   OPCTNME(8),4(RDEB)        SAVE FOR CHECKPOINT            17500020
         L     RTCB,AVTTCB               RESET THE TCB REG              17600020
         TM    OPCLEN,HEX40              BINARY REL LINE                17700020
         BZ    SCAN                      NO                             17800020
         CLI   OPCRLN,OPCZERO            ALL - SITUATION                17900020
         BNE   SCAN                       NO                            18000020
         MVI   OPCLEN,OPCZERO            SET ALL SWITCH FOR USE         18100020
         B     SCAN                                                     18200020
CKOP     EQU   *                                                        18300020
         L     RDEB,DCBDEBAD            GET DEB ADDR                    18400020
         IC    R1,OPCRLN                GET RLN                         18500020
         STC   R1,OPCBITSW+1            SAVE IT                         18600020
         B     PROCDCB                  GO PROCESS                      18700020
*                                                                       18800020
TRM      EQU   *                                                        18900020
         TM    OPCLEN,ADCODE            LINE ADDR FORM                  19000020
         BO    GETLCB                    YES, GET THE LCB               19100020
*                                                                       19200020
         TM    OPCBITSW,OPCMPPN         FROM MPP OR TOTE                19300020
         BNO   SCAN                     NO - ID DD FORM                 19400020
*                                                                       19500020
         TM    OPCED,OPCFOUR             FROM TOTE                      19600020
         BO    SCAN                      YES, PROCEED                   19700020
*                                                                       19800020
         L     RWORK,AVTRNMPT           GET TERMANE TABLE               19900020
         LA    RWORK2,OPCONE            SET OCUNTER                     20000020
         LH    RWORK3,TNTLEN-IEDQTNTD(RWORK) GET NUMBER ENTIIES         20100020
         SR    RCTR,RCTR                CLEAR                           20200020
         IC    RCTR,TNTENLEN-IEDQTNTD(RWORK) GET ENTRY LENGTH           20300020
         BCTR  RCTR,R0                  DECREMENT FOR EXECUTE           20400020
         LA    RWORK,TNTFIRST-IEDQTNTD(RWORK) GET FIRST ENTRY           20500020
TRMLOOP  EQU   *                                                        20600020
         CR    RWORK2,RWORK3            END OF TABLE                    20700020
         BH    ERR20                     YES, ERROR EXIT                20800020
*                                                                       20900020
SETDCB   EQU   *                                                        21000020
         EX    RCTR,TRMCOMP             ENTRY FOUND                     21100020
         BE    TRMEX                    YES - PROCESS IT                21200020
*                                                                       21300020
         LA    RWORK,OPCFOUR(RCTR,RWORK) BUMP TO NEXT ENTRY             21400020
         LA    RWORK2,OPCONE(,RWORK2)   BUMP COUNTER                    21500020
         B     TRMLOOP                  LOOK AT NEXT ENTRY              21600020
*                                                                       21700020
*                                                                       22100020
TRMEX    EQU   *                                                        22200020
         AR    RWORK,RCTR                                               22300020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RWORK)                        22400020
         L     RCTR,OPCWORK                                             22500020
         TM    TRMSTATE-IEDQTRM(RCTR),PROC+DIST PROCESS OR DISTRIBUTION 22530020
         BNZ   ERR20                     YES, REJECT COMMAND            22560020
         L     RCTR,TRMDESTQ-1-IEDQTRM(RCTR) QCB ADDR                   22600020
         L     RDCB,QCBDCBAD-1-IEDQQCB(RCTR)                            22700020
         B     CKOP                                                     22800020
*                                                                       22900020
COMINV   EQU   *                                                    618 23000020
         LA    R1,OPCERMSG              GET MSG ADDR                    23100020
         LA    R15,OPCEIGHT              INVALID LINE ERROR CODE        23150020
         B     EXIT                                                 618 23200020
*                                                                   618 23300020
GETRLN   EQU   *                                                        23400020
         IC    RWORK,OPCRLN             GET RLN                         23500020
         B     SAVERLN                                                  23600020
*                                                                       23700020
SCAN     EQU   *                                                        24000020
         CLI   OPCLEN,AVTEZERO          RLN 'ALL'                       24100020
         BE    GETDATA                  YES - SKIP RLN CONVERSION       24200020
*                                                                       24300020
         TM    OPCLEN,HEXRLN            RLN ALREADY HEX                 24400020
         BO    GETRLN                   YES                             24500020
*                                                                       24600020
         MVC   OPCDOUBL(OPCTHREE),OPCRLN PUT RLN IN WORK AREA           24700020
         SR    R15,R15                  CLEAR                           24800020
         IC    R15,OPCLEN               GET LENGTH OF RLN               24900020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE       619 25000020
         EX    R15,PACK                 PACK RLN                    619 25100020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CONVERT          619 25200020
         CVB   RWORK,OPCDOUBL           CONVERT TO HEX                  25300020
         CH    RWORK,MAXVAL             RLN > 255                       25400020
         BH    COMINV                   YES - REJECT COMMAND            25500020
*                                                                   618 25600020
SAVERLN  EQU   *                                                        25700020
         LTR   RWORK,RWORK              RLN ZERO SPECIFIED          619 25800020
         BZ    COMINV                   YES - REJECT COMMAND        619 25900020
*                                                                   619 26000020
         STC   RWORK,OPCBITSW+1         SAVE HEX RLN                    26100020
GETDATA  EQU   *                                                        26200020
         L     RDD,TIOT(RTCB)      ADDRESS OF THE TIOT                  26300020
         LA    R0,STARTOFF         OFFSET TO THE FIRST TIOT ENTRY       26400020
         SR    RWORK,RWORK                                              26500020
LOOP     EQU   *                                                        26600020
         AR    RDD,R0                   INCREMENT TO NEXT OFFSET        26700020
         AR    RWORK,R0            COMPUTE NEW TIOT OFFSET              26800020
         CLC   OPCFOUR(OPCEIGHT,RDD),OPCTNME SPECIFIED DD               26900020
         BE    GETLCB              BRANCH YES CORRECT ENTRY FOUND       27000020
*                                                                       27100020
         IC    R0,OPCZERO(,RDD)    OFFSET TO THE NEXT ENTRY             27200020
         LTR   R0,R0               IF ZERO INDICATES END OF THE TIOT    27300020
         BNZ   LOOP                GO CHECK NEXT ENTRY IF NOT ZERO      27400020
*                                                                       27500020
         B     ERR20                     ENTRY NOT FOUND                27600020
*                                                                       27700020
GETLCB   EQU   *                                                        28600020
         L     RDEB,DEB(,RTCB)          GET FIRST DEB                   28700020
GETDCB   EQU   *                                                        28800020
         L     RDCB,DEBDCBAD            GET DCB                         28900020
         TM    DCBDSORG+1,TX            TCAM LINE                       29000020
         BNO   NEXTDEB                  NO - WRONG DCB                  29100020
*                                                                       29200020
         TM    OPCLEN,ADCODE            ADDR FORM                       29300020
         BO    UCB                      YES - SEARCH UCBS               29400020
*                                                                       29500020
         LH    RWORK2,DCBTIOT           GET OFFSET INTO TIOT            29600020
         CR    RWORK2,RWORK        SAME AS FOR THE DD CARD              29700020
         BNE   NEXTDEB                  NO - WRONG DCB                  29800020
*                                                                       29900020
PROCDCB  EQU   *                                                        30000020
         CLI   DCBTIOT,A                LINE OPEN                       30100020
         BNL   ERR01                     NO, ERROR EXIT                 30200020
*                                                                       30300020
         LA    R0,1                SET FOR FIRST RELATIVE LINE          30400020
         SR    RCTR,RCTR                                                30500020
         IC    RCTR,DEBNMEXT       SET TOTAL NUMBER OF LINES            30600020
         CLI   OPCLEN,AVTEZERO          IS RLN 'ALL' SPECIFIED          30700020
         BE    STARTUP             BRANCH IF YES TO START LINES         30800020
*                                                                       30900020
         LR    RCTR,R0             SET INDEX FOR ONE LINE               31000020
         IC    R0,OPCBITSW+1            PICK UP RLN                     31100020
         CLC   OPCBITSW+1(OPCONE),DEBNMEXT RLN > NUMBER EXTENTS         31200020
         BH    COMINV                    GET ERR MSG                    31300020
*                                                                       31400020
STARTUP  EQU   *                                                        31500020
         LR    RWORK,R0                 SAVE RLN                        31600020
         SLL   RWORK,OPCTWO        RELATIVE LINE TIMES FOUR             31700020
         L     RUCB,DEBUCBAD-4-DEBNMSUB(RDEB,RWORK)                     31800020
         LA    RUCB,OPCZERO(RUCB)       CLEAR HI BYTE                   31900020
         LTR   RUCB,RUCB                OPENED DD DUMMY                 32000020
         BZ    DDDUMMY             BRANCH IF DD DUMMY SPECIFIED         32100020
*                                                                       32200020
         L     RLCB,DCBIOBAD            GET IOB                         32300020
         LA    RLCB,OPCZERO(,RLCB)      CLEAR HIGH BYTE                 32400020
         SR    R1,R1                    CLEAR                           32500020
         IC    R1,DCBEIOBX              GET IOB LENGTH                  32600020
         MR    R0,R0                                                    32700020
         AR    RLCB,R1                  ADD RESULT TO IOB ADDR          32800020
         LA    RWORK3,LCBFLAG1-IEDQLCB  GET LENGTH OF IOB               32900020
         SR    RLCB,RWORK3              GET TO LCB START                33000020
         CLI   LCBCPA,F1                 IS LCB UNDER TOTE CONTROL      33100020
         BNE   NOTTOTE                  NO, IGNORE TOTE                 33140020
         CLI   AVTOLTST,AVTEZERO        IS TOTE ACTIVE                  33180020
         BNE   TOTEERR                  YES,REJECT THE COMMAND          33220020
NOTTOTE  EQU   *                                                        33260020
         OI    OPCBITSW,OPCTEMPN        TURN ON PROCESS BIT             33300020
         SRL   RWORK,OPCTWO             RECONVERT TO RLN                33400020
         LR    RWORK2,RWORK                                             33500020
         BAL   R14,PROCESS1             GO LOOK AT LCB                  33600020
NEXT     EQU   *                                                        33700020
         LA    R0,OPCONE(RWORK)    COMPUTE NEXT RELATIVE LINE NUMBER    33800020
         BCT   RCTR,STARTUP        BRANCH IF MORE LINES                 33900020
         B     PROCESS2                                                 34000020
DDDUMMY  EQU   *                                                        34100020
         CLI   OPCLEN,AVTEZERO          IS RLN 'ALL' SPECIFIED          34200020
         BNE   ERR01                     NO, ERROR EXIT                 34300020
*                                                                       34400020
         SRL   RWORK,OPCTWO               RECONVERT OO RELATIVE LINE    34500020
         B     NEXT                                                     34600020
*                                                                       34700020
UCB      EQU   *                                                        34800020
         SR    RWORK,RWORK              CLEAR                           34900020
         IC    RWORK,DEBNMEXT           GET NUMBER OF RLNS              35000020
         LA    RWORK3,DEBUCBAD                                          35100020
         LA    RCTR,OPCONE              SET COUNT TO ONE                35200020
SETUCB   EQU   *                                                        35300020
         L     RUCB,OPCZERO(RWORK3)                                     35400020
         CLC   ADDR(OPCTHREE,RUCB),OPCTNME SPECIFIED ADDR               35500020
         BE    FOUND                    YES                             35600020
*                                                                       35700020
         LA    RCTR,OPCONE(,RCTR)       ADD 1 TO COUNT                  35800020
         LA    RWORK3,OPCFOUR(,RWORK3)  GET TO NEXT UCB ADDR            35900020
         CR    RCTR,RWORK               ANY MORE EXTENTS                36000020
         BH    NEXTDEB                  NO - GET NEXT DEB               36100020
*                                                                       36200020
         B     SETUCB                                                   36300020
*                                                                       36400020
FOUND    EQU   *                                                        36500020
         LR    R0,RCTR                  PUT RLN OFFSET IN R0            36600020
         STC   RCTR,OPCBITSW+1          SAVE RLN                        36700020
         CLI   DCBTIOT,A                LINE OPEN                       36800020
         BNL   ERR01                     NO - ERROR EXIT                36900020
*                                                                       37000020
         LA    RCTR,1              SET INDEX FOR ONE LINE               37100020
         B     STARTUP             GO START THE LINE                    37200020
*                                                                       37300020
NEXTDEB  EQU   *                                                        37400020
         TM    OPCBITSW,OPCTEMPN        PROCESS BIT ON                  37500020
         BO    PROCESS2                 YES - FIRST LOGIC COMPLETE      37600020
*                                                                       37700020
         L     RDEB,OPCFOUR(,RDEB)      PICK UP POINTER TO NEXT         37800020
         LA    RDEB,OPCZERO(,RDEB)      CLEAR HIGH BYTE                 37900020
         LTR   RDEB,RDEB                LAST DEB                        38000020
         BNZ   GETDCB                   NO - PROCESS IT                 38100020
ERR20    EQU   *                                                        38110020
         LA    R15,HEX20                 RTN CODE-INVALID TRM TABLE     38120020
         B     ERR                                                      38130020
ERR01    EQU   *                                                        38140020
         LA    R15,OPCONE                RTN CLDE - UNOPENED DCB        38150020
*                                                                       38200020
ERR      EQU   *                                                        38300020
         MVC   ERMGTXT(OPCEIGHT),OPCTNME PUT NAME IN MSG                38400020
         TM    OPCLEN,ADCODE            RLN SPECIFIED                   38500020
         BO    ERR1                     NO                              38600020
*                                                                       38700020
         LA    R1,ERMGTXT+9             GET VARIABLE ADDR               38800020
         BAL   R14,TESTALL                                              38900020
*                                                                       39000020
ERR1     EQU   *                                                        39100020
         LA    R1,ERMG                  PICK UP ERROR MESSAGE           39200020
EXIT     EQU   *                                                        39300020
         NI    OPCBITSW,BITSOFF                                         39600020
         ST    R1,OPCREG1(,R13)         SAVE ITS ADDRESS                39700020
EXIT2    EQU   *                                                        39900020
         RETURN (14,12),T,RC=(15)                                       40000020
*                                                                       40100020
PROCESS1 EQU   *                                                        40200020
         CLI   LCBSTAT1,AVTEZERO        LINE STOPPED                    40300020
         BCR   7,R14                     NO, RETURN                     40400020
PROCESS3 EQU   *                                                        40420020
         CLC   OPCONE(OPCTHREE,RLCB),AVTSUPPT+1  IS THE LCB ON READY    40440020
*                                         QUEUE FOR STARTUP MSG         40460020
         BE    PROCESS3                 YES, LOOP HERE UNTIL OFF        40480020
         MVI   LCBSTAT1,LCBRECVN        TURN ON RECIEVE BIT SWITCH      40500020
         ST    RLCB,OPCZERO(,RLCB)      POST LCB TO ITSELF              40600020
         B     EXCPRTNE                 YES - GO START IT               40700020
*                                         EXCP ROUTINE                  40800020
*                                                                       41800020
LOOPTHRU EQU   *                                                        41900020
         OI    OPCBITSW,OPCLCLN         TURN ON 'FOUND' INDICATOR       42000020
         BR    R14                                                      42100020
*                                                                       42200020
BISERROR EQU   *                                                        42300020
         MVC   BMSG1(OPCEIGHT),OPCTNME  PUT NAME IN MSG                 42400020
         TM    OPCLEN,ADCODE            RLN SPECIFIED                   42500020
         BO    BISERR1                  NO                              42600020
*                                                                       42700020
         LA    R1,BMSG1+9               GET VARIABLE ADDR               42800020
         BAL   R14,TESTALL                                              42900020
*                                                                       43000020
BISERR1  EQU   *                                                        43100020
         LA    R1,BMSG                                                  43200020
         LA    R15,OPCFOUR               RTN CODE                       43250020
         B     EXIT                                                     43300020
DLAYERR  EQU   *                                                        43320020
         LA    R1,ERDLAY                SET UP DELAY MESSAGE            43340020
         LA    R15,OPCFOUR              BAD RETURN CODE                 43360020
         B     EXIT                     REJECT THE COMMAND              43380020
*                                                                       43400020
PROCESS2 EQU   *                                                        43500020
         TM    OPCBITSW,OPCLCLN         FIRST TIME SWITCH ON            43600020
         BNO   ALR                                                      43700020
*                                                                       43800020
         MVC   GOOD(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 43900020
         TM    OPCLEN,ADCODE            RLN SPECIFIED                   44000020
         BO    PROC2                    NO                              44100020
*                                                                       44200020
         LA    R1,GOOD+9                GET VARIABLE ADDR               44300020
         BAL   R14,TESTALL                                              44400020
*                                                                       44500020
PROC2    EQU   *                                                        44600020
         LA    R1,GOODMSG               GET MSG ADDR                    44700020
         OI    OPCCKBIT,OPCCKPTN        TURN ON CKT BIT                 44800020
SETGOOD  EQU   *                                                        44900020
         SR    R15,R15                  SET GOOD RETURN                 45000020
         OI    OPCED,AVTE80              TURN ON CHECK POINT            45100020
         B     EXIT                                                     45200020
*                                                                       45300020
ALR      EQU   *                                                        45400020
         MVC   MSG67A(OPCEIGHT),OPCTNME PUT NAME IN MSG                 45500020
         TM    OPCLEN,ADCODE            RLN SPECIFIED                   45600020
         BO    ALR1                     NO                              45700020
*                                                                       45800020
         LA    R1,MSG67A+9              GET VARIABLE ADDR               45900020
         BAL   R14,TESTALL                                              46000020
*                                                                       46100020
ALR1     EQU   *                                                        46200020
         LA    R1,MSG67                 GET MSG ADDR                    46300020
         B     SETGOOD                                                  46400020
*                                                                       46500020
TESTALL  EQU   *                                                        46600020
         CLI   OPCLEN,AVTEZERO          'ALL' SPECIFIED                 46700020
          BE   MOVEALL                  YES                             46800020
*                                                                       46900020
         MVC   OPCZERO(OPCTHREE,R1),OPCRLN PUT RLN IN MSG               47000020
         BR    R14                                                      47100020
*                                                                       47200020
MOVEALL  EQU   *                                                        47300020
         MVC   OPCZERO(OPCTHREE,R1),ALL PUT ALL IN MSG                  47400020
         BR    R14                                                      47500020
*                                                                       47600020
TOTEERR  EQU   *                                                        47610020
         MVC   TOTEMSG1(OPCEIGHT),OPCTNME  TOTE CONTRL MSG              47620020
         TM    OPCLEN,ADCODE             AEL LINE                       47630020
         BO    TOTEERR1                  YES, CHECK OUT                 47640020
         CLI   OPCLEN,AVTEZERO           ALL SITUATOON                  47643020
         BE    NEXT                      YES, GET NEXT LINE             47646020
         LA    R1,TOTEMSG1+9             SET UP FOR REST OF MESSAGE     47650020
         BAL   R14,TESTALL               ALL SITUATION                  47660020
TOTEERR1 EQU   *                                                        47670020
         LA    R1,TOTEMSG                                               47680020
         LA    R15,OPCFOUR                                              47685020
         B     EXIT                                                     47690020
         EJECT                                                          47700020
EXCPRTNE EQU   *                                                        47800020
         STM   R0,R15,EXCPSAVE          SAVE ALL INCOMING REGISTERS     47900020
*   NEW REGISTER EQUATES                                                48000020
RE       EQU   0                        WORK REGISTER                   48100020
RF       EQU   1                        WORK REGISTER                   48200020
RTIOT    EQU   3                        WORK REGISTER                   48300020
RJ       EQU   15                       WORK REGISTER                   48400020
*                                                                       48500020
         LR    RF,RWORK2                 COPY RELATIVE LINE NUMBER      48600020
         BCTR    RF,0                                                   48700020
         SLL   RF,TWO                   MULTIPLY RELATIVE LINE          48800020
*                                         BY 4                          48900020
         L     RDCB,LCBDCBPT             GET THE DCB ADDRESS            49000020
         L     RDEB,DCBDEBAD            GET THE DEB ADDRESS             49100020
         L     RUCB,DEBUCBAD(RF)        LOCATE THE UCB ADDRESS FOR      49200020
*                                         THIS LINE                     49300020
         EJECT                                                          49400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     49500020
*                                                                 *     49600020
*        BUILD A NOP COMMAND FOR ANY DIAL LINES                   *     49700020
*                                                                 *     49800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     49900020
NEXTLIN  EQU   *                                                        50000020
         LA    RJ,LCBCPA                ADDRESS OF THE CHANNEL          50100020
*                                         PROGRAM AREA                  50200020
         ST    RJ,LCBSIOCC              STORE THE CPA ADDRESS IN        50300020
*                                         THE LCB                       50400020
         LA    RTIOT,FOUR               LOAD AN INCREMENT OF FOUR       50500020
         SR    RJ,RTIOT                 DECREMENT THE CPA POINTER       50600020
         ST    RAVT,FOUR(RJ)            STORE ANY VALID ADDRESS IN      50700020
*                                         THIS CCW                      50800020
         MVI   4(RJ),X'03'              SET THE COMMAND CODE FOR A      50900020
*                                         NOP                           51000020
         MVC   8(4,RJ),NOP              BUILD THE REST OF THE NOP       51100020
         CLI   DEVCLASS(RUCB),LOCAL     IS THIS A 2260 LOCAL LINE       51200020
         BE    STARTLIN                 YES, BRANCH                     51300020
         CLI   19(RUCB),X'82'           TEST FOR A 2701 CONTROL         51400020
*                                         UNIT WITH AN IBM TYPE III     51500020
*                                         ADAPTER                       51600020
         BE    STARTLIN                 IF YES, NO ENABLE IS            51700020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     51800020
*                                                                 *     51900020
*    TEST FOR A 2702 CONTROL UNIT                                       52000020
*                                                                 *     52100020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     52200020
CUTEST   EQU   *                                                        52300020
         IC    RTIOT,19(RUCB)           LOAD THE CONTROL UNIT BITS      52400020
*                                         FROM THE UCB                  52500020
         N     RTIOT,ANDMASK            CLEAR ALL UNWANTED BITS         52600020
*                                         FROM RTIOT                    52700020
         LTR   RTIOT,RTIOT              HAS A CONTROL UNIT BEEN         52800020
*                                         SPECIFIED FOR THIS DEVICE     52900020
         BZ    STARTLIN                 NO, THEN ASSUME THE DEVICE      53000020
*                                         IS A 7770                     53100020
         ST    RAVT,4(RJ)               STORE ANY VALID ADDRESS IN      53200020
*                                         THE CCW                       53300020
         MVI   4(RJ),X'2F'              SET THE COMMAND CODE FOR A      53400020
*                                         DISABLE                       53500020
         MVC   8(4,RJ),NOP              BUILD THE REST OF THE           53600020
*                                         DISABLE COMMAND               53700020
         LA    RJ,8(RJ)                 INCREMENT THE CCW POINTER       53800020
         BCT   RTIOT,NOT2702            IS EITHER A 2701 OR 2703        53900020
*                                         CONTROL UNIT                  54000020
*                                                                       54100020
         EJECT                                                          54200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     54300020
*                                                                 *     54400020
*    SET UP THE CORRECT SAD COMMAND FOR THIS 2702 CONTROL UNIT          54500020
*                                                                 *     54600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     54700020
*                                                                       54800020
         IC    RTIOT,17(RUCB)           LOAD THE FEATURE BYTE FROM      54900020
*                                         THE UCB                       55000020
         N     RTIOT,ANDMASK            CLEAR EXTRANEOUS FEATURE        55100020
*                                         BITS FROM RTIOT               55200020
         IC    RTIOT,SADCODE(RTIOT)     INSERT ACTUAL SAD COMMAND       55300020
         ST    RAVT,FOUR(RJ)            STORE ANY VALID ADDRESS IN      55400020
*                                         THIS CCW                      55500020
         STC   RTIOT,4(RJ)              STORE THE SAD CODE IN THE       55600020
*                                         CHANNEL PROGRAM AREA          55700020
         MVC   8(4,RJ),NOP              BUILD THE REST OF THE SAD       55800020
*                                         COMMANDS                      55900020
         OI    0(RJ),CMDCHAIN           TURN ON THE COMMAND CHAINING    56000020
*                                         FLAG IN THE PREVIOUS CCW      56100020
         LA    RJ,8(RJ)                 BUMP POINTER TO NEXT DOUBLE     56200020
*                                         WORD IN THE CPA AREA          56300020
         EJECT                                                          56400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     56500020
*                                                                 *     56600020
*    SET CORRECT COMMANDS FOR THE 2701 AND 2703 CONTROL UNITS           56700020
*                                                                 *     56800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     56900020
*                                                                       57000020
NOT2702  EQU   *                                                        57100020
         TM    19(RUCB),X'90'           DO WE HAVE A BINARY             57500020
*                                         SYNCHRONOUS ADAPTER,          57600020
*                                         TYPE II                       57700020
         BO    SETBISCP                 YES, BRANCH                     57800020
         TM    17(RUCB),X'90'           TEST FOR A DIAL LINE            57900020
         BNZ   STARTLIN                 GO TO START THE LINE            58000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     58100020
*                                                                 *     58200020
*        BUILD AN ENABLE COMMAND IF NOT A DIAL LINE               *     58300020
*                                                                 *     58400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     58500020
ENABLE   EQU   *                                                        58600020
         ST    RAVT,FOUR(RJ)            STORE ANY VALID ADDRESS IN      58700020
*                                         THIS CCW                      58800020
         MVI   4(RJ),X'27'              SET THE COMMAND CODE FOR        58900020
*                                         AN ENABLE                     59000020
         MVC   8(4,RJ),NOP              BUILD THE REST OF THE ENABLE    59100020
*                                         COMMAND                       59200020
         OI    0(RJ),CMDCHAIN           TURN ON THE COMMAND CHAIN       59300020
*                                         FLAG IN THE PRIOR             59400020
*                                         COMMAND                       59500020
         EJECT                                                          59600020
STARTLIN EQU   *                                                        59700020
         MVC   LCBTPCD(FOUR),TPOPCODE   MOVE THE TP OP CODE INTO        59800020
*                                         THE LCB                       59900020
         LA    RF,LCBFLAG1              GET IOB ADDRESS FOR IOS         60000020
         SVC   EXCP                     ISSUE SVC 0                     60100020
*                                                                       60200020
         LM    R0,R15,EXCPSAVE          RESTORE ALL REGISTERS           60300020
         B     LOOPTHRU                                                 60400020
         EJECT                                                          60500020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     60600020
*                                                                 *     60700020
*        THIS ROUTINE BUILDS THE CHANNEL PROGRAM FOR              *     60800020
*        AND MODIFIES THE ERROR TAB IN THE UCB FOR ALL TCAM       *     60900020
*              BINARY SYNCHRONOUS DEVICES                         *     61000020
*                                                                 *     61100020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     61200020
SETBISCP EQU   *                                                        61300020
         NI    LCBTPCD+11,NWRTEOT        OFF BIT - LE WRITE DLE EOT     61350020
         LA    RTIOT,DCBINVLI           LOAD THE ADDRESS OF THE         61400020
*                                         FIRST INVITATION LIST IN      61500020
*                                         THE DCB                       61600020
         AR    RTIOT,RF                 ACCESS THE ADDRESS OF THE       61700020
*                                         FIRST/NEXT INVITATION         61800020
*                                         LIST ADDRESS                  61900020
         TM    17(RUCB),X'90'           IS THIS A DIAL LINE             62000020
         BNZ   TESTADPT                 YES, BRANCH                     62100020
         OI    0(RTIOT),X'04'           NO, TURN ON THE BIT TO          62200020
*                                         PERMIT AN INTERRUPT MODE      62300020
*                                         OF OPERATION                  62400020
TESTADPT EQU   *                                                        62500020
         TM    19(RUCB),X'03'           IS THIS A 2703 CONTROL UNIT     62600020
         BO    SETMODE                  YES, BRANCH                     62700020
         TM    0(RTIOT),X'20'           IS THE DUAL COMMUNICATION       62800020
*                                         INTERFACE SET TO              62900020
*                                         INTERFACE B                   63000020
         BNO   TESTCODE                 NO, INTERFACE A WAS             63100020
*                                         SPECIFIED                     63200020
         TM    17(RUCB),X'20'           YES, IS IT LEGAL                63300020
         BZ    BISERROR                 NO, IT IS AN ERROR              63400020
TESTCODE EQU   *                                                        63500020
         TM    0(RTIOT),X'08'           IS THE DUAL CODE FEATURE        63600020
*                                         SET TO TRANSMISSION CODE      63700020
*                                         B                             63800020
         BZ    SETMODE                  NO, BRANCH                      63900020
         TM    17(RUCB),X'04'           YES, IS IT LEGAL                64000020
         BZ    BISERROR                 NO, IT IS AN ERROR              64100020
SETMODE  EQU   *                                                        64200020
         ST    RTIOT,4(RJ)              STORE THE DATA ADDRESS (THE     64300020
*                                         ADDRESS OF THE INVITATION     64400020
*                                         LIST ADDRESS FOR THIS         64500020
*                                         LINE) IN THE SECOND CCW       64600020
         MVI   4(RJ),X'23'              PUT THE SET MODE COMMAND        64700020
*                                         CODE IN THE SECOND CCW        64800020
         MVC   8(4,RJ),NOP              BUILD THE REST OF THE SET       64900020
*                                         MODE COMMAND                  65000020
         OI    0(RJ),CMDCHAIN           TURN ON THE COMMAND CHAIN       65100020
*                                         FLAG IN THE FIRST CCW         65200020
         LA    RJ,8(RJ)                 INCREMENT THE CCW POINTER       65300020
         TM    17(RUCB),X'90'           IS THIS A DIAL LINE             65400020
         BNZ   STARTLIN                 YES, BRANCH                     65500020
*                                         CHANNEL PROGRAM               65600020
         B     ENABLE                   BRANCH TO BUILD AN ENABLE       65700020
*                                         AS THE THIRD CCW IN THE       65800020
*                                                                       65900020
         EJECT                                                          66000020
EXCP     EQU   0                                                        66100020
TWO      EQU   2                                                        66200020
FOUR     EQU   4                                                        66300020
DEB      EQU   8                        OFFSET INTO TCB OF DEB          66400020
TIOT     EQU   12                       OFFSET INTO TCB OF TIOT         66500020
ADDR     EQU   13                                                       66600020
STARTOFF EQU   24                                                       66700020
CMDCHAIN EQU   X'40'                    COMMAND CHAINING BIT            66800020
ADCODE   EQU   X'80'                                                    66900020
DEVCLASS EQU   18                                                       67000020
LOCAL    EQU   X'10'                                                    67100020
BITSOFF  EQU   X'E0'                                                    67200020
HEX40    EQU   X'40'                                                    67300020
HEX20    EQU   X'20'                                                    67350020
A        EQU   C'A'                                                     67400020
PROC     EQU   X'20'                                                    67430020
DIST     EQU   X'40'                                                    67460020
HEXRLN   EQU   X'40'                                                    67500020
TX       EQU   X'40'                                                    67600020
F1       EQU   X'F1'                                                    67620020
ALL      DC    C'ALL'                                                   67700020
NWRTEOT  EQU   X'FE'                                                    67750020
EXCPSAVE DC    16F'0'                    EXCP SAVE AREA                 67800020
ANDMASK  DC    X'00000003'                                              67900020
TPOPCODE DC    X'02020202'                                              68000020
SADCODE  DC    X'13'                    SADZERO CODE                    68100020
         DC    X'17'                    SADONE CODE                     68200020
         DC    X'1B'                    SADTWO CODE                     68300020
         DC    X'1F'                    SADTHREE CODE                   68400020
NOP      DC    X'20000001'              NOP COMMAND                     68500020
TRMCOMP  CLC   OPCZERO(OPCONE,RWORK),OPCTNME                            68600020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                  619 68700020
MAXVAL   DC    H'255'                                               618 68800020
TOTEMSG  DS    0H                                                       68830020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   68860020
         DC    C'IED049I OLT CONTROLS LINE '                            68890020
TOTEMSG1 DC    12C' ',C',COMMAND REJECTED'                              68920020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    68950020
         DC    X'0000'                   ROUTING - IN REG 0             68980020
MSG67    DS    0H                    /                                  69010020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   69040020
         DC    C'IED019I LINE '                                         69070020
MSG67A   DC    12C' ',C' ALREADY STARTED'                               69100020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69130020
         DC    X'0000'                   ROUTING - IN REG 0             69160020
ERMG     DS    0H                                                       69190020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   69220020
         DC    C'IED017I LINE '                                         69250020
ERMGTXT  DC    12C' ',C' NOT OPEN'                                      69280020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69310020
         DC    X'0000'                   ROUTING - IN REG 0             69340020
GOODMSG  DS    0H                                                       69370020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   69400020
         DC    C'IED020I LINE '                                         69430020
GOOD     DC    12C' ',C' STARTED'                                       69460020
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69490020
         DC    X'0000'                   ROUTING - IN REG 0             69520020
BMSG     DS    0H                                                       69550020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   69580020
         DC    C'IED092I BISYNC ERROR - LINE '                          69610020
BMSG1    DC    12C' ',C' CANNOT BE STARTED'                             69640020
DESCR5   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69670020
         DC    X'0000'                   ROUTING - IN REG 0             69700020
ERDLAY   DS    0H                                                       69740020
         DC    AL2(DESCRH-*),X'6000'    LENGTH AND MCS FLAGS            69780020
         DC    C'IED047I SYSTEM INTERVAL IS ACTIVE'                     69820020
DESCRH   DC    X'0800',X'0000'          DESCRIPTOR AND ROUTING CODES    69860020
*                                                                       69900020
         PRINT NOGEN                                                    70000020
         TPRIOR                                                         70100020
         TTRMD                                                          70200020
         TTNTD                                                          70300020
         TQCBD                                                          70400020
         TOPCD                                                          70500020
         TDEBD                                                          70600020
         DCBD  DSORG=TX                                                 70700020
         TLCBD                                                          70800020
         TAVTD                                                          70900020
*                                                                       71000020
         END                                                            71100020
