         TITLE '''IEDQCV'' - STOP/HALT LINE'                            00100020
IEDQCV   CSECT                                                          00200020
*A212000,513000,540000                                           A42413 00230021
*C164000,212500                                                  A42413 00260021
*********************************************************************** 00300020
*                                                                     * 00400020
*TITLE 'IEDQCV' PROCESSOR OF VARY OFFTP C OR I COMMANDS               * 00500020
*                                                                     * 00600020
*STATUS -- CHANGE LEVEL 0                                             * 00700020
*                                                                     * 00800020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 00900020
*   REQUEST THE STOPPING OF ACTIVITY ON A LINE EITHER IMMEDIATELY     * 01000020
*   OR AT COMPLETION OF THE CURRENT OPERATION.                        * 01100020
*                                                                     * 01200020
*   THE CLOSEDOWN BIT IN THE AVT (AVTCLOSN IN AVTBIT1) IS TESTED.     * 01300020
*   IF ON, ALL LINES IN THE SYSTEM ARE TO BE STOPPED, SO A FLAG IS    * 01400020
*   SET IN THE STOPLINE REQUEST ELEMENT.  THE ADDRESS OF THE STOP     * 01500020
*   LINE SUBTASK (IEDQHK) IS PLACED IN THE ELEMENT AND AQCTL          * 01600020
*   (SVC 102) IS ISSUED TO POST THE REQUEST TO STOP ALL LINES.  A     * 01700020
*   WAIT (SVC 1) IS ISSUED TO WAIT FOR AT LEAST ONE LINE TO BE        * 01800020
*   STOPPED.  WHEN THE WAIT IS SATISFIED, A SPECIAL RETURN CODE IS    * 01900020
*   SET TO INDICATE CLOSEDOWN IN PROGRESS, AND THE ROUTINE RETURNS    * 02000020
*   TO THE CONTROL MODULE.                                            * 02100020
*                                                                     * 02200020
*   THE COMMON INPUT BLOCK IS EXAMINED TO DETERMINE THE FORMAT OF     * 02300020
*   THE INPUT.  IF IT IS DCB ADDRESS, THE DEB ADDRESS IS OBTAINED     * 02400020
*   FROM DCBDEBAD AND CONTROL BRANCHES TO PROCESS THE DCB.  IF IT     * 02500020
*   IS TERMINAL NAME INPUT, THE TERMINAL NAME TABLE IS SEARCHED FOR   * 02600020
*   A MATCHING ENTRY.  IF NONE IS FOUND CONTROL RETURNS TO THE        * 02700020
*   CONTROL MODULE.  WHEN THE ENTRY IS FOUND, ITS QUEUE IS OBTAINED   * 02800020
*   FROM TRMDESTQ AND USED TO LOCATE THE DCB (QCBDCBAD) AND DEB.      * 02900020
*   CONTROL BRANCHES TO PROCESS THE DCB.                              * 03000020
*                                                                     * 03100020
*   IF INPUT IS DDNAME/RLN FORMAT AND RLN IS STILL IN CHARACTER       * 03200020
*   FORMAT, IT IS CONVERTED TO HEXADECIMAL AND TESTED FOR ZERO OR     * 03300020
*   GREATER THAN 255.  IF EITHER, AN ERROR RESPONSE IS BUILT AND      * 03400020
*   CONTROL RETURNS TO THE CONTROL MODULE.  THE TIOT IS ACCESSED      * 03500020
*   FROM THE TCB (TCB+12 - TCB AT AVTTCB) AND SERIALLY SEARCHED FOR   * 03600020
*   AN ENTRY MATCHING THE DDNAME.  IF NONE IS FOUND AN ERROR          * 03700020
*   MESSAGE IS BUILT AND THE ROUTINE RETURNS TO THE CONTROL MODULE.   * 03800020
*   THE DEB CHAIN IS ACCESSED FROM TCB+8, AND EACH DCB ASSOCIATED     * 03900020
*   WITH THE DEB IS TESTED FOR TCAM LINE DCB (DSORG OF X'40') AND     * 04000020
*   FOR A TIOT OFFSET MATCHING THAT DETERMINED IN THE SEARCH OF THE   * 04100020
*   TIOT.  IF THE END OF THE DEB CHAIN IS REACHED BEFORE AN ENTRY     * 04200020
*   IS FOUND, AN ERROR RESPONSE IS BUILT AND CONTROL EXITS TO THE     * 04300020
*   CONTROL MODULE.  WHEN THE PROPER DCB IS FOUND, CONTROL BRANCHES   * 04400020
*   TO PROCESS IT.                                                    * 04500020
*                                                                     * 04600020
*   IF INPUT IS LINE ADDRESS FORMAT, THE DEB CHAIN IS ACCESSED AND    * 04700020
*   EACH UCB ASSOCIATED WITH A DEB IS TESTED FOR AN ID MATCHING       * 04800020
*   THAT SPECIFIED.  IF NONE IS FOUND BEFORE THE END OF THE DEB       * 04900020
*   CHAIN IS REACHED AN ERROR MESSAGE IS BUILT AND THE ROUTINE        * 05000020
*   EXITS TO THE CONTROL MODULE.                                      * 05100020
*                                                                     * 05200020
*   NOW THAT THE PROPER DCB HAS BEEN DETERMINED FOR ALL FORMATS OF    * 05300020
*   THE COMMAND, THE COMMAND IS TESTED FOR STOPLINE 'ALL'.  IF ALL,   * 05400020
*   THE DEB AND DCB ADDRESSES ARE PLACED IN THE STOPLINE REQUEST      * 05500020
*   ELEMENT, THE ELEMENT IS COMPLETED AND POSTED AND THE WAIT IS      * 05600020
*   ISSUED AS FOR CLOSEDOWN.  UPON RETURN FROM THE WAIT, A RESPONSE   * 05700020
*   IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.               * 05800020
*                                                                     * 05900020
*   FOR A SINGLE LINE STOP, THE RLN IS COMPARED TO THE NUMBER OF      * 06000020
*   LINES IN THE GROUP.  IF IT IS HIGHER, AN ERROR RESPONSE IS        * 06100020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  THE LINE IS     * 06200020
*   CHECKED TO SEE IF IT OPEN DD DUMMY AND IF SO AN ERROR MESSAGE     * 06300020
*   IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  THE LCB      * 06400020
*   ADDRESS IS DETERMINED FROM DCBIOBAD AND TESTED FOR ALREADY        * 06500020
*   STOPPED.  IF SO AN ERROR RESPONSE IS BUILT AND CONTROL EXITS      * 06600020
*   TO THE CONTROL MODULE.  OTHERWISE THE LCB AND DEB ADDRESSES ARE   * 06700020
*   PLACED IN THE STOPLINE REQUEST ELEMENT AND THE REQUEST, WAIT,     * 06800020
*   AND EXIT ARE THE SAME AS FOR STOPLINE ALL COMMANDS.               * 06900020
*                                                                     * 07000020
*ENTRY POINTS --                                                      * 07100020
*        'IEDQCV' TO PROCESS VARY OFFTP C OR I OPERATOR CONTROL       * 07200020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 07300020
*                        LOAD EPLOC=LOADPRFX                          * 07400020
*                        LR   R1,ROPC                                 * 07500020
*                        LR   R15,R0                                  * 07600020
*                        BALR R14,R15                                 * 07700020
*                                                                     * 07800020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  COMMON       * 07900020
*   INPUT BLOCK AT LOCATION OPCCKELE.  RELEVANT FIELDS ARE            * 08000020
*                   +4   OPCLEN    X'00' IF STOPLINE ALL              * 08100020
*                                  X'40' IF RLN IS HEX                * 08200020
*                                  X'80' IF NO RLN                    * 08300020
*                                  1 - 3 LENGTH OF RLN                * 08400020
*                   +5   OPCRLN    RELATIVE LINE NUMBER               * 08500020
*                   +8   OPCTNME   DCB ADDRESS OR                     * 08600020
*                                  TERMINAL NAME OR                   * 08700020
*                                  DDNAME OR                          * 08800020
*                                  LINE ADDRESS                       * 08900020
*                   +18  OPCFLG    X'80' IF I-TYPE VARY               * 09000020
*                                  X'40' IF C-TYPE VARY               * 09100020
*                                                                     * 09200020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 09300020
*                                                                     * 09400020
*OUTPUT -- REGISTER 1 - ADDRESS OF A RESPONSE MESSAGE.                * 09500020
*                                                                     * 09600020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 09700020
*                   0    LINE STOPPED OR ALREADY STOPPED              * 09800020
*                   4    TERMINAL NOT FOUND, LINE NOT OPEN OR OPEN    * 09900020
*                        DD DUMMY, RLN INVALID                        * 10000020
*                   20   CLOSEDOWN IN PROGRESS                        * 10100020
*                                                                     * 10200020
*EXTERNAL ROUTINES --                                                 * 10300020
*        'AQCTL' (SVC 102) TO POST THE STOPLINE REQUEST               * 10400020
*                                                                     * 10500020
*        'WAIT' (SVC 1) TO WAIT FOR COMPLETION OF THE STOPLINE        * 10600020
*                                                                     * 10700020
*EXITS-NORMAL -- LINE OR LINE GROUP STOPPED OR ALREADY STOPPED.       * 10800020
*   APPROPRIATE MESSAGE BUILT, X'00' RETURN CODE SET.                 * 10900020
*                                                                     * 11000020
*   CLOSEDOWN IN PROGRESS.  REQUEST TO STOP ALL LINES SENT, AND AT    * 11100020
*   LEAST ONE LINE STOPPED.  X'14' RETURN CODE SET.                   * 11200020
*                                                                     * 11300020
*EXITS-ERROR -- TERMINAL NOT FOUND, LINE OR LINE GROUP NOT OPEN OR    * 11400020
*   OPEN DD DUMMY, OR RLN INVALIDLY SPECIFIED.  ERROR RESPONSE        * 11500020
*   BUILT, X'04' RETURN CODE SET.                                     * 11600020
*                                                                     * 11700020
*TABLES/WORK AREAS -- MESSAGES, STOPLINE REQUEST ELEMENT, OPERATOR    * 11800020
*   CONTROL AVT, DEB, DCB, LCB, QCB, TERMNAME TABLE, TERMINAL ENTRY   * 11900020
*   AND AVT.                                                          * 12000020
*                                                                     * 12100020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 12200020
*   PROBLEM PROGRAM MODE.                                             * 12300020
*                                                                     * 12400020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 12500020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 12600020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 12700020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 12800020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 12900020
*   DEFINITIONS.                                                      * 13000020
*                                                                     * 13100020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 13200020
*              IED017I, IED018I, IED025I, IED026I, IED063I            * 13300020
*                                                                     * 13400020
*********************************************************************** 13500020
*                                                                       13600020
*                                                                       13700020
R0       EQU   0                                                        13800020
R1       EQU   1                        PARAMETER                       13900020
ROPC     EQU   2                        OP CTL AVT BASE                 14000020
RCIB     EQU   3                                                        14100020
RAVT     EQU   4                        AVT BASE                        14200020
RWORK    EQU   5                        WORK                            14300020
RTCB     EQU   6                        BASE FOR TCB                    14400020
RDEB     EQU   6                        DEB BASE                        14500020
RDCB     EQU   7                        DCB BASE                        14600020
RWORK3   EQU   8                        WORK                            14700020
RLCB     EQU   9                        LCB BASE                        14800020
RDD      EQU   10                       DDNAME                          14900020
RUCB     EQU   10                       UCB BASE                        15000020
ROFF     EQU   11                       OFFSET TO DDNAME                15100020
RCTR     EQU   11                       COUNTER FOR RLNS                15200020
RBASE    EQU   12                       BASE OF ROUTINE                 15300020
R13      EQU   13                       SAVE AREA                       15400020
R14      EQU   14                       RETURN                          15500020
R15      EQU   15                       ENTRY                           15600020
RWORK2   EQU   15                       WORK                            15700020
         USING IEDQCV,RBASE             ADDRESSABILITY FOR ROUTINE      15800020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          15900020
         USING IEDQLCB,RLCB             ADDRESSABILITY FOR LCB          16000020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          16100020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          16200020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       16300020
         SAVE  (14,12),,IEDQCV-01/12/72                          A42413 16400021
         LR    RBASE,R15                SET UP BASE                     16500020
         LR    ROPC,R1                                                  16600020
         L     RCIB,OPCINPUT                                            16700020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 16800020
         L     RTCB,AVTTCB              GET TCB ADDR                    16900020
         MVI   OPCBITSW+1,OPCZERO        AET TO ZERO FOR FIRST          17000020
         TM    AVTBIT1,AVTCLOSN         ENTRY FOR CLOSEDOWN             17100020
         BNO   OTHER                    NO                              17200020
*                                                                       17300020
         MVI   OPCINFO,HEX80            SET FOR CLOSEDOWN               17400020
         MVI   OPCLEN,OPCZERO           FAKE ALL                        17500020
         B     GETLCB                   PROCESS THE LCB'S               17600020
AQCTL    EQU   *                                                        17700020
         TM    OPCFLG,HEX80              HALT LINE                      17800020
         BNO   LOAD                                                     17900020
HEX80    EQU   X'80'                    HALT LINE BIT SWITCH            18000020
*                                                                       18100020
         OI    OPCSAVE2+8,HEX80         TURN ON HALT LINE INDICATOR     18200020
LOAD     EQU   *                                                        18400020
         L     RWORK,AVTHK              GET HIO SUBTASK ADDR            18500020
         ST    RWORK,OPCSAVE2           PUT IN PARAMETER LIST           18600020
         SR    RWORK,RWORK              CLEAR                           18700020
         ST    RWORK,OPCSAVE2+4         CLEAR LINK FIELD                18800020
         MVI   OPCSAVE2+4,PRIOPCTL      SET PRIORITY                    18900020
         LA    RWORK,OPCSAVE2           GET ADDR OF LIST                19000020
         ST    RWORK,OPCPPL             SET UP POST PARAMETER           19100020
         ST    RWORK,OPCPPL+4             LIST FOR AQCTL TO QUEUE       19200020
         MVI   OPCPPL,TIOT                STOP LINE REQUEST TO MPC      19300020
         MVI   OPCPPL+4,TJID                                            19400020
         LA    R1,OPCPPL                GET ADDR OF LIST                19500020
         MVI   AVTOPCOB+4,AVTEZERO      CLEAR ECB FOR WAIT              19600020
         AQCTL                                                          19700020
STOPDONE EQU   *                                                        20000020
         WAIT  ECB=AVTOPCOB+4           WAIT FOR STOP TO BE DONE        20050020
         MVI   AVTOPCOB+4,AVTEZERO      CLEAR ECB FOR WAIT              20100020
         L     RWORK,AVTOPCOB           GET FIRST LLEMENT               20400020
         LA    RWORK,OPCZERO(RWORK)     CLEAR HIGH ORDER BYTE           20450020
         CLI   OPCFOUR(RWORK),PRISTOP   STOPPED LCB                     20500020
         BNE   STOPDONE                 NO - WAIT AGAIN                 20600020
         SPACE                                                          20650020
         LA    R1,OPCSAVE2              ADDR OF ELEM PASSED TO HK       20660020
         CR    RWORK,R1                 IS ELE COMING BACK FROM HK?     20670020
         BE    AROUND                   YES, IT IS ELEM NOT LCB         20680020
         SPACE                                                          20690020
         CLI   OPCVBCD2,ICHNG            IF ICHNG LET IT SET CKPT       20700020
         BE    AROUND                                                   20800020
*                                                                       20900020
         OI    OPCCKBIT,OPCCKPTN        TURN ON CKPT BIT                21000020
         TM    OPCED,OPCFOUR             IS THIS TOTE REQUEST           21020020
         BZ    AROUND                    NO, GO ON                      21040020
         MVI   LCBCPA,F1                 MARK THE LCB TOTE'S            21060020
AROUND   EQU   *                                                        21100020
         SR    R15,R15                  CLEAR                           21200020
         L     RWORK3,CVTPTR            LOAD CVT ADDR            A42413 21250021
         CLC   AVTCVTMP+1(3,RWORK3),AVTFZERO MP GEN'ED IN SYSTEM A42413 21260021
         BE    NOTS                     NO, CONTINUE             A42413 21270021
TSTMP65  CLI   CPUSTAT-IEAQFX00,AVTEZERO MP ACTIVE IN SYSTEM     A42413 21280021
         BNE   NOTS                      NO - PROCEED                   21300020
         TS    AVTOPCOB+8                ANY ONE QUEUI                  21350020
         BC    4,TSTMP65                 YES, WAIT UNTIL HE IS DONE     21400020
NOTS     EQU   *                                                        21450020
         MVC   AVTOPCOB+1(3),5(RWORK)    DEQUEUE THE ELEMENT            21500020
         MVI   AVTOPCOB+8,AVTEZERO       DONE, CLEAR TS SWITCH          21550020
         CR    RWORK,R1                 IS ELE COMING BACK FROM HK?     21560020
         BE    ERRTSO                   YES, NOT STOPPED DUE TO TSO     21570020
         SPACE                                                          21580020
         CLI   OPCLEN,OPCZERO            STOP  ALL                      21600020
         BE    STOPALL1                   YES, GO FOR THE NEXT          21700020
WRITE    EQU   *                                                        21800020
         MVC   GOODMSG(OPCEIGHT),OPCTNME PUT NAME IN MSG                21900020
         TM    OPCLEN,ADCODE            RLN SPECIFIED                   22000020
         BO    WRITE1                   NO                              22100020
*                                                                       22200020
         LA    R1,GOODMSG+9             GET VARIABLE ADDR               22300020
         BAL   R14,ALLTEST              TEST FOR RLN ALL                22400020
*                                                                       22500020
WRITE1   EQU   *                                                        22600020
         LA    R1,MSG                   GET MSG ADDR                    22700020
*                                                                       22800020
EXIT     EQU   *                                                        22900020
         ST    R1,OPCREG1(,R13)                                         23000020
         NI    OPCBITSW,BITSOFF         CLEAR WORK BITS                 23100020
OUT      EQU   *                                                        23200020
         RETURN (14,12),T,RC=(15)                                       23300020
*                                                                       23400020
*                                                                       23500020
*                                                                       23600020
ALLTEST  EQU   *                                                        23700020
         CLI   OPCLEN,AVTEZERO          RLN 'ALL' SPECIFIED             23800020
         BE    MOVEALL                  YES                             23900020
*                                                                       24000020
         MVC   OPCZERO(OPCTHREE,R1),OPCRLN PUT RLN IN MSG               24100020
         BR    R14                                                      24200020
*                                                                       24300020
MOVEALL  EQU   *                                                        24400020
         MVC   OPCZERO(OPCTHREE,R1),ALL PUT 'ALL' IN MSG                24500020
         BR    R14                                                      24600020
*                                                                       24700020
OTHER    EQU   *                                                        24800020
         TM    AVTBIT1,AVTDLAYN         INA A SYSTEM DELAY              24830020
         BO    DLAYERR                  YES REJECT THE COMMAND          24860020
         CLI   OPCTNME,AVTEZERO         DCB ADDR FORM                   24900020
         BNE   TERM                     NO                              25000020
*                                                                       25100020
         L     RDCB,OPCTNME             GET DCB ADDR                    25200020
         L     RDEB,12(RTCB)             ADDRESS OF TIOT                25300020
         LA    RDEB,0(RDEB)              CLEAR HIGH ORDER BYTE          25400020
         AH    RDEB,40(RDCB)             OFF SET TO DD ENTRY            25500020
         MVC   OPCTNME(8),4(RDEB)        SAVE FOR CHECKPOINT            25600020
         L     RTCB,AVTTCB               RESET THE TCB REG              25700020
         TM  OPCLEN,HEX40                 BINARY REL LINE               25800020
         BZ    SNGL                        NO                           25900020
         CLI   OPCRLN,OPCZERO            ALL SITUATION                  26000020
         BNE   SNGL                      NO, PROCEED                    26100020
         MVI   OPCLEN,OPCZERO            SET ALL SWITCH FOR USE         26200020
         B     SNGL                                                     26300020
CKOP     EQU   *                                                        26400020
         L     RDEB,DCBDEBAD            GET DEB ADDR                    26500020
         IC    R1,OPCRLN                GET RLN                         26600020
         STC   R1,OPCBITSW+1            MOVE INTWO WORK AREA            26700020
         B     PROCDCB                                                  26800020
*                                                                       26900020
STOPALL  EQU   *                                                        27000020
STOPALL1 SR    RCIB,RCIB                 HOUSEKEEP                      27100020
         IC    RCIB,OPCBITSW+1           HOUSEKEEP                      27200020
         LA    RCIB,1(RCIB)             NEXT REL LINE                   27300020
         STC   RCIB,OPCBITSW+1          RESET FOR NEXT ROUND            27400020
         CLC   OPCBITSW+1(OPCONE),DEBNMEXT     DONE?                    27500020
         BNH   PROCDCB1                  GET NEXT IOB                   27600020
         TM    OPCINFO,HEX80            CLOSEDOWN                       27700020
         BO    NEXTDEB1                  YES , GET THE NEXT DEB         27800020
         TM    OPCINFO,OPCONE            HAVE ANY LCBS BEEN STOPED      27900020
         BO    WRITE                     YES, MSG ALL STOPED            28000020
         B     ALRA                       NO,  MSG- ALL READY STOPPED   28100020
*                                                                       28200020
TERM     EQU   *                                                        28300020
         TM    OPCLEN,ADCODE            LINE ADDR FORM                  28400020
         BO    GETLCB                   YES - GO PROCESS                28500020
*                                                                       28600020
         TM    OPCBITSW,OPCMPPN         FROM PROCESSING PROGRAM         28700020
         BNO   SNGL                     NO - MUST BE DD                 28800020
*                                                                       28900020
         TM    OPCED,OPCFOUR             FROM TOTE                      29000020
         BO    SNGL                      YES, MUST BE DD                29100020
*                                                                       29200020
         CLI   OPCVBCD2,ICHNG           ICHANGE FROM MPP                29300020
         BE    SNGL                     YES - MUST BE DD                29400020
*                                                                       29500020
         L     RWORK,AVTRNMPT           GET TERMNAME TABLE              29600020
         LA    RWORK2,OPCONE            SET COUNTER                     29700020
         LH    RWORK3,TNTLEN-IEDQTNTD(RWORK) GET NUMBER ENTRIES         29800020
         SR    RCTR,RCTR                CLEAR                           29900020
         IC    RCTR,TNTENLEN-IEDQTNTD(RWORK) GET ENTRY LENGTH           30000020
         BCTR  RCTR,R0                  DECREMENT FOR EXECUTE           30100020
         LA    RWORK,TNTFIRST-IEDQTNTD(RWORK) GET FIRST ENTRY           30200020
TRMLOOP  EQU   *                                                        30300020
         CR    RWORK2,RWORK3            END OF TABLE                    30400020
         BH    ERR20                     YES ERROR EXIT                 30500020
*                                                                       30600020
         EX    RCTR,TRMCOMP             ENTRY FOUND                     30700020
         BE    TRMSET                   YES - PROCESS IT                30800020
*                                                                       30900020
         LA    RWORK,OPCFOUR(RCTR,RWORK) TO NEXT ENTRY                  31000020
         LA    RWORK2,OPCONE(,RWORK2)   BUMP COUNTER                    31100020
         B     TRMLOOP                  LLOK AT NEXT ENTRY              31200020
*                                                                       31300020
*                                                                       31700020
TRMSET   EQU   *                                                        31800020
         AR    RWORK,RCTR               GET TO TERM ADDR                31900020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RWORK) PUT ON BDRY            32000020
         L     RCTR,OPCWORK             GET TERM ADDR                   32100020
         TM    TRMSTATE-IEDQTRM(RCTR),PROC+DIST PROCESS OR DISTRIBUTION 32130020
         BNZ   ERR20                     YES, REJECT COMMAND            32160020
         L     RCTR,TRMDESTQ-1-IEDQTRM(RCTR) GET QCB ADDR               32200020
         L     RDCB,QCBDCBAD-1-IEDQQCB(RCTR) GET DCB ADDR               32300020
         B     CKOP                                                     32400020
*                                                                       32500020
GETRLN   EQU   *                                                        32600020
         SR    RWORK,RWORK             CLEAR                            32700020
         IC    RWORK,OPCRLN             GET RLN                         32800020
         B     SAVERLN                                                  32900020
*                                                                       33000020
SNGL     EQU   *                                                        33100020
         CLI   OPCLEN,AVTEZERO          RLN 'ALL'                       33200020
         BE    DDLOOP                   YES - SKIP RLN CONVERSION       33300020
*                                                                       33400020
         TM    OPCLEN,HEXRLN            RLN ALREADY HEX                 33500020
         BO    GETRLN                   YES - DO NOT CONVERT            33600020
*                                                                       33700020
         MVC   OPCDOUBL(OPCTHREE),OPCRLN PUT RLN IN WORK AREA           33800020
         SR    R15,R15                  CLEAR                           33900020
         IC    R15,OPCLEN               GET LENGTH OF RLN               34000020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE       619 34100020
         EX    R15,PACK                 CONVERT TO PACKED           619 34200020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CONVERT          619 34300020
         CVB   RWORK,OPCDOUBL           CONVERT                         34400020
SAVERLN  EQU   *                                                        34450020
         CH    RWORK,MAXVAL             RLN > 255                       34500020
         BH    COMINV                   YES - REJECT COMMAND            34600020
*                                                                       34700020
         LTR   RWORK,RWORK              RLN ZERO                        34900020
         BZ    COMINV                   YES - REJECT COMMAND            35000020
*                                                                       35100020
         STC   RWORK,OPCBITSW+1         SAVE HEX RLN                    35200020
DDLOOP   EQU   *                                                        35300020
         L     RDD,TIOT(,RTCB)          GET TIOT ADDR                   35400020
         LA    ROFF,STARTOFF            OFFSET TO FIRST DD              35500020
         SR    RWORK2,RWORK2            CLEAR                           35600020
         LA    RDD,STARTOFF(,RDD)       SET ADDR FIRST DDNAME           35700020
LOOP     EQU   *                                                        35800020
         IC    RWORK2,OPCZERO(,RDD)     GET LENGTH BYTE                 35900020
         CLI   OPCZERO(RDD),OPCZERO     ANOTHER DD                      36000020
         BE    ERR20                     NO, DD NAME NOT FOUND          36100020
*                                                                       36200020
         CLC   OPCFOUR(OPCEIGHT,RDD),OPCTNME SPECIFIED DD               36300020
         BE    GETLCB                   YES - WE HAVE FOUND DD          36400020
*                                                                       36500020
         AR    ROFF,RWORK2              BUMP OFFSET TO NEXT DD          36600020
         AR    RDD,RWORK2               BUMP TO NEXT ENTRY              36700020
         B     LOOP                     GET NEXT DD                     36800020
*                                                                       36900020
COMINV   EQU   *                                                        37000020
         LA    R1,OPCERMSG              GET MSG ADDR                    37100020
         LA    R15,OPCEIGHT              SET RLN BAD - ERROR CODE       37160020
         B     EXIT                      GET OUT                        37220020
*                                                                       37300020
GETLCB   EQU   *                                                        37400020
         L     RDEB,DEB(,RTCB)          GET FIRST DEB                   37500020
GETDCB   EQU   *                                                        37600020
         L     RDCB,DEBDCBAD            GET DCB                         37700020
         TM    DCBDSORG+1,TX            TCAM LINE                       37800020
         BNO   NEXTDEB                  NO - WRONG DCB                  37900020
*                                                                       38000020
         TM    OPCLEN,ADCODE            ADDR FORM                       38100020
         BO    UCB                      YES - SEARCH UCBS               38200020
*                                                                       38300020
         TM    OPCINFO,HEX80            CLOSE DOWN                      38400020
         BO    STOPALL                  YES, GO AGAIN                   38500020
         LH    RWORK2,DCBTIOT           GET OFFSET INTO TIOT            38600020
         CR    RWORK2,ROFF              SAME AS FOR DD                  38700020
         BNE   NEXTDEB                  NO - WRONG DCB                  38800020
*                                                                       38900020
PROCDCB  EQU   *                                                        39000020
         CLI   OPCVBCD2,ICHNG            STOP LINE FOR ICHNG            39100020
         BNE   PRODCBA                   NO, PROCEED                    39200020
         TM    OPCED,HEX80               IS THIS RESTART                39300020
         BO    PRODCBB                   YES, DONT CK DCB FOR OPEN      39400020
PRODCBA  EQU   *                                                        39500020
         CLI   DCBTIOT,A                LINE OPEN                       39600020
         BNL   ERR01                     NO, REJECT COMMAND             39700020
*                                                                       39800020
PRODCBB  EQU   *                                                        39900020
         CLI   OPCLEN,AVTEZERO          STOP ALL                        40000020
         BE    STOPALL                  YES                             40100020
*                                                                       40200020
         CLC   OPCBITSW+1(OPCONE),DEBNMEXT RLN > NUMBER EXTENTS         40300020
         BH    COMINV                   YES - REJECT COMMAND            40400020
*                                                                   622 40500020
PROCDCB1 EQU   *                                                        40600020
         SR    R0,R0                    CLEAR                           40700020
         IC    R0,OPCBITSW+1            PICK UP RLN                     40800020
         LR    RWORK,R0                 SAVE FOR TEST                   40900020
         SLL   RWORK,OPCTWO             MULTIPLY BY FOUR                41000020
         L     RWORK,DEBUCBAD-4-DEBNMSUB(RWORK,RDEB) GET UCB ADDR       41100020
         LA    RWORK,OPCZERO(,RWORK)    CLEAR HIGH BYTE                 41200020
         LTR   RWORK,RWORK              OPENED DD DUMMY                 41300020
         BZ    ERRA                     YES - REJECT COMMAND            41400020
*                                                                       41500020
         B     IOBCALC                                                  41600020
*                                                                       41700020
OPENCODE EQU   *                                                        41800020
         CLI   DCBTIOT,A                LINE OPEN                       41900020
         BNL   ERR01                     NO REJECT COMMAND              42000020
*                                                                       42100020
IOBCALC  EQU   *                                                        42200020
         L     RLCB,DCBIOBAD            GET IOB                         42300020
         LA    RLCB,OPCZERO(RLCB)       CLDAR GIGH BYTE                 42400020
         SR    R1,R1                    CLEAR                           42500020
         IC    R1,DCBEIOBX              GET IOB LENGTH                  42600020
         MR    R0,R0                    MULTIPLY IOB BY RLN             42700020
         AR    RLCB,R1                  ADD RESULT TO IOB ADDR          42800020
         LA    RWORK3,LCBFLAG1-IEDQLCB  GET LENGTH OF IOB               42900020
         SR    RLCB,RWORK3              GET TO LCB START                43000020
         ST    RDEB,OPCSAVE2+12         SAVE DEB ADDR                   43100020
         ST    RLCB,OPCSAVE2+16         SAVE LCB ADDR                   43200020
         CLI   LCBSTAT1,AVTEZERO        LINE ALREADY STOPPED            43300020
         BE    ALR                                                      43400020
         TM    OPCBITSW,OPCMCPN          REQUEST FORM TERMINAL          43410020
         BZ    SPEC1                       NO, PROCEED                  43420020
         L     RWORK,AVTOPCOB            BUFFER REQUESTING              43430020
         L     RWORK,12(RWORK)           GET LCB ASSOCIATED             43440020
         LA    RWORK,OPCZERO(RWORK)      CLEAR HIGH BYTE                43450020
         CR    RWORK,RLCB                IS REQUESTED - REQUESTOR       43460020
         BE    ERRSELF                   YES, REJECT REQUEST            43470020
SPEC1    EQU   *                                                        43480020
         OI    OPCINFO,OPCONE            SET BIT SAYING HAVE GONE       43500020
*                                            TO STOP A LINE             43600020
*                                                                       43700020
         MVI   OPCSAVE2+8,AVTEZERO      SET 'SINGLE' INDICATOR          43800020
         CLI   OPCVBCD2,ICHNG            ISTHIS FOR ICHNG               43900020
         BNE   AQCTL                     NO GO ON                       44000020
         TM    OPCED,HEX80               RESTART SITUATION              44100020
         BO    ALR1                      YES, DONT STOP THE LINE        44200020
         B     AQCTL                                                    44300020
*                                                                       44400020
ALR      EQU   *                                                        44500020
         TM    OPCED,OPCFOUR             IS THIS TOTE REQUEST           44520020
         BZ    ALR2                      NO, PROCEED                    44540020
         MVI   LCBCPA,F1                 MARK THE LCB TOTES             44560020
ALR2     EQU   *                                                        44580020
         CLI   OPCLEN,OPCZERO            STOP LINE ALL                  44600020
         BE    STOPALL1                  YES, GET THE NEXT              44700020
ALRA     EQU   *                                                        44800020
         MVC   ALRMSG(OPCEIGHT),OPCTNME PUT NAME IN MSG                 44900020
         TM    OPCLEN,ADCODE            RLN SPECIFIED                   45000020
         BO    ALR1                     NO                              45100020
*                                                                       45200020
         LA    R1,ALRMSG+9              GET VARIABLE ADDR               45300020
         BAL   R14,ALLTEST              TEST FOR RLN ALL                45400020
*                                                                       45500020
ALR1     EQU   *                                                        45600020
         LA    R1,MSGA                                                  45700020
         SR    R15,R15                  SET GOOD RETURN                 45800020
         B     EXIT                                                     45900020
*                                                                       46000020
UCB      EQU   *                                                        46100020
         SR    RWORK,RWORK              CLEAR                           46200020
         IC    RWORK,DEBNMEXT           GET NUMBER OF RLNS              46300020
         LA    RWORK3,DEBUCBAD          GET POINTER TO UCBS             46400020
         LA    RCTR,OPCONE              SET COUNT TO ONE                46500020
UCBLOOP  EQU   *                                                        46600020
         L     RUCB,OPCZERO(,RWORK3)    GET FIRST UCB ADDR              46700020
         CLC   ADDR(OPCTHREE,RUCB),OPCTNME SPECIFIED ADDR               46800020
         BE    FOUND                    YES                             46900020
*                                                                       47000020
         LA    RCTR,OPCONE(,RCTR)       ADD 1 TO COUNT                  47100020
         LA    RWORK3,OPCFOUR(,RWORK3)  GET TO NEXT UCB ADDR            47200020
         CR    RCTR,RWORK               ANY MORE EXTENTS                47300020
         BH    NEXTDEB                  NO - GET NEXT DEB               47400020
*                                                                       47500020
         B     UCBLOOP                                                  47600020
*                                                                       47700020
FOUND    EQU   *                                                        47800020
         LR    R0,RCTR                  PUT RLN OFFSET IN R0            47900020
         STC   R0,OPCBITSW+1            SAVE HEX RLN FOR USE IN HK      47950020
         B     OPENCODE                                                 48000020
NEXTDEB1 EQU   *                                                        48100020
         MVI   OPCBITSW+1,OPCZERO       RESET FOR ANOTHER PASS          48200020
*                                                                       48300020
NEXTDEB  EQU   *                                                        48400020
         L     RDEB,OPCFOUR(RDEB)       GET NEXT DEB ADDR               48500020
         LA    RDEB,OPCZERO(,RDEB)      CLEAR HIGH BYTE                 48600020
         LTR   RDEB,RDEB                ANOTHER DEB                     48700020
         BNZ   GETDCB                   YES - PROCESS IT                48800020
*                                                                       48900020
         TM    OPCINFO,HEX80            CLOSEDEWN IN PROGRESS           49000020
         BZ    ERR20                   NO, THAN ERROR                   49100020
         LA    R15,CLOSERTN             CLOSEDOWN RETURY                49200020
         B     WRITE                    EXIT                            49300020
ERR20    EQU   *                                                        49310020
         LA    R15,HEX20               ERR OR CODE                      49320020
         B     ERR                                                      49330020
ERR01    EQU   *                                                        49340020
         LA    R15,OPCONE                DD NOT OPNED                   49350020
ERR      EQU   *                                                        49400020
         MVC   ERMGTXT(OPCEIGHT),OPCTNME PUT NAME IN MSG                49500020
         TM    OPCLEN,ADCODE            RLN SPECIFIED                   49600020
         BO    ERR1                     NO                              49700020
*                                                                       49800020
         LA    R1,ERMGTXT+9             GET VARIABLE ADDR               49900020
         BAL   R14,ALLTEST              TEST FOR RLN ALL                50000020
*                                                                       50100020
ERR1     EQU   *                                                        50200020
         LA    R1,ERMG                  PICK UP ERROR MESSAGE           50300020
         B     EXIT                                                     50350020
SETBAD   EQU   *                                                        50400020
         LA    R15,OPCFOUR              SET BAD RETURN                  50500020
         B     EXIT                                                     50600020
ERRA     CLI   OPCLEN,OPCZERO            STOPLINE ALL                   50700020
         BE    STOPALL1                  YES, GET THE NEXT              50800020
         B     ERR01                     NO, ERROR CONDITION            50850020
ERRSELF  EQU   *                                                        50905020
         CLI   OPCLEN,OPCZERO            STOP, ALL SITUATION            50910020
         BE    STOPALL1                  YES GET THE LEXT               50915020
         LA    R1,MSGSELF                GET ERR MSG                    50920020
         B     SETBAD                    GO SET BAD RETURN CODE         50925020
ERRTSO   EQU   *                                                        50930020
         MVC   ERTSOTXT(OPCEIGHT),OPCTNME     SET NAME IN MSG           50935020
         TM    OPCLEN,ADCODE             ABSOLUTE ADDRESS               50940020
         BO    ERRTSO1                   YES                            50945020
         CLI   OPCLEN,OPCZERO            ALL SITUATION                  50950020
         BE    STOPALL1                   YES, GET NEXT LINE            50955020
         LA    R1,ERTSOTXT+9              SET UP FOR RELATIVE LINE      50960020
         BAL   R14,ALLTEST               CHECK FOR RELATIVE LINE ALL    50965020
ERRTSO1  EQU   *                                                        50970020
         LA    R1,ERTSOM                 GET ADDR OF MESSAGE            50975020
         B     SETBAD                    SET BAD RETURN CODE            50980020
DLAYERR  EQU   *                                                        50985020
         LA    R1,ERDLAY                SET UP DELAY MESSAGE            50990020
         B     SETBAD                   REJECT THE COMMAND              50995020
*                                                                       51000020
DEB      EQU   8                        OFFSET INTO TCB OF DEB          51100020
TIOT     EQU   12                       OFFSET INTO TCB OF TIOT         51200020
ADDR     EQU   13                                                       51300020
CVTPTR   EQU   16                       POINTER TO CVT           A42413 51350021
STARTOFF EQU   24                                                       51400020
CLOSE    EQU   X'10'                                                    51500020
CLOSERTN EQU   X'14'                                                    51600020
C1       EQU   X'28'                                                    51700020
HEXRLN   EQU   X'40'                                                    51800020
PROC     EQU   X'20'                                                    51830020
DIST     EQU   X'40'                                                    51860020
TX       EQU   X'40'                                                    51900020
F1       EQU   X'F1'                                                    51950020
ICHNG    EQU   X'06'                                                    52000020
HEX40    EQU   X'40'                                                    52100020
HEX20    EQU   X'20'                                                    52150020
TJID     EQU   X'80'                                                    52200020
ADCODE   EQU   X'80'                                                    52300020
BITSOFF  EQU   X'E0'                                                    52400020
PRISTOP  EQU   X'E8'                                                    52500020
A        EQU   C'A'                                                     52600020
ALL      DC    C'ALL'                                                   52700020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                  619 52800020
TRMCOMP  CLC   OPCZERO(OPCONE,RWORK),OPCTNME                            52900020
MAXVAL   DC    H'255'                                                   53000020
MSGA     DS    0H                                                       53020020
         DC    AL2(DESCR6-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   53040020
         DC    C'IED025I '                                              53060020
ALRMSG   DC    12C' ',C' ALREADY STOPPED'                               53080020
DESCR6   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    53100020
         DC    X'0000'                   ROUTING - IN REG 0             53120020
ERMG     DS    0H                                                       53140020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   53160020
         DC    C'IED017I LINE '                                         53180020
ERMGTXT  DC    12C' ',C' NOT OPEN'                                      53200020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    53220020
         DC    X'0000'                   ROUTING - IN REG 0             53240020
MSGSELF  DS    0H                                                       53260020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   53280020
         DC    C'IED013I STOP REQUEST FOR SELF - '                      53300020
         DC    C'VARY COMMAND REJECTED'                                 53320020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    53340020
         DC    X'0000'                   ROUTING - IN REG 0             53360020
ERTSOM   DS    0H                                                       53380020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   53400020
         DC    C'IED012I TSO SESSION ON LINE '                          53420020
ERTSOTXT DC    12C' ',C' COMMAND REJECTED'                              53440020
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    53460020
         DC    X'0000'                   ROUTING - IN REG 0             53480020
MSG      DS    0H                                                       53500020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   53520020
         DC    C'IED026I '                                              53540020
GOODMSG  DC    12C' ',C' STOPPED'                                       53560020
DESCR5   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    53580020
         DC    X'0000'                   ROUTING - IN REG 0             53600020
ERDLAY   DS    0H                                                       53660020
         DC    AL2(DESCRH-*),X'6000'    LENGTH AND MCS FLAGS            53720020
         DC    C'IED047I SYSTEM INTERVAL IS ACTIVE'                     53780020
DESCRH   DC    X'0800',X'0000'          DESCRIPTOR AND ROUTING CODES    53840020
*                                                                       53900020
         IEAQFX 65,MCH,M65MP                                     A42413 54000021
         TPRIOR                                                         54100020
         TOPCD                                                          54200020
         TDEBD                                                          54300020
         DCBD  DSORG=TX                                                 54400020
         TLCBD                                                          54500020
         TQCBD                                                          54600020
         TTNTD                                                          54700020
         TTRMD                                                          54800020
         TAVTD                                                          54900020
         END                                                            55000020
