         TITLE '''IEDQCW'' - START/STOP AUTOPOLL'                       00200020
IEDQCW   CSECT                                                          00400020
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQCW' PROCESSOR OF MODIFY AUTOPOLL COMMANDS                 * 01000020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01400020
*                                                                     * 01600020
*FUNCTION -- THIS ROUTINE PROCESSES OPERATOR CONTROL COMMANDS WHICH   * 01800020
*   REQUEST THAT AUTOPOLLING BE STOPPED OR STARTED FOR A SPECIFIED    * 02000020
*   LINE.                                                             * 02200020
*                                                                     * 02400020
*   THE ROUTINE TESTS THE COMMON INPUT BLOCK TO DETERMINE IF THE      * 02600020
*   DDNAME/RLN OR THE HARDWARE ADDRESS FORMAT WAS USED.  IF IT IS     * 02800020
*   DDNAME, THE RLN IS CHECKED FOR ALL.  IF ALL, AN INVALID COMMAND   * 03000020
*   MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.       * 03200020
*   OTHERWISE THE RLN IS CONVERTED TO HEXADECIMAL AND TESTED FOR      * 03400020
*   ZERO OR GREATER THAN 255.  EITHER IS INVALID, SO THE COMMAND IS   * 03600020
*   REJECTED AND THE ROUTINE EXITS TO THE CONTROL MODULE.  IF THE     * 03800020
*   RLN IS VALID, THE TCB IS OBTAINED FROM THE AVT AND THE TIOT       * 04000020
*   (AT TCB+12) IS SERIALLY SEARCHED FOR THE DDNAME.  IF A MATCH IS   * 04200020
*   NOT FOUND, AN ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE   * 04400020
*   CONTROL MODULE.  WHEN THE MATCHING ENTRY IS FOUND, ITS OFFSET     * 04600020
*   INTO THE TIOT IS SAVED.                                           * 04800020
*                                                                     * 05000020
*   FOR BOTH INPUT FORMATS, THE START OF THE DEB CHAIN IS FOUND AT    * 05200020
*   TCB+8.  THE ASSOCIATED DCB (DEBDCBAD) IS TESTED FOR A TCAM LINE   * 05400020
*   DCB (DSORG OF X'40').  IF NOT, THE NEXT DEB IS ACCESSED AND THE   * 05600020
*   DEB CHAIN IS PROCESSED.  IF NO TCAM LINE DCBS ARE FOUND, AN       * 05800020
*   ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL         * 06000020
*   MODULE.                                                           * 06200020
*                                                                     * 06400020
*   FOR DDNAME FORMAT, A TCAM LINE DCB'S TIOT OFFSET IS COMPARED TO   * 06600020
*   THAT COMPUTED ABOVE.  IF THEY DO NOT MATCH, THE SEARCH THROUGH    * 06800020
*   THE DEB CHAIN CONTINUES.  WHEN THE PROPER DCB IS FOUND, ITS UCB   * 07000020
*   (AT DEBUCBAD) IS TESTED FOR ZERO, IMPLYING LINE OPEN DD DUMMY.    * 07200020
*   IF IT IS ZERO, AN ERROR MESSAGE IS BUILT AND CONTROL EXITS TO     * 07400020
*   THE CONTROL MODULE.                                               * 07600020
*                                                                     * 07800020
*   IF LINE ADDRESS WAS SPECIFIED, EACH UCB ASSOCIATED WITH THE DEB   * 08000020
*   IS TESTED FOR A MATCH ON THE ADDRESS.  SEARCHING CONTINUES        * 08200020
*   THROUGH THE DEB CHAIN UNTIL THE UCB IS FOUND.                     * 08400020
*                                                                     * 08600020
*   ONCE THE PROPER DCB IS OBTAINED FOR EITHER FORMAT, IT IS TESTED   * 08800020
*   FOR OPEN STATUS.  IF NOT OPEN, AN ERROR MESSAGE IS BUILT AND      * 09000020
*   CONTROL RETURNS TO THE CONTROL MODULE.  IF THE RLN IS GREATER     * 09200020
*   THAN THE NUMBER OF LINES IN THE LINE GROUP AN ERROR MESSAGE IS    * 09400020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  IF THE UCB IS   * 09600020
*   NOT A COMMUNICATIONS UCB OR IS NOT CAPABLE OF AUTOPOLL, AN        * 09800020
*   ERROR MESSAGE IS BUILT AND THE ROUTINE EXITS TO THE CONTROL       * 10000020
*   MODULE.                                                           * 10200020
*                                                                     * 10400020
*   THE INVITATION LIST ADDRESS IS OBTAINED FROM THE DCB (DCBINVLI)   * 10600020
*   AND THE INPUT BLOCK TESTED TO SEE IF AUTOPOLL IS TO BE STARTED    * 10800020
*   OR STOPPED.  IF TO BE STARTED AND IT IS ALREADY STARTED OR TO     * 11000020
*   BE STOPPED BUT IS ALREADY STOPPED, A RESPONSE IS BUILT AND        * 11200020
*   CONTROL RETURNS TO THE CONTROL MODULE.  OTHERWISE, THE STATUS     * 11400020
*   BIT IN THE INVITATION LIST IS TURNED ON OR OFF AS APPROPRIATE,    * 11600020
*   THE CHECKPOINT FLAGS ARE TURNED ON, A RESPONSE IS BUILT, AND      * 11800020
*   THE ROUTINE EXITS TO THE CONTROL MODULE.                          * 12000020
*                                                                     * 12200020
*ENTRY POINTS --                                                      * 12400020
*        'IEDQCW' TO PROCESS MODIFY AUTOPOLL OPERATOR CONTROL         * 12600020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 12800020
*                        LOAD EPLOC=LOADPRFX                          * 13000020
*                        LR   R1,ROPC                                 * 13200020
*                        LR   R15,R0                                  * 13400020
*                        BALR R14,R15                                 * 13600020
*                                                                     * 13800020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  THE COMMON   * 14000020
*   INPUT BLOCK IS AT THE TAG OPCCKELE AND THE FIELDS RELEVANT TO     * 14200020
*   THIS MODULE ARE                                                   * 14400020
*                   +4   OPCLEN    X'00' IF RLN ALL                   * 14600020
*                                  X'80' IF NO RLN (LINE ADDRESS)     * 14800020
*                                  1 - 3 LENGTH OF RLN                * 15000020
*                   +5   OPCRLN    RELATIVE LINE NUMBER               * 15200020
*                   +8   OPCTNME   DDNAME OR LINE ADDRESS             * 15400020
*                   +18  OPCFLG    X'80' IF MODIFY AUTOPOLL ON        * 15600020
*                                  X'40' IF MODIFY AUTOPOLL OFF       * 15800020
*                                                                     * 16000020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 16200020
*                                                                     * 16400020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE MESSAGE.               * 16600020
*                                                                     * 16800020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 17000020
*                   X'00' IF MODIFY SUCCESSFUL, OR IF REQUESTED       * 17200020
*                     STATUS ALREADY ACTIVE                           * 17400020
*                   X'04' IF RLN INVALID, LINE NOT OPEN, OR LINE      * 17600020
*                     NOT CAPABLE OF BEING AUTOPOLLED                 * 17800020
*                                                                     * 18000020
*EXTERNAL ROUTINES -- N/A.                                            * 18200020
*                                                                     * 18400020
*EXITS-NORMAL -- STATUS MODIFIED AS REQUESTED.  RESPONSE BUILT,       * 18600020
*   X'00' RETURN CODE SET.                                            * 18800020
*                                                                     * 19000020
*   REQUESTED STATUS ALREADY ACTIVE.  RESPONSE BUILT, X'00' RETURN    * 19200020
*   CODE SET.                                                         * 19400020
*                                                                     * 19600020
*EXITS-ERROR -- RELATIVE LINE NUMBER IN ERROR.  INVALID COMMAND       * 19800020
*   MESSAGE BUILT, X'04' RETURN CODE SET.                             * 20000020
*                                                                     * 20200020
*   LINE NOT FOUND SEARCHING TIOT OR DEB CHAIN, OR WAS NOT OPEN OR    * 20400020
*   OPENED DD DUMMY.  NOT OPEN MESSAGE BUILT, X'04' RETURN CODE       * 20600020
*   SET.                                                              * 20800020
*                                                                     * 21000020
*   LINE NOT COMMUNICATIONS LINE OR NOT CAPABLE OF AUTOPOLL.  NOT     * 21200020
*   CAPABLE MESSAGE BUILT, X'04' RETURN CODE SET.                     * 21400020
*                                                                     * 21600020
*TABLES/WORK AREAS -- MESSAGES, AVT, DCB, DEB, OPERATOR CONTROL       * 21800020
*   AVT.                                                              * 22000020
*                                                                     * 22200020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 22400020
*   PROBLEM PROGRAM MODE.                                             * 22600020
*                                                                     * 22800020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 23000020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 23200020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 23400020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 23600020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 23800020
*   DEFINITIONS.                                                      * 24000020
*                                                                     * 24200020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 24400020
*              IED017I, IED018I, IED021I, IED022I, IED027I, IED028I   * 24600020
*              IED057I                                                * 24800020
*                                                                     * 25000020
*********************************************************************** 25200020
*                                                                       25400020
*                                                                       25600020
R0       EQU   0                        WORK                            25800020
R1       EQU   1                        PARAMETER                       26000020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       26200020
RAVT     EQU   4                        AVT BASE                        26400020
RDD      EQU   5                        DDNAME                          26600020
RUCB     EQU   5                        UCB BASE                        26800020
ROFF     EQU   6                        OFFSET TO DDNAME                27000020
RCTR     EQU   6                        COUNTER                         27200020
RTCB     EQU   7                        TCB BASE                        27400020
RDEB     EQU   7                        DEB BASE                        27600020
RLCB     EQU   11                        LCB REGESTER                   27700020
RDCB     EQU   8                        DCB BASE                        27800020
RLIST    EQU   9                        INVITATION LIST BASE            28000020
RWORK    EQU   10                       WORK                            28200020
RWORK2   EQU   11                       WORK                            28400020
RBASE    EQU   12                       ROUTINE BASE                    28600020
R13      EQU   13                       SAVE AREA                       28800020
R14      EQU   14                       RETURN                          29000020
R15      EQU   15                       ENTRY POINT                     29200020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       29400020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          29600020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          29800020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          30000020
         USING IEDQLCB,RLCB                                             30100020
         USING IEDQCW,RBASE             ADDRESSABILITY FOR ROUTINE      30200020
         SAVE  (14,12),,IEDQCW-02/18/71                                 30400020
         LR    RBASE,R15                                                30600020
         LR    ROPC,R1                                                  30800020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 31000020
         L     RTCB,AVTTCB              GET TCB ADDR                    31200020
         MVI   OPCDOUBL,AVTEBLNK        CLEAR WORK AREA TO              31400020
         MVC   OPCDOUBL+1(OPCSEVEN),OPCDOUBL BLANKS                     31600020
         TM    OPCLEN,ADCODE             DDNAME OR ADDRESS              31800020
         BO    GETUCB                    ADDR - SKIP RLN CODE           32000020
*                                                                       32200020
         CLI   OPCLEN,AVTEZERO          RLN 'ALL'                       32400020
         BE    COMINV                   YES - REJECT COMMAND            32600020
*                                                                       32800020
         MVC   OPCDOUBL(OPCTHREE),OPCRLN PUT RLN IN WORK AREA           33000020
         SR    R15,R15                  CLEAR                           33200020
         IC    R15,OPCLEN               GET LENGTH OF LLN               33400020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE       620 33600020
         EX    R15,PACK                 CONVERT RLN TO PACKED       620 33800020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CVB              620 34000020
         CVB   RWORK,OPCDOUBL           CONVERT                         34200020
         CH    RWORK,MAXVAL             RLN > 255                       34400020
         BH    COMINV                   YES - REJECT COMAND             34600020
*                                                                       34800020
         LTR   RWORK,RWORK              RLN ZERO                        35000020
         BZ    COMINV                   YES - REJECT COMMAND            35200020
*                                                                       35400020
         STC   R15,OPCDOUBL             SAVE HEX RLN                    35600020
         STC   RWORK,OPCDOUBL            SAVE HEX REL                   35700020
         L     RDD,TIOT(RTCB)           GET TIOT ADDR                   35800020
         LA    ROFF,STARTOFF            OFFSET TO FIRST DD              36000020
         SR    RWORK2,RWORK2            CLEAR                           36200020
         LA    RDD,STARTOFF(RDD)        GET FIRST DD                    36400020
LOOP     EQU   *                                                        36600020
         IC    RWORK2,OPCZERO(,RDD)     GET LENGTH BYTE                 36800020
         CLI   OPCZERO(RDD),OPCZERO     ANOTHER DD                      37000020
         BE    ERR                      NO - DDNAME NOT FOUND           37200020
*                                                                       37400020
         CLC   OPCFOUR(OPCEIGHT,RDD),OPCTNME SPECIFIED DD               37600020
         BE    GETUCB                   YES - PROCESS IT                37800020
*                                                                       38000020
         AR    RDD,RWORK2               BUMP TO NEXT ENTRY              38200020
         AR    ROFF,RWORK2              BUMP OFFSET TO NEXT DD          38400020
         B     LOOP                     GET NEXT DD                     38600020
*                                                                       38800020
COMINV   EQU   *                                                        39000020
         LA    RWORK,OPCERMSG           GET MSG ADDR                    39200020
SETBAD   EQU   *                                                        39400020
         LA    R15,OPCFOUR              SET BAD RETURN                  39600020
         B     STORE                                                    39800020
*                                                                       40000020
GETUCB   EQU   *                                                        40200020
         L     RDEB,DEB(,RTCB)          GET START OF DEB CHAIN          40400020
GETDCB   EQU   *                                                        40600020
         L     RDCB,DEBDCBAD            GET DCB                         40800020
         TM    DCBDSORG+1,TX            TCAM LINE                       41000020
         BNO   NEXTDEB                  NO - GET NEXT DEB               41200020
*                                                                       41400020
         TM    OPCLEN,ADCODE             DD OR ADDR                     41600020
         BO    UCB                       ADDR                           41800020
*                                                                       42000020
         LH    RWORK2,DCBTIOT           GET OFFSET TO DDNAME            42200020
         CR    RWORK2,ROFF              SAME AS COMPUTED                42400020
         BNE   NEXTDEB                  NO - GET NEXT DEB               42600020
*                                                                       42800020
         SR    RUCB,RUCB                CLEAR                           43000020
         IC    RUCB,OPCDOUBL            GET HEX RLN                     43200020
         CLC   OPCDOUBL(OPCONE),DEBNMEXT  EXTENT NUMBER GREATER TOTAL   43260020
         BH    ERR                      YES, NOT OPENED                 43320020
         SLL   RUCB,OPCTWO              MULTIPLY BY FOUR                43400020
         L     RUCB,DEBUCBAD-4-DEBNMSUB(RUCB,RDEB) GET UCB ADDR         43600020
         LA    RUCB,OPCZERO(,RUCB)      CLEAR HIGH BYTE                 43800020
         LTR   RUCB,RUCB                OPENED DD DUMMY                 44000020
         BZ    ERR                      YES - REJECT COMMAND            44200020
*                                                                       44400020
TESTOP   EQU   *                                                        44600020
         CLI   DCBTIOT,A                LINE OPEN                       44800020
         BNL   ERR                      NO - REJECT COMMAND             45000020
*                                                                       45200020
         B     GETLIST                  PROCESS                         45400020
*                                                                       45600020
UCB      EQU   *                                                        45800020
         SR    RWORK,RWORK              CLEAR                           46000020
         IC    RWORK,DEBNMEXT           GET NUMBER OF LINES             46200020
         LA    RWORK2,DEBUCBAD          GET FIRST UCB ADDR              46400020
         LA    RCTR,OPCONE              SET COUNT TO ONE                46600020
SETUCB   EQU   *                                                        46800020
         L     RUCB,OPCZERO(,RWORK2)    GET UCB ADDR                    47000020
         STC   RCTR,OPCDOUBL            SAVE CURRENT RLN                47200020
         CLC   ADDR(OPCTHREE,RUCB),OPCTNME SPECIFIED ADDR               47400020
         BE    TESTOP                   YES - TEST FOR OPEN LINE        47600020
*                                                                       47800020
         LA    RCTR,OPCONE(,RCTR)       BUMP COUNTER                    48000020
         LA    RWORK2,OPCFOUR(,RWORK2)  GET TO NEXT UCB ADDR            48200020
         CR    RCTR,RWORK               ANY MORE LINES                  48400020
         BH    NEXTDEB                  NO - GET NEXT DEB               48600020
*                                                                       48800020
         B     SETUCB                   YES - TEST IT                   49000020
*                                                                       49200020
GETLIST  EQU   *                                                        49400020
         CLC   OPCDOUBL(OPCONE),DEBNMEXT RLN GREATER THAN EXTENT        49600020
         BH    ERR                      YES - REJECT COMMAND            49800020
*                                                                       50000020
         SR    R1,R1                    CLEAR                           50200020
         IC    R1,OPCDOUBL              GET RLN                         50400020
         TM    TYPE(RUCB),COMM          COMMUNICATIONS UCB              50600020
         BNO   ERR                      NO-TAKEE RROR EXIT              50800020
*                                                                       51000020
         TM    DATA(RUCB),POLL          CAPABLE OF AUTOPOLL             51200020
         BO    PROCESS                  YES - GO SET BITS               51400020
*                                                                       51600020
         LA    RWORK2,INCAP             GET VARIABLE ADDR               51800020
         LA    RWORK,INCAPMSG           GET MSG ADDR                    52000020
SETGOOD  EQU   *                                                        52200020
         SR    R15,R15                  SET GOOD RETURN                 52400020
         B     PUT                                                      52600020
*                                                                       52800020
PROCESS  EQU   *                                                        53000020
         SR    RWORK,RWORK              CLEAR                           53200020
         IC    RWORK,OPCDOUBL           GET RLN                         53400020
         SLL   RWORK,OPCTWO             MULTIPLY BY FOUR                53600020
         LA    RLIST,DCBINVLI-4         GET START OF LISTS              53800020
         AR    RLIST,RWORK              GET TO PROPER LIST ADDR         54000020
         L     RLIST,OPCZERO(,RLIST)    GET LIST                        54200020
         LR    R0,R1                     GET RLN                        54220020
         IC    R1,DCBEIOBX               INDEX TO IOB                   54240020
         MR    R0,R0                     INDEX TO PROPER IOB            54260020
         L     RLCB,DCBIOBAD             FIRST IOB ADDR                 54280020
         LA    RLCB,OPCZERO(RLCB)        CLEAR HIGH BYTE                54300020
         AR    RLCB,R1                   ADDR OF PROPER IOB             54320020
         LA    R1,LCBFLAG1-IEDQLCB       LCB INDEX                      54340020
         SR    RLCB,R1                   LCB ADDR                       54360020
         CLI   OPCFLG,OFF               STOP COMMAND                    54400020
         BE    STOP                     YES                             54600020
*                                                                       54800020
         TM    OPCTHREE(RLIST),AUTON    AUTOPOLL ALREADY ON             55000020
         BNO   SETON                    NO - SET IT                     55200020
*                                                                       55400020
         LA    RWORK2,MSG22             GET VARIABLE ADDR               55600020
         LA    RWORK,MSG22S             GET MSG ADDR                    55800020
         B     SETGOOD                                                  56000020
*                                                                       56200020
SETON    EQU   *                                                        56400020
         CLI   LCBRSKEY,X1A              IS THIS A BUFFERED TERMINALS   56420020
         BNE   SETON1                     NO, PROCEED                   56440020
         OI    OPCFIVE(RLIST),AUTON      TURN ON BUFFERED AUTOPOLL      56460020
         CLI   OPCFOUR(RLIST),OPCZERO    BURFERED  -  SENDING           56480020
         BNE   NOSET                     YES, DONT TURN ON AUTOPOLL     56500020
SETON1   EQU   *                                                        56520020
         OI    OPCTHREE(RLIST),AUTON    TURN ON AUTOPOLL BIT            56600020
NOSET    EQU   *                                                        56700020
         LA    RWORK2,MSG21             GET VARIALBE ADDR               56800020
         LA    RWORK,MSG21S             GET MSG ADDR                    57000020
         OI    OPCCKBIT,OPCCKPTN+OPCINVN TURN ON CKPT BITS              57200020
         B     SETGOOD                                                  57400020
*                                                                       57600020
STOP     EQU   *                                                        57800020
         TM    OPCTHREE(RLIST),AUTON    AUTOPOLL ALREADY OFF            58000020
         BO    SETOFF                   NO - SET IT                     58200020
         CLI   LCBRSKEY,X1A              BUFFERED TERM                  58230020
         BNE   STOP1                     NO, DONE                       58260020
         TM    OPCFIVE(RLIST),AUTON      BUFFERED AUTPPOLL ON           58290020
         BO    SETOFF                    YES SET IT OFF                 58320020
STOP1    EQU   *                                                        58350020
*                                                                       58400020
         LA    RWORK2,MSG28             GET VARIABLE ADDR               58600020
         LA    RWORK,MSG28S             GET MSG ADDR                    58800020
         B     SETGOOD                                                  59000020
*                                                                       59200020
SETOFF   EQU   *                                                        59400020
         CLI   LCBRSKEY,X1A              IS THIS FOR BUFFERED TERMS     59440020
         BNE   SETOFF1                   NO PROCEED                     59480020
         NI    OPCFIVE(RLIST),AUTOF      TURN OFF BUFFERED AUTOPOLL     59520020
SETOFF1  EQU   *                                                        59560020
         NI    OPCTHREE(RLIST),AUTOF    TURN OFF AUTOPOLL BIT           59600020
         CLI   LCBCPA+24,POLLCCW         IS IT AUTPPOLL                 59630020
         BNE   SETOFF2                   NO DON'T  RESET                59660020
         MVI   LCBCPA+32,NOPP            NOP THE TIC                    59690020
         MVI   LCBCPA+56,NOPP                COMMANDS                   59700020
SETOFF2  EQU   *                                                        59750020
         LA    RWORK2,MSG27             GET VARIABLE ADDR               59800020
         LA    RWORK,MSG27S             GET MSG ADDR                    60000020
         OI    OPCCKBIT,OPCCKPTN+OPCINVN TURN ON CKPT BITS              60200020
         B     SETGOOD                                                  60400020
*                                                                       60600020
PUT      EQU   *                                                        60800020
         MVC   OPCZERO(OPCEIGHT,RWORK2),OPCTNME PUT NAME IN MSG         61000020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   61200020
         BE    STORE                    NO                              61400020
*                                                                       61600020
         MVC   OPCNINE(OPCTHREE,RWORK2),OPCRLN PUT RLN IN MSG           61800020
STORE    EQU   *                                                        62000020
         ST    RWORK,OPCREG1(,R13)      PUT IN SAVE AREA                62200020
         RETURN (14,12),T,RC=(15)                                       62400020
*                                                                       62600020
NEXTDEB  EQU   *                                                        62800020
         L     RDEB,OPCFOUR(RDEB)       GET NEXT DEB ADDR               63000020
         LA    RDEB,OPCZERO(RDEB)       CLEAR HIGH BYTE                 63200020
         LTR   RDEB,RDEB                ANOTHER DEB                     63400020
         BNZ   GETDCB                   YES - PROCESS IT                63600020
*                                                                       63800020
ERR      EQU   *                                                        64000020
         LA    RWORK2,BAD               GET VARIABLE ADDR               64200020
         LA    RWORK,BADMSG             GET MSG ADDR                    64400020
         LA    R15,OPCFOUR              SET RETURN CODE                 64600020
         B     PUT                                                      64800020
*                                                                       65000020
DEB      EQU   8                                                        65200020
TIOT     EQU   12                                                       65400020
ADDR     EQU   13                                                       65600020
DATA     EQU   17                                                       65800020
TYPE     EQU   18                                                       66000020
STARTOFF EQU   24                                                       66200020
X1A      EQU   X'1A'                                                    66230020
POLLCCW  EQU   X'09'                                                    66260020
NOPP     EQU   X'03'                                                    66300020
COMM     EQU   X'40'                                                    66400020
POLL     EQU   X'40'                                                    66600020
OFF      EQU   X'40'                                                    66800020
ADCODE   EQU   X'80'                                                    67000020
AUTON    EQU   X'01'                                                    67200020
AUTOF    EQU   X'FF'-AUTON                                              67400020
TX       EQU   X'40'                                                    67600020
A        EQU   C'A'                                                     67800020
MAXVAL   DC    H'255'                                                   68000020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                  620 68200020
BADMSG   DS    0H                                                       68300020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   68400020
         DC    C'IED017I LINE '                                         68500020
BAD      DC    12C' ',C' NOT OPEN'                                      68600020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    68660020
         DC    X'0000'                   ROUTING - IN REG 0             68720020
INCAPMSG DS    0H                                                       68780020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   68840020
         DC    C'IED057I '                                              68900020
INCAP    DC    12C' ',C' NOT CAPABLE OF AUTOPOLL'                       69000020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69060020
         DC    X'0000'                   ROUTING - IN REG 0             69120020
MSG21S   DS    0H                                                       69180020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   69240020
         DC    C'IED021I AUTO POLL STARTED FOR '                        69300020
MSG21    DC    12C' '                                                   69400020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    69460020
         DC    X'0000'                   ROUTING - IN REG 0             69520020
MSG22S   DS    0H                                                       69580020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   69640020
         DC    C'IED022I AUTO POLL ALREADY STARTED'                     69700020
         DC    C' FOR '                                                 69800020
MSG22    DC    12C' '                                                   70000020
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    70060020
         DC    X'0000'                   ROUTING - IN REG 0             70120020
MSG27S   DS    0H                                                       70180020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   70240020
         DC    C'IED027I AUTO POLL STOPPED FOR '                        70300020
MSG27    DC    12C' '                                                   70400020
DESCR5   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    70460020
         DC    X'0000'                   ROUTING - IN REG 0             70520020
MSG28S   DS    0H                                                       70580020
         DC    AL2(DESCR6-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   70640020
         DC    C'IED028I AUTO POLL ALREADY STOPPED'                     70700020
         DC    C' FOR '                                                 70800020
MSG28    DC    12C' '                                                   71000020
DESCR6   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    71060020
         DC    X'0000'                   ROUTING - IN REG 0             71120020
         PRINT NOGEN                                                    71200020
         TLCBD                                                          71300020
         TOPCD                                                          71400020
         TAVTD                                                          71600020
         DCBD  DSORG=TX                                                 71800020
         TDEBD                                                          72000020
         END                                                            72200020
