         TITLE '''IEDQCX'' - MODIFY INTENSE'                            00200020
IEDQCX   CSECT                                                          00400020
*A341200                                                          M6399 00440000
*C312000                                                          M6399 00480000
*D334000                                                          M6399 00520000
*C212000,648000,664000-666000,776000                              M6406 00560000
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQCX' PROCESSOR OF MODIFY INTENSE COMMANDS                  * 01000020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01400020
*                                                                     * 01600020
*FUNCTION -- THIS MODULE PROCESSES OPERATOR CONTROL COMMANDS WHICH    * 01800020
*   REQUEST MODIFICATION OF THE SENSE INFORMATION FOR INTENSIVE       * 02000020
*   MODE RECORDING.                                                   * 02200020
*                                                                     * 02400020
*   THE MODIFY INTENSE ROUTINE TESTS THE COMMON INPUT BLOCK TO SEE    * 02600020
*   IF MODIFICATION IS FOR A TERMINAL OR A LINE.  IF FOR A TERMINAL   * 02800020
*   THE TERMINAL NAME TABLE IS SERIALLY SEARCHED FOR AN ENTRY         * 03000020
*   MATCHING THAT SPECIFIED IN THE INPUT.  IF END OF TABLE IS         * 03200020
*   REACHED BEFORE A MATCH IS FOUND, AN ERROR MESSAGE IS BUILT AND    * 03400020
*   CONTROL RETURNS TO THE CONTROL MODULE.  WHEN AN ENTRY IS FOUND,   * 03600020
*   ITS ADDRESS IS OBTAINED.                                          * 03800020
*                                                                     * 04000020
*   IF MODIFICATION IS FOR A LINE, THE INPUT IS TESTED FOR THE        * 04200020
*   DDNAME/RLN OR LINE ADDRESS FORMAT.  IF IT IS DDNAME, THE RLN IS   * 04400020
*   TESTED FOR 'ALL'.  IF ALL, AN ERROR RESPONSE IS BUILT AND         * 04600020
*   CONTROL RETURNS TO THE CONTROL MODULE.  OTHERWISE THE RLN IS      * 04800020
*   CONVERTED TO HEXADECIMAL AND THE RESULT TESTED FOR ZERO AND       * 05000020
*   GREATER THAN 255.  IF EITHER, AN ERROR RESPONSE IS BUILT AND      * 05200020
*   CONTROL RETURNS TO THE CONTROL MODULE.  THE TIOT IS ACCESSED      * 05400020
*   FROM THE TCB (TCB+12) AND SERIALLY SEARCHED FOR AN ENTRY WHICH    * 05600020
*   MATCHES THAT SPECIFIED IN THE INPUT.  IF NO ENTRY IS FOUND, AN    * 05800020
*   ERROR MESSAGE IS BUILT AND THE ROUTINE EXITS TO THE CONTROL       * 06000020
*   MODULE.  WHEN THE ENTRY IS FOUND, ITS OFFSET INTO THE TIOT IS     * 06200020
*   SAVED.                                                            * 06400020
*                                                                     * 06600020
*   FOR BOTH FORMATS OF LINE MODIFIES, THE START OF THE DEB CHAIN     * 06800020
*   IS OBTAINED FROM THE TCB (TCB+8) AND THE DCB ASSOCIATED WITH      * 07000020
*   EACH DEB (DEBDCBAD) IS TESTED FOR A TCAM LINE STATUS (DSORG OF    * 07200020
*   X'40').  IF NONE ARE FOUND BEFORE THE END OF THE DEB CHAIN, AN    * 07400020
*   ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL         * 07600020
*   MODULE.                                                           * 07800020
*                                                                     * 08000020
*   FOR DDNAME/RLN FORMAT, THE DCBTIOT FIELD IS COMPARED TO THAT      * 08200020
*   CALCULATED ABOVE.  IF THEY DO NOT MATCH, THE NEXT DEB IS          * 08400020
*   LOCATED AND DEB CHAIN PROCESSING CONTINUES.  WHEN THE PROPER      * 08600020
*   DCB IS FOUND, THE RLN IS COMPARED TO THE NUMBER OF LINES IN THE   * 08800020
*   LINE GROUP (DEBNMEXT) AND IF HIGH, AN ERROR MESSAGE IS BUILT      * 09000020
*   AND CONTROL RETURNS TO THE CONTROL MODULE.  THE LINE IS THEN      * 09200020
*   TESTED FOR OPEN DD DUMMY (DEBUCBAD OF ZERO) AND IF SO THE ERROR   * 09400020
*   RESPONSE IS BUILT AND THE ROUTINE EXITS TO THE CONTROL MODULE.    * 09600020
*                                                                     * 09800020
*   FOR ADDRESS FORMAT EACH UCB ASSOCIATED WITH A DEB IS CHECKED      * 10000020
*   FOR A MATCH ON THE SPECIFIED LINE ADDRESS.  THE DEB CHAIN IS      * 10200020
*   SEARCHED UNTIL A MATCH IS FOUND.                                  * 10400020
*                                                                     * 10600020
*   FOR BOTH LINE FORMATS, THE PROPER DCB, ONCE FOUND, IS TESTED      * 10800020
*   FOR AN OPEN CONDITION.  IF THE LINE IS NOT OPEN, AN ERROR         * 11000020
*   MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.       * 11200020
*   OTHERWISE, THE LCB ADDRESS FOR THE LINE IS DETERMINED.            * 11400020
*                                                                     * 11600020
*   NOW THAT THE CONTROL BLOCK TO BE MODIFIED HAS BEEN LOCATED, THE   * 11800020
*   SENSE FIELD OF THE INPUT BLOCK IS CONVERTED TO ITS HEXADECIMAL    * 12000020
*   EQUIVALENT THROUGH A SENSE CONVERSION TABLE AND SAVED.  THE       * 12200020
*   SENSE COUNT IS THEN OBTAINED AND CONVERTED TO HEXADECIMAL.  IF    * 12400020
*   THE COUNT IS GREATER THAN THE MAXIMUM, AN ERROR MESSAGE IS        * 12600020
*   BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.  THE CONVERTED   * 12800020
*   SENSE AND COUNT ARE CONVERTED TO A SINGLE BYTE AND STORED IN      * 13000020
*   THE SENSE FIELD OF THE PROPER CONTROL BLOCK (TRMSENSE IF A        * 13200020
*   TERMINAL, LCBERMSK IF A LINE).  THE CHECKPOINT FLAG IS SET, A     * 13400020
*   RESPONSE IS BUILT, AND CONTROL RETURNS TO THE CONTROL MODULE.     * 13600020
*                                                                     * 13800020
*ENTRY POINTS --                                                      * 14000020
*        'IEDQCX' TO PROCESS MODIFY INTENSE OPERATOR CONTROL          * 14200020
*   COMMANDS.  CALLING SEQUENCE IS                                    * 14400020
*                        LOAD EPLOC=LOADPRFX                          * 14600020
*                        LR   R1,ROPC                                 * 14800020
*                        LR   R15,R0                                  * 15000020
*                        BALR R14,R15                                 * 15200020
*                                                                     * 15400020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  AT THE       * 15600020
*   LOCATION OPCCKELE IS THE COMMON INPUT BLOCK.  FIELDS RELEVANT     * 15800020
*   TO THIS ROUTINE ARE                                               * 16000020
*                   +4   OPCLEN    X'80' IF LINE ADDRESS              * 16200020
*                                  X'00' IF RLN ALL                   * 16400020
*                                  1 - 3 LENGTH OF RLN                * 16600020
*                   +5   OPCRLN    RELATIVE LINE NUMBER               * 16800020
*                   +8   OPCTNME   TERMINAL NAME OR DDNAME OR LINE    * 17000020
*                                  ADDRESS                            * 17200020
*                   +18  OPCFLG    X'80' IF LINE MODIFY               * 17400020
*                                  X'40' IF TERMINAL MODIFY           * 17600020
*                   +20  OPCSNSE   SENSE FIELD                        * 17800020
*                   +22  OPCOTHR   SENSE COUNT                        * 18000020
*                                                                     * 18200020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 18400020
*                                                                     * 18600020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 18800020
*                                                                     * 19000020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 19200020
*                   0    MODIFY SUCCESSFUL                            * 19400020
*                   4    TERMINAL NOT FOUND, RLN INVALID, LINE NOT    * 19600020
*                        OPEN OR OPEN DD DUMMY, SENSE COUNT INVALID   * 19800020
*                                                                     * 20000020
*EXTERNAL ROUTINES -- N/A.                                            * 20200020
*                                                                     * 20400020
*EXITS-NORMAL -- SENSE INFORMATION IN THE TERMINAL OR LINE ENTRY IS   * 20600020
*   MODIFIED.  A RESPONSE MESSAGE SO INDICATING IS PREPARED AND ITS   * 20800020
*   ADDRESS IS RETURNED TO THE CALLING ROUTINE.                       * 21000020
*                                                                     * 21200020
*EXITS-ERROR -- TERMINAL NOT FOUND OR RLN INVALID, LINE NOT OPEN OR   * 21400020
*   OPEN DD DUMMY, OR SENSE COUNT INVALID.  APPROPRIATE ERROR         * 21600020
*   RESPONSE BUILT, X'04' RETURN CODE SET.                            * 21800020
*                                                                     * 22000020
*TABLES/WORK AREAS -- MESSAGES, SENSE FIELD CONVERSION TABLE, LCB,    * 22200020
*   OPERATOR CONTROL AVT, AVT, TERMNAME TABLE, TERMINAL ENTRY, DEB,   * 22400020
*   DCB.                                                              * 22600020
*                                                                     * 22800020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 23000020
*   PROBLEM PROGRAM MODE.                                             * 23200020
*                                                                     * 23400020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 23600020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 23800020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 24000020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 24200020
*   BE REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 24400020
*   DEFINITIONS.                                                      * 24600020
*                                                                     * 24800020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 25000020
*              IED016I, IED017I, IED018I, IED058I                     * 25200020
*                                                                     * 25400020
*********************************************************************** 25600020
*                                                                       25800020
*                                                                       26000020
R0       EQU   0                        WORK                            26200020
R1       EQU   1                        PARAMETER                       26400020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       26600020
RAVT     EQU   4                        AVT BASE                        26800020
RTNT     EQU   5                        TERMNAME TABLE BASE             27000020
RTCB     EQU   5                        TCB BASE                        27200020
RDEB     EQU   5                        DEB BASE                        27400020
RTERM    EQU   6                        TERMINAL ENTRY BASE             27600020
RLCB     EQU   6                        LCB BASE                        27800020
RUNIT    EQU   6                        MODIFY UNIT ADDRESS             28000020
RWORK1   EQU   7                        WORK                            28200020
RWORK2   EQU   8                        WORK                            28400020
RWORK3   EQU   15                                                       28600020
RDCB     EQU   9                        DCB BASE                        28800020
RDD      EQU   10                       DDNAME                          29000020
RUCB     EQU   10                       UCB BASE                        29200020
ROFF     EQU   11                       DD OFFSET                       29400020
RCTR     EQU   11                       COUNTER                         29600020
RBASE    EQU   12                       ROUTINE BASE                    29800020
R13      EQU   13                       SAVE AREA                       30000020
R14      EQU   14                       RETURN                          30200020
R15      EQU   15                       ENTRY                           30400020
         USING IEDQCX,RBASE             ADDRESSABILITY FOR ROUTINE      30600020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       30800020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          31000020
         SAVE  (14,12),,IEDQCX-05/17/71                           M6406 31200000
         LR    ROPC,R1                  GET OP CTL AVT                  31400020
         LR    RBASE,R15                GIVE ROUTINE A BASE             31600020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 31800020
         CLI   OPCFLG,LINE              TERM IR LINE INPUT              32000020
         BE    LINEPROC                 LINE - GO PROCESS               32200020
*                                                                       32400020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FOR TNT          32600020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERMINAL     32800020
         L     RTNT,AVTRNMPT            GET TERMNAME TABLE              33000020
         LA    RWORK2,OPCONE            SET UP COUNTER                  33200020
         SR    RTERM,RTERM              CLEAR                           33600020
         IC    RTERM,TNTENLEN           GET ENTRY LENGTH                33800020
         BCTR  RTERM,R0                                                 34000020
         CH    RTERM,AVTHA7           EIGHT BYTE TERMNAME               34020020
         BE    HTRMOK                   YES, VALID LENGTH               34040020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              34060020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   34080020
         BNE   TERMERR                  NO, ERROR                       34100020
HTRMOK   EQU   *                                                        34120020
         LH    RWORK3,TNTLEN           GET NUMBER OF ENTRIES      M6399 34160000
         LA    RTNT,TNTFIRST            GET TO START OF ENTREIS         34200020
TLOOP    EQU   *                                                        34400020
         CR    RWORK2,RWORK3            END OF TABLE                    34600020
         BH    TERMERR                  YES - ERROR                     34800020
*                                                                       35000020
         EX    RTERM,COMP               RIGHT ENTRY                     35200020
         BE    TERMPROC                 YES - PROCESS IT                35400020
*                                                                       35600020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TO NEXT ENTRY              35800020
         LA    RWORK2,OPCONE(,RWORK2)   ADD ONE TO COUNTER              36000020
         B     TLOOP                    GO PROCESS NEXT ENTRY           36200020
*                                                                       36400020
TERMERR  EQU   *                                                        36600020
         MVC   TBADM(OPCEIGHT),OPCTNME  PUT NAME IN MSG                 36800020
         LA    RWORK1,TBAD              PICK UP MSG ADDR                37000020
SETBAD   EQU   *                                                        37200020
         LA    R15,OPCFOUR              SET ERROR RETURN                37400020
EXIT     EQU   *                                                        37600020
         ST    RWORK1,OPCREG1(,R13)      STORE MSG ADDR IN SAVE         37800020
         RETURN (14,12),T,RC=(15)                                       38000020
*                                                                       38200020
TERMPROC EQU   *                                                        38400020
         AR    RTNT,RTERM               BUMP PAST TERMNAME              38600020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTNT) PUT ON BDRY             38800020
         L     RTERM,OPCWORK            GET TERMINAL ENTRY              39000020
         TM    TRMSTATE,PROC            PROCESS ENTRY                   39060020
         BZ    PROCESS                  NO, GO ON                       39120020
         MVC   PEMSG(OPCEIGHT),OPCTNME    SET TERMINAL IN MESSAGE       39180020
         LA    RWORK1,PEM               ADDRESS OF ERROR MESSAGE        39240020
         B     SETBAD                   SET UP BAD RETURN CODE          39300020
*                                                                       39400020
         SPACE 2                                                        39600020
COMINV   EQU   *                                                        39800020
         LA    RWORK1,OPCERMSG           ERROR GET ERROR MSG            40000020
         B     SETBAD                                                   40200020
         SPACE 2                                                        40400020
LINEPROC EQU   *                                                        40600020
         USING IEDQLCB,RLCB             ADDRESSABILITY FOR LCB          40800020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          41000020
         USING DEBNMSUB,RDEB            ADDRESSABILITY FOR DEB          41200020
         L     RTCB,AVTTCB                                              41400020
         CLI   OPCLEN,ADCODE            DD OR ADDR                      41600020
         BE    GETLCB                   ADDR - SKIP RLN CLDE            41800020
*                                                                       42000020
         CLI   OPCLEN,AVTEZERO          RLN 'ALL'                       42200020
         BE    COMINV                   YES - ERROR EXIT                42400020
*                                                                       42600020
         MVC   OPCDOUBL(OPCTHREE),OPCRLN PUT RLN IN WORK AREA           42800020
         SR    R15,R15                  CLEAR                           43000020
         IC    R15,OPCLEN               GET LENGTH OF RLN               43200020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE           43400020
         EX    R15,PACK                 PACK                            43600020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CONVERT              43800020
         CVB   RWORK1,OPCDOUBL          CONVERT TO HEX                  44000020
         LTR   RWORK1,RWORK1            RLN ZERO                        44200020
         BZ    COMINV                   YES - REJECT COMMAND            44400020
*                                                                       44600020
         CH    RWORK1,MAXVAL            RLN > 255                       44800020
         BH    COMINV                   YES - REJECT COMMAND            45000020
*                                                                       45200020
         STC   RWORK1,OPCDOUBL          SAVE HEX RLN                    45400020
         L     RDD,TIOT(RTCB)           GET TIOT ADDR                   45600020
         LA    ROFF,STARTOFF            GET OFFSET TO FIRST DD          45800020
         SR    RWORK2,RWORK2            CLEAR                           46000020
         LA    RDD,STARTOFF(RDD)        GET ADDR FIRST DD               46200020
DDLOOP   EQU   *                                                        46400020
         IC    RWORK2,OPCZERO(,RDD)     GET LENGTH BYTE                 46600020
         CLI   OPCZERO(RDD),OPCZERO     ANOTEHR DD                      46800020
         BE    LNERR                    NO - REJECT COMMAND             47000020
*                                                                       47200020
         CLC   OPCFOUR(OPCEIGHT,RDD),OPCTNME SPECIFIED DD               47400020
         BE    GETLCB                   YES - PROCESS IT                47600020
*                                                                       47800020
         AR    ROFF,RWORK2              ADD TO OFFSET COUNT             48000020
         AR    RDD,RWORK2               GET TO NEXT DD                  48200020
         B     DDLOOP                                                   48400020
*                                                                       48600020
GETLCB   EQU   *                                                        48800020
         L     RDEB,DEB(,RTCB)          GET FIRST DEB ADDR              49000020
GETDCB   EQU   *                                                        49200020
         L     RDCB,DEBDCBAD            GET DCB ADDR                    49400020
         TM    DCBDSORG+1,TX            TCAM LINE                       49600020
         BNO   NEXTDEB                  NO - GET NEXT DEB               49800020
*                                                                       50000020
         CLI   OPCLEN,ADCODE            DD OR ADDR                      50200020
         BE    UCB                      ADDR - PROCESS UCBS             50400020
*                                                                       50600020
         LH    RWORK2,DCBTIOT           GET OFFSET INTO TIOT            50800020
         CR    RWORK2,ROFF              SAME AS FOR DD                  51000020
         BNE   NEXTDEB                  NO - GET NEXT DEB               51200020
*                                                                       51400020
         SR    R0,R0                    CLEAR                           51600020
         IC    R0,OPCDOUBL              GET RLN                         51800020
         CLC   OPCDOUBL(OPCONE),DEBNMEXT RLN > # EXTENS                 52000020
         BH    LNERR                    YES - REJECT COMMAND            52200020
*                                                                       52400020
         LR    RWORK1,R0                SAVE FOR TEST                   52600020
         SLL   RWORK1,OPCTWO            MULTIPLY BY FOUR                52800020
         L     RWORK1,DEBUCBAD-4-DEBNMSUB(RWORK1,RDEB) GET UCB ADDR     53000020
         LA    RWORK1,OPCZERO(RWORK1)   CLEAR HIGH BYTE                 53200020
         LTR   RWORK1,RWORK1            OPENED DD DUMMY                 53400020
         BZ    LNERR                    YES - REJECT COMMAND            53600020
*                                                                   622 53800020
COUNTOK  EQU   *                                                        54000020
         CLI   DCBTIOT,A                LINE OPEN                       54200020
         BNL   LNERR                    NO - REJECT COMMNND             54400020
*                                                                       54600020
         L     RLCB,DCBIOBAD            GET IOB ADDR                    54800020
         LA    RLCB,OPCZERO(RLCB)       CLEAR HIGH BYTE                 55000020
         SR    R1,R1                    CLEAR                           55200020
         IC    R1,DCBEIOBX              GET SIZE OF IOB                 55400020
         MR    R0,R0                    MULTIPLY BY RLN                 55600020
         AR    RLCB,R1                  GET TO RIGHT IOB                55800020
         LA    RWORK3,LCBFLAG1-IEDQLCB                                  56000020
         SR    RLCB,RWORK3              BACK UP TO LCB                  56200020
         B     PROCESS                                                  56400020
*                                                                       56600020
UCB      EQU   *                                                        56800020
         SR    RWORK1,RWORK1            CLEAR                           57000020
         IC    RWORK1,DEBNMEXT          GET NUMBER OF EXTENTS           57200020
         LA    RWORK3,DEBUCBAD          GET UCB ADDR                    57400020
         LA    RCTR,OPCONE              SET COUNTER                     57600020
UCBLOOP  EQU   *                                                        57800020
         L     RUCB,OPCZERO(,RWORK3)                                    58000020
         CLC   ADDR(OPCTHREE,RUCB),OPCTNME SPECIFIED ADDR               58200020
         BE    FOUND                    YES - PROCESS IT                58400020
*                                                                       58600020
         LA    RCTR,OPCONE(,RCTR)       INCREMENT RLN COUNTER           58800020
         LA    RWORK3,OPCFOUR(,RWORK3)  NEXT UCB ADDR                   59000020
         CR    RCTR,RWORK1              AIOTHER UCB                     59200020
         BH    NEXTDEB                  NO - GET NEXT DEB               59400020
*                                                                       59600020
         B     UCBLOOP                                                  59800020
*                                                                       60000020
FOUND    EQU   *                                                        60200020
         LR    R0,RCTR                  RESET RLN                       60400020
         B     COUNTOK                                                  60600020
*                                                                       60800020
NEXTDEB  EQU   *                                                        61000020
         L     RDEB,OPCFOUR(,RDEB)      GET NEXT DEB ADDR               61200020
         LA    RDEB,OPCZERO(RDEB)       CLEAR HIGH BYTE                 61400020
         LTR   RDEB,RDEB                ANOTHER DEB                     61600020
         BNZ   GETDCB                   YES - PROCESS IT                61800020
*                                                                       62000020
LNERR    EQU   *                                                        62200020
         MVC   LBADM(OPCEIGHT),OPCTNME  PUT NAME IN MSG                 62400020
         CLI   OPCLEN,ADCODE            RLN SPEVIDIED                   62600020
         BE    LNERR1                   NO                              62800020
*                                                                       63000020
         MVC   LBADM+9(OPCTHREE),OPCRLN PUT RLN IN MSG                  63200020
LNERR1   EQU   *                                                        63400020
         LA    RWORK1,LBAD              GET MSG ADDR                    63600020
         B     SETBAD                                                   63800020
*                                                                       64000020
PROCESS  EQU   *                                                        64200020
         LA    RWORK1,TWOBIT            GET ADDR OF COMPARE TBL         64400020
         LA    RWORK2,OPCTHREE          SET BUMP LENGTH                 64600020
         LA    RWORK3,ELEVEN            GET NUMBER OF ENTRIES     M6406 64800000
SLOOP    EQU   *                                                        65000020
         CLC   OPCZERO(OPCTWO,RWORK1),OPCSNSE RIGHT SENSE VALUE         65200020
         BE    SETSENSE                 PUT SENSE IN UNIT               65400020
*                                                                       65600020
         AR    RWORK1,RWORK2            BUMP TO NEXT ENTRY              65800020
         BCT   RWORK3,SLOOP             TEST NEXT ENTRY                 66000020
*                                                                       66200020
         B     COMINV                   NOT VALID SENSE           M6406 66500000
*                                                                       66800020
SETSENSE EQU   *                                                        67000020
         BCTR  RWORK2,R0                DECREMENT BACK TO SENSE         67200020
         AR    RWORK1,RWORK2            GET SENSE BYTE                  67400020
         SR    RWORK3,RWORK3            CLEAR                           67600020
         IC    RWORK3,OPCZERO(,RWORK1)  PICK UP BYTE                    67800020
SETCT    EQU   *                                                        68000020
         MVC   MSG2+11(OPCTWO),OPCSNSE  PUT SENSE IN MSG                68200020
         SR    RWORK2,RWORK2            CLEAR                           68400020
         MVC   MSG2(OPCTWO),OPCOTHR     PUT COUNT IN MSG                68600020
         CLI   OPCOTHR,C'0'             LESS THAN ZERO                  68620020
         BL    COMINV                   YES, NOT NUMERIC - ERROR        68640020
         CLI   OPCOTHR,C'9'             GREATER THAN NINE               68660020
         BH    COMINV                   YES, NOT NUMERIC - ERROR        68680020
         CLI   OPCOTHR+1,C'0'           LESS THAN ZERO                  68700020
         BL    COMINV                   YES, NOT NUMERIC - ERROR        68720020
         CLI   OPCOTHR+1,C'9'           GREATER THAN NINE               68740020
         BH    COMINV                   YES, NOT NUMERIC - ERROR        68760020
         PACK  OPCDOUBL+6(OPCTWO),OPCOTHR(OPCTWO) PACK                  68800020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CONVERT              69000020
         CVB   RWORK1,OPCDOUBL          CONVERT TO HEX                  69200020
         CH    RWORK1,CTMAX             GREATER THAN 15                 69400020
         BH    COMINV                   YES - REJECT COMMAND            69600020
*                                                                       69800020
         AR    RWORK3,RWORK1                                            70000020
         CLI   OPCFLG,LINE              TERM OR LINE                    70200020
         BE    LINEEQU                  LINE - USE LINE EQU             70400020
*                                                                       70600020
         STC   RWORK3,TRMSENSE-IEDQTRM(RUNIT) PUT SENSE IN ENTRY        70800020
         B     MSG                                                      71000020
*                                                                       71200020
LINEEQU  EQU   *                                                        71400020
         STC   RWORK3,LCBERMSK-IEDQLCB(RUNIT) PUT SENSE IN LCB          71600020
MSG      EQU   *                                                        71800020
         MVC   MSG1(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 72000020
         CLI   OPCLEN,ADCODE            RLN SPECIFIED                   72200020
         BE    MSG1A                    NO                              72400020
*                                                                       72600020
         MVC   MSG1+9(OPCTHREE),OPCRLN  PUT RLN IN MSG                  72800020
MSG1A    EQU   *                                                        73000020
         LA    RWORK1,GOODMSG           GET MSG ADDR                    73200020
         SR    R15,R15                  SET GOOD RETURN                 73400020
         OI    OPCCKBIT,OPCCKPTN        TURN ON CKPT BIT                73600020
         B     EXIT                                                     73800020
*                                                                       74000020
DEB      EQU   8                                                        74200020
ELEVEN   EQU   11                                                       74400020
TIOT     EQU   12                                                       74600020
ADDR     EQU   13                                                       74800020
STARTOFF EQU   24                                                       75000020
PROC     EQU   X'20'                                                    75100020
TX       EQU   X'40'                                                    75200020
ONEBIT   EQU   X'A0'                                                    75400020
BITSOFF  EQU   X'E0'                                                    75600020
ADCODE   EQU   X'80'                                                    75800020
LINE     EQU   X'80'                                                    76000020
A        EQU   C'A'                                                     76200020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                  622 76400020
MAXVAL   DC    H'255'                                                   76600020
CTMAX    DC    H'15'                                                    76800020
COMP     CLC   OPCZERO(OPCONE,RTNT),OPCTNME                             77000020
TWOBIT   DC    C'TO',X'10',C'LD',X'20',C'OR',X'30',C'DC',X'40'          77200020
         DC    C'EC',X'50',C'BO',X'60',C'IR',X'70',C'CR',X'80'          77400020
         DC    C'UE',X'90',C'IM',X'F0',C'M2',X'A0'                M6406 77500000
TBAD     DS    0H                                                       77670020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   77740020
         DC    C'IED016I STATION '                                      77810020
TBADM    DC    8C' ',C' NOT FOUND'                                      77880020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    77950020
         DC    X'0000'                   ROUTING - IN REG 0             78020020
LBAD     DS    0H                                                       78090020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   78160020
         DC    C'IED017I '                                              78230020
LBADM    DC    12C' ',C' NOT OPEN'                                      78300020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    78370020
         DC    X'0000'                   ROUTING - IN REG 0             78440020
GOODMSG  DS    0H                                                       78510020
         DC    AL2(DESCR6-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   78580020
         DC    C'IED058I '                                              78650020
MSG1     DC    12C' ',C' SENSE COUNT='                                  78800020
MSG2     DC    C'  ',C' SETTING=  '                                     78900020
DESCR6   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    79000020
         DC    X'0000'                   ROUTING - IN REG 0             79100020
PEM      DS    0H                                                       79110020
         DC    AL2(DESCR0-*),X'6000'    LENGTH SCSFLGS-INREG0-IMMRSP    79120020
         DC    C'IED090I '                                              79130020
PEMSG    DC    8C' ',C' IS NOT SINGLE ENTRY'                            79140020
DESCR0   DC    X'0800'                  DESCRIPTOR IMMEDIATE RESP       79150020
         DC    X'0000'                  ROUTING - IN REG 0              79160020
         PRINT NOGEN                                                    79200020
         TLCBD                                                          79400020
         TOPCD                                                          79600020
         TAVTD                                                          79800020
         TTNTD                                                          80000020
         TTRMD                                                          80200020
         TDEBD                                                          80400020
         DCBD  DSORG=TX                                                 80600020
         END                                                            80800020
