         TITLE '''IEDQCZ'' - MODIFY INTERVAL'                           00200020
IEDQCZ   CSECT                                                          00400020
*********************************************************************** 00600020
*                                                                     * 00800020
*TITLE 'IEDQCZ' PROCESSOR OF MODIFY INTERVAL COMMANDS                 * 01000020
*                                                                     * 01200020
*STATUS -- CHANGE LEVEL 0                                             * 01400020
*                                                                     * 01600020
*FUNCTION -- THE PURPOSE OF THIS ROUTINE IS TO PROCESS OPERATOR       * 01800020
*   CONTROL COMMANDS WHICH REQUEST ACTIVATION OF THE SYSTEM           * 02000020
*   INTERVAL OR MODIFICATION OF THE VALUE OF THE SYSTEM OR POLLING    * 02200020
*   INTERVAL.                                                         * 02400020
*                                                                     * 02600020
*   THE CHANGE INTERVAL TYPE ROUTINE CHECKS THE COMMON INPUT BLOCK    * 02800020
*   TO DETERMINE WHETHER POLL OR SYSTEM INTERVAL IS BEING ALTERED.    * 03000020
*   IF POLL BUT NO VALUE IS SPECIFIED AN ERROR MESSAGE IS BUILT AND   * 03200020
*   CONTROL RETURNS TO THE CONTROL MODULE.  IF THE COMMAND IS TO      * 03400020
*   CHANGE THE SYSTEM INTERVAL VALUE, THE INTERVAL SPECIFIED BY THEE  * 03600020
*   COMMAND IS PLACED IN A RESPONSE MESSAGE AND IS TESTED FOR VALID   * 03800020
*   NUMERIC CHARACTERS.  IF ALL CHARACTERS ARE NOT VALID NUMBERS,     * 04000020
*   AN ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL      * 04200020
*   MODULE.                                                           * 04400020
*                                                                     * 04600020
*   THE INTERVAL VALUE IS CONVERTED TO HEXADECIMAL AND TESTED FOR     * 04800020
*   ZERO OR GREATER THAN THE MAXIMUM OF 65,535.  IF EITHER, AN        * 05000020
*   ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL         * 05200020
*   MODULE.  IF THE FIELD AVTHI IS ZERO, IMPLYING THAT THE SYSTEM     * 05400020
*   INTERVAL FUNCTION IS NOT SUPPORTED, AN ERROR RESPONSE IS BUILT    * 05600020
*   AND THE ROUTINE EXITS TO THE CONTROL MODULE.  OTHERWISE THE NEW   * 05800020
*   INTERVAL VALUE IS STORED IN THE AVT AT AVTINTLV, THE CHECKPOINT   * 06000020
*   BIT IS SET, A RESPONSE IS BUILT, AND CONTROL RETURNS TO THE       * 06200020
*   CONTROL MODULE.                                                   * 06400020
*                                                                     * 06600020
*   IF THE POLL INTERVAL IS TO BE MODIFIED, THE TERMNAME TABLE IS     * 06800020
*   SERIALLY SEARCHED FOR AN ENTRY MATCHING THAT SPECIFIED IN THE     * 07000020
*   COMMON INPUT BLOCK.  IF NO MATCH IS FOUND AN ERROR RESPONSE IS    * 07200020
*   BUILT AND THE ROUTINE EXITS TO THE CONTROL MODULE.  WHEN THE      * 07400020
*   ENTRY IS FOUND, THE SPECIFIED INTERVAL IS PLACED IN THE           * 07600020
*   RESPONSE AND THEN TESTED TO INSURE THAT EACH CHARACTER IS A       * 07800020
*   VALID NUMERIC.  IF A NON-NUMERIC CHARACTER IS FOUND, AN ERROR     * 08000020
*   MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.       * 08200020
*                                                                     * 08400020
*   THE INTERVAL IS CONVERTED TO HEXADECIMAL AND TESTED FOR ZERO      * 08600020
*   AND GREATER THAN 255.  IN EITHER CASE AN ERROR MESSAGE IS BUILT   * 08800020
*   AND CONTROL RETURNS TO THE CONTROL MODULE.  THE QCB ASSOCIATED    * 09000020
*   WITH THE TERMINAL ENTRY (TRMDESTQ) IS USED TO ACCESS THE DCB      * 09200020
*   (QCBDCBAD) WHICH IS TESTED FOR OPEN STATUS.  IF THE LINE IS NOT   * 09400020
*   OPEN AN ERROR RESPONSE IS BUILT AND THE ROUTINE EXITS TO THE      * 09600020
*   CONTROL MODULE.  THE DCB IS USED TO LOCATE AN LCB ON THE LINE     * 09800020
*   (DCBIOBAD+(DCBEIOBX*QCBRELLN)-X'20') WHICH IS TESTED FOR DIAL     * 10000020
*   (LCBDIAL ON IN LCBSTAT2).  IF DIAL, AN ERROR MESSAGE IS BUILT     * 10200020
*   AND CONTROL RETURNS TO THE CONTROL MODULE.  OTHERWISE THE NEW     * 10400020
*   INTERVAL IS PLACED IN THE DCB (DCBINTVL), THE CHECKPOINT FLAG     * 10600020
*   IS SET, A RESPONSE IS BUILT AND THE ROUTINE EXITS TO THE          * 10800020
*   CONTROL MODULE.                                                   * 11000020
*                                                                     * 11200020
*   IF THE SYSTEM INTERVAL IS TO BE ACTIVATED, AVTHI IS TESTED FOR    * 11400020
*   ZERO.  IF ZERO, THE SYSTEM INTERVAL FUNCTION IS NOT SUPPORTED,    * 11600020
*   SO AN ERROR MESSAGE IS BUILT AND CONTROL RETURNS TO THE CONTROL   * 11800020
*   MODULE.  IF THE INTERVAL VALUE AT AVTINTLV IS ZERO AN ERROR       * 12000020
*   RESPONSE IS BUILT AND CONTROL RETURNS TO THE CONTROL MODULE.      * 12200020
*   OTHERWISE A CROSS-PARTITION POST PARAMETER LIST IS BUILT TO       * 12400020
*   ACTIVATE IEDQHI, THE INTERVAL CONTROL MODULE, AND THE AQCTL       * 12600020
*   MACRO (SVC 102) ISSUED TO POST THE INTERVAL PROCESSOR.  A         * 12800020
*   RESPONSE IS BUILT, THE CHECKPOINT FLAG IS SET, AND THE ROUTINE    * 13000020
*   EXITS TO THE CONTROL MODULE.                                      * 13200020
*                                                                     * 13400020
*ENTRY POINT --                                                       * 13600020
*        'IEDQCZ' TO PROCESS MODIFY INTERVAL COMMANDS.  CALLING       * 13800020
*   SEQUENCE IS                                                       * 14000020
*                        LOAD EPLOC=LOADPRFX                          * 14200020
*                        LR   R1,ROPC                                 * 14400020
*                        LR   R15,R0                                  * 14600020
*                        BALR R14,R15                                 * 14800020
*                                                                     * 15000020
*INPUT -- REGISTER 1 - ADDRESS OF OPERATOR CONTROL AVT.  AT THE       * 15200020
*   LOCATION OPCCKELE IS THE COMMON INPUT BLOCK.  RELEVANT FIELDS     * 15400020
*   FOR THIS ROUTINE ARE                                              * 15600020
*                   +8   OPCTNME   TERMINAL NAME FOR POLL INTERVAL    * 15800020
*                   +18  OPCFLG    X'80' - SYSTEM                     * 16000020
*                                  X'40' - POLL                       * 16200020
*                                  X'20' - VALUE TO BE CHANGED        * 16400020
*                                                                     * 16600020
*   REGISTER 15 - ENTRY POINT ADDRESS.                                * 16800020
*                                                                     * 17000020
*OUTPUT -- REGISTER 1 - ADDRESS OF APPROPRIATE RESPONSE MESSAGE.      * 17200020
*                                                                     * 17400020
*   REGISTER 15 - RETURN CODE.  VALUES ARE                            * 17600020
*                   0    MODIFICATION SUCCESSFUL.                     * 17800020
*                   4    STATION NOT FOUND, INTERVAL INVALID, LINE    * 18000020
*                        NOT OPEN OR DIAL LINE, SYSTEM INTERVAL       * 18200020
*                        SUPPORT NOT IN SYSTEM.                       * 18400020
*                                                                     * 18600020
*EXTERNAL ROUTINES --                                                 * 18800020
*        'AQCTL' MACRO - SVC 102 TO ACTIVATE SYSTEM INTERVAL.         * 19000020
*                                                                     * 19200020
*EXITS-NORMAL -- SYSTEM INTERVAL ACTIVATED, SYSTEM OR POLL INTERVAL   * 19400020
*   MODIFIED.  RESPONSE BUILT, X'00' RETURN CODE SET.                 * 19600020
*                                                                     * 19800020
*EXITS-ERROR -- INTERVAL INVALID, STATION NOT FOUND, LINE NOT OPEN    * 20000020
*   OR DIAL LINE, SYSTEM INTERVAL NOT SUPPORTED.  APPROPRIATE ERROR   * 20200020
*   MESSAGE BUILT, X'04' RETURN CODE SET.                             * 20400020
*                                                                     * 20600020
*TABLES/WORK AREAS -- MESSAGES, MAXIMUM INTERVALS, AVT, OPERATOR      * 20800020
*   CONTROL AVT, LCB, QCB, DCB, BUFFER, TERMNAME TABLE, TERMINAL      * 21000020
*   ENTRY.                                                            * 21200020
*                                                                     * 21400020
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, TRANSIENT,    * 21600020
*   PROBLEM PROGRAM MODE.                                             * 21800020
*                                                                     * 22000020
*NOTES -- THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL       * 22200020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 22400020
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS      * 22600020
*   BEEN ARRANGED SO THAT REDEFINITION OF ''CHARACTER'' CONSTANTS,    * 22800020
*   BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW        * 23000020
*   DEFINITIONS.                                                      * 23200020
*                                                                     * 23400020
*   MESSAGES ISSUED BY THIS MODULE ARE                                * 23600020
*              IED011I, IED016I, IED018I, IED045I, IED047I, IED048I   * 23800020
*              IED085I, IED093I                                       * 24000020
*                                                                     * 24200020
*********************************************************************** 24400020
*                                                                       24600020
*                                                                       24800020
R0       EQU   0                        WORK                            25000020
R1       EQU   1                        PARAMETER                       25200020
ROPC     EQU   2                        OPERATOR CONTROL AVT BASE       25400020
RCIB     EQU   3                        INPUT BASE                      25600020
RAVT     EQU   4                        AVTB ASE                        25800020
RWORK    EQU   5                        WORK                            26000020
RWORK2   EQU   6                        WORK                            26200020
RTNT     EQU   7                        TERMNAME TABLE BASE             26400020
RTERM    EQU   8                        TERMINAL ENTRY BASE             26600020
RQCB     EQU   9                        QCB BASE                        26800020
RDCB     EQU   10                       DCB BASE                        27000020
RLCB     EQU   11                       LCB BASE                        27200020
RBASE    EQU   12                       ROUTINE BASE                    27400020
R13      EQU   13                       SAVE AREA                       27600020
R14      EQU   14                       RETURN                          27800020
R15      EQU   15                       ENTRY POINT                     28000020
         USING CVT,RWORK                                                28100020
         USING IEDQCZ,RBASE             ADDRESSABILITY FOR ROUTINE      28200020
         USING IEDQOPC,ROPC             ADDRESSABILITY FOR OP CTL       28400020
         USING IEDQAVTD,RAVT            ADDRESSABILITY FOR AVT          28600020
         USING IEDQTNTD,RTNT            ADDRESSABILITY FR TNT           28800020
         USING IEDQTRM,RTERM            ADDRESSABILITY FOR TERM         29000020
         USING IEDQQCB,RQCB             ADDRESSABILITY FOR TNT          29200020
         USING IHADCB,RDCB              ADDRESSABILITY FOR DCB          29400020
         USING IEDQLCB,RLCB             ADDRESSABILITY FOR LCB          29600020
         SAVE  (14,12),,IEDQCZ-03/08/71                                 29800020
         LR    RBASE,R15                SET UP ROUTINE BASE             30000020
         LR    ROPC,R1                  GET OP CTL AVT ADDRESS          30200020
         L     RAVT,OPCAVTAD            GET AVT ADDRESS                 30400020
         L     RCIB,OPCINPUT                                            30600020
         SR    R15,R15                   CLEAR FRR LENGTH               30800020
         IC    R15,OPCOTHR               GET LENGTH                     31000020
         STC   R15,OPCBITSW+1            SAVE FOR LATER                 31200020
         CLI   OPCFLG,POLL              POLL - NO DATA                  31400020
         BE    COMINV                   YES - REJECT COMMAND            31600020
*                                                                       31800020
         TM    OPCFLG,POLL              POLL WITH DATA                  32000020
         BO    SETPOLL                  YES - PROCESS                   32200020
*                                                                       32400020
         OI    OPCBITSW,OPCTEMPN        TURN ON SYSTEM BIT              32600020
         CLI   OPCFLG,SYSONLY           SYSTEM DELAY                    32800020
         BE    BITSW                    YES - INITIATE IT               33000020
         MVC   OPCDOUBL(OPCFIVE),OPCOPFLD   MOVE VOR COMVERT            33200020
*                                                                       33400020
         MVC   SYSMSG+28(OPCFIVE),OPCDOUBL PUT INVL IN MSG              33600020
         CLI   OPCBITSW+1,OPCFIVE       TOO MANY CHARACTERS             33800020
         BH    COMINV                   YES - REJECT COMMAND            34000020
*                                                                       34200020
         LA    R14,OPCDOUBL-1(R15)      INITIALIZE FOR LOOP             34400020
CLILOOP  EQU   *                                                    624 34600020
         CLI   OPCZERO(R14),FOXOH                                   624 34800020
         BL    COMINV                   ALPHA CHARACTER                 35000020
*                                                                   624 35200020
         BCTR  R14,R0                   DECREMENT                       35400020
         BCT   R15,CLILOOP              RETURN TO LOOP                  35600020
*                                                                   624 35800020
         IC    R15,OPCBITSW+1           GET LENGTH OF FIELD             36000020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE           36200020
         EX    R15,PACKS                PACK                            36400020
         XC    OPCDOUBL(OPCFIVE),OPCDOUBL CLEAR FOR CONVERT             36600020
         CVB   RWORK,OPCDOUBL           CONVERT                         36800020
         C     RWORK,SYSMAX             GREATER THAN MAX                37000020
         BH    COMINV                   YES - REJECT COMMAND            37200020
         LTR   RWORK,RWORK               INTERVAL ZERO                  37400020
         BZ    COMINV                    YES, REJECT THE COMMAND        37600020
*                                                                       37800020
         L     RWORK2,AVTHI             INTERVAL CODE ADDR              38000020
         LA    RWORK2,OPCZERO(RWORK2)   CLEAR HIGH BYTE                 38200020
         LTR   RWORK2,RWORK2            INTERVAL SPECIFIED              38400020
         BZ    REJECT                   NO - REJECT COMMAND             38600020
*                                                                       38800020
         STH   RWORK,AVTINTLV           RESET INTERVAL                  39000020
         LA    RWORK,SYSMSG             GET MSG ADDR                    39200020
SETGOOD  EQU   *                                                        39400020
         OI    OPCCKBIT,OPCCKPTN        TURN ON CKPT BIT                39800020
SETGOOD1 EQU   *                                                        39860020
         SR    R15,R15                   SET GOOD RETURN CODE           39920020
EXIT     EQU   *                                                        40000020
         ST    RWORK,OPCREG1(,R13)                                      40200020
         NI    OPCBITSW,BITSOFF         CLEAR WORK BITS                 40400020
         RETURN (14,12),T,RC=(15)                                       40600020
*                                                                       40800020
REJECT   EQU   *                                                        41000020
         LA    RWORK,NOSYS              GET MSG ADDR                    41200020
SETBAD   EQU   *                                                        41400020
         LA    R15,OPCFOUR              SET BAD RETURN                  41600020
         B     EXIT                                                     41800020
*                                                                       42000020
SETPOLL  EQU   *                                                        42200020
         L     RTNT,AVTRNMPT            GET TERM TABLE                  42400020
         LA    RWORK,OPCONE             SET COUNTER TO ONE              42600020
         LH    RWORK2,TNTLEN            GET NUMBER OF ENTRIES           42800020
         SR    RTERM,RTERM              CLEAR                           43000020
         IC    RTERM,TNTENLEN           GET ENTRY LENGTH                43200020
         BCTR  RTERM,R0                 DECREMENT                       43400020
         CH    RTERM,AVTHA7           EIGHT BYTE TERMNAME               43420020
         BE    HTRMOK                   YES, VALID LENGTH               43440020
         LA    R15,OPCTNME+1(RTERM)     PTR TO FIRST BLANK              43460020
        CLI   OPCZERO(R15),AVTEBLNK     IS IT A BLANK                   43480020
         BNE   ERR                      NO, ERROR                       43500020
         SR    R15,R15                  CLEAR TO RESET                  43520020
         IC    R15,OPCOTHR              PUT LENGTH BACK                 43540020
HTRMOK   EQU   *                                                        43560020
         LA    RTNT,TNTFIRST            BUMP TO FIRST ENTRY             43600020
LOOP     EQU   *                                                        43800020
         CR    RWORK,RWORK2             END OF TABLE                    44000020
         BH    ERR                      YES - TAKE ERROR EXIT           44200020
*                                                                       44400020
         EX    RTERM,COMP               RIGHT ENTRY                     44600020
         BE    FOUND                    YES - GO PROCESS IT             44800020
*                                                                       45000020
         LA    RWORK,OPCONE(,RWORK)     BUMP COUNTER BY ONE             45200020
         LA    RTNT,OPCFOUR(RTERM,RTNT) BUMP TO NEXT ENTRY              45400020
         B     LOOP                     GET NEXT ENTRY                  45600020
*                                                                       45800020
ERR      EQU   *                                                        46000020
         MVC   BAD(OPCEIGHT),OPCTNME    PUT NAME IN MSG                 46200020
         LA    RWORK,BADMSG             GET MSG ADDR                    46400020
         B     SETBAD                                                   46600020
*                                                                       46800020
FOUND    EQU   *                                                        47000020
         MVC   GOOD(OPCEIGHT),OPCTNME   PUT NAME IN MSG                 47200020
         AR    RTNT,RTERM               BUMP PAST TERMNAME              47400020
         MVC   OPCWORK+1(OPCTHREE),OPCONE(RTNT) PUT ON BDRY             47600020
         L     RTERM,OPCWORK             GET TERM ADDRESS               47800020
         MVC   OPCDOUBL(OPCTHREE),OPCOPFLD  MOVE FOR CONVERT            48000020
         MVC   GOOD+12(OPCTHREE),OPCDOUBL PUT INTVL IN MSG              48200020
         CLI   OPCBITSW+1,OPCTHREE      FIELD > 3                       48400020
         BH    COMINV                   YES - REJECT COMMAND            48600020
*                                                                       48800020
         LA    R14,OPCDOUBL-1(R15)      INITIALIZE FOR LOOP             49000020
CLIPOLL  EQU   *                                                    624 49200020
         CLI   OPCZERO(R14),FOXOH       ALPHA CHARACTER                 49400020
         BL    COMINV                   YES- REJECT COMMAND             49600020
*                                                                   624 49800020
         BCTR  R14,R0                   DECREMENT                       50000020
         BCT   R15,CLIPOLL              RETURN TO LOOP                  50200020
*                                                                   624 50400020
         IC    R15,OPCBITSW+1           RESTORE LENGTH                  50600020
         BCTR  R15,R0                   DECREMENT FOR EXECUTE           50800020
         EX    R15,PACK                 PACK                            51000020
         XC    OPCDOUBL(OPCSIX),OPCDOUBL CLEAR FOR CONVERT              51200020
         CVB   RWORK,OPCDOUBL           CONVERT                         51400020
         CH    RWORK,MAXVAL             GREATER THAN MAX                51600020
         BH    COMINV                   YES - REJECT COMMAND            51800020
*                                                                       52000020
*                                                                       52600020
         TM    TRMSTATE,PROC+DIST        DISTRIBUTION,PROCESS,OR CASCDE 52660020
         BNZ   PE                        YES, REJECT COMMAND            52720020
         L     RQCB,TRMDESTQ-1          GET QCB ADDR FROM TERM          52800020
         L     RDCB,QCBDCBAD-1          GET DCB ADDR FROM QCB           53000020
         CLI   DCBTIOT,A                LINE OPEN                       53200020
         BNL   LNENOP                  NO CAN NOT CHANGE                53400020
*                                                                       53600020
         SR    R0,R0                    CLEAR                           53800020
         IC    R0,QCBRELLN              GET RLN                         54000020
         SR    R1,R1                    CLEAR                           54200020
         IC    R1,DCBEIOBX              GET INDEX TO IOB                54400020
         MR    R0,R0                    GET INDEX TO THIS IOB           54600020
         L     RLCB,DCBIOBAD            FIRST IOB ACDR                  54800020
         LA    RLCB,OPCZERO(RLCB)       CLEAR HIGH BYTE                 55000020
         AR    RLCB,R1                  GET THIS IOB ADDR               55200020
         LA    R1,LCBFLAG1-IEDQLCB                                      55400020
         SR    RLCB,R1                  BACK UP TO LCB                  55600020
         TM    LCBSTAT2,LCBDIAL         DIAL LCB                        55800020
         BO    INVALID                  YES - REJECT COMMAND            56000020
*                                                                       56200020
         STC   RWORK,DCBINTVL           PUT INVL IN DCB                 56400020
         LA    RWORK,GOODMSG            GET MSG ADDR                    56600020
         B     SETGOOD                                                  56800020
*                                                                       57000020
INVALID  EQU   *                                                        57200020
         MVC   NO(OPCEIGHT),OPCTNME     PUT NAME IN MSG                 57400020
         LA    RWORK,NOGO               GET MSG ADDR                    57600020
         B     SETBAD                                                   57800020
*                                                                       58000020
LNENOP   EQU   *                                                        58040020
         MVC   ERMGTXT(OPCEIGHT),OPCTNME      SAVE TERM NAME            58080020
         LA    RWORK,ERMG              GET ADDR OF MESSAGE              58120020
         B     SETBAD                  SET BAD RETURN CODE              58160020
BITSW    EQU   *                                                        58200020
         TM    AVTBIT1,AVTDLAYN          SYSTEM INTERVAL ACTIVE         58260020
         BO    GTMSG45                     YES, REJECT THE COMMAMD      58320020
         MVC   NOACT+1(9),NOACTION     CHANGE 'ALTERED' TO 'ACTIVATED'  58500020
         L     RWORK,16                  GET                            58520020
         TM    CVTTSFLG,CVTTSRDY         IS TSO ON SYSTEM               58540020
         BO    REJECT                    YES, DON0T ALLOW INTERVAL      58560020
         L     RWORK,AVTHI               GET INTERVAL CODE ADDR         58580020
         LA    RWORK,OPCZERO(RWORK)     CLEAR HIGH BYTE                 58600020
         LTR   RWORK,RWORK              CODE IN SYSTEM                  58800020
         BZ    REJECT                   NO - REJECT COMMAND             59000020
*                                                                       59200020
         CLC   AVTINTLV(OPCTWO),AVTFZERO INTERVAL ZERO                  59400020
         BE    REJECT                   YES - REJECT COMMAND            59600020
*                                                                       59800020
         ST    RWORK,OPCSAVE2           BUILD PARAMETER                 60000020
         SR    RWORK,RWORK                LIST FOR                      60200020
         ST    RWORK,OPCSAVE2+4           COOSS-PARTITION               60400020
         MVI   OPCSAVE2+4,PRISYSDL        POST                          60600020
         LA    RWORK,OPCSAVE2                                           60800020
         ST    RWORK,OPCPPL                                             61000020
         ST    RWORK,OPCPPL+4                                           61200020
         MVI   OPCPPL,TWELVE                                            61400020
         MVI   OPCPPL+4,HIGH                                            61600020
         LA    R1,OPCPPL                                                61800020
         AQCTL                                                          62000020
*                                                                       62200020
         LA    RWORK,SYSMSGA            GET MSG ADDR                    62400020
         B     SETGOOD1                                                 62600020
*                                                                       62800020
PE       EQU   *                                                        62810020
         MVC   PEMSG(OPCEIGHT),OPCTNME   SET UP NAME                    62820020
         LA    RWORK,PEM                 GET ERROR MESSAGE ADDRESS      62830020
         B     SETBAD                    SET BAD RETURN CODE            62840020
GTMSG45  LA    RWORK,SYSON               MSG TO REJECT SYSTEM INTERV    62860020
         B     SETBAD                      BAD CODE - RETURN            62920020
COMINV   EQU   *                                                        63000020
         LA    RWORK,OPCERMSG           GET MSG ACDR                    63200020
         B     SETBAD                                                   63400020
*                                                                       63600020
DATLN    EQU   14                                                       63800020
PROC     EQU   X'20'                                                    63860020
DIST     EQU   X'40'                                                    63920020
TWELVE   EQU   X'0C'                                                    64000020
HIGH     EQU   X'80'                                                    64200020
BITSOFF  EQU   X'E0'                                                    64400020
FOXOH    EQU   X'F0'                                                    64600020
SYSONLY  EQU   X'80'                                                    64800020
POLL     EQU   X'40'                                                    65000020
A        EQU   C'A'                                                     65200020
SYSMAX   DC    F'65535'                                                 65400020
MAXVAL   DC    H'255'                                                   65600020
PACK     PACK  OPCDOUBL+6(OPCTWO),OPCDOUBL(OPCONE)                      65800020
PACKS    PACK  OPCDOUBL+5(OPCTHREE),OPCDOUBL(OPCONE)                    66000020
COMP     CLC   OPCZERO(OPCONE,RTNT),OPCTNME                             66200020
PEM      DS    0H                                                       66250020
         DC    AL2(DESCR1-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   66300020
         DC    C'IED090I '                                              66350020
PEMSG    DC    8C' ',C' IS NOT SINGLE ENTRY'                            66400020
DESCR1   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    66450020
         DC    X'0000'                   ROUTING - IN REG 0             66500020
SYSMSGA  DS    0H                                                       66550020
         DC    AL2(DESCR2-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   66600020
         DC    C'IED093I SET SYSTEM INTERVAL'                           66650020
         DC    C' COMMAND ACCEPTED'                                     66700020
DESCR2   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    66750020
         DC    X'0000'                   ROUTING - IN REG 0             66800020
SYSON    DS    0H                                                       66850020
         DC    AL2(DESCR3-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   66900020
         DC    C'IED045I SYSTEM INTERVAL ALREADY'                       66950020
         DC    C' ACTIVE'                                               67000020
DESCR3   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    67050020
         DC    X'0000'                   ROUTING - IN REG 0             67100020
SYSMSG   DS    0H                                                       67150020
         DC    AL2(DESCR4-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   67200020
         DC    C'IED047I SYS INTERVAL IS           '                    67250020
DESCR4   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    67300020
         DC    X'0000'                   ROUTING - IN REG 0             67350020
BADMSG   DS    0H                                                       67400020
         DC    AL2(DESCR5-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   67450020
         DC    C'IED016I STATION '                                      67500020
BAD      DC    8C' ',C' NOT FOUND'                                      67550020
DESCR5   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    67600020
         DC    X'0000'                   ROUTING - IN REG 0             67650020
GOODMSG  DS    0H                                                       67700020
         DC    AL2(DESCR6-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   67750020
         DC    C'IED048I POLLING DELAY FOR '                            67800020
GOOD     DC    8C' ',C' IS      '                                       67850020
DESCR6   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    67900020
         DC    X'0000'                   ROUTING - IN REG 0             67950020
NOGO     DS    0H                                                       68000020
         DC    AL2(DESCR7-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   68050020
         DC    C'IED061I POLLING DELAY FOR '                            68100020
NO       DC    8C' ',C'  CANNOT BE ALTERED'                             68150020
DESCR7   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    68200020
         DC    X'0000'                   ROUTING - IN REG 0             68250020
NOSYS    DS    0H                                                       68300020
         DC    AL2(DESCR8-*),X'6000'     LENGTH,MCSFLGS-INREG0-IMMRSP   68350020
         DC    C'IED011I SYSTEM INTERVAL CANNOT BE'                     68400020
NOACT    DC    C' ALTERED  '                                            68450020
DESCR8   DC    X'0800'                   DESCRIPTOR - IMMEDIATE RESP    68500020
         DC    X'0000'                   ROUTING - IN REG 0             68550020
NOACTION DC    C'ACTIVATED'                                             68900020
ERMG     DS    0H                                                       68910020
         DC    AL2(DESCR9-*),X'6000'   LENGTH, MCSFLGS-INREG0-IMMRSP    68920020
         DC    C'IED017I LINE FOR '                                     68930020
ERMGTXT  DC    8C' ',C' NOT OPEN'                                       68940020
DESCR9   DC    X'0800'                 DESCRIPTOR - IMMED RESP          68950020
         DC    X'0000'                 ROUTING - IN REG 0               68960020
CVT      DSECT                                                          69000020
         CVT                                                            69100020
         PRINT NOGEN                                                    69200020
         TOPCD                                                          69400020
         TAVTD                                                          69600020
         TPRIOR                                                         69800020
         TLCBD                                                          70000020
         TQCBD                                                          70200020
         DCBD  DSORG=TX                                                 70400020
         TPRFD                                                          70600020
         TTRMD                                                          70800020
         TTNTD                                                          71000020
         END                                                            71200020
