E7       TITLE '''IEDQE7'' - TCAM/CQTAM RETRIEVE SCHEDULER'             00200020
IEDQE7   CSECT                                                          00400020
         SPACE 3                                                        00401022
*  CHANGE ACTIVITY AS FOLLOWS:                                          00402022
******************** MICROFICHE FLAGS *********************** SUPT CODE 00403022
*D177000                                                        SA55385 00410022
*C280000-282000                                                 SA55385 00410122
*C172400,653000                                                  A41026 00410222
*A196000,200000                                                   M6692 00410322
*C172400                                                          M6692 00410422
*D700000                                                         S21903 00410522
*C172200,172300,201000,548000,600000,614000                      S21903 00410622
*A290001,302001-302011,308500-309500,346001,432001,690200-690600SA56920 00410722
*C302006                                                        SA62965 00410805
*A404000                                                        SA63603 00470852
*D410000,417200                                                 SA63603 00530852
*A404200                                                        SA67767 00550856
*C405600,406400                                                 SA67767 00570856
         SPACE 4                                                        00600020
*********************************************************************** 00800020
*                                                                     * 01000020
*TITLE: 'IEDQE7' RETRIEVE SCHEDULER                                   * 01200020
*                                                                     * 01201022
*  MODULE NAME = IEDQE7                                               * 01202022
*                                                                     * 01203022
*  DESCRIPTIVE NAME = RETRIEVE SCHEDULER                              * 01204022
*                                                                     * 01205022
*  COPYRIGHT = 'NONE'                                                 * 01206022
*                                                                     * 01207022
*  STATUS: CHANGE LEVEL 5                                             * 01208052
*                                                                     * 01209022
*FUNCTION: THIS ROUTINE RETRIEVES A BUFFER FROM A DESTINATION QUEUE   * 01400020
*   BY SEQUENCE NUMBER(HEADER BUFFERS) OR BY RELATIVE BUFFER ADDRESS  * 01600020
*   (TEXT BUFFERS).  IT IS ACTIVATED BY A SPECIAL RETRIEVE ELEMENT    * 01800020
*   POSTED BY THE RETRIEVE ROUTINE IN THE APPL PROG.  FOR INITIAL     * 02000020
*   REQUESTS, THE QBACK CHAIN IS SCANNED FOR THE DESIRED SEQ. NO.     * 02200020
*   UNTIL IT IS FOUND OR DETERMINED TO HAVE BEEN LOST OR NOT ON       * 02400020
*   THE QUEUE.  THE RETRIEVED BUFFER IS PLACED IN THE ELEMENT CHAIN   * 02600020
*   OF THE PCB QCB AND THE WAITING RETRIEVE ROUTINE IS POSTED         * 02800020
*   COMPLETE.  WHEN RETRIEVE EMPTIES THE BUFFER, IT POSTS AN EMPTY-   * 03000020
*   BUFFER ELEMENT TO THE RETRIEVE SCHEDULER.  IT RETURNS THE BUFFER  * 03200020
*   TO THE POOL, DEALLOCATES MAIN STORAGE FOR DUMMY LCB AND SCB,      * 03400020
*   AND WAITS FOR ANOTHER RETRIEVE REQUEST.                           * 03600020
*ENTRY POINT:                                                         * 03800020
*        IEDQE7                                                       * 04000020
*INPUT:                                                               * 04200020
*   1  - ONE OF THE FOLLOWING:                                        * 04400020
*        A. RETRIEVE ELEMENT                                          * 04600020
*        B. ERB                                                       * 04800020
*        C. BUFFER RETURN ELEMENT                                     * 05000020
*OUTPUT:                                                              * 05200020
*        NONE                                                         * 05400020
*EXTERNAL ROUTINES:                                                   * 05600020
*        DISPATCHER                                                   * 05800020
*        AQCTL                                                        * 06000020
*EXITS-NORMAL:                                                        * 06200020
*        RETURNS TO DSPDISP                                           * 06400020
*EXITS-ERROR:                                                         * 06600020
*        NONE                                                         * 06800020
*TABLES/WORKAREAS:                                                    * 07000020
*        AVT                                                          * 07200020
*        PCB                                                          * 07400020
*        SCB                                                          * 07600020
*        LCB                                                          * 07800020
*        QCB                                                          * 08000020
*        TERMINAL ENTRY                                               * 08200020
*ATTRIBUTES: REENTRANT,REFRESHABLE,PROBLEM PROGRAM MODE               * 08400020
*                                                                       08600020
*NOTES: THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 08800020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 09000020
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED   * 09200020
*   SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,     * 09400020
*   WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.          * 09600020
*********************************************************************** 09800020
         EJECT                                                          10000020
*                                                                     * 10200020
*        S Y M B O L I C    R E G I S T E R S                         * 10400020
*                                                                     * 10600020
         SPACE  2                                                       10800020
RZERO    EQU   0                                                        11000020
RPARM    EQU 1                          PARAMETER REGISTER              11200020
RELEM    EQU   2                        SPECIAL ELEMENT                 11400020
RWORK    EQU   3                                                        11600020
RTERM    EQU   4                        TERMINAL ENTRY                  11800020
RBFR     EQU   5                        BUFFER PREFIX                   12000020
RDQ      EQU   6                        DESTINATION QCB                 12200020
RQCB     EQU   7                        QUEUE CONTROL BLOCK             12400020
RLCB     EQU   8                        DUMMY LINE CONTROL BLOCK        12600020
RSCB     EQU   9                        DUMMY STATION CONTROL BLOCK     12800020
RPCB     EQU   10                       PROCESS CONTROL BLOCK           13000020
RDISP    EQU   11                       TCAM DISPATCHER                 13200020
RBASE    EQU   12                       CSECT BASE REGISTER             13400020
RAVT     EQU   13                       TCAM ADDRESS VECTOR             13600020
RETURN   EQU   14                                                       13800020
RENTRY   EQU   15                                                       14000020
         SPACE 2                                                        14200020
         BALR  RBASE,RZERO              ESTABLISH                       14400020
         USING *,RBASE                           ADDRESSABILITY         14600020
         EJECT                                                          14800020
*                                                                     * 15000020
*     ESTABLISH TCAM CONTROL BLOCKS ADDRESSABILITY                    * 15200020
*                                                                     * 15400020
         SPACE                                                          15600020
         USING IEDQQCB,RDQ              DESTINATION QCB                 15800020
         USING IEDQDISP,RDISP           TCAM DISPATCHER                 16000020
         USING IEDQAVTD,RAVT            TCAM ADDRESS VECTOR TABLE       16200020
         USING IEDQSCB,RSCB             STATION CONTROL BLOCK           16400020
         USING IEDQLCB,RLCB             LINE CONTROL BLOCK              16600020
         USING IEDQPCB,RPCB             PROCESS CONTROL BLOCK           16800020
         USING IEDQTRM,RTERM            TERMINAL ENTRY                  17000020
         USING IEDQPRF,RBFR             BUFFER PREFIX                   17200020
IEDQE7   IEDHJN SKIPID                  ASSEMBLY DATE            S21903 17220005
         LA    RPCB,0(0,RQCB)           COPY QCB ADDRESS                17280020
         LA    RWORK,8                  QCB OFFSET INTO PCB             17300020
         SR    RPCB,RWORK               PCB ADDRESS                     17320020
         CLI   8(RPARM),X'FF'           FREE-BUFFER ELEMENT             17400020
         BNE   TEST                     BRANCH IF NOT                   17600020
         L     RBFR,QCBELCHN-1-IEDQQCB(0,RQCB) EMPTY BUFFER ADDR        17800020
         XC    QCBELCHN-IEDQQCB(3,RQCB),QCBELCHN-IEDQQCB(RQCB)          17900020
         LA    RETURN,POSTBUF                                           18000020
EBUF     EQU   *                                                        18200020
         LA    RZERO,AVTBFRTB           BUFFER RETURN QCB ADDRESS       18400020
         ST    RZERO,PRFQCBA-1          STORE IN EMPTY BUFFER RCB       18600020
         MVI   PRFPRI,PRIBFRTB          EMPTY BUFFER PRIORITY           18800020
         XC    PRFLINK(3),PRFLINK       ZERO THE LINK FIELD             19000020
         LR    RPARM,RBFR               DISP PARAMETER REGISTER         19200020
         BR    RETURN                   RETURN TO CALLER                19400020
POSTBUF  EQU   *                                                        19600020
         LR    RELEM,RQCB               SAVE OVER DISP CALL       M6692 19650020
         BAL   RETURN,DSPPOSTR          POST EMPTY BUFFER TO            19800020
*                                       BUFFER RETURN SUBTASK           20000020
         LR    RQCB,RELEM               RESTORE QCB ADDRESS       M6692 20050020
         B     SVC                      BR TO POST APPL PROGRAM  S21903 20100022
         EJECT                                                          20200020
TEST     EQU   *                                                        20400020
         CLI   4(RPARM),PRIRTBFR        SPECIAL RETRIEVE ELEMENT        21200020
         BNE   ERB                      BRANCH IF NO TO HANDLE ERB      21400020
*                                                                     * 21600020
*      DYNAMIC ALLOCATION OF LINE AND STATION CONTROL BLOCKS          * 21800020
*                                                                     * 22000020
         SR    RWORK,RWORK              CLEAR WORK REGISTER TO ZERO     22200020
         IC    RWORK,AVTSCBSZ           STATION CONTROL BLOCK SIZE      22400020
         LA    RWORK,LCBCPA-IEDQLCB(0,RWORK) ADD LCB SIZE TO COUNT      22600020
         ST    RWORK,AVTGETMN           STORE BYTE COUNT IN GM LIST     22800020
         ST    RWORK,0(0,RPCB)          SAVE GETMAIN COUNT              23000020
         LA    RWORK,4(0,RQCB)          ADDRESS OF WORD TO CONTAIN      23200020
*                                       GETMAIN AREA ADDRESS            23400020
         ST    RWORK,AVTGETMN+4                                         23600020
         MVI   AVTGETMN+9,0             SUBPOOL NUMBER                  23800020
         LA    RPARM,AVTGETMN           GETMAIN PARAMETER LIST          24000020
         GETMAIN  ,MF=(E,(1))                                           24200020
         MVI   4(RQCB),X'1C'                                            24400020
         LTR   RENTRY,RENTRY            SUCCESSFUL GETMAIN              24600020
         BZ    GO                       BRANCH IF YES                   24800020
         EJECT                                                          25000020
SETERR   EQU   *                                                        25200020
         MVI   PCBORC,4                 SET ERROR RETURN CODE           25400020
SVC      EQU   *                                                        25600020
*                                                                     * 25800020
*      POST WAITING APPLICATION PROGRAM'S ECB COMPLETE                * 26000020
*                                                                     * 26200020
         MVI   PCBWRKA,POSTER           AQCTL ACTION CODE               26400020
         MVC   PCBWRKA+1(3),PCBWRKA+17  ECB ADDRESS                     26600020
         LA    RPARM,PCBTJID                                            26800020
         ST    RPARM,PCBWRKA+4                                          27000020
         MVC   PCBWRKA+9(3),PCBTCBAD+1                                  27200020
         MVI   PCBWRKA+8,EOL                                            27400020
         LA    RPARM,PCBWRKA            AQCTL PARAMETER LIST            27600020
         AQCTL                          POST APPL PROG ECB              27800020
         CLI   QCBELCHN-IEDQQCB(RQCB),AVTEZERO BFR RETURNED YET SA55385 28000022
         BNE   DSPDISP                  BRANCH IF NO            SA55385 28200022
         SPACE 2                                                        28400020
*                                                                     * 28600020
*        DEALLOCATION OF LINE AND STATION CONTROL BLOCKS              * 28800020
*                                                                     * 29000020
CLEANUP  EQU   *                                                SA56920 29000122
         MVC   AVTGETMN(4),0(RPCB)      SIZE OF AREA TO FREE            29200020
         LA    RWORK,4(0,RQCB)          ADDR OF ADDR OF AREA            29400020
         ST    RWORK,AVTGETMN+4         STORE IN PARAMETER LIST         29600020
         MVI   AVTGETMN+9,0             SUBPOOL NUMBER                  29800020
         LA    RPARM,AVTGETMN           FREEMAIN PARM LIST ADDR         30000020
         FREEMAIN  ,MF=(E,(1))          FREEMAIN FOR LCB AND SCB        30200020
         TM    PCBOFLG,PCBRTRVE         QTAM RETRIEVE           SA56920 30200122
         BZ    DISPRET                  GO BACK TO DISPATCHER   SA56920 30200222
         TM    PCBOFLG,PCBCLOSE         CLOSE IN EFFECT         SA56920 30200322
         BZ    DISPRET                  NO                      SA56920 30200422
         NI    PCBOFLG,PCBCLN           CLEAN UP BITS           SA56920 30200522
         L     RPARM,PCBWRKA            SPECIAL ELEMENT ADDRESS SA62965 30200605
         MVI   FOUR(RPARM),PRIRTBFR     SET PRIORITY FOR CLOSE  SA56920 30200722
         MVC   ONE(THREE,RPARM),AVTOCQPT+ONE OPEN/CLOSE QCB     SA56920 30200822
         B     DSPPOST                  POST ELEMENT TO EU      SA56920 30200922
DISPRET  EQU   *                                                SA56920 30201022
         NI    PCBOFLG,AVTEFF-PCBRTRVE  TURN OFF QTAM RET FLAG  SA56920 30201122
         B     DSPDISP                  RETURN TO DISPATCHER            30400020
         EJECT                                                          30600020
ERB      EQU   *                                                        30800020
         NI    PCBOFLG,AVTEFF-PCBERBUS  TURN OFF ERB BUSY FLAG  SA56920 30850022
         TM    PCBOFLG,PCBCLOSE         CLOSE IN EFFECT         SA56920 30900022
         BO    CLEANUP                  YES,GO CLEANUP          SA56920 30950022
         LR    RLCB,RPARM               ERB WITHIN LCB                  31000020
         LA    RWORK,LCBERB-IEDQLCB     ERB DISPLACEMENT WITHIN LCB     31200020
         SR    RLCB,RWORK               STARTING ADDRESS OF LCB         31400020
         LA    RSCB,LCBCPA-IEDQLCB(0,RLCB)  GET SCB ADDRESS             31600020
         NC    LCBERBCH(3),LCBERBCH     RECALL READ ERROR               31660020
         BZ    SETERR                   BRANCH IF YES                   31720020
         TM    PCBOFLG,PCBRETVN         SUBSEQUENT RETRIEVAL            31800020
         BNO   INIT                     BRANCH IF NO                    32000020
SAVBFR   EQU   *                                                        32200020
         MVC   PCBWRKA+20(1),SCBSTAT1                                   32300020
         MVC   PCBWRKA+21(3),SCBSCSEG   SAVE CURRENT SEGMENT ADDR       32400020
         MVC   PCBWRKA+24(1),SCBDEOB                                    32500020
         MVC   PCBWRKA+25(3),SCBXTRA                                    32600020
         MVC   PCBOFLG+1(3),SCBNTXT                                     32700020
         MVC   QCBELCHN-IEDQQCB(3,RQCB),LCBERBCH PUT BFR ON RTV QCB     33000020
         L     RPARM,LCBERBCH-1         GET BUFFER ADDRESS              33060020
         MVI   PRFSCAN-IEDQPRF(RPARM),AVTEZERO CLEAR IDLE COUNT         33120020
         MVI   PCBORC,0                 NORMAL COMPLETION CODE          33200020
         NI    PCBOFLG,PCBRETVF         TURN OFF RETRIEVE FLAG          33400020
         B     SVC                      GO ACTIVATE APPL. PROG.         33600020
         SPACE 2                                                        33800020
GO       EQU   *                                                        34000020
*                                                                     * 34200020
*          SCB  AND  LCB  INITIALIZATION                              * 34400020
*                                                                     * 34600020
         OI    PCBOFLG,PCBRTRVE         IT IS QTAM RETRIEVE     SA56920 34600122
         L     RLCB,4(0,RQCB)           LCB ADDRESS                     34800020
         L     RWORK,0(0,RPCB)          SIZE OF GETMAIN AREA            35000020
         LR    RSCB,RLCB                COMPUTE STARTING ADDRESS        35200020
         LA    RSCB,LCBCPA-IEDQLCB(0,RSCB)   OF SCB                     35400020
         XC    0(LCBCPA-IEDQLCB,RLCB),0(RLCB)                           35600020
         XC    0(SCBRGSAV-IEDQSCB,RSCB),0(RSCB)                         35800020
         ST    RPCB,LCBDCBPT                                            36000020
         ST    RQCB,LCBRCQCB                                            36200020
         OI    LCBSTAT1,LCBRCLLN+LCBRECVN  SET RECALL FLAGS             36400020
         ST    RSCB,LCBSCBDA-1          CURRENT SCB ADDRESS             36600020
         ST    RSCB,LCBSCBA-1           CURRENT SCB                     36800020
         MVI   LCBERBCT,1               BUFFER REQUEST COUNT            37000020
         MVI   LCBERBCT+1,0                                             37200020
         XC    LCBTTCIN(2),LCBTTCIN                                     37300020
         CLI   PCBWRKA+8,0              SUBSEQUENT RETRIEVAL            37400020
         BE    SETERB                   BRANCH IF YES                   37500020
         XC    PCBWRKA+20(3),PCBWRKA+20                                 37600020
         NI    PCBORC,AVTEFF-FIRSTR     TURN OFF FIRST-TIME FLAG        37800020
         EJECT                                                          38000020
         L     RTERM,PCBWRKA+8          TERMINAL ENTRY ADDRESS          38400020
         L     RDQ,TRMDESTQ-1           DESTINATION QCB ADDRESS         38600020
         ST    RDQ,SCBDESTQ-1           SET UP DEST QCB ADDRESS         38800020
         MVC   SCBDEOB+1(3),QCBQBACK    QBACK CHAIN POINTER             39000020
         MVC   SCBSCHDR(3),SCBDEOB+1                                    39100020
         NC    QCBQBACK,QCBQBACK        QBACK EMPTY                     39200020
         BZ    SETERR                   BRANCH IF YES                   39400020
SETERB   EQU   *                                                        39600020
         MVI   SCBDEOB,0                                                39800020
         CLI   PCBWRKA+8,0              SUBSEQUENT BFR RETRIEVAL        40000020
         BNE   POSTERB                  BRANCH IF NO                    40200020
         LH    RPARM,PCBWRKA+14         TNT OFFSET                      40240020
         L     RENTRY,AVTRNMPT          CONVERSION LOGIC OFFSET         40280020
         BALR  RETURN,RENTRY            GET TERM ENTRY ADDRESS          40320020
         MVC   SCBDESTQ(3),TRMDESTQ-IEDQTRM(RPARM) QCB ADDRESS          40360020
         MVC   SCBDEOB+1(3),PCBWRKA+9   QBACK POINTER TO NEXT TEXT      40400020
         MVI   LCBSTAT1,LCBRCLLN+LCBSENDN SET RECALL STATE      SA63603 40410052
         OI    PCBOFLG,PCBRETVN         SET SUBSEQUENT RETRIEVE SA63603 40420052
         CLC   SCBDEOB+1(3),PCBWRKA+21  PREVIOUS SCSEQ          SA67767 40422056
         BE    SETERBX                  BRANCH IF YES           SA67767 40424056
         CLI   PCBWRKA+24,AVTEZERO      DEOB EQUAL ZERO?        SA67767 40426056
         BNE   SETERBX                  BRANCH IF NO            SA67767 40428056
         CLC   SCBDEOB+1(3),PCBWRKA+25  TEXT RECALL             SA63603 40430052
         BE    SETERBX                  BRANCH IF YES           SA63603 40440052
         CLC   SCBDEOB+1(3),PCBOFLG+1   TEXT RECALL             SA63603 40450052
         BNE   POSTERB                  BRANCH IF NO            SA63603 40460052
SETERBX  EQU   *                                                SA63603 40470052
         MVC   SCBDEOB(1),PCBWRKA+24                                    40480020
         XC    SCBXTRA(3),SCBXTRA       SET UP TO RECALL        SA67767 40560056
         XC    SCBNTXT(3),SCBNTXT       SUBSEQUENT UNIT         SA67767 40640056
         XC    PCBOFLG+1(3),PCBOFLG+1                                   40720020
         MVC   SCBUNTCT(4),PCBWRKA+24   BYTE COUNT & HDR ADDR           40800020
         NI    SCBQTYPE,X'0F'                                           41600020
         MVC   SCBSTAT1(1),PCBWRKA+20                                   41760020
POSTERB  EQU   *                                                        41800020
         LA    RWORK,AVTDSIOB           DISK I/O QCB                    42000020
         ST    RWORK,LCBERBQB-1         STORE IN ERB QCB FIELD          42200020
         XC    LCBERBLK,LCBERBLK        SET LINK FIELD TO ZERO          42400020
         XC    LCBERBCH(3),LCBERBCH     CLEAR PTR TO LAST BFR           42600020
         MVI   LCBERBPY,PRIAPBFR        ERB PRIORITY                    42800020
         LA    RPARM,LCBERB             ERB ADDRESS FOR POST            43000020
         MVI   LCBERBCT,1               BUFFER REQUEST COUNT            43200020
         OI    PCBOFLG,PCBERBUS         ERB IS BUSY             SA56920 43200122
         B     DSPPOST                  POST ERB TO DISK I/O QCB        43400020
         EJECT                                                          44400020
INIT     EQU   *                                                        44600020
*                                                                     * 44800020
*    THIS SUBR3UTINE SCANS QBACK CHAIN FOR DESIRED MESSAGE            * 45000020
*                                                                     * 45200020
         NC    LCBERBCH(3),LCBERBCH     WRAPPED QUEUE                   45400020
         BZ    SETERR                   BRANCH IF YES                   45600020
         L     RBFR,LCBERBCH-1          RECALLED BUFFER - EITHER        45800020
*                                       HEADER OR LAST TEXT             46000020
         CLI   PCBWRKA+8,C'I'           SCAN BY INPUT SEQ. NO.          46200020
         BE    INPUT                    BRANCH IF YES                   46400020
*                                                                     * 46600020
*       SCAN QBACK CHAIN FOR HEADERS UNTIL DESIRED MESSAGE IS FOUND   * 46800020
*     OR UNTIL IT IS EVIDENT THAT MESSAGE IS NO LONGER IN DEST Q.     * 47000020
*                                                                     * 47200020
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   47400020
         BNO   HDR                      BRANCH IF YES TO TEST           47600020
*                                       SEQUENCE NUMBER                 47800020
RCHDR    EQU   *                                                        48000020
         XC    PCBWRKA+20(3),PCBWRKA+20                                 48100020
         MVC   SCBDEOB+1(3),PRFTQBCK    SET UP TO RECALL HDR            48200020
*                                                                     * 48400020
*   RETURN EMPTY BUFFER AND POST ERB                                  * 48600020
*                                                                     * 48800020
CONT     EQU   *                                                        49000020
         MVC   SCBSCHDR(3),SCBDEOB+1                                    49100020
         XC    SCBXTRA(3),SCBXTRA                                       49200020
         XC    SCBNTXT(3),SCBNTXT                                       49400020
         NI    SCBQTYPE,X'0F'                                           49600020
         BAL   RETURN,EBUF              POST EMPTY BUFFER TO            49800020
*                                       BUFFER RETURN QCB               50000020
         NC    SCBDEOB+1(3),SCBDEOB+1   END OF CHAIN                    50200020
         BZ    ERR                      BRANCH IF YES                   50400020
         BAL   RETURN,DSPPOSTR          PUT EMPTY BFR ON READY Q        50600020
         B     POSTERB                  POST ERB TO DISK I/O QCB        50800020
         SPACE 2                                                        50820020
RECALL   EQU   *                                                        50840020
         TM    LCBSTAT1,LCBRECVN        RECIEVE RECALL                  50860020
         BNO   SAVBFR                   BRANCH IF NO                    50880020
        MVC   SCBDEOB+1(3),PRFCRCD     DO EXTRA RECALL                  50900020
         MVI   LCBSTAT1,LCBRCLLN+LCBSENDN SET SEND STATE                50920020
         B     CONT                     GO DO THE RECALL                50940020
         EJECT                                                          51000020
HDR      EQU   *                                                        51200020
         CLC   PCBWRKA+14(2),PRFDEST    CORRECT DESTINATION             51400020
         BNE   DESTTST                  BRANCH IF NO                    51600020
*                                                                     * 51800020
*         SEE IF THIS ONE HAS THE DESIRED SEQUENCE NUMBER             * 52000020
*                                                                     * 52200020
         CLC   PCBWRKA+12(2),SCBOSEQ    COMPARE SEARCH ARGUMENT         52400020
*                                       WITH OUTPUT SEQUENCE NUMBER     52600020
*                                       OF RECALLED HEADER              52800020
         BE    RECALL                   BRANCH IF YES                   53100020
NEXTONE  EQU   *                                                        53400020
         NC    PRFHQBCK,PRFHQBCK        END OF BACK CHAIN               53600020
         BZ    ERR                      BRANCH IF YES                   53800020
*                                                                     * 54000020
*        ASSUME THAT SEARCH MUST CONTINUE                             * 54200020
*                                                                     * 54400020
         MVC   SCBDEOB+1(3),PRFHQBCK    SET UP TO RECALL HDR            54600020
         B     CONT                     BR TO RETURN EMPTY BFR   S21903 54800022
ERR      EQU   *                                                        55000020
         BAL   RETURN,EBUF              POST EMPTY BUFFER TO            55200020
*                                       BUFFER RETURN QCB               55400020
         BAL   RETURN,DSPPOSTR          PUT EMPTY BFR ON READY Q        55600020
         LA    RQCB,8(0,RPCB)           RESTORE QCB ADDRESS             55800020
         B     SETERR                   DO ERROR CLEANUP                56000020
DESTTST  EQU   *                                                        56200020
         LH    RPARM,PRFDEST            DESTINATION OFFSET              56400020
         N     RPARM,AVTCLRHI           CLEAR HIGH-ORDER HALFWORD       56600020
         L     RENTRY,AVTRNMPT          TNT CONVERSION ROUTINE          56800020
         BALR  RETURN,RENTRY            GET TERM ENTRY ADDRESS          57000020
         CLC   TRMDESTQ-IEDQTRM(3,RPARM),SCBDESTQ  SAME QUEUE           57200020
         BE    NEXTONE                  BRANCH IF YES                   57400020
         B     RCHDR                    SHIFT TO PROPER QBACK CHAIN     57600020
         EJECT                                                          57800020
INPUT    EQU   *                                                        58000020
*                                                                     * 58200020
*      SCAN QBACK CHAIN FOR LAST TEXT SEGMENTS. WHEN ONE IF FOUND,    * 58400020
*      RECALL ASSOCIATED HEADER AND COMPARE SEQUENCE NUMBERS.         * 58600020
*                                                                     * 58800020
         TM    SCBSTAT1,PRFNLSTN        EOM BUFFER RECALLED             59000020
         BNO   LASTSEG                  BRANCH IF YES                   59200020
         TM    PCBORC,FIRSTR            FIRST TIME THROUGH              59400020
         BO    NUMTST                   BRANCH IF NO                    59600020
         B     NEXTONE                  BRANCH FOR NEXT CHECK    S21903 60000022
LASTSEG  EQU   *                                                        60200020
         CLC   PCBWRKA+14(2),PRFSRCE    CORRECT SOURCE                  60600020
         BE    HDRTST                   BRANCH IF YES                   60800020
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   61000020
         BO    RCHDR                    BRANCH IF NO                    61200020
         B     DESTTST                  BRANCH TO CHECK DEST.    S21903 61400022
HDRTST   EQU   *                                                        61600020
*                                                                     * 61800020
*              RECALL ASSOCIATED HEADER                               * 62000020
*                                                                     * 62200020
         TM    PRFSTAT1,PRFNHDRN        HEADER AND LAST TEST            62400020
         BNO   NUMTST                   BRANCH IF YES AND BYPASS        62600020
*                                       HEADER RECALL                   62800020
         MVC   PCBWRKA+20(3),PRFTQBCK   QBACK PTR OF LAST TEXT          63000020
         MVC   SCBDEOB+1(3),PRFCHDR     SET UP TO RECALL HEADER         63200020
         OI    PCBORC,FIRSTR            SET HDR-RECALL SWITCH           63300020
         B     CONT                     CONTINUE THE SCAN               63400020
         SPACE 2                                                        63600020
NUMTST   EQU   *                                                        63800020
*                                                                     * 64000020
*        CHECK SEQUENCE NUMBER IN THIS RECALLED HEADER                * 64200020
*                                                                     * 64400020
         CLC   PCBWRKA+12(2),PRFISEQ    DO INPUT SEQUENCE NUMBERS       64600020
*                                       COMPARE                         64800020
         BE    RECALL                   BRANCH IF YES                   65100020
         TM    PCBORC,FIRSTR            HDR-RECALL MODE                 65200020
         BNO   DESTTST                  BRANCH IF NO             A41026 65300020
*                                                                     * 65400020
*        ASSUME SEQUENCE NUMBER HAS NOT YET BEEN REACHED              * 65600020
*                                                                     * 65800020
GETNEXT  EQU   *                                                        66000020
         NC    PCBWRKA+20(3),PCBWRKA+20 END OF QBACK CHAIN              66200020
         BZ    DESTTST                  BRANCH IF YES                   66400020
         MVC   SCBDEOB+1(3),PCBWRKA+20  QBACK FROM CURRENT LAST TXT     66600020
         XC    PCBWRKA+20(3),PCBWRKA+20                                 66800020
         NI    PCBORC,AVTEFF-FIRSTR     EXIT HDR-RECALL MODE            66900020
         B     CONT                     CONTINUE TO SCAN QBACK          67000020
         EJECT                                                          68400020
*                                                                     * 68600020
*        C O N S T A N T S     A N D     E Q U A T E S                * 68800020
*                                                                     * 69000020
ONE      EQU   1                        OFFSET                  SA56920 69050022
THREE    EQU   3                        LENGTH                  SA56920 69100022
FOUR     EQU   4                        DISPLACEMENT            SA56920 69150022
EOL      EQU   X'80'                                                    69200020
PRIRTBFR EQU   X'D4'                                                    69400020
POSTER   EQU   X'20'                                                    69600020
FIRSTR   EQU   X'08'                                                    69800020
         TPRIOR                                                         70200020
         EJECT                                                          70400020
*                                                                     * 70600020
*              D   S   E   C   T   S                                  * 70800020
*                                                                     * 71000020
         TAVTD 2                                                        71200020
         TPCBD                                                          71400020
         TSCBD                                                          71600020
         TLCBD                                                          71800020
         TDISPD                                                         72000020
         TQCBD                                                          72200020
         TTRMD                                                          72400020
         TPRFD                                                          72600020
         END                                                            72800020
