IEDQE8   TITLE 'IEDQE8  -  BINARY SEARCH ROUTINE'                       00300022
IEDQE8   CSECT                                                          00600022
*********************************************************************** 00900022
*                                                                     * 01200022
*STATUS -- CHANGE LEVEL 0                                             * 01500022
*                                                                     * 01800022
*FUNCTION -- SEARCHES THE TERMINAL NAME TABLE TO FIND THE ENTRY       * 02100022
*   NAME PASSED.                                                      * 02400022
*                                                                     * 02700022
*   THE ADDRESS OF THE FIELD CONTAINING THE TERMINAL NAME SOUGHT      * 03000022
*   AND THE LENGTH OF THE FIELD ARE LOADED FROM THE PARAMETER LIST    * 03300022
*   INTO REGISTERS 2 AND 1 RESPECTIVELY.  REGISTER 4 IS INITIALIZED   * 03600022
*   TO THE ADDRESS OF THE TERMINAL NAME TABLE (AVTRNMPT) AND          * 03900022
*   REGISTER 7 TO THE ENTRY LENGTH FROM THE TERMINAL NAME TABLE.      * 04200022
*                                                                     * 04500022
*   THE LENGTH FROM THE PARAMETER LIST IS COMPARED WITH THE LENGTH    * 04800022
*   FROM THE TERMINAL NAME TABLE.  IF THE LENGTH FROM THE TABLE IS    * 05100022
*   HIGHER THAN OR EQUAL TO THE LENGTH PASSED,  THE LENGTH PASSED     * 05400022
*   IS TO BE USED AS THE COMPARE LENGTH.  IT IS LEFT IN REGISTER 1.   * 05700022
*   IF THE LENGTH FROM THE TABLE IS LOW,  THE LENGTH FROM THE TABLE   * 06000022
*   IS USED AS THE COMPARE LENGTH.  IT IS MOVED INTO REGISTER 1       * 06300022
*   FROM REGISTER 7.                                                  * 06600022
*                                                                     * 06900022
*   REGISTER 1 IS DECREMENTED TO BE USED FOR EXECUTING THE SUBSE-     * 07200022
*   QUENT COMPARE.  REGISTER 10 IS INITIALIZED TO THE ADDRESS OF      * 07500022
*   THE MIDDLE ENTRY FROM THE TERMINAL NAME TABLE.  REGISTER 7 IS     * 07800022
*   INCREMENTED BY 3 TO GET THE FULL LENGTH OF A TERMINAL NAME        * 08100022
*   TABLE ENTRY,  AND THIS VALUE IS SAVED IN REGISTER 11.  REGISTER   * 08400022
*   8 IS SET TO POINT ONE ENTRY BEYOND THE LAST ENTRY IN THE TABLE.   * 08700022
*   REGISTER 7 IS MULTIPLIED BY THE SEARCH EXTENT FACTOR IN THE       * 09000022
*   TERMINAL NAME TABLE TO GET THE LENGTH OF THE FIRST SEARCH         * 09300022
*   EXTENT.  THE SEARCH LOOP IS THEN ENTERED.                         * 09600022
*                                                                     * 09900022
*   REGISTER 10 (THE ADDRESS OF THE ENTRY TO BE COMPARED) IS          * 10200022
*   COMPARED TO REGISTER 8 (THE ADDRESS OF THE LAST ENTRY,  PLUS      * 10500022
*   THE LENGTH OF ONE ENTRY) TO DETERMINE IF THE SEARCH IS BEYOND     * 10800022
*   THE END OF THE TABLE.  IF SO,  THE CURRENT ENTRY IS NOT           * 11100022
*   COMPARED (BECAUSE IT IS NOT A REAL ENTRY).  INSTEAD IT IS         * 11400022
*   IMMEDIATELY DECREMENTED BY THE SEARCH EXTENT IN REGISTER 7 AND    * 11700022
*   COMPARED WITH REGISTER 11.                                        * 12000022
*                                                                     * 12300022
*   IF THE CURRENT ENTRY IS A REAL ENTRY,  IT IS COMPARED TO THE      * 12600022
*   ENTRY PASSED (POINTED TO BY REGISTER 2).  IF THE CURRENT ENTRY    * 12900022
*   IS HIGH,  REGISTER 10 IS DECREMENTED BY REGISTER 7 (THE CURRENT   * 13200022
*   SEARCH EXTENT);  IF IT IS LOW,  IT IS INCREMENTED BY REGISTER     * 13500022
*   7.  REGISTER 7 IS THEN COMPARED WITH REGISTER 11 (THE LENGTH OF   * 13800022
*   ONE ENTRY).  IF REGISTER 7 IS LESS THAN THE LENGTH OF ONE         * 14100022
*   ENTRY,  THE SEARCH HAS FAILED.  REGISTER 15 IS SET TO A RETURN    * 14400022
*   CODE OF X'00',  THE ADDRESS OF THE SCB IS SET IN REGISTER 0 AND   * 14700022
*   RETURN IS MADE VIA THE RETURN INTERFACE ROUTINE.                  * 15000022
*                                                                     * 15300022
*   IF REGISTER 7 IS NOT LESS THAN THE LENGTH OF ONE ENTRY,  IT IS    * 15600022
*   DIVIDED BY TWO TO OBTAIN A NEW SEARCH EXTENT AND THE SEARCH       * 15900022
*   LOOP IS REENTERED.                                                * 16200022
*                                                                     * 16500022
*   IF THE CURRENT ENTRY IS EQUAL TO THE NAME PASSED,  THE SEARCH     * 16800022
*   IS COMPLETE.  THE KEY (ORDINAL INDEX) TO THE MATCHING ENTRY IS    * 17100022
*   COMPUTED BY DIVIDING THE LENGTH FROM THE FIRST ENTRY TO THE       * 17400022
*   MATCHING ENTRY BY THE LENGTH OF ONE ENTRY AND ADDING ONE.  THE    * 17700022
*   KEY IS RETURNED IN REGISTER 15.  THE ADDRESS OF THE SCB IS SET    * 18000022
*   IN REGISTER 0 AND RETURN IS MADE VIA THE RETURN INTERFACE         * 18300022
*   ROUTINE.                                                          * 18600022
*                                                                     * 18900022
*ENTRY POINTS --                                                      * 19200022
*       'IEDQE8' TO SEARCH THE TERMINAL NAME TABLE TO FIND THE        * 19500022
*   ENTRY NAME PASSED.  CALLING SEQUENCE FROM APPLICATION PROGRAM     * 19800022
*   PROGRAM MODULES IS:                                               * 20100022
*                                                                     * 20400022
*        L     R12,AVTMSGS-1            GET ADDR OF VCON TABLE        * 20700022
*        IC    R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR     * 21000022
*        L     R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS           * 21300022
*        BR    R12                      EXIT TO ROUTINE               * 21600022
*                                                                     * 21900022
*INPUT --                                                             * 22200022
*   REGISTER 1 - THE ADDRESS OF A PARAMETER LIST.  PARAMETER LIST     * 22500022
*   FORMAT IS:                                                        * 22800022
*                                                                     * 23100022
*        *********************************                            * 23400022
*        *       * PARAM * UN-   * CHAR  *                            * 23700022
*        * INDEX * LIST  *  USED * LNGTH *                            * 24000022
*        *       * LNGTH *       *       *                            * 24300022
*        *********************************                            * 24600022
*        *                               *                            * 24900022
*        *  ADDRESS OF CHARACTER STRING  *                            * 25200022
*        *                               *                            * 25500022
*        *********************************                            * 25800022
*                                                                     * 26100022
*   REGISTER 3 - THE ADDRESS OF THE SCB.                              * 26400022
*                                                                     * 26700022
*   REGISTER 9 - THE ADDRESS OF THE AVT.                              * 27000022
*                                                                     * 27300022
*   REGISTER 12 - THE ENTRY POINT ADDRESS AND BASE REGISTER FOR       * 27600022
*   THIS ROUTINE.                                                     * 27900022
*                                                                     * 28200022
*OUTPUT --                                                            * 28500022
*   REGISTER 0 - THE ADDRESS OF THE SCB.                              * 28800022
*                                                                     * 29100022
*   REGISTER 15 - IF A MATCHING ENTRY IS FOUND,  THE KEY (ORDINAL     * 29400022
*   INDEX) TO THE MATCHING ENTRY.  IF NO MATCHING ENTRY IS FOUND,     * 29700022
*   A RETURN CODE OF X'00'.                                           * 30000022
*                                                                     * 30300022
*EXTERNAL REFERENCES --                                               * 30600022
*                                                                     * 30900022
*   TERMINAL NAME TABLE.                                              * 31200022
*                                                                     * 31500022
*   AVT - ADDRESS VECTOR TABLE.                                       * 31800022
*                                                                     * 32100022
*   SCB - STATION CONTROL BLOCK FOR CURRENT STATION.                  * 32400022
*                                                                     * 32700022
*EXITS,  NORMAL -- A MATCHING ENTRY IS FOUND.  REGISTER 0 CONTAINS    * 33000022
*   THE ADDRESS OF THE SCB.  REGISTER 15 CONTAINS THE KEY (ORDINAL    * 33300022
*   INDEX) TO THE MATCHING ENTRY.                                     * 33600022
*                                                                     * 33900022
*EXITS,  ERROR -- NO MATCHING ENTRY IS FOUND.  REGISTER 0 CONTAINS    * 34200022
*   THE ADDRESS OF THE SCB.  REGISTER 15 CONTAINS A RETURN CODE OF    * 34500022
*   X'00'.                                                            * 34800022
*                                                                     * 35100022
*TABLES/WORK AREAS -- N/A.                                            * 35400022
*                                                                     * 35700022
*ATTRIBUTES -- SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT,     * 36000022
*   PROBLEM PROGRAM MODE.                                             * 36300022
*                                                                     * 36600022
*   NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN     * 36900022
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 37200022
*                                                                     * 37500022
*********************************************************************** 37800022
         EJECT                                                          37900022
********* REGISTER EQUATES **********                                   38100022
         SPACE                                                          38400022
R0       EQU   0                        DUMMY BASE REG                  38700022
         SPACE                                                          39000022
R1       EQU   1                        PARAMETER LIST ADDRESS          39300022
         SPACE                                                          39600022
RFLD     EQU   2                        ADDR OF FIELD PASSED            39900022
         SPACE                                                          40200022
RSCB     EQU   3                        ADDRESS OF SCB                  40500022
         SPACE                                                          40800022
RTAB     EQU   4                        ADDR OF TABLE TO BE             41100022
*                                         SEARCHED                      41400022
         SPACE                                                          41700022
RLEN     EQU   5                        LENGTH OF FIELD PASSED          42000022
         SPACE                                                          42300022
RSRCHX   EQU   7                        SEARCH EXTENT REGISTER          42600022
         SPACE                                                          42900022
RLAST    EQU   8                        ADDR OF LAST ENTRY + 1          43200022
         SPACE                                                          43500022
RAVT     EQU   9                        ADDRESS OF AVT                  43800022
RADDR    EQU   10                       ADDR OF CURRENT ENTRY IN        44100022
*                                         TABLE                         44400022
         SPACE                                                          44700022
RTRULEN  EQU   11                       FULL LENGTH OF A TABLE ENTRY    45000022
         SPACE                                                          45300022
RBASE    EQU   12                       BASE REGISTER                   45600022
R13      EQU   13                       CALLERS SAVE AREA ADDR          45900022
         SPACE                                                          46200022
R14      EQU   14                       RETURN REGISTER                 46500022
R15      EQU   15                       BRANCH REGISTER, BASE           46800022
*                                         REGISTER AND RETURN CODE      47100022
*                                         REGISTER                      47400022
         SPACE                                                          47700022
********* OTHER EQUATES **********                                      48000022
         SPACE                                                          48300022
ADDRLEN  EQU   3                        LENGTH OF AN ADDR CONSTANT      48600022
         SPACE                                                          48900022
ONE      EQU   1                        OFFSET TO START OF NAME         49200022
         SPACE                                                          49500022
DIVIDE   EQU   1                        SHIFT LENGTH TO HALVE A         49800022
*                                         VALUE IN A REG                50100022
         SPACE                                                          50400022
         SPACE                                                          50700022
INCX     EQU   1                        FACTOR TO GET ORDINAL INDEX     51000022
         SPACE                                                          51300022
TWO      EQU   2                        OFFSET TO LENGTH FIELD          51600022
FOUR     EQU   4                        OFFSET TO FIELD ADDRESS         51900022
SEVEN    EQU   7                        LENGTH FACTOR FOR CLEARING      52200022
*                                         AVT WORK AREA                 52500022
CVTOFF   EQU   16                       ADDRESS OF CVT                  52800022
         SPACE                                                          53100022
MOVEFLAG EQU   X'01'                    INDEX FLAG: MOVE NAME           53400022
         EJECT                                                          53700022
         USING IEDQTNTD,RTAB                                            54000022
         USING *,RBASE                                                  54300022
SAVEIT   SAVE (14,12)                                                   54600022
         LR    RBASE,R15                SET BASE REGISTER               54900022
         L     RAVT,CVTOFF              GET ADDRESS OF CVT              55200022
         L     RAVT,AVTCVTPT(,RAVT)     FIND POINTER TO AVT             55500022
         L     RAVT,AVTEZERO(,RAVT)     GET ADDRESS OF AVT              55800022
         USING IEDQAVTD,RAVT                                            56100022
IEDQE801 EQU   *                                                        56400022
         B     BINSRCH                  BRANCH AROUND ID                56700022
         DC    C'IEDQE8'                MODULE NAME                     57000022
         DC    X'2019'                  CHANGE DATE                     57300022
         SPACE                                                          57600022
BINSRCH  DS    0H                                                       57900022
         SPACE                                                          58200022
         L     RTAB,AVTRNMPT            GET ADDR OF TERMNAME TABLE      58500022
         LR    RFLD,R0                  LOAD TERM NAME ADDRESS          58800022
         SR    RLEN,RLEN                CLEAR REGISTER 5                59100022
         IC    RLEN,TNTENLEN            PUT LENGTH OF TABLE IN R5       59400022
         LR    RSRCHX,RLEN              SET TERM LENGTH                 59700022
         SPACE                                                          60000022
         BCTR  RLEN,AVTEZERO            DECREMENT FOR COMPARE           60300022
         L     RADDR,TNTMIDEN-1         GET ADDR OF MIDDLE ENTRY        60600022
         LA    RADDR,AVTEZERO(,RADDR)   CLEAR HIGH-ORDER BYTE           60900022
         LA    RSRCHX,ADDRLEN(,RSRCHX)  GET FULL ENTRY LENGTH           61200022
         LR    RTRULEN,RSRCHX           SAVE FULL ENTRY LENGTH          61500022
         MH    RSRCHX,TNTLEN            GET OFFSET TO LAST + 1          61800022
         LA    RLAST,TNTFIRST           GET ADDR OF FIRST ENTRY         62100022
         AR    RLAST,RSRCHX             GET ADDR OF LAST + 1            62400022
         LR    RSRCHX,RTRULEN           GET FULL ENTRY LNG              62700022
         MH    RSRCHX,TNTSRCHX          MULTIPLY BY SEARCH EXTENT       63000022
*                                         FACTOR TO GET SEARCH          63300022
*                                         EXTENT                        63600022
         B     ENTRLOOP                 ENTER LOOP                      63900022
         SPACE                                                          64200022
LOOP     EQU   *                                                        64500022
         CR    RSRCHX,RTRULEN           SEARCH EXTENT LT TRUE LNG       64800022
         BL    BADRTN                   YES, ENTRY NOT FOUND            65100022
         SRL   RSRCHX,DIVIDE            DIVIDE EXTENT BY TWO            65400022
         CR    RADDR,RLAST              POINTING BEYOND TABLE END       65700022
         BNL   LO                       YES, GO ADJUST DOWN             66000022
         SPACE                                                          66300022
ENTRLOOP EQU   *                                                        66600022
         EX    RLEN,COMPEX              COMPARE ENTRY WITH FIELD        66900022
         BH    HI                       HIGH, GO ADJUST UP              67200022
         BE    FOUND                    EQUAL, ENTRY FOUND              67500022
         EJECT                                                          67800022
LO       EQU   *                                                        68100022
         SR    RADDR,RSRCHX             LO, ADJUST DOWN                 68400022
         B     LOOP                     BRANCH TO COMPARE NAME          68700022
         SPACE                                                          69000022
HI       EQU   *                                                        69300022
         BXH   RADDR,RSRCHX,LOOP        ADJUST UP AND LOOP              69600022
         SPACE                                                          69900022
FOUND    EQU   *                                                        70200022
         LA    RTAB,TNTOFF(,RTAB)       GET ADDRESS OF 1ST ENTRY        70500022
         SR    RADDR,RTAB               GET OFFSET TO OUR ENTRY         70800022
         SR    R0,R0                    CLEAR FOR DIVIDE                71100022
         LR    R1,RADDR                 MOVE OFFSET TO DIVIDE REG       71400022
         SPACE                                                          71700022
         DR    R0,RTRULEN               DIVIDE TO GET INDEX             72000022
         LA    R15,INCX(,R1)            INCREMENT TO GET ORDINAL        72300022
*                                         INDEX                         72600022
         SPACE                                                          72900022
         B     RETURN                   RETURN TO CALLER                73200022
         SPACE                                                          73500022
BADRTN   EQU   *                                                        73800022
         SR    R15,R15                  RETURN X'00' RETURN CODE        74100022
         SPACE                                                          74400022
RETURN   EQU   *                                                        74700022
         SPACE                                                          75000022
         L     R14,12(R13)              LOAD CALLERS RETURN ADDRESS     75300022
         LM    RFLD,RBASE,28(R13)       RESTORE REGISTERS               75600022
         MVI   12(R13),X'FF'            SET FLAG                        75900022
         BR    R14                      RETURN TO CALLER                76200022
         SPACE                                                          76500022
********* EXECUTED INSTRUCTIONS **********                              76800022
         SPACE                                                          77100022
         SPACE                                                          77400022
COMPEX   CLC   AVTEZERO(1,RFLD),AVTEZERO(RADDR) FIELD-ENTRY COMPARE     77700022
         EJECT                                                          78000022
********* DSECTS *********                                              78300022
         SPACE 2                                                        78600022
         TAVTD                                                          78900022
         EJECT                                                          79200022
         TTNTD                                                          79500022
         END                                                            79800022
