C102     TITLE '''IGC102'' - AQCTL SVC'                                 00100020
IEDQEB01 CSECT                                                          00200020
         SPACE 4                                                        00201022
*CHANGE-ACTIVITY = AS FOLLOWS:                                  SA21903 00202022
************************MICROFICHE FLAGS ******************** SUPT CODE 00203022
*C167000,198500,202000,296000,300000,478000                     0Y00448 00204022
*A202300,202600,501700                                           A44022 00205022
*A383000,502000                                                  A42413 00210021
*C198500,199400,427000,431000                                    CLUP21 00220021
*A422000                                                         CLUP21 00230021
*A202300,202600,501700                                           A44022 00240021
*A198000,206000                                                  A42362 00250021
*C199400,252000,379000                                           CLUP21 00250121
*C199400                                                         A42362 00260021
*A468000                                                         CLUP21 00260121
         SPACE 4                                                        00300020
*********************************************************************** 00400020
*TITLE: 'IEDQEB'  TCAM COMMUNICATION SVC                              * 00500020
*STATUS: CHANGE LEVEL 0                                               * 00600020
*MODULE-NAME = IEDQEB                                           SA21903 00650022
*DESCRIPTIVE NAME = TCAM COMMUNICATION SVC                      SA21903 00660022
*COPYRIGHTS = 'NONE'                                            SA21903 00670022
*FUNCTION: THIS ROUTINE SUPPORTS TCAM APPLICATION PROGRAMS AND        * 00700020
*   ATTACHED TASKS BY PERFORMING THE FOLLOWING GENERAL FUNCTIONS:     * 00800020
*    (1) CROSS-PARTITION DATA MOVEMENT.                               * 00900020
*    (2) INTER-PARTITION/REGION ECB POSTING.                          * 01000020
*    (3) POSTING ELEMENTS TO DISABLED READY QUEUE.                    * 01100020
*    (4) FLAGGING THE TCB FOR A TSO APPL PROG AS SWAPPABLE OR NON-    * 01200020
*        SWAPPABLE.                                                   * 01300020
*    (5) FLAGGING THE TCB FOR A RORI APPL PROG AS ROLLOUTABLE OR      * 01400020
*        NON-ROLLOUTABLE.                                             * 01500020
*    (6) FLAGGING PCB FOR APPL PROG NOT DISPATCHABLE IF CALLED BY     * 01530020
*        ABEND IF CLOSE FAILS OR AN OUT-OF-CORE ABEND OCCURS.         * 01560020
*                                                                     * 01600020
*   ECBS FALL INTO THREE CATEGORIES:                                  * 01700020
*    (1) TSO - TASK MAY NOT BE RESIDENT, I.E., SWAPPED OUT, AT THE    * 01800020
*              TIME OF THE POST.                                      * 01900020
*    (2) RORI - TASK MAY NOT BE RESIDENT, I.E., ROLLED OUT, AT THE    * 02000020
*              TIME OF THE POST.                                      * 02100020
*    (3) STANDARD - TASK ALWAYS RESIDENT.                             * 02200020
*                                                                     * 02300020
*   THIS SVC INTERFACES WITH SYSTEM POST(IEAQSY50) AT A NON-VALIDITY  * 02400020
*   CHECKING ENTRY POINT(IEAOPT01).  INPUT IS AS FOLLOWS:             * 02500020
*    15- BRANCH ENTRY POINT ADDRESS                                   * 02600020
*    14- RETURN ADDRESS                                               * 02700020
*    13- TJID(TSO JOB ID) FOR ECB IN LOW-ORDER 16 BITS(ZERO FOR RORI  * 02800020
*        AND STANDARD ECBS)                                           * 02900020
*    11- COMPLEMENT OF ECB ADDRESS                                    * 03000020
*    10- POST COMPLETION CODE                                         * 03100020
*                                                                     * 03200020
*   IF TASK IS ROLLED OUT, A POST-PENDING BIT IS SET IN THE TCB AND   * 03300020
*   THE DEB ASSOCIATED WITH THE ECB IS ALSO FLAGGED.                  * 03400020
*   THIS ROUTINE BRANCHES VIA TSEVENT MACRO TO THE TIME SHARING       * 03500020
*   INTERFACE PROGRAM(TSIP) TO FLAG A TASK SWAPPABLE OR NON-SWAPPABLE.* 03600020
*   THIS ROUTINE BRANCHES TO THE STATUS SVC(IGC079) TO CAUSE A TASK   * 03700020
*   TO BE FLAGGED ROLLOUTABLE OR NON-ROLLOUTABLE.  INPUT FOLLOWS:     * 03800020
*    0 - ALWAYS ZERO                                                  * 03900020
*    1 - ZERO TO FLAG ISSUING NON-ROLLOUTABLE; TCB ADDRESS TO FLAG    * 04000020
*        A TASK ROLLOUTABLE.                                          * 04100020
         EJECT                                                          04200020
*ENTRY POINT:                                                         * 04300020
*        IGC102                                                       * 04400020
*INPUT:                                                               * 04500020
*   1 -  ADDRESS OF VARIABLE-LENGTH PARAMETER LIST.                   * 04600020
*        BYTE 0 IN THE LIST CONTAINS THE ACTION CODE:                 * 04700020
*        BIT  FUNCTION                                                * 04800020
*        ***  ********                                                * 04900020
*         0  FLAG ISSUING TASK NON-ROLLOUTABLE                        * 05000020
*         1  POST RORI ECB COMPLETE                                   * 05100020
*         2  POST STANDARD OR TSO ECB COMPLETE                        * 05200020
*         3  FLAG ISSUING TASK NON-SWAPPABLE                          * 05300020
*         4  MOVE DATA ACROSS PARTION/REGION BOUNDARY                 * 05400020
*         5  ENQUEUE AN ELEMENT ON DISABLED READY QUEUE AND           * 05500020
*            POST THE MCP ECB COMPLETE                                * 05600020
*         6  FLAG A TASK SWAPPABLE                                    * 05700020
*         7  FLAG A TASK ROLLOUTABLE                                  * 05800020
*        NOTE: ALL BITS ON INDICATES THAT CALLER IS SYSTEM ABEND.     * 05850020
*                                                                     * 05900020
*     THE CONTENTS OF THE PARAMETER LIST VARY WITH THE ACTION CODE.   * 06000020
*        (1) FOR POST-ONLY REQUESTS, THE LIST MAY CONTAIN TWO OR THREE* 06100020
*            WORDS.                                                   * 06200020
*             A. TSO AND STANDARD(TJID=0)                             * 06300020
*                                                                     * 06400020
*              **********************                                 * 06500020
*              *X'20'* ECB ADDRESS  *                                 * 06600020
*              **********************                                 * 06700020
*              *X'80'* TJID ADDRESS *                                 * 06800020
*              **********************                                 * 06900020
*             B. RORI - THE SECOND WORD POINTS TO THE APPL PROG TCB.  * 07000020
*                WORD THREE POINTS TO THE DEB ASSOCIATED WITH THE     * 07100020
*                ECB BEING POSTED.                                    * 07200020
*                                                                     * 07300020
*        *********************                                        * 07400020
*        *X'40'* ECB ADDRESS *                                        * 07500020
*        *********************                                        * 07600020
*        *X'00'* TCB ADDRESS *                                        * 07700020
*        *********************                                        * 07800020
*        *X'80'* DEB ADDRESS *                                        * 07900020
*        *********************                                        * 08000020
*                                                                     * 08100020
*        (2) THREE WORDS ARE REQUIRED FOR CROSS-PARTITION DATA        * 08200020
*            TRANSFER.  WORD ONE POINTS TO DATA TO BE MOVED.  WORD TWO* 08300020
*            POINTS TO TARGET OF THE MOVE.  WORD THREE POINTS TO A    * 08400020
*            HALFWORD CONTAINING THE NUMBER OF BYTES TO BE MOVED.     * 08500020
*                                                                     * 08600020
*              ************************                               * 08700020
*              *X'08'* DATA ADDRESS   *                               * 08800020
*              ************************                               * 08900020
*              *X'00'* TARGET ADDRESS *                               * 09000020
*              ************************                               * 09100020
*              *X'80'* LENGTH ADDRESS *                               * 09200020
*              ************************                               * 09300020
*                                                                     * 09400020
*            IF WORDS ONE AND TWO ARE THE SAME, NO DATA IS MOVED,     * 09500020
*            BUT THE TARGET IS POSTED TO THE DISABLED READY QUEUE     * 09600020
*            IF THE TARGET IS AN ELEMENT TO POST, BIT 5 MUST ALSO     * 09700020
*            BE SET TO 1(X'0C').  BITS MAY ALSO BE SET TO FLAG THE    * 09800020
*            ISSUING TASK NON-SWAPPABLE OR NON-ROLLOUTABLE.           * 09900020
*                                                                     * 10000020
*         (3) THREE WORDS ARE REQUIRED TO FLAG A TASK SWAPPABLE AND   * 10100020
*            ITS ECB COMPLETE.                                        * 10200020
*                                                                     * 10300020
*              ***********************                                * 10400020
*              *X'42' * ECB ADDRESS  *                                * 10500020
*              ***********************                                * 10600020
*              *X'00' * TJID ADDRESS *                                * 10700020
*              ***********************                                * 10800020
*              *X'80' * TCB ADDRESS  *                                * 10900020
*              ***********************                                * 11000020
*                                                                     * 11100020
*        (4) THREE WORDS ARE REQUIRED TO FLAG A TASK ROLLOUTABLE AND  * 11200020
*            ITS ECB COMPLETE.                                        * 11300020
*                                                                     * 11400020
*              **********************                                 * 11500020
*              *X'81' * ECB ADDRESS *                                 * 11600020
*              **********************                                 * 11700020
*              *X'00' * TCB ADDRESS *                                 * 11800020
*              **********************                                 * 11900020
*              *X'80' * DEB ADDRESS *                                 * 12000020
*              **********************                                 * 12100020
*                                                                     * 12200020
*        (5) TWO WORDS ARE REQUIRED TO FLAG A PCB NOT USABLE FOR      * 12210020
*            INTER-TASK POSTING.                                      * 12220020
*                                                                     * 12230020
*              *********************                                  * 12240020
*              *X'FF' *X'00'* TJID *                                  * 12250020
*              *********************                                  * 12260020
*              *X'00' * TCB ADDRESS*                                  * 12270020
*              *********************                                  * 12280020
*                                                                     * 12290020
         EJECT                                                          12300020
*   3 -  CVT ADDRESS                                                  * 12400020
*   4 -  TCB ADDRESS                                                  * 12500020
*   14-  RETURN ADDRESS                                               * 12600020
*   15-  ENTRY POINT                                                  * 12700020
*OUTPUT:                                                              * 12800020
*   15-  COMPLETION CODE                                              * 12900020
*EXTERNAL ROUTINES:                                                   * 13000020
*        IEAQSY50                                                     * 13100020
*        IGC079                                                       * 13200020
*        IHJTSI00                                                     * 13300020
*EXIT-NORMAL: RETURN TO SVC INTERRUPT HANDLER(R15=0)                  * 13400020
*EXIT-ERROR:  RETURN TO SVC INTERRUPT HANDLER(R15=4) IF TCAM IS       * 13500020
*             NOT ACTIVE                                              * 13600020
*TABLES/WORKAREAS:                                                    * 13700020
*   CVT                                                               * 13800020
*   AVT                                                               * 13900020
*   TCB                                                               * 14000020
*   DEB                                                               * 14100020
*ATTRIBUTES: REENTRANT, REFRESHABLE, SUPERVISOR MODE                  * 14200020
*NOTES: THIS ROUTINE IS A RESIDENT TYPE 1 SVC FOR USE ONLY BY TCAM.   * 14300020
*   THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL             * 14400020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 14500020
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED   * 14600020
*   SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,     * 14700020
*   WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.          * 14800020
*********************************************************************** 14900020
         EJECT                                                          15000020
         SPACE 2                                                        15100020
         ENTRY IGC102                                                   15200020
         SPACE 2                                                        15300020
*                                                                     * 15400020
*            S Y M B O L I C   R E G I S T E R S                      * 15500020
*                                                                     * 15600020
         SPACE 2                                                        15700020
RZERO    EQU   0                                                        15800020
RPARM    EQU   1                        PARAMETER LIST REGISTER         15900020
RELEM    EQU   2                        ELEMENT TO BE POSTED TO         16000020
*                                       DISABLED READY QUEUE            16100020
RCVT     EQU   3                        COMM. VECTOR TABLE              16200020
RTCB     EQU   4                        TASK CONTROL BLOCK              16300020
RMOVE    EQU   5                        GENERAL WORK REGISTER           16400020
RAVT     EQU   6                        ADDRESS VECTOR TABLE            16500020
RNUM     EQU   7                        BYTES-TO-MOVE COUNTER           16600020
RSAVE    EQU   8                        SAVE REGISTER           0Y00448 16700022
RWORK    EQU   9                        GENERAL WORK REGISTER           16800020
RCOMPC   EQU   10                       COMPLETION CODE                 16900020
RCECB    EQU   11                       COMPLEMENT OF ECB ADDRESS       17000020
RBASE    EQU   12                       CSECT BASE REGISTER             17100020
RTJID    EQU   13                       TSO JOB IDENTIFIER              17200020
RETURN   EQU   14                       RETURN ADDRESS                  17300020
RENTRY   EQU   15                       ENTRY POINT ADDRESS             17400020
         SPACE 2                                                        17500020
IGC102   DS    0D                       DOUBLE-WORD BOUNDARY            17600020
         BALR  RBASE,RZERO              ESTABLISH                       17700020
         USING *,RBASE                            ADDRESSABILITY        17800020
         USING IEDQAVTD,RAVT            ADDRESS VECTOR TABLE(AVT)       17900020
*                                       ADDRESSABILITY                  18000020
         USING IEDQTCB,RTCB             TASK CONTROL BLOCK              18100020
*                                       ADDRESSABILITY                  18200020
         USING IEDQRECB,RELEM           ELEMENT CONTROL BLOCK           18300020
         EJECT                                                          18400020
         L     RAVT,AVTCVTPT(0,RCVT)    ADDRESS OF ADDRESS VECTOR       18500020
*                                       TABLE FROM COMMUNICATION        18600020
*                                       VECTOR TABLE(CVT)               18700020
         LTR   RAVT,RAVT                MESSAGE CONTROL PROGRAM         19000020
*                                       CURRENTLY ACTIVE                19100020
         BNZ   START                    BRANCH IF YES                   19200020
         SPACE                                                          19300020
         LA    RENTRY,NOTCAM            SET ERROR RETURN CODE           19400020
EXIT     EQU   *                                                        19500020
         BR    RETURN                   RETURN TO CALLER                19600020
USERINV  EQU   *                                                        19700020
         LA    RENTRY,EQ8               INVALID AQCTL USER              19800020
         LTR   RETURN,RETURN            FIRST TIME THROUGH       A42362 19802021
         BZ    SETBACK                  BRANCH IF NO             A42362 19804021
         L     RWORK,4(,RWORK)          CURRENT TCB ADDRESS      A42362 19806021
         LA    RWORK,TCBOTC-4-IEDQTCB(,RWORK) ATTACHING TCB ADDR A42362 19808021
         SR    RETURN,RETURN            SET FIRST-TIME SWITCH    A42362 19808421
         NC    5(3,RWORK),5(RWORK)      ATTACHER ADDRESS VALID   A42362 19808821
         BNZ   TESTTCB                  BRANCH IF YES            A42362 19809221
SETBACK  EQU   *                                                        19810020
         L     RTCB,AVTTCB              TCAM MCP TCB ADDRESS            19820020
         NI    TCBNDSP1,AVTEFF-TCBTPSP  SET TCAM DISPATCHABLE           19830020
         NC    TCBNDSP1(3),TCBNDSP1     IS TCAM NONDISPATCHABLE         19840020
         BNZ   SKIP                     BRANCH IF NO                    19842020
         NI    TCBFLGS+4,AVTEFF-TCBPNDSP SET TCAM DISPATCHABLE          19844020
SKIP     EQU   *                                                        19846020
         LR    RETURN,RSAVE             RESTORE RETURN ADDRESS  0Y00448 19850022
         BR    RETURN                                                   19900020
         DC    C'IGC102'                                                19920020
         DC    X'1319'                  MODIFICATION DATE        CLUP21 19940021
         DS    0H                                                       19960020
         EJECT                                                          20000020
START    EQU   *                                                        20100020
         L     RAVT,0(0,RAVT)           GET ADDRESS OF AVT FROM         20130020
*                                       DISPATCHER LOAD LIST            20160020
         LR    RSAVE,RETURN             SAVE RETURN ADDRESS     0Y00448 20200022
         CLI   0(RPARM),TSOACTN      ENTRY FOR TSO CLEANUP       A44022 20250030
         BE    ENQTST               BRANCH IF YES                A44022 20260030
*                                                                     * 20300020
*        VERIFY THAT REQUESTOR IS EITHER TCAM MCP OR TCAM APPL PROG   * 20400020
*                                                                     * 20500020
         TM    0(RPARM),ABEND           CALLED DUE TO CLOSE FAILURE     20530020
         BO    PCBSCAN                  BRANCH IF YES                   20560020
         L     RWORK,0(0,RCVT)          ADDR OF ADDR OF CURRENT TCB     20600020
TESTTCB  EQU   *                                                 A42362 20650021
         CLC   5(3,RWORK),AVTTCB+1      IS REQUESTOR TCAM MCP           20700020
         BE    NOTMP                    BRANCH IF YES                   20800020
         L     RNUM,AVTPCBPT            PCB ADDRESS                     20900020
PCBLOOP  EQU   *                                                        21000020
         LA    RNUM,0(0,RNUM)           CLEAR HIGH-ORDER BYTE           21100020
         LTR   RNUM,RNUM                END OF PCB CHAIN                21200020
         BZ    ATTCB                                                    21300020
         CLC   PCBTCBAD+1-IEDQPCB(3,RNUM),5(RWORK) VALID APPL PROG      21400020
         BE    USEROK                   BRANCH IF YES                   21500020
         L     RNUM,PCBLINK-1-IEDQPCB(RNUM) ADDRESS OF NEXT PCB         21600020
         B     PCBLOOP                  GO CHECK THIS PCB               21700020
         SPACE 2                                                        21800020
ATTCB    EQU   *                                                        21900020
*                                                                     * 22000020
*                                                                     * 22100020
*        CHECK FOR ATTACHED TCAM SUBTASKS THAT ARE NOT APPL PROGS     * 22200020
         CLC   5(3,RWORK),AVTCKTCB+1    CHECKPOINT                      22300020
         BE    USEROK                   BRANCH IF YES                   22400020
         CLC   5(3,RWORK),AVTOCTCB+1    OPERATOR CONTROL                22500020
         BE    USEROK                   BRANCH IF YES                   22600020
         CLC   5(3,RWORK),AVTOLTCB+1    ON-LINE TEST                    22700020
         BE    USEROK                   BRANCH IF YES                   22800020
         CLC   5(3,RWORK),AVTCWTCB+1    COMMON WRITE(FE)                22900020
         BE    USEROK                   BRANCH IF YES                   22910020
*                                                                     * 22920020
*            TEST FOR DAUGHTER TASK OF ON-LINE TEST SUBTASK           * 22930020
*                                                                     * 22940020
         L     RTCB,AVTOLTCB            ONLINE TEST TCB                 22950020
         LA    RTCB,0(0,RTCB)           CLEAR HIGH-ORDER BYTE           22960020
         LTR   RTCB,RTCB                ONLINE TEST ACTIVE              22970020
         BZ    USERINV                  BRANCH IF NO                    22980020
         L     RTCB,TCBLTC              FIRST DAUGHTER TCB              22990020
TCBLOOP  EQU   *                                                        23000020
         LA    RTCB,0(0,RTCB)           CLEAR HIGH-ORDER BYTE           23010020
         C     RTCB,4(0,RWORK)          VALID TCB                       23020020
         BE    USEROK                   BRANCH IF YES                   23030020
         LTR   RTCB,RTCB                END OF SUBTASK CHAIN            23040020
         BZ    USERINV                  BRANCH IF YES                   23050020
         L     RTCB,TCBNTC              NEXT TCB                        23060020
         B     TCBLOOP                  CONTINUE TO SCAN CHAIN          23070020
         SPACE                                                          23100020
         EJECT                                                          23200020
USEROK   EQU   *                                                        23300020
*                                                                     * 23400020
*     RPARM IS POINTING TO A VARIABLE-LENGTH PARAMETER LIST           * 23500020
*                                                                     * 23600020
*         HANDLE MP65 INTERFACE SITUATION NOW                           23609020
         L     RTJID,AVTCVTMP(0,RCVT)   ADDRESS OF MP CVT               23618020
         LTR   RTJID,RTJID              MULTIPROCESSOR ACTIVE           23627020
         BZ    NOTMP                    BRANCH IF NO                    23636020
         L     RTCB,AVTTCB              TCAM TCB ADDRESS                23645020
         OI    TCBNDSP1,TCBTPSP         SET TCAM NONDISPATCHABLE        23654020
         OI    TCBFLGS+4,TCBPNDSP       SET TCAM NONDISPATCHABLE        23656020
         L     RENTRY,AVTMPTRR(0,RTJID) GET ADDRESS OF TASK             23663020
*                                       REMOVAL ROUTINE FROM MP CVT     23672020
         BALR  RETURN,RENTRY                                            23681020
NOTMP    EQU   *                                                        23690020
         SPACE                                                          23700020
         TM    0(RPARM),POST            POST REQUEST(NON-RORI)          23800020
         BNO   RORITST                  BRANCH IF NO                    23900020
*                                                                     * 24000020
*       PREPARE TO INTERFACE WITH SYSTEM POST ROUTINE                 * 24100020
*                                                                     * 24200020
         L     RTJID,4(0,RPARM)         GET ADDRESS OF TJID FROM        24300020
*                                       SECOND WORD OF PARM LIST        24400020
         LH    RTJID,0(0,RTJID)         PUT TJID IN LOW-ORDER           24500020
*                                       HALF OF REGISTER                24600020
POSTER   EQU   *                                                        24700020
         L     RCECB,0(0,RPARM)         GET ADDRESS OF ECB TO BE        24800020
*                                       POSTED COMPLETE FROM LIST       24900020
         LA    RCECB,0(0,RCECB)         CLEAR HIGH-ORDER BYTE           25000020
         BAL   RETURN,ECBVALID          TEST FOR ECB VALIDITY           25100020
         LA    RCECB,0(,RCECB)          CLEAR HIGH-ORDER BYTE FORCLUP21 25200021
         O     RCECB,HION               SET INTERPARTITION POST  CLUP21 25250021
*                                       CROSS-PARTITION POST            25300020
         SR    RCOMPC,RCOMPC            SET COMPLETION CODE             25400020
*                                       REGISTER TO ZERO                25500020
         SLL   RTJID,C16                CLEAR HIGH-ORDER HALF OF        25600020
         SRL   RTJID,C16                REGISTER TO ZERO                25700020
         L     RENTRY,POSTNTRY(0,RCVT)  ADDRESS OF BRANCH ENTRY         25800020
*                                       TO POST ROUTINE                 25900020
         LR    RELEM,RBASE              SAVE BASE REGISTER              26000020
         CLC   9(3,RPARM),FF            HAS ABEND FAILED FOR TASK       26010020
         BE    NORMAL                   BRANCH IF YES                   26020020
         L     RBASE,8(0,RPARM)         TCB ADDRESS                     26050020
         BALR  RETURN,RENTRY            POST ECB COMPLETE               26100020
         LR    RBASE,RELEM              RESTORE BASE REGISTER           26200020
         L     RTJID,4(0,RPARM)         RESTORE TJID ADDRESS            26300020
         TM    0(RPARM),SWAP            NEED TO FLAG TCB SWAPPABLE      26400020
         BO    TSOPOST                  BRANCH IF YES                   26500020
         TM    0(RPARM),RORI            NEED TO FLAG TCB ROLLOUTABLE    26600020
         BO    ROUTTST                  BRANCH IF YES                   26700020
NORMAL   EQU   *                                                        26800020
         SR    RENTRY,RENTRY            NORMAL COMPLETION CODE          27000020
         EJECT                                                          27100020
         B     SETBACK                                                  27200020
RORITST  EQU   *                                                        27300020
         SPACE                                                          27400020
         TM    0(RPARM),RORI            ONLY A RORI ECB TO POST         27500020
         BNO   MOVE                     BRANCH IF NO                    27600020
*                                                                     * 27700020
*      RPARM POINTS TO A THREE-WORD PARAMETER LIST:                   * 27800020
*         1. ADDRESS OF EVENT CONTROL BLOCK(ECB)                      * 27900020
*         2. ADDRESS OF TASK CONTROL BLOCK(TCB)                       * 28000020
*         3. ADDRESS OF DATA EXTENT BLOCK(DEB)                        * 28100020
*                                                                     * 28200020
         SPACE                                                          28300020
         L     RTCB,4(0,RPARM)          GET ADDRESS OF TCB FOR          28400020
*                                       TASK TO BE POSTED FROM          28500020
*                                       SECOND WORD OF PARM LIST        28600020
         TM    TCBFLGS+4,ROFLG          IS TASK ROLLED OUT              28700020
         BO    POSTPEND                 BRANCH IF YES                   28800020
PREPOST  EQU   *                                                        28900020
         SR    RTJID,RTJID              PUT DEFAULT TJID IN REG         29000020
         B     POSTER                   GO POST ECB COMPLETE            29100020
         SPACE                                                          29200020
POSTPEND EQU   *                                                        29300020
         OI    TCBFLTRN,TCBTCPP         SET POST-PENDING FLAG IN TCB    29400020
*                                       IN TCB                          29500020
         USING IEDQDEB,RENTRY           DATA EXTENT BLOCK       0Y00448 29600022
*                                       ADDRESSABILITY                  29700020
         CLI   4(RPARM),X'80'           CQTAM INTERFACE                 29800020
         BE    ROUTTST                  BRANCH IF YES                   29900020
         L     RENTRY,EIGHT(,RPARM)     GET ADDRESS OF DEB FROM 0Y00448 30000022
*                                       THIRD WORD OF PARM LIST         30100020
         MVI   DEBTAMPP,PPFLG           INDICATE A PENDING POST         30200020
*                                       FOR ECB RELATED TO THIS         30300020
*                                       DEB-THE PROCESS ENTRY           30400020
*                                       POINTS TO THE ECB               30500020
ROUTTST  EQU   *                                                        30600020
         TM    0(RPARM),ROUT            NEED TO FLAG TCB ROLLOUTABLE    30700020
         BNO   NORMAL                   BRANCH IF NO TO RETURN          30800020
*                                       TO SVC INTERRUPT HANDLER        30900020
         MVI   4(RPARM),X'80'           SET STATUS FLAG                 31000020
         SR    RZERO,RZERO                                              31100020
         L     RPARM,4(0,RPARM)         TCB ADDRESS AND FLAG            31200020
         L     RENTRY,STATUSAD          SET STATUS ROUTINE ADDRESS      31300020
         BALR  RETURN,RENTRY            FLAG TCB ROLLOUTABLE            31400020
         B     NORMAL                   PREPARE TO RETURN               31500020
         EJECT                                                          31600020
*                                       ROLLOUT                         31700020
MOVE     EQU   *                                                        31800020
         TM    0(RPARM),MOVEFLG         DATA TO BE MOVED                31900020
         BNO   TSOPOST                  BRANCH IF NO                    32000020
*                                                                     * 32100020
*      RPARM POINTS TO A THREE-WORD PARAMETER LIST:                   * 32200020
*         1. ADDRESS OF DATA TO BE MOVED.                             * 32300020
*         2. ADDRESS OF TARGET FIELD OF THE MOVE.                     * 32400020
*         3. ADDRESS OF FIELD CONTAINING LENGTH OF DATA FIELD.        * 32500020
*                                                                     * 32600020
         SPACE                                                          32700020
         CLC   1(3,RPARM),5(RPARM)      TARGET AND FIELD THE SAME       32800020
         BE    ENQTST                   BRANCH IF YES TO BYPASS MOVE    32900020
         L     RNUM,8(0,RPARM)          ADDRESS OF BYTE COUNT           33000020
         LR    RZERO,RMOVE                                              33100020
         LH    RNUM,0(0,RNUM)           GET BYTE COUNT                  33200020
         L     RWORK,4(0,RPARM)         ADDRESS OF TARGET OF MOVE       33300020
         L     RMOVE,0(0,RPARM)         ADDRESS OF FIELD TO MOVE        33400020
         SPACE 2                                                        33500020
LOOP     EQU   *                                                        33600020
         C     RNUM,MAX                 NEED TO USE MOVE LOOP           33700020
         BNH   LAST                     BRANCH IF LOOP NOT REQUIRED     33800020
         SH    RNUM,MAXIM               DECREMENT TOTAL NUMBER OF       33900020
*                                       BYTES TO BE MOVED BY 255        34000020
         MVC   0(MAXI,RWORK),0(RMOVE)   DO MAXINUM DATA TRANSFER        34100020
         LA    RWORK,MAXI(RWORK)        BUMP TARGET WORK AREA           34200020
*                                       POINTER BY 255                  34300020
         LA    RMOVE,MAXI(RMOVE)        BUMP POINTER TO DATA TO BE      34400020
*                                       MOVED BY 255                    34500020
         B     LOOP                     GO MOVE DATA                    34600020
LAST     EQU   *                                                        34700020
         LTR   RNUM,RNUM                ALL DATA MOVED                  34800020
         BZ    ENQTST                   BRANCH IF YES                   34900020
         BCTR  RNUM,RZERO               DECREMENT NO. OF BYTES BY ONE   35000020
         EX    RNUM,MOVER               MOVE NUMBER OF BYTES IN RNUM    35100020
         LR    RMOVE,RZERO                                              35200020
         EJECT                                                          35300020
ENQTST   EQU   *                                                        35400020
         TM    0(RPARM),ENQFLG          ELEMENT JUST MOVED TO BE        35500020
*                                       POSTED TO READY QUEUE           35600020
         BNO   NORMAL                   BRANCH IF NO TO EXIT            35700020
*                                                                       35800020
*        POST ELEMENT TO DISABLED READY QUEUE(TWO-WORD FIFO)          * 35900020
*                                                                       36000020
         NC    AVTREADD+1(2),AVTREADD+1 DISABLED READY QUEUE EMPTY      36100020
         BNZ   ENQ                      BRANCH IF NO                    36200020
         L     RELEM,4(0,RPARM)         ADDR OF ELEMENT TO ENQUEUE      36300020
         ST    RELEM,AVTREADD           PUT ELEMENT ON TWO-WORD         36400020
*                                       DISABLED READY QUEUE            36500020
         B     QPOST                    GO POST MCP'S ECB COMPLETE      36600020
         SPACE 2                                                        36700020
ENQ      EQU   *                                                        36800020
         L     RELEM,AVTREADD+4         ADDRESS OF LAST ELEMENT ON      36900020
*                                       DISABLED READY QUEUE            37000020
         MVC   RECBLINK(3),5(RPARM)     LINK NEW ELEMENT TO LAST        37100020
         L     RELEM,4(0,RPARM)         ADDRESS OF NEW ELEMENT          37200020
QPOST    EQU   *                                                        37300020
         ST    RELEM,AVTREADD+4         UPDATE POINTER TO LAST          37400020
*                                       ELEMENT ON DISABLED R.Q.        37500020
         XC    RECBLINK(3),RECBLINK     SET LINK FIELD TO ZERO          37550020
         SPACE 2                                                        37600020
         LA    RCECB,AVTOSECB                                           37700020
         BAL   RETURN,ECBVALID          TEST FOR ECB VALIDITY           37800020
         LA    RCECB,0(,RCECB)          CLEAR HIGH-ORDER BYTE    CLUP21 37900021
         O     RCECB,HION               SET INTERPARTITION POST  CLUP21 37950021
         SR    RCOMPC,RCOMPC                                            38000020
         L     RENTRY,POSTNTRY(0,RCVT)  BRANCH ENTRY TO POST            38100020
         SR    RTJID,RTJID              PUT DEFAULT TJID IN REG         38200020
         LR    RELEM,RBASE              SAVE BASE REGISTER              38300020
         L     RTCB,AVTTCB              TCAM MCP TCB ADDRESS     A42413 38306021
         NI    TCBNDSP1,AVTEFF-TCBTPSP SET TCAM DISPATCHABLE     A42413 38312021
         NC    TCBNDSP1(3),TCBNDSP1     IS TCAM DISPATCHABLE     A42413 38318021
         BNZ   BYPASS                   NO,LEAVE PRIMARY DISP ON A42413 38324021
         NI    TCBFLGS+4,AVTEFF-TCBPNDSP SET TCAM DISPATCHABLE          38330021
BYPASS   EQU   *                                                 A42413 38336021
         SR    RCOMPC,RCOMPC            CLEAR REGISTER 10        A42413 38342021
         L     RBASE,AVTTCB             MCP TCB ADDRESS                 38350020
         BALR  RETURN,RENTRY            POST ECB COMPLETE               38400020
         LR    RBASE,RELEM              RESTORE BASE REGISTER           38500020
         EJECT                                                          38600020
TSOTST   EQU   *                                                        38700020
         TM    0(RPARM),TSOFLG          TCB TO BE FLAGGED AS            38800020
*                                       NON-SWAPPABLE                   38900020
         BNO   NORORI                   BRANCH IF NO                    39000020
TSOTCB   EQU   *                                                        39100020
*                                                                       39200020
*      PREPARE INTERFACE WITH TSO SERVICE ROUTINE                       39300020
*                                                                       39400020
         L     RENTRY,CVTTSCVT(0,RCVT)  GET ADDRESS OF TSO CVT          39500020
*                                       EXTENSION FROM CVT              39600020
         LTR   RENTRY,RENTRY            TSO IN SYSTEM                   39700020
         BNZ   TSO                      BRANCH IF YES                   39800020
         LA    RENTRY,NOTSO             SET ERROR RETURN CODE           39900020
         B     SETBACK                                                  40000020
         SPACE 2                                                        40200020
TSO      EQU   *                                                        40300020
         L     RENTRY,TSCVTTSI(0,RENTRY) GET ADDRESS OF TSIP            40400020
         L     RTJID,0(0,RCVT)          ADDR OF CURRENT TCB ADDRESS     40450020
         L     RTJID,4(0,RTJID)         CURRENT TCB ADDRESS             40500020
         L     RTJID,TCBJSCB(0,RTJID)   JOB STEP CONTROL BLOCK          40550020
         LH    RTJID,JSCBTJID(0,RTJID)  TSO TJID                        40620020
         TSEVENT DONTSWAP,TJID=(RTJID),ENTRY=BRANCH                     40700020
         B     NORMAL                   RETURN TO CALLER                40800020
         EJECT                                                          40900020
NORORI   EQU   *                                                        41000020
         TM    0(RPARM),RORIFLG         NON-ROLLOUTABLE REQUEST         41100020
         BNO   NORMAL                   IF NO, PREPARE TO RETURN        41200020
         SR    RZERO,RZERO              STATUS ROUTINE PARM             41300020
         SR    RPARM,RPARM              STATUS ROUTINE PARM             41400020
         L     RENTRY,STATUSAD          SET STATUS ROUTINE ADDRESS      41500020
         BALR  RETURN,RENTRY            FLAG TCB NON-ROLLOUTABLE        41600020
         B     NORMAL                   RETURN TO CALLER                41700020
         SPACE 4                                                        41800020
ECBVALID EQU   *                                                        41900020
*                                                                     * 42000020
*        CHECK ECB VALIDITY                                           * 42100020
*                                                                     * 42200020
         LA    RENTRY,EQ8               ERROR RETURN CODE        CLUP21 42250021
         LR    RWORK,RCECB              SET UP ECB ADDRESS              42300020
         SLL   RWORK,30                 CLEAR ALL BUT TWO HIGH-         42400020
*                                       ORDER BITS                      42500020
         LTR   RWORK,RWORK              FULLWORD BOUNDARY               42600020
         BNZ   SETBACK                  BRANCH IF NO             CLUP21 42700021
         LR    RWORK,RCECB                                              42800020
         LA    RWORK,0(0,RCECB)         CLEAR HIGH-ORDER BYTE           42900020
         C     RWORK,MAXAD(0,RCVT)      VALID MACHINE ADDRESS           43000020
         BNL   SETBACK                  BRANCH OUT IF NO         CLUP21 43100021
DUMSTAT  EQU   *                                                        43150020
         BR    RETURN                   RETURN TO MAINLINE CODE         43200020
         EJECT                                                          43300020
TSOPOST  EQU   *                                                        43400020
*                                                                       43500020
*        RPARM POINTS TO A THREE-WORD PARAMETER LIST:                   43600020
*         1. ADDRESS OF ECB TO BE POSTED.                               43700020
*         2. ADDRESS OF TSO JOB IDENTIFIER.                             43800020
*         3. ADDRESS OF TCB.                                            43900020
*                                                                       44000020
         SPACE 2                                                        44100020
*                                                                       44200020
*      PREPARE INTERFACE WITH TSO ROUTINE TO FLAG TCB SWAPPABLE         44300020
*                                                                       44400020
         L     RENTRY,CVTTSCVT(0,RCVT)  GET ADDRESS OF TSO CVT          44500020
*                                       EXTENSION FROM CVT              44600020
         LTR   RENTRY,RENTRY            TSO IN SYSTEM                   44700020
         BNZ   TSOX                     BRANCH IF YES                   44800020
         LA    RENTRY,NOTSO             SET ERROR RETURN CODE           44900020
         B     SETBACK                                                  45000020
TSOX     EQU   *                                                        45200020
         L     RENTRY,TSCVTTSI(0,RENTRY) GET ADDRESS OF TSIP            45300020
         L     RTJID,4(0,RPARM)         TJID ADDRESS                    45400020
         LH    RTJID,0(0,RTJID)         TJID                            45500020
         TSEVENT OKSWAP,TJID=(RTJID),ENTRY=BRANCH                       45600020
         B     NORMAL                                                   45700020
         EJECT                                                          45800020
         SPACE                                                          45900020
PCBSCAN  EQU   *                                                        45902020
*                                                                     * 45904020
*              SCAN PCB CHAIN FOR CORRESPONDING TJID(TSO) OR TCB      * 45906020
*              ADDRESS.  SET CORRESPONDING TASK NONDISPATCHABLE BY    * 45908020
*              TCAM BY REPLACING TCB ADDRESS IN PCB WITH X'FFFFFF'.   * 45910020
*                                                                     * 45912020
         SPACE 2                                                        45914020
         L     RNUM,AVTPCBPT            HEAD OF PCB CHAIN               45916020
PLOOP    EQU   *                                                        45918020
         LA    RNUM,0(0,RNUM)           CLEAR HIGH-ORDER BYTE           45920020
         LTR   RNUM,RNUM                END OF PCB CHAIN                45922020
         BZ    NORMAL                   EXIT IF YES                     45924020
         CLC   2(2,RPARM),AVTFZERO      VALID TJID                      45926020
         BNE   TJIDTEST                 BRANCH IF YES                   45928020
         CLC   5(3,RPARM),PCBTCBAD+1-IEDQPCB(RNUM) IS THIS THE TCB      45930020
*                                       FOR AN ACTIVE APPL PROG         45932020
         BE    SETTCB                   BRANCH IF YES                   45934020
         SPACE                                                          45936020
NEXTPCB  EQU   *                                                        45938020
         L     RNUM,PCBLINK-1-IEDQPCB(0,RNUM) ADDRESS OF NEXT PCB       45940020
         B     PLOOP                    GO CHECK THIS PCB               45942020
         SPACE                                                          45944020
TJIDTEST EQU   *                                                        45946020
         CLC   2(2,RPARM),PCBTJID-IEDQPCB(RNUM) IS THIS THE TJID        45948020
*                                       FOR AN ACTIVE APPL PROG         45950020
         BNE   NEXTPCB                  BRANCH IF NO                    45952020
         SPACE                                                          45954020
SETTCB   EQU   *                                                        45956020
         CLI   PCBUCNT-IEDQPCB(RNUM),AVTEZERO ALL DCBS CLOSED           45958020
         BE    NORMAL                   BRANCH TO EXIT IF YES           45960020
         MVC   PCBTCBAD+1-IEDQPCB(3,RNUM),FF INVALIDATE TCB ADDRESS     45962020
         B     NORMAL                   RETURN TO ABEND HANDLER         45964020
         EJECT                                                          45966020
*                                                                     * 46000020
*                  C O N S T A N T S   A N D   E Q U A T E S          * 46100020
*                                                                     * 46200020
MOVER    DS    0H                       HALFWORD BOUNDARY               46300020
         MVC   0(1,RWORK),0(RMOVE)      MOVE DATA ACROSS PARTITION      46400020
*                                       BOUNDARY                        46500020
MAXIM    DC    H'256'                                                   46600020
MAX      DC    F'255'                   MAXIMUN NUMBER OF BYTES THAT    46700020
*                                       CAN BE MOVED VIA MVC            46800020
HION     DS    0F                       BOUNDARY ALINEMENT       CLUP21 46850021
         DC    X'80'                                             CLUP21 46860021
         DC    AL3(0)                                            CLUP21 46870021
POSTNTRY EQU   152                      OFFSET INTO CVT OF BRANCH       46900020
*                                       ENTRY-POINT TO POST             47000020
STATUSAD DC    A(DUMSTAT)               SET STATUS ROUTINE ADDRESS      47060020
*                                       RESERVED FOR LATER              47120020
CVTTSCVT EQU   X'E4'                    TSO CVT ADDRESS OFFSET          47210020
ROUT     EQU   X'01'                                                    47300020
TSCVTTSI EQU   48                       DISPLACEMENT IN TSO CVT         47400020
*                                       OF ADDRESS OF TSIP              47500020
TSOFLG   EQU   X'10'                    FLAG TASK NON-SWAPPABLE         47600020
RDISP    EQU   11                                                       47700020
EIGHT    EQU   8                        CONSTANT                0Y00448 47800022
ENQFLG   EQU   X'04'                    FLAG INDICATING THAT ELEM       47900020
*                                       IS TO BE POSTED TO DISABLED     48000020
*                                       READY QUEUE AND THAT MCP        48100020
*                                       ECB IS TO BE POSTED             48200020
*                                       TO READY QUEUE                  48300020
SWAP     EQU   X'02'                    SET-TCB-SWAPPABLE FLAG          48400020
NOTCAM   EQU   4                        RETURN CODE INDICATING          48500020
*                                       TCAM MCP NOT ACTIVE             48600020
POST     EQU   X'20'                    POST QNLY INDICATOR USED        48700020
*                                       FOR TSO AND NON-RORI            48800020
*                                       APPLICATION PROGRAMS            48900020
C16      EQU   16                                                       49000020
PPFLG    EQU   X'EE'                                                    49100020
POSTFLG  EQU   X'01'                    MCP ECB TO-BE-POSTED FLAG       49200020
MOVEFLG  EQU   X'08'                                                    49300020
ROFLG    EQU   X'08'                    TASK ROLLED OUT FLAG            49400020
MAXI     EQU   256                                                      49500020
RORIFLG  EQU   X'80'                                                    49600020
NOTSO    EQU   8                                                        49700020
RORI     EQU   X'40'                    AQCTL ACTION CODE               49800020
MAXAD    EQU   X'A4'                    CVT OFFSET TO MAXIMUM           49900020
*                                       MACHINE ADDRESS                 50000020
EQ8      EQU   8                        INVALID USER OR ECB ADDRESS     50100020
FF       DC    X'FFFFFF'                                                50110020
ABEND    EQU   X'FF'                                                    50120020
TCBJSCB  EQU   X'B4'                    JOB STEP CONTROL BLOCK          50130020
JSCBTJID EQU   X'10C'                   TJID OFFSET IN JSCB             50140020
         PRINT NOGEN                                                    50150020
TSOACTN  EQU   X'64'      TSO CLEANUP CODE                       A44022 50160030
PAD      DC    25H'0'                   SUPERZAP PADDING                50200020
ZERO     EQU   0                                                 A42413 50250021
         EJECT                                                          50300020
*                                                                     * 50400020
*                 D S E C T S                                         * 50500020
*                                                                     * 50600020
         SPACE 2                                                        50700020
         TAVTD                                                          50800020
         TTCBD                                                          50900020
         TDEBAPD                                                        51000020
         TRECBD                                                         51100020
         TPCBD                                                          51200020
         END                                                            51300020
