EC01     TITLE '''IEDQEC'' - TCAM PUT SCHEDULER'                        00100020
         SPACE 1                                                        00150022
IEDQEC   CSECT                                                          00200020
         SPACE 3                                                        00200322
******************** MICROFICHE FLAGS *********************** SUPT CODE 00200622
*C186000,191000,327000,360000,460000,                            S21903 00200704
*C474000,505000,510000,550000,624000                             S21903 00200804
*C340000                                                        SA52991 00201022
*A314000,345000,630000                                          SA52991 00201122
*A250200                                                        SA52508 00201222
*C081200                                                        SA52508 00201322
*A420000                                                         A44891 00201422
*D422700,431000-437000,570000                                    A44891 00201522
*C409000                                                         A44891 00201622
*C081400,655950                                                  A42404 00201722
*C081200                                                         S22025 00201822
*A126000,592000                                                  A48279 00201922
*C081400                                                         A48279 00202022
*D656000                                                         A48279 00202122
*A109000,541000,549000,564000                                   SA51096 00202222
*C523000,524000                                                  S21903 00202322
*A564500                                                        SA57699 00202422
*D564000                                                        SA57699 00202522
*C122000                                                        SA59182 00202622
*A240000,247000                                                  S22024 00202722
*A497500                                                        SA58449 00202800
*A549000,564000                                                 SA50196 00202900
*C110000                                                        SA50196 00203000
*C006000                                                         S21903 00203100
*A126300                                                        SA59526 00203200
*           CLEAN-UP                                            S21903  00203305
*A389000                                                        OY00458 00203405
*C122000                                                        SA66354 00233453
*A292600                                                        OX02215 00263453
*C 587000-588000                                                SA69971 00263555
*A 655990                                                       SA69971 00263655
         SPACE 4                                                        00300020
*********************************************************************** 00400020
*                                                                     * 00500020
*TITLE: 'IEDQEC' PUT SCHEDULER                                        * 00600020
*                                                                     * 00610000
*  MODULE NAME = IEDQEC                                               * 00620000
*                                                                     * 00630000
*  DESCRIPTIVE NAME = PUT SCHEDULER                                   * 00640000
*                                                                     * 00650000
*  COPYRIGHT = 'NONE'                                                 * 00660000
*                                                                     * 00670000
*  STATUS:  CHANGE LEVEL 5                                            * 00680000
*                                                                     * 00690000
*FUNCTION: THIS ROUTINE MOVES DATA FROM THE USER'S WORKAREA IN AN     * 00700020
*   APPLICATION PROGRAM INTO MCP BUFFERS.  IT REQUESTS BUFFERS FROM   * 00800020
*   THE TCAM BUFFER POOL, FILLS THEM WITH DATA FROM THE USER'S WORK   * 00900020
*   AREA, AND POSTS THE FULL BUFFERS TO THE MH POINTED TO BY THE PCB. * 01000020
*                                                                     * 01100020
*   WHEN THE WORK AREA IS EMPTY, IT ISSUES AQCTL SVC TO POST THE      * 01200020
*   APPLICATION PROGRAM COMPLETE IF WAITING, SWAPPABLE IF NOT         * 01300020
*   SWAPPABLE(TSO ONLY), AND ROLLOUTABLE IF NOT ELIGIBLE FOR ROLLOUT. * 01400020
*                                                                     * 01500020
*   IF THE DCB INDICATES RECORD FORMAT W/O WORK AREA CONTENTS         * 01600020
*   DESCRIPTOR BYTE, THE CURRENT LAST FULL BUFFER IS SAVED.  CLOSE    * 01700020
*   POSTS THIS BUFFER TO THE MH, FLAGGING IT AS END OF MESSAGE.       * 01800020
*                                                                     * 01810020
*   THE PUT SCHEDULER IS ACTIVATED WHEN THE DISPATCHER POSTS ON OF    * 01820020
*   THE FOLLOWING ELEMENTS TO THE PUT SCHEDULER:                      * 01830020
*      1.  SPECIAL PUT ELEMENT FROM APPLICATION PROGRAM ROUTINE.      * 01840020
*      2.  ERB CONTAINING EMPTY BUFFERS.                              * 01850020
*      3.  LCB POSTED BY BUFFER DISPOSITION AT END-OF-MESSAGE TIME.   * 01860020
*                                                                     * 01870020
*ENTRY POINT:                                                         * 01900020
*        IEDQEC                                                       * 02000020
*INPUT:                                                               * 02100020
*   1  - ADDRESS OF ERB, LCB OR SPECIAL ELEMENT                       * 02200020
*   11 - ADDRESS OF DISPATCHER                                        * 02300020
*   13 - ADDRESS OF REGISTER SAVEAREA                                 * 02400020
*   15 - ENTRY POINT ADDRESS                                          * 02500020
*OUTPUT:                                                              * 02600020
*   1  - ADDRESS OF ERB OR BUFFER                                     * 02700020
*   11 - SEE 'INPUT'                                                  * 02800020
*   13 - SEE 'INPUT'                                                  * 02900020
*EXTERNAL ROUTINES:                                                   * 03000020
*        DISPATCHER-IGG019RB(DSPPOSTR)                                * 03100020
*EXITS-NORMAL:                                                        * 03200020
*        EXITS TO DISPATCHER(DSPCHAIN) TO POST ERB OR FULL BUFFER(S)  * 03300020
*EXITS-ERROR:                                                         * 03400020
*        NONE                                                         * 03500020
*TABLES/WORKAREAS:                                                    * 03600020
*        AVT                                                          * 03700020
*        LCB                                                          * 03800020
*        PROCESS ENTRY                                                * 03900020
*        PROCESS ENTRY WORKAREA                                       * 04000020
*        DEB                                                          * 04100020
*        PCB                                                          * 04200020
*        ACCESS METHOD WORKAREA                                       * 04300020
*        SCB                                                          * 04400020
*        QCB                                                          * 04500020
*        DCB                                                          * 04600020
*ATTRIBUTES:REENTRANT,REFRESHABLE                                     * 04700020
*                                                                       04800020
*NOTES: THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 04900020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 05000020
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED   * 05100020
*   SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,     * 05200020
*   WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.          * 05300020
*********************************************************************** 05400020
         EJECT                                                          05500020
         SPACE                                                          05600020
*                                                                     * 05700020
*           S Y M B O L I C    R E G I S T E R S                      * 05800020
*                                                                     * 05900020
         SPACE                                                          06000020
RZERO    EQU   0                        GENERAL WORK REGISTER           06100020
RPARM    EQU   1                        PARAMETER REGISTER              06200020
RCNT     EQU   2                        NUMBER OF BYTES IN BUFFER       06300020
RTEMP    EQU   3                        GENERAL WORK REGISTER           06400020
RNUM     EQU   4                        NUMBER OF BYTES TO BE MOVED     06500020
RUNIT    EQU   5                        ADDR OF CURRENT BUFFER UNIT     06600020
RWORK    EQU   6                        ADDRESS OF DATA IN WORKAREA     06700020
RBUF     EQU   7                        ADDR OF NEXT EMPTY BYTE         06800020
*                                       IN CURRENT BUFFER UNIT          06900020
RPEWA    EQU   8                        PROCESS ENTRY WORKAREA          07000020
RERB     EQU   9                        ELEMENT REQUEST BLOCK           07100020
RPWA     EQU   10                       PUT/WRITE WORKAREA              07200020
RDISP    EQU   11                       ADDRESS OF DISPATCHER           07300020
RBASE    EQU   12                       ADDRESS VECTOR TABLE            07400020
RAVT     EQU   13                       ADDRESS VECTOR TABLE(AVT)       07500020
RPCB     EQU   14                       PROCESS CONTROL BLOCK           07600020
RBFR     EQU   15                       ADDRESS OF BUFFER PREFIX        07700020
RETURN   EQU   14                       RETURN ADDRESS                  07800020
RENTRY   EQU   15                       ENTRY POINT ADDRESS             07900020
         BALR  RBASE,RZERO              ESTABLISH                       08000020
         USING *,RBASE                            ADDRESSABILITY        08100020
IEDQEC   IEDHJN LABEL                  LABEL AND DATE           SA52508 08120000
         EJECT                                                          08200020
*                                                                     * 08300020
*      C O N T R O L   B L O C K   A D D R E S S A B I L I T Y        * 08400020
*                                                                     * 08500020
         SPACE                                                          08600020
         USING IEDQAVTD,RAVT            TCAM ADDRESS VECTOR TABLE       08700020
         USING IEDQDISP,RDISP           TCAM DISPATCHER                 08800020
         USING IEDQPCB,RPCB             PROCESS CONTROL BLOCK (PCB)     08900020
         USING IEDQPEWA,RPEWA           PROCESS ENTRY WORKAREA (PEWA)   09000020
         USING IEDQWRKA,RPWA            PUT/WRITE WORKAREA (PWA)        09100020
         USING LCBERB,RERB              ELEMENT(EMPTY BUFFER)           09200020
*                                       REQUEST BLOCK(ERB)              09300020
         USING IEDQPRF,RBFR             BUFFER PREFIX                   09400020
         SPACE                                                          09500020
         CLI   LCBRSKEY-IEDQLCB(RPARM),PSVTO LCB                        09600020
         BE      CLEANUP                BRANCH IF YES                   09700020
         CLI   0(RPARM),ERBKEY          IS POSTED ELEMENT AN ERB        09800020
*                                       OR A SPECIAL ELEMENT            09900020
         BE    RESTORE                  BRANCH IF IT IS AN ERB          10000020
         L     RPWA,8(0,RPARM)          GET ADDRESS OF PUT/WRITE        10100020
*                                       WORKAREA FROM THIRD WORD        10200020
*                                       OF SPECIAL ELEMENT              10300020
         L     RPEWA,PWAPEWA            ADDRESS OF PROCESS ENTRY        10400020
*                                       WORKAREA FROM PUT/WRITE         10500020
*                                       WORKAREA                        10600020
         L     RPCB,PEPCBAD             ADDRESS OF PROCESS CONTROL      10700020
*                                       BLOCK FROM PROCESS ENTRY        10800020
*                                       WORKAREA                        10900020
         OI    PCBOFLG,PCBPIPN          SET PUT IN PROGRESS      A50196 11000022
         L     RWORK,PWASTART           ADDRESS OF DATA TO BE           11100020
*                                       MOVED FROM USER'S WORKAREA      11200020
         LH    RNUM,PWASOWA             NUMBER OF BYTES TO BE MOVED     11300020
         N     RNUM,AVTCLRHI            CLEAR HIGH-ORDER HALF           11400020
         LA    RERB,PEERB               ADDRESS OF ELEMENT REQUEST      11500020
*                                       BLOCK FROM PROCESS ENTRY        11600020
*                                       WORKAREA                        11700020
         EJECT                                                          11800020
         TM    PEWAFLG,PBUF             PART-EMPTY BUFFER TO FILL       11900020
         BO    SETUP                    BRANCH IF YES                   12000020
         CLC   PWASOWA(2),AVTFZERO      NO-DATA OPERATION               12100020
         BE    CLEANX                   BRANCH IF YES           SA66354 12200053
*                                                                     * 12220020
*   PICK UP AND POST BUFFER SAVED FROM LAST OPERATION.                * 12240020
*                                                                     * 12260020
         L     RPARM,PERAQCB            ADDR OF SAVED BUFFER            12300020
         LTR   RPARM,RPARM              BFR TO POST                     12400020
         BZ    NEXTBUFX                 BRANCH IF NO                    12500020
         XC    PERAQCB(4),PERAQCB       CLEAR ADDR OF PARTIAL MSG       12550020
         LR    RBFR,RPARM               SET PREFIX ADDRESS              12600020
         L     RTEMP,PRFLCB-1           GET LCB ADDRESS          A48279 12610022
         MVC   LCBTTCIN-IEDQLCB(2,RTEMP),PRFSRCE SET SOURCE      A48279 12620022
*                                         OFFSET                 A48279 12630022
         LA    RZERO,PEWASCB            SCB ADDRESS             SA59526 12636000
         ST    RZERO,LCBSCBA-1-IEDQLCB(,RTEMP) STORE IN LCB     SA59526 12642000
         B     NEXTBUF                  POST BFR AND CONTINUE           12650020
SETUP    EQU   *                                                        13200020
         NI    PEWAFLG,AVTEFF-PBUF      SET NOT PARTIAL BUFFER          13300020
         L     RBFR,PERAQCB             BUFFER PREFIX ADDRESS           13400020
         XC    PERAQCB(4),PERAQCB                                       13500020
         L     RBUF,PECBUF              ADDR OF FIRST EMPTY BYTE        13600020
         L     RPARM,PEWATIC            ADDR OF CURRENT UNIT            13700020
         LH    RCNT,PRFSIZE             INITIALIZE COUNTER              13800020
         L     RTEMP,PRFLCB-1           LCB ADDRESS                     13900020
*                                                                     * 13920020
*        INITIALIZE LCB FOR USE AFTER BUFFER ENTERS MESSAGE HANDLER   * 13940020
*                                                                     * 13960020
         LA    RZERO,PEWASCB                                            14000020
         ST    RZERO,LCBSCBDA-1-IEDQLCB(0,RTEMP) SCB DIRECTORY ADDR     14100020
         ST    RZERO,LCBSCBA-1-IEDQLCB(0,RTEMP)                         14200020
         MVI   LCBSTAT1-IEDQLCB(RTEMP),LCBRECVN SET RECIEVE SWITCH      14300020
         OI    LCBERBST-IEDQLCB(RTEMP),LCBDLNKN                         14400020
         MVI   LCBRSKEY-IEDQLCB(RTEMP),PSVTO PUT SCHEDULER MCPL         14500020
         MVC   LCBISZE-IEDQLCB(1,RTEMP),PCBRSERH RESERVE CNT TO LCB     14600020
         MVC   LCBTTCIN-IEDQLCB(2,RTEMP),PRFSRCE TNT OFFSET             14700020
         ST    RPEWA,LCBERCCW-IEDQLCB(RTEMP)                            14800020
         L     RZERO,PERAQCB+4          END OF THIS UNIT                14900020
         SR    RZERO,RBUF               NUMBER OF EMPTY BYTES LEFT      15000020
         CLC   PWASOWA(2),AVTFZERO      SPECIAL NO-DATA EOM CASE        15040020
         BNE   MOVE                     BRANCH IF NO                    15080020
         NI    PRFSTAT1,AVTEFF-PRFNLSTN FLAG BUFFER AS EOM              15120020
         B     POSTBUF                  POST BUFFER TO MH               15160020
         EJECT                                                          15200020
RESTORE  EQU   *                                                        15300020
         LM    RCNT,RBFR,PESAVE-PEERB(RPARM)                            15400020
*                                       RESTORE VALUES SAVED AS A       15500020
*                                       RESULT OF WORKAREA SIZE         15600020
*                                       EXCEEDING CAPACITY OF           15700020
*                                       NUMBER OF INITIAL BUFFERS       15800020
*                                       ALLOCATED                       15900020
         SPACE                                                          16000020
*                                                                     * 16100020
*   PERFORM INITIALIZATION NECESSARY TO EFFECT CROSS-PARTITION DATA   * 16200020
*  TRANSFER FROM THE USER'S WORKAREA TO MCP BUFFERS.                  * 16300020
*                                                                     * 16400020
         SPACE                                                          16500020
         L     RBFR,LCBERBCH-1          ADDRESS OF FIRST EMPTY          16600020
*                                       BUFFER IN ERB CHAIN             16700020
*                                                                     * 16800020
*              INITIALIZE BUFFER PREFIX                               * 16900020
*                                                                     * 17000020
BUFINIT  EQU   *                                                        17100020
         MVI   PRFSTAT1,PRFNHDRN                                        17200020
         SR    RCNT,RCNT                INIT PRFSIZE COUNTER            17300020
         MVI   PRFPRI,PRIAPBFR          SET BUFFER PRIORITY             17400020
         MVI   PRFTIC,TIC               SET UP TIC FIELD                17500020
         LA    RBUF,PRFSTXT             START OF TEXT LABEL             17600020
         C     RWORK,PWASTART           IS THIS THE BEGINNING OF        17700020
*                                       A NEW WORKAREA                  17800020
         BNE   GO                       BRANCH IF NOT TO AVOID          17900020
*                                       TESTING FOR HEADER              18000020
         MVI   PRFSTAT1,AVTEZERO        INIT BFR STATUS FIELD           18100020
         TM    PWACTL,HDR               HEADER SEGMENT IN WORKAREA      18200020
         BO    CLOSTST                  BRANCH IF YES                   18300020
         OI    PRFSTAT1,PRFNHDRN        SET NOT-HEADER FLAG IN          18400020
*                                       BUFFER PREFIX                   18500020
         B     GO                       BRANCH TO INITIALIZE LCB S21903 18600004
*                                       AND BUFFER PREFIX.       S21903 18650004
CLOSTST  EQU   *                                                        18700020
         TM    AVTBIT1,AVTCLOSN+AVTQUCKN CLOSEDOWN IN PROGRESS          18800020
         BNO   GO                       BRANCH IF NO                    18900020
         OI    PERCQCB+3,PBUF           SET ERROR FLAG                  19000020
         B     CLEANX                   BRANCH TO POST APPLIC    S21903 19100004
*                                       PGM ECB COMPLETE         S21903 19150004
         EJECT                                                          19200020
GO       EQU   *                                                        19300020
*                                                                     * 19320020
*        INITIALIZE LCB AND BUFFER PREFIX                             * 19340020
*                                                                     * 19360020
         MVC   PRFLCB(3),PCBLCBAD+1     PUT ADDRESS OF SOURCE LCB       19400020
*                                       INTO BUFFER PREFIX              19500020
         L     RPARM,PRFLCB-1           LCB ADDRESS                     19600020
         MVI   LCBSTAT1-IEDQLCB(RPARM),LCBRECVN SET RECIEVE SWITCH      19700020
         OI    LCBERBST-IEDQLCB(RPARM),LCBDLNKN                         19800020
         MVI   LCBRSKEY-IEDQLCB(RPARM),PSVTO PUT SCHEDULER MCPL         19900020
         MVC   LCBISZE-IEDQLCB(1,RPARM),PCBRSERH RESERVE CNT TO LCB     20000020
         LA    RZERO,PEWASCB            SOURCE SCB ADDRESS              20100020
         ST    RZERO,LCBSCBA-1-IEDQLCB(RPARM) STORE IT IN LCB           20200020
         ST    RZERO,LCBSCBDA-1-IEDQLCB(0,RPARM)                        20300020
         ST    RPEWA,LCBERCCW-IEDQLCB(RPARM) SAVE PEWA ADDRESS          20400020
         L     RPARM,PEWADEB            ADDRESS OF DATA EXTENT          20500020
*                                       BLOCK                           20600020
         MVC   PRFQCBA(3),PCBMH         ADDRESS OF MESSAGE HANDLER      20700020
*                                       TO PROCESS THIS BUFFER          20800020
         MVC   PRFSRCE(2),DEBTAMOS-IEDQDEB(RPARM)                       20900020
*                                       MOVE TERMNAME TABLE OFFSET      21000020
*                                       OF PUT PROCESS ENTRY INTO       21100020
*                                       SOURCE FIELD IN BFR PREFIX      21200020
         L     RPARM,PRFLCB-1           LCB ADDRESS                     21300020
         MVC   LCBTTCIN-IEDQLCB(2,RPARM),PRFSRCE TNT OFFSET             21400020
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   21500020
         BO    STARTY                   BRANCH IF NO                    21600020
         LA    RBUF,PRFSHDR             START OF HEADER LABEL           21700020
         MVC   PRFDEST(2),PWAOFF        MOVE DESTINATION OFFSET         21800020
*                                       TO TERMNAME TABLE FROM          21900020
*                                       PUT/WRITE WORKAREA INTO         22000020
*                                       BUFFER PREFIX                   22100020
         NC    PRFDEST(2),PRFDEST       DESTINATION OFFSET VALID        22200020
         BZ    STARTY                   BRANCH IF NOT TO BYPASS         22300020
*                                       LOCK MODE FUNCTIONS             22400020
         L     RPARM,PCBLCBAD           APPL PROG LCB ADDRESS           22500020
         NC    LCBINCAM-IEDQLCB(2,RPARM),LCBINCAM-IEDQLCB(RPARM)        22600020
*                                       OUTSTANDING LOCK RESPONSE       22700020
         BZ    STARTY                   BRANCH IF NO                    22800020
         STM   RCNT,RBFR,PESAVE         SAVE REGISTERS                  22900020
         EJECT                                                          23000020
*                                                                     * 23100020
*      TEST TO SEE IF MESSAGE DESTINATION IS IN LOCK MODE             * 23200020
*                                                                     * 23300020
         SR    RPARM,RPARM              CLEAR WORK REGISTER TO ZERO     23400020
         LH    RPARM,PWAOFF             DESTINATION OFFSETT             23500020
         N     RPARM,AVTCLRHI           CLEAR HIGH-ORDER HALF           23600020
         L     RENTRY,AVTRNMPT          ADDRESS OF OFFSET               23700020
*                                       CONVERSION LOGIC                23800020
         BALR  RETURN,RENTRY            CONVERT OFFSET TO TERMINAL      23900020
*                                       TABLE ENTRY ADDRESS             24000020
         LR    RTEMP,RPARM                                       S22024 24010022
         TM    TRMSTATE-IEDQTRM(RPARM),SINGLE VALID TERM ENTRY          24030020
         BNZ   START                    BRANCH IF NO                    24060020
         L     RPARM,TRMDESTQ-1-IEDQTRM(0,RPARM) GET ADDRESS OF         24100020
*                                       DEST QCB FROM TERM ENTRY        24200020
         LR    RENTRY,RPARM             SAVE DEST QCB ADDRESS           24300020
         L     RPARM,QCBDCBAD-1-IEDQQCB(0,RPARM) GET ADDRESS OF         24400020
*                                       DCB FROM DEST QCB               24500020
         TM    DCBOFLGS-IHADCB(RPARM),DCBOPEN  IS DCB OPENED            24600020
         BNO   START                    BRANCH IF NO                    24700020
         TM    DCBDSORG-IHADCB(RPARM),AVTE80   IS THIS AN LGB    S22024 24710022
         BNO   NOT3705                  BRANCH IF NOT            S22024 24720022
         LR    RPARM,RENTRY             RESTORE QCB ADDRESS      S22024 24730022
         SH    RPARM,AVTHA4             BACKUP TO RN PREFIX      S22024 24740022
         USING IEDNQCB,RPARM                                     S22024 24750022
         ICM   RPARM,15,QCBPLCBA-1      PLCB ADDRESS             S22024 24760022
         DROP  RPARM                                             S22024 24770022
         BNM   START                    BRANCH IF POSITIVE - NO  S22024 24780022
*                                       PLCB ASSIGNED            S22024 24790022
         B     LCBLOOP                  BRANCH TO LCBLOOP        S22024 24800022
NOT3705  EQU   *                                                 S22024 24810022
         SR    RCNT,RCNT                CLEAR COUNTER TO ZERO           24900020
         IC    RCNT,QCBLKRLN-IEDQQCB(0,RENTRY) LOCK RELATIVE LINE       24960020
*                                       NUMBER                          25020020
         LTR   RCNT,RCNT               IS THIS TERM LOCKED      SA52508 25040000
         BZ    START                   NO, PROCESS NORMALLY     SA52508 25060000
         SR    RZERO,RZERO              CLEAR REG TO ZERO               25100020
         LA    RZERO,LCBFLAG1-IEDQLCB                                   25200020
         SR    RTEMP,RTEMP              CLEAR REG TO ZERO               25300020
         IC    RTEMP,DCBEIOBX-IHADCB(0,RPARM)  LCB LENGTH               25400020
         L     RPARM,DCBIOBAD-IHADCB(0,RPARM)  GET ADDRESS OF           25500020
*                                       IOB FROM DCB                    25600020
         SR    RPARM,RZERO              ADDR OF DUMMY LCB               25700020
         LR    RZERO,RPARM              SAVE DUMMY LCB ADDRESS          25730020
         LR    RPARM,RCNT               RELATIVE LINE NUMBER            25760020
         MR    RTEMP-1,RPARM            COMPUTE LCB DISPLACEMENT        25790020
         LR    RPARM,RTEMP                                              25820020
         AR    RPARM,RZERO              ADDR OF REAL LCB                25850020
LCBLOOP  EQU   *                                                        25900020
         CLC   LCBTTCIN-IEDQLCB(2,RPARM),PWAOFF  LCB FOR MSG DEST       26000020
         BNE   START                    BRANCH IF NO                    26100020
         EJECT                                                          26500020
*                                                                     * 26620020
*        INSURE THAT CURRENT MESSAGE IS CORRECT RESPONSE              * 26640020
*                                                                     * 26660020
         LR    RZERO,RPARM              SAVE LCB ADDRESS                26700020
         L     RPARM,LCBSCBA-1-IEDQLCB(0,RPARM) GET ADDRESS OF          26702020
*                                       SCB FROM LCB                    26704020
         TM    SCBSTATE-IEDQSCB(RPARM),SCBLCK1N+SCBMSGLN  LOCK MODE     26706020
         BZ    START                    BRANCH IF NO                    26708020
         LR    RPARM,RZERO              RESTORE LCB ADDRESS             26710020
         L     RPARM,LCBINSRC-1-IEDQLCB(0,RPARM) INQUIRY DEST OFFSET    26714020
         SRL   RPARM,8                                                  26721020
         N     RPARM,AVTCLRHI           CLEAR HIGH-ORDER HALFWORD       26728020
         LTR   RPARM,RPARM              LINE NOT LOCKED                 26730020
         BZ    START                    BRANCH IF NO                    26732020
         LR    RCNT,RZERO               SAVE SOURCE LCB ADDRESS         26735020
         LR    RNUM,RENTRY              SAVE DEST QCB ADDRESS           26742020
         L     RENTRY,AVTRNMPT          TNT OFFSET CONVERTER            26749020
         BALR  RETURN,RENTRY            GET TERM ENTRY ADDRESS          26756020
         L     RPARM,TRMDESTQ-1-IEDQTRM(0,RPARM) DEST QCB ADDRESS       26763020
         CLC   QCBDCBAD-IEDQQCB(3,RPARM),PESAVE+49 IDENTICAL PCB'S      26770020
         BNE   START                    BRANCH IF NO                    26777020
         LR    RZERO,RCNT               RESTORE SOURCE LCB ADDRESS      26784020
         LR    RENTRY,RNUM              RESTORE DEST QCB ADDRESS        26791020
         LR    RPARM,RZERO              RESTORE LCB ADDRESS             26795020
         L     RPARM,LCBSCBA-1-IEDQLCB(0,RPARM) GET ADDRESS OF          26800020
*                                       SCB FROM LCB                    26900020
         LR    RTEMP,RZERO              LCB ADDRESS                     27120020
         TM    LCBINSRC+2-IEDQLCB(RTEMP),LOCKR   LINE DUE A RESPONSE    27140020
         BNO   START                    BRANCH IF NO                    27160020
         NI    LCBINSRC+2-IEDQLCB(RTEMP),AVTEFF-LOCKR                   27180020
         LA    RTEMP,PEWASCB            SOURCE SCB                      27200020
         MVC   SCBSTATE-IEDQSCB(1,RTEMP),SCBSTATE-IEDQSCB(RPARM)        27400020
*                                       COPY LOCK FLAGS TO SOURCE SCB   27500020
         NI    SCBSTATE-IEDQSCB(RTEMP),SCBLCK1N+SCBMSGLN                27800020
         LR    RPARM,RZERO              ADDRESS OF SOURCE LCB           28100020
         L     RETURN,PESAVE+48         RESTORE PCB ADDRESS             28700020
         L     RTEMP,PCBLCBAD           APPL PROG LCB ADDRESS           28800020
         LH    RETURN,LCBINCAM-IEDQLCB(0,RTEMP)  LOCK RESPONSE COUNT    28900020
         BCTR  RETURN,0                 DECREMENT COUNT BY ONE          29000020
         STH   RETURN,LCBINCAM-IEDQLCB(0,RTEMP)  NEW RESPONSE COUNT     29100020
         EJECT                                                          29200020
         TM    QCBSLINK+2-IEDQQCB(RENTRY),RELEASE RELEASE IN EFFECT     29230020
         BO    START                    BRANCH IF YES                   29260020
         TM    QCBINSRC+2-IEDQQCB(RENTRY),QCBDELAY              OX02215 29260453
*                                       QCB IN TIME DELAY QUEUE OX02215 29260853
         BNO   NOTIMQ                   NO                      OX02215 29261253
         LR    RTEMP,RPARM              SAVE LCB ADDRESS        OX02215 29261653
         LR    RPARM,RENTRY             GET QCB ADDRESS         OX02215 29262053
         L     RENTRY,AVTHG02           ADDRESS OF TIME DELAY   OX02215 29262453
*                                       REMOVAL ROUTINE         OX02215 29262853
         BALR  RETURN,RENTRY            REMOVE QCB FROM TDQ     OX02215 29263253
         LR    RENTRY,RPARM             RESTORE QCB ADDRESS     OX02215 29263653
         LR    RPARM,RTEMP              RESTORE LCB ADDRESS     OX02215 29264053
         LA    RETURN,QCBSTVTO-IEDQQCB(,RENTRY)  ADDRESS OF SENDOX02215 29264453
*                                       SCHEDULER STCB          OX02215 29264853
         MVC   QCBSLINK-IEDQQCB(3,RENTRY),QCBSTCHN-IEDQQCB(RENTRY)      29265253
         IC    RTEMP,QCBSTVTO-IEDQQCB(RENTRY) SAVE INDEX BYTE   OX02215 29265653
         ST    RETURN,QCBSTCHN-IEDQQCB-1(RENTRY) PUT SEND       OX02215 29266053
*                                        SCHED BACK INTO QCB    OX02215 29266453
         STC   RTEMP,QCBSTVTO-IEDQQCB(RENTRY)  RESTORE INDX     OX02215 29266853
*                                       PUT SEND SCHEDULER BACK OX02215 29267253
*                                       INTO THE QCB            OX02215 29267653
NOTIMQ   EQU   *                                                OX02215 29268053
*                                                                     * 29270020
*        FIND SEND SCHEDULER AND INSERT IT'S STCB IN LCB              * 29280020
*                                                                     * 29290020
         L     RTEMP,QCBSTVTO-IEDQQCB(0,RENTRY) ADDR OF TOP STCB        29300020
         LA    RTEMP,0(0,RTEMP)         CLEAR HIGH-ORDER BYTE           29400020
         LA    RZERO,QCBSTVTO-IEDQQCB(0,RENTRY) ADDR OF STCB            29500020
         LA    RBUF,LCBSTCBA-1-IEDQLCB(0,RPARM) STCB CHAIN ADDR         29600020
         CR    RTEMP,RZERO              SEND SCHED ON DEST QCB          29700020
         BNE   STCBOUT                  BRANCH IF NO                    29800020
         MVC   QCBSTCHN-IEDQQCB(3,RENTRY),QCBSLINK-IEDQQCB(RENTRY)      29900020
*                                       REMOVE SEND SCHED FROM CHAIN    30000020
         LR    RPARM,RZERO              SEND SCHEDULER ADDRESS          30100020
INSERT   EQU   *                                                        30200020
         BAL   RETURN,DSPLIFOR          PUT SEND SCHEDULER ON TOP       30300020
         B     START                    RETURN TO MAINLINE CODE         30400020
STCBOUT  EQU   *                                                        30500020
         CLI   LCBFLAG1-IEDQLCB(RPARM),AVTEZERO PLCB             S22024 30520000
         BE    STCBOUTX                 BRANCH YES - USE COMMON  S22024 30540000
*                                       CODE                     S22024 30560000
         TM    LCBSTAT2-IEDQLCB(RPARM),LCBDIAL DIAL LINE                30600020
         BO    DIAL                     BRANCH IF YES                   30700020
STCBOUTX EQU   *                                                        30800020
         L     RTEMP,LCBSTCBA-1-IEDQLCB(0,RPARM) TOP STCB IN LCB        30900020
         LA    RWORK,4(0,RPARM)         SIMULATE FIRST ELEMENT          31000020
STCBLOOP EQU   *                                                        31100020
         LA    RTEMP,0(0,RTEMP)         CLEAR HIGH-ORDER BYTE           31200020
         CR    RTEMP,RZERO              DESIRED SEND SCHED STCB         31300020
         BE    DELINK                   BRANCH IF YES                   31400020
         CLI   4(RTEMP),AVTEZERO        END OF STCB CHAIN       SA52991 31430022
         BCR   AVTECD8,RETURN           BRANCH IF YES           SA52991 31460022
         LR    RWORK,RTEMP                                              31500020
         L     RTEMP,4(0,RTEMP)         ADDR OF NEXT STCB               31600020
         B     STCBLOOP                 GET NEXT STCB                   31700020
DELINK   EQU   *                                                        31800020
         MVC   5(3,RWORK),5(RTEMP)      DELINK STCB                     31900020
         LR    RPARM,RTEMP              DISP PARM REG                   32000020
         B     INSERT                   PUT STCB ON TOP OF CHAIN        32100020
         EJECT                                                          32200020
DIAL     EQU   *                                                        32300020
         TM    QCBTSOF1-IEDQQCB(RENTRY),QCBDELAY QCB IN TIME DELAY      32400020
         BNO   DIALQ                    BRANCH IF NO                    32500020
         LR    RPARM,RZERO              STCB ADDRESS                    32600020
         B     INSERT                   BRANCH TO INSERT         S21903 32700004
*                             SEND SCHEDULER'S STCB IN LCB CHAIN S21903 32750004
DIALQ    EQU   *                                                        32800020
         L     RWORK,QCBDCBAD-1-IEDQQCB(RENTRY) DCB ADDRESS             32900020
         SR    RTEMP,RTEMP              CLEAR REGISTER TO ZERO          33000020
         IC    RTEMP,DCBEIOBX-IHADCB(0,RWORK)   LCB SIZE                33100020
         L     RWORK,DCBIOBAD-IHADCB(0,RWORK) IOB ADDRESS               33200020
         LA    RWORK,0(0,RWORK)         CLEAR HIGH-ORDER BYTE           33300020
         LA    RETURN,LCBFLAG1-IEDQLCB+8 OFFSET TO DIALOUT QUEUE        33400020
         SR    RWORK,RETURN             ADDR OF DIALOUT CALL Q          33500020
         AR    RWORK,RTEMP              ACTUAL LCB ADDRESS              33600020
DCQLOOP  EQU   *                                                        33700020
         L     RTEMP,4(0,RWORK)         ADDR OF STCB ON D.C. Q          33800020
         CLI   4(RTEMP),0               END OF D.C. QUEUE               33900020
         BE    SCANALL                  BRANCH IF YES           SA52991 34000022
         LA    RTEMP,0(0,RTEMP)         CLEAR HIGH-ORDER BYTE           34100020
         CR    RZERO,RTEMP              DEST SCHED STCB FOUND           34200020
         BE    DELINK                   BRANCH IF YES                   34300020
         LR    RWORK,RTEMP              SAVE TOP STCB ADDR              34400020
         B     DCQLOOP                  GO TEST NEXT STCB               34500020
         EJECT                                                          34503022
SCANALL  EQU   *                                                SA52991 34506022
*                                                               SA52991 34509022
*        FIND DEST QCB FOR LOCKED TERMINAL BY SCANNING THE      SA52991 34512022
*        STCB CHAIN FOR EACH LCB IN LINE GROUP.                 SA52991 34515022
*                                                               SA52991 34518022
         SPACE                                                          34521022
         SR    RUNIT,RUNIT              CLEAR WORK REGISTER     SA52991 34524022
         L     RWORK,QCBDCBAD-1-IEDQQCB(,RENTRY) DCB ADDRESS    SA52991 34527022
         L     RERB,DCBDEBAD-IHADCB(,RWORK) DEB ADDRESS         SA52991 34530022
         IC    RUNIT,DEBNMEXT(,RERB)    NUMBER OF LCBS IN GROUP SA52991 34533022
RLNLOOP  EQU   *                                                SA52991 34536022
         LR    RCNT,RUNIT               RELATIVE LINE NUMBER    SA52991 34539022
         L     RWORK,QCBDCBAD-1-IEDQQCB(,RENTRY) DCB ADDRESS    SA52991 34542022
         L     RPARM,DCBIOBAD-IHADCB(,RWORK) IOB ADDRESS        SA52991 34545022
         LA    RETURN,LCBFLAG1-IEDQLCB  LCBSTART OFFSET         SA52991 34548022
         LA    RPARM,0(,RPARM)          CLEAR HIGH-ORDER BYTE   SA52991 34551022
         SR    RPARM,RETURN             DUMMY LCB ADDRESS       SA52991 34554022
         LR    RETURN,RPARM             SAVE LCB ADDRESS        SA52991 34557022
         LR    RPARM,RCNT               RELATIVE LINE NUMBER    SA52991 34560022
         SR    RTEMP,RTEMP              CLEAR WORK REGISTER     SA52991 34563022
         IC    RTEMP,DCBEIOBX-IHADCB(,RWORK) LCB LENGTH         SA52991 34566022
         MR    RTEMP-1,RPARM            COMPUTE RELATIVE OFFSET SA52991 34569022
         LR    RPARM,RTEMP              LCB OFFSET              SA52991 34572022
         AR    RPARM,RETURN             CURRENT LCB ADDRESS     SA52991 34575022
         BAL   RETURN,STCBOUTX          STCB CHAIN              SA52991 34578022
         BCT   RUNIT,RLNLOOP            GET NEXT LCB IN GROUP   SA52991 34581022
         B     START                    IGNORE LOCK IF NOT FOUNDSA52991 34584022
         EJECT                                                          34600020
START    EQU   *                                                        34700020
         LM    RCNT,RBFR,PESAVE         RESTORE REGISTERS               34800020
STARTY   EQU   *                                                        34900020
         LR    RPARM,RBFR               ADDRESS OF FIRST BUFFER UNIT    35000020
*                                       LINK FIELD                      35100020
         ST    RPARM,PEWATIC            SAVE CURRENT UNIT ADDR          35200020
         MVI   PEWATIC,PSVTO                                            35300020
*                                                                     * 35420020
*        COMPUTE BUFFER SIZE, UNIT SIZE, AND UNITS PER BUFFER         * 35440020
*                                                                     * 35460020
         LA    RZERO,PRFSUNIT           START OF BUFFER AFTER UMA       35500020
         L     RPCB,PEPCBAD             RESTORE PCB ADDRESS             35600020
         CLC   AVTKEYLE(2),PEWASOWA     FULL UNITS WANTED               35700020
         BNH   LESS                     BRANCH IF YES                   35800020
         AH    RZERO,PEWASOWA           EMPTY BYTE COUNT                35900020
         B     CONT                     BRANCH TO                S21903 36000004
*                                       SET-END-OF-UNIT ADDR     S21903 36050004
LESS     EQU   *                                                        36100020
         AH    RZERO,AVTKEYLE           ADDRESS OF END OF BUFFER        36200020
CONT     EQU   *                                                        36300020
         ST    RZERO,PERAQCB+4          ADDR OF END OF THIS UNIT        36400020
         SR    RZERO,RBUF               SIZE OF DATA FIELD IN BFR       36500020
*                                                                     * 36620020
*              ALLOW SPACE IN BUFFER FOR RESERVE CHARACTERS           * 36640020
*                                                                     * 36660020
         L     RPCB,PEPCBAD             RESTORE PCB ADDRESS             36700020
         SR    RTEMP,RTEMP              CLEAR COUNTER                   36800020
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   36900020
         BO    TEXTBFR                  BRANCH IF NO                    37000020
         NC    PCBRSERH,PCBRSERH        RESERVE CHARS FOR HDR           37100020
         BZ    MOVE                     BRANCH IF YES                   37200020
         IC    RTEMP,PCBRSERH           RESERVE CHAR COUNT              37300020
         B     BUMPER                   BUMP POINTER & COUNTER          37400020
TEXTBFR  EQU   *                                                        37500020
         NC    PCBRSERT,PCBRSERT        RESERVE CHARS FOR TEXT          37600020
         BZ    MOVE                     BRANCH IF NO                    37700020
         IC    RTEMP,PCBRSERT           RESERVE CHAR COUNT              37800020
BUMPER   EQU   *                                                        37900020
         AR    RBUF,RTEMP               BUMP PAST RESERVE CHARS         38000020
         AR    RCNT,RTEMP               ADD RESERVE CHAR COUNT          38100020
         SR    RZERO,RTEMP              SUBTRACT RESERVE COUNT          38200020
         EJECT                                                          38300020
*                                                                     * 38400020
*        MOVE DATA FROM USER'S WORKAREA TO THE MCP BUFFER             * 38500020
*                                                                       38600020
         SPACE                                                          38700020
MOVE     EQU   *                                                        38800020
         LR    RTEMP,RZERO              SIZE OF DATA FIELD IN BFR       38900020
         CR    RTEMP,RNUM               MORE THAN ONE UNIT      OY00458 38920005
         BNH   MOVE1                    BRANCH IF NO            OY00458 38940005
         LR    RTEMP,RNUM               SET SMALLER COUNT       OY00458 38960005
MOVE1    EQU   *                                                OY00458 38980005
         BCTR  RTEMP,RZERO              DECREMENT COUNT BY ONE          39000020
         EX    RTEMP,MOVER              FILL THE BUFFER                 39100020
         CR    RNUM,RZERO               WORKAREA EMPTY                  39200020
         BH    NEXT                     BRANCH IF NO                    39300020
         AR    RCNT,RNUM                INCREMENT COUNTER OF BYTES      39400020
*                                       MOVED INTO BUFFER               39500020
         AR    RBUF,RNUM                ADDR OF NEXT EMPTY BYTE         39600020
         STH   RCNT,PRFSIZE             STORE BYTE COUNT IN PREFIX      39700020
         TM    PWARECFM,CQMASK          CURRENT QTAM PUT                39800020
         BZ    NORECDEL                 BRANCH IF YES                   39900020
         TM    PWAOPTCD,MSG             IS WORK UNIT A MESSAGE          40000020
         BO    NORECDEL                 BRANCH IF YES                   40100020
         TM    GWARECFM,VAR             VARIABLE FORMAT                 40400020
         BNO   NORECDEL                 BRANCH IF NO                    40500020
         L     RTEMP,PEWAPROC           PROCESS ENTRY ADDRESS           40600020
         NC    TRMCHCIN-IEDQTRM(1,RTEMP),TRMCHCIN-IEDQTRM(RTEMP)        40700020
*                                       RECORD DELIMITER SPECIFIED      40800020
         BZ    NORECDEL                 BRANCH IF NO             A44891 40900021
         BCTR  RBUF,0                   BACK UP ONE BYTE                41000020
         MVC   0(1,RBUF),TRMCHCIN-IEDQTRM(RTEMP) RECORD DELIMITER       41100020
         LA    RBUF,1(0,RBUF)           BUMP TO NEXT EMPTY BYTE         41200020
NORECDEL EQU   *                                                        41300020
         NI    PRFSTAT1,AVTEFF-PRFNLSTN FLAG BFR AS EOM                 41400020
         TM    PWACTL,EOM               WORKAREA CONTAIN END OF         41500020
*                                       A MESSAGE                       41600020
         BO    POSTBUF                  BRANCH IF YES TO POST BFR       41700020
         OI    PRFSTAT1,PRFNLSTN        SET NOT-EOM BIT IN PREFIX       41800020
         ST    RBFR,PERAQCB             SAVE ADDR OF LAST FILLED        41900020
*                                       BUT NON-EOM BUFFER              42000020
         OI    PEWAFLG,PBUF             PARTIAL BUFFER FLAG      A44891 42050021
         C     RBUF,PERAQCB+4           IS CURRENT UNIT FULL            42100020
         BL    SAVIT                    BRANCH IF NO                    42200020
         LA    RETURN,CLEANX            SET UP RETURN ADDRESS           42250020
         NC    9(2,RPARM),9(RPARM)      ANOTHER UNIT TO FILL            42300020
         BNZ   SETUNIT                  BRANCH IF YES                   42400020
         NI    PEWAFLG,AVTEFF-PBUF      SET NOT PARTIAL BUFFER          42500020
         B     CLEANX                   GO POST APPL PROG ECB           42600020
         EJECT                                                          42700020
NEXT     EQU   *                                                        43800020
         OI    PRFSTAT1,PRFNLSTN        SET NOT-EOM FLAG                43900020
         AR    RCNT,RZERO                                               44000020
         STH   RCNT,PRFSIZE                                             44100020
         SR    RNUM,RZERO               COMPUTE SIZE OF DATA            44200020
*                                       REMAINING IN WORKAREA           44300020
         AR    RWORK,RZERO              ADDRESS OF NEXT BYTE OF         44400020
*                                       DATA TO BE MOVED                44500020
         NC    9(2,RPARM),9(RPARM)      ANOTHER UNIT IN BUFFER          44600020
         BZ    NEXTBUF                  BRANCH IF NO                    44700020
         LA    RETURN,MOVE              SET UP RETURN ADDRESS           44730020
SETUNIT  EQU   *                                                        44760020
         L     RBUF,8(0,RPARM)          ADDRESS OF NEXT UNIT            44800020
         MVI   8(RBUF),TIC              SET UP TIC COMMAND              44900020
         LR    RPARM,RBUF               ADDRESS OF NEXT BUFFER UNIT     45000020
*                                       LINK FIELD                      45100020
         ST    RPARM,PEWATIC            SAVE CURRENT UNIT ADDR          45200020
         MVI   PEWATIC,PSVTO                                            45300020
MOVEIT   EQU   *                                                        45400020
         LA    RBUF,AVTUMALN(0,RBUF)    ADDRESS OF FIRST EMPTY          45500020
*                                       BYTE IN BUFFER                  45600020
         CLC   AVTKEYLE(2),PEWASOWA     FULL UNITS WANTED               45700020
         BNH   LESSA                    BRANCH IF YES                   45800020
         LH    RZERO,PEWASOWA           EMPTY BYTE COUNT                45900020
         B     CONTA                    BRANCH TO                S21903 46000004
*                                       COMPUTE END-OF-UNIT ADDR S21903 46050004
LESSA    EQU   *                                                        46100020
         LH    RZERO,AVTKEYLE           NUMBER OF EMPTY BYTES           46200020
*                                       IN BUFFER                       46300020
CONTA    EQU   *                                                        46400020
         LR    RTEMP,RBUF               FIRST EMPTY BYTE IN BFR         46500020
         ST    RBUF,PECBUF              FIRST EMPTY BYTE ADDRESS        46550020
         AR    RTEMP,RZERO              ADDR OF END OF THIS UNIT        46600020
         ST    RTEMP,PERAQCB+4          SAVE THIS POINTER               46700020
         BR    RETURN                   RETURN TO CALLER                46800020
         EJECT                                                          46900020
NEXTBUF  EQU   *                                                        47000020
         BAL   RETURN,SETPRFS           GO COMPUTE PREFIX SIZE          47100020
         MVC   LCBERBCH(3),PRFLINK      REMOVE BFR FROM ERB CHAIN       47200020
         XC    PRFLINK,PRFLINK          SET LINK FIELD TO ZERO          47300020
         BAL   RETURN,SETFLAG           GO FLAG LAST BUFR UNIT   S21903 47400004
         LR    RPARM,RBFR               BUFFER PREFIX ADDRESS           47500020
         BAL    RETURN,DSPPOSTR         POST FULL BUFFER                47600020
         XC    PERAQCB(4),PERAQCB       CLEAR CURRENT BFR ADDR          47650020
         L     RPCB,PEPCBAD             RESTORE PCB ADDRESS             47700020
NEXTBUFX EQU   *                                                        47800020
         NC    LCBERBCH(3),LCBERBCH     ANOTHER BUFFER LEFT             47900020
         BZ    ERB                      BRANCH IF NO TO GET MORE        48000020
         L     RBFR,LCBERBCH-1          ADDR OF NEXT EMPTY BFR          48100020
         B     BUFINIT                  GO FILL THIS BUFFER             48200020
POSTBUF  EQU   *                                                        48300020
         BAL   RETURN,SETPRFS           GO COMPUTE PREFIX SIZE          48400020
         MVC   LCBERBCH(3),PRFLINK      REMOVE BFR FROM ERB CHAIN       48500020
         XC    PRFLINK,PRFLINK          SET LINK FIELD TO ZERO          48600020
         LR    RPARM,RBFR               ADDR OF BUFFER TO POST          48700020
         L     RTEMP,PEWATIC            ADDR OF CURRENT TIC FIELD       48800020
TICLOOP  EQU   *                                                        48900020
         NC    9(2,RTEMP),9(RTEMP)      LAST UNIT IN BUFFER             49000020
         BZ    SETTIC                   BRANCH IF YES                   49100020
         L     RTEMP,8(0,RTEMP)         GET ADDR OF NEXT UNIT           49200020
         B     TICLOOP                  GO CHECK FOR LAST UNIT          49300020
SETTIC   EQU   *                                                        49400020
         MVI   11(RTEMP),INVTIC         SET INVALID TIC ADDRESS TO      49460020
*                                       INDICATE END OF BUFFER          49520020
         L     RTEMP,PRFLCB-1           LCB ADDRESS                     49600020
         ST    RPEWA,LCBERCCW-IEDQLCB(RTEMP) SAVE PEWA ADDR IN LCB      49700020
         XC    PERAQCB(4),PERAQCB       CLEAR CURRENT BFR ADDR          49750020
         TM    PRFSTAT1-IEDQPRF(RPARM),PRFNLSTN EOM BUFFER      SA58449 49756000
         BO    DSPPOST                  BRANCH IF NO            SA58449 49762000
         OI    PEWAFLG,ERBBUSY          SET LCB TO BE POSTED            49770020
         B     DSPPOST                  POST FULL BUFFER                49800020
         SPACE 3                                                        49900020
SETPRFS  EQU   *                                                        50000020
         LH    RTEMP,PRFSIZE            BYTES OF DATA IN BFR            50100020
         TM    PRFSTAT1,PRFNHDRN        IS BUFFER A HEADER              50200020
         BO    SHORTP                   BRANCH IF NO                    50300020
         LA    RTEMP,PRFSHDR-PRFSUNIT(0,RTEMP)  ADD HEADER PREFIX       50400020
         B     STOREP                   GO UPDATE PREFIX SIZE    S21903 50500004
SHORTP   EQU   *                                                        50600020
         LA    RTEMP,PRFSTXT-PRFSUNIT(0,RTEMP)  ADD TEXT PREFIX         50700020
STOREP   EQU   *                                                        50800020
         STH   RTEMP,PRFSIZE            UPDATE PREFIX SIZE              50900020
         BR    RETURN                   RETURN TO CALLER         S21903 51000004
         EJECT                                                          51100020
CLEANUP  EQU   *                                                        51200020
*                                                                     * 51300020
*        POST WAITING APPLICATION PROGRAM COMPLETE VIA AQCTL          * 51400020
*                                                                     * 51500020
         L     RPEWA,LCBERCCW-IEDQLCB(RPARM) RESTORE PEWA ADDR          51600020
         NI    PEWAFLG,AVTEFF-ERBBUSY   SET LCB NOT LOOSE               51620020
         MVI   PEWASCB,AVTEZERO         RESET SCBSTATE TO NOT LOCK      51660020
         NI    LCBERBST-IEDQLCB(RPARM),LCBDLNKF SET ERB NOT POSTED      51730020
         TM    PEWAFLG,CFLG             CLOSE IN PROGRESS               51800020
         BO    CLOSE                    BRANCH IF YES                   51900020
CLEANX   EQU   *                                                        52000020
         LA    RPARM,PEAQCTL            ADDRESS OF AQCTL SVC            52100020
*                                       PARAMETER LIST                  52200020
         L     RTEMP,PEWAPROC           PROCESS ENTRY ADDRESS    S21903 52300000
         L     RTEMP,TRMDESTQ-1-IEDQTRM(,RTEMP) QCB ADDRESS      S21903 52350000
         L     RPCB,QCBDCBAD-1-IEDQQCB(,RTEMP) PCB ADDRESS       S21903 52400000
         MVC   1(3,RPARM),PEWAECBA+1    MOVE ADDRESS OF APPLICATION     52500020
*                                       PROGRAM ECB FROM PEWA TO        52600020
*                                       AQCTL PARAMETER LIST            52700020
         MVI   0(RPARM),XPOST           SET AQCTL ACTION FLAG           52750020
         MVC   9(3,RPARM),PCBTCBAD+1    APPL PROG TCB ADDRESS           52770020
         TM    PCBOFLG,PCBRORIN         IS APPLICATION PROGRAM          52800020
*                                       ELIGIBLE FOR ROLLOUT            52900020
         BO    RORI                     BRANCH IF YES                   53000020
         SPACE                                                          53100020
         TM    PCBOFLG,PCBTSON          TSO APPL PROGRAM                53130020
         BNO   POST                     BRANCH IF NO                    53160020
         LA    RTEMP,PCBTJID            ADDRESS OF TSO TJID FIELD       53200020
*                                       IN PROCESS CONTROL BLOCK        53300020
         ST    RTEMP,4(0,RPARM)         STORE ADDRESS OF TJID IN        53400020
*                                       AQCTL PARAMETER LIST            53500020
         MVI   0(RPARM),TSOFLG          AQCTL ACTION CODE               53600020
         MVI   8(RPARM),EOL                                             53700020
         MVC   9(3,RPARM),PCBTCBAD+1                                    53800020
         B     POST                     GO ISSUE AQCTL SVC              53900020
        SPACE 2                                                         54000020
CLOSE    EQU   *                                                        54100020
         L     RPARM,PEWAPROC           PROCESS ENTRY ADDRESS   SA51096 54120000
         L     RPARM,TRMDESTQ-1-IEDQTRM(,RPARM) QCB ADDRESS     SA51096 54140000
         L     RPCB,QCBDCBAD-1-IEDQQCB(,RPARM) PCB ADDRESS      SA51096 54160000
         LA    RPARM,PEWAELEM           ADDRESS OF SPECIAL ELEMENT      54200020
*                                       FOR OPEN/CLOSE SUBTASK          54300020
         MVC   PEWAELEM+1(3),AVTOCQPT+1 OPEN/CLOSE QCB ADDRESS          54400020
         MVI   PEWAELEM+4,PRIAPBFR      SET ELEMENT PRIORITY            54500020
         XC    PEWAELEM+5(3),PEWAELEM+5 SET LINK FIELD TO ZERO          54600020
         MVC   PEWAELEM+8(4),PEWAPROC   PROCESS ENTRY ADDRESS           54700020
         MVC   PEWAELEM+12(4),PEWAECBA  APPL PROG ECB ADDRESS           54800020
         MVI   PEWAELEM,AVTEZERO        SET CLOSE FLAG FOR IEDQEU       54900020
         NI    PCBOFLG,AVTEFF-PCBPIPN   SET PUT DONE             A50196 54950022
         B     DSPPOST                  EXIT TO DISPATCHER TO    S21903 55000004
*                                       POST ELEM TO READY QUEUE S21903 55050004
         EJECT                                                          55100020
RORI     EQU   *                                                        55200020
         MVI   0(RPARM),RORIFLG         AQCTL ACTION CODE               55300020
         MVC   5(3,RPARM),PCBTCBAD+1    PUT ADDRESS OF APPLICATION      55400020
*                                       PROGRAM TASK CONTROL BLOCK      55500020
*                                       IN AQCTL PARAMETER LIST         55600020
         MVI   8(RPARM),EOL             FLAG END OF PARAMETER LIST      55700020
         MVC   9(3,RPARM),PEWADEB+1     ADDRESS OF DEB INTO             55800020
*                                       AQCTL PARAMETER LIST            55900020
POST     EQU   *                                                        56000020
         LA    RTEMP,PCBTJID                                            56200020
         ST    RTEMP,4(RPARM)                                           56300020
         NI    PCBOFLG,AVTEFF-PCBPIPN   SET PUT DONE             A50196 56450022
         AQCTL                                                  SA57699 56470022
         B     DSPDISP                  RETURN TO DISPATCHER            56500020
SAVIT    EQU   *                                                        56600020
         ST    RPARM,PEWATIC            SAVE CURRENT UNIT ADDR          56700020
         MVI   PEWATIC,PSVTO                                            56800020
         ST    RBUF,PECBUF              SAVE ADDR OF NEXT EMPTY BYTE    56900020
         B     CLEANX                   GO POST APPL PROG ECB           57100020
         EJECT                                                          57200020
ERB      EQU   *                                                        57300020
         SPACE                                                          57400020
*                                                                     * 57500020
*     INITIALIZE ERB TO OBTAIN EMPTY BUFFERS                          * 57600020
*                                                                     * 57700020
         SPACE                                                          57800020
         LA    RPARM,AVTBFREB           ADDRESS OF AVAILABLE            57900020
*                                       BUFFER QCB                      58000020
         ST    RPARM,LCBERB             INITIALIZE ERB KEY AND          58100020
*                                       QCB FIELDS                      58200020
         MVI   LCBERBPY,PRIINTRQ        SET ERB PRIORITY                58300020
         XC    LCBERBLK(3),LCBERBLK     CLEAR ERB LINK FIELD TO ZERO    58400020
         MVI   LCBERBST,PUTFLG          FLAG THIS ERB AS A PUT ERB      58500020
         XC    LCBERBCH(3),LCBERBCH     SET BUFFER CHAIN PTR TO ZERO    58600020
         SR    RZERO,RZERO              CLEAR WORK REG          SA69971 58700055
         IC    RZERO,PCBBUFIN           IN/OUT COUNT            SA69971 58750055
         SRL   RZERO,FOUR               ISOLATE BUFIN           SA69971 58800055
         STC   RZERO,LCBERBCT           INITIALIZE BFR REQ      SA69971 58850055
         MVC   LCBERBCT+1(1),PEUNCT     UNITS PER BUFFER                58900020
         LA    RZERO,PEWASCB            SCB ADDRESS                     59000020
         ST    RZERO,LCBSCBA-1          ADDRESS OF CURRENT SCB          59100020
         L     RPARM,PCBLCBAD           LCB ADDRESS                     59200020
         ST    RZERO,LCBSCBA-1-IEDQLCB(,RPARM) SET SCB FOR MSG   A48279 59250022
         MVC   LCBISZE-IEDQLCB(1,RPARM),PCBRSERH RESERVE CNT IN LCB     59300020
         LA    RZERO,PERAQCB            ADDRESS OF PUT SCHEDULER        59400020
*                                       QCB                             59500020
         ST    RZERO,PERCQCB            MAKE ADDRESS OF QCB             59600020
*                                       AVAILABLE TO BUFFER REQUEST     59700020
*                                       SUBTASK                         59800020
         MVI   LCBPRI-IEDQLCB(RPARM),PRIAPBFR  LCB PRIORITY             59900020
         MVI   LCBERBST-IEDQLCB(RPARM),X'01'                            60000020
         LA    RZERO,8(0,RPARM)         STCB ADDRESS                    60100020
         ST    RZERO,LCBRSKEY-IEDQLCB(0,RPARM)                          60200020
         MVI   LCBRSKEY-IEDQLCB(RPARM),PSVTO PUT SCHEDULER VTO          60300020
         MVI   LCBLSPCI+2-IEDQLCB(RPARM),1 INVALID CCW OP CODE          60400020
         EJECT                                                          60500020
REQUEST  EQU   *                                                        60600020
*                                                                     * 60700020
*        POST ERB TO BUFFER REQUEST QCB VIA DISPATCHER                * 60800020
*                                                                     * 60900020
         SPACE                                                          61000020
         STM   RCNT,RBFR,PESAVE         SAVE CONSTANT REGISTERS         61100020
         LR    RPARM,RERB               ADDRESS OF ERB TO POST          61200020
         B     DSPCHAIN                 POST ERB TO BUFFER REQUEST      61300020
         SPACE 3                                                        61400020
*                                                                     * 61420020
*              FLAG THE LAST UNIT OF BUFFER BY STORING INVALID        * 61440020
*              TIC ADDRESS IN ITS TIC FIELD.                          * 61460020
*                                                                     * 61480020
SETFLAG  EQU     *                                                      61500020
         L     RPARM,PEWATIC            ADDR OF CURRENT BFR UNIT        61600020
TICX     EQU   *                                                        61700020
         NC    9(2,RPARM),9(RPARM)      LAST UNIT IN BUFFER             61800020
         BZ    TICIT                    BRANCH IF YES                   61900020
         L     RPARM,8(0,RPARM)         GET ADDR OF NEXT UNIT           62000020
         B     TICX                     GO CHECK FOR LAST UNIT          62100020
TICIT    EQU   *                                                        62200020
         MVI   11(RPARM),INVTIC         INVALID TIC ADDRESS             62300020
         BR    RETURN                   RETURN TO CALLER.        S21903 62400004
         EJECT                                                          62500020
*                                                                     * 62600020
*     E Q U A T E S   A N D   R E A D - O N L Y   C O N S T A N T S   * 62700020
*                                                                     * 62800020
         SPACE                                                          62900020
ERBKEY   EQU   X'00'                    ELEMENT REQUEST BLOCK KEY       63000020
DEBNMEXT EQU   X'10'                    EXTENT OFFSET IN DEB    SA52991 63050022
MOVER    DS    0H                                                       63100020
         MVC   0(1,RBUF),0(RWORK)       EXECUTED INSTRUCTION THAT       63200020
*                                       MOVES DATA FROM A USER'S        63300020
*                                       WORKAREA TO A MCP BUFFER        63400020
PSVTO    EQU   X'12'                    HEX UI                   S22024 63600022
PUTFLG   EQU   X'02'                    PUT ERB IDENTIFIER              63700020
OUTFLG   EQU   X'0F'                    HEX 0F                   S22024 63800022
HDR      EQU   X'F1'                    WORKAREA CONTENTS CONTROL       64100020
*                                       BYTE VALUE FOR A HEADER         64200020
EOM      EQU   X'F2'                    WORKAREA CONTENTS CONTROL       64300020
*                                       BYTE VALUE FOR END OF MSG       64400020
TSOFLG   EQU   X'22'                    HEX 22                   S22024 64500022
VAR      EQU   X'40'                    HEX 40                   S22024 64600022
MSG      EQU   X'40'                    HEX 40                   S22024 64700022
CQMASK   EQU   X'F0'                    HEX F0                   S22024 64900022
RORIFLG  EQU   X'41'                    HEX JU                   S22024 65000022
EOL      EQU   X'80'                    END OF PARAMETER LIST           65100020
CFLG     EQU   X'40'                    HEX 40                   S22024 65300022
X3F      EQU   X'3F'                    HEX 3F                   S22024 65330022
DCBOPEN  EQU   X'10'                    HEX 10                   S22024 65360022
LOCKR    EQU X'20'                      HEX 20                   S22024 65390022
XPOST    EQU   X'20'                    HEX 20                   S22024 65420022
ERBBUSY  EQU   X'80'                    HEX 80                   S22024 65450022
PBUF     EQU   X'01'                    HEX 01                   S22024 65480022
SINGLE   EQU   X'60'                    HEX 60                   S22024 65510022
RELEASE  EQU   X'01'                    HEX 01                   S22024 65540022
TIC      EQU   X'08'                    TIC COMMAND                     65598020
INVTIC   EQU   2                        INVALID TIC ADDRESS             65599020
FOUR     EQU   4                        SHIFT CONSTANT          SA69971 65649055
         TPRIOR                                                         65700020
         EJECT                                                          65800020
*                                                                     * 65900020
*              D  S  E  C  T  S                                       * 66000020
*                                                                     * 66100020
         SPACE                                                          66200020
         TAVTD 2                        ADDRESS VECTOR TABLE            66300020
         TLCBD                          LINE CONTROL BLOCK              66400020
         TPRFD                          BUFFER PREFIX                   66500020
         TDISPD                         TCAM DISPATCHER                 66600020
         TTRMD                          PUT PROCESS ENTRY               66700020
         TDEBAPD                        DATA EXTENT BLOCK               66800020
         TPCBD                          PROCESS CONTROL BLOCK           66900020
         TACSMD                         TCAM ACCESS METHOD WORKAREA     67000020
         TPEWAD                         PROCESS ENTRY WORKAREA          67100020
         TSCBD                                                          67200020
         TQCBD                                                          67300020
         DCBD  DSORG=TX                                                 67400020
MASKOFF  EQU   X'FF'-LCBTETEN-LCBBFRSZ-LCBABRTN                         67500020
         END                                                            67600020
