ES01     TITLE '''IEDQES'' - TCAM/CQTAM RETRIEVE ROUTINE'               00200020
IEDQES   CSECT                                                          00400020
*C202600                                                         S21101 00460020
*D210600-211200                                                  S21101 00520020
*C668000                                                         A42396 00600021
*D391000,394100-395400,712500                                    A42396 00700021
*A350600-351200                                                  S22026 00750022
*A06600,078200-079200                                            S22025 00760022
*C066000,342000,362000,554000,580000,632000,654000,686000,712000 S22025 00770022
*D714000                                                                00780022
*C166000                                                        SA52502 00785022
*A170000,390000,708000                                          SA52502 00790022
*D202600-203200                                                 SA52502 00795022
*C414000,416000,424000,425000                                   SA66358 00797053
*********************************************************************** 00800020
*TITLE: 'IEDQES' TCAM/CQTAM RETRIEVE ROUTINE                          * 01000020
*FUNCTION: THIS ROUTINE PROVIDES SUPPORT COMPATIBLE WITH CQTAM        * 01200020
*   MESSAGE RETRIEVAL.  IT CONVERTS THE TERMNAME OF THE MESSAGE       * 01400020
*   DESTINATION TO A TNT OFFSET.  IT BUILDS A SPECIAL ELEMENT FOR     * 01600020
*   THE RETRIEVE SCHEDULER CONSISTING OF THE OFFSET AND MESSAGE       * 01800020
*   INFORMATION.  FOR HEADER BUFFER RETRIEVAL,  THE ELEMENT CONTAINS  * 02000020
*   THE SEQUENCE NUMBER AND TYPE.  FOR SUBSEQUENT RETRIEVAL, IT       * 02200020
*   CONTAINS THE RELATIVE RECORD ADDRESS OF THE BUFFER TO BE          * 02400020
*   RETRIEVED.                                                        * 02600020
*      AQCTL IS USED TO POST THE SPECIAL ELEMENT TO THE RETRIEVE      * 02800020
*   SCHEDULER'S QCB IN THE PCB.  WHEN THE BUFFER HAS BEEN RETRIEVED   * 03000020
*   OR AN ERROR HAS BEEN DETECTED, RETRIEVE GETS CONTROL.  IF NO      * 03200020
*   ERROR, IT BUILDS A CQTAM BUFFER IN THE USER'S WORKAREA.  IT       * 03400020
*   THEN POSTS A BUFFER RETURN ELEMENT TO THE RETRIEVE SCHEDULER      * 03600020
*   VIA AQCTL AND EXITS TO THE USER.                                  * 03800020
*ENTRY POINT:                                                         * 04000020
*        IEDQES                                                       * 04200020
*INPUT:                                                               * 04400020
*   0  - USER'S WORKAREA ADDRESS(WORKAREA CONTAINS TERMINAL NAME)     * 04600020
*   1  - SEQUENCE NUMBER FOR OUTPUT NUMBER (COMPLEMENT OF SEQUENCE    * 04800020
*        NUMBER FOR INPUT SEQUENCE NUMBER), OR RELATIVE RECORD        * 05000020
*        ADDRESS FOR SUBSEQUENT RETRIEVAL.                            * 05200020
*   13 - REGISTER SAVEAREA ADDRESS                                    * 05400020
*   14 - RETURN ADDRESS                                               * 05600020
*   15 - ENTRY POINT ADDRESS                                          * 05800020
*OUTPUT:                                                              * 06000020
*   15 - RETURN CODE                                                  * 06200020
*EXTERNAL ROUTINES:                                                   * 06400020
*        IEDQE8 - BINARY SEARCH ROUTINE                          S22025 06600022
*        IEDQTNT - TERMINAL TABLE CODE                           S22025 06700022
*        IGC102-AQCTL SVC                                             * 06800020
*EXITS-NORMAL:                                                        * 07000020
*        BUFFER MOVED INTO USER'S WORKAREA AND RETURN CODE OF 0 IN    * 07200020
*        REG 15                                                       * 07400020
*EXITS-ERROR:                                                         * 07600020
*        RETURN CODE OF 4(INVALID SEQ. NO. OR ADDR) IN REG 15         * 07800020
*        RETURN CODE OF X'20' IN REG 15 INDICATING ONE OF THE    S22025 07820022
*        FOLLOWING :                                             S22025 07840022
*          TCAM MCP NOT ACTIVE                                   S22025 07860022
*          NO TCAM DEB FOUND                                     S22025 07880022
*          CLOSEDOWN IN PROGRESS                                 S22025 07900022
*          DISK QUEUING NOT USED                                 S22025 07920022
*TABLES/WORKAREAS:                                                    * 08000020
*        CVT                                                          * 08200020
*        AVT                                                          * 08400020
*        DEB                                                          * 08600020
*        ACSMETH WORKAREA                                             * 08800020
*        PCB                                                          * 09000020
*        TERMINAL ENTRY                                               * 09200020
*        QCB                                                          * 09400020
*        TERMNAME TABLE                                               * 09600020
*        TCB                                                          * 09800020
*        SCB                                                          * 10000020
*        LCB                                                          * 10200020
*        BUFFER PREFIX                                                * 10400020
*ATTRIBUTES: REENTRANT, REFRESHABLE, PROBLEM PROGRAM MODE             * 10600020
*NOTES: THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 10800020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 11000020
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED   * 11200020
*   SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,     * 11400020
*   WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.          * 11600020
*********************************************************************** 11800020
         EJECT                                                          12000020
         SPACE 2                                                        12200020
*                                                                     * 12400020
*   S  Y  M  B  O  L  I  C    R  E  G  I  S  T  E  R  S               * 12600020
*                                                                     * 12800020
         SPACE 2                                                        13000020
RZERO    EQU   0                        GENERAL WORK REGISTER           13200020
RPARM    EQU   1                        PARAMETER REGISTER              13400020
RWORK    EQU   2                        GENERAL WORK REGISTER           13600020
RMOVE    EQU   3                        USER'S WORK AREA                13800020
RBFR     EQU   4                        TCAM BUFFER                     14000020
RPCB     EQU   5                        PROCESS CONTROL BLOCK           14200020
RWORKA   EQU   6                        ACCESS METHOD WORKAREA          14400020
RDEB     EQU   7                        DATA EXTENT BLOCK               14600020
RTCB     EQU   8                        TASK CONTROL BLOCK              14800020
RTERM    EQU   9                        TERMINAL TABLE ENTRY            15000020
RTNT     EQU   10                       TERMINAL NAME TABLE             15200020
RAVT     EQU   11                       TCAM ADDRESS VECTOR TABLE       15400020
RBASE    EQU   12                       CSECT BASE REGISTER             15600020
RSAVE    EQU   13                       SAVE AREA ADDRESS REGISTER      15800020
RETURN   EQU   14                       RETURN ADDRESS                  16000020
RENTRY   EQU   15                       ENTRY POINT/RETURN CODE REG     16200020
         SPACE 2                                                        16400020
         SAVE  (14,12)                  SAVE CALLER'S REGISTERS SA52502 16600022
         BALR  RBASE,RZERO              ESTABLISH                       16800020
         USING *,RBASE                           ADDRESSABILITY         17000020
IEDQES   IEDHJN   LABEL                 ID AND DATE             SA52502 17100022
         EJECT                                                          17200020
         USING IEDQPCB,RPCB             PROCESS CONTROL BLOCK           17400020
         USING IEDQAVTD,RAVT            TCAM ADDRESS VECTOR TABLE       17600020
         USING IEDQTNTD,RTNT            TCAM TERMINAL NAME TABLE        17800020
         USING IEDQTRM,RTERM            TERMINAL TABLE ENTRY            18000020
         USING IEDQTCB,RTCB             TASK CONTROL BLOCK              18200020
         USING IEDQDEB,RDEB             DATA EXTENT BLOCK               18400020
         USING IEDQWRKA,RWORKA          ACCESS METHOD WORKAREA          18600020
         EJECT                                                          18800020
         L     RAVT,CVT                 ADDR OF CVT                     19000020
         L     RAVT,AVTCVTPT(0,RAVT)    ADDR OF TCAM LOAD LIST          19200020
         LTR   RAVT,RAVT                TCAM MCP ACTIVE                 19400020
         BNZ   GO                       BRANCH IF YES                   19600020
NOMCP    EQU   *                                                        19800020
         LA    RENTRY,NOTCAM            ERROR COMPLETION CODE           20000020
         B     EXIT                     RETURN TO USER                  20200020
GO       EQU   *                                                        20400020
         L     RAVT,0(0,RAVT)           ADDRESS OF AVT                  20600020
         TM    AVTBIT1,AVTCLOSN         CLOSEDOWN IN PROGRESS           20800020
         BO    NOMCP                    BRANCH IF YES                   21000020
         TM    AVTBIT1,AVTDISKN         DISK QUEUEING SUPPORTED         21020020
         BNO   NOMCP                    BRANCH IF NO                    21040020
ONEDISK  EQU   *                                                        21140020
         LR    RMOVE,RZERO              USER'S WORKAREA ADDRESS         21200020
         LR    RBFR,RPARM               SEQUENCE NUMBER OR RELATIVE     21400020
*                                       RECORD ADDRESS                  21600020
*                                                                     * 21800020
*        FIND AN ACCESS METHOD WORKAREA TO USE TEMPORARILY            * 22000020
*                                                                     * 22200020
         L     RTCB,CVT                 ADDRESS OF CVT                  22400020
         L     RTCB,0(0,RTCB)           POINTER TO NEXT AND             22600020
*                                       CURRENT TCB ADDRESSES           22800020
         L     RTCB,4(0,RTCB)           ADDRESS OF CURRENT TCB          23000020
         L     RDEB,TCBDEB              ADDRESS OF FIRST DEB            23200020
LOOP     EQU   *                                                        23400020
         LA    RDEB,0(0,RDEB)           CLEAR HIGH-ORDER BYTE           23600020
         LTR   RDEB,RDEB                DEB CHAIN EXHAUSTED BEFORE      23800020
*                                       TCAM DEB HAS BEEN FOUND         24000020
         BNZ   OK                       BRANCH IF NO                    24200020
         LA    RENTRY,NOPEN             ERROR COMPLETION CODE           24400020
         B     EXIT                     RETURN TO USER                  24600020
OK       EQU   *                                                        24800020
         TM    DEBTAMID,ID              TCAM DEB                        25000020
         BO    TCAMDEB                  BRANCH IF YES                   25200020
         L     RDEB,DEBDEBAD-1          ADDRESS OF NEXT DEB             25400020
         B     LOOP                     GO LOOK AT IT                   25600020
TCAMDEB  EQU   *                                                        25800020
         L     RWORKA,DEBTAMWA-1        ADDRESS OF ACCESS METHOD        26000020
*                                       WORKAREA                        26200020
         ST    RSAVE,GWASAVA+4          ADDRESS OF CALLER'S REGS        26400020
*                                       REGISTER SAVEAREA               26600020
         LA    RPARM,GWASAVA            ADDRESS OF MY SAVEAREA          26660020
         ST    RPARM,8(0,RSAVE)         PUT INTO CALLER'S SAVEAREA      26720020
         LA    RSAVE,GWASAVA            QCOPY'S REGISTER SAVEAREA       26800020
         CLI   0(RMOVE),0               SUBSEQUENT RETRIEVAL            26860020
         BE    NAMEOK                   BRANCH IF YES                   26920020
         L     RTNT,AVTRNMPT            ADDRESS OF TERMNAME TABLE       27000020
         L     RENTRY,AVTE8             LOAD ADDR OF BINARY SRCH S22025 27200022
         BALR  RETURN,RENTRY            BRANCH TO SEARCH ROUTINE S22025 28100022
BACK     EQU   *                                                        29000020
         LTR   RENTRY,RENTRY            TERMNAME VALID                  29200020
         BNZ   NAMEOK                   BRANCH IF YES                   29400020
ERROR    EQU   *                                                        29600020
         LA    RENTRY,INVTN             ERROR COMPLETION CODE           29800020
         B     PREEXIT                  RETURN TO USER                  30000020
         EJECT                                                          30200020
NAMEOK   EQU   *                                                        30400020
         LR    RPARM,RENTRY             TERMNAME TABLE OFFSET           30600020
         LR    RTNT,RPARM               SAVE TNT OFFSET                 30800020
         L     RPCB,DEBPCBAD-1          PROCESS CONTROL BLOCK ADDR      31000020
         LA    RPARM,8(0,RPCB)          RETRIEVE QCB ADDRESS            31200020
         ST    RPARM,GWAELEM            STORE IN SPECIAL ELEMENT        31400020
         MVI   GWAELEM+4,PRIRTBFR       SET PRIORITY                    31600020
         ST    RBFR,GWAELEM+8           ADDR OF TERMINAL ENTRY OR       31800020
*                                       RECORD ADDRESS                  32000020
         XC    GWAELEM+5(3),GWAELEM+5   SET LINK FIELD TO ZERO          32200020
         MVC   GWAELEM+14(2),PCBWRKA+14 SAVE OLD TNT OFFSET             32400020
         CLI   0(RMOVE),0               SUBSEQUENT RETRIEVAL BY         32600020
*                                       RECORD ADDRESS                  32800020
         BE    SETELEM                  BRANCH IF YES                   33000020
         STH   RTNT,GWAELEM+14          TNT OFFSET                      33100020
*                                                                     * 33200020
*       ASSUME ADDRESS RETRIEVAL ** TEST FOR SEQUENCE NUMBER TYPE     * 33400020
*                                                                     * 33600020
         LR    RPARM,RTNT                                               33800020
         L     RENTRY,AVTRNMPT                                          34000020
         BALR  RETURN,RENTRY            LINK TO TERMINAL TABLE   S22025 34200022
*                                       ROUTINE                         34300022
         ST    RPARM,GWAELEM+8                                          34400020
         L     RPARM,TRMDESTQ-1-IEDQTRM(0,RPARM) DEST QCB ADDRESS       34600020
         CLI   QCBDSFLG-IEDQQCB(RPARM),QCBCORE+QCBFQCB CORE-ONLY QCB    34800020
         BE    ERROR                    BRANCH IF YES                   35000020
         TM    QCBDSFLG-IEDQQCB(RPARM),QCBDRQQ  CONC DRQ         S22026 35060022
         BO    ERROR                    BRANCH IF YES            S22026 35120022
         LTR   RBFR,RBFR                INPUT SEQUENCE                  35200020
         BM    INPUT                    BRANCH IF YES                   35400020
         MVI   GWAELEM+8,C'O'           INDICATE SEARCH BY OUTPUT       35600020
*                                       SEQUENCE NUMBER                 35800020
         STH   RBFR,GWAELEM+12          STORE IN SPECIAL ELEMENT        36000020
         B     ZIPTEST                  GO CHECK FOR SEQ # = 0   S22025 36200022
INPUT    EQU   *                                                        36400020
         LCR   RBFR,RBFR                GET COMPLEMENT OF NEGATIVE      36600020
*                                       SEQUENCE NUMBER                 36800020
         STH   RBFR,GWAELEM+12          STORE IN SPECIAL ELEMENT        37000020
         MVI   GWAELEM+8,C'I'           INDICATE SEARCH BY INPUT        37200020
*                                       SEQUENCE NUMBER                 37400020
ZIPTEST  EQU   *                                                        37600020
         NC    GWAELEM+12(2),GWAELEM+12 SEQ NO EQUAL TO ZERO            37800020
         BZ    BADOUT                   BRANCH IF YES                   38000020
         B     POST                     GO POST ELEMENT                 38200020
         EJECT                                                          38400020
SETELEM  EQU   *                                                        38600020
         MVI   GWAELEM+8,0              INDICATE SUBSEQUENT             38800020
*                                       RETRIEVAL                       39000020
         SPACE                                                          39006022
*                                                               SA52502 39012022
*        PERFORM VALIDITY CHECKING ON USER'S RELATIVE RECORD NO.SA52502 39018022
*                                                               SA52502 39024022
         SPACE 2                                                        39030022
         NC    GWAELEM+9(3),GWAELEM+9   ZERO RECORD NUMBER      SA52502 39036022
         BE    BADRRN                   BRANCH IF YES           SA52502 39042022
         TM    GWAELEM+E11,REUS         REUSABLE DISK           SA52502 39048022
         BO    REUSDISK                 BRANCH IF YES           SA52502 39054022
         CLC   AVTADEBN,AVTFZERO        NONREUS DISK OPEN       SA52502 39060022
         BE    BADRRN                   BRANCH IF NO            SA52502 39066022
         L     RENTRY,AVTADEBN+AVTECD16 NONREUS THRESHOLD VALUE SA52502 39072022
         SR    RZERO,RZERO              CLEAR FOR DIVISION      SA52502 39078022
         LA    RPARM,AVTEZERO(,RBFR)    RELATIVE RECORD NUMBER  SA52502 39084022
         LA    RPARM,ROUNDER(,RPARM)    ADJUST THE              SA52502 39090022
         SRL   RPARM,DIV4               RELATIVE RECORD NUMBER  SA52502 39096022
         DR    RPARM-1,RENTRY           COMPUTE LOGICAL VALUE   SA52502 39102022
         L     RZERO,AVTHRESN           THRESHOLD VALUE         SA52502 39108022
         CR    RPARM,RZERO              THRESHOLD EXCEEDED      SA52502 39114022
         BH    BADRRN                   BRANCH IF YES           SA52502 39120022
         B     POST                     POST SPECIAL ELEMENT    SA52502 39126022
         SPACE 2                                                        39132022
REUSDISK EQU   *                                                SA52502 39138022
         CLC   AVTADEBR,AVTFZERO        REUS DISK OPEN          SA52502 39144022
         BNE   POST                     BRANCH IF YES           SA52502 39150022
         SPACE 2                                                        39156022
BADRRN   EQU   *                                                SA52502 39162022
         LA    RENTRY,RRNERR            ERROR RETURN CODE       SA52502 39168022
         B     PREEXIT                  RETURN TO USER          SA52502 39174022
         EJECT                                                          39180022
         SPACE 2                                                        39200020
POST     EQU   *                                                        39400020
*                                                                     * 39600020
*        POST SPECIAL ELEMENT TO RETRIEVE SCHEDULER                   * 39800020
*                                                                     * 40000020
         LA    RZERO,GWAELEM            SPECIAL ELEMENT ADDR(AP)        40200020
         LA    RPARM,PCBWRKA            SPECIAL ELEMENT ADDR(MCP)       40400020
         LA    RWORK,SELEMLEN           SPEC ELEM LENGTH ADDR           40600020
         STM   RZERO,RWORK,GWALIST      SET UP AQCTL PARAMETER LIST     40800020
         MVI   GWALIST,CODE             AQCTL ACTION CODE               41000020
         MVI   GWALIST+8,EOL            END-OF-LIST INDICATOR           41200020
         XC    GWASAVA+16(4),GWASAVA+16 CLEAR ECB TO ZERO       SA66358 41400053
         LA    RPARM,GWASAVA+16         ECB ADDRESS             SA66358 41600053
         ST    RPARM,GWAELEM+16         STORE IN SPECIAL ELEMENT        41800020
         LA    RPARM,GWALIST            AQCTL PARAMETER LIST            42000020
         AQCTL                                                          42200020
         WAIT  ECB=GWASAVA+16           WAIT FOR RETRIEVE       SA66358 42400053
         XC    GWASAVA+16(4),GWASAVA+16 CLEAR ECB TO ZERO       SA66358 42500053
         CLI   GWAELEM+8,X'FF'          RETURNED BUFFER                 42530020
         BE    GOODOUT                  BRANCH IF YES                   42560020
         CLI   PCBORC,0                 NORMAL COMPLETION               42600020
         BE    MOVE                     BRANCH IF YES TO MOVE DATA      42800020
BADOUT   EQU   *                                                        43000020
         LA    RENTRY,INVSEQ            ERROR CODE                      43200020
         B     PREEXIT                  PREPARE TO RETURN TO USER       43400020
         EJECT                                                          43600020
GOODOUT  EQU   *                                                        43800020
         SR    RENTRY,RENTRY            NORMAL COMPLETION CODE          44000020
PREEXIT  EQU   *                                                        44200020
         L     RSAVE,GWASAVA+4          ADDRESS OF CALLER'S REGS        44400020
EXIT     EQU   *                                                        44600020
         RETURN (14,12),T,RC=(15)       RETURN TO USER                  44800020
         EJECT                                                          45000020
MOVE     EQU   *                                                        45200020
*                                                                     * 45400020
*     BUILD CQTAM BUFFER FROM TCAM BUFFER PREFIX                      * 45600020
*                                                                     * 45800020
         USING IECKPREF+8,RMOVE         CQTAM BUFFER PREFIX             46000020
         L     RBFR,8(0,RPCB)           TCAM BUFFER ADDRESS             46200020
         USING IEDQPRF,RBFR             TCAM BUFFER PREFIX              46400020
         MVC   TTSKEY(2),PRFSRCE        SOURCE TNT OFFSET               46600020
         MVC   MSLCB(3),PRFCRCD         CURRENT SEGMENT ADDRESS         46800020
         LA    RMAX,MSTATUS             STATUS BYTE ADDRESS             47000020
         L     RPARM,12(0,RPCB)         LCB/SCB ADDRESS                 47200020
         LA    RPARM,LCBCPA-IEDQLCB(0,RPARM) SCB ADDRESS                47400020
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   47600020
         BO    TEXT                     BRANCH IF NO                    47800020
         MVI   MSTATUS,0                SET HEADER FLAG                 48000020
         MVC   MSHEAD(3),PRFHQBCK       ADDR OF PREVIOUS MSG HDR        48200020
         MVC   MSDLINK(3),PRFNHDR       ADDR OF NEXT HEADER             48400020
         MVC   MSLINK(3),SCBDEOB+1-IEDQSCB(RPARM) NEXT SEG ADDR         48500020
         MVC   MSPTR(1),PRFSCAN+1       SCAN POINTER                    48600020
         MVC   TTDKEY(2),PRFDEST        DESTINATION TNT OFFSET          48800020
         MVC   MSNUMIN(2),PRFISEQ       INPUT SEQUENCE NUMBER           49000020
         MVC   MSNUMOUT(2),SCBOSEQ-IEDQSCB(RPARM)                       49200020
*                                       OUTPUT SEQUENCE NUMBER          49400020
         LA    RMOVE,HDSTRT             FIRST EMPTY BYTE IN             49600020
*                                       USER'S WORKAREA                 49800020
         LA    RBUF,PRFSHDR             FIRST DATA BYTE IN BUFFER       50000020
         B     EOMTEST                  GO COMPLETE MSTATUS             50200020
         SPACE 2                                                        50400020
TEXT     EQU   *                                                        50600020
         MVC   MSHEAD-MSTATUS(3,RMAX),PRFCHDR CURRENT HDR ADDRESS       50800020
         MVC   MSLINK(3),SCBDEOB+1-IEDQSCB(RPARM) NEXT SEG ADDR         51000020
         LA    RMOVE,TXSTRT             FIRST EMPTY BYTE IN             51200020
*                                       USER'S WORKAREA                 51400020
         LA    RBUF,PRFSTXT             FIRST DATA BYTE IN BUFFER       51600020
         MVI   0(RMAX),1                SET TEXT FLAG IN MSTATUS        51800020
EOMTEST  EQU   *                                                        52000020
         TM    PRFSTAT1,PRFNLSTN        EOM SEGMENT                     52200020
         BO    DATA                     BRANCH IF NO                    52400020
         OI    0(RMAX),X'02'            SET EOM FLAG IN MSTATUS         52600020
         EJECT                                                          52800020
DATA     EQU   *                                                        53000020
*                                                                     * 53200020
*       FILL WORKAREA WITH TEXT PORTION OF CURRENT BUFFER             * 53400020
*                                                                     * 53600020
         SPACE                                                          53800020
         SR    RWORK,RWORK                                              54000020
         LH    RWORK,PRFSIZE            TOTAL COUNT OF BYTES TO         54200020
*                                       BE MOVED                        54400020
         N     RWORK,HIOFF              CLEAR HIGH-ORDER HALF           54600020
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   54800020
         BO    SHORTP                   BRANCH IF NO                    55000020
         LA    RZERO,PRFSHDR-PRFSUNIT   HEADER PREFIX LENGTH            55200020
         B     STOREP                   GO CHECK BUFFER PREFIX   S22025 55400022
SHORTP   EQU   *                                                        55600020
         LA    RZERO,PRFSTXT-PRFSUNIT   TEXT PREFIX LENGTH              55800020
STOREP   EQU   *                                                        56000020
         SR    RWORK,RZERO              ACTUAL NUMBER OF BYTES          56200020
         SH    RWORK,PRFSCAN            SUBTRACT IDLE CHAR COUNT        56400020
        AH    RBUF,PRFSCAN             BUMP PAST IDLE CHARS             56600020
         STH   RWORK,GWASAVA+12         SAVE IDLE COUNT                 56800020
         SH    RMAX,AVTHA4              POINT TO MSEGSZE FIELD          57000020
         LR    RZERO,RWORK              ACTYAL BYTE COUNT               57200020
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   57400020
         BO    NO                       BRANCH IF NO                    57600020
         LA    RPARM,HDSTRT-FDATA       HEADER PREFIX LENGTH            57800020
         B     FIX                      SKIP ADJUSTMENT FOR TEXT S22025 58000022
*                                       PREFIX                   S22025 58100022
NO       EQU   *                                                        58200020
         LA    RPARM,TXSTRT-FDATA       TEXT PREFIX LENGTH              58400020
FIX      EQU   *                                                        58600020
         AR    RZERO,RPARM              ADD PREFIX LENGTH TO SEGSIZE    58800020
         STH   RZERO,GWASAVA+12         UPDATE MSEGSIZE                 59000020
         MVC   0(2,RMAX),GWASAVA+12     DATA LENGTH                     59200020
RMAX     EQU   9                        MAX DATA BYTES IN ONE UNIT      59400020
         SR    RMAX,RMAX                                                59600020
         LH    RMAX,AVTKEYLE            MAX DATA PER BUFFER UNIT        59800020
RBUF     EQU   8                        NEXT BYTE TO BE MOVED           60000020
         CLC   PRFTIC+1(2),AVTFZERO     SINGLE-UNIT BUFFER              60200020
         BNZ   MORE                     BRANCH IF NO                    60400020
LAST     EQU   *                                                        60600020
         BCTR  RWORK,RZERO              DECREMENT COUNT BY ONE          60800020
         EX    RWORK,MOVER              EMPTY THE BUFFER                61000020
         B     CLEANUP                  RETURN BUFFER                   61200020
         SPACE 2                                                        61400020
MORE     EQU   *                                                        61600020
         LR    RPARM,RBFR               UNIT ADDRESS                    61800020
         LR    RENTRY,RBFR              START OF BUFFER                 62000020
         AH    RENTRY,AVTKEYLE                                          62200020
         LA    RENTRY,AVTUMALN(0,RENTRY) END OF UNIT                    62400020
         SR    RENTRY,RBUF              DATA IN FIRST UNIT              62600020
         SH    RENTRY,PRFSCAN           SUBTRACT IDLE CHAR COUNT        62800020
EMPTY    EQU   *                                                        63000020
         BCTR  RENTRY,RZERO             DECREMENT BY ONE         S22025 63200022
         EX    RENTRY,MOVER             EMPTY FIRST UNIT                63400020
         LA    RENTRY,1(0,RENTRY)                                       63600020
         AR    RMOVE,RENTRY             ADDR OF NEXT EMPTY BYTE         63800020
         SR    RWORK,RENTRY             COUNT OF DATA TO BE MOVED       64000020
         L     RPARM,8(0,RPARM)         ADDRESS OF NEXT UNIT            64200020
         LA    RBUF,AVTUMALN(0,RPARM)   DATA ADDRESS                    64400020
         CLC   9(2,RPARM),AVTFZERO      LAST UNIT IN BUFFER             64800020
         BZ    LAST                     BRANCH IF YES                   65000020
         LR    RENTRY,RMAX                                              65200020
         B     EMPTY                    GO EMPTY ANOTHER UNIT    S22025 65400022
         EJECT                                                          65600020
CLEANUP  EQU   *                                                        65800020
*                                                                     * 66000020
*      BUILD BUFFER RETURN ELEMENT AND POST VIA AQCTL                 * 66200020
*                                                                     * 66400020
         MVI   GWAELEM+8,X'FF'          BUFFER RETURN CODE              66600020
         B     POST                     BRANCH TO POST BUFFER    A42396 66800021
         EJECT                                                          67600020
*                                                                     * 67800020
*        C O N S T A N T S    A N D    E Q U A T E S                  * 68000020
*                                                                     * 68200020
         SPACE 2                                                        68400020
SELEMLEN DC    H'20'                    SPECIAL ELEMENT LENGTH   S22025 68600022
MOVER    DS    0H                                                       68800020
         MVC   0(1,RMOVE),0(RBUF)       MOVE FROM BFR TO WORKAREA       69000020
NOTCAM   EQU   X'20'                                                    69200020
PRIRTBFR EQU   X'D4'                                                    69400020
NOPEN    EQU   X'20'                                                    69600020
INVTN    EQU   X'20'                                                    69800020
INVSEQ   EQU   X'40'                                                    70000020
CODE     EQU   X'0C'                                                    70200020
EOL      EQU   X'80'                                                    70400020
CVT      EQU   16                                                       70600020
ID       EQU   X'C0'                                                    70800020
E11      EQU   11                       CONSTANT                SA52502 70830022
REUS     EQU   X'03'                    REUS DISK RRN FLAG      SA52502 70860022
ROUNDER  EQU   3                        CONSTANT                SA52502 70890022
DIV4     EQU   2                        CONSTANT                SA52502 70920022
RRNERR   EQU   X'02'                    INVALID REL REC NO.     SA52502 70950022
         DS    0F                                                       71000020
HIOFF    DC    X'0000FFFF'              MASK TO CLEAR HIGH ORDER S22025 71200022
*                                       HALF OF REGISTER         S22025 71250022
PROC     EQU   X'20'                                                    71300020
PROCESS  EQU   X'C0'                                                    71350020
         TPRIOR                                                         71600020
         EJECT                                                          71800020
*                                                                     * 72000020
*        D   S   E   C   T   S                                        * 72200020
*                                                                     * 72400020
         SPACE 2                                                        72600020
         TAVTD                                                          72800020
         TACSMD                                                         73000020
         TTRMD                                                          73200020
         TTNTD                                                          73400020
         TDEBAPD                                                        73600020
         TTCBD                                                          73800020
         TPCBD                                                          74000020
         TPRFD                                                          74200020
         TSCBD                                                          74400020
         TLCBD                                                          74600020
         TQCBD                                                          74800020
         EJECT                                                          75000020
* HEADER AND TEXT PREFIX DEFINITION                                     75200020
         SPACE                                                          75400020
*            **THE FOLLOWING APPLY TO HEADER AND TEXT SEGMENTS**        75600020
         SPACE                                                          75800020
IECKPREF DSECT  CURRENT QTAM BUFFER PREFIX                              76000020
FBLOCK   EQU   IECKPREF                                                 76200020
         SPACE                                                          76400020
MSQUEUE  DS    0XL4 QUEUEING INFORMATION--                              76600020
FKEY     DS    XL1 KEY FIELD ALWAYS ZERO                                76800020
FQUEUE   DS    AL3 ADDR OF QCB TO WHICH POSTED                          77000020
FPRI     DS    0XL1                                                     77200020
MSPRIOR  DS    XL1 MESSAGE PRIORITY                                     77400020
FLINK    DS    0AL3                                                     77600020
MSQLINK  DS    AL3 ADDR OF NEXT STCB OR NEXT ITEM ON READY Q            77800020
         SPACE                                                          78000020
FDATA    DS    0A                                                       78200020
MSTIC    DS    0A                                                       78400020
MSEGSZE  DS    XL2 SEGMENT SIZE                                         78600020
TTSKEY   DS    XL2 SOURCE KEY                                           78800020
MSTATUS  DS    XL1 MESSAGE STATUS INDICATORS                            79000020
*                   BIT  -----IF ZERO---   --IF NON-ZERO---             79200020
*          CANCEL    0   CHAIN MESSAGE       DO NOT CHAIN               79400020
*          REROUTE   1   ORIG MSG HDR        DUPL MSG HDR               79600020
*          EOB       2   NO IMBEDDED EOB     EOB NOT LAST CHAR IN BUFF  79800020
*          SRVCD     3   OUT MSG NOT         OUT MSG                    80000020
*                        PREV SERVICED       PREV SERVICED              80200020
*          TRUNC     4   MSG COMPLETE        MSG INCOMPLETE             80400020
*          PRIORITY  5   MSG WITH NO         MSG WITH                   80600020
*                        PRIORITY            PRIORITY                   80800020
*          SEGTP    6-7  00=HDR,01=TEXT,10=HDR(EOM),11=TEXT(EOM)        81000020
MSLCB    DS    AL3 MSG ADDR ON DIRECT-ACCESS DEVICE                     81200020
MSLINK   DS    AL3 ADDR OF NEXT SEGMENT                                 81400020
MSMLINK  DS    0AL3                                                     81600020
MSHEAD   DS    AL3 IF HDR SEG=ADDR OF PREVIOUS MSG HDR                  81800020
*                   IF TXT SEG=ADDR OF HDR FOR THIS MSG                 82000020
TXSTRT   DS    0C START OF MSG TEXT IF TEXT SEG                         82200020
         SPACE                                                          82400020
*            **THE FOLLOWING APPLIES ONLY TO HEADER SEGMENTS**          82600020
MSDLINK  DS    AL3 ADDR OF NEXT MSG                                     82800020
MSPTR    DS    XL1 STORED SCAN PTR                                      83000020
TTDKEY   DS    XL2 DESTINATION KEY                                      83200020
MSNUMIN  DS    XL2 IN MSG SEQUENCE NUMBER                               83400020
MSNUMOUT DS    XL2 OUT MSG SEQUENCE NUMBER                              83600020
HDSTRT   DS    0C START OF MSG HEADER IF HDR SEG                        83800020
         END                                                            84000020
