ET01     TITLE '''IEDQET'' - OPER. CTL./APPL. PROG. INTERFACE'          00400020
IEDQET   CSECT                                                          00800020
*D856000                                                         S21903 00810022
*C288500,428000,436000,499000,536000,680000,732000,736000,740000 S21903 00820022
*A548000                                                        SA55391 00920022
         SPACE 4                                                        01200020
*********************************************************************** 01600020
*                                                                     * 02000020
*TITLE: 'IEDQET' OPERATOR CONTROL/APPL. PROG. INTERFACE ROUTINE       * 02400020
*FUNCTION: THIS ROUTINE ALLOWS THE USER TO PERFORM A SUBSET OF TCAM   * 02800020
*   OPERATOR CONTROL FUNCTIONS FROM THE APPLICATION PROGRAM.  A       * 03200020
*   COMMAND INPUT BUFFER(CIB) IS MOVED INTO THE PCB AND POSTED TO     * 03600020
*   THE OPERATOR CONTROL QCB VIA AQCTL.  THE APPL. PROG. TASK THEN    * 04000020
*   WAITS FOR THE CIB TO BE PROCESSED.  THE ROUTINE, AFTER THE POST,  * 04400020
*   LOADS THE RETURN CODE PASSED BY OPERATOR CONTROL TO THE USER FOR  * 04800020
*   INSPECTION.  IF THE MCP IS PASSWORD-PROTECTED, THIS ROUTINE       * 05200020
*   TESTS FOR THE PRESENCE OF A VALID PASSWORD BEFORE INVOKING        * 05600020
*   OPERATOR CONTROL.                                                 * 06000020
*ENTRY POINT:                                                         * 06400020
*        IEDQET                                                       * 06800020
*INPUT:                                                               * 07200020
*   0  - PASSWORD ADDRESS OR BINARY ZERO                              * 07600020
*   1  - COMMAND INPUT BUFFER ADDRESS                                 * 08000020
*   13 - REGISTER SAVEAREA ADDRESS                                    * 08400020
*   14 - RETURN ADDRESS                                               * 08800020
*   15 - ENTRY POINT ADDRESS                                          * 09200020
*OUTPUT:                                                              * 09600020
*   15 - RETURN CODE                                                  * 10000020
*EXTERNAL ROUTINES:                                                   * 10400020
*        IEDQE6-PASSWORD SCRAMBLER                                    * 10800020
*        IGC102-AQCTL SVC                                             * 11200020
*        IGC001-WAIT SVC                                              * 11600020
*        IGC006-LINK SVC                                              * 12000020
*EXITS-NORMAL:                                                        * 12400020
*        RETURNS TO CALLER WITH RETURN CODE OF 0 IN REG 15            * 12800020
*EXITS-ERROR:                                                         * 13200020
*        RETURNS TO CALLER WITH NON-ZERO RETURN CODE IN REG 15        * 13600020
*        X'40'- INVALID OR MISSING PASSWORD                           * 14000020
*TABLES/WORKAREAS:                                                    * 14400020
*        CIB                                                          * 14800020
*        CVT                                                          * 15200020
*        AVT                                                          * 15600020
*        PCB                                                          * 16000020
*ATTRIBUTES: REENTRANT, REFRESHABLE, PROBLEM PROGRAM MODE             * 16400020
*                                                                       16800020
*NOTES: THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 17200020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 17600020
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED   * 18000020
*   SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,     * 18400020
*   WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.          * 18800020
*********************************************************************** 19200020
         EJECT                                                          19600020
RZERO    EQU   0                        GENERAL WORK REGISTER           20000020
RPARM    EQU   1                        PARAMETER REGISTER              20400020
R2       EQU   2                        RESERVED                        20800020
R3       EQU   3                        RESERVED                        21200020
R4       EQU   4                        RESERVED                        21600020
RECB     EQU   5                        EVENT CONTROL BLOCK             22000020
RCVT     EQU   6                        COMMUNICATIONS VECTOR TABLE     22400020
RWORK    EQU   7                        GENERAL WORK REGISTER           22800020
RTCB     EQU   8                        APPL. PROG TCB ADDRESS          23200020
RCIB     EQU   9                        COMMAND INPUT BUFFER            23600020
RPCB     EQU   10                       PROCESS CONTROL BLOCK           24000020
RAVT     EQU   11                       ADDRESS VECTOR TABLE            24400020
RBASE    EQU   12                       CSECT BASE REGISTER             24800020
RSAVE    EQU   13                       SAVEAREA ADDRESS                25200020
RETURN   EQU   14                       RETURN ADDRESS                  25600020
RENTRY   EQU   15                       ENTRY POINT/RETURN CODE         26000020
*                                                                     * 26400020
*          S Y M B O L I C    R E G I S T E R S                       * 26800020
*                                                                     * 27200020
         SPACE 2                                                        27600020
         SAVE  (14,12),,*               SAVE CALLER'S REGISTERS         28000020
         BALR  RBASE,RZERO              ESTABLISH                       28400020
         USING *,RBASE                           ADDRESSABILITY         28800020
         B     DATE                     BRANCH AROUND DATE       S21903 28850022
         IEDHJN                                                         28900022
DATE     DS    0H                                                       28950020
         ST    RSAVE,ETSAVE+4           ADDRESS OF CALLER'S REGS        29000020
         LA    R4,ETSAVE                ADDRESS OF MY SAVEAREA          29200020
         ST    R4,8(0,RSAVE)            PUT IT IN CALLER'S SAVEAREA     29400020
         LR    RSAVE,R4                 ADDRESS OF MY SAVEAREA          29700020
         EJECT                                                          30000020
         L     RCVT,CVT                 ADDRESS OF CVT                  30400020
         CLC   AVTCVTPT+1(2,RCVT),ZIP                                   30800020
*                                       IS TCAM MCP ACTIVE              31200020
         BNE   START                    BRANCH IF YES                   31600020
ERROR    EQU   *                                                        32000020
         LA    RENTRY,NOTCAM            SET COMPLETION CODE             32400020
EXIT     EQU   *                                                        32800020
         L     RSAVE,ETSAVE+4           ADDRESS OF CALLER'S REGS        33200020
         RETURN (14,12),T,RC=(15)       RETURN TO CALLER                33600020
         SPACE 2                                                        34000020
START    EQU   *                                                        34400020
         L     RAVT,AVTCVTPT(0,RCVT)    ADDRESS OF TCAM LIST            34800020
         L     RAVT,0(0,RAVT)           ADDRESS OF TCAM AVT             35200020
         USING IEDQAVTD,RAVT            ADDRESS VECTOR TABLE            35600020
         USING IEDQPCB,RPCB             PROCESS CONTROL BLOCK           36000020
         USING IEDQCIB,RCIB             COMMAND INPUT BUFFER            36400020
         USING ETCVT,RCVT               COMMUNICATIONS VECTOR TABLE     36600020
         LA    RPARM,0(0,RPARM)                                         36800020
         LTR   RPARM,RPARM              BAD RELATIVE LINE NUMBER        37200020
         BZ    TSOERROR                 IF YES, TAKE ERROR EXIT         37600020
         LR    RCIB,RPARM               ADDRESS OF CIB                  38000020
         EJECT                                                          38400020
         CLI   CIBRC,CQTAM              PASSWORD APPLICABLE             38800020
         BE    NOPASS                   BRANCH IF YES TO AVOID TEST     39200020
         CLC   AVTPASWD(8),BLANKS       PASSWORD IN AVT                 39600020
         BE    NOPASS                   BRANCH IF NO                    40000020
         LTR   RZERO,RZERO              PASSWORD TO BE UNSCRAMBLED      40400020
         BZ    PWERR                    BRANCH IF NO                    40800020
         LR    RPARM,RZERO              PUT ADDRESS OF PASSWORD IN      41200020
*                                       PARAMETER REGISTER              41600020
         LINK  EP=IEDQE6                TCAM PASSWORD SCRAMBLER         42000020
         C     RZERO,AVTPASWD                                           42400020
         BNE   PWERR                    BRANCH TO SETUP ERROR RTNS21903 42800022
         C     RPARM,AVTPASWD+4                                         43200020
         BE    PASSOK                   BRANCH TO CONTINUE       S21903 43600022
PWERR    EQU   *                                                        44000020
         LA    RENTRY,BADPASS           PASSWORD ERROR INDICATOR        44400020
         B     EXIT                     RETURN TO USER                  44800020
         EJECT                                                          45200020
PASSOK   EQU   *                                                        45600020
NOPASS   EQU   *                                                        46000020
         MVI   CIBRC,0                  CLEAR COMPLETION CODE TO ZERO   46400020
*                                                                     * 46800020
*        DO SPECIAL PROCESSING FOR CLOSEDOWN                          * 47200020
*                                                                     * 47600020
         SPACE                                                          48000020
         TM    CIBVERB,CLOSE            MCPCLOSE OR CLOSEMC             48400020
         BZ    NOCLOSE                  BRANCH IF NEITHER               48800020
         TM    AVTBIT1,AVTCLOSN         CLOSEDOWN ALREADY BEGUN         49200020
         BO    NOP                      BRANCH IF YES                   49600020
         TM    CVTTSFLG,CVTTSRDY        TSO STILL ACTIVE                49700020
         BO    TSOERROR                 BRANCH IF YES TO REJECT         49800020
*                                       THIS CLOSEDOWN REQUEST          49900022
NOCLOSE  EQU   *                                                        50000020
*                                                                     * 50400020
*        FIND ADDRESS OF TCB FOR APPLICATION PROGRAM                  * 50800020
*                                                                     * 51200020
         L     RWORK,0(0,RCVT)          ADDRESS OF FIELD POINTING       51600020
*                                       TO NEXT AND CURRENT TCBS        52000020
         L     RTCB,4(0,RWORK)          APPL PROG TCB POINTER           52400020
         SPACE 2                                                        52800020
*                                                                     * 53200020
*        FIND PCB ASSOCIATED WITH THIS APPLICATION PROGRAM            * 53600022
         L     RPCB,AVTPCBPT            ADDRESS OF FIRST PCB IN         54000020
*                                       TCAM MCP'S PCB CHAIN            54400020
LOOP     EQU   *                                                        54800020
         LA    RTCB,0(,RTCB)            CLEAR HIGH-ORDER BYTE   SA55391 55000022
         C     RTCB,PCBTCBAD            MATCHING PCB FOR TCB            55200020
         BE    GO                       BRANCH IF YES                   55600020
         CLC   PCBLINK(2),AVTFZERO      PCB CHAIN EXHAUSTED BEFORE      56000020
*                                       A MATCH HAS BEEN FOUND          56400020
         BZ    ERROR                    BRANCH IF YES                   56800020
         L     RPCB,PCBLINK-1           GET ADDRESS OF NEXT PCB         57200020
         B     LOOP                     GO TEST THIS ONE                57600020
         SPACE 2                                                        57680020
TSOERROR EQU   *                                                        57760020
         LA    RENTRY,TSO               TSO /CLOSEDOWN RETURN CODE      57840020
         B     EXIT                     RETURN TO CALLER                57920020
         EJECT                                                          58000020
GO       EQU   *                                                        58400020
         LA    RWORK,AVTOPCOB           ADDRESS OF OPERATOR             58800020
*                                       CONTROL QCB FROM AVT            59200020
         ST RWORK,CIBQCBA               STORE IN CIB                    59600020
         MVI   CIBSIZE(RCIB),CODE       AQCTL ACTION CODE               60000020
         LA    RWORK,PCBWRKA            TARGET CIB IN PCB               60400020
         ST    RWORK,CIBSIZE+4(0,RCIB)  STORE IN AQCTL PARM LIST        60800020
         LA    RWORK,ELEMLEN            ADDR IF CIB LENGTH              61200020
         ST    RWORK,CIBSIZE+8(0,RCIB)  STORE IN AQCTL PARM LIST        61600020
         MVI   CIBSIZE+8(RCIB),EOL      END-OF-LIST INDICATOR           62000020
         LA    RPARM,CIBSIZE(0,RCIB)    ADDR OF AQCTL PARM LIST         62400020
         LA    RECB,CIBSIZE+4(0,RCIB)   ECB ADDRESS                     62800020
*                                                                       63200020
         MVI   CIBPRI,PRIOPCTL          SET OPCTL PRIORITY              63300020
         OI    CIBVERB,OPCFLAG          SET APPL PROG FLAG FOR OPC      63400020
         AQCTL                                                          63600020
         NI    CIBVERB,AVTEFF-OPCFLAG   FLIP OPCTL SWITCH               63800020
*                                                                       64000020
         TM    CIBVERB,CLOSE            MCPCLOSE OR CLOSEMC             64400020
         BO    NOWAIT                   BYPASS WAIT IF YES              64800020
         WAIT  ECB=(RECB)               ADDRESS OF APPL PROG ECB        65200020
NOWAIT   EQU   *                                                        65600020
         XC    0(4,RECB),0(RECB)        RESET ECB TO ZERO               66000020
         SR    RENTRY,RENTRY            CLEAR REGISTER TO ZERO          66400020
         LA    RCIB,PCBWRKA             OP CTL CIB ADDRESS              66800020
         IC    RENTRY,CIBRC             COMPLETION CODE FROM            67200020
*                                       OPERATOR CONTROL                67600020
         B     EXIT                     RETURN TO USER           S21903 68000022
         SPACE 2                                                        68400020
NOP      EQU   *                                                        68800020
         LA    RENTRY,ZERO              NORMAL COMPLETION CODE          69200020
         B     EXIT                     RETURN TO USER                  69600020
         SPACE 2                                                        70000020
         EJECT                                                          71600020
*                                                                     * 72000020
*   C O N S T A N T S    A N D    E Q U A T E S                       * 72400020
*                                                                     * 72800020
ZIP      DC    H'0'                     CONSTANT                 S21903 73200022
ETSAVE   DC    18F'0'                   SAVE AREA                S21903 73600022
BLANKS   DC    CL8' '                   CONSTANT                 S21903 74000022
CLOSE    EQU   X'10'                    CLOSEDOWN VERB CODE             74400020
ZERO     EQU   0                                                        74800020
NOTCAM   EQU   X'0C'                    ERROR COMPLETION CODE           75600020
CVT      EQU   16                       ADDRESS OF CVT                  76000020
CODE     EQU   X'0C'                    AQCTL MOVE/END/POST CODE        76400020
EOL      EQU   X'80'                    END-OF-LIST FLAG                76800020
BADPASS  EQU   X'14'                                                    77200020
CQTAM    EQU   X'FF'                    CIB CODE FOR CQTAM MACROS       77600020
ELEMLEN  DC    H'28'                    CIB LENGTH                      78000020
OPCFLAG  EQU   X'20'                                                    78200020
TSO      EQU   4                        TSO/CLOSEDOWN RETURN CODE       78300020
         EJECT                                                          78400020
*                                                                       78800020
*     D U M M Y    C O N T R O L    S E C T I O N S                   * 79200020
*                                                                     * 79600020
IEDQCIB  DSECT                          COMMAND INPUT BUFFER(CIB)       80000020
CIBQCBA  DS    F                        ADDRESS OF TCAM OPERATOR        80400020
*                                       CONTROL SUBTASK QCB             80800020
CIBPRI   DS    FL1                      CIB PRIORITY                    81200020
CIBLINK  DS    XL3                      LINK FIELD                      81600020
CIBVERB  DS    FL1                      COMMAND VERB CODE               82000020
CIBLEN   DS    XL1                      LENGTH OF CIB                   82400020
CIBLRN   DS    XL1                      RELATIVE LINE NUMBER            82800020
CIBRC    DS    XL1                      COMPLETION CODE(APPL PROG)      83200020
CIBECBA  DS    F                        ECB ADDRESS                     83600020
CIBTNAME DS    XL8                      TERMINAL NAME                   84000020
CIBICHNG DS    F                        ICHNG WORKAREA ADDRESS          84400020
CIBEND   DS    0XL1                     END OF CIB                      84800020
CIBSIZE  EQU   CIBEND-IEDQCIB           LENGTH OF ONE CIB               85200020
         TAVTD                                                          86000020
         TPCBD                                                          86400020
         TPRIOR                                                         86600020
ETCVT    DSECT                                                          86660020
         CVT                                                            86720020
         END                                                            86800020
