EZ01     TITLE  '''IEDQEZ'' - TCAM GET/RETRIEVE FIFO ROUTINE'           01000020
IEDQEZ   CSECT                                                          02000020
*A870000                                                        SA56912 02300022
*C610000-630000                                                 SA56912 02600022
         SPACE 4                                                        03000020
*********************************************************************** 04000020
*                                                                     * 05000020
*TITLE: 'IEDQEZ' GET/RETRIEVE FIFO ROUTINE                            * 06000020
*FUNCTION:  THIS ROUTINE MONITORS THE READ-AHEAD QCB FOR A SPECIAL    * 07000020
*   RETRIEVE ELEMENT POSTED WHEN THE GET SCHEDULER IS WAITING IN      * 08000020
*   THE DESTINATION QCB.  IT RAISES THE PRIORITY OF THE RETRIEVE      * 09000020
*   ELEMENT AND POSTS IT TO THE DESTINATION QCB.                      * 10000020
*ENTRY POINT:                                                         * 11000020
*        IEDQEZ                                                       * 12000020
*INPUT:                                                               * 13000020
*   1  - RETRIEVE ELEMENT ADDRESS                                     * 14000020
*   3  - STCB ADDRESS                                                 * 15000020
*   7  - QCB ADDRESS                                                  * 16000020
*   11 - DISPATCHER ADDRESS                                           * 17000020
*   13 - REGISTER SAVEAREA ADDRESS                                    * 18000020
*   15 - ENTRY POINT ADDRESS                                          * 19000020
*OUTPUT:                                                              * 20000020
*   NONE                                                              * 21000020
*EXTERNAL ROUTINES:                                                   * 22000020
*        IGG019RB-DISPATCHER AT 'DSPPOST'                             * 23000020
*EXITS-NORMAL:                                                        * 24000020
*        BRANCHES TO DSPPOST ENTRY POINT IN TCAM DISPATCHER           * 25000020
*EXITS-ERROR:                                                         * 26000020
*        NONE                                                         * 27000020
*TABLES/WORKAREAS:                                                    * 28000020
*        PEWA                                                         * 29000020
*        TERMINAL ENTRY                                               * 30000020
*ATTRIBUTES: REENTRANT, REFRESHABLE, PROBLEM PROGRAM MODE             * 31000020
*NOTES: THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 32000020
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT  * 33000020
*   TO THE ONE USED AT ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED   * 34000020
*   SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,     * 35000020
*   WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.          * 36000020
*********************************************************************** 37000020
         EJECT                                                          38000020
*                                                                     * 39000020
*               S Y M B O L I C    R E G I S T E R S                  * 40000020
*                                                                     * 41000020
         SPACE                                                          42000020
RZERO    EQU   0                        GENERAL WORK REGISTER           43000020
RPARM    EQU   1                        PARAMETER REGISTER              44000020
RSTCB    EQU   3                        STCB ADDRESS                    45000020
RQCB     EQU   7                        READ-AHEAD QCB ADDRESS          46000020
RWORK    EQU   9                        GENERAL WORK REGISTER           47000020
RDISP    EQU   11                       DISPATCHER BASE REGISTER        48000020
RBASE    EQU   12                       CSECT ADDRESSABILITY            49000020
RSAVE    EQU   13                       ADDRESS OF AVTSAVE2             50000020
RENTRY   EQU   15                       ENTRY POINT ADDRESS             51000020
         SPACE 2                                                        52000020
         BALR  RBASE,RZERO              ESTABLISH                       53000020
         USING *,RBASE                          ADDRESSABILITY          54000020
         EJECT                                                          55000020
         USING IEDQQCB,RQCB             READ-AHEAD QCB                  56000020
         USING IEDQRECB,RPARM           SPECIAL RETRIEVE ELEMENT        57000020
         USING IEDQDISP,RDISP           TCAM DISPATCHER                 58000020
         USING IEDQTRM,RWORK            PROCESS ENTRY                   59000020
         SPACE 2                                                        60000020
         USING IEDQAVTD,RSAVE           AVT ADDRESSABILITY      SA56912 61000022
         MVC   QCBLINK(3),AVTDELAD+1    DUMMY ELEM ADDR         SA56912 62000022
         L     RWORK,PEWAPROC-PEGFSTCB(RSTCB)                           64000020
*                                       GET ADDRESS OF PROCESS          65000020
*                                       CONTROL BLOCK FROM PROCESS      66000020
*                                       ENTRY WORKAREA                  67000020
         MVC   RECBQCBA(3),TRMDESTQ     ADDRESS OF QCB ON WHICH         68000020
*                                       GET SCHEDULER IS WAITING        69000020
         MVI   RECBPRI,HIPRI            RAISE PRIORITY OF RETRIEVE      70000020
*                                       ELEMENT SO GET SCHEDULER        71000020
*                                       WILL SEE ELEMENT BEFORE AN      72000020
*                                       EOM BUFFER                      73000020
         B     DSPPOST                  POST RETRIEVE ELEMENT TO        74000020
*                                       DESTINATION QCB                 75000020
HIPRI    EQU   X'50'                    RETRIEVE ELEMENT PRIORITY       76000020
         EJECT                                                          78000020
*                                                                     * 79000020
*                         D  S  E  C  T  S                            * 80000020
*                                                                     * 81000020
         SPACE                                                          82000020
         TQCBD                                                          83000020
         TRECBD                                                         84000020
         TPEWAD                                                         85000020
         TTRMD                                                          86000020
         TDISPD                                                         87000020
         TAVTD 2                                                SA56912 87500022
         END                                                            88000020
