         TITLE 'IEDQGH - CTBFORM MODULE'                                00080022
         SPACE 3                                                        00120022
IEDQGH   CSECT                                                          00160022
         SPACE 3                                                        00170022
*  CHANGE ACTIVITY AS FOLLOWS                                           00180005
******************** MICROFICHE FLAGS *********************** SUPT CODE 00190005
*A352800                                                        SA54269 00200022
*A101600,867200                                                 SA56209 00200122
*C847200                                                        SA56209 00200222
*D870400                                                        SA56209 00200322
*C683200                                                        SA57673 00200422
*A878400                                                        S22027  00200522
*A465600,647200                                                 SA52971 00200622
*C308800                                                        SA59170 00200722
*A700880-701440,711200-715200                                   SA60814 00200822
*D70800,711200-716000                                           SA60814 00200922
*A354400                                                        SA59199 00201005
         SPACE 3                                                        00300022
*********************************************************************** 00320022
* TITLE -- 'IEDQGH' CTBFORM MODULE                                    * 00340022
*                                                                     * 00360022
*  MODULE NAME = IEDQGH                                               * 00400005
*                                                                     * 00410005
*  DESCRIPTIVE NAME = CTBFORM MODULE                                  * 00420005
*                                                                     * 00430005
*  COPYRIGHT = 'NONE'                                                 * 00440005
*                                                                     * 00450005
*  STATUS:  CHANGE LEVEL 5                                            * 00460005
*                                                                     * 00480022
* FUNCTION --                                                         * 00560022
*    AT ENTRY FROM CTBFORM: TO INSERT DATA AND DVCIDS                 * 00640022
*    IF SPECIFIED                                                     * 00720022
*                                                                     * 00800022
*    AT ENTRY FROM OUTMSG: TO DETERMINE CONCENTRATED END OF MESSAGE,  * 00880022
*    TO INSERT CTB ENDING CHARACTERS,TO MARK QUEUES TEMPORARILY HELD  * 00960022
*                                                                     * 01040022
*    AT ENTRY FROM IEDQGD(BUFFER ASSOCIATION): TO LINK BUFFERS INTO   * 01120022
*    WRITE IDLES LOOP                                                 * 01200022
*                                                                     * 01280022
* ENTRY POINTS --                                                     * 01360022
*         IEDQGH -- WHEN ENTERED FROM CTBFORM OR OUTMSG               * 01440022
*         THE CALLING SEQUENCE FROM USER INTERFACE IS:                * 01520022
*         L   R12,AVTMSGS-1            GET ADDR OF VCON TABLE         * 01600022
*         IC  R15,AVTEZERO(,R1)        GET INDEX TO ROUTINE ADDR      * 01680022
*         L   R12,AVTEZERO(R12,R15)    GET ROUTINE ADDRESS            * 01760022
*         BR  R12                       EXIT TO ROUTINE               * 01840022
*                                                                     * 01920022
*         IEDQGH01                                                    * 02000022
*                                                                     * 02080022
* INPUT --                                                            * 02160022
*                                                                       02240022
*    AT ENTRY IEDQGH                                                  * 02320022
*    R1  ADRESS OF A MACRO GENERATED PARAMETER LIST                   * 02400022
*    R3  ADDRESS OF SCB                                               * 02480022
*    R4  ADDRESS OF LCB                                               * 02560022
*    R6  ADDRESS OF CURRENT BUFFER                                    * 02640022
*    R9  ADDRESS OF AVT                                               * 02720022
*    R12 ENTRY POINT ADDRESS NAD BASE OF THIS ROUTINE                 * 02800022
*                                                                     * 02880022
*    AT ENTRY IEDQGH01                                                * 02960022
*                                                                     * 03040022
*    R1  ADDRESS OF ERB                                               * 03120022
*    R7  ADDRESS OF QCB                                               * 03200022
*    R13 ADDRESS OF AVTSAVE2                                          * 03280022
*    R11 DISPATCHER BASE                                              * 03360022
* OUTPUT --                                                           * 03440022
*                                                                     * 03520022
* EXTERNAL REFERENCES --                                              * 03600022
*                                                                     * 03680022
*         IEDQUI                                                      * 03760022
*         IEDQAF                                                      * 03840022
*         IEDQAO                                                      * 03920022
*         IEDQAE                                                      * 04000022
*         IEDQGD                                                      * 04040022
*         DSPPOSTR                                                    * 04080022
*         AVTRNMPT - TNT CODE                                         * 04160022
*                                                                     * 04240022
* EXITS,NORMAL --                                                     * 04320022
*    DSPDISP                                                          * 04400022
*    IEDQUI                                                           * 04480022
*                                                                     * 04560022
* EXITS,ERROR --                                                      * 04640022
*                                                                     * 04720022
*    NONE                                                             * 04800022
*                                                                     * 04880022
* TABLES/WORK AREAS --                                                * 04960022
*    AVT                                                              * 05040022
*    LCB                                                              * 05120022
*    QCB                                                              * 05200022
*    SCB                                                              * 05280022
*    DCB                                                              * 05360022
*    SCT                                                              * 05440022
*    TERMINAL ENTRY                                                   * 05520022
*    QCBE                                                             * 05600022
*    DRQ                                                              * 05680022
*    BUFFER PREFIX                                                    * 05760022
*    DVCID TABLE                                                      * 05840022
*                                                                     * 05920022
* ATTRIBUTES --                                                       * 06000022
*    SERIALLY REUSABLE, REFRESHABLE, ENABLED, PROBLEM PROGRAM MODE,   * 06080022
*    RESIDENT                                                         * 06160022
*                                                                     * 06240022
*                                                                     * 06320022
* CHARACTER CODE DEPENDENCY --                                        * 06400022
*    THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON AN             * 06480022
*    INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.           * 06560022
*                                                                     * 06640022
* NOTES --                                                            * 06720022
*    STANDARD TCAM LINKAGES AND DEVIATIONS FROM STANDARDS             * 06800022
*                                                                     * 06880022
*********************************************************************** 06960022
         EJECT                                                          07040022
*********************************************************************** 07120022
*        REGISTER EQUATES                                             * 07200022
*********************************************************************** 07280022
         SPACE 1                                                        07360022
R0       EQU   0                        WORK REGISTER                   07440022
R1       EQU   1                        WORK REG                        07520022
RPARM    EQU   1                        PARAMETER REGISTER              07600022
RPQCB    EQU   1                        PRIORITY QCB BASE               07680022
R2       EQU   2                        WORK REG                        07760022
RDRQ     EQU   2                        DATA READY QUEUE BASE           07840022
R3       EQU   3                        WORK REG                        07920022
RSCB     EQU   3                        SCB  BASE                       08000022
R4       EQU   4                        WORK REG                        08080022
RLCB     EQU   4                        LCB  BASE                       08160022
R5       EQU   5                        WORK REGISTER                   08240022
RPREFIX  EQU   6                        BUFFER ADDRESS                  08320022
R7       EQU   7                        WORK REG                        08400022
RQCB     EQU   7                        QCB  BASE                       08480022
R8       EQU   8                        WORK REG                        08560022
RTERM    EQU   8                        TERMINAL ENTRY                  08640022
R9       EQU   9                        WORK REG                        08720022
RAVT     EQU   9                        AVT  BASE                       08800022
R10      EQU   10                       RESERVED FOR ANOTHER BASE       08880022
R11      EQU   11                       WORK REG                        08960022
RQCBE    EQU   11                                                       09040022
RDISP    EQU   11                       DISPATCHER BASE                 09120022
RBASE    EQU   12                       BASE REGISTER                   09200022
R13      EQU   13                       ADDR OF AVTSAVB                 09280022
R14      EQU   14                       LINK REG                        09360022
R15      EQU   15                       WORK REG                        09440022
         SPACE 1                                                        09520022
CTBFMENT EQU   X'01'                    ENTRY FROM OUTMSG               09600022
CTBOPFLD EQU   X'01'                    OPFLD SPECIFIED                 09680022
CTBDVCID EQU   X'02'                    DVCID = YES ON CTBFORM          09760022
CTBSPCHR EQU   X'04'                    ENDCHAR = YES ON CTBFORM        09840022
CTBINSRT EQU   X'08'                    INDICATES DATA NOT INSERTED     09920022
CTBINSFS EQU   X'10'                    INSERT = NO ON CTBFORM   S22027 09960022
CTBNULL  EQU   X'FF'                    NULL SEPARATOR CHARACTER        10000022
X0F      EQU   X'0F'                    CLEAR SCBQTYPE                  10080022
ECD10    EQU   X'10'                    RETURN CODE                     10160022
ECD20    EQU   X'20'                    INVALID FIELD RETURN CD SA56209 10200022
E48      EQU   X'48'                    SIZE OF SAVE AREA               10240022
LAST     EQU   X'02'                    LAST UNIT OF BUFFER FLAG        10320022
TIC      EQU   X'08'                    TIC                             10400022
DCBPCISN EQU   X'04'                    PCI = N                         10480022
SCTEOT   EQU   X'14'                    SCT INDEX BYTE TO EOT           10560022
INSOFF   EQU   4                        OFFSET                          10640022
DATOFF   EQU   6                        OFFSET                          10720022
ADDUNIT  EQU   X'80'                    UNIT NEEDED FOR INSERT  SA60814 10760022
ZERO     EQU   0                        ZERO                            10800022
ONE      EQU   1                        ONE                             10880022
TWO      EQU   2                        TWO                             10960022
THREE    EQU   3                        THREE                           11040022
FOUR     EQU   4                        FOUR                            11120022
FIVE     EQU   5                        FIVE                            11200022
EIGHT    EQU   8                        EIGHT                           11280022
NINE     EQU   9                        NINE                            11360022
ELEVEN   EQU   11                       ELEVEN                          11440022
TWELVE   EQU   12                       TWELVE                          11520022
D15      EQU   15                       NO OF BITS TO SHIFT             11600022
FIFTEEN  EQU   15                       FIFTEEN                         11680022
SIXTEEN  EQU   16                       SIXTEEN                         11760022
*********************************************************************** 11840022
*        ESTABLISH CSECT AND CONTROL BLOCK ADDRSSABILITY              * 11920022
*********************************************************************** 12000022
         SPACE 2                                                        12080022
         USING IEDQPRF,RPREFIX          BUFFER PREFIX BASE              12160022
         USING IEDQDRQ,RDRQ             DRQ BASE                        12240022
         USING IEDQLCB,RLCB             LCB BASE                        12320022
         USING IEDQSCB,RSCB             SCB BASE                        12400022
         USING IEDQQCBE,RQCBE           QCBE BASE                       12480022
         USING IEDQTRM,RTERM            TERMINAL ENTRY BASE             12560022
         USING IEDQQCB,RQCB             QCB BASE                        12640022
         USING IEDQPQCB,RPQCB           PRIORITY QCB BASE               12720022
         USING IEDQAVTD,RAVT            AVT BASE                        12800022
         USING IEDQGH,RBASE             ROUTINE BASE                    12880022
         SPACE 2                                                        12960022
         B     ID                       BRANCH AROUND ID                13040022
         B     IEDQGH02                 ENTRY FROM GD                   13120022
         DC    AL1(DSPMCPL4)            STCB                            13200022
         DC    AL3(*-1)                 STCB ADDR                       13280022
*******   FIRST TWO BRANCHES ARE THE QCB FOR THE STCB ***********       13320005
         SPACE 1                                                        13360022
*    THE ERB IS POSTED TO GH WHEN ONLY CANCELED MSGS ARE LEFT ON        13440022
*    QUEUE INORDER FOR GH TO FORCE CONCENTRATED END OF MSG              13520022
         SPACE 1                                                        13600022
IEDQGH01 EQU   *                                                        13680022
         LR    RBASE,RQCB               SET BASE                        13760022
         LA    R5,LCBERB-IEDQLCB        ERB OFFSET IN LCB               13840022
         LR    RLCB,RPARM               ERB ADDR                        13920022
         SR    RLCB,R5                  SET LCB BASE                    14000022
         LR    RAVT,R13                 ADDR OF AVTSAVE2                14080022
         LA    R0,E48                   SIZE OF SAVE AREA               14160022
         SR    RAVT,R0                  SET AVT BASE                    14240022
         L     RSCB,LCBSCBA-1           SET SCB BASE                    14320022
         L     RQCB,SCBDESTQ-1          SET DEST Q ADDR                 14400022
         LH    RQCBE,QCBEXTO            GET QCBE OFFSET                 14480022
         AR    RQCBE,RQCB               SET QCBE BASE                   14560022
         L     RDRQ,QCBECONC-1          POINTER TO CONC TERM ENTRY      14640022
         L     RDRQ,ZERO(RDRQ)          SET DRQ BASE                    14720022
         LA    R15,GODISP               SET EXIT ADDR                   14800022
         BAL   R14,GETUNIT              GET A UNIT TO BUILD A BUF       14880022
         B     NONE                     BRANCH NO UNITS AVAIL           14960022
         LR    RPREFIX,R1               SET BUFFER ADDR                 15040022
         SPACE 1                                                        15120022
*    BUILD A BUFFER                                                     15200022
         SPACE 1                                                        15280022
         SR    R0,R0                    CLEAR WORK REG                  15360022
         STC   R0,LCBISZE               SET ISZR TO NO RESERVES         15440022
         ST    RLCB,PRFLCB-1            SET LCB ADDR IN BUFFER          15520022
         MVI   PRFNBUNT,ONE             SET UNIT COUNT TO ONE           15600022
         LA    R8,AVTTXTSZ+ONE          TXT PREFIX SIZE                 15680022
         MVI   PRFSTAT1,PRFNHDRN        SET NOT HEDR                    15760022
         MVI   PRFTIC,TIC               SET TIC OPCODE                  15840022
         MVI   PRFTIC+THREE,LAST        SET AS LAST                     15920022
         L     R5,LCBDCBPT              GET PTR TO DCB                  16000022
         USING IHADCB,R5                                                16080022
         L     R5,DCBSCTAD-1            GET SCT ADDR FROM DCB           16160022
         DROP  R5                                                       16240022
         LA    R1,SCTEOT                SCT INDEX TO EOT                16320022
         IC    R1,ZERO(R1,R5)           INDEX TO EOT                    16400022
         LA    R1,ZERO(R1,R5)           GET ADDR OF EOT                 16480022
         CLI   ZERO(R1),TWO             IS SCT ENTRY LENGTH 2           16560022
         BNE   NOETX                    BRANCH IF NO                    16640022
         LA    R8,ONE(R8)               INCR PRFSIZE                    16720022
NOETX    EQU   *                                                        16800022
         STH   R8,PRFSIZE               SET PRFSIZE                     16880022
         LA    R0,AVTTXTSZ              TXT PREFIX SIZE                 16960022
         SR    R8,R0                    LENGTH OF DATA TO MOVE          17040022
         EX    R8,MVCRS                 MOVE DATA                       17120022
         L     R15,AVTGD                ADDR OF BUFFER ASSOCIATION      17200022
NONE     EQU   *                                                        17280022
         L     R1,LCBSCBDA-1            GET LINE SCB ADDR               17360022
         XC    SCBEOBAC-IEDQSCB(TWO,R1),SCBEOBAC-IEDQSCB(R1)            17440022
*                                       CLEAR SCBEOBAC                  17520022
         OI    SCBSTAT1-IEDQSCB(R1),SCBCEND                             17600022
*                                       SET CONC END OF MSG             17680022
         NI    SCBSTAT1-IEDQSCB(R1),AVTEFF-SCBNIDLE                     17760022
*                                       RESET SO BUF WILL BE HOOKED     17840022
*                                       IN IDLES LOOP                   17920022
         OI    LCBERBST,LCBEOMSG        SET ERB AVAILABLE        S22027 17960022
         MVC   DRQCTBCT,DRQCTBMX        RESET MSG COUNT                 18000022
         BR    R15                      RETURN                          18080022
IEDQGH   IEDHJN                                                         18180022
         DS    0H                                                       18320022
         SPACE 1                                                        18400022
ID       EQU   *                                                        18480022
         ST    RPARM,PARMSAVE           SAVE ADDR OF PARMLIST           18560022
         LH    R15,PRFSIZE              TEST FOR ZERO                   18640022
         LTR   R15,R15                  LENGTH BUFFER                   18720022
         BZ    EXIT                     YES,EXIT IMMEDIATELY            18800022
         TM    SCBQTYPE,SCBCONC         IS THIS CONCENTRATOR BUFF       18880022
         BZ    EXIT                     NO, EXIT                        18960022
         LR    R5,RPARM                 SET PARM ADDR                   19040022
         SPACE 1                                                        19120022
         LH    RPARM,LCBTTCIN           PICK UP TERMNAMEINDEX           19200022
         N     RPARM,AVTCLRHI           CLEAR HI-ORDER TWO BYTES        19280022
         BZ    EXIT                     ERROR IF ZEROS                  19360022
         SPACE 1                                                        19440022
         L     R15,AVTRNMPT             GET ADDR OF TERMNAME RTN        19520022
         BALR  R14,R15                  GIVE IT CONTROL                 19600022
         SPACE 2                                                        19680022
         LR    RTERM,RPARM              SET BASE FOR TERM ENTRY         19760022
         L     RQCB,TRMDESTQ-1          GET QCB ADDR                    19840022
         LA    RQCB,ZERO(RQCB)          CLEAR HI BYTE                   19920022
         LH    RQCBE,QCBEXTO            GET QCB EXTERNSION ADDR         20000022
         AR    RQCBE,RQCB               SET QCBE BASE                   20080022
         TM    ZERO(R5),CTBFMENT        IS ENTRY FROM CTBFORM           20160022
         BO    COUNT                    BRANCH IF NO                    20240022
         MVC   AVTCSCH(ONE),ZERO(R5)    SAVE VCON TABLE OFFSET          20320022
*                                       TO GH FOR GD USE                20400022
         TM    PRFSTAT1,PRFNHDRN        IS THIS A HEADER BUFFER         20480022
         BO    CKCTBBGN                 NO,CHECK FOR CTB BEGIN          20560022
         BAL   R14,EXTFIND              FIND CORRECT EXT                20640022
         MVC   QCBETCIN-IEDQQCBE(TWO,R5),LCBTTCIN                       20720022
*                                       SAVE TTCIN FOR CONC SCHED       20800022
*                                       TO USE TO SET UP ON             20880022
*                                       RECALLED BUFFERS                20960022
         TM    QCBEFLG,QCBECNT          DOES QCNTRL = MSG OR ALL        21040022
         BZ    CKOPTFLD                 BRANCH IF YES                   21050022
CKCTBBGN EQU   *                                                        21060022
         TM    QCBEFLG,QCBECNT          IS INTEGER SPECFIED ON QCNTRL   21070022
         BZ    EXIT                     BRANCH IF NO TO RETURN          21080022
         CLC   SCBCTBSZ,QCBEDAMT        IS THIS CTB BEGIN               21090022
         BNE   EXIT                     BRANCH IF NO TO RETURN          21100022
         TM    QCBEFLG,QCBESRVC+QCBEHELD                                21110022
*                                       IS THIS Q SERV OR HELD          21120022
         BNZ   EXIT                     BRANCH IF YES TO RETURN         21130022
         MVC   QCBEEOB,SCBEOB           SAVE PREVIOUS SCBEOB FOR MB     21140022
         MVC   QCBEDEOB,SCBDEOB         SAVE PREVIOUS DEOB VOR MB       21150022
         SPACE 1                                                        21200022
CKOPTFLD EQU   *                                                        21280022
         L     R5,PARMSAVE              RESTORE PTR TO PARMLIST         21360022
         MVC   SCBCTBSV(ONE),TWO(R5)    SAVE CTBFORM PARAMETERS         21440022
         SR    R5,R5                    CLEAR REG                       21520022
         TM    SCBCTBSV,CTBSPCHR        IS INSERT SEPARATOR CHARACTER   21600022
*                                       SPECIFIED                       21680022
         BZ    CKFLD                    BRANCH IF NO                    21760022
         CLI   QCBERS,CTBNULL           IS A SEPARATOR CHAR DEFINED     21840022
         BNE   CKFLD                    BRANCH IF YES                   21920022
         SPACE 1                                                        22000022
         NI    SCBCTBSV,AVTEFF-CTBSPCHR RESET SEPARATOR                 22080022
*                                       CHARACTER DEFINED BIT           22160022
         OI    RTNCDE,AVTECD4           SET RETURN CODE                 22240022
CKFLD    EQU   *                                                        22320022
         SR    R15,R15                  CLEAR REG IF NO INSERT DONE     22400022
         TM    SCBCTBSV,CTBOPFLD        IS OPTION FIELD SPECIFIED       22480022
         BZ    CKINSDVC                 BRANCH IF NO                    22560022
         SPACE 2                                                        22640022
*    THIS ROUTINE LOCATES THE OPTION FIELD. IF THE OPTION FIELD IS      22720022
*        NOT FOUND A RETURN CODE IS GIVEN IN REG 15                     22800022
         SPACE 2                                                        22880022
*    BUILD PARMLIST FOR AE                                              22960022
         SPACE 1                                                        23040022
         L     R5,PARMSAVE              GET ADDR OF PARMLIST            23120022
         USING PRMLST,R5                                                23200022
         MVC   PRMOFFST,PRMAEOFF        SET AE OFFSET                   23280022
         MVI   PRMLNGTH,FOUR            SET LENGTH OF PARM LIST         23360022
         MVC   PRMOPTN,PRMOPFLD         SET OPTION FIELD OFFSET         23440022
         MVI   PRMREGOF,SIXTEEN         SET RETURN REG OFFSET           23520022
         DROP  R5                                                       23600022
         LA    RPARM,PARMLIST           GET ADDR OF PARAMETER LIST      23680022
         L     R15,AVTUI                GET USER INTERFACE ROUTINE      23760022
         BALR  R14,R15                  GO LOCATE OPTION FIELD          23840022
         LTR   R15,R15                  DID LOCATE OPTION FIELD         23920022
         BNZ   CKINSDVC                 YES SEE IF DVCID TO BE INSRTED  24000022
         SPACE 1                                                        24080022
         NI    SCBCTBSV,AVTEFF-CTBOPFLD RESET OPFLD INSRT REQ BIT       24160022
         SR    R5,R5                    CLEAR REG                       24240022
         OI    RTNCDE,AVTECD8           SET BAD RETURN CODE             24320022
         SPACE 2                                                        24400022
CKINSDVC EQU   *                                                        24480022
         TM    SCBCTBSV,CTBDVCID        IS DVCID TO BE INSERTED         24560022
         BZ    CKINSRT                  SEE IF ANY INSRTS TO BE DONE    24640022
         SPACE 1                                                        24720022
*    THIS ROUTINE GETS THE ADDR OF THE DEVICE DEPENDENT FIELD           24800022
*     CONTAINING THE ADDRESS THE DVCID TABLE ENTRY FOR THIS TERMINAL    24880022
         SPACE 2                                                        24960022
         LA    R1,TRMOPNO               PRT TO DEVICE DEPENDENT FIELD   25040022
*                                       IF NO OPTION FIELDS             25120022
         TM    TRMSTATE,TRMOPTFN        OPTION FIELDS USED              25200022
         BZ    NOOPT                    NO,GO FIND DEVICE DEPENP FIELD  25280022
         SPACE 1                                                        25360022
         SR    R2,R2                    CLEAR WORK REG                  25440022
         IC    R2,TRMOPNO               GET NUMBER OF OPTION ENTRIES    25520022
         LA    R1,THREE(R1,R2)          BUMP DVC DEPEND FIELD PTR       25600022
*                                       PAST OPTION OFFSETS             25680022
NOOPT    EQU   *                                                        25760022
         SR    R2,R2                    CLEAR WORK REG                  25840022
         LH    R0,TRMDEVFL              GET DVC DEPEND FIELD FLAGS      25920022
         SLL   R0,D15                   SHIFT FLAGS TO LEFT IN R0       26000022
         LA    R14,EIGHT                SET COUNTER TO TEST NINE        26080022
*                                       DEVICE DEPEND FIELD FLAGS       26160022
LOOP     EQU   *                                                        26240022
         SLL   R0,ONE                   SHIFT TO TEST FOR PRESENCE      26320022
*                                       OF NEXT DEVICE DEPEND FIELD     26400022
         LTR   R0,R0                    THIS FIELD PRESENT              26480022
         BNM   BCTIT                    NO, DON'T BUMP POINTER          26560022
         SPACE 1                                                        26640022
         IC    R2,ZERO(R1)              GET LENGTH OF THIS FIELD        26720022
         LA    R1,ONE(R1,R2)            BUMP PTR PAST THIS FIELD        26800022
         SPACE 1                                                        26880022
BCTIT    EQU   *                                                        26960022
         BCT   R14,LOOP                 REACHED DVCID TABLE PTR?        27040022
*                                       NO, TRY NEXT                    27120022
         MVC   AVTPARM+1(THREE),TWO(R1) YES MOVE TABLE ADDR TO WORK     27200022
         L     R1,AVTPARM               AREA FOR LOAD INTO REG          27280022
         CLI   ONE(R1),CTBNULL          IS DVCID DEFINED                27360022
         BNE   INSDVCID                 BRANCH IF YES                   27440022
         OI    RTNCDE,ECD10             SET BAD RETURN CODE             27520022
         NI    SCBCTBSV,AVTEFF-CTBDVCID RESET INSERTDVCID BIT           27600022
*                                       REQUESTED, NO DVCID DEFINED     27680022
         SR    R1,R1                    CLEAR REG                       27760022
CKINSRT  EQU   *                                                        27840022
         LTR   R5,R5                    ANY INSERTS TO BE DONE          27920022
         BZ    EXIT                     NO RETURN                       28000022
INSDVCID EQU   *                                                        28080022
         SPACE 1                                                        28160022
         SPACE 2                                                        28240022
         BAL   R14,INSERT               GO INSERT DVCID                 28320022
EXIT     EQU   *                                                        29040022
         L     R5,PARMSAVE              GET PTR TO PARM LIST            29120022
         TM    ZERO(R5),CTBFMENT        IS ENTRY FROM CTBFORM           29200022
         BO    EXIT2                    BRANCH IF NO EXIT               29250022
*                                       TO OUTMSG SUBGROUP              29300022
         SR    R15,R15                  CLEAR REG                       29360022
         IC    R15,RTNCDE               GET RETURN CODE                 29440022
         MVI   RTNCDE,ZERO              RESET FIELD                     29520022
         L     RBASE,AVTUI              GET ADDR OF USER INTERFACE RTN  29600022
         B     FOUR(RBASE)              RETURN TO CALLER                29680022
         SPACE 2                                                        29760022
*    THIS ROUTINE GAINS CONTROL AT OUTMSG TO UPDATE  ERB COUNTS         29840022
*    IN DRQ AND OTHEE THINGS                                            29920022
         SPACE 2                                                        30000022
COUNT    EQU   *                                                        30080022
         L     RDRQ,QCBECONC-1          GET PTR TO CONC TERM ENTRY      30160022
         L     RDRQ,ZERO(RDRQ)          SET DRQ BASE                    30240022
         TR    DRQBUFCT,TABLE-1         DECR DRQBUFCT                   30320022
         TR    DRQERBCT,TABLE-1         DECR DRQERBCT                   30400022
         TM    QCBEFLG,QCBESRVC+QCBEHELD                                30480022
*                                       IS THIS Q SERVICED OR HELD      30560022
         BNZ   RIDBUF                   BRANCH IF YES                   30640022
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   30720022
         BO    NOTAHDR                  BRANCH IF NO                    30800022
         SR    R1,R1                    CLEAR WORK REGISTER     SA59170 30880022
         L     R14,PARMSAVE             GET PARM LIST ADDRESS   SA59170 30890022
         IC    R1,ONE(R14)              PARM LIST LNGTH         SA59170 30900022
         AR    R14,R1                   BUMP TO END             SA59170 30910022
         ST    R14,AVTDOUBL             SAVE LAST ENTRY ADDRESS SA59170 30920022
         MVC   QCBEMACR(THREE),AVTDOUBL+1                       SA59170 30930022
*                                       SET SCBMACR                     30960022
         SPACE 1                                                        31040022
SAVESCB  EQU   *                                                        31120022
         TM    QCBEFLG-IEDQQCBE(RQCBE),QCBEOPL                          31200022
*                                       IS NEW PRIORITY LEVEL SCHEME    31280022
*                                       BEING USED                      31360022
         BZ    NOTAHDR                  BRAMCH IF NO                    31440022
         BAL   R14,EXTFIND              GET CORRECT EXTENSION           31520022
         DROP  RQCBE                                                    31600022
         USING IEDQQCBE,R5                                              31680022
         MVC   QCBEHDR(THREE),SCBSCHDR  SAVE CURRENT HDR POINTER        31760022
         MVC   QCBEOSEQ(TWO),SCBOSEQ    SAVE SEQ OUT NO                 31840022
         MVC   QCBEPRI(ONE),SCBPRI      SAVE PRIORITY INDEX TO QCB      31920022
         MVC   QCBEFEFO(THREE),SCBFEFO  SAVE FEFO POINTER               32000022
         MVC   QCBEQTYP,SCBQTYPE        SAVE SCB QTYPE                  32080022
         DROP  R5                                                       32160022
         USING IEDQQCBE,RQCBE                                           32240022
         SPACE 1                                                        32320022
NOTAHDR  EQU   *                                                        32400022
         TM    QCBEFLG,QCBECNT          INTEGER SPECIFIED ON QCNTRL     32480022
         BZ    CKEOM                    NO GO SEE IF NEED TO INSERT     32560022
*                                       SEPARATOR CHARACTER             32640022
         SPACE 1                                                        32720022
*    THIS ROUTINE DETERMINES IF THIS BUFFER IS CTBEND                   32800022
         SPACE 2                                                        32880022
         LA    R1,AVTTXTSZ              ASSUME TEXT BUFFER              32960022
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   33040022
         BO    SUBTRR                   NO                              33120022
         IC    R1,LCBISZE               GET NO OF IDLES REMAINING       33200022
         LA    R1,AVTHDRSZ(R1)          AMT NOT TO WRITE                33280022
SUBTRR   EQU   *                                                        33360022
         SR    R5,R5                    CLEAR WORK REGS                 33440022
         SR    R0,R0                    CLEAR WORK REGS                 33520022
         LH    R0,SCBCTBSZ              GET DATA LEFT IN THIS CTB       33600022
         LH    R5,PRFSIZE               GET DATA SIZE IN BUFFER         33680022
         SR    R5,R1                    MINUS PREFIX SIZE               33760022
         TM    PRFSTAT1,PRFCNCLN        RECALLED BUFFER?                33840022
         BNO   SETEND                   NO,GO DETERMINE CTBEND          33920022
         SPACE 1                                                        34000022
         AR    R5,R1                    PLUS PREFIX SIZE                34080022
         SH    R5,SCBEOB                GET DATA COUNT LEFT IN BUFFER   34160022
         L     R14,LCBSCBDA-1           GET LINE SCB ADDR               34240022
         MVC   SCBEOB-IEDQSCB(TWO,R14),SCBEOB                           34320022
*                                       SET EOB OFFSET FOR AK           34400022
         SPACE 1                                                        34480022
SETEND   EQU   *                                                        34560022
         SR    R0,R5                    IS DATA SIZE LESS THAN          34640022
*                                       AMT NEEDED FOR CTB              34720022
         BM    SETCTBND                 NO SET CTB END                  34800022
         TM    PRFSTAT1,PRFNLSTN        EOM BUFFER                      34880022
         BZ    UPDT                     YES GO SEE IF INSERT RS         34960022
         STH   R0,SCBCTBSZ              SAVE AMT DATA NEEDED TO FILL    35040022
*                                       CTB                             35120022
         LTR   R0,R0                    NEED RECALL                     35200022
         BNZ   IDLES                    NO                              35280022
         OI    SCBCTBFL,SCBCTBND        SET CTB END             SA54269 35320022
         XC    SCBDEOB,SCBDEOB          CLEAR FOR Q9                    35360022
         XC    SEOBSV,SEOBSV            CLEAR EOB OFFSET                35440022
         XC    SCBCTBAC,SCBCTBAC        CLEAR OUT COUNT OF DATA SA59199 35480005
         B     MVCCTBSZ                 RESET SIZE                      35520022
UPDT     EQU   *                                                        35600022
         MVC   SCBCTBSZ(TWO),QCBEDAMT   RESET CTB SIZE TO QCNTRL        35680022
         XC    DRQCURQ,DRQCURQ          CLEAR CURRENT QCB PTR           35760022
         NI    SCBQTYPE,AVTEFF-SCBBFMM  RESET MIDDLE OF MSG BIT         35840022
         B     CKRS                     CHECK FOR RS INSERTION          35920022
         SPACE 1                                                        36000022
*********************************************************************** 36080022
*    THIS ROUTINE IS ENTERED WHEN THE DATA IN THIS BUFFER WILL NOT      36160022
*    FIT INTO A CTB                                                     36240022
         SPACE 1                                                        36320022
*    THIS ROUTINE CHECKS FOR A RECALLED BUFFER                          36400022
*    FOR A NON RECALLED BUFFER SCBEOB IS SET TO SCBCTBSZ,               36480022
*    SCBCTBSZ IS THE RESET TO SIZE SPECIIFIED ON QNCTRL OPERAND         36560022
*    OF TERM MACRO, AND PRFSIZE IS SET TO QCBCTBSZ                      36640022
*                                                                       36720022
*    FOR A RECALLED BUFFER SCBEOB IS ADDED TO SCBCTBSZ AND SAVED        36800022
*    SCBEOB IS NOT UPDATED UNTIL RETURN TO THIS MODULE IS MADE          36880022
*    BY GD.                                                             36960022
*    SCBCTBSZ IS RESET TO SIZE SPECIFIED ON QCNTRL OPERAND OF           37040022
*    TERMINAL MACRO                                                     37120022
*********************************************************************** 37200022
SETCTBND EQU   *                                                        37280022
         SPACE 2                                                        37360022
         OI    SCBCTBFL,SCBCTBND        SET CTB END                     37440022
         TM    PRFSTAT1,PRFCNCLN        RECALLED BUFFER?                37520022
         BO    RECALL                   YES                             37600022
         LH    R5,SCBCTBSZ              GET CTB SIZE AND SET AS         37680022
*                                       NEW DATA COUNT IN THIS          37760022
*                                       BUFFER                          37840022
         AR    R5,R1                    ADD PREFIX SIZE                 37920022
         B     MVC                      GO MOVE                         38000022
         SPACE 2                                                        38080022
RECALL   EQU   *                                                        38160022
         LH    R5,SCBCTBSZ              GET CTB SIZE AND                38240022
         AH    R5,SCBEOB                CALCULATE NEW SCBEOB PTR        38320022
MVC      EQU   *                                                        38400022
         STH   R5,SEOBSV                SAVE SCBEOB OFFSET              38640022
         STH   R5,PRFSIZE               RESET PRFSIZE TO REFLECT        38720022
         MVC   SCBDEOB(ONE),PRFNTXT     SET DISK RECORD                 38800022
         MVC   SCBDEOB+ONE(THREE),PRFCRCD                               38880022
*                                       SET DISK ADDRESS                38960022
MVCCTBSZ EQU   *                                                        39040022
         MVC   SCBCTBSZ(TWO),QCBEDAMT   RESET CTB SIZE TO QCNTRL        39120022
         SPACE 1                                                        39200022
         SPACE 2                                                        39280022
         SPACE 1                                                        39360022
CKRS     EQU   *                                                        39440022
         TM    SCBCTBSV,CTBSPCHR        IS RS TO BE INSERTED            39520022
         BZ    CKSTAT                   NO GO SEE IF STATUS SPECIFIED   39600022
         SPACE 1                                                        39680022
         LH    R5,PRFSIZE               AMT DATA IN BUFFER              39760022
         BAL   R14,INSERTRS             GO INSERT RS                    39840022
         SPACE 2                                                        39920022
         B     CKSTAT                   CHECK FOR STATUS                40000022
*    CONTROL IS GIVEN TO THIS ROUTINE WHEN INTEGER NOT SPECIFIED ON     40080022
*    QCNTRL                                                             40160022
         SPACE 1                                                        40240022
CKEOM    EQU   *                                                        40320022
         TM    PRFSTAT1,PRFNLSTN        EOM BUFFER                      40400022
         BO    IDLES                    NO GO HOOK BUFFER IN CHAIN      40480022
         NI    SCBQTYPE,AVTEFF-SCBBFMM  RESET MIDDLE MSG BIT            40560022
         SPACE 1                                                        40640022
         TM    SCBCTBSV,CTBSPCHR        IS RS CHAR TO BE INSERTED       40720022
         BZ    INCRBFCT                 NO UPDATE DRQ BUFFER COUNT      40800022
         LH    R5,PRFSIZE               GET DATA COUNT IN BUFFER        40880022
         BAL   R14,INSERTRS             GO INSERT CTB CHARS             40960022
         SPACE 1                                                        41040022
INCRBFCT EQU   *                                                        41120022
         SPACE 2                                                        41200022
         CLC   QCBEDAMT(TWO),MSGCNT1    DID QCNTRL SPECIFY ONE MSG      41280022
         BE    CKSTAT                   YES,SAYS ONE MSG FROM THIS Q    41360022
*                                       GO SEE IF STATUS SPECIFIED      41440022
*                                       NO ASSUME MULTI MSG             41520022
         LH    R5,SCBCTBSZ              GET NUMBER OF MESSAGES TO       41600022
         BCTR  R5,ZERO                  DECR NUMBER OF MSGS             41680022
         STH   R5,SCBCTBSZ              SAVE MSG COUNT                  41760022
         BAL   R14,MSGSERV              GO MARK MSG SERVICED            41840022
         NI    QCBEFLG,AVTEFF-QCBEDATA  RESET DATA IN MSG LLAG          41920022
         SPACE 1                                                        42000022
         CLC   SCBCTBSZ(TWO),AVTFZERO   IS MSG COUNT ZERO               42080022
         BE    QSERV                    YES GO MARK Q SERV              42160022
         NC    DRQCTBMX,DRQCTBMX        CTBMAX SPECIFIED                42240022
         BZ    CKPRILVL                 NO GO SEE IF UNSENT MSG         42320022
         SR    R0,R0                    CLEAR WORK REG                  42400022
         IC    R0,DRQCTBCT              GET NO OF MSGS REMAINING        42480022
         BCTR  R0,ZERO                  DECR NO OF MSGS                 42560022
         STC   R0,DRQCTBCT              AND SAVE                        42640022
         LTR   R0,R0                    ANY LEFT                        42720022
         BZ    SETCEOM                  NO GO SET CONC EOM              42800022
         SPACE 1                                                        42880022
CKPRILVL EQU   *                                                        42960022
         SR    R5,R5                    CLEAR WORK REG                  43040022
         IC    R5,QCBENPLV              GET NO OF PRIORITY LEVELS       43120022
         LA    RPQCB,IEDQPQCB-IEDQQCB(ZERO,RQCB)                        43200022
*                                       POINT TO FIRST PRIORITY         43280022
*                                       LEVEL QCB                       43360022
LOOPPQCB EQU   *                                                        43440022
         NC    QCBFFEFO,QCBFFEFO        IS THERE AN UNSENT MSG          43520022
         BNZ   IDLES                    YES                             43600022
         LA    RPQCB,QCBPEND            ADDR NEXT PRIORITY LEVEL QCB    43680022
         BCT   R5,LOOPPQCB              GO TEST NEXT PRI LEVEL          43760022
         SPACE 1                                                        43840022
QSERV    EQU   *                                                        43920022
         BAL   R14,EXTFIND              GO FIND CORRECT EXTENSION       44000022
         OI    QCBEFLG-IEDQQCBE(R5),QCBESRVC                            44080022
*                                       SET Q SERVICED                  44160022
         CLC   DRQCURQ(THREE),AVTFZERO  IS CURRENT PTR ZERO             44240022
         BE    OUTMSG                   YES SET OUTMSG PENDING          44320022
         XC    DRQCURQ(THREE),DRQCURQ   CLEAR CURRENT QCB POINTER       44400022
         CLC   QCBEDAMT,MSGCNT1         MULTI MSG                       44480022
         BNE   CKCEOM                   YES SKIP SET OF OUTMSG          44560022
*                                       PENDING                         44640022
OUTMSG   EQU   *                                                        44720022
         OI    QCBEFLG-IEDQQCBE(R5),QCBEOMSG                            44800022
*                                       SET OUTMSG PENDING              44880022
         OI    QCBEFLG-IEDQQCBE(RQCBE),QCBEOMSG                         44960022
*                                       SET OUTMSG PENDING              45040022
         B     CKCEOM                   CHECK CONC EOM                  45120022
         SPACE 1                                                        45200022
EXTFIND  EQU   *                                                        45280022
         LR    R5,RQCBE                 SET QCBE ADDR                   45360022
         TM    QCBEFLG,QCBEOPL          IS NEW PRIORITY LEVEL           45440022
*                                       SCHEME BEING USED               45520022
         BCR   8,R14                    NO  RETURN                      45600022
         SR    R15,R15                  CLEAR WORK REG                  45680022
         SR    R1,R1                    ZERO WORK REG                   45760022
         IC    R15,QCBELGTH             GET QCBE LENGTH                 45840022
         AR    R5,R15                   POINT TO FIRST LEVEL EXT        45920022
         IC    R1,SCBPRI                GET INDEX TO CURRENT PRI LEVEL  46000022
         IC    R15,QCBELGTH-IEDQQCBE(R5)                                46080022
*                                       GET LENGTH OF LEVEL QCB EXT     46160022
         MR    R0,R15                   MULTIPLY PRI LEVEL INDEX        46240022
*                                       BY LENGTH OF A PRI LEVEL EXT    46320022
         AR    R5,R1                    POINT TO CURRENT PRI LEVEL EXT  46400022
         BR    R14                      RETURN TO CALLER                46480022
CKSTAT   EQU   *                                                        46560022
         TM    QCBEFLG,QCBEOPL          IS THIS MSG,L           SA52971 46570022
         BZ    NOZERO                   NO, EXTENSION NOT SET   SA52971 46580022
         XC    SCBSCHDR(3),SCBSCHDR     ZERO HDR PTR TO TELL    SA52971 46590022
*                                         HM03 IT'S IN EXTENSIONSA52971 46600022
*                                         ONLY                  SA52971 46610022
NOZERO   EQU   *                                                SA52971 46620022
         TM    QCBEFLG,QCBESTAT         IS STATUS SPECIFIED ON QCNTRL   46640022
         BZ    QSERV                    NO,GO MARK Q SERVICED           46720022
         BAL   R14,EXTFIND              GO FIND CORRECT EXTENSION       46800022
         DROP  RQCBE                                                    46880022
         USING IEDQQCBE,R5                                              46960022
         OI    QCBEFLG,QCBEHELD         SET Q HELD                      47040022
         CLC   DRQCURQ(THREE),AVTFZERO  CURRENT QCB PTR ZERO            47120022
         BE    OUTMSG1                  BRANCH IF YES                   47200022
         TM    QCBEFLG,QCBECNT          BYTE CNT SPEC                   47280022
         BO    NOOUTMSG                 BRANCH IF YES                   47360022
OUTMSG1  EQU   *                                                        47440022
         OI    QCBEFLG,QCBEOMSG         SET OUTMSG PENDING              47520022
         OI    QCBEFLG-IEDQQCBE(RQCBE),QCBEOMSG                         47600022
*                                       SET OUTMSG PENDING              47680022
NOOUTMSG EQU   *                                                        47760022
         XC    DRQCURQ,DRQCURQ          CLEAR CURRENT QCB PTR           47840022
         DROP  R5                                                       47920022
         USING IEDQQCBE,RQCBE                                           48000022
         SPACE 1                                                        48080022
*    THIS ROUTINE CHECKS FOR CONCENTRATED END OF MESSAGE                48160022
*    CONCENTRATED EOM IS SET WHEN                                       48240022
*        (1)  NO QUEUES ARE LEFT IN DRQ TO SERVICE                      48320022
*        (2)  OR MAXCTB HAS BEEN REACHED                                48400022
*    WHICH EVER OCCURS FIRST                                            48480022
         SPACE 1                                                        48560022
CKCEOM   EQU   *                                                        48640022
         LR    RQCB,RDRQ                INIT REG FOR LOOP               48720022
         SH    RQCB,HTWELVE             DECR REG FOR LOOP               48800022
LOOPDRQ  EQU   *                                                        48880022
         LA    RQCB,EIGHT(RQCB)         INIT REG FOR LOP                48960022
         L     RQCB,FOUR(RQCB)          GET NEXT ELEMENT IN DRQ CHAIN   49040022
         CLI   FOUR(RQCB),ZERO          IS THIS LAST ELEMENT ON DRQ     49120022
         BE    SETCEOM                  YES,GO SET CONC EOM             49200022
         SH    RQCB,HEIGHT              POINT TO QCB                    49280022
         LH    RQCBE,QCBEXTO            GET QCB EXTENSION               49360022
         AR    RQCBE,RQCB               ADDRESS                         49440022
         TM    QCBDSFLG,QCBHELD         HAS REUS GOT Q                  49520022
         BO    LOOPDRQ                  BRANCH IF YES                   49600022
         TM    QCBSTAT,QCBTRMHO         IS Q HELD                       49680022
         BO    LOOPDRQ                  BRANCH IF YES                   49760022
         TM    QCBEFLG,QCBEHELD+QCBESRVC                                49840022
*                                       IS THIS QCB AVAILABLE           49920022
         BNZ   LOOPDRQ                  NO GO CHECK NEXT                50000022
*                                       ELEMENT IN CHAIN                50080022
         TM    QCBEFLG,QCBEOPL          NEW PRI LEVEL USED              50160022
         BO    LEVEL                    YES GO SEE IF ANY LEVEL         50240022
*                                       WITH MESSAGES AVAILABLE         50320022
         SR    R5,R5                    CLEAR WORK REG                  50400022
         IC    R5,QCBENPLV              GET NO OF PRI LEVELS            50480022
         LA    RPQCB,IEDQPQCB-IEDQQCB(ZERO,RQCB)                        50560022
*                                       POINT TO FIRST PRIORITY         50640022
*                                       LEVEL QCB                       50720022
LOOPP    EQU   *                                                        50800022
         NC    QCBFFEFO,QCBFFEFO        IS THERE AN UNSENT MSG          50880022
         BNZ   RESETDRQ                 YES GO CHECK FOR CONC EOM       50960022
         LA    RPQCB,QCBPEND            ADDR NEXT PRIORITY LEVEL QCB    51040022
         BCT   R5,LOOPP                 BRANCH IF MORE LEVELS           51120022
         B     LOOPDRQ                  GO SEE IF ANY MORE MSGS         51200022
RESETDRQ EQU   *                                                        51280022
SETEOM   EQU   *                                                        51360022
         SR    R5,R5                    CLEAR WORK REG                  51440022
         NC    DRQCTBMX,DRQCTBMX        ARE TO SEND TILL Q              51520022
*                                       EMPTY                           51600022
         BZ    IDLES                    BRANCH IF YES                   51680022
         IC    R5,DRQCTBCT              GET NO OF MESSAGES REMAINING    51760022
*                                       TO BE ADDED TO THIS CONC MSG    51840022
         BCTR  R5,ZERO                  DECR NO OF MESSAGES             51920022
         STC   R5,DRQCTBCT              AND SAVE                        52000022
         LTR   R5,R5                    IS COUNT ZERO                   52080022
         BP    IDLES                    NO                              52160022
         SPACE 1                                                        52240022
SETCEOM  EQU   *                                                        52320022
         L     R1,LCBSCBDA-1            GET CONC SCB ADDR               52400022
         OI    SCBSTAT1-IEDQSCB(R1),SCBCEND                             52480022
*                                       SET CONC EOM                    52560022
         NI    SCBSTAT1-IEDQSCB(R1),AVTEFF-SCBNIDLE                     52640022
*                                       RESET SO BUFS WILL BE HOOKED IN 52720022
         MVC   DRQCTBCT(ONE),DRQCTBMX   RESET MSG COUNT                 52800022
         TM    LCBERBST,LCBDLNKN+LCBEOMSG                               52810022
*                                       IS ERB AVAILABLE                52820022
         BNZ   EXIT1                    BRANCH IF YES                   52830022
         OI    PRFTIC,PRFEOMSG          SET NOT EOM                     52840022
         B     EXIT1                    EXIT                            52880022
IDLES    EQU   *                                                        52960022
         L     R1,LCBSCBDA-1            GET  POINTER TO CONC SCB        53040022
         TM    SCBSTAT1-IEDQSCB(R1),SCBCBGN                             53120022
*                                      IS THIS CONCENTRATED             53200022
*                                       MESSAGE BEGIN                   53280022
         BZ    CKBUFOUT                 BRANCH IF NO                    53360022
         OI    SCBSTAT1-IEDQSCB(R1),SCBNIDLE                            53440022
*                                       SET FIRST TIME SW               53520022
*                                       SET SWITCH SO GD WILL NOT       53600022
*                                       LINK BUFFERS INTO WRITE         53680022
*                                       IDLE LOOP                       53760022
CKBUFOUT EQU   *                                                        53840022
         CLI   DRQBUFCT,ZERO            HAVE REACHED BUFFOUT            53920022
         BNE   NOBGN                    NO                              54000022
         TM    SCBSTAT1-IEDQSCB(R1),SCBNIDLE                            54080022
*                                       IS THIS BUFFOUT                 54160022
         BZ    NOBGN                    NO SKIP PRI SET                 54240022
         MVI   LCBERBPY,PRIINTRQ        SET PRI FOR FIRST PCI           54320022
*                                       FOR PCI POST                    54400022
         NI    SCBSTAT1-IEDQSCB(R1),AVTEFF-SCBNIDLE                     54480022
*                                       RESET FIRST TIME SW SO          54560022
*                                       GD WILL LINK BUFFERS            54640022
*                                       INTO CHAIN                      54720022
NOBGN    EQU   *                                                        54800022
         OI    DRQFLAG3,DRQERBAV        SET ERB NOT AVAIL               54880022
         TM    LCBERBST,LCBDLNKN+LCBEOMSG                               54960022
*                                       IS ERB AVAILABLE                55040022
         BZ    CHKREQ                   BRANCH IF NO                    55120022
         NI    LCBERBST,LCBDLNKF        SET ERB NOT POSTABLE            55200022
         TM    PRFSTAT1,PRFNLSTN        EOM BUFFER                      55280022
         BZ    CKBUFCT                  YES CHECK DRQBUFCT              55360022
         TM    SCBCTBFL,SCBCTBND        IS THIS CTB END                 55440022
         BO    CKBUFCT                  BRANCH IF YES                   55520022
         LA    R14,EXIT1                SET EXIT ADDR                   55600022
         CLI   DRQERBCT,ZERO            IS DRQ ERB COUNT ZERO           55680022
         BNE   SET                      BRANCH IF NO                    55760022
CKBUFCT  EQU   *                                                        55840022
         SR    R5,R5                    CLEAR WORK REG                  55920022
         IC    R5,DRQBUFCT              GET BUF CT                      56000022
         LTR   R5,R5                    IS COUNT POSITIVE               56080022
         BP    POST                     YES POST ERB                    56160022
         L     R5,LCBDCBPT              GET DCB PTR                     56240022
         USING IHADCB,R5                                                56320022
         TM    DCBPCI,DCBPCISN          DCP = PCI = N                   56400022
         BO    CKPOST                   YES SEE IF POST OR              56480022
*                                       FORCE CONC EOM                  56560022
         LA    R14,EXIT1                SET EXIT A                      56640022
SET      EQU   *                                                        56720022
         NI    LCBERBST,AVTEFF-LCBEOMSG RESET SO ERB AVAIL              56800022
         OI    LCBERBST,LCBDLNKN        SET ERB AVAIL                   56880022
         BR    R14                      EXIT                            56960022
         SPACE 1                                                        57040022
CHKREQ   EQU   *                                                        57048022
         TM    LCBERBST,LCBCOMPL        OUTSTANDING CPB                 57056022
         BZ    EXIT1                    BRANCH IF NO                    57064022
         NI    SCBSTAT1-IEDQSCB(R1),AVTEFF-SCBNIDLE                     57072022
*                                       SET TO LINK BUFFERS IN CHAIN    57080022
         L     R5,LCBDCBPT              DCB ADDR                        57088022
         TM    DCBPCI-IHADCB(R5),DCBPCISN                               57096022
*                                       PCI EQUAL N                     57104022
         BZ    EXIT1                    BRANCH IF NO                    57112022
CKPOST   EQU   *                                                        57120022
         LA    R14,SETCEOM              SET EXIT ADDR                   57200022
         TM    PRFSTAT1,PRFNLSTN        EOM BUFFER                      57280022
         BZ    SET                      BRANCH IF YES                   57360022
         TM    SCBCTBFL,SCBCTBND        IS THIS CTB END                 57440022
         BO    SET                      BRANCH IF YES                   57520022
         MVI   DRQBUFCT,ONE             SET SO GET A BUFFER             57600022
         DROP  R5                                                       57680022
POST     EQU   *                                                        57760022
         L     R5,AVTCSCH               GET ADDR OF CONC SCHED          57840022
         BCTR  R5,ZERO                  SUBTRACT 1                      57920022
         BCTR  R5,ZERO                  SUBTRACT 1 TO POINT TO          58000022
*                                       CONC SCHED QCB                  58080022
         ST    R5,LCBERB                SET QCB ADDR IN ERB             58160022
         MVI   LCBERBPY,PRIEDISP        SET PRIORITY                    58240022
         LA    R1,LCBERB                SET ELEM ADDR FOR DISP          58320022
         BAL   R14,ENQUEUE              GO PUT ERB ON READY Q           58400022
         SPACE 2                                                        58480022
*    THIS EXIT GOES TO AK  OR A4 IF NO MSGFORM                          58560022
EXIT1    EQU   *                                                        58640022
         NI    DRQFLAG3,AVTEFF-DRQERBAV SET ERB AVAIL                   58720022
EXIT2    EQU   *                                                        58800022
         L     R1,PARMSAVE              GET POINTER TO PARMLIST         58880022
         LA    R1,TWO(R1)               POINT TO NEXT PARMLIST          58960022
         LA    R13,AVTSAVE2             ADDR OF SAVE2                   59040022
         L     R15,AVTUI                USER INTERFACE                  59120022
         BR    R15                      EXIT                            59200022
         SPACE 1                                                        59280022
LEVEL    EQU   *                                                        59360022
         LR    R5,RQCBE                 SAVE QCBE ADDR                  59440022
         SR    R15,R15                  CLEAR WORK REG                  59520022
         IC    R15,QCBENPLV             GET NO OF PRI LEVELS            59600022
CKNXTLVL EQU   *                                                        59680022
         SR    R0,R0                    CLEAR WORK REG                  59760022
         IC    R0,QCBELGTH-IEDQQCBE(R5) GET LENGTH OF EXTENSION         59840022
         AR    R5,R0                    POINT TO NEXT EXT               59920022
         TM    QCBEFLG-IEDQQCBE(R5),QCBEHELD+QCBESRVC                   60000022
*                                       IS PRI LEVEL Q SERVICED         60080022
*                                       OR HELD                         60160022
         BZ    CKFEFO                   NO SEE IF ANY UNSENT MSGS ON    60240022
*                                       THIS LEVEL                      60320022
         BCT   R15,CKNXTLVL             YES GO CHECK NEXT EXT           60400022
         B     LOOPDRQ                  NO  EXTENSIONS AVAILABLE        60480022
*                                       GO CK NEXT ITEM ON DRQ          60560022
CKFEFO   EQU   *                                                        60640022
         SR    R1,R1                    CLEAR WORK REG                  60720022
         IC    R1,QCBENPLV              GET NO OF PRI LEVELS            60800022
         SR    R1,R15                   GET PRI LEVEL INDEX             60880022
         SR    R14,R14                  CLEAR WORK REG                  60960022
         LA    R14,QCBPSIZE             GET SIZE OF PRI LEVEL QCB       61040022
         MR    R0,R14                   PRI LEVEL INDEX X SIZE          61120022
         LA    RPQCB,IEDQPQCB-IEDQQCB(R1,RQCB)                          61200022
*                                       POINT TO FIRST PRI LEVEL Q      61280022
         NC    QCBFFEFO,QCBFFEFO        ANY UNSENT MESSAGES             61360022
         BNZ   RESETDRQ                 YES GO CHECK FOR CONC EOM       61440022
         BCT   R15,CKNXTLVL             YES GO CHECK NEXT EXT           61520022
         B     LOOPDRQ                  NO EXTENSIONS  HAVE UNSENT      61600022
*                                       MESSAGES. GO SEE IF ANY         61680022
*                                       ITEMS ON DRQ                    61760022
*    THIS ROUTINE GETS A UNIT, SETS UP BUFFER PREFIX, AND POST THE      61840022
*    BUFFER TO DISK I/O TO MARK A MSG SERVICED                          61920022
         SPACE 1                                                        62000022
GETUNIT  EQU   *                                                        62080022
         L     R1,AVTBFREB              ADDR OF FIRST UNIT AVAIL        62160022
         LA    R1,ZERO(R1)              CLEAR HI-ORDER BYTE             62240022
         LTR   R1,R1                    ANY UNITS AVAILABLE             62320022
         BCR   EIGHT,R14                NO RETURN TO CALLING RTN        62400022
         SPACE 1                                                        62480022
         DROP  RPREFIX                                                  62560022
         USING IEDQPRF,R1                                               62640022
         MVC   AVTBFREB+ONE(THREE),PRFLINK                              62720022
*                                       DELINK BUFFER                   62800022
         LH    R5,AVTAVFCT              GET BUFFER COUNT                62880022
         N     R5,AVTCLRHI              CLEAR HI BYTES                  62960022
         BCTR  R5,ZERO                  SUBTRACT ONE                    63040022
         STH   R5,AVTAVFCT              RESTORE COUNT                   63120022
         XC    PRFTIC+ONE(THREE),PRFTIC+ONE                             63200022
*                                                                       63280022
         B     FOUR(R14)                RETURN TO CALLING RTN           63360022
*                                       WITH A UNIT                     63440022
MSGSERV  EQU   *                                                        63520022
         LR    R0,R14                   SAVE RETURN ADDR                63600022
         BAL   R14,GETUNIT              GO GET A UNIT                   63680022
         B     NOUNITS                  NO UNITS ARE AVAILABLE          63760022
         LR    R14,R0                   RESET RETURN REG                63840022
         SPACE 1                                                        63920022
         MVC   ZERO(PRFSHDR-PRFRCB,R1),ZERO(RPREFIX)                    64000022
*                                       COPY EOM PREFIX TO NEW UNIT     64080022
         MVI   PRFNBUNT,ONE             SET UNIT COUNT TO ONE           64160022
         SPACE 1                                                        64240022
*    SET MESSAGE SERVICED                                               64320022
         SPACE 1                                                        64400022
         XC    SCBTRANS,SCBTRANS        CLEAR FOR FA                    64480022
         MVI   SCBHBFNO,ZERO            CLEAR RESIDUAL COUNTER          64560022
         MVZ   SCBHBFNO(ONE),SCBQTYPE   SAVE SCBQTYPE FOR FA            64640022
         NI    SCBQTYPE,X0F             CLEAR HIGH ORDER HALF           64720022
         MVC   PRFSRCE(3),SCBFEFO       SET FEFO CHAINING       SA52971 64740022
         MVC   PRFTQBCK(1),SCBPRI         FIELDS FOR FA         SA52971 64760022
         MVC   PRFTQBCK+1(2),SCBOSEQ                            SA52971 64780022
         SPACE 1                                                        64800022
*    SET UP BUFFER TO POST TO DISK I/O                                  64880022
         SPACE 1                                                        64960022
         LA    R5,AVTDSIOB              DISK I/O QUEUE ADDRESS          65040022
         ST    R5,PRFRCB                SET IN BUFFER                   65120022
         MVI   PRFPRI,PRIDKSRV          SET PRIORITY TO MARK SERV       65200022
         SPACE 1                                                        65280022
         DROP  R1                                                       65360022
         USING IEDQPRF,RPREFIX                                          65440022
ENQUEUE  EQU   *                                                        65520022
         STM   R14,RBASE,TWELVE(R13)    SAVE REGS IN AVTSAV3            65600022
         ST    R13,PARMLIST             SAVE PTR TO AVTSAV3             65680022
         L     RDISP,AVTEA              GET ADDR OF DISPATCHER          65760022
         DROP  RQCBE                                                    65840022
         USING IEDQDISP,RDISP                                           65920022
         LA    R13,AVTSAVE2             SET FOR DISPATCHER              66000022
         BAL   R14,DSPPOSTR             GO ENQUEUE BUFFER ON RDY Q      66080022
         L     R13,PARMLIST             RESTORE SAVE AREA ADDR          66160022
         LM    R14,RBASE,TWELVE(R13)    RESTORE REGS FROM AVTSAV3       66240022
         BR    R14                      RETURN TO CALLING ROUTINE       66320022
RIDBUF   EQU   *                                                        66400022
         LA    R5,AVTBFRTB              ADDR OF BUFFER RETURN           66480022
         ST    R5,PRFRCB                SET IN BUFFER                   66560022
         MVI   PRFPRI,PRIBFRTB          SET PRIORITY                    66640022
         LR    R1,RPREFIX               SET PARM REG                    66720022
         BAL   R14,ENQUEUE              PUT ON RDY Q                    66800022
         NC    SCBDEOB,SCBDEOB          IS THIS BUFFER A RCL ONE        66880022
         BNZ   GODISP                   BRANCH IF YES                   66960022
         MVC   SCBDEOB(ONE),PRFNTXT     SET DISK RCD                    67040022
         MVC   SCBDEOB+ONE(THREE),PRFCRCD                               67120022
*                                       SET DISK ADDRESS                67200022
GODISP   EQU   *                                                        67280022
         LA    R13,AVTSAVE2             SET FOR DISP                    67360022
         L     RDISP,AVTEA              ADDR OF DISPATCHER              67440022
         B     DSPDISP                  GO AWAY                         67520022
         SPACE 1                                                        67600022
         DROP  RDISP                                                    67680022
         USING IEDQQCBE,RQCBE                                           67760022
*    THIS SUBROUTINE FORCES CONCENTRATED END OF MESSAGE IF A BUFFER     67840022
*    UNIT IS NOT AVAILABLE FOR MARKING THIS MESSAGE SERVICED.           67920022
         SPACE 1                                                        68000022
NOUNITS  EQU   *                                                        68080022
         LR    R14,R0                   RESET RETURN REG                68160022
         MVI   DRQCTBCT,ZERO            RESET CTB COUNT                 68240022
         MVC   SCBCTBSZ(TWO),AVTFZERO   RESET MSG COUNT         SA57673 68320022
         XC    SCBERRST,SCBERRST        CLEAR SCB ERROR WORD     S22027 68360022
         OI    QCBEFLG,QCBEOMSG         SET OUTMSG PENDING              68400022
         B     FOUR(R14)                RETURN                          68480022
*     THIS ROUTINE INSERTS THE ENDING CHARACTERS SPECIFIED ON           68560022
*     THE QCNTRL OPERAND OF THE TERMINAL MACRO. WHEN ENTERED            68640022
*     R5 CONTAINS THE OFFSET INTO THE BUFFER TO INSERT THE CTB          68720022
*     END CHARS                                                         68800022
         SPACE 2                                                        68880022
INSERTRS EQU   *                                                        68960022
         STM   R14,RBASE,TWELVE(R13)    SAVE REGS                       69040022
         SR    R3,R3                    CLEAR WORK REG                  69120022
         IC    R3,PRFNBUNT              GET NO UNITS THIS BUFFER        69200022
         LH    R7,AVTKEYLE              UNIT SIZE                       69280022
         MR    R2,R7                    UNITS X UNIT ZIZE               69360022
         LA    R3,ONE(R3)               TRUE INSRT OFFSET               69440022
         STH   R3,DATOFF(,RPREFIX)      SPACE AVAILABLE                 69520022
         BCTR  R3,ZERO                  RESTORE SPACE AVAIL             69600022
         SR    R3,R5                    SUBTRACT                        69680022
         STH   R3,INSOFF(,RPREFIX)      OFFSET AT WHICH TO INSRT DATA   69760022
         IC    R2,QCBELRS               LENGTH OF DATA TO INSRT         69840022
         LA    R3,QCBERS                ADDR OF DATA TO UNSRT           69920022
         ST    R3,AVTPARM3              SET ADDR FOR AF                 70000022
         STC   R2,AVTPARM3              SET LENGTH FOR AF               70080022
         LA    R14,0(R14)               CLEAR HI ORDER BYTE     SA60814 70088022
         ST    R14,R14SAVE              SAVE RETURN REG         SA60814 70096022
         SR    R2,R2                    CLEAR REG               SA60814 70104022
         IC    R2,AVTPARM3              LNG OF DATA TO INSERT   SA60814 70112022
         CH    R2,INSOFF(RPREFIX)       ENOUGH SPACE FOR INSERT SA60814 70120022
         BNH   NOUNIT                   BR YES                  SA60814 70128022
         OI    R14SAVE,ADDUNIT          REMEMBER TO ADJUST SIZE SA60814 70136022
NOUNIT   EQU   *                                                SA60814 70144022
         L     R5,PARMSAVE              GET PARM LIST ADDR              70160022
         USING PRMLST,R5                                                70240022
         MVC   AVTPARM(ONE),PRMAOOFF    SET AO OFFSET                   70320022
         MVI   AVTPARM+ONE,ZERO         INDICATE DATA TYPE = CHARS      70400022
         MVC   AVTPARM+TWO(ONE),PRMAFOFF                                70480022
*                                       SET AF OFFSET                   70560022
         DROP  R5                                                       70640022
         LM    R14,RBASE,TWELVE(R13)    RESTORE REGS                    70720022
         LA    RPARM,AVTPARM            PARAMETER LIST ADDR             70880022
         L     R15,AVTUI                USER INTERFACR                  70960022
         BALR  R14,R15                  GO INSRT DATA                   71040022
         L     R14,R14SAVE              RESTORE RETURN REG      SA60814 71120022
         MVI   RTNCDE,AVTECD4           ASSUME RAN OUT OF UNITS SA60814 71220022
         LTR   R15,R15                  RUN OUT OF UNITS        SA60814 71320022
         BNZR  R14                      BR YES                  SA60814 71420022
         MVI   RTNCDE,AVTEZERO          RESET RETURN CODE       SA60814 71520022
         SR    R1,R1                    CLEAR REG                       71680022
         IC    R1,QCBELRS               LNGTH OD DATA INSRTED           71760022
         AH    R1,PRFSIZE               INCR PRFSIZE                    71840022
         TM    R14SAVE,ADDUNIT          EXTRA UNIT ADDED        SA60814 71850022
         BZ    NOTADDED                 BR NO                   SA60814 71860022
         SH    R1,AVTKEYLE              ADJUST SIZE             SA60814 71870022
NOTADDED EQU   *                                                SA60814 71880022
         STH   R1,PRFSIZE               AND SAVE AS NEW DATA LNGTH      71920022
         BR    R14                      RETURN                          72000022
INSERT   EQU   *                                                        72080022
*    WHEN ENTERED R1 CONTAINS A POINTER TO DVCID ENTRY FOR THIS         72160022
*    TERMINAL OR ZERO, R15 CONTAINS A POINTER TO THE OPTION FIELD       72240022
*    OR ZERO                                                            72320022
         SPACE 1                                                        72400022
*        THE OPTION FIELD DATA IS CHECKED TO INSURE THAT THE INSERT     72480022
*    OFFSET IS LE 8                                                     72560022
         SPACE 1                                                        72640022
         STM   R14,RBASE,SAVE           SAVE REGS                       72720022
         OI    SCBCTBSV,CTBINSRT        ASSUME NO INSERTS               72800022
         LR    R11,R15                  SAVE PTR TO OPFIELD             72880022
         TM    SCBCTBSV,CTBDVCID        ARE TO INSERT DVCID             72960022
         BZ    INSRTOP                  NO CHECK IF OPFIELD DATA        73040022
*                                       IS TO BE INSERTED               73120022
         SR    R7,R7                    CLEAR WORK REG                  73200022
         SR    R0,R0                    CLEAR WORK REG                  73280022
         IC    R0,ZERO(R1)              GET LNGTH OF DVCID FIELD        73360022
         LA    R8,ONE(R1)               SET ADDR OF DATA TO INSRT       73440022
         TM    PRFSTAT1,PRFCNCLN        RECALLED BUFFER                 73520022
         BO    RECLLBUF                 YES                             73600022
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   73680022
         BO    INSRT                    BRANCH IF NO                    73760022
         SR    R2,R2                    CLEAR WORK REG                  73840022
         IC    R2,LCBISZE               GET NO OF RESERVES REMAINING    73920022
         LTR   R2,R2                    ANY RESERVES                    74000022
         BZ    INSRT                    BRANCH IF NO                    74080022
         SR    R2,R0                    WILL DVCID FIT IN SPACE AVAIL   74160022
         BM    INSRT                    BRANCH IF NO                    74240022
         STC   R2,LCBISZE               UPDATE RESERVE COUNT            74320022
         AR    R2,R0                    RESTORE PREVIOUS ISZE           74400022
         LA    R2,AVTHDRSZ+ONE(R2)      HDR SIZE + RESERVES             74480022
INSRT1   EQU   *                                                        74560022
         STH   R2,DATOFF(,RPREFIX)      SET AS INSERT OFFSET            74640022
         STH   R0,INSOFF(,RPREFIX)      SET AS SPACE AVAILABLE          74720022
         LA    R2,TWO                   REQUEST INSERT AND RETURN FCN   74800022
         LR    R7,R0                    SET INSERT DATA LENGTH          74880022
         SR    R0,R0                    INDICATE DATA TYPE = CHARS      74960022
         BAL   R14,LINKAF               EXIT TO AF                      75040022
         TM    SCBCTBSV,CTBOPFLD        ARE TO INSERT OPFLD DATA        75120022
         BO    INSRTOP                  BRANCH IF YES                   75200022
         B     OUT                      RETURN                          75280022
INSRTX   EQU   *                                                        75360022
         AR    R7,R5                    TRUE INSERT OFFSET              75440022
INSRT    EQU   *                                                        75520022
         SPACE 1                                                        75600022
*    SET UP BUFFER FOR AO AND AF                                        75680022
         LH    R1,AVTKEYLE              UNIT SIZE                       75760022
         N     R1,AVTCLRHI              CLEAR HI BYTES                  75840022
         SR    R2,R2                    CLEAR WORK REG                  75920022
         ST    R2,INSOFF(,RPREFIX)      CLEAR WORK AREA                 76000022
AGAIN    EQU   *                                                        76080022
         L     RLCB,PRFLCB-1            RESTORE LCB BASE                76160022
         LA    RLCB,ZERO(RLCB)          CLEAR HI BYTE                   76240022
         IC    R2,LCBISZE               GET NO OF IDLES REMAIN          76320022
         LA    R2,AVTTXTSZ+ONE(R7,R2)   ASSUME TEXT BUFFER              76400022
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   76480022
         BO    NOHDR                    BRANCH IF NO                    76560022
         LA    R2,AVTHDRSZ-AVTTXTSZ(R2) TEXT BUFFER                     76640022
NOHDR    EQU   *                                                        76720022
         SPACE 1                                                        76800022
         STH   R2,DATOFF(,RPREFIX)      SET AS INSERT OFFSET            76880022
         SPACE 1                                                        76960022
*    BUILD PARM LIST FOR AO AND AF                                      77040022
         SPACE 1                                                        77120022
         LR    R7,R0                    SET INSERT DATA LENGTH          77200022
         CR    R0,R1                    WILL ALL DATA FIT IN            77280022
*                                       SPACE AVAIL                     77360022
         BNH   ALLONE                   YES GO INSERT IT                77440022
         LR    R7,R1                    GET SPACE AVAIL                 77520022
         SR    R0,R7                    SAVE REMAINING AMT OF DATA      77600022
*                                       TO INSERT                       77680022
         LNR   R0,R0                    INDICATE MORE DATA TO INSRT     77760022
ALLONE   EQU   *                                                        77840022
         L     R5,PARMSAVE              ADDR OF PARMLIST                77920022
         USING PRMLST,R5                                                78000022
         ST    R8,AVTPARM3              SET ADDR IN PARMLIST            78080022
         STC   R7,AVTPARM3              SET INSERT DATA LENGTH          78160022
         MVC   AVTPARM(ONE),PRMAOOFF    SET AO OFFSET                   78240022
         MVI   AVTPARM+ONE,ZERO         INDICATE DATA TYPE = CHARS      78320022
         MVC   AVTPARM+TWO(ONE),PRMAFOFF                                78400022
*                                       SET AF OFFSET                   78480022
         LA    RPARM,AVTPARM            GET PARAMETER LIST ADDR         78560022
         ST    R0,R14SAVE               SAVE REF                        78640022
         L     R15,AVTUI                ADDR OF USER INTERFACE          78720022
         BALR  R14,R15                  GO INSERT DATA                  78800022
         LTR   R15,R15                  HAVE WE RUN OUT OF INITS        78880022
         BNZ   ERREXIT                  BRANCH IF YES                   78960022
         NI    SCBCTBSV,AVTEFF-CTBINSRT INDICATE INSERTS DONE           79040022
         LH    R5,SCBCTBAC              AMOUNT OF DATA INSERTED         79120022
         SR    R5,R7                    DECR BY AMT INSERTED NOW        79200022
         STH   R5,SCBCTBAC              AND SAVE                        79280022
         L     R0,R14SAVE               RESTORE REG                     79360022
         LTR   R0,R0                    ANY MORE DATA TO INSRT          79440022
         BP    FINALIZE                 BRANCH IF NO                    79520022
         LPR   R0,R0                    SET REG POSITIVE                79600022
         SR    R2,R2                    CLEAR WORK REG                  79680022
         AR    R8,R7                    UPDATE ADDR OF DATA TO INSERT   79760022
         TM    PRFSTAT1,PRFCNCLN        RECALLED BUFFER                 79840022
         BO    RECLLBUF                 BRANCH IF YES                   79920022
         B     INSRT                    GO INSERT DATA                  80000022
         SPACE 1                                                        80080022
FINALIZE EQU   *                                                        80160022
         LA    R4,OUT                   ASSUME NO OPFLD INSERT          80240022
         TM    SCBCTBSV,CTBOPFLD        ARE TO INSERT OPFLD DATA        80320022
         BO    INSRTOP                  BRANCH IF YES                   80400022
CLOSEUP  EQU   *                                                        80480022
         OI    SCBCTBSV,CTBINSRT        ASSUME NO INSERTS               80560022
         LH    R5,DATOFF(,RPREFIX)      GET CURRENT DATA OFFSET         80640022
         N     R5,AVTCLRHI              CLEAR HI BYTE                   80720022
         LH    R2,PRFSIZE               GET TOTAL DATA SIZE             80800022
         N     R2,AVTCLRHI              CLEAR HI BYTE                   80880022
         LA    R2,ONE(R2)               POINT BEYOND LAST BYTE          80960022
         SR    R2,R5                    GET RESIDUAL COUNT              81040022
         LR    R8,R2                    SET FOR AF                      81120022
         SR    R0,R0                    INDICATE DATA TYPE = CHARS      81200022
         LA    R2,ONE                   REQUEST SHIFT DATA FCN          81280022
         BAL   R14,LINKAF1              EXIT TO AF                      81360022
         LH    R2,DATOFF(,RPREFIX)      GET FINAL DATA OFFSET           81440022
         N     R2,AVTCLRHI              CLEAR HI BYTE                   81520022
         SH    R2,INSOFF(,RPREFIX)      GET FINAL DATA SIZE             81600022
         BCTR  R2,ZERO                  POINT TO LAST BYTE OD DATA      81680022
         STH   R2,PRFSIZE               SET IN BUFFER                   81760022
         BR    R4                       RETURN                          81840022
INSRTOP  EQU   *                                                        81920022
         NI    SCBCTBSV,AVTEFF-CTBOPFLD RESET OPFLD INSRT REQ           82000022
         TM    SCBCTBSV,CTBINSFS        ARE TO INSERT OPFIELD    S22027 82008022
*                                       DATA IN FIRST CTB        S22027 82016022
         BZ    INSRTFST                 BRANCH IF YES            S22027 82024022
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER            S22027 82032022
         BO    INSRTFST                 BRANCH IF NO             S22027 82040022
         TM    PRFSTAT1,PRFCNCLN        RECALLED BUFFER          S22027 82048022
         BO    INSRTFST                 BRANCH IF YES            S22027 82056022
         TM    SCBCTBSV,CTBINSRT        ANY INSERTS TO BE DONE   S22027 82057022
         BO    OUT                      BRANCH IF NO             S22027 82058022
         LA    R4,OUT                   SET EXIT ADDR            S22027 82059022
         B     CLOSEUP                  CLOSE BUFFER UP          S22027 82060022
INSRTFST EQU   *                                                        82064022
         SR    R7,R7                    CLEAR WORK REG                  82080022
         IC    R7,ZERO(R11)             GET HI BYTE OF INSERT OFFSET    82160022
         SLL   R7,EIGHT                 SHIFT                           82240022
         IC    R7,ONE(R11)              INSERT OFFSET                   82320022
         CH    R7,AVTFZERO              IS OFFSET ZERO                  82400022
         BE    OFFSTOK                  YES INSERT IMMED AFTER          82480022
*                                       ID OR AT END OF PREFIX          82560022
         CH    R7,HEIGHT                IS OFFSET LENGTH LE 8           82640022
         BH    ERREXIT                  BRANCH IF NO                    82720022
         TM    SCBCTBSV,CTBINSRT        ANY INSERTS TO BE DONE          82800022
         BO    OFFSTOK                  BRANCH IF NO                    82880022
         BAL   R4,CLOSEUP               GO SHIFT DATA                   82960022
OFFSTOK  EQU   *                                                        83040022
         LA    R8,FOUR(R11)             ADDR OF DATA TO INSRT           83120022
         SR    R0,R0                    CLEAR REG                       83200022
         IC    R0,THREE(R11)            LENGTH OF DATA TO INSERT        83280022
         CLI   THREE(R11),AVTEFF        IS LENGTH LE 255                83360022
         BH    ERREXIT                  BRANCH IF YES                   83440022
         LTR   R0,R0                    IS LENGTH ZERO                  83520022
         BZ    ERREXIT                  BRANCH IF YES                   83600022
         TM    PRFSTAT1,PRFCNCLN        RECALLED BUFFER                 83680022
         BO    RECLLBUF                 BRANCH IF YES                   83760022
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   83840022
         BNO   ISHDR                    BRANCH IF YES                   83920022
         TM    SCBCTBSV,CTBINSRT        ANY INSERTS DONE                84000022
         BO    INSRT                    BRANCH IF NO                    84080022
         LH    R1,DATOFF(,RPREFIX)      SPACE AVAIL                     84160022
         B     AGAIN                    BRANCH                          84240022
         SPACE 1                                                        84320022
ISHDR    EQU   *                                                        84400022
         SR    R2,R2                    CLEAR REG                       84480022
         STC   R2,PRMOPTN               INDICATE ISZE NOT SAVES         84560022
         IC    R2,LCBISZE               GET RESERVES REMAINING          84640022
         LA    R2,AVTHDRSZ(R2,R7)       NEW SCAN PTR            SA56209 84720022
STSCAN   EQU   *                                                        84800022
         LH    R5,PRFSCAN               GET SCAN PTR                    84880022
         STH   R5,PARMLIST              SAVE SCAN PTR                   84960022
         STH   R2,PRFSCAN               SET SCAN PTR FOR INSERT         85040022
         LR    R11,R0                   SAVE INSERT DATA LENGTH         85120022
         LA    R2,THREE                 REQUEST EXPAND BUF FCN          85200022
         BAL   R14,LINKAF1              EXIT TO AF                      85280022
         LR    R0,R11                   RESTORE INSERT DATA LENGTH      85360022
         LH    R5,PARMLIST              ADDR OF PARM LIST               85440022
         STH   R5,PRFSCAN               RESTORE SCAN PTR                85520022
         LTR   R15,R15                  WAS EXPAND FCN PERFORMED        85600022
         BNZ   INSRT                    BRANCH IF NO                    85680022
         SR    R2,R2                    CLEAR WORK REG                  85760022
         IC    R2,PRMOPTN               GET SAVED ISZE                  85840022
         LTR   R2,R2                    WAS ISZE SAVED                  85920022
         BZ    NTSVE                    BRANCH IF NO                    86000022
         STC   R2,LCBISZE               RESTORE ISZE                    86080022
         SPACE 1                                                        86160022
NTSVE    EQU   *                                                        86240022
         LR    R7,R0                    SET INSERT DATA LENGTH          86320022
         SR    R0,R0                    INDICATE DATA TYPE = CHARS      86400022
         LA    R2,TWO                   REQUEST INSERT AND RETURN FCN   86480022
         BAL   R14,LINKAF               GO INSERT DATA                  86560022
         B     OUT                      RETURN                          86640022
ERREXIT  EQU   *                                                        86720022
         OI    RTNCDE,ECD20             SET RETURN CODE         SA56209 86760022
         TM    SCBCTBSV,CTBINSRT        ANY INSERTS DONE                86800022
         BO    OUT                      BRANCH IF NO                    86880022
         BAL   R4,CLOSEUP               GO SHIFT DATA                   86960022
OUT      EQU   *                                                        87120022
         NI    SCBCTBSV,AVTEFF-CTBINSRT INDICATE INSERTS DONE           87200022
         LM    R14,RBASE,SAVE           RESTORE REGS                    87280022
         BR    R14                      RETURN                          87360022
         SPACE 1                                                        87440022
         SPACE 1                                                        87520022
*    THIS ROUTINE HANDLES INSERTION IN RECALLED BUFFERS                 87600022
         SPACE 1                                                        87680022
RECLLBUF EQU   *                                                        87760022
         LR    R5,R7                    SAVE OFFSET                     87840022
         LH    R7,PRFSIZE               GET DATA SIZE            S22027 87850022
         CH    R7,SCBEOB                IS PRFSIZE LT EOB OFFSET S22027 87860022
         BH    SIZEOKNW                 BRANCH IF NO             S22027 87870022
         OI    RTNCDE,AVTECD20          INDICATE NO INSERTS      S22027 87880022
         B     OUT                      EXIT                     S22027 87890022
SIZEOKNW EQU   *                                                 S22027 87900022
         SR    R7,R7                    CLEAR WORK REG                  87920022
         LH    R7,SCBEOB                GET OFFSET TO DATA              88000022
         LA    R1,AVTTXTSZ              ASSUME TEXT BUFFER              88080022
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   88160022
         BO    NTHDR                    BRANCH IF NO                    88240022
         IC    R1,LCBISZE               GET NO RESERVES REMAINING       88320022
         LA    R1,AVTHDRSZ(R1)          ADD HDR PREFIX SIZE             88400022
NTHDR    EQU   *                                                        88480022
         SR    R7,R1                    CALC SPACE AVAIL IN BUFFER      88560022
         TM    SCBCTBSV,CTBINSRT        ANY INSERTS DONE                88640022
         BZ    INSRTX                   BRANCH IF YES                   88720022
         CR    R0,R7                    WILL DATA FIT IN AVAIL SPACE    88800022
         BH    INSRTX                   BRANCH IF NO                    88880022
         LH    R2,SCBEOB                GET DATA OFFSET                 88960022
         SR    R2,R0                    DECR SCBEOB BY AMT DATA         89040022
         STH   R2,SCBEOB                INSERTED AND SAVE               89120022
         TM    SCBCTBSV,CTBDVCID        ARE TO INSERT DVCID             89200022
         BZ    NOID                     BRANCH IF NO                    89280022
         NI    SCBCTBSV,AVTEFF-CTBDVCID RESET DVCID INSRT REQ BIT       89360022
         LA    R2,ONE(R7,R1)            SET INSERT DATA OFFSET          89440022
         LR    R7,R0                    SET INSERT DATA LENGTH          89520022
         B     INSRT1                   GO INSERT DATA                  89600022
         SPACE 1                                                        89680022
NOID     EQU   *                                                        89760022
         IC    R2,LCBISZE               GET RESERVES REMAINING          89840022
         STC   R2,PRMOPTN               SAVE ISZE                       89920022
         LA    R15,AVTEFF               SET MAX ISZE                    90000022
         CR    R7,R15                   IS SPACE IN BUF GT ISZE         90080022
         BH    STC                      BRANCH IF YES                   90160022
         LR    R15,R7                   SET FAKE ISZE                   90240022
STC      EQU   *                                                        90320022
         STC   R15,LCBISZE              SET ISZE FOR AF                 90400022
         AR    R7,R1                    RESTORE SCBEOB OFFSET           90480022
         AR    R7,R5                    TRUE INSERT OFFSET              90560022
         LR    R2,R7                    SET SCAN PTR                    90640022
         B     STSCAN                   GO SAVE SCAN                    90720022
         SPACE 1                                                        90800022
*    WHEN ENTERED R2 CONTAINS THE INDEX FLAG FOR AF                     90880022
LINKAF   EQU   *                                                        90960022
         ST    R8,AVTPARM3              SET INSERT DATA ADDR            91040022
         STC   R7,AVTPARM3              SET INSERT DATA LENGTH          91120022
LINKAF1  EQU   *                                                        91200022
         USING PRMLST,R5                                                91280022
         L     R5,PARMSAVE              GET POINTER TO PARMLIST         91360022
         SR    R15,R15                  CLEAR WORK REG                  91440022
         IC    R15,PRMAFOFF             GET AF INDEX                    91520022
         AR    R15,R2                   SET INDEX FLAGS                 91600022
         STC   R15,AVTPARM              SET AF INDEX IN PARMLIST        91680022
         STC   R0,AVTPARM+ONE           SET DATA TYPE                   91760022
         LA    RPARM,AVTPARM            POINT TO PARAMETER LIST         91840022
         L     R15,AVTUI                ADDR USER INTERFACE RTN         91920022
         BR    R15                      RETURN                          92000022
         DROP  R5                                                       92080022
         DROP  RQCBE                                                    92160022
         USING IEDQDISP,RDISP                                           92240022
         SPACE 1                                                        92320022
IEDQGH02 EQU   *                                                        92400022
*    THIS ROUTINE IS ENTERED FROM IEDQGD - BUFFER ASSOCIATION           92480022
         SPACE 1                                                        92560022
         DROP  RAVT                                                     92640022
         USING AVTSAVE2,R13                                             92720022
         L     R1,LCBSCBDA-1            GET LINE SCB ADDR               92800022
         LA    R2,ZERO(R2)              ZERO HI-ORDER BYTE              92840022
         CR    R9,R2                    CURRENT BUF = FIRST BUF         92880022
         BE    CHAIN                    YES GO SEE IF READY TO          92960022
*                                       HOOK IN IDLE LOOP               93040022
LOOKATIT EQU   *                                                        93120022
         TM    PRFTIC+THREE-IEDQPRF(R2),LAST                            93200022
*                                       LAST UNIT                       93280022
         BO    FOUNDIT                  BR YES                          93360022
         L     R2,PRFTIC-IEDQPRF(R2)    NEXT UNIT                       93440022
         B     LOOKATIT                 GO LOOK AT IT                   93520022
FOUNDIT  EQU   *                                                        93600022
         ST    R9,AVTPARM               SET IN WORK AREA                93680022
         MVC   PRFTIC+ONE-IEDQPRF(THREE,R2),AVTPARM+ONE                 93760022
*                                       SET TIC ADDR                    93840022
CHAIN    EQU   *                                                        93920022
         TM    SCBSTAT1-IEDQSCB(R1),SCBNIDLE                            94000022
*                                       ARE TO LINK BUFFERS INTO        94080022
*                                       CHAIN                           94160022
         BO    RESET1                   NO NOT YET                      94240022
         LA    R5,LCBCPA                ADDR OF CPA                     94320022
         ST    R5,AVTPARM               SET IN AVTPARM                  94400022
         CLC   AVTPARM+ONE(THREE),LCBCPA+NINE                           94480022
*                                       HAVE BUFFERS ALREADY            94560022
*                                       BEEN HOOKED IN LCB              94640022
         BNE   RESET1                   YES                             94720022
         L     R9,LCBLSPCI-1            ADDR OF FIRST BUFFER            94800022
SETR2    EQU   *                                                        94880022
         MVI   LCBCPA+TWELVE,AVTEZERO   CLEAR FLAG                      94960022
         LA    R2,LCBCPA                ADDR OF CPA                     95040022
         B     FOUNDIT                  BRANCH                          95120022
RESET1   EQU   *                                                        95200022
         LH    R5,SEOBSV                GET NEW SCBEOB OFFSET           95280022
         AH    R5,SCBCTBAC              UPDATE BY AMT DATA INSERTED     95360022
         STH   R5,SCBEOB                UPDATE SCBEOB                   95440022
         XC    SCBCTBAC,SCBCTBAC        CLEAR COUNT                     95520022
         XC    SEOBSV,SEOBSV            CLEAR                           95600022
         NI    SCBSTAT1-IEDQSCB(R1),AVTEFF-SCBCBGN                      95680022
*                                       RESET CONC MSG BEGIN            95760022
         NI    SCBCTBFL,AVTEFF-SCBCTBND RESET CTB END                   95840022
         NI    SCBQTYPE-IEDQSCB(R1),SCBCONC                             95920022
*                                       RESET TEMP FLAG IN LINE SCB     96000022
         L     RDISP,AVTEA              GET DISPATCHER ADDR             96080022
         B     DSPDISP                  EXIT                            96160022
PARMSAVE DC    F'0'                     ADDR OF PARMLIST                96240022
PARMLIST DS    0F                       PARAMETER LIST                  96320022
PRMOFFST DC    X'00'                    MODULE OFFSET                   96400022
PRMLNGTH DC    X'00'                    LENGTH OF PARMLIST              96480022
PRMOPTN  DC    X'00'                    OFFSET TO OPTION FIELD          96560022
PRMREGOF DC    X'00'                    REG OFFSET                      96640022
R14SAVE  DC    F'0'                     SAVE FOR R14                    96720022
SAVE     DC    15F'0'                   SAVE AREA                       96800022
HTWELVE  DC    H'12'                    CONSTANT                        96880022
HEIGHT   DC    H'8'                     CONSTANT                        96960022
MSGCNT1  DC    H'1'                     NO OF MSGS                      97040022
SEOBSV   DC    H'0'                     SCBEOB SAVE                     97120022
RTNCDE   DC    X'00'                    RETURN CODE                     97200022
         DC    X'FAFBFCFDFE'            BEGINING OF X-LATE TBL          97280022
         DC    X'FF'                    MORE TRANSLATE TABLE            97360022
TABLE    EQU   *                                                        97440022
         DC    X'000102030405060708090A0B0C0D0E0F' TABLE                97520022
MVCRS    MVC   PRFSTXT-IEDQPRF(ZERO,RPREFIX),ONE(R1)                    97600022
*    DSECTS                                                             97680022
         SPACE 2                                                        97760022
         TPRIOR                                                         97840022
         TAVTD                                                          97920022
         TTRMD                                                          98000022
         TQCBD                                                          98080022
         TPRFD                                                          98160022
         TLCBD                                                          98240022
         TSCBD                                                          98320022
         TDISPD                                                         98400022
         TQCBED                                                         98480022
         TDRQD                                                          98560022
         DCBD  DSORG=TX                                                 98640022
PRMLST   DSECT                                                          98720022
PRMGHOFF DS    XL1                      OFFSET TO IEDQGH                98800022
PRMGHLN  DS    XL1                      LENGTH OF PARAMETER LIST        98880022
PRMCTBOP DS    XL1                      CTBFORM OPTIONS                 98960022
PRMAVAIL DS    XL1                      RESERVED                        99040022
PRMAFOFF DS    XL1                      OFFSET TO IEDQAF                99120022
PRMAOOFF DS    XL1                      OFFSET TO IEDQAO                99200022
PRMAEOFF DS    XL1                      OFFSET TO IEDQAE                99280022
PRMOPFLD DS    XL1                      OPTION FIELD OFFSET             99360022
         END                                                            99440022
