GP       TITLE 'IEDQGP - MHGET/MHPUT MODULE'                            00200022
IEDQGP   CSECT                                                          00400022
         SPACE 3                                                        00450005
*  CHANGE ACTIVITY AS FOLLOWS                                           00500005
******************** MICROFICHE FLAGS *********************** SUPT CODE 00550005
*C656000-658000                                                 SA62380 00600005
*C587000                                                        SA64709 00600152
*C274600,716500                                                 SA65442 00600252
*A652000                                                        OX05322 00600356
         SPACE 3                                                        00800005
*********************************************************************** 01000005
*                                                                     * 01010005
*  TITLE:  'IEDQGP' - MHGET/MHPUT MODULE                              * 01020005
*                                                                     * 01030005
*  MODULE NAME = IEDQGP                                               * 01040005
*                                                                     * 01050005
*  DESCRIPTIVE NAME = MHGET/MHPUT ROUTINE                             * 01060005
*                                                                     * 01070005
*  COPYRIGHT = 'NONE'                                                 * 01080005
*                                                                     * 01090005
*  STATUS CHANGE LEVEL 5                                              * 01100052
*                                                                     * 01110005
*                                                                     * 01200022
* FUNCTION -- THIS MODULE IS USED BY MHGET AND MHPUT.  WHEN ENTERED   * 01400022
*    FROM MHGET, IT MOVES DATA FROM THE CURRENT BUFFER TO A USER      * 01600022
*    SPECIFIED WORK AREA OR PUTS THE STARTING ADDRESS OF THE DATA     * 01800022
*    WITHIN THE BUFFER INTO A USER SPECIFIED REGISTER.  WHEN ENTERED  * 02000022
*    FROM MHPUT, IT MOVES DATA FROM A USER SPECIFIED WORK AREA INTO   * 02200022
*    THE CURRENT BUFFER.                                              * 02400022
*                                                                     * 02600022
* ENTRY POINTS --                                                     * 02800022
*         FIRST EXECUTABLE INSTRUCTION                                * 03000022
*                                                                     * 03200022
* INPUT --                                                            * 03400022
*    R1 ADDRESS OF USER PARAMETER LIST BUILT BY MHGET OR MHPUT        * 03600022
*    R14 RETURN ADDRESS                                               * 03800022
*                                                                     * 04000022
* OUTPUT --                                                           * 04200022
*    R15 RETURN CODE                                                  * 04400022
*                                                                     * 04600022
* EXTERNAL REFERENCES --                                              * 04800022
*         NONE                                                        * 05000022
*                                                                     * 05200022
* EXITS,NORMAL --                                                     * 05400022
*         BR 14 RETURN TO CALLER                                      * 05600022
*                                                                     * 05800022
* EXITS,ERROR --                                                      * 06000022
*         NONE                                                        * 06200022
*                                                                     * 06400022
* TABLES/WORK AREAS --                                                * 06600022
*    PRF                                                              * 06800022
*    LCB                                                              * 07000022
*    DCB                                                              * 07200022
*    AVT                                                              * 07400022
*    USER SUPPLIED DATA WORK AREA                                     * 07600022
*                                                                     * 07800022
* ATTRIBUTES --                                                       * 08000022
*    SERIALLY REUSABLE, REFRESHABLE, ENABLED, RESIDENT, PROBLEM       * 08200022
*    PROGRAM MODE                                                     * 08400022
*                                                                     * 08600022
* CHARACTER CODE DEPENDENCY --                                        * 08800022
*    THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR   * 09000022
*    INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.           * 09200022
*                                                                     * 09400022
* NOTES --                                                            * 09600022
*    STANDARD TCAM DEVIATIONS FROM STANDARDS                          * 09800022
*                                                                     * 10000022
*********************************************************************** 10200022
         EJECT                                                          10400022
         USING IEDQGP,R15BASE                                           10600022
         USING IHADCB,R2                                                10800022
         USING IEDQLCB,R4LCB                                            11000022
         USING IEDQPRF,R6BUFF                                           11200022
         USING IEDQAVTD,R9AVT                                           11400022
         SPACE 1                                                        11600022
*********************************************************************** 11800022
***        REGISTER EQUATES                                         *** 12000022
*********************************************************************** 12200022
R0       EQU   0                        WORK REGISTER                   12400022
R1PARM   EQU   1                        MHGET/MHPUT PARAMETER           12600022
R2       EQU   2                        WORK REGISTER                   12800022
R3WKSIZ  EQU   3                        SIZE OF THE WORK AREA           13000022
R3       EQU   3                        WORK REGISTER                   13200022
R4LCB    EQU   4                        LCB ADDRESS                     13400022
R5       EQU   5                        WORK REGISTER                   13600022
R6BUFF   EQU   6                        BUFFER ADDRESS                  13800022
R7       EQU   7                        WORK REGISTER                   14000022
R8DASIZ  EQU   8                        DATA SIZE                       14200022
R9AVT    EQU   9                        AVT ADDRESS                     14400022
R10DATA  EQU   10                       DATA ADDRESS                    14600022
R11      EQU   11                       WORK REGISTER                   14800022
R12      EQU   12                       WORK REGISTER                   15000022
R13SAVE  EQU   13                       SAVE AREA ADDRESS               15200022
R14RETRN EQU   14                       RETURN ADDRESS                  15400022
R14      EQU   14                       WORK REGISTER                   15600022
R15BASE  EQU   15                       BASE REGISTER                   15800022
         EJECT                                                          16000022
*********************************************************************** 16200022
***            MAIN  ROUTINE                                        *** 16400022
*********************************************************************** 16600022
         SPACE 2                                                        16800022
IEDQGP   IEDHJN BEGIN,HJN                                               17000022
         STM   R14RETRN,R12,SAVAREA+OFFSET                              17100022
*                                       SAVE REGS 14 - 12               17200022
         ST    R13SAVE,SAVAREA+WORDLEN  SAVE REG 13                     17300022
         LA    R13SAVE,SAVAREA          LOAD SAVE AREA ADR              17600022
         XC    SAVAREA+FOFFSET(WORDLEN),SAVAREA+FOFFSET                 17700022
*                                       INIT R15 W/GOOD RET CODE        17800022
         L     R9AVT,CVTOFF             GET ADDRESS OF CVT              18000022
         L     R9AVT,AVTCVTPT(,R9AVT)   FIND POINTER TO AVT             18200022
         LTR   R9AVT,R9AVT              AVT POINTER ZERO                18230022
         BNZ   GETAVT                   BRANCH IF NOT ZERO              18260022
         MVI   RETCODOF(R13SAVE),NTCAM  NO TCAM - SET RET CODE          18290022
         B     RESTREG                  RETURN TO USER                  18320022
GETAVT   EQU   *                                                        18350022
         L     R9AVT,AVTEZERO(,R9AVT)   GET ADDRESS OF AVT              18400022
         L     R6BUFF,AVTADBUF          INITIALIZE BUFFER ADR           18600022
         L     R4LCB,PRFLCB-ADDROFF     INITIALIZE LCB ADDR             18800022
         L     R2,LCBDCBPT              POINTER TO DCB                  19000022
         SR    R5,R5                    CLEAR REG 5                     19200022
         IC    R5,LCBISZE               GET NO OF RESERVES              19400022
         STH   R5,RESRVS                SAVE IT                         19600022
         LA    R14,AVTHDRSZ             HDR BUFR PREFIX SIZE            19800022
         TM    PRFSTAT1,PRFNHDRN        HDR BUFR                        20000022
         BZ    CONTINU1                 BRANCH IF YES                   20200022
         SPACE 1                                                        20400022
         LA    R14,AVTTXTSZ             TEXT BUFR PREFIX SIZE           20600022
         SPACE 1                                                        20800022
CONTINU1 EQU   *                                                        21000022
         LH    R11,PRFSIZE              LOAD BUFFER LENGTH              21200022
         LTR   R11,R11                  IS IT ZERO                      21400022
         BNZ   CONTINU2                 BRANCH IF NO                    21600022
         SPACE 1                                                        21800022
         TM    PARMID(R1PARM),PUTID     IS THIS AN MHPUT                21900022
         BO    RESTREG                  BRANCH IF YES                   22000022
         MVI   RETCODOF(R13SAVE),SYSBUF SET RETURN CODE                 22100022
         B     RESTREG                  GO TO EXIT                      22200022
         SPACE 1                                                        22400022
CONTINU2 EQU   *                                                        22600022
         N     R11,AVTCLRHI             CLEAR SIGN BITS                 22800022
         TM    PARMID(R1PARM),PUTID     IS THIS A MHPUT                 23000022
         BO    MHPUT                    YES, GO TO MHPUT RTNE           23200022
         B     MHGET                    NO, A MHGET                     23400022
         SPACE 1                                                        23600022
RESTREG  EQU   *                                                        23800022
         L     R13SAVE,SAVAREA+WORDLEN  RESTORE USER REG 13             23900022
         LM    R14RETRN,R12,SAVAREA+OFFSET                              24000022
*                                       RESTORE USER REGS               24100022
         BR    R14RETRN                 RETURN TO CALLER                24400022
         EJECT                                                          24600022
*********************************************************************** 24800022
***            MHGET  SUBROUTINE                                    *** 25000022
*********************************************************************** 25200022
         SPACE 2                                                        25400022
MHGET    EQU   *                        MHGET ROUTINE                   25600022
         LA    R11,FIRSTIME             FIRST TIME BRANCH               25800022
         TM    AVTEZERO(R1PARM),GETRES  RESERVES WANTED                 25830022
         BO    CKFOREG                  BRANCH IF YES                   25860022
         AH    R14,RESRVS               ADD RESERVES TO PREFIX          25890022
         SPACE 1                                                        25920022
CKFOREG  EQU   *                                                        25950022
         CLI   PARM4(R1PARM),NULL       ANSWER REG SPECIFIED            26000022
         BE    MOVEIT                   BRANCH IF NO                    26200022
         SPACE 1                                                        26400022
         SR    R5,R5                    CLEAR REG 5                     26600022
         IC    R5,PARM4(,R1PARM)        LOAD ANSWER REG NO IN R5        26800022
         SLL   R5,TWO                   QUADRUPLE REG NO                27000022
         LA    R10DATA,AVTECD12(R14,R6BUFF)  GET DATA ADR               27200022
         ST    R10DATA,OFSETR0(R5,R13SAVE)                              27270022
*                                       MOVE DATA ADR TO USR REG        27340022
         SR    R7,R7                    CLEAR REG 7                     27420022
         IC    R7,PRFSTAT1              MOVE IN PRFSTAT                 27440022
         SLL   R7,SHIFT16               SHIFT LEFT 2 BYTES      SA65442 27460052
         LH    R12,PRFSIZE              GET DATA SIZE                   27480022
         SR    R12,R14                  SUBTR BUFFER PREFIX             27500022
         OR    R7,R12                   PUT IT IN REG 7                 27520022
         ST    R7,OFSETR1(R5,R13SAVE)   STORE IN USER REG               27560022
         B     RESTREG                  DEPART                          27600022
         SPACE 1                                                        27800022
MOVEIT   EQU   *                                                        28000022
         L     R10DATA,PARMAWK(,R1PARM)  LOAD WK AREA ADR IN R10        28200022
         TM    PARMLEN(R1PARM),LEN8     IS IT AN ADR                    28400022
         BO    CKSIZE                   BRANCH IF YES                   28600022
         SPACE 1                                                        28800022
         SR    R5,R5                    CLEAR REG 5                     29000022
         IC    R5,PARMWRK(,R1PARM)      PUT WORKREG NO IN REG 5         29200022
         SLL   R5,TWO                   QUADRUPLE REG NO                29400022
         L     R10DATA,OFSETR0(R5,R13SAVE)                              29500022
*                                       LOAD WORK AREA ADDR             29600022
         SPACE 1                                                        29800022
         SPACE 1                                                        30000022
CKSIZE   EQU   *                                                        30200022
         LH    R3WKSIZ,AVTEZERO(,R10DATA)                               30300022
*                                       PUT WK AREA SIZE IN REG3        30400022
         LH    R5,DATLEN(,R10DATA)      LOAD LENGTH ALREADY MOVD        30500022
         SR    R3WKSIZ,R5               SUBT LENGTH ALREADY USED        30800022
         LH    R8DASIZ,PRFSIZE          PUT DATA SIZE IN REG 8          31000022
         SR    R8DASIZ,R14              SUBTR BUFR PRFX SIZE            32400022
         CR    R3WKSIZ,R8DASIZ          WORK AREA TOO SMALL             32600022
         BNL   CONTINU3                 NO, CONTINUE                    32800022
         SPACE 1                                                        33000022
         MVI   RETCODOF(R13SAVE),TRUNC  YES, SET RETURN CODE            33200022
         LR    R8DASIZ,R3WKSIZ          PUT WORK SIZE IN REG 8          33400022
         SPACE 1                                                        33600022
CONTINU3 EQU   *                                                        33800022
         LA    R7,WRKPRFX(R5,R10DATA)   ADDR OF NEXT WRKAR SPACE        34000022
         LH    R5,AVTKEYLE              PUT UNIT LENGTH IN REG 5        34200022
         SR    R5,R14                   SUBTRACT PREFIX FROM LTH        34400022
         LA    R6BUFF,AVTEZERO(R14,R6BUFF)                              34500022
*                                       ADD BUFR PREFIX TO ADDR         34600022
         SPACE 1                                                        34800022
LOOP     EQU   *                                                        35000022
         CR    R5,R8DASIZ               UNIT LNTH GT DATA SIZE          35200022
         BNH   MOVDATA                  NO, PROCEED                     35400022
         SPACE 1                                                        35600022
         LR    R5,R8DASIZ               YES, MAKE UNIT EQ DATA          35800022
         EJECT                                                          36000022
MOVDATA  EQU   *                                                        36200022
         SPACE 1                                                        36400022
*********************************************************************** 36600022
***  AT THIS POINT, REGISTERS ARE SET UP AS FOLLOWS:                *** 36800022
***      REG 5 - LENGTH OF DATA TO BE MOVED FROM THE BUFR UNIT      *** 37000022
***      REG 6 - ADR OF DATA IN BUFR MINUS UNIT PREFIX              *** 37200022
***      REG 7 - ADR DATA IS TO BE MOVED TO IN USER WORKAREA        *** 37400022
***      REG 8 - LENGTH OF REMAINING DATA TO BE MOVED BY MHGET      *** 37600022
*********************************************************************** 37800022
         SPACE 1                                                        38000022
         LTR   R5,R5                    IS WORKAREA FULL                38200022
         BZ    ALLDONE                  BRANCH IF YES                   38400022
         BCTR  R5,AVTEZERO              SUBTRACT 1 FROM REG 5           38600022
         EX    R5,EXECUTE2              PUT DATA LNTH IN EXEC2          38800022
         LA    R5,ADDROFF(,R5)          ADD 1 TO REG 5                  39000022
         CR    R5,R8DASIZ               DATA SIZE GT UNIT SIZE          39200022
         BNL   ALLDONE                  BRANCH IF NO                    39400022
         SPACE 1                                                        39600022
         SR    R8DASIZ,R5               YES, SUBT DATA JUST MOVD        39800022
         AR    R7,R5                    BUMP ADR POINTER                40000022
         BR    R11                      R11 INIT TO FIRSTIME            40200022
         SPACE 1                                                        40400022
FIRSTIME EQU   *                                                        40600022
         LA    R11,SUBSEQ               CHANGE FIRST TIME BRANCH        40800022
         LH    R5,AVTKEYLE              RESTORE UNIT LNTH IN R5         41000022
         L     R6BUFF,AVTADBUF          RESTORE BUFR UNIT ADR           41200022
         SPACE 1                                                        41400022
SUBSEQ   EQU   *                                                        41600022
         L     R6BUFF,PRFTIC            LOAD ADR OF NEXT UNIT           41800022
         SPACE 1                                                        42000022
         B     LOOP                     CHECK DATA LENGTH               42200022
         SPACE 1                                                        42400022
ALLDONE  EQU   *                                                        42600022
         AR    R7,R5                    POINT R7 TO END OF DATA         42800022
         SR    R7,R10DATA               GET DATA LNTH PLUS PRFX         43000022
         SH    R7,WKPRFX                SUBT WORK AREA PREFIX           43200022
         STH   R7,PARMWRK(,R10DATA)     PUT DATA LNTH IN WKAREA         43400022
         L     R6BUFF,AVTADBUF          RESTORE BUFR ADR                43600022
         MVC   WRKSTAT(LEN1,R10DATA),PRFSTAT1                           43700022
*                                       PUT STAT IN WORK AREA           43800022
         MVC   WRKUNRS(LEN1,R10DATA),LCBISZE                            43900022
*                                       NO OF UNUSED RESERVES           44000022
         B     RESTREG                  DEPART                          44200022
         EJECT                                                          44400022
*********************************************************************** 44600022
***            MHPUT  SUBROUTINE                                    *** 44800022
*********************************************************************** 45000022
         SPACE 2                                                        45200022
MHPUT    EQU   *                                                        45400022
         MVI   UCNT,CNTINIT             INITIALIZE UNIT CNTR            45500022
         SR    R11,R11                  CLEAR REG 11                    45600022
         IC    R11,LCBISZE              GET DCB RESERVES                45800022
         TM    PRFSTAT1,PRFNHDRN        HEADER BUFFER                   46000022
         BO    ADDRES                   NO, USE DCB RESERVES            46200022
         SPACE 1                                                        46400022
         TM    PARM4(R1PARM),AVTEFF     RESERVES SPECIFIED              46600022
         BO    ADDRES                   NO, USE DCB RESERVES            46800022
         SPACE 1                                                        47000022
         IC    R11,PARM4(,R1PARM)       LOAD USER RESERVES IN 11        47200022
         LH    R7,AVTKEYLE              LOAD UNIT SIZE IN REG 7         47400022
         SR    R7,R14                   SUBT BUFR PRFX FROM R7          47600022
         SH    R7,MINLNTH               SUBT MINIMUM DATA LNTH          47800022
         CR    R11,R7                   RESERVES GT ALLOWBL SIZE        48000022
         BNH   STORES                   NO, USE THEM                    48200022
         SPACE 1                                                        48400022
         MVI   RETCODOF(R13SAVE),MAXRES SET RETURN CODE                 48600022
         LR    R11,R7                   USE MAX ALLOWABLE               48800022
         SPACE 1                                                        49000022
STORES   EQU   *                                                        49200022
         STC   R11,LCBISZE              UPDATE LCBISZE                  49400022
         SPACE 1                                                        49600022
ADDRES   EQU   *                                                        49800022
         AR    R14,R11                  ADD RESERVES TO PREFIX          50000022
         STH   R14,PRFSIZE              INITIALIZE PRFSIZE              50200022
         STH   R14,PRFSCAN              SET SCAN PTR                    50400022
         L     R10DATA,PARMAWK(,R1PARM)  LOAD WK AREA ADR               51400022
         TM    PARMLEN(R1PARM),LEN8     IS IT AN ADR                    51600022
         BO    CKWRK                    YES, CHECK SIZE                 51800022
         SPACE 1                                                        52000022
         SR    R5,R5                    CLEAR REG 5                     52200022
         IC    R5,PARMWRK(,R1PARM)      PUT WK REG NO IN REG 5          52400022
         SLL   R5,TWO                   QUADRUPLE REG NO                52600022
         L     R10DATA,OFSETR0(R5,R13SAVE)                              52700022
*                                       LOAD WORK AREA ADDR             52800022
         SPACE 1                                                        53000022
CKWRK    EQU   *                                                        53200022
         LH    R8DASIZ,DATLEN(,R10DATA) PUT DATA SIZE IN REG 8          53400022
         LTR   R8DASIZ,R8DASIZ          WAS LENGTH INITIALIZED          53500022
         BNZ   LNGTHOK                  BRANCH IF YES                   53600022
         MVI   RETCODOF(R13SAVE),ZROLEN SET RETURN CODE                 53700022
         B     RESTREG                  DEPART                          53800022
LNGTHOK  EQU   *                                                        53900022
         AH    R10DATA,WKPRFX           MOVE POINTER PAST PREFIX        54000022
         L     R12,PRFTIC               SAVE TIC FIELD                  54200022
         LH    R11,AVTKEYLE             LOAD UNIT SIZE IN REG 11        54400022
         SR    R11,R14                  SUBT PRFX AND RESERVES          54600022
         LR    R3,R6BUFF                POINT R3 AT BEG OF UNIT         54800022
         LA    R14,AVTEZERO(R14,R6BUFF) POINT R14 AT DATA AREA          55000022
         SPACE 1                                                        55200022
LOOP1    EQU   *                                                        55400022
         CR    R8DASIZ,R11              IS DATA LESS THAN UNIT          55600022
         BNL   CONTINU4                 NO,CONTINUE                     55800022
         SPACE 1                                                        56000022
         LR    R11,R8DASIZ              YES, SET MOVE LNTH              56200022
         SPACE 1                                                        56400022
CONTINU4 EQU   *                                                        56600022
         BCTR  R11,AVTEZERO             SUBTRACT 1 FROM REG 11          56800022
         EX    R11,EXECUTE3             LOAD LENGTH IN EXECUTE3         57000022
         LA    R11,ADDROFF(,R11)        ADD 1 TO REG 11                 57200022
         LH    R5,PRFSIZE               LOAD DATA SIZE                  57400022
         AR    R5,R11                   ADD LAST CHUNK TO IT            57600022
         STH   R5,PRFSIZE               STORE IT BACK                   57800022
         SR    R8DASIZ,R11              GET REMAINING DATA LNTH         58000022
         BZ    RESTREG                  ALL DATA MOVED, DEPART          58200022
         CLC   PRFNBUNT,MAXUNIT         IS UNIT COUNT GE 255            58230022
         BL    CKUNITS                  BRANCH IF NO                    58260022
         MVI   RETCODOF(R13SAVE),NUNITS SET MAX UNIT EXCEEDED           58290022
         B     RESTREG                  EXIT                            58320022
CKUNITS  EQU   *                                                        58350022
         SPACE 1                                                        58400022
         CLC   UCNT,PRFNBUNT            ORIG UNITS USED UP              58600022
         BNL   GETUNIT                  YES, GO GET ONE         SA64709 58700052
         SR    R7,R7                    CLEAR REG 7                     58800022
         IC    R7,UCNT                  LOAD UNIT COUNT IN R7           59000022
         LA    R7,ADDROFF(,R7)          BUMP IT ONE                     59200022
         STC   R7,UCNT                  STORE IT                        59400022
         LR    R3,R12                   NO, POINT R3 TO NXT UNIT        60000022
         LR    R14,R12                  POINTER TO DATA POSITION        60200022
         L     R12,PRFTIC1(,R3)         SAVE TIC FIELD                  60400022
         SPACE 1                                                        60600022
CONTINU5 EQU   *                                                        60800022
         AR    R10DATA,R11              POINT R10 TO DATA               61000022
         LH    R11,AVTKEYLE             LOAD UNIT SIZE IN REG 11        61200022
         B     LOOP1                    CHECK DATA SIZE                 61400022
         SPACE 1                                                        61600022
GETUNIT  EQU   *                                                        61800022
         L     R7,AVTBFREB              ADR OF FIRST FREE UNIT          62000022
         LA    R7,AVTEZERO(,R7)         CLEAR FIRST BYTE                62200022
         LTR   R7,R7                    ANY UNITS THERE                 62400022
         BNZ   GOT1                     YES, DELINK ONE                 62600022
         SPACE 1                                                        62800022
         MVI   RETCODOF(R13SAVE),NUNITS NO UNITS - SET RET CODE         63000022
         B     RESTREG                  DEPART                          63200022
         SPACE 1                                                        63400022
GOT1     EQU   *                                                        63600022
         MVC   AVTBFREB+1(THREE),FIVE(R7)  DELINK UNIT                  63800022
         XC    FIVE(SEVEN,R7),FIVE(R7)  CLEAR ADDRESSES IN UNIT         64000022
         LH    R0,AVTAVFCT              LOAD UNIT CTR                   64200022
         BCTR  R0,AVTEZERO              SUBTRACT 1                      64400022
         STH   R0,AVTAVFCT              STORE IT BACK                   64600022
         SR    R5,R5                    CLEAR REG 5                     64700022
         IC    R5,PRFNBUNT              LOAD NO OF UNITS                64800022
         LA    R5,ADDROFF(,R5)          ADD 1                           65000022
         STC   R5,PRFNBUNT              STORE IT BACK                   65200022
         STC   R5,UCNT                  UPDATE UNIT COUNTER     OX05322 65250056
         MVC   PRFTIC1(WORDLEN,R7),PRFTIC1(R3)                          65300022
*                                       POINT NEW UNIT TO NEXT 1        65400022
         IC    R0,PRFTIC1(,R3)          CHAIN NEW UNIT          SA62380 65600005
         ST    R7,PRFTIC1(,R3)          TO THE PREVIOUS UNIT    SA62380 65700005
         STC   R0,PRFTIC1(,R3)          SAVING FLAGS IN TIC     SA62380 65800005
         LR    R3,R7                    POINT DSECT TO NEW UNIT         66000022
         LR    R14,R7                   POINTER TO DATA POSITION        66200022
         B     CONTINU5                 BACK TO MOVE DATA RTNE          66400022
         EJECT                                                          66600022
*********************************************************************** 66800022
***        RETURN  CODES                                            *** 67000022
*********************************************************************** 67200022
TRUNC    EQU   X'04'                    USER WORKAREA TOO SMALL         67500022
NUNITS   EQU   X'04'                    NOT ENOUGH UNITS AVAILBL        67600022
NTCAM    EQU   X'08'                    TCAM NOT IN SYSTEM              67700022
MAXRES   EQU   X'0C'                    USER RESERVES TOO LARGE         68000022
SYSBUF   EQU   X'0C'                    EMPTY BUFFER - NO               68060022
*                                       USER PROCESSING PERMITTED       68120022
ZROLEN   EQU   X'10'                    LENGTH FIELD IS ZERO            68160022
         SPACE 2                                                        68200022
*********************************************************************** 68400022
***        MISCELLANEOUS  EQUATES                                   *** 68600022
*********************************************************************** 68800022
PARMID   EQU   0                        PARM - ID                       69000022
PARMLEN  EQU   1                        PARM - LENGTH                   69200022
PARMWRK  EQU   2                        PARM - WORK AREA ADR REG        69400022
PARM4    EQU   3                        PARM - MHGET-ANSWER REG         69600022
*                                              MHPUT-NO OF USER         69800022
*                                              RESERVES                 70000022
PARMAWK  EQU   4                        PARM - ADR OF WORK AREA         70200022
GETRES   EQU   X'02'                    GET RESERVES, TOO               70400022
PUTID    EQU   X'01'                    MHPUT ID                        70600022
NULL     EQU   X'00'                    EMPTY BYTE                      70800022
TIC      EQU   X'08'                    FIRST BYTE OF LAST TIC          71000022
LEN8     EQU   X'08'                    MASK FOR LENGTH TEST            71200022
ADDROFF  EQU   1                        OFFSET OF 1                     71210022
LEN1     EQU   1                        LENGTH OF 1                     71220022
DATLEN   EQU   2                        OFFSET TO DATA LNTH MOVD        71230022
WORDLEN  EQU   4                        LENGTH OF 1 WORD                71240022
WRKPRFX  EQU   6                        PREFIX ON USER WRK AREA         71250022
OFFSET   EQU   12                       OFFSET TO REGS IN SAVARE        71260022
FOFFSET  EQU   16                       REG 15 OFFSET IN SAVAREA        71270022
RETCODOF EQU   19                       RETURN CODE OFFSET              71280022
OFSETR0  EQU   20                       OFFSET TO REG 0 IN SAVAR        71290022
OFSETR1  EQU   24                       OFFSET TO REG 1 IN SAVAR        71300022
CVTOFF   EQU   16                       ADR OF CVT                      71400022
PRFTIC1  EQU   8                        OFFSET OF PRFTIC                71600022
SHIFT16  EQU   16                       16 BIT SHIFT AMOUNT     SA65442 71650052
CNTINIT  EQU   1                        UNIT COUNTER INIT               71700022
TWO      EQU   2                        EQUATED 2                       71800022
THREE    EQU   3                        MOVE LENGTH FOR BUFR            72000022
FIVE     EQU   5                        OFFSET FOR DELINK BUFR          72200022
SEVEN    EQU   7                        EQUATED 7                       72600022
WRKSTAT  EQU   4                        PRFSTAT OFFSET IN WKAR          73400022
WRKUNRS  EQU   5                        UNUSED RESERVES OFFSET          73600022
         EJECT                                                          73800022
*********************************************************************** 74000022
***        EXECUTE  INSTRUCTIONS                                    *** 74200022
*********************************************************************** 74400022
EXECUTE2 MVC   AVTEZERO(AVTEZERO,R7),AVTUMALN(R6BUFF)                   74500022
*                                       MOVE DATA TO WORK AREA          74600022
EXECUTE3 MVC   AVTUMALN(AVTEZERO,R14),AVTEZERO(R10DATA)                 74700022
*                                       MOVE DATA TO BUFFER             74800022
*********************************************************************** 75000022
***        CONSTANTS                                                *** 75200022
*********************************************************************** 75400022
MINLNTH  DC    H'4'                     MIN DATA LNTH IN UNIT           75600022
WKPRFX   DC    H'6'                     WORK AREA PREFIX LNTH           75900022
SAVAREA  DS    18F                      SAVE AREA                       76200022
RESRVS   DS    AL2                      NO OF RESERVES                  76400022
UCNT     DC    AL1(1)                   UNIT COUNT                      76600022
MAXUNIT  DC    AL1(255)                 MAX NO OF UNITS                 76700022
         SPACE 2                                                        76800022
*********************************************************************** 77000022
         EJECT                                                          77200022
*********************************************************************** 77400022
***        DSECTS                                                   *** 77600022
*********************************************************************** 77800022
         SPACE 2                                                        78000022
*********************************************************************** 78200022
***            TPRFD  DSECT                                         *** 78400022
*********************************************************************** 78600022
         SPACE 2                                                        78800022
         TPRFD                                                          79000022
         EJECT                                                          79200022
*********************************************************************** 79400022
***            TLCBD  DSECT                                         *** 79600022
*********************************************************************** 79800022
         SPACE 2                                                        80000022
         TLCBD                                                          80200022
         EJECT                                                          80400022
*********************************************************************** 80600022
***            DCBD  DSECT                                          *** 80800022
*********************************************************************** 81000022
         SPACE 2                                                        81200022
         DCBD  DSORG=TX                                                 81400022
         EJECT                                                          81600022
*********************************************************************** 81800022
***            TAVTD  DSECT                                         *** 82000022
*********************************************************************** 82200022
         SPACE 2                                                        82400022
         TAVTD                                                          82600022
         END                                                            82800022
