         TITLE 'IEDQGQ - QUEUE RESET EXECUTOR'                          00200022
IEDQGQ   CSECT                                                          00400022
*CHANGE ACTIVITY AS FOLLOWS:                                            00400122
*D338000-339000                                                 SA51078 00400222
*A338000-339200                                                 SA51078 00400322
*A028200-029200,125000,159000,183000                            SA51783 00400422
*D449000-456000                                                 SA51783 00400522
*A449000-453000,457300-457600                                   SA51783 00400622
*C587000                                                        SA51783 00400722
*A587020-587780,642200-642800                                   SA51783 00400822
*********************************************************************** 00600022
* MODULE NAME -- IEDQGQ                                               * 00620022
*                                                                     * 00640022
* DESCRIPTIVE NAME -- QUEUE RESET EXECUTOR                            * 00660022
*                                                                     * 00680022
* COPYRIGHT -- NONE                                                   * 00700022
*                                                                     * 00720022
* STATUS --                                                           * 00800022
*    CHANGE LEVEL 0                                                   * 01000022
*                                                                     * 01200022
* FUNCTION --                                                         * 01400022
*    RECALLS 'SERVICED' HEADER RECORDS FROM THE DISK MESSAGE QUEUE    * 01600022
*    LOOKING FOR THE USER SPECIFIED OUTPUT SEQUENCE NUMBER AND        * 01800022
*    SCHEDULES IEDQFA TO MARK 'UNSERVICED' THOSE MESSAGES FOUND WITH  * 02000022
*    SEQUENCE NUMBERS HIGHER THAN OR EQUAL TO THE REQUESTED ONE.      * 02200022
*                                                                     * 02400022
* ENTRY POINT --                                                      * 02600022
*         IEDQGQ                                                      * 02800022
*         BUILDCPB - IS A SUBROUTINE BRANCHED TO OUT IEDQFA     SA51783 02820022
*         AFTER AN 'EE' REQUEST FOR A CPB BY IEDQGQ HAS BEEN    SA51783 02840022
*         SATISFIED.  THIS SUBROUTINE BUILDS THE CPB PASSED TO  SA51783 02860022
*         IT BY IEDQFA TO MARK A MESSAGE UNSERVICED AND RETURNS SA51783 02880022
*         CONTROL TO IEDQFA TO EXECUTE THE WRITE TO DISK        SA51783 02900022
*                                                               SA51783 02920022
*                                                                     * 03000022
* INPUT --                                                            * 03200022
*    FROM IEDQGR-QRESET SERVICE ROUTINE, A 5 WORD ELEMENT MOVED INTO A* 03400022
*    SPECIAL WORKAREA WHOSE ADDRESS IS IN THE PEWA AT PEGQWKAR        * 03600022
*                                                                     * 03800022
*    WORD                     CONTAINS                                * 04000022
*     1             IEDQGQ'S ENTRY POINT ADDRESS                      * 04200022
*     2             X'D4' PRIORITY AND LINK FIELD = ZERO              * 04400022
*     3 BYTES 0-1   TERMINAL INDEX OFFSET                             * 04600022
*             2-3   REQUESTED OUTPUT SEQUENCE NUMBER                  * 04800022
*     4             TERMINAL ENTRY ADDRESS                            * 05000022
*     5             ECB ADDRESS TO POST FOR RETURN TO IEDQGR          * 05200022
*                                                                     * 05400022
*    FROM IEDQFA - THE ADDRESS OF THE RECALLED BUFFER IN THE WORK     * 05600022
*    AREA'S LCB                                                       * 05800022
*                                                                     * 06000022
* OUTPUT --                                                           * 06200022
*    QCBFFEFO IS CHANGED TO DISK RECORD ADDRESS OF THE MESSAGE WITH   * 06400022
*    THE REQUESTED SEQUENCE NUMBER OR THE MESSAGE WITH THE NEXT       * 06600022
*    HIGHEST SEQUENCE NUMBER FOUND                                    * 06800022
*                                                                     * 07000022
*    ALSO, A 6 BYTE ELEMENT IS RETURNED TO IEDQGR WITH THE FOLLOWING  * 07200022
*    1- IF SUCCESSFUL COMPLETION  - ALL ZEROES                        * 07400022
*    2- IF NOT ALL THE REQUESTED MESSAGES CAN BE MARKED UNSERVICED -  * 07470022
*    BYTES 0-3 X'00000004'                                            * 07540022
*    3- IF REUSABLE DISK REORGANIZATION BECOMES ACTIVE ON THE QUEUE   * 07610022
*    BEING RESET - BYTES 0-3 X'00000008'                              * 07680022
*    4- IF REQUESTED MSG IS NOT MARKED SERVICED BYTES 0-3 X'000000C'  * 07750022
*    5- IF A HEADER IS NO LONGER AVAILABLE OR IF IT LIES IN A ZONE    * 07820022
*    THAT HAS BEEN OR IS ABOUT TO BE REORGANIZED BY REUSABILITY       * 07890022
*    BYTES 0-3 X'00000010'                                            * 07960022
*                                                                     * 08030022
*    FOR 2,3,AND 5 ABOVE, BYTES 4-5 CONTAIN THE COUNT OF MESSAGES     * 08100022
*    SUCCESSFULLY PROCESSED.                                          * 08170022
*                                                                     * 08240022
* EXTERNAL REFERENCES --                                              * 08400022
*         IEDQFA                                                      * 08600022
*         IGC102 - AQCTL SVC                                          * 08800022
*         IGG019R4 - SEND SCHEDULER                                   * 09000022
*                                                                     * 09200022
*                                                                     * 09400022
* EXITS,NORMAL --                                                     * 09600022
*         DSPDISP                                                     * 09800022
*                                                                     * 10000022
*                                                                     * 10200022
*                                                                     * 10400022
* EXITS,ERROR --                                                      * 10600022
*         NONE                                                        * 10800022
*                                                                     * 11000022
* TABLES/WORKAREAS --                                                 * 11200022
*    AVT                                                              * 11400022
*    BUFFER PREFIX                                                    * 11600022
*    LCB                                                              * 11800022
*    QCB                                                              * 12000022
*    SCB                                                              * 12200022
*    TERMINAL TABLE                                                   * 12400022
*    CPB                                                        SA51783 12500022
*                                                                     * 12600022
* ATTRIBUTES --                                                       * 12800022
*    REENTERANT,REFRESHABLE,RESIDENT,ENABLED,PROBLEM PROGRAM MODE     * 13000022
*                                                                     * 13200022
* CHARACTER CODE DEPENDENCY --                                        * 13400022
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL REPRESENTA-* 13600022
*    TION OF AN EXTERNAL CHARACTER SET.  THE CODING HAS BEEN ARRANGED * 13800022
*    SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,    * 14000022
*    WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.         * 14200022
*********************************************************************** 14400022
         SPACE 5                                                        14600022
*********************************************************************** 14800022
*              REGISTER EQUATES                                         15000022
*********************************************************************** 15200022
RZERO    EQU   0                                                        15400022
R1       EQU   1                        REG ONE                         15500022
RONE     EQU   1                                                        15600022
R2       EQU   2                                                        15800022
RDAT     EQU   2                        DATA FIELDS POINTER     SA51783 15900022
RELEM    EQU   3                        SPECIAL ELEMENT POINTER         16000022
RLCB     EQU   4                        LCB BASE REGISTER               16200022
RWORK    EQU   5                        GENERAL WORK REGISTER           16400022
RBFR     EQU   6                        RETURNED BUFFER POINTER         16600022
RQCB     EQU   7                        QCB BASE                        16800022
RTERM    EQU   8                        TERMINAL ENTRY BASE             17000022
RSCB     EQU   9                        SCB BASE                        17200022
RDISP    EQU   11                       DISPATCHER BASE                 17400022
RBASE    EQU   12                       MODULE BASE                     17600022
RAVT     EQU   13                       AVT BASE                        17800022
R14      EQU   14                                                       18000022
RENTRY   EQU   15                                                       18200022
RCPB     EQU   15                       CPB REG FOR BUILD SBRTN SA51783 18300022
*********************************************************************** 18400022
         SPACE 2                                                        18600022
         USING IEDQDISP,RDISP                                           18800022
         USING AVTSAVE2,RAVT                                            19000022
         USING IEDQQCB,RQCB                                             19200022
         USING IEDQTRM,RTERM                                            19400022
         USING IEDQPRF,RBFR                                             19600022
         USING IEDQLCB,RLCB                                             19800022
         USING IEDQSCB,RSCB                                             20000022
         SPACE 2                                                        20200022
IEDQGQ   IEDHJN                                                         20400022
         DC    AL1(DSPMCPL4)            STCB                            20600022
         DC    AL3(*-1)                  ENTRY                          20800022
         SPACE 1                                                        21000022
BEGIN    LR    RBASE,RENTRY             SET UP BASE REGISTER            21200022
         USING BEGIN,RBASE              ESTABLISH ADDRESSIBILITY        21400022
         LR    RELEM,RONE               GET SPECIAL ELEMENT POINTER     21600022
         CLI   FOUR(RONE),PRIRTBFR      IS THIS A RESET REQUEST OR      21800022
*                                       AN ERB FROM IEDQFA              22000022
         BNE   ERBRET                   BRANCH IF ERB FROM IEDQFA       22200022
         LR    RLCB,RELEM                                               22400022
         SH    RELEM,WRKSTRT            BACK UP TO BEGINNING OF         22600022
*                                       IEDQGQ'S WORK AREA              22800022
         OI    ZERO(RELEM),AVTE80       TURN ON RESET IN PROGRESS FLAG  23000022
         XC    X18(D234,RELEM),X18(RELEM)    CLEAR WORK AREA LCB & SCB  23200022
         LA    RLCB,LCBINDX(RLCB)       GET ADDRESS OF LCB              23400022
         LA    RSCB,LCBCPA-IEDQLCB(0,RLCB)     GET SCB ADDRESS          23600022
         ST    RSCB,LCBSCBDA-1          SET CURRENT SCB ADDRESS         23800022
         ST    RSCB,LCBSCBA-1           SET CURRENT SCB ADDRESS         24000022
         L     RTERM,TRMINDX(,RELEM)    GET TERM ENTRY ADDRESS          24200022
         L     RQCB,TRMDESTQ-1          GET TERMINAL'S DESTINATION      24400022
*                                       QCB ADDRESS                     24600022
         LA    RQCB,0(0,RQCB)           CLEAR HIGH ORDER BYTE           24800022
         ST    RQCB,SCBDESTQ-1          SET SCB DEST QUEUE ADDRESS      25000022
         OI    QCBSTAT,QCBTRMHO         MARK TERMINAL'S QCB 'HELD'      25200022
         MVC   SCBDEOB+1(3),QCBQBACK    GET QBACK CHAIN POINTER         25400022
         LH    RWORK,TRMOUTSQ           GET CURRENT OUTPUT SEQ NUMBER   25600022
         SH    RWORK,SEQINDX(RELEM)     GET NUMBER OF MESSAGES  TO BE   25800022
*                                       MARKED UNSERVICED               26000022
         STH   RWORK,LCBTPCD+2          SAVE COUNTER                    26200022
         STH   RWORK,LCBTPCD+4          SAVE COUNTER AGAIN              26300022
         SPACE 2                                                        26400022
*********************************************************************** 26600022
*                       CONTINUE SEARCH                               * 26800022
*********************************************************************** 27000022
         SPACE 1                                                        27200022
CONT     EQU   *                                                        27400022
         LH    RWORK,LCBTPCD+2          GET NUMBER OF MESSAGES LEFT     27600022
*                                       TO BE MARKED UNSERVICED         27800022
         LTR   RWORK,RWORK              HAVE ALL BEEN MARKED UNSERVICED 28000022
         BZ    GOTEM                    BRANCH IF YES                   28200022
         MVC   LCBTPCD+6(3),LCBINVPT    SAVE DISK POINTER               28300022
         LA    RWORK,NOTALL             SET POSSIBLE RETURN CODE        28400022
         NC    SCBDEOB+1(3),SCBDEOB+1   WAS RECALLED PRFHQBCK EMPTY     28500022
         BZ    GOTEM1                   BRANCH IF YES                   28600022
         MVC   SCBSCHDR(3),SCBDEOB+1    SET DISK RECORD NUMBER FOR      28700022
*                                       NEXT BUFFER TO BE RECALLED      28800022
         XC    SCBXTRA(3),SCBXTRA       SET UP                          28900022
         XC    SCBNTXT(3),SCBNTXT       FIELDS                          29000022
         NI    SCBQTYPE,XOF             FOR IEDQFA                      29100022
         MVI   SCBDEOB,AVTEZERO         CLEAR HI-ORDER BYTE             29150022
         SPACE 1                                                        29200022
*********************************************************************** 29300022
*              POST REQUEST FOR DISK I/O TO RECALL BUFFER             * 29400022
*********************************************************************** 29500022
         SPACE 1                                                        29600022
POSTERB  EQU   *                                                        29700022
         LA    RWORK,REUSGO             SET RETURN CODE = REUS IS GOING 29800022
         TM    QCBDSFLG,QCBHELD         IS REUSABILITY ACTIVE ON        29900022
*                                       THIS QUEUE                      30000022
         BNO   GOPOST                   BRANCH IF NO                    30100022
         OI    LCBSNSV,X40              SET ABORT FLAG                  30200022
         B     ABORT                    TERMINATE FUNCTION              30300022
GOPOST   EQU   *                                                        30400022
         ST    RELEM,LCBERCCW           SAVE REGISTERS ACROSS POST      30500022
         STM   RQCB,RTERM,LCBERCCW+4    TO IEDQFA                       30600022
         LA    RWORK,AVTDSIOB           GET ADDRESS OF DISK I/O QCB     30700022
         ST    RWORK,LCBERBQB-1         STORE IT IN ERB QCB FIELD       30800022
         XC    LCBERBLK,LCBERBLK        SET LINK FIELD TO ZERO          30900022
         MVI   LCBERBST,AVTEZERO        CLEAR ERBST                     30950022
         XC    LCBERBCH(3),LCBERBCH     CLEAR POINTER TO LAST BUFFER    31000022
         MVI   LCBERBPY,PRIAPBFR        SET PRIORITY                    31100022
         MVI   LCBERBCT,ONE             SET BUFFER REQUEST COUNT        31200022
         OI    LCBSTAT1,LCBRCLLN+LCBSENDN   SET RECALL FLAGS            31300022
         XC    LCBTTCIN(2),LCBTTCIN     CLEAR INDEX TO TERM CURR CONN   31400022
         LR    RWORK,RBASE              GET ENTRY ADDRESS               31500022
         SH    RWORK,MODBKUP                                            31600022
         ST    RWORK,LCBRCQCB           AND SAVE IT                     31700022
         LA    RONE,LCBERB              ERB ADDRESS FOR POST            31800022
         B     DSPPOST                  POST ERB TO DISK IO QCB         31900022
         SPACE 2                                                        32000022
*********************************************************************** 32100022
* RESTORE BASE REGISTERS FROM POST TO IEDQFA AND CHECK FOR A RETURNED * 32200022
* BUFFER                                                              * 32300022
*********************************************************************** 32400022
         SPACE 1                                                        32500022
ERBRET   EQU   *                                                        32600022
         LR    RLCB,RONE                GET ADDRESS OF LCBERB           32700022
         LA    RLCB,0(0,RLCB)           CLEAR HIGH ORDER BYTE           32800022
         SH    RLCB,LCBBKUP             GET LCB BASE                    32900022
         L     RSCB,LCBSCBDA-1          SET SCB BASE                    33000022
         L     RELEM,LCBERCCW           RESTORE REGISTER                33100022
         LM    RQCB,RTERM,LCBERCCW+4    RESTORE REGISTERS               33200022
         NC    LCBERBCH(3),LCBERBCH     HAS BUFFER BEEN RETURNED        33300022
         BZ    ABORTQR                  BRANCH IF NO                    33400022
         L     RBFR,LCBERBCH-1          GET ADDRESS OF RECALLED BUFFER  33500022
         TM    PRFSTAT1,PRFNHDRN        IS THIS A HEADER BUFFER         33600022
         BO    NTHDR                    BRANCH IF NO                    33700022
         LH    RONE,PRFDEST             LOAD DEST OFFSET        SA51078 33800022
         N     RONE,AVTCLRHI            CLEAR HI-ORDER HALF     SA51078 33820022
         L     RENTRY,AVTRNMPT          TERM NAME ROUTINE       SA51078 33840022
         BALR  R14,RENTRY               LINK TO IT              SA51078 33860022
         CLC   TRMDESTQ-IEDQTRM(,RONE),SCBDESTQ                 SA51078 33880022
*                                       SAME DEST QCB           SA51078 33900022
         BNE   WRNGDEST                 BRANCH IF NO            SA51078 33920022
         SPACE 2                                                        34000022
*********************************************************************** 34100022
*    SAVE POINTERS FOR NEXT RECALL AND BEGIN CHECKING FOR ERRORS      * 34200022
*********************************************************************** 34300022
         SPACE 1                                                        34400022
         MVC   SCBDEOB+1(3),PRFHQBCK    SET UP TO RECALL NEXT UNIT      34500022
         CLC   SCBOSEQ,SEQINDX(RELEM)   IS THIS THE SEQUENCE NUMBER     34600022
*                                       WE'RE LOOKING FOR               34700022
         BE    CHKSVCD                  BRANCH IF YES                   34800022
         BL    RETBUF                   BRANCH IF RECALLED NUM IS LOWER 34900022
         BH    CHKREUS                  BRANCH IF HIGHER                35000022
         SPACE 1                                                        35100022
CHKSVCD  EQU   *                                                        35200022
         TM    ZERO(RBFR),SRVCD         HAS THIS MESSAGE BEEN SERVICED  35300022
         LA    RWORK,RC12               SET UP RETURN CODE              35400022
         BZ    ABORT                    BRANCH IF NO                    35500022
         SPACE 1                                                        35600022
CHKREUS  EQU   *                                                        35800022
         SPACE 2                                                        36000022
         TM    QCBDSFLG,QCBREUS         IS THIS QUEUE ON REUSABLE DISK  36100022
         BNO   CHKFEFO                  BRANCH IF NO                    36200022
         SPACE 1                                                        36300022
*********************************************************************** 36400022
* IF RECALLED HEADER ( POINTED TO BY PRFCRCD) RESIDES IN A DISK ZONE  * 36500022
* THAT HAS BEEN REORGANIZED BY REUSABILITY, QRESET TERMINATES.        * 36600022
*********************************************************************** 36700022
         SPACE 1                                                        36800022
         L     RWORK,AVTTOTNR           GET TOTAL NUM OF DISK RECORDS   36900022
         SRL   RWORK,DIV2               GET NUMBER OF RECORDS ON 1/2    37000022
         LR    RONE,RWORK               THE DISK AND THEN FIND THE NUM  37100022
         SRL   RONE,DIV4                OF RECORDS ON 1/8 DISK          37200022
         AR    RWORK,RONE               TOTAL RECORDS ON 5/8 DISK       37300022
         MVC   LCBERCCW+X11(3),PRFCRCD  SET UP PTR TO CURRENT HDR UNIT  37400022
         L     RONE,LCBERCCW+X10        FOR REGISTER LOAD               37500022
         L     R2,AVTLODPT              GET RADDR THAT WILL TRIGGER     37600022
*                                       REUSABILITY                     37700022
         LA    RONE,3(RONE)             ROUND DISK RECORD ADDRESSES     37800022
         LA    R2,3(R2)                 TO A MULTIPLE OF FOUR           37900022
         SRL   RONE,DIV4                GET NUMBER OF DISK RECORDS      38000022
*                                       REPRESENTED BY AVTLODPT         38100022
         SRL   R2,DIV4                  AND BY PRFCRCD                  38200022
         SR    R2,RONE                  GET THE NUMBER OF RECORDS       38300022
*                                       BETWEEN AVTLODPT AND CURRENT    38400022
*                                       UNIT                            38500022
         CR    R2,RWORK                 IS CURRENT HDR 2 1/2 ZONES      38600022
*                                       BEHIND AVTLODPT                 38700022
         BNH   CHKTEXT                  BRANCH IF NO                    38800022
ABORTQR  EQU   *                                                        38900022
         OI    LCBSNSV,X40              SET ABORT FLAG                  39000022
         LA    RWORK,RC16               SET RETURN CODE                 39100022
         B     ABORT                    PREPARE TO EXIT WITHOUT         39200022
*                                       RESETTING QCBFFEFO              39300022
         SPACE 1                                                        39400022
*********************************************************************** 39500022
* CHECK TEXT AND/OR XTRA UNIT TO SEE IF IT LIES WITHIN AN ENDANGERED  * 39600022
* ZONE.  IF IT DOES, RETURN HEADER WITHOUT MARKING IT UNSERVICED AND  * 39700022
* CONTINUE SEARCH.                                                    * 39800022
*        RONE CONTAINS # OF RECORDS REPRESENTED BY PRFCRCD            * 39900022
*        RWORK CONTAINS # OF RECORDS WITHIN 5/8 OF TOTAL DISK         * 40000022
*********************************************************************** 40100022
         SPACE 1                                                        40200022
CHKTEXT  EQU   *                                                        40300022
         CLC   PRFNTXT,PRFCRCD          IS THERE A TEXT BUFFER          40400022
         BNL   CHKXTRA                  BRANCH IF NO TEXT UNIT OR IF    40500022
*                                       TEXT FOLLOWS HEADER             40600022
         MVC   LCBERCCW+X11,PRFNTXT     SET UP DISK ADDRESS FOR         40700022
         L     R2,LCBERCCW+X10          REGISTER LOAD                   40800022
         BAL   R14,COMPR                GO CHECK DISTANCE BETWEEN HDR   40900022
*                                       AND TEXT                        41000022
         SPACE 1                                                        41100022
CHKXTRA  EQU   *                                                        41200022
         MVC   LCBERCCW+X11,PRFXTRA     SET UP DISK ADDRESS FOR         41300022
         L     R2,LCBERCCW+X10          REGISTER LOAD                   41400022
         LTR   R2,R2                    ARE THERE ANY XTRA UNITS        41500022
         BZ    CHKFEFO                  BRANCH IF NO                    41600022
         CLC   PRFXTRA,PRFCRCD          COMPARE XTRA AND HDR            41700022
         BH    CHKFEFO                  BRANCH IF XTRA IS AHEAD OF HDR  41800022
         LA    R14,CHKFEFO              SET SUBROUTINE EXIT ADDRESS     41900022
         SPACE 1                                                        42000022
COMPR    EQU   *                                                        42100022
         LA    R2,3(R2)                 ROUND TO MULTIPLE OF FOUR       42200022
         SRL   R2,DIV4                  CONVERT ADDRESS TO NUMBER       42300022
*                                       OF RECORDS IT REPRESENTS        42400022
         SR    RONE,R2                  GET DIFFERENCE BETWEEN HEADER   42500022
*                                       AND TEXT OR XTRA UNIT           42600022
         CR    RONE,RWORK               IS UNIT 2 1/2 ZONES BEHIND HDR  42700022
         BH    SKIPONE                  GO UPDATE COUNTER AND RETURN    42800022
*                                       UNIT.  THE UNIT IS TOO FAR      42900022
*                                       BEHIND HEADER. DO NOT RISK A    43000022
*                                       LOGICAL READ ERR                43100022
         BR    R14                      RETURN FROM SUBROUTINE          43200022
         SPACE 1                                                        43300022
*********************************************************************** 43400022
* IF RECALLED DATFEFO IS ZERO AND THIS IS NOT THE LAST MESSAGE        * 43500022
* QUEUED, SKIP UNSERVICING, RETURN UNIT AND CONTINUE SEARCH           * 43600022
*********************************************************************** 43700022
         SPACE 1                                                        43800022
CHKFEFO  EQU   *                                                        43900022
         L     RWORK,ZERO(RBFR)         GET DATFEFO POINTER             44000022
         LA    RWORK,ZERO(RWORK)                                        44100022
         LTR   RWORK,RWORK              IS DATFEFO ZERO                 44200022
         BNZ   UNSRV                    BRANCH IF NO                    44300022
         CLC   PRFCRCD,QCBLFEFO         IS THIS THE LAST MSG QUEUED     44400022
*                                       FOR THIS TERMINAL               44500022
         BNE   SKIPONE                  GO UPDATE COUNTER, RETURN UNIT  44600022
*                                       CONTINUE SEARCH                 44700022
UNSRV    EQU   *                                                        44800022
         MVC   LCBINVPT,PRFCRCD         SAVE DISK POINTER TO THIS UNIT  44850022
         LH    R2,LCBTPCD+2             GET COUNT OF MESSAGES LEFT TO   44860022
*                                       BE HANDLED                      44870022
         BCTR  R2,ZERO                  DECREMENT BY ONE                44880022
         STH   R2,LCBTPCD+2             SAVE BACK                       44890022
         MVC   PRFSVFLG,AVTEZERO(RBFR)  SAVE DATA FLAGS         SA51783 44900022
         MVC   PRFSVFFO,ONE(RBFR)       SAVE FEFO PTR           SA51783 45100022
         MVC   PRFSVSEQ,SCBOSEQ         SAVE SEQ OUT NUMBER     SA51783 45300022
         MVI   PRFPRI,PRIFEFO           PUT PRIORITY INTO BUFFER        45700022
         LA    R14,BUILDCPB             ADDR OF CPB BUILD SBRTN SA51783 45730022
         ST    R14,PRFTIC               PASS IT TO IEDQFA       SA51783 45760022
         MVI   PRFTIC,TIC               MARK IT AS BUFFER               45800022
         LA    RENTRY,AVTDSIOB          GET ADDRESS OF DISK I/O QCB     45900022
         B     WRTBUF                   GO POST RECALLED BUFFER TO      46000022
*                                       IEDQFA TO MARK MESSAGE          46100022
*                                       UNSERVICED                      46200022
         SPACE 1                                                        46300022
*********************************************************************** 46400022
* KEEP A COUNT OF THOSE MESSAGES THAT HAVE BEEN FOUND BUT SHOULD NOT  * 46500022
* BE MARKED UNSERVICED.  E.G., TEXT OR XTRA UNITS IN ENDANGERED ZONE  * 46600022
* ON REUSABLE DISK OR MESSAGE WAS ORIGINALLY SENT IN INITIATE OR      * 46700022
* LOCK MODE.                                                          * 46800022
*********************************************************************** 46900022
         SPACE 1                                                        47000022
SKIPONE  EQU   *                                                        47100022
         LH    RWORK,LCBTPCD+XA         GET COUNT OF MESSAGES SKIPPED   47200022
         LA    RWORK,ONE(RWORK)         BUMP BY ONE                     47300022
         STH   RWORK,LCBTPCD+XA         SAVE BACK                       47400022
         B     RETBUF                   GO RETURN BUFFER                47500022
         SPACE 2                                                        47600022
*********************************************************************** 47700022
*                  RETURN RECALLED UNIT                               * 47800022
*********************************************************************** 47900022
         SPACE 1                                                        47930022
NTHDR    EQU   *                                                        47960022
WRNGDEST EQU   *                                                        48000022
         MVC   SCBDEOB+1(3),PRFNTXT     PICK UP PROPER Q-BACK PTR       48100022
RETBUF   EQU   *                                                        48500022
         MVI   PRFPRI,PRIBFRTB          SET EMPTY BUFFER PRIORITY       48600022
         LA    RENTRY,AVTBFRTB          GET BUFFER RETURN QCB ADDRESS   48700022
         SPACE 5                                                        48800022
WRTBUF   EQU   *                                                        48900022
         ST    RENTRY,PRFQCBA-1         STORE IN BUFFER QCB             49000022
         XC    PRFLINK(3),PRFLINK       ZERO THE LINK FIELD             49100022
         LR    RONE,RBFR                SET PARM REG FOR DISPATCHER     49200022
         BAL   R14,DSPPOSTR             PUT BUFFER ON THE READY QUEUE   49300022
         L     RELEM,LCBERCCW           RESTORE REG FROM DISPATCHER     49400022
         LM    RQCB,RTERM,LCBERCCW+4    RESTORE REGISTERS               49500022
         B     CONT                     GO REQUEST READ OF HEADER       49600022
         SPACE 2                                                        49700022
*********************************************************************** 49800022
*          SET RETURN CODE AND, IF NECESSARY, UPDATE QCBFFEFO         * 49900022
*********************************************************************** 50000022
         SPACE 1                                                        50100022
         SPACE 1                                                        50200022
GOTEM    EQU   *                                                        50300022
         SR    RWORK,RWORK              ZERO REGISTER                   50400022
         SPACE 1                                                        50500022
GOTEM1   EQU   *                                                        50600022
         MVC   QCBFFEFO,LCBINVPT        UPDATE THE FEFO POINTER FOR THE 50700022
*                                       SEND SCHEDULER                  50800022
         MVC   QCBPFEFO,LCBINVPT        AND SET UP OTHER QCB            50820022
         MVC   QCBPREVF,LCBINVPT        MESSAGE POINTERS                50840022
         SPACE 1                                                        50860022
ABORT    EQU   *                                                        50900022
         LH    R2,LCBTPCD+4             ORIGINAL NUM OF MESSAGES TO     51000022
*                                       BE MARKED UNSERVICED            51100022
         SH    R2,LCBTPCD+2             SUBTRACT NUMBER NOT FOUND       51200022
         LR    RONE,R2                  SAVE NUM OF MESSAGES RESET      51220022
         AH    RONE,QCBMSGCT            ADD NUM OF MESSAGES ON QUEUE    51240022
         STH   RONE,QCBMSGCT            UPDATE MESSAGE COUNT            51260022
         LH    RONE,LCBTPCD+XA          CHECK FOR SKIPPED MESSAGES      51300022
         LTR   RONE,RONE                ARE THERE ANY                   51400022
         BZ    SAVCNT                   BRANCH IF NO                    51500022
         SR    R2,RONE                  SUBTRACT SKIPPED MESSAGES FROM  51600022
*                                       TOTAL HANDLED                   51700022
         LTR   RWORK,RWORK              IS THERE AN ERROR CODE          51800022
         BNZ   SAVCNT                   BRANCH IF YES                   51900022
         LA    RWORK,FOUR               SET RETURN CODE INDICATING THAT 52000022
*                                       SOME OF THE REQUESTED MESSAGES  52100022
*                                       HAVE NOT BEEN MARKED UNSERVICED 52200022
         SPACE 1                                                        52300022
SAVCNT   EQU   *                                                        52400022
         STH   R2,LCBTPCD+2             SAVE # MESSAGES HANDLED -       52500022
*                                       INCLUDES THOSE 'UNSERVICED AND  52600022
*                                       THOSE SKIPPED DUE TO CERTAIN    52700022
*                                       ERROR CONDITIONS                52800022
         TM    ZERO(RELEM),CLOSDOWN     IS CLOSEDOWN IN PROGRESS        52830022
         BO    SKPAPOST                 BRANCH ON YES                   52860022
         L     R2,20(,RELEM)            GET PTR TO ECB FOR POST         52900022
         ST    R2,LCBERCCW+XC           SAVE ECB ADDRESS                53000022
         XC    4(16,RELEM),4(RELEM)     CLEAR FIELDS                    53100022
         ST    RWORK,FOUR(,RELEM)       STORE RETURN CODE               53200022
         MVC   8(2,RELEM),LCBTPCD+2     STORE NUMBER OF MESSAGES        53300022
*                                       MARKED UNSERVICED               53400022
         LA    RZERO,FOUR(,RELEM)       DATA ADDRESS                    53500022
         LA    RONE,4(,R2)              TARGET ADDRESS                  53600022
         LA    R2,RETELLEN              ELEMENT LENGTH ADDRESS          53700022
         STM   RZERO,R2,12(RELEM)       FILL IN LIST                    53800022
         MVI   12(RELEM),MOVE           AQCTL ACTION CODE               53830022
         MVI   20(RELEM),EOL            END OF LIST FLAG                53860022
         LA    RONE,12(RELEM)           SET PARM REG FOR SVC 102        53900022
         SVC   102                      POST TO APPLICATION REGION      54000022
         SPACE 2                                                        54100022
*********************************************************************** 54200022
* THIS CODE BUILDS THE AQCTL PARM LIST IN PREPARATION FOR RETURN TO   * 54300022
* THE QRESET SERVICE ROUTINE                                          * 54400022
*********************************************************************** 54500022
         SPACE 1                                                        54600022
         L     R2,LCBERCCW+XC           RESTORE ECB ADDRESS             54700022
         ST    R2,FOUR(RELEM)           SET ECB ADDRESS IN AQCTL LIST   54800022
         LA    RWORK,TJIDAD             GET ADDRESS OF TJID FOR AQCTL   54900022
         ST    RWORK,EIGHT(RELEM)       AND MOVE INTO PARM LIST         55000022
         MVI   FOUR(RELEM),X'20'        AQCTL ACTION CODE               55100022
         MVI   EIGHT(RELEM),X'80'                                       55200022
         LA    RONE,FOUR(RELEM)         GET PARAMETER ADDRESS           55300022
         SVC   102                                                      55400022
SKPAPOST EQU   *                                                        55450022
         SPACE 1                                                        55500022
*********************************************************************** 55600022
*        IF NECESSARY, GET SEND SCHEDULER IN THE LCB                  * 55700022
*********************************************************************** 55800022
         SPACE 1                                                        55900022
         SPACE 1                                                        56000022
         NI    QCBSTAT,AVTEFF-QCBTRMHO  RELEASE TERMINAL'S QCB          56100022
         NI    0(RELEM),AVTEFF-AVTE80   TURN OFF BUSY FLAG              56200022
         TM    ZERO(RELEM),CLOSDOWN     CLOSEDOWN IN PROGRESS           56210022
         BZ    NOTCLOSE                 BRANCH IF NO                    56220022
         MVC   X39(3,RELEM),AVTOCQPT+1  OPEN/CLOSE QCB ADDRESS          56230022
         MVI   X3C(RELEM),PRIAPBFR      SET PRIORITY                    56240022
         LA    RONE,X38(RELEM)          POINT TO SPECIAL ELEMENT        56250022
         LR    R2,RQCB                  SAVE REG                        56260022
         BAL   R14,DSPPOSTR             POST CLOSE ELEMENT              56270022
         LR    RQCB,R2                  RESTORE REG                     56280022
NOTCLOSE EQU   *                                                        56290022
         TM    LCBSNSV,X40              IS ABORT FLAG ON                56300022
         BO    LEAVE                    BRANCH IF YES                   56400022
         NC    AVTCKGET+1(3),AVTCKGET+1 CHECKPOINT IN SYSTEM            56405022
         BZ    NOCKPT                   BRANCH IF NO                    56410022
         LA    R1,AVTCKELE              CKPT ELE                        56415022
         L     RENTRY,AVTHG02           TIME Q DELINK ROUTINE           56420022
         BALR  R14,RENTRY               REMOVE CKPT ELE                 56425022
         TM    AVTCKELF,AVTCRTLN        CKPT ELE ALREADY POSTED         56430022
         BO    NOCKPT                   BRANCH IF YES                   56435022
         TM    AVTCKELF,AVTCPIPN        CKPT IN PROGRESS                56440022
         BO    REQCKPT                  BRANCH IF YES                   56445022
         MVC   AVTCKELE+1(3),AVTCKQAD   CKPT QCB ADDR                   56450022
         LA    R1,AVTCKELE              CKPT ELEMENT ADDR               56455022
         MVI   AVTCKELE+FOUR,PRICKPT    SET PRIORITY                    56460022
         LR    R2,RQCB                  SAVE REG                        56465022
         BAL   R14,DSPPOSTR             POST CKPT ELE                   56470022
         LR    RQCB,R2                  RESTORE REG                     56475022
REQCKPT  EQU   *                                                        56480022
         OI    AVTCKELF,AVTCRTLN        SET CKPT REQUESTED              56485022
NOCKPT   EQU   *                                                        56490022
         TM    TRMSTATE,TRMPROC         IS RESET FOR A PROCESS ENTRY    56500022
         BO    LEAVE                    BRANCH IF PROCESS ENTRY         56600022
         LA    RWORK,QCBSTVTO           GET ADDRESS OF STCB             56700022
         L     R2,QCBSTCHN-1            GET ADDRESS OF FIRST STCB       56800022
*                                       IN CHAIN                        56900022
         LA    R2,ZERO(,R2)             CLEAR HIGH ORDER BYTE           57000022
         CR    RWORK,R2                 IS SEND SCHEDULER STCB IN QCB   57100022
         BNE   LEAVE                    BRANCH IF NO                    57200022
         SR    RENTRY,RENTRY            CLEAR REGISTER                  57300022
         IC    RENTRY,QCBSTVTO          GET SCHEDULER'S SUBTASK VECTOR  57400022
         AR    RENTRY,RENTRY            TABLE ENTRY AND GO TO THE       57500022
         L     R2,AVTDISP-24(RENTRY)    SPECIAL ENTRY IN THE            57600022
         SH    R2,AVTHA2                SEND SCHEDULER TO               57700022
         LH    RENTRY,ZERO(,R2)         INSERT ITS                      57800022
         AR    RENTRY,R2                STCB                            57900022
         BALR  R14,RENTRY               IN TERMINAL'S LCB               58000022
         SPACE 1                                                        58100022
*********************************************************************** 58200022
*                        EXIT TO THE DISPATCHER                       * 58300022
*********************************************************************** 58400022
LEAVE    EQU   *                                                        58500022
         B     DSPDISP                  EXIT                            58600022
         EJECT                                                          58700022
****************************************************************SA51783 58702022
*                                                              *SA51783 58704022
* THIS SUBROUTINE IS BRANCHED TO OUT OF IEDQFA AFTER A REQUEST *SA51783 58706022
* FOR A CPB BY IEDQGQ HAS BEEN FULFILLED.  IT BUILDS THE CPB   *SA51783 58708022
* AND DATA FIELDS NECESSARY TO MARK A MESSAGE UNSERVICED,      *SA51783 58710022
* RETURNS THE RECALLED BUFFER TO BUFFER RETURN, AND RETURNS    *SA51783 58712022
* TO IEDQFA ON A BRANCH TO DSPPOSTR SINCE R14 CONTAINS THE     *SA51783 58714022
* RETURN ADDRESS TO IEDQFA.                                    *SA51783 58716022
*                                                              *SA51783 58718022
****************************************************************SA51783 58720022
         SPACE 3                                                        58722022
         DROP  RBASE                    SUBROUTINE HAS NO BASE  SA51783 58724022
         USING IEDQDATA,RDAT            DATA FIELD              SA51783 58726022
         USING IEDQCPB,RCPB             CPB                     SA51783 58728022
         SPACE 3                                                        58730022
BUILDCPB EQU   *                                                SA51783 58732022
         L     RCPB,PRFTIC              ADDR OF CPB FROM IEDQFA SA51783 58734022
         L     RDAT,CPBXREAF            UNIT ADDR FOR WRT DATA  SA51783 58736022
         L     RQCB,PRFQCBA-1           QCB ADDR STORED BY FA   SA51783 58738022
         MVI   CPBRDWR,CPBWRC           WRITE DATA COMMAND      SA51783 58740022
         MVI   CPBXDWR,CPBNOPC          NOP COMMAND CODE        SA51783 58742022
         MVC   CPBADDR+1(3),PRFCRCD     SET ADDR OF BUFFER      SA51783 58744022
         MVC   DATFLAGS,PRFSVFLG        SET SAVED DATA FLAGS    SA51783 58746022
         NI    DATFLAGS,X'FF'-DATSENT   TURN OFF SERVICED FLAG  SA51783 58748022
         MVC   DATFEFO,PRFSVFFO         SET SAVED FEFO PTR      SA51783 58750022
         MVC   DATSEQOT,PRFSVSEQ        SET SAVED SEQ OUT NUM   SA51783 58752022
         MVI   PRFPRI,PRIBFRTB          SET RETURN BFR PRIORITY SA51783 58754022
         LA    R2,AVTBFRTB              BFR RETURN QCB ADDRESS  SA51783 58756022
         ST    R2,PRFQCBA-1             SET IT IN BUFFER        SA51783 58758022
         LR    R1,RBFR                  SET BFR AS ELEMENT      SA51783 58760022
         CLC   QCBLFEFO,PRFCRCD         LAST MSG QUEUED FOR TRM SA51783 58762022
         BNE   DSPPOSTR                 BR NO - POST BFR TO     SA51783 58764022
*                                       BFR RETURN AND RETURN   SA51783 58766022
*                                       ON R14 TO IEDQFA        SA51783 58768022
         MVC   QCBDATFL,DATFLAGS        UPDATE QCB FLAG FOR MSG SA51783 58770022
         B     DSPPOSTR                 POST BFR TO BFR RETURN  SA51783 58772022
*                                       QUEUE AND RETURN ON     SA51783 58774022
*                                       REGISTER 14 TO IEDQFA   SA51783 58776022
         EJECT                                                          58778022
*********************************************************************** 58800022
*                       EQUATES AND CONSTANTS                         * 58900022
*********************************************************************** 59000022
         SPACE 1                                                        59100022
TJIDAD   DC    F'0'                     TJID FOR AQCTL                  59200022
         DS    0H                                                       59300022
LCBBKUP  DC    AL2(LCBERB-IEDQLCB)      USED TO ADJUST LCB BASE         59400022
MODBKUP  DC    AL2(12)                  USED TO LOCATE IEDQGQ'S QCB     59500022
RETELLEN DC    H'0006'                  LENGTH OF ELEMENT FOR RETURN    59600022
*                                       TO IEDQGR                       59700022
WRKSTRT  DC    H'0004'                  QUANTITY TO BACH UP TO THE      59800022
*                                       BEGINNING OF IEDQGQ'S WORK AREA 59900022
FOUR     EQU   4                                                        60000022
NOTALL   EQU   X'04'                    RETURN CODE = PARTIAL RETRIEVAL 60100022
ONE      EQU   1                                                        60200022
PRIRTBFR EQU   X'D4'                    RETRIEVE PRIORITY               60300022
XC       EQU   12                                                       60400022
EIGHT    EQU   8                                                        60500022
REUSGO   EQU   8                                                        60600022
SELELEN  EQU   16                       LENGTH OF SPECIAL ELEMENT       60700022
TIC      EQU   X'08'                    FLAG = BUFFER FOR DISK I/O      60800022
XOF      EQU   X'0F'                    QUEUE TYPE MASK                 60900022
ZERO     EQU   0                                                        61000022
X18      EQU   X'18'                                                    61100022
XA       EQU   10                                                       61200022
D234     EQU   234                      LENGTH OF WORK AREA MINUS       61300022
*                                       SPECIAL ELEMENT AREA            61400022
RC12     EQU   12                       SEQUENCE ERROR RETURN CODE      61500022
RC16     EQU   16                       RETURN CODE FOR ABORTED FUNC-   61600022
*                                       TION TO AVOID POSSIBLE LOGICAL  61700022
*                                       READ ERROR                      61800022
SRVCD    EQU   X'40'                    FLAG = MESSAGE SERVICED         61900022
DIV4     EQU   2                                                        62000022
DIV2     EQU   1                                                        62100022
X40      EQU   X'40'                                                    62200022
X11      EQU   17                                                       62300022
X10      EQU   16                                                       62400022
MOVE     EQU   X'08'                                                    62430022
EOL      EQU   X'80'                                                    62460022
CLOSDOWN EQU   X'40'                                                    62468022
X38      EQU   X'38'                                                    62476022
X39      EQU   X'39'                                                    62484022
X3C      EQU   X'3C'                                                    62492022
         SPACE 2                                                        62500022
***                                                                 *** 62600022
*                  SPECIAL ELEMENT FIELD DISPLACEMENTS                * 62700022
***                                                                 *** 62800022
TNTINDX  EQU   12                       TNT INDEX                       62900022
SEQINDX  EQU   14                       SEQ NUMBER REQUESTED            63000022
TRMINDX  EQU   16                       DISPLACEMENT TO TERM ENTRY      63100022
LCBINDX  EQU   24                       OFFSET TO BEGINNING OF          63200022
*                                       DUMMY LCB                       63300022
         EJECT                                                          63400022
         TDISPD                                                         63500022
         TPRIOR                                                         63600022
         TSCBD                                                          63700022
         TQCBD                                                          63800022
         TPRFD                                                          63900022
         TLCBD                                                          64000022
         TTRMD                                                          64100022
         TAVTD                                                          64200022
         EJECT                                                          64220022
         TCPBD 3330                                             SA51783 64240022
         EJECT                                                          64260022
         TDATAD                                                 SA51783 64280022
         END                                                            64300022
         EJECT                                                          76800022
         TDISPD                                                         77000022
         TPRIOR                                                         77200022
         TSCBD                                                          77400022
         TQCBD                                                          77600022
         TPRFD                                                          77800022
         TLCBD                                                          78000022
         TTRMD                                                          78200022
         TAVTD                                                          78400022
         END                                                            78600022
