         TITLE 'IEDQGR - QRESET SERVICE ROUTINE'                        00300022
IEDQGR   CSECT                                                          00600022
*******************CHANGE ACTIVITY AS FOLLOWS**************** SUPT CODE 00700056
*C480000,483000                                                 SA70211 00800056
*********************************************************************** 00900022
*                                                                     * 01200056
* MODULE NAME = IEDQGR                                                * 01200156
*                                                                     * 01200256
* DESCRIPTIVE NAME = QRESET SERVICE ROUTINE                           * 01200356
*                                                                     * 01200456
* COPYRIGHT = NONE                                                    * 01200556
*                                                                     * 01200656
* STATUS = LEVEL 5                                                    * 01200756
*                                                                     * 01200856
* FUNCTION --                                                         * 02100022
*    VALIDITY CHECKS USER INPUT FOR A QRESET REQUEST AND BUILDS A     * 02400022
*    PARAMETER LIST FOR 'IEDQGQ - QUEUE RESET EXECUTOR'.  POSTS THE   * 02700022
*    PARAMETER LIST CROSS PARTITION TO IEDQGQ'S WORKAREA AND WAITS    * 03000022
*    FOR IEDQGQ TO COMPLETE PROCESSING THE REQUEST.                   * 03300022
*                                                                     * 03600022
* ENTRY POINT --                                                      * 03900022
*         IEDQGR                                                      * 04200022
*                                                                     * 04500022
* INPUT --                                                            * 04800022
*    REG 1 CONTAINS A POINTER TO AN OPENED APPLICATION PROGRAM DCB    * 05100022
*    REG 2 CONTAINS A POINTER TO A FIELD WITH THE FOLLOWING FORMAT -  * 05400022
*    *  TERMINAL   *SEQUENCE*                                         * 05700022
*    *   NAME      * NUMBER *                                         * 06000022
*    ************************                                         * 06300022
*    0             7        9 BYTES                                   * 06600022
*                                                                     * 06900022
* OUTPUT --                                                           * 07200022
*    REG 15 CONTAINS ONE OF THE FOLLOWING RETURN CODES -              * 07500022
*    CODE      MEANING                                                * 07800022
*    X'00'     QRESET HAS BEEN EXECUTED SUCCESSFULLY                  * 08100022
*    X'04'     QRESET HAS BEEN UNABLE TO FIND ONE OR MORE OF THE      * 08400022
*              REQUESTED SEQUENCE NUMBERS.  REG 2 WILL CONTAIN THE    * 08700022
*              COUNT OF MESSAGES SUCCESSFULLY PROCESSED.              * 09000022
*    X'08'     REUSABLE DISK REORGANIZATION IS IN PROGRESS.  REG 2    * 09300022
*              WILL CONTAIN THE COUNT OF MESSAGES SUCCESSFULLY PRO-   * 09600022
*              CESSED BEFORE THE START OF THE REORGANIZATION.         * 09900022
*    X'0C'     REQUESTED SEQUENCE NUMBER IN ERROR                     * 10200022
*    X'10'     QRESET NOT ALLOWED FROM REQUESTING APPLICATION PROGRAM * 10500022
*    X'14'     INVALID TERMINAL NAME OR TERMINAL IS HELD              * 10800022
*    X'18'     AN ERROR EXISTS REGARDING THE TYPE OF QUEUING OR THERE * 11100022
*              ARE NO MESSAGES QUEUED FOR THE SPECIFIED TERMINAL      * 11400022
*    X'1C'     TERMINATE FUNCTION TO AVOID  POSSIBLE LOGICAL READ ERR * 11470022
*              REG 2 WILL CONTAIN THE COUNT OF MESSAGES MARKED UNSER- * 11540022
*              VICED.  HOWEVER, NO MESSAGES ARE SCHEDULED TO BE RESENT* 11610022
*                                                                     * 11700022
* EXTERNAL REFERENCES --                                              * 12000022
*         IGC102 - AQCTL SVC                                          * 12300022
*         IEDQE8 - BINARY SEARCH ROUTINE                              * 12600022
*         IEDQTNT - TERMINAL NAME TABLE CONVERSION LOGIC              * 12900022
*                                                                     * 13200022
* EXITS,NORMAL --                                                     * 13500022
*         RETURN TO QRESET MACRO EXPANSION                            * 13800022
*                                                                     * 14100022
* EXITS,ERROR --                                                      * 14400022
*         NONE                                                        * 14700022
*                                                                     * 15000022
* TABLES/WORKAREAS --                                                 * 15300022
*    AVT                                                              * 15600022
*    ACCESS METHOD WORK AREA                                          * 15900022
*    PROCESS ENTRY WORK AREA                                          * 16200022
*    QCB                                                              * 16500022
*    TERMINAL TABLE                                                   * 16800022
*                                                                     * 17100022
* ATTRIBUTES --                                                       * 17400022
*    SERIALLY REUSABLE,ENABLED,PROBLEM PROGRAM MODE                   * 17700022
*                                                                     * 18000022
* CHARACTER CODE DEPENDENCY --                                        * 18300022
*    THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL REPRESENTA-* 18600022
*    TION OF AN EXTERNAL CHARACTER SET.  THE CODING HAS BEEN ARRANGED * 18900022
*    SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,    * 19200022
*    WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.         * 19500022
*********************************************************************** 19800022
         SPACE 5                                                        20100022
**********************************************************************  20400022
*                            REGISTER  EQUATES                        * 20700022
**********************************************************************  21000022
RZERO    EQU   0                                                        21300022
RONE     EQU   1                                                        21600022
RPARM2   EQU   2                                                        21900022
RPEWA    EQU   3                                                        22200022
RWORKA   EQU   4                        PARAMETER POINTER               22500022
RWORKB   EQU   5                        PARAMETER POINTER               22800022
RQCB     EQU   6                        QCB BASE                        23100022
RTERM    EQU   7                        TERM ENTRY POINTER              23400022
RSEQ     EQU   8                        SEQUENCE NUMBER REGISTER        23700022
RACSMD   EQU   9                        ACCESS METHOD WORK AREA PTR     24000022
RAVT     EQU   10                       AVT BASE                        24300022
RDISP    EQU   11                       DISPATCHER BASE                 24600022
RBASE    EQU   12                       MODULE BASE REGISTER            24900022
RSAVE    EQU   13                       SAVE AREA POINTER               25200022
R14      EQU   14                                                       25500022
R15      EQU   15                                                       25800022
*********************************************************************** 25900022
         SPACE 5                                                        26000022
         USING IEDQWRKA,RACSMD                                          26100022
         USING IEDQAVTD,RAVT                                            26400022
         USING IEDQQCB,RQCB                                             26700022
         USING IEDQTRM,RTERM                                            27000022
         USING IEDQDISP,RDISP                                           27300022
         SPACE 2                                                        27400022
         SAVE  (14,12)                  SAVE CALLLER'S REGISTERS        27600022
         LR    RBASE,R15                SET UP BASE REGISTER            27900022
         USING IEDQGR,RBASE             ESTABLISH ADDRESSABILITY        28200022
IEDQGR   IEDHJN  BEGIN                                                  28500022
         L     RWORKA,CVTADD            GET CVT POINTER                 28800022
         L     RAVT,AVTCVTPT(RWORKA)    GET POINTER TO AVT ADRRESS      29100022
         L     RAVT,ZERO(RAVT)          GET AVT ADDRESS                 29400022
         L     RDISP,AVTEA              GET POINTER TO DISPATCHER       29700022
         ST    RSAVE,MYSAVE+FOUR        SAVE PTR TO CALLER'S SAVE AREA  30000022
         LA    RSAVE,MYSAVE             SET UP PTR TO MY SAVE AREA      30300022
         LR    RWORKA,RONE              SAVE PARAMETER POINTER          30600022
         LR    RWORKB,RPARM2            SAVE USER'S PARAMETER PTR       30900022
         SPACE 1                                                        31000022
**********************************************************************  31200022
* THIS CODE LOCATES THE WORK AREA USED BY THE 'QUEUE RESET EXECUTOR'  * 31500022
* (IEDQGQ).  IF THE USER HAS NOT PROVIDED FOR THE WORK AREA OR IF THE * 31800022
* QUEUE RESET EXECUTOR IS IS CURRENTLY PROCESSING A REQUEST FROM THIS * 32100022
* APPLICATION PROGRAM, THE FUNCTION IS ABORTED.                       * 32400022
**********************************************************************  32700022
         SPACE 1                                                        32800022
         LR    RPEWA,RONE               START TO FIND IEDQGQ'S WORK     33000022
*                                       AREA                            33300022
         L     RPEWA,ZERO(RPEWA)        GET DCB ADDRESS                 33600022
         TM    X30(RPEWA),OPEN          IS DCB OPENED                   33900022
         BNO   PROCERR                  BRANCH IF NO                    34200022
         USING IHADCB,RPEWA                                             34500022
         L     RONE,DCBDEBAD            GET DEB ADDRESS                 34800022
         DROP  RPEWA                                                    35100022
         USING IEDQDEB,RONE                                             35400022
         L     RACSMD,DEBTAMWA-1        GET ADDR OF ACCESS METHOD       35700022
*                                       WORK AREA                       36000022
         DROP  RONE                                                     36300022
         L     RPEWA,PWAPEWA            GET POINTER TO PROCESS ENTRY    36600022
*                                       WORK AREA                       36900022
         USING IEDQPEWA,RPEWA                                           37200022
         L     RPARM2,PEGQWKAR          GET ADDRESS OF IEDQGQ'S         37500022
*                                       WORKAREA                        37800022
         LTR   RPARM2,RPARM2            IS QUEUE RESET ALLOWED FROM     38100022
         BZ    PROCERR                  BRANCH IF NO                    38400022
CHKBSY   EQU   *                                                        38700022
         LR    RPEWA,RPARM2             GET PTR TO WORK AREA            39000022
         DROP  RPEWA                                                    39300022
         TM    ZERO(RPEWA),AVTE80       IS QUEUE RESET ALREADY ACTIVE   39600022
*                                       FOR THIS APPLICATION PROGRAM    39900022
         BO    PROCERR                  BRANCH IF YES                   40200022
         SPACE 2                                                        40500022
**********************************************************************  40800022
* THIS CODE FINDS THE TERMINAL TABLE OFFSET AND TERMINAL ENTRY ADDRESS  41100022
* ALSO VALIDITY CHECKS THE TERMINAL SPECIFICATION                     * 41400022
**********************************************************************  41700022
CHKINDX  EQU   *                                                        42000022
         LR    RZERO,RWORKB             GET PTR TO TERMINAL NAME        42300022
         L     R15,AVTE8                GET ADDRESS OF BINARY SEARCH    42600022
         BALR  R14,R15                  GO TO SEARCH ROUTINE            42900022
         LTR   R15,R15                  WAS TERM ENTRY FOUND            43200022
         BZ    TERMERR                  BRANCH IF NO                    43500022
         STH   R15,GWAELEM+EIGHT        SET TERM INDEX IN SPECIAL ELEM  43800022
CHKENTAD EQU   *                                                        44100022
         LR    RONE,R15                 GET TERMNAME TABLE OFFSET       44400022
         L     R15,AVTRNMPT             GET ADDRESS OF TERM TABLE       44700022
*                                       CONVERSION LOGIC                45000022
         BALR  R14,R15                  GO GET ENTRY ADDRESS            45300022
         ST    RONE,GWAELEM+12          STORE ENTRY ADDR IN SPECIAL     45600022
*                                       ELEMENT                         45900022
         LR    RTERM,RONE               SAVE TERMINAL ENTRY ADDRESS     46200022
         L     RQCB,ZERO(RTERM)         GET QCB ADDRESS                 46500022
         TM    TRMSTATE,LGLNLST         TERM ENTRY FOR LOG, LINE OR     46600022
*                                       LIST TYPE ENTRY                 46700022
         BNZ   TERMERR                  BRANCH IF ANY OF ABOVE          46800022
         SPACE 1                                                        46900022
*********************************************************************** 47000022
*        CHECK FOR CLOSED DCB IF PROCESS ENTRY SPECIFIED              * 47100022
*********************************************************************** 47200022
         SPACE 1                                                        47300022
         TM    TRMSTATE,TRMPROC         IS THIS A PROCESS ENTRY         47400022
         BNO   CHKHELD                  BRANCH IF NOT                   47500022
         L     RONE,QCBDCBAD-1          GET DCB ADDRESS                 47700022
         CLI   TRMSTAT+1,AVTEZERO       IS DCB OPEN?            SA70211 48000056
         BNE   PROCERR                  BR YES, DCB FOR SPECI-  SA70211 48300056
*                                       FIED PROCESS ENTRY MUST BE      48600022
*                                       CLOSED                          48900022
         B     CHKQTYPE                 CONTINUE CHECKING               49200022
CHKHELD  EQU   *                                                        49500022
         TM    TRMSTATE,TRMHELDN        IS TERMINAL HELD                49800022
         BO    TERMERR                  BRANCH IF YES                   50100022
         SPACE 2                                                        50400022
*********************************************************************** 50700022
*              CHECK FOR ERRORS REGARDING QUEUING MEDIUM              * 51000022
*********************************************************************** 51300022
CHKQTYPE EQU   *                                                        51600022
         TM    QCBFLAG,QCBPROC+QCBTERMQ CHECK FOR Q BY TERMINAL OR      51900022
*                                       PROCESS ENTRY                   52200022
         BZ    QERR                     BRANCH IF NEITHER               52500022
CHKPRI   EQU   *                                                        52800022
         TM    QCBPRIPQ,AVTEFF          DOES THIS QUEUE USE PRIORITY    53100022
*                                       LEVEL QUEUING                   53400022
         BNZ   QERR                     BRANCH IF YES                   53700022
CHKDISK  EQU   *                                                        54000022
         TM    QCBDSFLG,QCBDISK         DOES TERMINAL USE DISK QUEUES   54300022
         BZ    QERR                     BRANCH IF NO                    54600022
         TM    QCBDSFLG,QCBDRQQ         IS THIS A CONC DATA READY Q     54700022
         BO    QERR                     BRANCH IF YES                   54800022
CHKMSGS  EQU   *                                                        54900022
         L     RONE,QCBQBACK-1          GET POINTER TO LAST MSG QUEUED  55200022
         LA    RONE,ZERO(RONE)          CLEAR HIGH ORDER BYTE           55500022
         LTR   RONE,RONE                IS QUEUE EMPTY                  55800022
         BZ    QERR                     BRANCH IF YES                   56100022
         SPACE 2                                                        56400022
*********************************************************************** 56700022
*                  CHECK FOR SEQUENCE NUMBER ERRORS                   * 57000022
*********************************************************************** 57300022
CHKSEQ   EQU   *                                                        57600022
         LH    RSEQ,8(,RWORKB)                                          57900022
         LTR   RSEQ,RSEQ                IS REQUESTED NUMBER ZERO        58200022
         BZ    SEQERR                   BRANCH IF YES                   58500022
         STH   RSEQ,GWAELEM+TEN         AND STORE IN SPECIAL ELEMENT    58800022
         LH    RPARM2,TRMOUTSQ          GET NEXT SEQ OUT NUMBER         59100022
         BCTR  RPARM2,0                 DECREMENT BY 1                  59400022
         CR    RSEQ,RPARM2              IS REQUESTED SEQ NUMBER LESS    59700022
*                                       THAN LAST OUTPUT NUMBER RECVD   60000022
*                                       AT THE TERMINAL                 60300022
         BH    SEQERR                   BRANCH IF NO                    60600022
CHKMAX   EQU   *                                                        60900022
         LA    RPARM2,ONE(RPARM2)       ADJUST FOR NEXT COMPARE         61000022
         L     RONE,FOUR(,RWORKA)       GET THE VALUE OF THE MAX BY     61200022
*                                       WHICH QUEUE CAN BE BACKED UP    61500022
         SR    RPARM2,RSEQ              FIND THE DIFFERENCE BETWEEN     61800022
*                                       LAST OUT SEQ NUMBER AND THE     62100022
*                                       REQUESTED SEQ NUMBER            62400022
         CR    RPARM2,RONE              IS THE DIFFERENCE GREATER THAN  62700022
*                                       MAX ALLOWED                     63000022
         BH    SEQERR                   BRANCH IF YES                   63300022
         SPACE 2                                                        63600022
**********************************************************************  63900022
*                  SET UP SPECIAL ELEMENT PARAMETERS                  * 64200022
**********************************************************************  64500022
         L     RWORKA,ZERO(RPEWA)       GET ADDRESS OF IEDQGQ AND       64800022
         ST    RWORKA,GWAELEM           STORE IT                        65100022
         MVI   GWAELEM+FOUR,PRIRTBFR    SET UP PRIORITY                 65400022
         XC    GWAELEM+FIVE(THREE),GWAELEM+FIVE   CLEAR LINK FIELD      65700022
         LA    RWORKA,GRECB                                             66000022
         ST    RWORKA,GWAELEM+16        PUT ECB ADDR IN ELEM            66300022
         SPACE 2                                                        66600022
**********************************************************************  66900022
*        BUILD AQCTL LIST TO POST SPECIAL ELEMENT TO IEDQGQ           * 67200022
**********************************************************************  67500022
         LA    RZERO,GWAELEM            GET SPECIAL ELEMENT ADDRESS     67800022
         LA    RONE,FOUR(RPEWA)         GET ADDRESS OF TARGET FIELD     68100022
*                                       IN IEDQGQ'S WORK AREA           68400022
         LA    RPARM2,SPELLEN           GET LENGTH OF SPECIAL ELEMENT   68700022
         STM   RZERO,RPARM2,GWALIST     FILL IN AQCTL'S PARAMETER LIST  69000022
         MVI   GWALIST,ACTCODE          SET AQCTL ACTION CODE           69300022
         LA    RONE,GWALIST             SET PARM REGISTER FOR AQCTL     69600022
         SVC   102                                                      69900022
         WAIT  ECB=GRECB                                                70200022
         XC    GRECB(FOUR),GRECB        CLEAR ECB                       70500022
         L     R15,RETELEM              PICK UP RETURN CODE             70800022
         B     TABLE(R15)               CHECK FOR ERRORS                71100022
         SPACE 1                                                        71400022
*********************************************************************** 71700022
*             ACT ON RETURN CODES FROM IEDQGQ AND EXIT                * 72000022
*********************************************************************** 72300022
         SPACE 1                                                        72600022
TABLE    EQU   *                                                        72900022
         B     LEAVE                    NO ERRORS                       72950022
         B     NOTALL                   NOT ALL MESSAGES COULD BE       73000022
*                                       MARKED UNSERVICED               73050022
         B     NOTALL                   REUSABILITY IS ACTIVE ON        73100022
*                                       THIS QUEUE                      73150022
         B     SEQERR                   REQUESTED SEQ NUM HAS NOT YET   73200022
*                                       BEEN SERVICED                   73250022
ABORTQR  EQU   *                        FUNCTION ABORTED BECAUSE ONE    73300022
*                                       OF REQUESTED MSGS IS NOT AVAIL- 73350022
*                                       ABLE DUE TO REUS DISK REORG     73400022
         LA    R15,28                   SET RETURN CODE                 73450022
NOTALL   EQU   *                                                        74100022
         LH    RWORKA,RETMSGS           GET NUMBER OF MSGS UNSERVICED   74500022
         L     RWORKB,MYSAVE+FOUR       GET POINTER TO CALLERS SAVE     75000022
         ST    RWORKA,X1C(RWORKB)       STORE IN USER'S REG 2           75300022
         B     LEAVE                    EXIT                            75600022
SEQERR   EQU   *                                                        75900022
         LA    R15,12                   SET ERROR CODE                  76200022
         B       LEAVE                  EXIT                            76500022
PROCERR  EQU   *                                                        77700022
         LA    R15,16                                                   78000022
         B     LEAVE                    EXIT                            78300022
TERMERR  EQU   *                                                        78600022
         LA    R15,20                   SET RETURN CODE                 78900022
         B     LEAVE                    EXIT                            79200022
QERR     EQU   *                                                        79500022
         LA    R15,24                   SET RETURN CODE                 79800022
         B     LEAVE                    EXIT                            80100022
LEAVE    EQU   *                                                        81000022
         L     RSAVE,MYSAVE+FOUR        RESTORE CALLER'S SAVE AREA PTR  81300022
         RETURN  (14,12),RC=(15)                                        81600022
         SPACE 5                                                        81900022
**********************************************************************  82200022
*                  EQUATES AND CONSTANTS                                82500022
**********************************************************************  82800022
MYSAVE   DC    18F'0'                   MY SAVE AREA                    83100022
GRECB    DC    F'0'                     ECB FOR POST FROM IEDQGQ        83400022
RETELEM  DC    F'0'                     CONTAINS RETURN CODE PASSED BY  83700022
*                                       IEDQGQ                          84000022
RETMSGS  DC    H'0'                     CONTAINS NUMBER OF MESSAGES     84300022
*                                       MARKED UNSERVICED               84600022
         DS    0H                                                       84900022
SPELLEN  DC    H'0020'                  SPECIAL ELEMENT LENGTH          85200022
X1C      EQU   X'1C'                    OFFSET FROM USER'S SAVE AREA    85500022
*                                       TO HIS REGISTER 2               85800022
DCBOFLG  EQU   48                       DCB OFFSET TO DCBOFLGS          86400022
OPEN     EQU   X'10'                                                    86700022
ZERO     EQU   0                                                        87000022
ONE      EQU   1                                                        87300022
TWO      EQU   2                                                        87600022
THREE    EQU   3                                                        87900022
FOUR     EQU   4                                                        88200022
FIVE     EQU   5                                                        88500022
SIX      EQU   6                                                        88800022
EIGHT    EQU   8                                                        89100022
NINE     EQU   9                                                        89400022
X30      EQU   48                       OFFSET TO DCB OPEN FLAGS        89700022
ACTCODE  EQU   X'0C'                    SVC 102 ACTION CODE             90000022
TEN      EQU   10                                                       90300022
CVTADD   EQU   16                       ABSOLUTE ADDRESS OF CVT         90600022
PRIRTBFR EQU   X'D4'                    RETRIEVE REQUEST PRIORITY       90900022
LGLNLST  EQU   X'C0'                    MASK FOR ALL BUT PROCESS OR     91000022
*                                       TERMINAL ENTRY                  91100022
**********************************************************************  91200022
*                          DESECTS                                    * 91500022
**********************************************************************  91800022
         TDEBAPD                                                        92100022
         DCBD  DSORG=PS                                                 92400022
         TAVTD                                                          92700022
         TQCBD                                                          93000022
         TACSMD                                                         93300022
         TPEWAD                                                         93600022
         TTRMD                                                          93900022
         TDISPD                                                         94200022
         END                                                            94500022
