HG   TITLE '''IEDQHG'' - TIME DELAY SUBTASK'                            00100020
IEDQHG   CSECT                                                          00200020
         SPACE 3                                                        00210005
*  CHANGE ACTIVITY AS FOLLOWS                                           00220005
******************** MICROFICHE FLAGS *********************** SUPT CODE 00230005
*C226000                                                         A41021 00250005
*D339200-339800                                                  A41021 00250105
*C226000,421000                                                  S22025 00250205
*C225000                                                         S22025 00250305
*C225000                                                        S21903  00250405
*C410400-410600                                                 SA62950 00250505
*A248000                                                        SA70674 00250656
         SPACE 3                                                        00300005
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00400020
*                                                                     * 00500020
*TITLE   'IEDQHG' - TIME DELAY SUBTASK                                * 00600020
*                                                                     * 00700020
*  MODULE NAME = IEDQHG                                               * 00800005
*                                                                     * 00810005
*  DESCRIPTIVE NAME = TIME DELAY SUBTASK                              * 00820005
*                                                                     * 00830005
*  COPYRIGHT = 'NONE'                                                 * 00840005
*                                                                     * 00850005
*  STATUS:  CHANGE LEVEL 4                                            * 00860005
*                                                                     * 00900020
*FUNCTION -- THIS SUBTASK RECEIVES ELEMENTS, EACH REQUESTING          * 01000020
*   NOTIFICATION UPON COMPLETION OF A SPECIFIED TIME INTERVAL.        * 01100020
*   THESE ELEMENTS ARE MAINTAINED ON A QUEUE FROM WHICH THEY MAY      * 01200020
*   BE REMOVED UPON A SUBSEQUENT REQUEST.                             * 01300020
*                                                                     * 01400020
*ENTRY POINTS -- THERE ARE FOUR ENTRY POINTS -                        * 01500020
*        'IEDQHG' - THE SUBTASK IS ACTIVATED WHEN AN ELEMENT IS       * 01600020
*   POSTED TO THE TIME DELAY QCB, ORDERS THEM ON THE TIME DELAY       * 01700020
*   QUEUE, AND ISSUES STIMER MACRO TO REQUEST INTERRUPT WHEN THE      * 01800020
*   TIME INTERVAL ON THE FIRST ELEMENT HAS ELAPSED.  UPON RECEIVING   * 01900020
*   THE TIME ELAPSED INTERRUPT, THIS ROUTINE IS ALSO POSTED BY THE    * 02000020
*   STIMER EXIT ROUTINE TO REMOVE THE ELAPSED ELEMENT FROM            * 02100020
*   THE TIME QUEUE, POST THE ELEMENT BACK TO THE INDICATED QCB TO     * 02200020
*   SIGNIFY TO THE REQUESTOR THAT THE INTERVAL HAS ELAPSED, AND       * 02300020
*   ISSUES STIMER ON THE NEXT ELEMENT ON THE TIME DELAY QUEUE.  THIS  * 02400020
*   ENTRY IS USED BY ATTACHED TASKS.                                  * 02500020
*        'IEDQHG01' - TCAM SUBTASKS MAY ALSO HAVE ELEMENTS PUT ON     * 02600020
*   THE TIME DELAY QUEUE BY MEANS OF A 'BALR' TO THIS ENTRY.          * 02700020
*        'IEDQHG02' - TCAM SUBTASKS MAY REQUEST THE REMOVAL OF AN     * 02800020
*   ELEMENT BY MEANS OF A 'BALR' TO THIS ENTRY.                       * 02900020
*        'IEDQHG03' - ATTACHED TASKS MAY REQUEST THE REMOVAL OF AN    * 03000020
*   ELEMENT BY POSTING ANOTHER ELEMENT TO THIS SUBTASK.               * 03100020
*                                                                     * 03200020
*INPUT -- THE INPUT VARIES ACCORDING TO THE ENTRY POINT -             * 03300020
*   'IEDQHG' - A TIME DELAY REQUEST ELEMENT IS POSTED TO THE TIME     * 03400020
*   DELAY SUBTASK QCB.  THE REQUEST ELEMENT IS FORMATTED AS -         * 03500020
*                                                                     * 03600020
*        BYTE 0 - ADDRESS OF TIME DELAY QCB IN AVT          4 BYTES   * 03700020
*        BYTE 4 - PRIORITY                                  1 BYTE    * 03800020
*        BYTE 5 - LINK FIELD, USED BY DISPATCHER            3 BYTES   * 03900020
*        BYTE 8 - UNDEFINED                                 8 BYTES   * 04000020
*        BYTE 16- NUMBER OF SECONDS OF TIME INTERVAL WANTED 2 BYTES   * 04100020
*        BYTE 18- OFFSET INTO ELEMENT OF WORD WHOSE LOW               * 04200020
*          ORDER 3 BYTES IS THE ADDRESS OF THE QCB TO WHICH           * 04300020
*          THIS ELEMENT IS TO BE POSTED UPON COMPLETION OF            * 04400020
*          THE TIME DELAY INTERVAL.                         1 BYTE    * 04500020
*            X'00' - TIME DELAY REQUEST ELEMENT IS A QCB              * 04600020
*            X'14' - TIME DELAY REQUEST ELEMENT IS AN LCB             * 04700020
*            X'08' - OTHERS (SPECIAL ELEMENTS, BUFFERS, CHECKPOINT)   * 04800020
*        BYTE 19-UNDEFINED                                  4 BYTES   * 04900020
*        BYTE 23-FLAG BYTE, ONLY ONE BIT DEFINED, X'02'     1 BYTE    * 05000020
*            BIT ON- ELEMENT IS IN TIME DELAY Q                       * 05100020
*            BIT OFF- ELEMENT IS NOT IN QUEUE                         * 05200020
*          THIS BIT IS FLIPPED FOR ALL ELEMENTS ON TIME DELAY Q,      * 05300020
*          HOWEVER, IT MAY BE CHECKED FOR IN ONLY THE LCB OR QCB      * 05400020
*          AND CHECKPOINT WHERE THE BIT IS DEDICATED TO THIS          * 05500020
*          PURPOSE.  IN OTHER ELEMENTS, THIS FIELD HAS OTHER          * 05600020
*          DEFINITIONS.  USERS OF THESE OTHER ELEMENTS MUST TAKE      * 05700020
*          PRECAUTIONS TO PRESERVE THE STATUS OF THIS BIT IF          * 05800020
*          SUCH INFORMATION IS NEEDED TO BE KEPT AND THEN RESTORED    * 05900020
*          WHEN THE ELEMENT LEAVES THE TIME DELAY QUEUE.              * 06000020
*        BYTE 24- UNDEFINED                                 5 BYTES   * 06100020
*        BYTE 29- LINK FIELD TO CHAIN ELEMENTS ON TIME DELAY          * 06200020
*          QUEUE                                            3 BYTES   * 06300020
*   THIS ELEMENT IS ALSO TO HAVE A 3 BYTE ADDRESS OF THE QCB TO       * 06400020
*   WHICH THIS ELEMENT IS TO BE RETURNED UPON COMPLETION OF THE TIME  * 06500020
*   INTERVAL.  THE WORD CONTAINING THIS QCB ADDRESS IS LOCATED        * 06600020
*   ACCORDING TO TH SET VALUE OF BYTE 18, THE OFFSET, WHICH IS        * 06700020
*   UNIQUE DEPENDING ON THE TYPE OF ELEMENT BEING SENT TO TIME DELAY. * 06800020
*                                                                     * 06900020
*   NOTE THE PRESENCE OF TWO LINK FIELDS - DISPATCHER'S AND TIME      * 07000020
*   DELAY'S.  ONCE AN ELEMENT IS ON THE TIME DELAY Q, IT MAY ALSO     * 07100020
*   BE POSTED TO ANOTHER SUBTASK.                                     * 07200020
*                                                                     * 07300020
*   'IEDQHG01' - CALLED BY MEANS OF 'BALR' FROM TCAM SUBTASKS.        * 07400020
*   R14 - RETURN ADDRESS                                              * 07500020
*   R13 - ANY STANDARD SAVEAREA                                       * 07600020
*   R1  - THE ADDRESS OF A TIME DELAY REQUEST ELEMENT (DESCRIBED      * 07700020
*        ABOVE--FIRST TWO WORDS NOT NEEDED) TO BE ADDED TO TIME Q     * 07800020
*        ELEMENT NEEDS -                                              * 07900020
*          NUMBER OF SECONDS OF INTERVAL                              * 08000020
*          ADDRESS OF QCB TO BE POSTED WHEN INTERVAL HAS ELAPSED      * 08100020
*          OFFSET TO QCB ADDRESS WORD                                 * 08200020
*   R15 - ENTRY POINT OF 'IEDQHG01', WHOSE VCON IS IN AVT             * 08300020
*                                                                     * 08400020
*   TO REMOVE AN ELEMENT FROM THE TIME DELAY QUEUE WITHOUT WAITING    * 08500020
*   FOR THE INDICATED TIME INTERVAL, THERE ARE TWO ENTRY POINTS.      * 08600020
*                                                                     * 08700020
*   IF THE INDICATED ELEMENT IS NOT ON THE TIME QUEUE, NO ACTION.     * 08800020
*                                                                     * 08900020
*   'IEDQHG02' - CALLED BY MEANS OF A 'BALR' FROM TCAM SUBTASKS.      * 09000020
*   R14 - RETURN ADDRESS                                              * 09100020
*   R13 - ANY STANDARD SAVEAREA                                       * 09200020
*   R1  - ADDRESS OF THE ELEMENT TO BE REMOVED FROM TIME DELAY Q      * 09300020
*   R15 - ENTRY POINT OF 'IEDQHG02', WHOSE VCON IS IN AVT             * 09400020
*                                                                     * 09500020
*   'IEDQHG03' - A SUBTASK USED BY ATTACHED TASKS TO REMOVE AN        * 09600020
*   ELEMENT FROM THE TIME DELAY QUEUE.  A SPECIAL 'DELETE FROM TIME   * 09700020
*   Q ELEMENT' IS POSTED TO THE REMOVE ELEMENT FROM TIME Q QCB.       * 09800020
*                                                                     * 09900020
*   FORMAT OF 'DELETE FROM TIME QUEUE ELEMENT'                        * 10000020
*        BYTE 0 - UNDEFINED                                 1 BYTE    * 10100020
*        BYTE 1 - ADDRESS OF DELETE FROM TIME Q QCB (IN AVT)3BYTES    * 10200020
*        BYTE 4 - PRIORITY                                  1 BYTE    * 10300020
*        BYTE 5 - LINK, USED BY DISPATCHER                  3 BYTES   * 10400020
*        BYTE 8 - UNDEFINED                                 1 BYTE    * 10500020
*        BYTE 9 - ADDRESS OF ELEMENT TO BE REMOVED FROM     3 BYTES   * 10600020
*          TIME DELAY QUEUE, IF ELEMENT IS ON THAT Q                  * 10700020
*        BYTE 12- UNDEFINED                                 1 BYTE    * 10800020
*        BYTE 13- ADDRESS OF QCB TO WHOM THIS DELETE ELEMENT          * 10900020
*          IS TO BE POSTED AFTER REQUEST IS SERVICED        3 BYTES   * 11000020
*   (WHEN ELE IS AN LCB, THIS ADDRESS IS NOT NEEDED. SINCE IT IS      * 11100020
*   UNDERSTOOD AN LCB IS ALWAYS POSTED TO ITSELF.)                    * 11200020
*                                                                     * 11300020
*OUTPUT -- WHEN THE INDICATED TIME INTERVAL HAS ELAPSED, THE          * 11400020
*   TIME DELAY REQUEST ELEMENT IS POSTED TO THE QCB WHOSE ADDRESS     * 11500020
*   IS POINTED TO BY THE OFFSET BYTE OF THE ELEMENT.                  * 11600020
*                                                                     * 11700020
*   WHEN AN ELEMENT IS REQUESTED TO BE REMOVED FROM THE TIME QUEUE,   * 11800020
*   IT IS SEARCHED FOR ON THE QUEUE, AND IF FOUND, REMOVED.  IF       * 11900020
*   REQUEST WAS MADE TO 'IEDQHG03', THE DELETE REQUESTING ELEMENT     * 12000020
*   IS POSTED BACK TO THE INDICATED QCB.  IF 'IEDQHG02' WAS USED,     * 12100020
*   RETURN IS MADE TO ADDRESS IN REGISTER 14.                         * 12200020
*                                                                     * 12300020
*   WHEN EITHER OF THE 'BALR' ENTRIES ARE USED, ALL CALLER'S          * 12400020
*   REGISTERS ARE PRESERVED, USING SAVEAREA IN REGISTER 13.           * 12500020
*                                                                     * 12600020
*EXTERNAL ROUTINES -- SUPERVISOR CALLS ARE MADE WITH THREE MACROS -   * 12700020
*   'STIMER' - SVC 47, REQUEST TIME DELAY                             * 12800020
*   'TIME' - SVC 11, GET CURRENT TIME OF DAY                          * 12900020
*   'AQCTL' - SVC 102, TPOST TIME QCB TO ITSELF WHEN TIME ELAPSES     * 13000020
*                                                                     * 13100020
*EXITS-NORMAL -- BOTH SUBTASKS EXIT TO THE DISPATCHER, BOTH 'BALR'    * 13200020
*   ROUTINES RETURN TO THE ADDRESS IN R14, ALL REGISTERS INTACT.      * 13300020
*   NO RETURN CODE IS PASSED IN R15.                                  * 13400020
*                                                                     * 13500020
*EXITS-ERROR -- N/A                                                   * 13600020
*                                                                     * 13700020
*TABLES/WORK AREAS -- THE AVT HAS BOTH TIME DELAY QCBS, ENQUEUE       * 13800020
*   AND DELETE FUNCTIONS, THE AQCTL POST ELEMENT.  BOTH TIME DELAY    * 13900020
*   REQUEST AND DELETE REQUEST ELEMENTS MUST NOT BE STORAGE           * 14000020
*   PROTECTED FROM TCAM SUBTASKS.                                     * 14100020
*                                                                     * 14200020
*ATTRIBUTES -- NON-REFRESHABLE, REUSABLE, RESIDENT, PROBLEM           * 14300020
*   PROGRAM MODE.                                                     * 14400020
*                                                                     * 14500020
*NOTES -- THE 'STIMER' MACRO REQUIRES A USER EXIT TO RECEIVE          * 14600020
*   CONTROL UPON COMPLETION OF THE REQUESTED TIME INTERVAL.  THIS     * 14700020
*   ROUTINE IS ALSO PART OF THIS MODULE.  (SEE TAG 'TIMEEXIT').       * 14800020
*   THIS ROUTINE GETS CONTROL AS A RESULT OF A TIME INTERVAL INTER-   * 14900020
*   RUPT, USES AQCTL (SVC 102) TO POST THE TIME DELAY QCB TO ITSELF,  * 15000020
*   THEN RETURNS TO THE SUPERVISOR.  WHEN TIME DELAY SUBTASK RECEIVES * 15100020
*   ITS OWN QCB FROM THE DISPATCHER, HE KNOWS THIS IS NOT A REQUEST   * 15200020
*   TO ADD AN ELEMENT TO THE TIME QUEUE, BUT CHECKS THE QUEUE FOR     * 15300020
*   ELEMENTS WHOSE TIME HAS ELAPSED, IF ANY.                          * 15400020
*                                                                     * 15500020
*   MACROS USED IN THIS MODULE -                                      * 15600020
*        STIMER - SET INTERVAL TIMER                                  * 15700020
*        AQCTL - SVC 102, TPOST ELEMENT TO DISABLED READY QUEUE       * 15800020
*        RETURN - RESTORE REGISTERS AND EXIT TO CALLER                * 15900020
*        TIME - GET TIME OF DAY NOW                                   * 16000020
*   REMAINING MACROS DEFINE TCAM DSECTS REFERENCED BY THIS MODULE.    * 16100020
*        TDISPD                                                       * 16200020
*        TTCBD                                                        * 16300020
*        TLCBD                                                        * 16400020
*        TQCBD                                                        * 16500020
*        TAVTD                                                        * 16600020
*                                                                     * 16700020
*   THIS MODULE IS OPTIONAL.  A 12 BYTE DUMMY 'IEDQHG' IS             * 16720020
*   GENERATED BY INTRO MACRO IF USER CODES 'FEATURE=(,,NOTIMER)'.     * 16740020
*                                                                     * 16760020
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    * 16800020
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            * 16900020
*                                                                     * 17000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 17100020
         EJECT                                                          17150005
*                                                                       17200020
R15      EQU   15                       ENTRY ADDRESS, TEMPORARY BASE   17300020
R14      EQU   14                       RETURN ADDRESS                  17400020
R13      EQU   13                       SAVEAREA ADDRESS                17500020
RAVT     EQU   13                       AVT DSECT BASE                  17600020
R12      EQU   12                                                       17700020
RBASE    EQU   12                       PROGRAM BASE                    17800020
R11      EQU   11                       DISPATCHER ENTRY ADDRESS        17900020
R10      EQU   10                                                       18000020
REXIT    EQU   10                       SWITCH DETERMINES TYPE OF EXIT  18100020
*                                         A(DSPDISP)  - DISPATCH        18200020
*                                         A(RETURN)   - BR 14           18300020
*                                         A(POSTEXIT) - POST            18400020
R9       EQU   9                        UNUSED                          18500020
R8       EQU   8                        HOLDS CALLER'S SAVEAREA ADDR    18600020
R7       EQU   7                        TIME INTERVAL - ODD             18700020
R6       EQU   6                        TIME INTERVAL - EVEN            18800020
RSPEC    EQU   6                        BASE OF SPECIAL ELEMENT         18900020
*                                         REQUESTING REMOVAL OF ELE     19000020
R5       EQU   5                                                        19100020
RTIME    EQU   5                        TIME OF DAY                     19200020
R4       EQU   4                                                        19300020
RELE     EQU   4                        TIME DELAY ELEMENT              19400020
R3       EQU   3                        TIME DELAY ELEMENT ON Q         19500020
R2       EQU   2                        TEMP REG                        19600020
R1       EQU   1                        INPUT PARAMETER                 19700020
R0       EQU   0                        EVEN REG FOR MULT OR DIVIDE     19800020
*                                                                       19900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 20000020
*                                                                       20100020
         USING IEDQTCB,R2                                               20200020
         USING IEDQDISP,R11                                             20300020
         USING IEDQAVTD,RAVT                                            20400020
         USING SPECELE,RSPEC                                            20500020
         USING ELEMENT,RELE                                             20600020
*                                                                       20800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 20900020
*                                                                       21000020
*                       ENTRY IEDQHG                                    21100020
*                                                                       21200020
* SUBTASK PUTS ENTRY ON TIME DELAY QUEUE AND REQUEST TIME INTERRUPT     21300020
*                                                                       21400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 21500020
*                                                                       21600020
         DC    AL1(DSPMCPL2),AL1(0)     IEDQHG STCB                     21700020
*                                                                       21800020
         USING *,R15                    TEMPORARY BASE                  21900020
         BAL   RBASE,TAG                SKIP CONSTANTS AND              22000020
*                                         SET PROGRAM BASE              22100020
         DROP  R15                      FORGET TEMPORARY                22200020
         USING *,RBASE                  ESTABLISH ADDRESSABILITY        22300020
BASE     EQU   *                                                        22400020
IEDQHG   IEDHJN                                                         22450005
TAG      DS    0H                                                       22800020
         BAL   REXIT,SET                PRESET REGS                     22900020
*                                                                       23000020
         LA    REXIT,DSPDISP            REQUEST EXIT TO DISPATCHER      23100020
*                                                                       23200020
* R1 HAS ADDRESS OF ELEMENT TO BE ADDED TO TIME DELAY QUEUE             23300020
*                                                                       23400020
ADDNEW   EQU   *                                                        23500020
         LA    RELE,0(,R1)              CLEAR HIGH BYTE                 23600020
         LR    R15,RELE                                                 23700020
         TIME  BIN                      GET TIME OF DAY INTO R0         23800020
*                                                                       23900020
         LR    R1,R0                    SHIFT TIME TO ODD REG           24000020
         M     R0,UNITSDAY              MULTIPLY BY UNITS/DAY           24100020
         D     R0,SECSX100              DIVIDE BY SEC/DAY * 100         24200020
         LR    RTIME,R1                 PRESERVE TIME OF DAY            24300020
         C     RELE,AVTDELYB            IS NEW ELE THE TIME DELAY       24400020
*                                         QCB ITSELF                    24500020
         BE    STIMER                     YES, A TIMER INTERRUPT        24600020
*                                           HAS OCCURRED                24700020
*                                         NO, ADD ELE TO TIME Q         24800020
         LA    R7,AVTCKELE              GET CHECKPOINT QCB ADDR SA70674 24807056
         CR    R7,RELE                  IS CKPT BEING POSTED    SA70674 24814056
         BNE   NOTCKP                   BRANCH IF NOT           SA70674 24821056
         NI    AVTCKELF,AVTEFF-AVTCPIPN TURN OFF CHECKPOINT     SA70674 24828056
*                                        IN PROGRESS            SA70674 24835056
         LR    R14,REXIT                SET RETURN ADDRESS      SA70674 24842056
         MVC   ELEPOST+1(3),ELESPEQ+1   SET POST ADDRESS        SA70674 24849056
         TM    AVTCKELF,AVTCRTLN        HAS ANOTHER CHECKPOINT  SA70674 24856056
*                                        BEEN REQUESTED         SA70674 24863056
         BE    POSTSUB                  YES,POST REQUEST FOR    SA70674 24870056
*                                        A NEW CHECKPOINT       SA70674 24877056
NOTCKP   EQU   *                                                SA70674 24884056
         LH    R7,ELETIME               GET NUMBER OF SECONDS OF TIME   24900020
*                                         INTERVAL FROM NEW ELEMENT     25000020
*                                         INTO ODD REG                  25100020
         N     R7,AVTCLRHI              FORCE POSITIVE                  25200020
         M     R6,UNITSDAY              MULTIPLY SEC * UNITS/DAY        25300020
         D     R6,SECPRDAY              DIVIDE BY SEC/DAY TO GET UNITS  25400020
         LTR   R6,R7                    IS INTERVAL ZERO                25500020
         BNZ   TIME                       NO, HAVE NON-ZERO INTERVAL    25600020
*                                         YES, INTERVAL IS ZERO         25700020
         LA    R6,DEFAULT               FORCE INTERVAL TO POSITIVE      25800020
TIME     EQU   *                                                        25900020
*                                       TIME OF DAY IS IN R1            26000020
         STH   RTIME,AVTDELYB+(ELETIME-ELEMENT) SAVE TIME OF DAY IN     26100020
*                                         TIME QCB                      26200020
         XI    AVTDELYB+(ELETIME-ELEMENT),AVTE80 ESTABLISH REFERENCE    26300020
*                                         TIME 6 HOURS OFF CURRENT      26400020
*                                         TIME OF DAY                   26500020
         AR    R6,RTIME                 ADD TIME OF DAY TO INTERVAL     26600020
*                                         TO GET TIME OF INTERRUPT      26700020
         STH   R6,ELETIME               PUT INTERRUPT TIME BACK         26800020
*                                         INTO NEW ELEMENT              26900020
         CLI   ELEINDEX,ELELCB          IS ELE AN LCB                   27000020
         BNE   NOTLCB                     NO, NOT AN LCB                27100020
*                                         YES, IT IS AN LCB             27200020
         CLI   LCBRSKEY-IEDQLCB(RELE),DSPBUFSC IS LCB FOR BUFFERED      27460020
         BE    NOTLCB                   YES, SKIP POST BUF LCB          27490020
*                                         NO, NOT BUFFERED              27520020
LEASED   EQU   *                                                        27550020
         ST    RELE,ELEPOST             AN LCB IS TO BE POSTED          27600020
*                                         AS SOON AS RECEIVED BY        27700020
*                                         TIME DELAY                    27800020
         BAL   R14,POSTSUB              POST LCB TO ITSELF              27900020
NOTLCB   EQU   *                                                        28000020
         LA    R3,AVTDELYB              GET ADDRESS OF TIME QCB         28100020
*                                                                       28200020
TIMELOOP EQU   *                                                        28300020
         LR    R6,R3                    R6 HAS ADDR OF EITHER TIME      28400020
*                                         QCB (IF FIRST PASS), OR       28500020
*                                         PREVIOUS ELE ON TIME Q        28600020
*                                       TIME QCB LOOKS LIKE TIME ELE    28700020
         L     R3,ELELINK-1-ELEMENT(R6) GET ADDRESS OF NEXT ENTRY       28800020
         CLC   ELETIME,AVTDELYB+(ELETIME-ELEMENT) COMPARE CURRENT       28900020
*                                         ENTRY WITH REFERENCE TIME     29000020
         BNH   TIMESKIP                 BRANCH IF IN LATTER PORTION     29100020
*                                       CONTINUE IF IN EARLY PORTION    29200020
         CLC   ELETIME-ELEMENT(,R3),AVTDELYB+(ELETIME-ELEMENT)          29300020
*                                       COMPARE NEXT ENTRY ON QUEUE     29400020
*                                         WITH REFERENCE TIME           29500020
         BNH   TIMEINS                  BRANCH IF IN LATTER PORTION     29600020
*                                       CONTINUE IF IN EARLY PORTION    29700020
         B     TIMEADD                  BOTH NEW ELE AND OLD ELE ON     29800020
*                                         Q ARE IN EARLY PORTION        29900020
TIMESKIP EQU   *                        NEW ELE IS IN LATTER PORTION    30000020
         CLC   ELETIME-ELEMENT(,R3),AVTDELYB+(ELETIME-ELEMENT)          30100020
*                                       COMPARE NEXT ENTRY IN Q WITH    30200020
*                                         REFERENCE TIME                30300020
         BH    TIMELOOP                 BRANCH IF ENTRY IS IN EARLIER   30400020
*                                         PORTION, CONTINUE IF IT IS    30500020
*                                         IN LATTER PORTION ALSO        30600020
TIMEADD  EQU   *                        BOTH ENTRIES ARE IN SAME        30700020
*                                         PORTION                       30800020
         CLC   ELETIME,ELETIME-ELEMENT(R3) COMPARE CURRENT REQUEST      30900020
*                                         TO ENTRY IN Q                 31000020
         BH    TIMELOOP                 BRANCH IF CURRENT REQUEST IS    31100020
*                                         LATER, CONTINUE IF CURRENT    31200020
*                                         REQUEST IS EARLIER            31300020
TIMEINS  EQU   *                                                        31400020
         MVC   ELELINK,ELELINK-ELEMENT(R6) INSERT NEW ELEMENT AFTER     31500020
*                                         LAST ENTRY IN TIME QUEUE      31600020
         IC    R3,ELELINK-1-ELEMENT(R6) SAVE HIGH BYTE                  31700020
         ST    RELE,ELELINK-1-ELEMENT(R6) PUT ON NEW ELEMENT            31800020
         STC   R3,ELELINK-1-ELEMENT(R6) RESTORE HIGH BYTE               31900020
         OI    ELEBYTE,ELEBIT           MARK NEW ELE AS BEING ON        32000020
*                                         TIME DELAY Q                  32100020
STIMER   EQU   *                                                        32200020
         L     RELE,AVTDELYB+(ELELINK-1-ELEMENT) GET ADDR OF FIRST      32300020
*                                         ELEMENT ON CHAIN              32400020
         CLC   AVTDELYB+1(3),AVTDELYB+(ELELINK-ELEMENT) IS TIME QCB     32500020
*                                         ONLY ELE ON TIME Q            32600020
         BCR   EQUAL,REXIT                YES, QUIT                     32700020
*                                         NO, DO STIMER                 32800020
         LH    R6,ELETIME               GET INTERRUPT TIME FOR FIRST    32900020
*                                         ELEMENT ON TIME Q             33000020
         N     R6,AVTCLRHI              FORCE POSITIVE                  33100020
         SR    R6,RTIME                 SUBTRACT CURRENT TIME OF DAY    33200020
*                                         FROM TIME OF INTERRUPT        33300020
         SLL   R6,HALFWORD              SHIFT LOWER HALF TO UPPER HALF  33400020
         SRA   R6,HALFWORD              EXTEND SIGN BIT                 33500020
         BC    ZERORNEG,RESUME          BRANCH IF TIME HAS ALREADY      33600020
*                                         ELAPSED FOR FIRST ELEMENT     33700020
*                                       CONTINUE IF TIME INTERVAL       33800020
*                                         HAS NOT ELAPSED AND DO STIMER 33900020
         LR    R7,R6                    MOVE INTERVAL TO ODD REG        34000020
         M     R6,SECSX100              MULTIPLY BY SECS/DAY * 100      34100020
         D     R6,UNITSDAY              DIVIDE BY UNITS/DAY             34200020
         ST    R7,AVTDELYB+12           SET INTERVAL INTO TIME QCB      34300020
         LA    R1,AVTDELYB+12             FOR STIMER                    34400020
         LR    R15,RELE                                                 34500020
         STIMER REAL,TIMEEXIT,BINTVL=(1) REQUEST TIMER INTERRUPT       *34600020
                                          AT END OF TIME INTERVAL       34700020
*                                                                       34800020
         ST    RELE,STIMADDR            REMEMBER WHAT ELE GOT STIMER    34850020
         BR    REXIT                    END OF ROUTINE                  34900020
*                                                                       35000020
RESUME   EQU   *                        TIME HAS ELAPSED FOR FIRST      35100020
*                                         ELEMENT ON TIME Q             35200020
         MVI   STIMADDR,AVTEFF          MARK TO INDICATE NO STIMER      35230020
*                                         STILL ACTIVE                  35260020
         MVC   AVTDELYB+ELELINK-ELEMENT(3),ELELINK DELINK 1ST ELE       35300020
*                                         FROM TIME DELAY QCB           35400020
         CLI   ELEINDEX,AVTEZERO        IS ELEMENT A QCB                35420020
         BE    QCB                        YES, ELE IS A QCB             35440020
*                                         NO, NOT A QCB                 35460020
         NI    ELEBYTE,X'FF'-ELEBIT     TURN OFF BIT-MARK ELE AS        35500020
*                                         NOT BEING ON TIME Q           35600020
         CLI   ELEINDEX,ELELCB          IS ELEMENT AN LCB               35700020
         BE    LCB                        YES, GOT LCB                  35800020
*                                         NO, ELE IS BUF OR SPECIAL     36200020
         MVC   ELEPOST+1(3),ELESPEQ+1   THIRD WORD OF BUF (OR SPECIAL   36300020
*                                         ELE) HAS QCB ADDR TO          36400020
*                                         RECEIVE ELE AT END OF TIME    36500020
         LA    R1,0(,RELE)              CLEAR HIGH BYTE OF ELE ADDR     36600020
         LA    R15,AVTCKELE             GET CKPOINT ELE ADDR            36700020
         CR    R1,R15                   IS CKPT BEING POSTED            36800020
         BNE   POST                       NO, SOMETHING ELSE            36900020
*                                         YES, POSTING CKPOINT          37000020
         OI    AVTCKELF,AVTCRTLN        MARK CKPT ELE AS 'POSTED'       37100020
POST     EQU   *                        RETURN ELEMENT TO ITS QCB       37200020
         BAL   R14,POSTSUB              POST ELE TO ITS QCB             37300020
*                                                                       37400020
         B     STIMER                   GO CHECK NEXT ELEMENT ON        37500020
*                                         TIME QUEUE                    37600020
QCB      EQU   *                                                        37700020
         TM    QCBSTAT-IEDQQCB(RELE),QCBTIME QCB NEED 12 MORE HOUR      37800020
         BO    TWELVE                     YES, REPOST IT TO TIME Q      37900020
*                                         NO, READY TO LEAVE TIME Q     38000020
         TM    QCBFLAG-IEDQQCB(RELE),QCBTSSES IS THIS A TSO QCB         38020020
         BNO   NOTTSO                     NO, NOTHING SPECIAL           38040020
*                                         YES, TSO NEEDS SPECIAL        38060020
         OI    QCBTSOF2-IEDQQCB(RELE),QCBPOSTO MARK QCB POSTED          38080020
         MVC   ELELINK(3),ELEPRI+1      TSO HAS SAVED DATA INTO         38100020
*                                         ELEPRI+1 FROM ELELINK         38200020
*                                         PRIOR TO PUTTING QCB          38300020
*                                         ON TIME DELAY. THIS           38400020
*                                         RESTORES TSO INFO             38500020
         NI    ELEBYTE,X'FF'-ELEBIT     MARK QCB AS NOT BEING ON        38507020
*                                         TIME DELAY Q                  38514020
*                                                                       38521020
* TO AVOID DISABLED-ENABLED INTERFACE CONFUSION, THIS ELEBIT BIT        38528020
* MUST BE TURNED OFF AFTER THE QCBPOSTO BIT IS SET.                     38535020
*                                                                       38542020
         B     POST                     GO POST QCB                     38549020
*                                       TSO DOES NOT CHANGE THE         38556020
*                                         SCHEDULERS IN ITS QCBS        38563020
*                                                                       38570020
NOTTSO   EQU   *                                                        38577020
         NI    ELEBYTE,X'FF'-ELEBIT     TURN OFF BIT-MARK ELE AS        38584020
*                                         NOT BEING ON TIME Q           38591020
         LA    RELE,0(,RELE)            CLEAR HIGH BYTE                 38600020
         C     RELE,AVTHI               QCB COMING OFF TIME Q, IS IT    38700020
*                                         THE SYSTEM DELAY QCB          38800020
         BE    POST                       YES, SKIP MOVING SCHEDULERS   38900020
*                                           SINCE IT HAS NONE           39000020
*                                         NO, MUST BE DESTINATION QCB   39100020
         CLI   QCBSTVTO-IEDQQCB(RELE),DSPBUFSC IS QCB FOR BUF TERM      39200020
         BE    POST                       YES, SKIP MOVE SCHEDULER      39300020
*                                         NO, MOVE SCHEDULERS           39400020
         MVC   QCBSLINK-IEDQQCB(3,RELE),QCBSTCHN-IEDQQCB(RELE) MOVE     39500020
*                                       DESTINATION ASSIGNMENT DOWN     39600020
*                                         IN SUBTASK CHAIN              39700020
         LA    R14,QCBSTCHN-1-IEDQQCB(RELE) MOVE                        39800020
         IC    R0,QCBSTCHN-1-IEDQQCB(RELE)  THE                         39900020
         ST    R14,QCBSTCHN-1-IEDQQCB(RELE)   SCHEDULER                 40000020
         STC   R0,QCBSTCHN-1-IEDQQCB(RELE)                              40100020
         B     POST                     GO RETURN ELEMENT               40200020
*                                                                       40300020
TWELVE   EQU   *                                                        40400020
         NI    QCBSTAT-IEDQQCB(RELE),X'FF'-QCBTIME TURN OFF 12 HR REQ   40500020
         MVC   ELETIME(2),HOUR12        REQUEST 12 HOUR DELAY           40600020
         LR    R1,RELE                  PASS ADDR OF NEW ELE IN R1      40700020
         B     ADDNEW                   GO HANG QCB ONTO TIME Q         40800020
*                                                                       40900020
LCB      EQU   *                                                        41000020
         TM    LCBSTAT2-IEDQLCB(RELE),LCBDIAL IS IT A DIAL LCB          41010020
         BO    LEASLCB                    YES, DIAL LCB, GO MOVE        41016020
*                                           SCHEDULER AS IF LEASED      41022020
*                                         NO, NOT DIAL                  41030020
         CLI   LCBRSKEY-IEDQLCB(RELE),DSPBUFSC BUFFERED LINE    SA62950 41040005
         BE    NOMOVE                   YES, SKIP MOVE SCHEDULERSA62950 41050005
*                                       NO, LEASED LCB          SA62950 41060005
LEASLCB  EQU   *                                                        41070020
         LA    R7,LCBRSKEY-IEDQLCB(RELE) LINK RECEIVE SCHEDULER         41100020
         LR    R1,R7                      INTO THE STCB CHAIN           41200020
         BAL   R14,DSPPRIOR             MOVE SCHEDULER                  41300020
*                                                                       41400020
NOMOVE   EQU   *                                                        41600020
         TM    LCBSTAT1-IEDQLCB(RELE),LCBFREEN IS LCB FREE              41800020
         BZ    STIMER                     IF NOT FREE, FORGET IT, AND   41900020
*                                           GO CK NEXT ELE ON TIME Q    42000020
         XI    LCBSTAT1-IEDQLCB(RELE),LCBRECVN+LCBFREEN          S22025 42100022
*                                       MARK LCB NOT POSTABLE    S22025 42150022
POSTLCB  EQU   *                                                        42200020
         ST    RELE,ELEPOST               IF FREE, POST IT TO ITSELF    42300020
         B     POST                     GO POST LCB                     42400020
*                                                                       42500020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 42600020
*                                                                       42700020
*                       TIMER COMPLETION EXIT ROUTINE                   42800020
*                                                                       42900020
TIMEEXIT EQU   *                                                        43000020
         USING *,R15                    TEMPORARY BASE                  43080020
         STM   R1,R2,HISREG1(R13)       SAVE STIMER OS REGS             43160020
         L     R1,CVTPTR                GET CVT ADDR                    43240020
         L     R1,AVTCVTPT(,R1)         GET DISPATCHER ADDR FROM        43320020
*                                         TCAM WORD IN CVT              43400020
         LTR   R1,R1                    IS TCAM IN SYSTEM               43480020
         BZ    TIMERET                    NO, FORGET INTERRUPT          43560020
*                                         YES, CONTINUE                 43640020
         L     R1,0(,R1)                GET AVT ADDR FROM DISPATCHER    43720020
         L     R2,AVTTCB-IEDQAVTD+AVTSVSIZ(,R1) GET TCB ADDR FROM AVT   43800020
         TM    TCBFLGS,TCBENDED         IS TCAM TASK SHUT DOWN          43880020
         BC    MIXEDONE,TIMERET           YES, FORGET INTERRUPT         43960020
*                                         NO, CONTINUE                  44040020
         MVI   AVTDELYB-IEDQAVTD+QCBPRI-IEDQQCB+AVTSVSIZ(R1),PRITIME    44120020
*                                       SET PRIORITY TO TIME QCB        44200020
         XC    AVTDELYB-IEDQAVTD+QCBLINK-IEDQQCB+AVTSVSIZ(L'QCBLINK,R1)*44280020
               ,AVTDELYB-IEDQAVTD+QCBLINK-IEDQQCB+AVTSVSIZ(R1)          44360020
*                                       CLEAR ELEMENT LINK FIELD        44440020
         LA    R1,AVTIMQPS-IEDQAVTD+AVTSVSIZ(,R1) PASS SPEC ELE TO HAVE 44600020
         AQCTL                          TIME QCB POSTED TO ITSELF       44700020
TIMERET  EQU   *                                                        44800020
         LM    R1,R2,HISREG1(R13)       RESTORE OS REGS                 44900020
         BR    R14                      RETURN TO SUPERVISOR            45000020
*                                                                       45100020
         DROP  R15                      FORGET TEMPORARY BASE           45130020
*                                                                       45160020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 45200020
*                                                                       45300020
                        ENTRY IEDQHG01                                  45400020
*                                                                       45500020
* ADD ELEMENT TO TIME QUEUE, CALLED WITH 'BALR'                         45600020
*                                                                       45700020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 45800020
*                                                                       45900020
IEDQHG01 EQU   *                                                        46000020
         USING *,R15                    TEMPORARY BASE                  46100020
         STM   R14,R12,HISREG14(R13)    SAVE CALLER'S REGISTERS         46200020
         L     RBASE,ADBASE             SET ADDRESSABILITY              46300020
         DROP  R15                                                      46400020
         BAL   REXIT,SET                PRESET REGS                     46500020
*                                                                       46600020
         LA    REXIT,RETURN             REQUEST EXIT WITH RETURN        46700020
         B     ADDNEW                   GO ADD ELE TO TIME QUEUE        46800020
*                                                                       46900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 47000020
*                                                                       47100020
                        ENTRY IEDQHG03                                  47200020
*                                                                       47300020
* SUBTASK TO REMOVE ELEMENT FROM Q                                      47400020
*                                                                       47500020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 47600020
*                                                                       47700020
IEDQHG03 EQU   *                                                        47800020
         DC    AL1(DSPMCPL2),AL1(0)     IEDQHG03 STCB                   47900020
*                                                                       48000020
         USING *,R15                    TEMPORARY BASE                  48100020
         L     RBASE,ADBASE             ESTABLISH ADDRESSABILITY        48200020
         DROP  R15                                                      48300020
         BAL   REXIT,SET                PRESET REGISTERS                48400020
*                                                                       48500020
         LA    REXIT,POSTEXIT           REQUEST EXIT TO DSPPOST         48600020
         LR    RSPEC,R1                 SET BASE OF REMOVE ELEMENT      48700020
*                                         REQUESTING ELEMENT            48800020
         L     R1,SPECELEP              GET ADDR OF ELEMENT TO BE       48900020
*                                         REMOVED                       49000020
TAKEOFF  EQU   *                                                        49100020
         LA    R1,0(,R1)                CLEAR HIGH BYTE                 49200020
         LA    RELE,AVTDELYB            START WITH TIME QCB             49300020
*                                                                       49400020
LOOP     EQU   *                                                        49500020
         L     R2,ELELINK-1             GET NEXT ELEMENT ON Q           49600020
         LA    R2,0(,R2)                CLEAR HIGH BYTE                 49700020
         C     R2,AVTDELYB              IS ELE REALLY TIME QCB ITSELF   49800020
         BCR   EQUAL,REXIT                YES, DESIRED ELE IS NOT HERE  49900020
*                                         NO, IT IS A REAL ELEMENT      50000020
         CLR   R2,R1                    IS THIS THE DESIRED ELEMENT     50100020
         BE    REMOVEIT                   YES, TAKE IF OFF              50200020
*                                         NO, THIS IS NOT IT            50300020
         LR    RELE,R2                  BUMP TO NEXT ELE ON Q           50400020
         B     LOOP                     GO CHECK NEXT ELEMENT           50500020
*                                                                       50600020
REMOVEIT EQU   *                                                        50700020
         MVC   ELELINK,ELELINK-ELEMENT(R2) REMOVE ELEMENT FROM Q        50800020
         MVC   ELELINK-ELEMENT(3,R2),ELEPRI+1-ELEMENT(R2) TSO INFO      50850020
         NI    ELEBYTE-ELEMENT(R2),X'FF'-ELEBIT MARK ELE AS NOT ON      50900020
*                                         TIME QUEUE                    51000020
         C     R2,STIMADDR              IS ELE BEING REMOVED THE        51010020
*                                         ONE WITH ACTIVE STIMER        51020020
         BCR   NOTEQUAL,REXIT             NO, A DIFFERENT ONE, QUIT     51030020
*                                         YES, CONTINUE                 51040020
         MVI   STIMADDR,AVTEFF          MARK TO INDICATE NO STIMER      51050020
*                                         STILL ACTIVE                  51060020
         BR    REXIT                    QUIT                            51100020
*                                                                       51200020
POSTEXIT EQU   *                                                        51300020
         LR    R1,RSPEC                 PASS ELE TO BE POSTED           51400020
         MVC   SPECPOST+1-SPECELE(3,R1),SPECQCB+1-SPECELE(R1) SET       51500020
*                                         SPECIAL ELEMENT TO GO TO      51600020
*                                         SPECIFIED QCB                 51700020
         B     DSPPOST                  EXIT TO DISPATCHER              51800020
*                                                                       51900020
RETURN   EQU   *                                                        52000020
         LR    R13,R8                   RESTORE TO CALLER'S SAVEAREA    52100020
         LM    R14,R12,HISREG14(R13)    RESTORE CALLER'S REGISTERS      52160020
         BR    R14                      RETURN TO CALLER                52220020
*                                                                       52300020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 52400020
*                                                                       52500020
                        ENTRY IEDQHG02                                  52600020
*                                                                       52700020
* ROUTINE REMOVES ELEMENT FROM TIME Q, CALLED WITH 'BALR'               52800020
*                                                                       52900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 53000020
*                                                                       53100020
IEDQHG02 EQU   *                                                        53200020
         USING *,R15                    TEMPORARY BASE                  53300020
         STM   R14,R12,HISREG14(R13)    SAVE CALLER'S REGISTERS         53400020
         L     RBASE,ADBASE             ESTABLISH ADDRESSABILITY        53500020
         DROP  R15                                                      53600020
         BAL   REXIT,SET                PRESET REGS                     53700020
*                                                                       53800020
         LA    REXIT,RETURN             REQUEST EXIT WITH RETURN        53900020
         B     TAKEOFF                  REMOVE ELEMENT                  54000020
*                                                                       54100020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54200020
*                                                                       54300020
*                       SUBROUTINES                                     54400020
*                                                                       54500020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54600020
*                                                                       54700020
SET      EQU   *                                                        54800020
         LR    R8,R13                   SAVE CALLER'S SAVEAREA          54900020
         L     RAVT,ADAVT               SET AVT DSECT BASE              55000020
         LA    R13,AVTSAVE2+AVTSVSIZ    SET R13 TO SAVE2 FOR DISPATCHER 55100020
         L     R11,AVTEA                SET DISPATCHER BASE             55200020
         BR    REXIT                    RETURN TO ENTRY POINT           55300020
*                                                                       55400020
POSTSUB  EQU   *                                                        55500020
         LR    R1,RELE                  PASS ELE TO BE POSTED           55600020
         B     DSPPOSTR                 POST ELEMENT                    56600020
*                                                                       56700020
*                                       RETURN ADDR IN R14 ALREADY      56800020
*                                         SET BY CALLER                 56900020
*                                                                       57000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 57100020
*                                                                       57200020
*                       CONSTANTS                                       57300020
*                                                                       57400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 57500020
*                                                                       57600020
CVTPTR   EQU   16                       WORD HAVING CVT ADDRESS         57700020
HISREG14 EQU   12                       OFFSET INTO SAVEAREA OF R14     57750020
HISREG1  EQU   24                       OFFSET INTO SAVEAREA OF R1      57800020
DEFAULT  EQU   1                        SUBSTITUTED FOR ZERO INTERVAL   57900020
HALFWORD EQU   16                       SHIFT COUNT FOR HALF WORD       58000020
ZERORNEG EQU   12                       CONDITION CODE FOR ZERO OR      58100020
*                                         NEG FOLLOWING SRA INSTR       58200020
MIXEDONE EQU   7                        CONDITION CODE, MIXED OR ONES   58400020
NOTEQUAL EQU   7                        CONDITION CODE, NOT EQUAL       58450020
EQUAL    EQU   8                        CONDITION CODE, EQUAL           58500020
*                                                                       58700020
HOUR12   DC    AL2((60*60*12)-1)        SECONDS IN 12 HOURS             58800020
ADAVT    DC    A(IEDQAVT)               SETS AVT DSECT BASE             58900020
         EXTRN IEDQAVT                                                  59000020
ADBASE   DC    A(BASE)                  SETS RBASE FOR ADDRESSABILITY   59100020
STIMADDR DC    X'FF',AL3(0)             ADDRESS OF LAST ELE TO          59110020
*                                         HAVE STIMER DONE              59120020
*                                           FIRST BYTE ---              59130020
*                                             X'FF'-NO STIMER ACTIVE    59140020
*                                             X'00'-STIMER ACTIVE       59150020
SECPRDAY DC    F'86400'                 SECONDS/DAY                     59200020
UNITSDAY DC    F'65536'                 UNITS PER DAY                   59300020
SECSX100 DC    F'8640000'               SEC/DAY * 100                   59400020
*                                                                       59600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 59700020
*                                                                       59800020
*                       DSECTS                                          59900020
*                                                                       60000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 60100020
*                                                                       60200020
SPECELE  DSECT                          ELEMENT REQUESTS REMOVAL OF     60300020
*                                         ELEMENT FROM TIME DELAY Q     60400020
SPECPOST DS    A                        ADDR OF QCB TO RECEIVE ELE      60500020
SPECLINK DS    A                        LINK FIELD                      60600020
SPECELEP DS    A                        ADDR OF ELE TO BE REMOVED       60700020
SPECQCB  DS    A                        ADDR OF QCB TO RECEIVE THIS     60800020
*                                         ELE WHEN SERVICE COMPLETE     60900020
*                                                                       61000020
*       DECHEX *********************************************            61100020
*        0  0  * SPECPOST                                  *            61200020
*              *********************************************            61300020
*        4  4  * SPECLINK                                  *            61400020
*              *********************************************            61500020
*        8  8  * SPECELEP                                  *            61600020
*              *********************************************            61700020
*        12 C  * SPECQCB                                   *            61800020
*              *********************************************            61900020
*                                                                       62000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 62100020
*                                                                       62200020
ELEMENT  DSECT                          TIME DELAY REQUEST ELEMENT      62300020
ELEPOST  DS    A                        ADDR OF TIME DELAY QCB          62400020
ELEPRI   DS    A                        DISPATCHER LINK FIELD           62500020
ELESPEQ  DS    A                        IF ELE IS BUF OR SPECIAL ELE,   62550020
*                                         ADDR OF QCB TO BE RETURNED TO 62600020
         DS    A                        UNUSED BY TIME DELAY            62650020
ELETIME  DS    H                        INTERVAL IN SECONDS             62700020
ELEINDEX DS    X                        OFFSET TO QCB ADDRESS TO RE-    62800020
*                                         CEIVE ELE WHEN TIME ELAPSES   62900020
*                                       ALSO TYPE ELEMENT IDENTIFIER    63000020
*                                         X'00' - QCB                   63100020
*                                         X'14' - LCB                   63200020
*                                         X'08' - OTHERS                63300020
ELELCB   EQU   X'14'                    OFFSET INTO LCB OF ADDR OF QCB  63400020
         DS    4X                       UNDEFINED                       63500020
ELEBYTE  DS    X                        FLAG BYTE, ONE BIT USED         63600020
ELEBIT   EQU   X'02'                    BIT ON, ELE ON TIME Q           63700020
*                                         BIT OFF, ELE NOT ON Q         63800020
*                                       BIT IS MEANINGFUL ON LCB        63900020
*                                         AND QCB ONLY                  64000020
         DS    5X                       UNDEFINED                       64100020
ELELINK  DS    AL3                      LINK FIELD OF ELEMENTS ON       64200020
*                                         TIME QUEUE                    64300020
*                                                                       64400020
*       DECHEX *********************************************            64500020
*        0  0  * ELEPOST                                   *            64600020
*              *********************************************            64700020
*        4  4  * ELEPRI   * (LINK FIELD)                   *            64800020
*              *********************************************            64900020
*        8  8  * ELESPEQ                                   *            65000020
*              *********************************************            65100020
*        12 C  * (UNUSED)                                  *            65200020
*              *********************************************            65300020
*        16 10 * ELETIME             * ELEINDEX * (UNUSED) *            65400020
*              *********************************************            65500020
*        20 14 * (UNUSED)                       * ELEBYTE  *            65600020
*              *********************************************            65700020
*        24 18 * (UNUSED)                                  *            65800020
*              *********************************************            65900020
*        28 1C * (UNUSED) * ELELINK                        *            66000020
*              *********************************************            66100020
*                                                                       66200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 66300020
         PRINT NOGEN                                                    66400020
         TDISPD                                                         66500020
         TPRIOR                                                         66600020
         TTCBD                                                          66700020
TCBENDED EQU   X'F7'                    IF ANY ONE OF THESE BITS        66800020
*                                         IN TCBFLGS IS ON, TASK        66900020
*                                         HAS TERMINATED                67000020
         TLCBD                                                          67100020
         TQCBD                                                          67200020
         TAVTD 2                                                        67300020
         END                                                            67400020
