HI    TITLE '''IEDQHI'' - SYSTEM DELAY SUBTASK'                         00200020
IEDQHI   CSECT                                                          00400020
*A212000,242000,366000,380000                                    S22025 00460022
*C304000                                                         S22025 00520022
*C303000,318000,796000                                           S22025 00560022
*C692000                                                        SA59011 00580022
*                                                                       00600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00800020
*                                                                     * 01000020
*TITLE   'IEDQHI' - SYSTEM DELAY SUBTASK                              * 01200020
*                                                                     * 01400020
*FUNCTION -- THIS SUBTASK CAUSES THE SYSTEM TO DELAY (REFERENCE,      * 01600020
*   INTRO MACRO, INTVAL=INTEGER) ACCORDING TO A SPECIFIED NUMBER      * 01800020
*   OF SECONDS BY HOLDING LCBS PASSED TO IT ON A DELAY Q UNTIL ALL    * 02000020
*   LCBS ARE THUS HELD, AT WHICH TIME A REQUEST FOR THE SPECIFIED     * 02200020
*   INTERVAL IS PASSED TO TIME DELAY.  AT END OF TIME INTERVAL,       * 02400020
*   THE LCBS ARE REMOVED FROM THE SYSDELAY Q AND EACH LCB IS POSTED   * 02600020
*   TO ITSELF TO ACTIVATE EACH LINE.                                  * 02800020
*                                                                     * 03000020
*ENTRY POINTS -- THERE IS ONLY ONE ENTRY POINT, CALLED BY DISPATCHER. * 03200020
*        'IEDQHI' - ACTIVATED BY OPERATOR CONTROL WHEN IT RECEIVES    * 03400020
*   A REQUEST FOR A SYSTEM DELAY.                                     * 03600020
*                                                                     * 03800020
*INPUT -- WHEN CALLED FROM THE DISPATCHER, R13 MUST HAVE THE ADDRESS  * 04000020
*   OF AVTSAVE2, R1 HAS THE ADDRESS OF AN ELEMENT, AND R7 HAS THE     * 04200020
*   ADDRESS OF THE SYSDELAY QCB.                                      * 04400020
*                                                                     * 04600020
*   THERE ARE 3 TYPES OF ELEMENTS PASSED IN R1. --                    * 04800020
*                                                                     * 05000020
*   IF PRIORITY FIELD IS 'PRISYSDL' (REFERENCE, TPRIOR MACRO), THE    * 05200020
*   ELEMENT IS THE SYSTEM DELAY REQUEST ELEMENT (WHICH IS ACTUALLY    * 05400020
*   IN THE OPERATOR COLTROL 'LITTLE AVT').  NO OTHER ELEMENT          * 05600020
*   BEING PASSED TO THIS SUBTASK MAY HAVE THIS PRIORITY.              * 05800020
*                                                                     * 06000020
*   THE ELEMENT IN R1 MAY BE THE SYSTEM DELAY QCB.  THIS WAS          * 06200020
*   ORIGINALLY POSTED BY SYSDELAY TO THE TIME Q TO INITIATE TIMING    * 06400020
*   OF THE SYSTEM INTERVAL.  WHEN THE TIME HAS ELAPSED, TIME DELAY    * 06600020
*   POSTS THE SYSTEM DELAY QCB BACK TO SYSTEM DELAY.  WHEN THIS QCB   * 06800020
*   IS RECEIVED, THE LCBS ARE TO BE ACTIVATED.                        * 07000020
*                                                                     * 07200020
*   THE ELEMENT IN R1 MAY BE A SINGLE LCB.  THIS LCB MUST HAVE        * 07400020
*   BEEN ACTIVE WHEN THE ORIGINAL REQUEST FOR SYSTEM DELAY CAME IN.   * 07600020
*   RECEIVE SCHEDULER POSTS THIS LCB TO SYSDELAY WHEN IT FINDS        * 07800020
*   THE SYSDELAY BIT ON (AVTBIT1,AVTDLAYN) TO HAVE THE LINE SHUT      * 08000020
*   DOWN AND THE LCB KEPT ON THE SYSDELAY QUEUE.  WHEN ALL            * 08200020
*   APPROPRIATE LCBS HAVE THUS BEEN SURRENDERED TO THE SYSDELAY Q,    * 08400020
*   THE QCB IS POSTED TO TIME DELAY TO START TIMIMG THE SYSTEM        * 08600020
*   INTERVAL.                                                         * 08800020
*                                                                     * 09000020
*OUTPUT -- TWO MESSAGES ARE DISPLAYED ON THE OPERATOR'S CONSOLE.      * 09200020
*                                                                     * 09400020
*   'IED080I START OF TCAM SYSTEM DELAY', INDICATES WHEN ALL NON-     * 09600020
*   DIAL LINES ARE HELD FOR THE INTERVAL SPECIFIED ON INTRO MACRO     * 09800020
*   INTVAL KEYWORD.                                                   * 10000020
*                                                                     * 10200020
*   'IED081I END OF TCAM SYSTEM DELAY', INDICATES ALL NON-DIAL        * 10400020
*   LINES ARE BEING REACTIVATED TO RESUME NORMAL TRAFFIC.             * 10600020
*                                                                     * 10800020
*EXTERNAL ROUTINES -- CALLS ARE MADE TO TWO ROUTINES --               * 11000020
*        'IEDQHG01' - ADD ELEMENT TO TIME DELAY Q                     * 11200020
*        'IEDQHG02' - REMOVE ELEMENT FROM TIME DELAY Q                * 11400020
*                                                                     * 11600020
*EXITS-NORMAL -- EXIT IS ALWAYS TO DISPATCHER, 'DSPDISP', EXCEPT      * 11800020
*   WHEN POSTING ALL LCBS TO THEMSELVES AT 'DSPCHAIN'.                * 12000020
*                                                                     * 12200020
*EXITS-ERROR -- N/A                                                   * 12400020
*                                                                     * 12600020
*TABLES/WORK AREAS -- SYSTEM DELAY QCB IS INCLUDED AT START OF MODULE.* 12800020
*   THE LCBLINK FIELD OF THE LCB IS MODIFIED TO CHAIN LCB ONTO        * 13000020
*   SYSDELAY Q.  AVT IS REFERENCED TO GET ADDR OF IEDQHG01 AND 02.    * 13200020
*                                                                     * 13400020
*ATTRIBUTES -- REUSABLE, OPTIONALLY RESIDENT, PROBLEM PROGRAM MODE,   * 13600020
*   NON-REFRESHABLE                                                   * 13800020
*                                                                     * 14000020
*NOTES -- THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A         * 14200020
*   PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET. * 14400020
*                                                                     * 14600020
*   THIS MODULE IS OPTIONALLY LOADED AT INTRO EXECUTION TIME BY       * 14800020
*   IEDQOS IF AVTINTLV IS NON-ZERO.  AVTINTLV CONTAINS THE VALUE      * 15000020
*   SPECIFIED ON INTRO WITH 'INTVAL=INTEGER' OPERAND.                 * 15200020
*                                                                     * 15400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 15600020
*                                                                       15800020
R15      EQU   15                       TEMPORARY REG                   16000020
R14      EQU   14                       RETURN ADDR                     16200020
R13      EQU   13                       SAVEAREA POINTER (SAVE2)        16400020
RAVT     EQU   13                       AVT DSECT BASE                  16600020
R12      EQU   12                                                       16800020
RBASE    EQU   12                       PROGRAM BASE                    17000020
R11      EQU   11                                                       17200020
RDISP    EQU   11                       DISPATCHER ENTRY                17400020
R10      EQU   10                                                       17600020
RDCB     EQU   10                       DCB DSECT BASE                  17800020
R9       EQU   9                        UNUSED                          18000020
R8       EQU   8                                                        18200020
RSW      EQU   8                        BRANCH SWITCH                   18400020
R7       EQU   7                                                        18600020
RQCB     EQU   7                        QCB DSECT BASE                  18800020
R6       EQU   6                                                        19000020
REXIT    EQU   6                        SUBROUTINE RETURN ADDRESS       19200020
R5       EQU   5                                                        19400020
RDEB     EQU   5                        DEB DSECT BASE                  19600020
R4       EQU   4                                                        19800020
RLCB     EQU   4                        LCB DSECT BASE                  20000020
R3       EQU   3                                                        20200020
RTCB     EQU   3                        TCB DSECT BASE                  20400020
R2       EQU   2                        UNUSED                          20600020
R1       EQU   1                        PARAMETER PASSER                20800020
R0       EQU   0                        TEMPORARY                       21000020
*                                                                       21200020
COUNT    EQU   4                                                 S22025 21240022
EIGHT    EQU   8                                                 S22025 21280022
ONE      EQU   1                                                 S22025 21320022
ENDILIST EQU   X'FE'                    END OF INVITATION LIST   S22025 21360022
         USING DELAYQCB,RBASE           PROGRAM BASE                    21400020
         USING IEDQLCB,RLCB                                             21600020
         USING IEDQDEB,RDEB                                             21800020
         USING IEDQQCB,RQCB                                             22000020
         USING IHADCB,RDCB                                              22200020
         USING IEDQTCB,RTCB                                             22400020
         USING IEDQDISP,RDISP                                           22600020
         USING IEDQAVTD,RAVT                                            22800020
*                                                                       23000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 23200020
*                                                                       23400020
*                       DSECTS                                          23600020
*                                                                       23800020
         TTCBD                                                          24200020
         TSCBD                                                   S22025 24300022
         TDEBD                                                          24400020
         TQCBD                                                          24600020
         TLCBD                                                          24800020
         TDISPD                                                         25000020
         DCBD DSORG=TX                                                  25200020
         TPRIOR                                                         25400020
         TCCWD                                                          25600020
         TAVTD 2                                                        25800020
*                                                                       26200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 26400020
*                                                                       26600020
IEDQHI   CSECT                                                          26800020
*                                                                       27000020
*                       SYSTEM DELAY QCB                                27200020
*                                                                       27400020
DELAYQCB DC    X'02',AL3(*-1)           KEY + QCBADDR                   27600020
PRI      DC    X'00',AL3(0)             PRIORITY + LINK                 27800020
         DC    A(SYSDSTCB-DELAYQCB)     STCB ADDRESS                    28000020
NOEXTENT DC    H'0'                     NUMBER OF EXTENTS               28200020
LCBFIXR  DC    AL2(LCBFLAG1-IEDQLCB)    OFFSET INTO LCB OF IOB          28400020
TIME     DC    H'0'                     TIME INTERVAL OF SYS DELAY      28600020
         DC    X'00'                    INDEX - INDICATES QCB TO TIME   28800020
*                                         DELAY SUBTASK                 29000020
         DC    4X'00'                   UNUSED                          29200020
TIMEFLAG DC    X'00'                    X'02' BIT ON, QCB ON TIME Q     29400020
SYSDELQ  DC    A(0)                     CHAIN OF LCBS ON SYSDELAY Q     29600020
         DC    A(0)                     TIME Q LINK FIELD               29800020
*                                                                       30000020
IEDQHI   IEDHJN ,                                                S22025 30300022
*                                                                       30600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 30800020
*                                                                       31000020
*                       SYSTEM DELAY STCB                               31200020
*                                                                       31400020
         DS    0H                       HALFWORD BOUNDARY FOR STCB      31600020
SYSDSTCB DC    AL1(DSPMCPL2),AL1(0)     STCB FOR SYSTEM DELAY    S22025 31800022
*                                                                       32000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 32200020
*                                                                       32400020
*                       SYSTEM DELAY SUBTASK ENTRY POINT                32600020
*                                                                       32800020
         LA    RBASE,0(,RQCB)           SET PROGRAM BASE, AND CLEAR     33000020
*                                         HIGH BYTE FOR                 33200020
*                                         ADDRESS COMPARE               33400020
         LA    RLCB,0(,R1)              CLEAR HIGH BYTE OF ELE ADDR     33600020
         L     RDISP,AVTEA              ADDRESS OF DISPATCHER           33800020
*                                                                       34000020
* WHAT KIND OF ELEMENT WAS PASSED IN R1 -                               34200020
*   SYSTEM DELAY REQUEST ELEMENT FROM OPERATOR CONTROL                  34400020
*   SYSTEM DELAY QCB BEING RETURNED FROM TIME Q AT END OF SYSTEM        34600020
*     INTERVAL.                                                         34800020
*   AN LCB THAT NEEDS SHUTTING DOWN, FROM SCHEDULER                     35000020
*                                                                       35200020
         CLI   LCBPRI-IEDQLCB(R1),PRISYSDL IS THIS THE SYSTEM DELAY     35400020
*                                         ELEMENT FROM OPERATOR CTL     35600020
         BE    OPCTL                      YES, START SYSTEM DELAY       35800020
*                                         NO, SOMETHING ELSE            36000020
         CR    RBASE,RLCB               IS ELE MY OWN QCB FROM TIME Q   36200020
         BE    MYQCB                      YES, END OF SYSTEM INTERVAL   36400020
*                                         NO, MUST BE AN LCB            36600020
         TM    LCBSTAT1,LCBFREEN        IS LCB FREE              S22025 36603022
         BZ    CONTDELY                 NO-BR                    S22025 36606022
         SR    R3,R3                    CLEAR REG FOR INDEXING   S22025 36609022
         IC    R3,LCBUCBX               REL LINE-1               S22025 36612022
         SLL   R3,2                     MULTIPLY BY FOUR         S22025 36615022
         L     R6,LCBDCBPT              LOAS THE DCB ASDRESS     S22025 36618022
         L     R6,DCBINVLI-IHADCB(R6,R3) GET INVITATION LIST ADDRS22025 36621022
*                                       FOR THIS LINE            S22025 36624022
         CLI   COUNT(R6),AVTEZERO       CURRENTLY SENDING        S22025 36627022
         BNE   NOSET01                  YES DONT SET SYSDELAY    S22025 36630022
         TM    LCBSTAT2,LCBSNDPR        RECIEVE SIDE STOPPED     S22025 36633022
         BO    NOSET01                  YES-BR                   S22025 36636022
         LA    R3,EIGHT(R6)             GET THE ADDRESS OF THE   S22025 36639022
*                                       FIRST INVITATION LIST ENTS22025 36642022
         SR    R5,R5                    CLEAR WORK REG           S22025 36645022
         IC    R5,TWO(R6)               GET THE SIZE OF EACH ENTYS22025 36648022
FNDILST  EQU   *                                                 S22025 36651022
         LR    R8,R5                    COPY SIZE                S22025 36654022
         BCTR  R8,0                     REDUCE THE ZIZE BY 1     S22025 36657022
         IC    R8,AVTEZERO(R8,R3)       PICK UP THE INDEX TO THE S22025 36660022
*                                       TNT OFFSET               S22025 36663022
         AR    R8,R8                    DOUBLE TO COMPUTE THE    S22025 36666022
*                                       ILIST OFFSET             S22025 36669022
         LR    R3,R6                    COPY ADDRESS OF THE ILISTS22025 36672022
         SR    R3,R8                    SUBTRACT THE INDEX FROM  S22025 36675022
*                                       THE BEGINNING ADDRESS    S22025 36678022
         LR    R10,R1                   SAVE REG 1 ACROSS TNT    S22025 36681022
         LH    R1,AVTEZERO(R3)          GET THE TNT OFFSET       S22025 36684022
         L     R15,AVTRNMPT             GET THE TNT CONVERSION   S22025 36687022
*                                       ROITINE ADDR             S22025 36690022
         BALR  R14,R15                  LINK TO IT               S22025 36693022
         L     RQCB,AVTEZERO(R1)        LOAD DESTINATION QCB ADDRS22025 36696022
         SR    R0,R0                    CLEAR                    S22025 36699022
         SR    R1,R1                    WORK REGS                S22025 36702022
         SR    R15,R15                  WORK REGS                S22025 36705022
         IC    R1,QCBSCBOF              GET SCB OFFSET           S22025 36708022
         IC    R0,AVTSCBSZ              GET SCB SIZE             S22025 36711022
         MR    R0,R0                    SIZE X OFFSET            S22025 36714022
         L     R15,LCBSCBDA-1           SCB DIRECTORY            S22025 36717022
         LA    R15,AVTEZERO(R1,R15)     GET SCB ADDR             S22025 36720022
         LR    R1,R10                   RESTORE 1                S22025 36723022
         TM    SCBQTYPE-IEDQSCB(R15),SCBBFMM MIDDLE OF MSG ON    S22025 36726022
         BO    NOSET01                  YES DONT SET SYS DELAY   S22025 36729022
         AR    R8,R5                    INCREMENT CURRENT ILIST  S22025 36732022
*                                       POINTER                  S22025 36735022
         CLI   AVTEZERO(R8),ENDILIST    END OF INVITATION LIST   S22025 36738022
         BE    CONTDELY                 YES BRANCH               S22025 36741022
         CLI   ONE(R8),ENDILIST         ENE OF INVITATION LIST   S22025 36744022
         BE    CONTDELY                 YES BRANCH               S22025 36747022
         B     FNDILST                  COMPUTE NEXT SCB ADDR    S22025 36750022
CONTDELY EQU   *                                                 S22025 36753022
         NI    LCBSTAT1,AVTEFF-(LCBRECVN+LCBSENDN) MARK LCB AS STOPPED  36800020
         BAL   REXIT,HANGLCB            GO HANG LCB ON SYSDEL Q         37000020
*                                                                       37200020
EXIT     EQU   *                                                        37400020
         NC    AVTOPCNT,AVTOPCNT        HAS LAST LCB BEEN STOPPED       37600020
         BZ    CALLTIME                   YES, WAIT ON TIME Q           37800020
*                                         NO, NOT ALL LCBS IN YET       38000020
NOSET01  EQU   *                                                 S22025 38100022
         B     DSPDISP                  RETURN TO DISPATCHER            38200020
*                                                                       38400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 38600020
*                                                                       38800020
* A SYSTEM DELAY REQUEST ELEMENT IS RECEIVED FROM OPERATOR CONTROL      39000020
* START GRABBING LCBS.                                                  39200020
*                                                                       39400020
OPCTL    EQU   *                                                        39600020
         XC    AVTOPCNT,AVTOPCNT        CLEAR COUNTER                   39800020
         OI    AVTBIT1,AVTDLAYN         TURN ON SYSTEM DELAY BIT        40000020
*                                                                       40200020
* HUNT FOR LCBS. TCB POINTS TO DEB CHAIN, DEB POINTS TO DCB, DCB        40400020
* POINTS TO SERIES OF LCBS.  GO FIND THEM.                              40600020
*                                                                       40800020
         L     RTCB,AVTTCB              GET ADDR OF TCAM TCB            41000020
         L     RDEB,TCBDEB              GET START OF DEB CHAIN          41200020
DEBLOOP  EQU   *                                                        41400020
         L     RDCB,DEBDCBAD-DEBFIXR    GET ADDR OF DCB                 41600020
         TM    DCBOFLGS,OPENDCB         IS DCB OPEN                     41800020
         BZ    BUMPDEB                    NO, FORGET THIS DCB           42000020
*                                         YES, CONTINUE                 42200020
         TM    DCBDSORG+1,LINEDCB       IS THIS A LINE DCB DSORG=TX     42400020
         BO    ISLINE                     YES, GOT A LINE DCB           42600020
*                                         NO, NOT A LINE DCB            42800020
BUMPDEB  EQU   *                                                        43000020
         L     RDEB,DEBDEBAD-DEBFIXR    LOOK AT NEXT DEB IN CHAIN       43200020
         LA    RDEB,0(,RDEB)            CLEAR HIGH BYTE                 43400020
         LTR   RDEB,RDEB                IS THERE ANOTHER DEB            43600020
         BZ    EXIT                       NO, ALL DEBS DONE, GO SEE     43800020
*                                           IF ALL LCBS STOPPED         44000020
*                                         YES, THERE IS ANOTHER DCB     44200020
         B     DEBLOOP                  PROCESS NEW DEB                 44400020
*                                                                       44600020
* A LINE DCB HAS BEEN FOUND.  FIND ITS LCBS.                            44800020
*                                                                       45000020
ISLINE   EQU   *                                                        45200020
         L     RLCB,DCBIOBAD            GET ADDR OF PSEUDO IOB          45400020
         SH    RLCB,LCBFIXR             GET ADDR OF PSEUDO LCB          45600020
         MVC   NOEXTENT+1(1),DEBNMEXT-DEBFIXR GET NO. EXTENTS           45800020
LCBLOOP  EQU   *                                                        46000020
         SR    R15,R15                                                  46200020
         IC    R15,DCBEIOBX             GET SIZE OF AN LCB              46400020
         AR    RLCB,R15                 BUMP FROM PSEUDO TO 1ST         46600020
*                                         (OR NEXT) LCB                 46800020
         CLI   LCBRSKEY,RECSCHED        IS RECEIV SCHEDULER AT TOP      47000020
         BE    LEASED                     YES, LINE IS LEASED           47200020
*                                         NO, GUESS AGAIN               47400020
         CLI   LCBRSKEY,BUFSCHED        IS BUFFERED SCHEDULER AT TOP    47600020
         BE    LEASED                     YES, LINE IS LEASED           47800020
*                                         NO, NOT LEASED                48000020
*                                                                       48200020
NEXTLCB  EQU   *                                                        48400020
* FINISHED ONE LCB ON THIS DCB.  FIND OTHER LCBS OFF THIS SAME DCB.     48600020
*                                                                       48800020
         LH    R15,NOEXTENT             GET NO. OF LCBS REMAINING       49000020
         BCT   R15,LCBLOOPR             SUBTRACT THE ONE LCB JUST DONE  49200020
*                                       IS THERE ANOTHER LCB TO DO      49400020
*                                         YES, BRANCH                   49600020
*                                         NO, CONTINUE                  49800020
         B     BUMPDEB                  DONE ALL LCBS ON THIS DEB       50000020
*                                       GO GET NEXT DEB ON DEB CHAIN    50200020
LCBLOOPR EQU   *                                                        50400020
         STH   R15,NOEXTENT             SAVE DECREMENTED LCB COUNTER    50600020
         B     LCBLOOP                  GO GET NEXT LCB                 50800020
*                                                                       51000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 51200020
*                                                                       51400020
* SYSTEM DELAY QCB HAS BEEN RETURNED FROM TIME DELAY Q.  THIS SYSTEM    51600020
* INTERVAL IS UP.  FIND ALL LCBS ON SYSDELAY Q, REMOVE THEM, POST       51800020
* THEM TO THEMSELVES, REACTIVATING THE SYSTEM.                          52000020
*                                                                       52200020
MYQCB    EQU   *                                                        52400020
         NI    AVTBIT1,AVTDLAYF         TURN OFF SYSTEM DELAY BIT       52600020
         WTO   'IED081I END OF TCAM SYSTEM DELAY',                     *52800020
               ROUTCDE=2,DESC=6                                         53000020
*                                                                       53200020
         L     RLCB,SYSDELQ             GET FIRST LCB FROM SYSDELAY Q   53400020
         LA    RLCB,0(,RLCB)            CLEAR HIGH BYTE                 53600020
         LTR   RLCB,RLCB                WERE ANY LCBS ON SYSDELAY Q     53800020
         BZ    DSPDISP                    NO, NONE HERE, RETURN TO      54000020
*                                           DISPATCHER                  54200020
*                                         YES, SYSDELAY Q HAS LCBS      54400020
ANOTLCB  EQU   *                        GO GET LCBS                     54600020
         IC    R0,LCBQCBA-1             POST                            54800020
         ST    RLCB,LCBQCBA-1             LCB TO                        55000020
         STC   R0,LCBQCBA-1                 ITSELF                      55200020
         MVI   LCBPRI,PRILNFRE          SET PRIORITY                    55400020
         LR    R1,RLCB                  REMEMBER WHICH LCB THIS ONE     55600020
*                                         WAS, INCASE IT IS THE LAST    55800020
         L     RLCB,LCBLINK-1           GET NEXT LCB FROM SYSDELAY Q    56000020
         LA    RLCB,0(,RLCB)            CLEAR HIGH BYTE                 56200020
         LTR   RLCB,RLCB                IS THERE ANOTHER LCB            56400020
         BNZ   ANOTLCB                    YES, GO POST NEW LCB          56600020
*                                         NO, NO MORE LCBS              56800020
         XC    LCBLINK-IEDQLCB(3,R1),LCBLINK-IEDQLCB(R1) CLEAR LINK     57000020
*                                         FIELD IN LAST LCB FROM Q      57200020
         L     R1,SYSDELQ               GET FIRST LCB OF A CHAIN,       57400020
*                                         ALL TO BE POSTED TO DISPATCH  57600020
         XC    SYSDELQ,SYSDELQ          CLEAR DELAY QUEUE               57800020
         B     DSPCHAIN                 POST ALL LCBS TO THEMSELVES     58000020
*                                       EXIT TO DISPATCHER              58200020
*                                                                       58400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 58600020
*                                                                       58800020
* LAST LCB HAS BEEN FOUND AND STOPPED.  ALL ARE ON SYSDELAY Q.          59000020
* PICK UP LENGTH OF SYSTEM INTERVAL FROM AVT, POST MY QCB TO TIME       59200020
* DELAY, REQUESTING NOTIFICATION OF WHEN TIME INTERVAL IS UP.           59400020
*                                                                       59600020
CALLTIME EQU   *                                                        59800020
         WTO   'IED080I START OF TCAM SYSTEM DELAY',                   *60000020
               ROUTCDE=2,DESC=6                                         60200020
*                                                                       60400020
         MVC   TIME,AVTINTLV            GET NUMBER OF SECONDS OF        60600020
*                                         SYSTEM DELAY INTERVAL         60800020
         L     R15,AVTHG01              GET ADDR OF TIME DELAY          61000020
         LR    R1,RBASE                 PASS ADDR OF MY QCB TO TIME Q   61200020
         MVI   PRI,PRISYSDL-4           POST MY QCB TO TIME DELAY       61400020
*                                         USING LOWER PRIORITY THAN     61600020
*                                         WHEN REQUESTING SYS DELAY     61800020
*                                       (CANNOT USE SAME PRI, THAT IS   62000020
*                                       HOW I TELL THE SYSDELAY         62200020
*                                       REQUEST ELE FROM OTHERS)        62400020
         BALR  R14,R15                  PUT MY QCB ON TIME DELAY Q      62600020
*                                                                       62800020
         B     DSPDISP                  RETURN TO DISPATCHER.  SYSTEM   63000020
*                                         WAITS FOR THIS QCB TO COME    63200020
*                                         BACK FROM TIME DELAY          63400020
*                                                                       63600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 63800020
*                                                                       64000020
* REXIT HAS RETURN ADDRESS                                              64200020
HANGLCB  EQU   *                                                        64400020
         NI    LCBSTAT1,X'FF'-LCBFREEN  LCB NO LONGER FREE              64600020
         MVI   LCBPRI,PRILCBDL          MARK LCB AS BEING ON            64660020
*                                         SYSTEM DELAY QUEUE            64720020
         MVC   LCBLINK,SYSDELQ+1        HANG LCB ONTO                   64800020
         ST    RLCB,SYSDELQ               SYSTEM DELAY QUEUE            65000020
DECCOUNT EQU   *                                                        65200020
         LH    R15,AVTOPCNT             GET NUMBER OF LCBS TO BE        65400020
         BCTR  R15,0                      PUT ON SYSDELAY Q, SUB-       65600020
*                                         TRACT ONE FOR LCB JUST        65800020
*                                         PUT ON Q, AND RESTORE         66000020
         STH   R15,AVTOPCNT               REMAINING COUNT               66200020
         BR    REXIT                    LCB PROCESSED, RETURN TO        66400020
*                                         MAIN ROUTINE                  66600020
*                                                                       66800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 67000020
*                                                                       67200020
LEASED   EQU   *                                                        67400020
         LH    R15,AVTOPCNT             GET PREVIOUS COUNT              67600020
         LA    R15,1(,R15)              BUMP IT BY ONE                  67800020
         STH   R15,AVTOPCNT             SAVE BUMPED COUNT               68000020
         TM    LCBSTAT1,LCBFREEN        IS LINE FREE                    68200020
         BO    FREE                       YES, LINE IS FREE             68400020
*                                         NO, LINE IS NOT FREE          68600020
         TM    LCBSTAT1,LCBRECVN+LCBSENDN IS LINE SENDING OR            68800020
*                                         RECEIVING, OR STOPPED         69000020
         BNM   STOPPED                  LINE IS STOPPED IF ZERO SA59011 69200022
*                                        OR CU NOT-OPERATIONAL          69260022
*                                        WAS REC'D ON OPEN - IF 03      69320022
*                                       LINE IS NOT STOPPED.CONTINUE    69400020
         TM    LCBSTAT1,LCBOCNI         IS A STOPLINE BEEN REQUESTED    69450020
         BO    STOPPED                    YES, ASSUME LINE STOPPED      69500020
*                                         NO, LINE IS NOT STOPPED       69550020
         CLI   LCBCPA+24,CCWPOLL        IS LINE AUTOPOLL                69600020
         BE    AUTOPOLL                   YES, LINE IS AUTOPOLL         69800020
*                                         NO, LINE IS NOT AUTOPOLL      70000020
         CLI   LCBCPA+32,CCWSENSE       IS LINE STOP/START CONTENTION   70200020
         BE    STARTSTP                   YES, START/STOP               70400020
*                                         NO, NOT START/STOP            70600020
         CLI   LCBCPA+24,CCWSENSE       IS TERMINAL WORLD TRADE         70800020
         BE    WORLDTDE                   YES, IT IS                    71000020
*                                         NO, GUESS AGAIN               71200020
         TM    LCBSTAT2,LCBSYNC         IS LINE BISYNC                  71400020
         BO    BISYNC                     YES, BISYNC                   71600020
*                                         NO, NOT BISYNC                71800020
         B     NEXTLCB                  NONE OF ABOVE, FORGET THIS LCB  72000020
*                                                                       72200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 72400020
*                                                                       72600020
FREE     EQU   *                                                        72800020
         TM    TIMEBYTE(RLCB),TIMEBIT   IS LCB ON TIME Q                73000020
         BZ    HANGLCBX                   NO, LCB IS NOT ON TIME Q      73200020
*                                         YES, LCB IS ON TIME Q         73400020
         L     R15,AVTHG02              GET TIME DELAY REMOVE ENTRY     73600020
         LR    R1,RLCB                  PASS ADDR OF LCB TO BE REMOVED  73800020
         BALR  R14,R15                  REMOVE LCB FROM TIME Q          74000020
*                                                                       74200020
         CLI   LCBRSKEY,RECSCHED        IS IT A LEASED LCB              74220020
         BNE   NOMOVE                     NO, SKIP MOVE SCHEDULER       74240020
*                                         YES, LEASED LCB               74260020
         LA    R7,LCBRSKEY              LINK RECEIVE SCHEDULER BACK     74280020
         LR    R1,R7                      INTO STCB CHAIN               74300020
         BAL   R14,DSPPRIOR             MOVE SCHEDULER                  74320020
*                                                                       74340020
NOMOVE   EQU   *                                                        74360020
HANGLCBX EQU   *                                                        74400020
         BAL   REXIT,HANGLCB            GO PUT LCB ON SYSDELAY Q        74600020
*                                                                       74800020
         B     NEXTLCB                  GO PROCESS THE NEXT LCB         75000020
*                                                                       75200020
AUTOPOLL EQU   *                                                        75400020
         MVI   LCBCPA+32,CCWNOP         KILL POLL WITH PAIR OF          75600020
         MVI   LCBCPA+56,CCWNOP           NO-OP CCWS                    75800020
         B     NEXTLCB                  FORGET LCB FOR NOW, IT WILL     76000020
*                                         COME THRU AGAIN LATER         76200020
*                                                                       76400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 76600020
*                                                                       76800020
STARTSTP EQU   *                                                        77000020
         L     R15,LCBCPA+32            GET ADDR OF DATA AREA FROM      77200020
*                                         SENSE CCW                     77400020
CKSTARST EQU   *                                                        77600020
         CLI   0(R15),STARSTOP          IS TERMINAL ACTIVE              77800020
         BE    IOHALT                     NO, STOP I/O                  78000020
*                                         YES, FORGET LCB FOR NOW,      78200020
*                                           IT WILL COME THRU AGAIN     78400020
         B     NEXTLCB                  GO PRECESS NEXT LCB             78600020
*                                                                       78800020
WORLDTDE EQU   *                                                        79000020
         L     R15,LCBCPA+24            GET ADDR OF DATA AREA FROM      79200020
*                                         SENSE CCW                     79400020
         B     CKSTARST                 CHECK FOR ACTIVE TERMINALS22026 79600022
*                                                                       79800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 80000020
*                                                                       80200020
BISYNC   EQU   *                                                        80400020
         CLI   LCBCPA+16,CCWPREP        PREPARE                         80600020
         BNE   NEXTLCB                    NO, FORGET FOR NOW            80800020
*                                         YES, CONTINUE                 81000020
         TS    LCBTSTSW                 IS LINE FREE                    81200020
         BNZ   NEXTLCB                    NO, BUSY,WAIT TILL NEXT TIME  81400020
*                                         YES, FREE                     81600020
IOHALT   EQU   *                                                        81800020
         SR    R15,R15                  CLEAR INDEX REG                 82000020
         IC    R15,LCBUCBX              GET INDEX TO UCB                82200020
         SLL   R15,TIMES4               MULTIPLY BY 4, THE NO. BYTES    82400020
*                                         IN EACH DEB EXTENT WHICH      82600020
*                                         HAS ADDR OF UCB               82800020
         L     R1,LCBDCBPT              GET ADDR OF DCB                 83000020
         L     R1,DCBDEBAD-IHADCB(R1)   GET ADDR OF BASIC DEB           83200020
         L     R1,DEBUCBAD-DEBFIXR-IEDQDEB(R1,R15) GET UCB ADDR         83400020
         LA    R1,0(,R1)                CLEAR HIGH BYTE                 83600020
         IOHALT (1)                     STOP THAT LINE                  83800020
*                                                                       84000020
*                                       FORGET LCB FOR NOW, IT WILL     84200020
*                                         COME THRU AGAIN LATER         84400020
         B     NEXTLCB                  GO PRECESS NEXT LCB             84600020
*                                                                       84800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 85000020
*                                                                       85200020
STOPPED  EQU   *                                                        85400020
         BAL   REXIT,DECCOUNT           DO NOT COUNT IT                 85600020
*                                                                       85800020
         B     NEXTLCB                  GO PROCESS NEXT LCB             86000020
*                                                                       86200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 86400020
*                                                                       86600020
*                       EQUATES                                         86800020
*                                                                       87000020
RECSCHED EQU   X'0C'                                                    87200020
BUFSCHED EQU   X'1A'                                                    87400020
STARSTOP EQU   X'FF'                                                    87600020
TIMES4   EQU   2                        SHIFT COUNT                     87800020
DEBFIXR  EQU   DEBNMSUB-IEDQDEB         ADJUSTS TCAM DEB DSECT TO       88000020
*                                         OS DEB (WHICH BEGINS AT       88200020
*                                         DEBNMSUB OF TCAM DEB)         88400020
LINEDCB  EQU   X'40'                    DCBDSORG+1, DSORG=TX            88600020
OPENDCB  EQU   X'10'                    CHECK FOR OPEN DCB              88800020
TWO      EQU   2                        SWITCH                          89000020
TIMEBYTE EQU   X'17'                    OFFSET INTO TIME DELAY ELE      89200020
*                                         OF FLAG BYTE                  89400020
TIMEBIT  EQU   X'02'                    BIT ON, ELE ON TIME Q           89600020
         END                                                            89800020
