QNG      TITLE 'IEDQNG  -BUILD INCIDENT RECORD FOR CHECKPT MACRO'       00400020
IEDQNG   CSECT                                                          00800020
         SPACE 3                                                        01200020
*********************************************************************** 01600020
*                                                                     * 02000020
*TITLE: 'IEDQNG'-INCIDENT CHECKPOINT FOR AN MH MACRO-CHECKPT          * 02400020
*                                                                     * 02800020
*STATUS:CHANGE LEVEL 0                                                * 03200020
*                                                                     * 03600020
*FUNCTION:THIS MODULE BUILDS AN INCIDENT DISK RECORD WHEN THE         * 04000020
*   REQUEST ELEMENT ON THE CHECKPOIN QCB IS AN LCB FROM A CHECKPT     * 04400020
*   MACRO. IT DETERMINES THE TERMINAL CURRENTLY ASSOCIATED WITH THE   * 04800020
*   LCB(IF THE CHECKPT MACRO IS IN THE IN MH,IT IS THE SOURCE TERMINAL* 05200020
*   IF IT IS IN THE OUT MH, IT IS THE DESTINATION TERMINAL.) IF       * 05600020
*   LCBTTCIN IS ZERO THE TERMINAL ENTRY CANNOT BE IDENTIFIED SO AN    * 06000020
*   INCIDENT CHECKPOINT                                               * 06400020
*  RECORD IS NOT BUILT. A BIT IS TURNED ON IN CKPLREB AND THE OFFSET *  06800020
*   OF THE NOTIFICATION ROUTINE IS RETURNED IN REGISTER 15.           * 07200020
*                                                                     * 07600020
*ENTRY POINT:                                                         * 08000020
*                                                                     * 08400020
*        IEDQNG                                                       * 08800020
*                                                                     * 09200020
*INPUT:REGISTERS 2,3,9,12,14,15 CONTAIN THE FOLLOWING:                * 09600020
*                                                                     * 10000020
*   2-ADDRESS OF THE CHECKPOINT WORK AREA                             * 10400020
*   3-ADDRESS OF REQUEST ELEMENT THIS MODULE IS TO PROCESS            * 10800020
*   9-ADDRESS OF AVT                                                  * 11200020
*   12-BASE REGISTER FOR CHECKPOINT EXECUTOR-IEDQNF                   * 11600020
*   14-RETURN ADDRESS-IN IEDQNF                                       * 12000020
*   15-ENTRY POINT FOR THIS MODULE                                    * 12400020
*                                                                     * 12800020
*   THE LCB(REQUEST ELEMENT) POINTED TO BY R3.                        * 13200020
*                                                                     * 13600020
*OUTPUT:THE ABOVE REGISTERS 2-14 REMAIN THE SAME(R15 MAY HAVE A       * 14000020
*   RETURN CODE).                                                     * 14400020
*                                                                     * 14800020
*   AN INCIDENT DISK RECORD IS BUILT IN A GETMAIN AREA.(ITS ADDRESS   * 15200020
*   IS IN CKPLDRB.)                                                   * 15600020
*                                                                     * 16000020
*EXTERNAL ROUTINES:                                                   * 16400020
*        IEDQTNT-DETERMINES TERMINAL TABLE ADDRESS                    * 16800020
*                                                                     * 17200020
*EXITS-NORMAL:THIS MODULE RETURNS TO THE ADDRESS IN R14. R15 HAS AN   * 17600020
*   OFFSET FOR THE CHECKPOINT QUENE MANAGER(72) OR THE INCIDENT       * 18000020
*   OVERFLOW ROUTINE(96) OR THE NOTIFICATION ROUTINE(80).             * 18400020
*                                                                     * 18800020
*EXITS ERROR:THIS MODULE RETURNS TO THE ADDRESS IN R14. R15 HAS AN    * 19200020
*   OFFSET FOR THE NO CORE ROUTINE(88).                               * 19600020
*                                                                     * 20000020
*TABLES/WORK AREAS:                                                   * 20400020
*                                                                     * 20800020
*   AVT(AVTCLRHI,AVTRNMPT,AVTOPTPT)                                   * 21200020
*   CHECKPOINT WORK AREA                                              * 21600020
*   TERMNAME TABLE                                                    * 22000020
*   TERMINAL TABLE                                                    * 22400020
*   OPTION TABLE                                                      * 22800020
*   OPTION LENGTH TABLE                                               * 23200020
*                                                                     * 23600020
*ATTRIBUTES:REENTERABLE                                               * 24000020
*                                                                     * 24400020
*NOTES:THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL REPRE-   * 24800020
*   SENTATION OF THE EXTERNAL CHARACTER SET WHICH IS EQUIVALENT TO    * 25200020
*   THE ONE USED AT ASSEMBLY TIME. THE CODING HAS BEEN ARRANGED SO    * 25600020
*   THAT REDEFINITION OF 'CHARACTER' CONSTANTS,BY REASSEMBLY,WILL     * 26000020
*   RESULT IN A CORRECT MODULE FOR THE NEW DEFINITIONS.               * 26400020
*                                                                     * 26800020
*********************************************************************** 27200020
         SPACE 3                                                        27600020
*REGISTER ASSIGNMENTS                                                   28000020
         SPACE                                                          28400020
R0       EQU   0                                                        28800020
R1       EQU   1                        PARM REGISTER-OR WORK REG       29200020
R2       EQU   2                        ADDRESS OF CKPT WORK AREA       29600020
R3       EQU   3                        ADDRESS OF REQUEST ELEMENT      30000020
R4       EQU   4                        ADDRESS OF DISK RECORD          30400020
R5       EQU   5                        ADDRESS OF OPTION ENTRY         30800020
R6       EQU   6                        INDEX REG                       31200020
R7       EQU   7                        OFFSET TO TERMNAME TABLE        31600020
RTERM    EQU   8                        ADDRESS OF TERM. TABLE ENTRY    32000020
RAVT     EQU   9                        ADDRESS OF AVT                  32400020
R10      EQU   10                       LENGTH FOR MOVE(OPTN ENTRY)     32800020
R11      EQU   11                       COUNT OF TERMNAME ENTRIES       33200020
RBASE    EQU   12                       BASE REG                        33600020
R13      EQU   13                       ADDRESS OF OPTION FIELDS        34000020
R14      EQU   14                       RETURN REG                      34400020
R15      EQU   15                       ENTRY POINT OR RETURN CODE      34800020
         SPACE 3                                                        35200020
*STANDARD LINKAGE                                                       35600020
         SPACE                                                          36000020
         USING *,R15                    TEMP BASE                       36400020
         B     QNG00                                                    36800020
         DC    CL8'IEDQNG'                                              37200020
         DC    CL6'041671'                                              37600000
QNG00    EQU   *                                                        38000020
         USING IEDQAVTD,RAVT            BASE FOR AVT                    38400020
         USING IEDQCKPD,R2              BASE FOR CKPT WORK AREA         38800020
         USING LCBERB,R3                BASE FOR ERB-REQUEST ELEMNT1016 39200020
         SPACE 3                                                        39600020
         LH    R7,LCBTTCIN              GET TERMNAME TABLE OFFSET       40000020
         N     R7,AVTCLRHI                                              40400020
         BZ    QNG50                    BRANCH IF NO TRM OFFSET    0720 40800020
         LR    R4,R14                   SAVE REG                        41200020
         LR    R5,R15                   SAVE REG                        41600020
         DROP  R15                                                      42000020
         USING IEDQNG,R5                TEMPORARY BASE                  42400020
         L     R15,AVTRNMPT             GET BEGINNING OF TERM TABL      42800020
         LR    R1,R7                    SET PARM FOR SUBRTN             43200020
         BALR  R14,R15                  GET ADDRESS OF TERM ENTRY       43600020
         LR    R14,R4                   RESTORE REG                     44000020
         SPACE 3                                                        44400020
         USING IEDQTRM,RTERM            BASE FOR TERM ENTRY             44800020
         LR    RTERM,R1                                                 45200020
         SR    R0,R0                    CLEAR                           45600020
         IC    R0,CKPINCNO              GET COUNT OF INCIDENTS LEFT     46000020
         LTR   R0,R0                    CHECK COUNT                     46400020
         BZ    QNG70                    BRANCH IF NONE                  46800020
         BCTR  R0,0                     SUBTRACH FROM COUNT             47200020
         STC   R0,CKPINCNO              RESTORE                         47600020
         SPACE 3                                                        48000020
         LH    R6,CKPINCLN              LENGTH OF INCIDENT RECORD       48400020
         GETMAIN EC,LV=(R6),A=CKPLDRB,MF=(E,CKPGETML)                   48800020
         SPACE 3                                                        49200020
         LTR   R15,R15                  CHECK RETURN CODE               49600020
         LR    R14,R4                   RESTORE REG                     50000020
         LR    R15,R5                   RESTORE REG                     50400020
         DROP  R5                                                       50800020
         USING IEDQNG,R15               RESTORE BASE                    51200020
         BNZ   QNG60                    BRANCH IF NO CORE ALLOCATED     51600020
         L     R4,CKPLDRB               GET ADDRESS OF DISK RECORD      52000020
         USING IEDQCDRD,R4              BASE FOR CKPT DISK RECORD       52400020
         SPACE 3                                                        52800020
*BUILD INCIDENT RECORD FOR LCB                                          53200020
         SPACE                                                          53600020
         MVI   CDRKEY,CDRLCB            SET KEY FIELD                   54000020
         STH   R7,CDROFFS               PUT IN OFFSET                   54400020
         MVC   CDRSTAT,TRMSTATE         MOVE TERM STATUS TO RCD    0720 54800020
         MVC   CDRSEQIN(4),TRMINSEQ     MOVE SEQ NUMBERS TO RCD    1008 55000020
         TM    TRMSTATE,TRMOPTFN        CHECK FOR OPTION FIELDS         55200020
         BZ    QNG48                    BRANCH IF NOT USED              55600020
         SPACE 3                                                        56000020
*MOVE OPTION FIELDS TO DISK RECORD (USES REGISTERS 1,4,5,6,7,8,10,      56400020
*11,13)                                                                 56800020
         SPACE                                                          57200020
*SET UP FOR LOOP                                                        57600020
         SPACE                                                          58000020
         SR    R11,R11                                                  58400020
         IC    R11,TRMOPNO              COMPARAND                       58800020
         L     R13,AVTOPTPT              ADDRESS OF OPTION TABLE        59200020
         L     R7,4(R13)                ADDRESS OF OPT LENGTH TABLE     59600020
         LH    R1,TRMOPTBL              OFFST TO OPT FOR THIS ENTRY     60000020
         N     R1,AVTCLRHI              CLEAR HIGH ORDER HALF WORD      60400020
         AR    R13,R1                   ADD OFFSET TO ADDRESS           60800020
         SR    R1,R1                    CLEAR                           61200020
         SR    R10,R10                  CLEAR-LENGTH FOR MOVE           61600020
         LA    R6,TRMOPT                GET BEGINNING OF OFFSETS        62000020
         SPACE 3                                                        62400020
*BEGINNING OF LOOP THROUGH OPTION TABLE OFFSETS FOR THIS TERM           62800020
         SPACE                                                          63200020
QNG40    EQU   *                                                        63600020
         LR    R5,R13                   INITIALIZE                      64000020
         IC    R1,0(R6)                 OPTION OFFSET                   64400020
         CLI   0(R6),X'FF'              CHECK FOR UNUSED ENTRY          64800020
         BE    QNG45                    BRANCH IF UNUSED                65200020
         AR    R5,R1                    ADDRESS OF OPTION ENTRY         65600020
         IC    R10,0(R7)                GET LENGTH OF THIS OP ENTRY     66000020
         CLI   1(R7),X'D0'              CHECK OPTION TYPE          1111 66060020
         BH    QNG43                    BRANCH IF NOT ADDRESS TYPE 1111 66120020
         CLI   1(R7),X'80'              CHECK OPTION TYPE          1111 66180020
         BH    QNG45                    BRANCH IF ADDRESS TYPE     1111 66240020
QNG43    EQU   *                                                   1111 66300020
         EX    R10,QNGMOVE              MOVE OPTIONS TO DISK RECORD     66400020
         LA    R4,1(R4,R10)             ADD LENGTH MOVED TO BASE OF    X66800020
                                        DISK RECORD                     67200020
QNG45    EQU   *                                                        67600020
         LA    R7,CKPOPLTL(0,R7)        GET OPT LNGTH TABLE ENTRY       68000020
         LA    R6,1(0,R6)                                               68400020
         BCT   R11,QNG40                SUB FROM COUNT OF ENTRIES       68800020
         SPACE                                                          69200020
*END OF LOOP THROUGH OPTION TABLE OFFSETS FOR THIS TERM ENTRY           69600020
         SPACE 3                                                        70000020
QNG48    EQU   *                                                   0720 70400020
         LA    R15,CKPIOQM              OFFSET FOR ENQUEUE RTN          70800020
         BR    R14                      RETURN TO EXECUTOR              71200020
         SPACE 3                                                        71600020
*THE TERMINAL ENTRY CANNOT BE IDENTIFIED.NO CKPT IS TAKEN.         0720 72000020
         SPACE                                                          72400020
QNG50    EQU   *                                                        72800020
         OI    CKPLREB,CKPNDRB          INDICATE NO DISK RCB BUILT      73200020
         LA    R15,CKPNOTIF             OFFSET FOR NOTIFICATION RTN     73600020
         BR    R14                      RETURN TO EXECUTOR              74000020
         SPACE 3                                                        74400020
*NO GETMAIN AREA ALLOCATED. SET UP FOR NO GETMAIN RTN                   74800020
         SPACE                                                          75200020
QNG60    EQU   *                                                        75600020
         LA    R15,CKPNOCOR             OFFSET FOR RTN                  76000020
         BR    R14                      RETURN TO EXECUTOR              76400020
         SPACE 3                                                        76800020
*THERE ARE NO MORE INCIDENT RECORDS AVAILABLE-GO TO INCIDENT            77200020
*OVERFLOW RTN TO SET UP FOR TOTAL.                                      77600020
         SPACE                                                          78000020
QNG70    EQU   *                                                        78400020
         LA    R15,CKPNOINC             OFFSET FOR RTN                  78800020
         BR    R14                      RETURN TO EXECUTOR              79200020
         SPACE                                                          79600020
QNGMOVE  MVC   CDROPTN(0),0(R5)         MOVE TO RECORD FROM OPT TBL     80000020
         PRINT NOGEN                                                    80400020
         TAVTD                                                          80800020
         TCKPD 3330                                                     81200000
         TLCBD                                                          81600020
         TTRMD                                                          82000020
         END                                                            82400020
