OM01     TITLE '''IEDQOM'' - TERMNAME TABLE SORT ROUTINE'               00100020
IEDQOM   CSECT                                                          00200020
*                                                                       00300020
*STATUS - CHANGE LEVEL 0                                              * 00400020
*                                                                     * 00500020
*FUNCTION/OPERATION - THIS ROUTINE SORTS THE TERMNAME TABLE           * 00600020
*   INTO ALPHABETICAL SEQUENCE.  IT RE-CALCULATES THE TERMNAME        * 00700020
*   TABLE OFFSETS FOR DISTRIBUTION LISTS, CASCADE LISTS, LINE         * 00800020
*   ENTRIES, AND INVITATION LISTS AS WELL AS RE-CALCULATING ALTERNATE * 00900020
*   DESTINATION OFFSETS AND TESTING ALL ALTERNATE DESTINATIONS        * 01000020
*   FOR ACCEPT CAPABILITIES.  IT INITIALIZES CERTAIN FIELDS IN        * 01100020
*   THE TERMNAME TABLE THAT ARE NECESSARY FOR THE BINARY SEARCH       * 01200020
*   ROUTINE AND CHECKS FOR THE PRESENCE OF A PRIMARY OPERATOR         * 01300020
*   CONTROL TERMINAL.  IF A DEAD LETTER QUEUE IS DEFINED              * 01400020
*   IEDQOM COMPUTES THE NUMBER WITHIN THE TERMNAME TABLE              * 01500020
*   OF THE DLQ ENTRY AND STORES THIS NUMBER IN THE AVT.               * 01600020
*                                                                     * 01700020
*ENTRY POINT - CALLED ONLY FROM 'IEDQOA'                              * 01800020
*                                                                     * 01900020
*INPUT                                                                * 02000020
*   R1 - ADDRESS OF THE AVT                                           * 02100020
*   R13- ADDRESS OF AN 18 WORD SAVE AREA                              * 02200020
*                                                                     * 02300020
*OUTPUT - THE TERMNAME TABLE WILL NOW BE IN ALPHABETICAL ORDER,       * 02400020
*   AND ANY OFFSETS IN CASCADE LISTS, DISTRIBUTION LISTS, OR          * 02500020
*   INVITATION LISTS WHICH FORMERLY POINTED TO A SPECIFIC ENTRY       * 02600020
*   IN THE TERMNAME TABLE WILL HAVE BEEN RE-CALCULATED AND            * 02700020
*   WILL POINT TO THE  CORRECT ENTRY IN THE SORTED TERMNAME TABLE.    * 02800020
*                                                                     * 02900020
*EXTERNAL ROUTINES - NONE                                             * 03000020
*                                                                     * 03100020
         EJECT                                                          03200020
*EXITS - NORMAL                                                       * 03300020
*   RETURN IS MADE TO THE LINKING ROUTINE WITH REGISTER 15            * 03400020
*   CONTAINING A RETURN CODE OF ZERO.                                 * 03500020
*                                                                     * 03600020
*        ERROR                                                        * 03700020
*   RETURN IS MADE TO THE LINKING ROUTINE WITH REGISTER 15            * 03800020
*   CONTAINING A NON-ZERO RETURN CODE.                                * 03900020
*                                                                     * 04000020
*       12   SUFFICIENT MAIN STORAGE WAS NOT AVAILABLE TO             * 04100020
*            SATISFY A GETMAIN REQUEST.                               * 04200020
*                                                                     * 04300020
*       16   A TERMINAL DEFINITION ERROR.  AN ERROR MESSAGE           * 04400020
*            OF THE FORM'IEDQ065I "TERMINAL NAME" ILLEGAL             * 04500020
*            DESTINATION' WILL BE WRITTEN OUT ON THE CONSOLE          * 04600020
*            FOR EACH ENTRY IN THE TERMINAL TABLE THAT IS IN          * 04700020
*            ERROR.                                                   * 04800020
*                                                                     * 04900020
*       20   AN ERROR IN DEFINING THE PRIMARY OPERATOR                * 05000020
*            CONTROL TERMINAL.                                        * 05100020
*                                                                     * 05200020
*                   THE TERMINAL DEFINED AS THE PRIMARY OPERATOR      * 05300020
*                   CONTROL TERMINAL COULD NOT BE FOUND IN THE        * 05400020
*                   TERMNAME TABLE                                    * 05500020
*                                                                     * 05600020
*                   THE PRIMARY OPERATOR CONTROL TERMINAL DID         * 05700020
*                   NOT HAVE SEND AND ACCEPT CAPABILITIES             * 05800020
*                                                                     * 05900020
*                   THE PRIMARY OPERATOR CONTROL TERMINAL WAS NOT     * 06000020
*                   DEFINED AS BEING A POSSIBLE SECONDARY OPERATOR    * 06100020
*                   CONTROL TERMINAL                                  * 06200020
*                                                                     * 06300020
*TABLES/WORKAREAS - THE ADDRESS VECTOR TABLE IS A RESIDENT            * 06400020
*   VECTOR LIST USED TO LOCATE CERTAIN ADDRESSES WHICH ARE            * 06500020
*   NECESSARY FOR SORTING THE TERMNAME TABLE.  THE TERMNAME           * 06600020
*   TABLE CONTAINS THE NAMES OF ALL TERMINALS IN THE                  * 06700020
*   SYSTEM.  THE TERMINAL TABLE CONSISTS OF BLOCKS OF DEVICE-         * 06800020
*   DEPENDENT INFORMATION ABOUT EACH TERMINAL IN THE TCAM             * 06900020
*   SYSTEM.  THE OFFSET TABLE IS GENERATED BY IEDQOM AND IS           * 07000020
*   USED TO KEEP TRACK OF ALL OFFSETS TO THE TERMNAME TABLE           * 07100020
*   THAT ARE GENERATED BY MACRO EXPANSION                             * 07200020
*                                                                     * 07300020
*ATTRIBUTES - NON-RESIDENT, NON-REUSABLE, AND NON-REFRESHABLE         * 07400020
*                                                                     * 07500020
*NOTES - THIS ROUTINE IS ON SYS1.LINKLIB AND IS LINKED TO BY          * 07600020
*   IEDQOA, THE TCAM NON-RESIDENT START UP ROUTINE WHICH WAS          * 07700020
*   ITSELF LINKED TO BY INTRO.                                        * 07800020
*                                                                     * 07900020
         EJECT                                                          08000020
*        REGISTER USAGE                                                 08100020
*                                                                       08200020
RO       EQU   0                        GENERAL PURPOSE REGISTER        08300020
RPRESENT EQU   1                        POINTER TO PRESENT ENTRY IN     08400020
*                                       TERMNAME TABLE                  08500020
RLENGTH  EQU   2                        LENGTH IN BYTES OF A FULL       08600020
*                                         ENTRY IN TERMNAME TABLE       08700020
RLEN1    EQU   3                        LENGTH OF A TERMNAME ENTRY      08800020
*                                         MINUS ONE                     08900020
RLEN3    EQU   4                        LENGTH OF A TERMNAME ENTRY      09000020
*                                         MINUS THREE                   09100020
RENDTAB  EQU   5                        POINTER TO THE LAST ENTRY       09200020
*                                         IN THE TERMNAME TABLE         09300020
RDIVIDE  EQU   6                        EVEN NUMBERED REGISTER FOR      09400020
*                                         DIVIDE OPERATION              09500020
ROTNEXT  EQU   6                        POINTER TO NEXT ENTRY IN        09600020
*                                         OFFSET TABLE                  09700020
RTOT     EQU   7                        TOTAL ENTRIES IN TERMNAME       09800020
*                                         TABLE                         09900020
RFIRST   EQU   8                        ADDRESS OF FIRST ENTRY IN       10000020
*                                       TERMNAME TABLE                  10100020
R9       EQU   9                        AVT BASE REGISTER               10200020
RGETAREA EQU   10                       ENDING ADDRESS OF THE           10300020
*                                         OFFSET TABLE                  10400020
RWORK    EQU   11                       SCRATCH REGISTER                10500020
*                                                                       10600020
RBASE    EQU   12                       ROUTINE BASE REGISTER           10700020
RTERMNAM EQU   13                       POINTER TO THE BEGINNING OF     10800020
*                                         THE TERMNAME TABLE            10900020
ROTNOW   EQU   14                       POINTER TO PRESENT ENTRY IN     11000020
*                                         OFFSET TABLE                  11100020
RNEXT    EQU   15                       POINTER TO NEXT ENTRY IN        11200020
*                                         THE TERMNAME TABLE            11300020
R15      EQU   15                                                       11400020
*                                                                       11500020
         USING IHADCB,RENDTAB                                           11600020
         USING IEDQQCB,RLEN1            QCB DSECT                       11700020
         USING IEDQAVTD,R9                                              11800020
         USING IEDQTNTD,RTERMNAM                                        11900020
         USING IEDQTRM,RNEXT            TERMINAL ENTRY DSECT            12000020
*                                                                       12100020
          SAVE  (14,12),,IEDQOM.INTRO.SORT.05/02/69                     12200020
*                                                                       12300020
         BALR  RBASE,0                                                  12400020
         USING *,RBASE                                                  12500020
         EJECT                                                          12600020
         LA    R9,3*AVTSVSIZ(RPRESENT)   POINT TO AVTSAVE 4             12700020
         ST    RTERMNAM,4(0,R9)         ADDRESS OF CALLERS SAVE AREA    12800020
         ST    R9,8(0,RTERMNAM)         ADDRESS OF MY SAVE AREA         12900020
*                                                                       13000020
         L     RTERMNAM,AVTRNMPT        LOAD THE ADDRESS OF THE         13100020
*                                         TERMNAME TABLE                13200020
         SR    RLEN3,RLEN3              CLEAR THE LENGTH REGISTER       13300020
         IC    RLEN3,TNTENLEN           INSERT THE LENGTH OF EACH       13400020
*                                         TERMNAME ENTRY                13500020
         LA    RLENGTH,3(RLEN3)         GET THE LENGTH OF THE           13600020
*                                         ENTRY NAME AND ADDRESS        13700020
         LA    RLEN1,2(RLEN3)           GET THE LENGTH OF THE           13800020
*                                         ENTRY NAME AND ADDRESS        13900020
*                                         MINUS 1                       14000020
         BCTR  RLEN3,0                  SUBTRACT ONE TO EXECUTE         14100020
*                                         THE COMPARISON                14200020
         L     RENDTAB,TNTENLEN         LOAD ADDRESS OF LAST ENTRY      14300020
*                                         IN TERMNAME TABLE             14400020
         LA    RENDTAB,0(RENDTAB)       CLEAR HIGH ORDER BYTE OF        14500020
*                                         ADDRESS OF LAST ENTRY         14600020
         LR    RTOT,RENDTAB             COPY ADDRESS OF LAST ENTRY      14700020
         LA    RFIRST,TNTFIRST          ADDRESS OF FIRST ENTRY IN       14800020
*                                         TERMNAME TABLE                14900020
         EJECT                                                          15000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     15100020
*                                                                 *     15200020
*      THIS NEXT SECTION OF CODE WILL CALCULATE THE TOTAL         *     15300020
*      NUMBER OF ENTRIES IN THE TERMNAME TABLE, GETMAIN           *     15400020
*      AN OFFSET TABLE, AND INITIALIZE THE TABLE.                 *     15500020
*                                                                 *     15600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     15700020
         SR    RTOT,RFIRST              SUBTRACT THE ADDRESS OF THE     15800020
*                                         FIRST ENTRY FROM THE          15900020
*                                         ADDRESS OF THE LAST ENTRY     16000020
         SR    RDIVIDE,RDIVIDE          CLEAR DIVIDE REGISTER           16100020
         DR    RDIVIDE,RLENGTH          DIVIDE THE LENGTH OF TABLE      16200020
*                                         BY THE LENGTH OF AN ENTRY     16300020
*                                                                       16400020
         LA    RTOT,ONE(RTOT)           ADD ONE TO THE RESULT TO        16500020
*                                         GET THE ACTUAL NUMBER         16600020
*                                         OF ENTRIES                    16700020
         STH   RTOT,TNTLEN              STORE THE TOTAL NUMBER OF       16800020
*                                         TERMNAME ENTRIES              16900020
*                                         IN THE TERMNAME TABLE         17000020
         LA    RPRESENT,ONE             LOAD A COMPARISON VALUE         17100020
         CR    RPRESENT,RTOT            TEST FOR JUST ONE ENTRY IN      17200020
*                                         THE TERMNAME TABLE            17300020
         BE    PRIMOPT                  BRANCH IF THERE IS JUST ONE     17400020
*                                         ENTRY, AND TEST FOR A         17500020
*                                         PRIMARY OPERATOR CONTROL      17600020
*                                         TERMINAL                      17700020
         LR    RPRESENT,RTOT            COPY THE NUMBER OF ENTRIES      17800020
         SLL   RPRESENT,ONE             MULTIPLY ENTRIES BY 2 TO        17900020
*                                         GET SIZE OF OFFSET TABLE      18000020
         LA    RO,AVTGETMN+4            LOAD ADDRESS OF WORD TO         18100020
*                                         RECEIVE THE ADDRESS OF        18200020
*                                         THE GETMAINED AREA            18300020
         BAL   ROTNOW,AVTPAR            SET UP PARAMETER LIST           18400020
*                                                                       18500020
         L     RGETAREA,AVTGETMN+4      LOAD THE ADDRESS OF THE         18600020
*                                         OFFSET TABLE                  18700020
         LA    RWORK,ONE                FIRST OFFSET VALUE              18800020
         ST    RGETAREA,AVTSAVE4+16     STORE BEGINNING ADDRESS OF      18900020
*                                         THE OFFSET TABLE              19000020
         LR    RPRESENT,RTOT            COPY THE NUMBER OF ENTRIES      19100020
*                                         TERMNAME ENTRIES              19200020
OFFSTORE EQU   *                                                        19300020
         STH   RWORK,0(RGETAREA)        STORE FIRST/NEXT VALUE IN       19400020
*                                         THE OFFSET TABLE              19500020
         BCT   RPRESENT,UPDATE          REDUCE NUMBER OF ENTRIES        19600020
*                                         BY ONE                        19700020
         EJECT                                                          19800020
FIRSTENT EQU   *                                                        19900020
         LR    RPRESENT,RFIRST          ADDRESS OF THE FIRST ENTRY      20000020
*                                         IN THE TERMNAME TABLE         20100020
         LA    RNEXT,0(RLENGTH,RFIRST)  ADDRESS OF THE SECOND ENTRY     20200020
*                                         IN THE TERMNAME TABLE         20300020
         L     ROTNOW,AVTGETMN+4        LOAD ADDRESS OF OFFSET TABLE    20400020
         LA    ROTNEXT,2(ROTNOW)        LOAD THE ADDRESS OF THE         20500020
*                                         SECOND ENTRY IN OFFSET TBL    20600020
         MVI   AVTGETMN,X'00'           CLEAR THE SWAP INDICATOR        20700020
*                                                                       20800020
EXECT    EX    RLEN3,COMPENT            EXECUTE A COMPARISON OF THE     20900020
*                                         TWO TERMNAME ENTRIES          21000020
         BH    SWAP                     THE TWO ENTRIES ARE NOT IN      21100020
*                                         ALPHABETICAL ORDER            21200020
*                                                                       21300020
COMTAB   EQU   *                                                        21400020
         CR    RNEXT,RENDTAB            CHECK FOR END OF THE            21500020
*                                         TERMNAME TABLE                21600020
         BNL   CHKSWAP                  IF END OF TABLE, GO TO          21700020
*                                         CHECK SWAP INDICATOR          21800020
         LR    RPRESENT,RNEXT           UPDATE POINTER TO TERMNAME      21900020
*                                         ENTRY N                       22000020
         LA    RNEXT,0(RLENGTH,RNEXT)   UPDATE POINTER TO TERMNAME      22100020
*                                         ENTRY N+1                     22200020
         LR    ROTNOW,ROTNEXT           UPDATE PRESENT OFFSET POINTER   22300020
         LA    ROTNEXT,TWO(ROTNEXT)     UPDATE NEXT OFFSET POINTER      22400020
         B     EXECT                   COMPARE NEXT 2 ENTRIES           22500020
CHKSWAP  TM    AVTGETMN,X'80'           TEST SWAP INDICATOR             22600020
         BO    FIRSTENT                 GO THRU TABLE ONCE MORE         22700020
         EJECT                                                          22800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     22900020
*                                                                 *     23000020
*       THIS SECTION OF CODE STORES NEW VALUES INTO THE ALTERNATE *     23100020
*       TERMINAL OFFSET FIELD IN THE TERMINAL TABLE AND TESTS THE *     23200020
*       STATUS OF EACH TERMINAL LISTED AS AN ALTERNATE DESTINATION*     23300020
*                                                                 *     23400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     23500020
*                                                                       23600020
         LR    ROTNEXT,RTOT             LOAD TOTAL NUMBER OF            23700020
*                                          ENTRIES IN TERMNAME TABLE    23800020
         MVI   AVTGETMN,X'00'           ZERO HIGH ORDER BYTE            23900020
ALTSET   EQU   *                                                        24000020
         LA    RPRESENT,MSGC            ADDRESS OF THE ERROR MESSAGE    24100020
         EX    RLEN3,ERRSET             USE AN EXECUTE TO MOVE THE      24200020
*                                         TERMINAL NAME TO THE          24300020
*                                        ERROR MESSAGE                  24400020
         LA    RFIRST,1(RLEN3,RFIRST)   BUMP THE POINTER TO THE         24500020
*                                         ADDRESS PORTION OF THE        24600020
*                                         ENTRY                         24700020
         MVC   AVTGETMN+1(3),0(RFIRST)  MOVE TERMINAL TABLE             24800020
*                                         ADDRESS OF ENTRY INTO         24900020
*                                         A SCRATCH WORD                25000020
         L     RNEXT,AVTGETMN           LOAD ADDRESS OF TERM. ENTRY     25100020
         TM    TRMSTATE,SINGLINE        IS THIS ENTRY EITHER A          25200020
*                                         SINGLE ENTRY OR A LINE        25300020
*                                         ENTRY                         25400020
         BZ    TESTLIST                 YES, BRANCH                     25500020
         TM    TRMSTATE,LOGTYPE         IS THIS A LOG ENTRY             25600020
         BO    LOADAD                   YES, BRANCH                     25700020
         TM    TRMSTATE,CORDLIST        IS THIS ENTRY EITHER A          25800020
*                                         CASCADE OR A DISTRIBUTION     25900020
*                                         LIST ENTRY                    26000020
         BO    CASDISTL                 GO TO UPDATE ANY CASCADE OR     26100020
*                                       DISTRIBUTION LIST ENTRIES       26200020
ALTDTEST EQU   *                                                        26300020
         CLC   TRMALTD(2),AVTFZERO      HAS AN ALTERNATE DESTINATION    26400020
*                                         BEEN SPECIFIED                26500020
         BZ    FOUNDMAT                 NO, BRANCH                      26600020
LOADAD   EQU   *                                                        26700020
         L     RPRESENT,AVTSAVE4+16     LOAD THE BEGINNING ADDRESS      26800020
*                                         OF THE OFFSET TABLE           26900020
         LR    RO,RPRESENT              COPY THE BEGINNING ADDRESS      27000020
CLCOFF   EQU    *                                                       27100020
         CLC   TRMALTD(2),0(RPRESENT)   COMPARE THE ALTERNATE           27200020
*                                         DESTINATION OFFSET TO THE     27300020
*                                         FIRST/NEXT ENTRY IN THE       27400020
*                                         OFFSET TABLE                  27500020
         BNE   ENDTAB                   CHECK FOR END OF THE            27600020
*                                         OFFSET TABLE                  27700020
         SR    RPRESENT,RO              PICK UP THE OFFSET FROM         27800020
*                                          START OF OFFSET TABLE        27900020
         LA    RPRESENT,TWO(RPRESENT)   ADD 2 TO THE DIFFERENCE         28000020
         SRL   RPRESENT,ONE             DIVIDE BY TWO TO GET NEW        28100020
*                                         INDEX FOR ALTERNATE           28200020
         STH   RPRESENT,TRMALTD         STORE THE NEW ALTERNATE         28300020
*                                         DESTINATION OFFSET IN THE     28400020
*                                         TERMINAL ENTRY                28500020
         TM    AVTGETMN,ILISTNOW        ARE WE CURRENTLY SORTING AN     28600020
*                                         INVITATION LIST               28700020
         BO    ALCONT                   YES, BRANCH                     28800020
         TM    AVTGETMN,CDLSTNOW        ARE WE CURRENTLY SORTING A      28900020
*                                         CASCADE OR A DISTRIBUTION     29000020
*                                         LIST                          29100020
         BO    CASDIST2                 YES, BRANCH                     29200020
         TM    TRMSTATE,LOGTYPE         IS THIS A LOG ENTRY             29300020
         BO    SETLOG                   YES, BRANCH                     29400020
         L     RTERMNAM,AVTRNMPT        LOAD THE ADDRESS OF THE         29500020
*                                         TERMNAME TABLE                29600020
         LA    RNEXT,TNTFIRST           SET THE ADDRESS OF THE FIRST    29700020
*                                         ENTRY IN THE TERMNAME         29800020
*                                         TABLE                         29900020
        BCTR  RPRESENT,0               SUBTRACT 1 FROM OFFSET VALUE     30000020
         LTR   RPRESENT,RPRESENT        IS ALTERNATE DESTINATION        30100020
*                                       THE FIRST ENTRY IN TABLE        30200020
         BE    ENTRY1                   YES, BRANCH                     30300020
LOOP     EQU   *                                                        30400020
        LA    RNEXT,0(RLENGTH,RNEXT)   GO THRU TERMNAME TABLE           30500020
        BCT   RPRESENT,LOOP            GO TO NEXT ENTRY                 30600020
ENTRY1   EQU   *                                                        30700020
         LA    RNEXT,1(RLEN3,RNEXT)     BUMP THE POINTER TO THE         30800020
*                                         ADDRESS PORTION OF THE        30900020
*                                         ENTRY                         31000020
        MVC   AVTGETMN+1(3),0(RNEXT)   MMOVE TERMNAL TABLE              31100020
*                                        ADDRESS OF ENTRY INTO A        31200020
*                                        SCRATCH WORD                   31300020
        L     RNEXT,AVTGETMN           LLOAD THE ADDRESS OF THE         31400020
*                                         TERMINAL ENTRY                31500020
         TM    TRMSTATE,TRMACPTN        IS THIS TERMINAL ABLE TO        31600020
*                                         ACCEPT                        31700020
         BNO   TERMERR                 UNABLE TO ACCEPT                 31800020
FOUNDMAT EQU   *                                                        31900020
         LA    RFIRST,3(RFIRST)         BUMP TERMINAL I.D. POINTER      32000020
*                                         TO NEXT ENTRY                 32100020
         BCT   ROTNEXT,ALTSET           REDUCE ENTRY COUNT AND GO       32200020
*                                         TO NEXT ID ENTRY              32300020
         TM    AVTGETMN,ALTDSTER        HAVE WE DETECTED ANY ERRORS     32400020
*                                         WHILE RESETTING THE           32500020
*                                         ALTERNATE DESTINATIONS        32600020
         BO    TERMERR1                 YES, BRANCH                     32700020
         EJECT                                                          32800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     32900020
*                                                                       33000020
*        THIS ROUTINE SETS UP CERTAIN FIELDS IN THE FIRST OF THE        33100020
*        TERMNAME TABLE NECESSARY FOR THE BINARY SEARCH ROUTINE         33200020
*                                                                       33300020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     33400020
PRIMOPT  EQU   *                                                        33500020
L        L     RTERMNAM,AVTRNMPT        LOAD THE ADDRESS OF THE         33600020
*                                         TERMNAME TABLE                33700020
         SR    ROTNEXT,ROTNEXT          CLEAR POWER COUNTER             33800020
         LH    RPRESENT,TNTLEN          LOAD THE TOTAL NUMBER OF        33900020
*                                         ENTRIES IN THE TABLE          34000020
         LR    RTOT,RPRESENT            COPY THE ENTRY COUNT            34100020
TNTLOOP  EQU   *                                                        34200020
         SRL   RPRESENT,ONE             DIVIDE ENTRIES BY 2             34300020
         LA    ROTNEXT,ONE(ROTNEXT)     INCREMENT THE POWER OF 2        34400020
*                                         COUNTER BY 1                  34500020
         LTR   RPRESENT,RPRESENT        TEST FOR ZERO                   34600020
         BNE   TNTLOOP                  DIVIDE IS NOT FINISHED          34700020
         LA    RPRESENT,ONE             PRIME OPTIMUM ENTRY COUNTER     34800020
TNTLOOP2 EQU   *                                                        34900020
         SLL   RPRESENT,ONE             MULTIPLY ENTRIES BY 2           35000020
         BCT   ROTNEXT,TNTLOOP2         REDUCE POWER COUNTER BY ONE     35100020
         LR    ROTNEXT,RPRESENT         COPY OPTIMUM+1 NUMBER           35200020
         SRL   RPRESENT,ONE             DIVIDE OPTIMUM+1 NUMBER BY      35300020
*                                         TWO                           35400020
         BCTR  RPRESENT,0               SUBTRACT 1 FROM THE RESULT      35500020
         SRL   ROTNEXT,SHIFT2           DIVIDE OPTIMUM BY 4             35600020
         STH   ROTNEXT,TNTSRCHX         STORE SEARCH EXTENT FACTOR      35700020
         SR    RNEXT,RNEXT              CLEAR ENTRY LENGTH REGISTER     35800020
         IC    RNEXT,TNTENLEN           SAVE ENTRY LENGTH               35900020
         LA    RFIRST,TNTFIRST          ADDRESS OF THE FIRST ENTRY      36000020
*                                         IN THE TERMNAME TABLE         36100020
         LTR   ROTNEXT,ROTNEXT          TEST FOR 1 ENTRY                36200020
         BNE   TERMAD                   THERE IS MORE THAN 1 ENTRY      36300020
TERMSTOR EQU   *                                                        36400020
         ST    RFIRST,TNTENLEN          STORE IN THE TERMNAME TABLE     36500020
         STC   RNEXT,TNTENLEN           RESTORE ENTRY LENGTH            36600020
         B     AVTTEST                                                  36700020
TERMAD    EQU   *                                                       36800020
         AR    RFIRST,RLENGTH           BUMP THE ADDRESS POINTER        36900020
          BCT   RPRESENT,TERMAD          BUMP THE POINTER AGAIN         37000020
         B     TERMSTOR                 STORE THE ADDRESS OF THE        37100020
*                                          MIDDLE ENTRY                 37200020
         EJECT                                                          37300020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     37400020
*                                                                 *     37500020
*                  THIS ROUTINE CHECKS FOR THE PRESENCE           *     37600020
*                  OF A PRIMARY OPERATOR CONTROL TERMINAL         *     37700020
*                  BEING SPECIFIED IN THE AVT                           37800020
*                                                                 *     37900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     38000020
AVTTEST  EQU   *                                                        38100020
         CLI   AVTDOUBX,X'00'           TEST FOR A PRIMARY OPERATOR     38200020
*                                         CONTROL TERMINAL              38300020
         BE    BEGINDLQ                 NO POC TERMINAL, BRANCH         38400020
         CLC   AVTDOUBX(EIGHT),SYSCON   HAS SYSCON BEEN SPECIFIED       38500020
*                                         AS THE PRIMARY OPERATOR       38600020
*                                         CONTROL TERMINAL              38700020
         BE    BEGINDLQ                 YES, BRANCH                     38800020
         LR    RLEN1,RTOT               COPY THE NUMBER OF ENTRIES      38900020
*                                         IN THE TERMNAME TABLE         39000020
         LA    RPRESENT,AVTDOUBX        LOAD THE ADDRESS OF PRIMARY     39100020
*                                       OPERATOR CONTROL TERMINAL       39200020
         LA    RNEXT,TNTFIRST           LOAD ADDRESS OF FIRST ENTRY     39300020
*                                         IN TERMNAME TABLE             39400020
         BAL   RWORK,COMPSUBR           BRANCH TO THE COMPARISON        39500020
*                                         SUBROUTINE                    39600020
         STH   RO,AVTOPCON              STORE OFFSET IN AVT             39700020
         LA    RNEXT,ONE(RLEN3,RNEXT)   BUMP POINTER TO THE             39800020
*                                         ADDRESS PORTION OF ENTRY      39900020
         MVC   AVTGETMN+1(3),0(RNEXT)   MOVE TERMINAL TBL ADDRESS       40000020
*                                         ADDRESS TO SCRATCH AREA       40100020
         L     RWORK,AVTGETMN           LOAD TERMINAL ADDRESS           40200020
         TM    0(RWORK),SENDACPT        DOES THIS TERMINAL HAVE SEND    40300020
*                                         AND ACCEPT CAPABILITIES       40400020
         BNO   POCERR                   GO TO ERROR CODE ROUTINE        40500020
         TM    0(RWORK),SECOPCTL        HAS THIS TERMINAL BEEN          40600020
*                                         DEFINED AS A SECONDARY        40700020
*                                         OPERATOR CONTROL TERMINAL     40800020
         BZ    POCERR                   NO, THEN THERE IS AN ERROR      40900020
         LR    RTOT,RLEN1               RESTORE THE COUNT OF THE        41000020
*                                         NUMBER OF TERMINAL ENTRIES    41100020
         EJECT                                                          41200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     41300020
*                                                                 *     41400020
*        THIS SECTION OF CODE TESTS FOR THE PRESENCE OF AN        *     41500020
*        ENTRY IN THE TERMNAME TABLE WHICH HAS BEEN               *     41600020
*        DEFINED AS THE DEAD LETTER QUEUE TERMINAL                *     41700020
*                                                                 *     41800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     41900020
BEGINDLQ EQU   *                                                        42000020
         LA    RPRESENT,AVTDLQ          LOAD THE ADDRESS OF THE         42100020
*                                         DEAD LETTER QUEUE             42200020
*                                         TERMINAL NAME                 42300020
         NC    0(8,RPRESENT),0(RPRESENT)  HAS THE USER DEFINED A        42400020
*                                         TERMINAL AS A DEAD LETTER     42500020
*                                         QUEUE                         42600020
         BE    CODEFIX                  NO, BRANCH                      42700020
         LA    RNEXT,TNTFIRST           LOAD THE ADDRESS OF THE         42800020
*                                         FIRST ENTRY IN THE            42900020
*                                         TERMNAME TABLE                43000020
         BAL   RWORK,COMPSUBR           BRANCH TO THE COMPARISON        43100020
*                                         SUBROUTINE                    43200020
         LA    RPRESENT,TNTOFF          LOAD THE ADDRESS OF THE         43300020
*                                         FIRST ENTRY IN THE            43400020
*                                         TERMNAME TABLE                43500020
         SR    RO,RPRESENT              SUBTRACT THE ADDRESS OF         43600020
*                                         THE FIRST ENTRY FROM THE      43700020
*                                         DLQ OFFSET                    43800020
         LR    RPRESENT,RO              COPY THE TERMINAL OFFSET        43900020
         SR    RO,RO                    CLEAR THIS REGISTER FOR         44000020
*                                         THE DIVISION                  44100020
         DR    RO,RLENGTH               DIVIDE THE TERMINAL OFFSET      44200020
*                                         BY THE LENGTH OF A            44300020
*                                         TERMNAME TABLE ENTRY          44400020
         LA    RPRESENT,ONE(RPRESENT)   INCREMENT THE TERMINAL          44500020
*                                         BY ONE                        44600020
         STH   RPRESENT,AVTDLQX         STORE THE TERMINAL NUMBER       44700020
*                                         OF THE DEAD LETTER QUEUE      44800020
*                                         IN THE AVT                    44900020
         AR    RNEXT,RLEN3              ACCESS THE ADDRESS OF THE       45000020
*                                         TERMINAL ENTRY                45100020
         MVC   AVTGETMN+1(3),1(RNEXT)   MOVE THE TERMINAL ADDRESS       45200020
*                                         OF THE DEAD LETTER QUEUE      45300020
*                                         ENTRY TO A SCATCH WORD        45400020
         L     RNEXT,AVTGETMN           LOAD THIS ADDRESS INTO          45500020
*                                         REGISTER                      45600020
         L     RLEN1,0(RNEXT)           LOAD THE ADDRESS OF THE QCB     45700020
*                                         FOR THIS TERMINAL             45800020
         TM    QCBDSFLG,X'70'           IS THIS A TSO TERMINAL          45900020
         BZ    DLQMSG                   YES, BRANCH                     46000020
         EJECT                                                          46100020
CODEFIX  EQU   *                                                        46200020
         SR    R15,R15                  SET A GOOD RETURN CODE          46300020
RTEND    EQU   *                                                        46400020
         L     RTERMNAM,4(0,R9)         LOAD ADDRESS OF CALLERS         46500020
*                                         SAVE AREA                     46600020
         RETURN (14,12),T,RC=(15)                                       46700020
         EJECT                                                          46800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     46900020
*                                                                 *     47000020
*        THIS SECTION OF CODE RESETS THE TERMNAME OFFSETS         *     47100020
*        FOR ALL ENTRIES IN EITHER A CASCADE OR A DISTRIBUTION    *     47200020
*                            LIST                                 *     47300020
*                                                                 *     47400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     47500020
CASDISTL EQU   *                                                        47600020
         LA    RTOT,TWO                 LOAD A DISPLACEMENT OF 2        47700020
         SR    RNEXT,RTOT               DECREMENT THE BEGINNING         47800020
*                                         ADDRESS OF THE LIST           47900020
         LH    RLEN1,SIX(RNEXT)         LOAD THE NUMBER OF ENTRIES      48000020
         OI    AVTGETMN,CDLSTNOW        SET A FLAG TO INDICATE THAT     48100020
*                                         WE ARE CURRENTLY SORTING      48200020
*                                         A CASCADE OR DISTRIBUTION     48300020
*                                         LIST                          48400020
*                                         IN THE LIST                   48500020
         B     LOADAD                   SET OFFSET TABLE ADDRESSES      48600020
CASDIST2 EQU   *                                                        48700020
         LA    RNEXT,2(RNEXT)           BUMP THE POINTER TO THE         48800020
*                                         NEXT LIST ENTRY               48900020
         BCT   RLEN1,LOADAD             SET OFFSET TABLE ADDRESSES      49000020
         NI    AVTGETMN,CDLSTOFF        TURN OFF THE CASCADE SORT       49100020
*                                         IN PROGRESS FLAG              49200020
         BE    FOUNDMAT                 GO TO NEXT ENTRY IN TABLE       49300020
         EJECT                                                          49400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     49500020
*                                                                 *     49600020
*        THIS SECTION OF CODE STORES THE NEW TERMNAME OFFSET      *     49700020
*        FOR ALL LOG ENTRIES IN THE LCB OF THE ENTRIES            *     49800020
*                                                                 *     49900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     50000020
SETLOG   EQU   *                                                        50100020
         XC    TRMALTD(TWO),TRMALTD     CLEAR THE DUMMY ALTERNATE       50200020
*                                         DESTINATION FIELD IN THE      50300020
*                                         LOG TERMINAL ENTRY            50400020
         L     RLEN1,TRMSTATE           LOAD THE ADDRESS OF THE         50500020
*                                         DESTINATION QCB FOR THIS      50600020
*                                         ENTRY                         50700020
         L     RLEN1,QCBRELLN           LOAD THE ADDRESS OF THE LOG     50800020
*                                         LCB                           50900020
         STH   RPRESENT,LCBTTCIN(RLEN1) STORE THE NEW TERMNAME          51000020
*                                         OFFSET IN THE LOG LCB         51100020
         B     FOUNDMAT                 CHECK THE NEXT ENTRY IN THE     51200020
*                                         TERMNAME TABLE                51300020
         EJECT                                                          51400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     51500020
*                                                                 *     51600020
*        THIS ROUTINE SETS UP CERTAIN FIELDS NECESSARY FOR        *     51700020
*        SORTING ALL INVITATION LISTS ASSOCIATED WITH A DCB       *     51800020
*                                                                 *     51900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     52000020
TESTLIST EQU   *                                                        52100020
         L     RLEN1,TRMSTATE           LOAD THE ADDRESS OF THE         52200020
*                                         DESTINATION QCB FOR THIS      52300020
*                                         ENTRY                         52400020
         L     RENDTAB,QCBRELLN         ADDRESS OF THE DCB              52500020
         TM    DCBEIOBX,ILISORTD        HAVE WE SORTED ALL THE          52600020
*                                         INVITATION LISTS              52700020
*                                         ASSOCIATED WITH THIS DCB      52800020
         BO    ALTDTEST                 YES, BRANCH                     52900020
         SR    RTERMNAM,RTERMNAM        CLEAR A REGISTER FOR THE        53000020
*                                         COUNT OF INVITATION LISTS     53100020
         IC    RTERMNAM,DCBILCT         GET THE NUMBER OF INVITATION    53200020
*                                         LIST ADDRESSES IN THIS DCB    53300020
         SR    RWORK,RWORK              CLEAR AN INDEX REGISTER         53400020
ILSTLOAD EQU   *                                                        53500020
         L     RNEXT,DCBINVLI(RWORK)    LOAD THE ADDRESS OF THE         53600020
*                                         FIRST/NEXT INVITATION         53700020
*                                         LIST                          53800020
         TM    THREE(RNEXT),INVLSRTD    HAVE WE PREVIOUSLY SORTED       53900020
*                                         THIS INVITATION LIST          54000020
         BO    RESET                    YES, BRANCH                     54100020
         SR    RLEN1,RLEN1              CLEAR AN ENTRY COUNTER          54200020
         IC    RLEN1,0(RNEXT)           LOAD THE NUMBER OF ENTRIES      54300020
*                                         IN THE INVITATION LIST        54400020
         LTR   RLEN1,RLEN1              IS THIS A DUMMY INVITATION      54500020
*                                         LIST                          54600020
         BZ    RESET                    YES, BRANCH                     54700020
         LA    RTOT,TEN                 LOAD A DISPLACEMENT OF 10       54800020
         SR    RNEXT,RTOT               SET THE STARTING ADDRESS        54900020
*                                         OF THE LIST TO MINUS 8        55000020
         OI    AVTGETMN,ILISTNOW        SET A FLAG TO INDICATE AN       55100020
*                                         INVITATION LIST IS BEING      55200020
*                                         SORTED                        55300020
         B     LOADAD                   LOAD OFFSET ADDRESSES           55400020
ALCONT   EQU   *                                                        55500020
         LA    RTOT,TWO                 LOAD A DISPLACEMENT OF 2        55600020
         SR    RNEXT,RTOT               DECREMENT THE ADDRESS           55700020
*                                         POINTER BY 2 BYTES            55800020
         BCT   RLEN1,LOADAD             TEST THE NEXT INVITATION        55900020
*                                         LIST ENTRY                    56000020
         L     RLEN1,DCBINVLI(RWORK)    LOAD THE ADDRESS OF THE         56100020
*                                         CURRENT INVITATION LIST       56200020
         OI    THREE(RLEN1),INVLSRTD    INDICATE THAT THIS              56300020
*                                         INVITATION LIST HAS BEEN      56400020
*                                         SORTED                        56500020
         EJECT                                                          56600020
RESET    EQU   *                                                        56700020
         LA    RWORK,FOUR(RWORK)        INCREMENT THE ADDRESS INDEX     56800020
*                                         BY 4                          56900020
         BCT   RTERMNAM,ILSTLOAD        DECREMENT THE COUNT OF          57000020
*                                         INVITATION LISTS TO BE        57100020
*                                         SORTED                        57200020
         NI    AVTGETMN,ILISTOFF        TURN OFF THE LIST BEING         57300020
*                                         SORTED FLAG                   57400020
         OI    DCBEIOBX,ILISORTD        SET THE FLAG TO INDICATE        57500020
*                                         THAT ALL INVITATION LISTS     57600020
*                                         FOR THIS DCB HAVE BEEN SORTED 57700020
         MVC   AVTGETMN+1(3),0(RFIRST)  MOVE THE ADDRESS OF THE         57800020
*                                         TERMINAL ENTRY INTO A         57900020
*                                       SCRATCH WORD                    58000020
         L     RNEXT,AVTGETMN           LOAD THE TERMINAL ADDRESS       58100020
         B     ALTDTEST                 TEST FOR AN ALTERNATE           58200020
*                                         DESTINATION                   58300020
         EJECT                                                          58400020
UPDATE   EQU   *                                                        58500020
         LA    RGETAREA,2(RGETAREA)     BUMP POINTER TO THE             58600020
*                                         OFFSET TABLE BY TWO           58700020
         LA    RWORK,ONE(RWORK)         BUMP INDEX BY ONE               58800020
         B     OFFSTORE                 STORE OFFSET IN OFFSET TABLE    58900020
         EJECT                                                          59000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     59100020
*                                                                       59200020
*        SWAPPING ROUTINE                                         *     59300020
*                                                                 *     59400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     59500020
SWAP     EQU   *                                                        59600020
         EX    RLEN1,EX1                SWAP THE TWO                    59700020
         EX    RLEN1,EX2                  ENTRIES IN THE                59800020
         EX    RLEN1,EX1                  TERMNAME TABLE                59900020
*                                                                       60000020
         XC    0(TWO,ROTNOW),0(ROTNEXT) SWAP THE TWO                    60100020
         XC    0(TWO,ROTNEXT),0(ROTNOW)   ENTRIES IN THE                60200020
         XC    0(TWO,ROTNOW),0(ROTNEXT)   OFFSET TABLE                  60300020
*                                                                       60400020
         MVI   AVTGETMN,X'80'           SET SWAP INDICATOR              60500020
         B     COMTAB                   TEST FOR END OF TABLE           60600020
         EJECT                                                          60700020
ENDTAB   EQU   *                                                        60800020
         CR    RPRESENT,RGETAREA        TEST FOR END OF OFFSET TBL      60900020
         BNL   TERMERR                  TERMINAL ERROR DETECTED         61000020
*                                                                       61100020
         LA    RPRESENT,TWO(RPRESENT)   BUMP POINTER TO NEXT ENTRY      61200020
*                                         IN OFFSET TABLE               61300020
         B     CLCOFF                   TEST NEXT ENTRY IN OFFSET       61400020
*                                         TABLE                         61500020
ERRSET   MVC   0(0,RPRESENT),0(RFIRST)  MOVE THE TERMINAL NAME          61600020
*                                        TO THE ERROR MESSAGE           61700020
COMPENT  CLC   0(0,RPRESENT),0(RNEXT)   COMPARE ENTRIES IN TERMNAME     61800020
*                                         TABLE                         61900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     62000020
EX1      XC    0(0,RPRESENT),0(RNEXT)   SWAP THE TWO                    62100020
EX2      XC    0(0,RNEXT),0(RPRESENT)     TERMNAME ENTRIES              62200020
*                                                                       62300020
         EJECT                                                          62400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     62500020
*                                                                 *     62600020
*        GETMAIN ROUTINE                                          *     62700020
*                                                                 *     62800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     62900020
*                                                                       63000020
AVTPAR   EQU   *                                                        63100020
         ST    RPRESENT,AVTGETMN        STORE THE BYTE COUNT            63200020
         ST    RO,AVTGETMN+4            STORE THE AREA ADDRESS          63300020
         LA    RPRESENT,AVTGETMN        ADDRESS OF THE PARAMETER LIST   63400020
*                                                                       63500020
         GETMAIN  ,MF=(E,(1))                                           63600020
*                                                                       63700020
         LTR   RNEXT,RNEXT              TEST THE RETURN CODE            63800020
         BNE   GETERR                   GETMAIN FAILED                  63900020
         BR    ROTNOW                   RETURN TO THE CALLER            64000020
         EJECT                                                          64100020
GETERR   EQU   *                                                        64200020
         LA    R15,TWELVE               GETMAIN ERROR CODE              64300020
         B     RTEND                    GO TO ROUTINE END               64400020
TERMERR  EQU   *                                                        64500020
         OI    AVTGETMN,ALTDSTER        SET THE ERROR INDICATOR IN      64600020
*                                         THE AVT                       64700020
         B     MSGLOAD                  WRITE THE TERMINAL ERROR        64800020
*                                         MESSAGE                       64900020
TERMERR1 EQU   *                                                        65000020
         LA    R15,SIXTEEN              AN ERROR IN DEFINING THE        65100020
*                                         TERMINAL                      65200020
         B     RTEND                    EXIT THIS ROUTINE               65300020
POCERR   EQU   *                                                        65400020
         LA    R15,TWENTY               AN ERROR IN DEFINING THE        65500020
*                                         PRIMARY OPERATOR CONTROL      65600020
*                                         TERMINAL                      65700020
         B     RTEND                    PASS AN ERROR CODE OF 20        65800020
*                                         TO IEDQOA                     65900020
         EJECT                                                          66000020
COMPSUBR EQU   *                                                        66100020
         EX    RLEN3,COMPENT            EXECUTE A COMPARISON TO         66200020
*                                         FIND A MATCH FOR THE          66300020
*                                         OPERATOR CONTROL TERMINAL     66400020
         BNE   NEXTERM                  UPDATE ENTRY POINTER            66500020
*                                                                       66600020
         LR    RO,RNEXT                 COPY POINTER TO ENTRY IN        66700020
*                                         THE TERMNAME TABLE            66800020
         SR    RO,RTERMNAM              GET OFFSET FROM START OF        66900020
*                                         TERMNAME TABLE                67000020
         BR    RWORK                    RETURN                          67100020
         EJECT                                                          67200020
NEXTERM  EQU   *                                                        67300020
         LA    RNEXT,0(RLENGTH,RNEXT)   UPDATE POINTER TO NEXT          67400020
*                                         ENTRY IN TERMNAME TABLE       67500020
         BCT   RTOT,COMPSUBR            TEST THE NEXT TERMINAL          67600020
         LA    RTOT,AVTDOUBX            LOAD THE ADDRESS OF THE         67700020
*                                         PRIMARY OPERATOR CONTROL      67800020
*                                         TERMINAL NAME                 67900020
         CR    RTOT,RPRESENT            ARE WE TESTING FOR A POC        68000020
*                                         TERMINAL                      68100020
         BE    POCERR                   YES, BRANCH BECAUSE WE HAVE     68200020
*                                         NOT FOUND THAT TERMINAL       68300020
*                                         DEFINED AS THE PRIMARY        68400020
*                                         OPERATOR CONTROL TERMINAL     68500020
DLQMSG   EQU   *                                                        68600020
         SR    RLEN1,RLEN1              CLEAR A REGISTER TO ZEROES      68700020
         STH   RLEN1,AVTDLQX            SET THE DEAD LETTER QUEUE       68800020
*                                         OFFSET TO ZERO                68900020
         EJECT                                                          69000020
         WTO   'IED078I DLQ TERM ERROR',MF=I,ROUTCDE=11,DESC=4          69100020
*                                                                       69200020
         B     CODEFIX                  RETURN                          69300020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     69400020
        CNOP  0,4                                                       69500020
MSG      DC    AL2(MSGEND-*)                                            69600020
         DC    X'1000'                                                  69700020
         DC    C'IED007I '                                              69800020
MSGC     DC    CL9'0'                                                   69900020
         DC    C'ILLEGAL DESTINATION'                                   70000020
MSGEND  EQU   *                                                         70100020
         DC    X'1000'                                                  70200020
         DC    X'0020'                                                  70300020
        CNOP  0,4                                                       70400020
MSGLOAD EQU   *                                                         70500020
        LA    RPRESENT,MSG             ADDRESS OF ERROR MESSAGE         70600020
        SVC   35                       WRITE THE ERROR MESSAGE          70700020
         TM    AVTGETMN,ILISTNOW        ARE WE CURRENTLY SORTING        70800020
*                                         AN INVITATION LIST            70900020
         BO    RESET                    YES, BRANCH                     71000020
         TM    AVTGETMN,CDLSTNOW        ARE WE CURRENTLY SORTING A      71100020
*                                         CASCADE OR A DISTRIBUTION     71200020
*                                         LIST                          71300020
         BZ    CASDSEND                 NO, BRANCH                      71400020
         NI    AVTGETMN,CDLSTOFF        YES, TURN OFF THE SORT IN       71500020
*                                         PROGRESS FLAG                 71600020
CASDSEND EQU   *                                                        71700020
        B     FOUNDMAT                 GO TO THE NEXT ENTRY             71800020
         EJECT                                                          71900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     72000020
ONE      EQU   1                                                        72100020
TWO      EQU   2                                                        72200020
SHIFT2   EQU   2                                                        72300020
THREE    EQU   3                                                        72400020
FOUR     EQU   4                                                        72500020
SIX      EQU   6                                                        72600020
EIGHT    EQU   8                                                        72700020
TEN      EQU   10                                                       72800020
TWELVE   EQU   12                                                       72900020
SIXTEEN  EQU   16                                                       73000020
TWENTY   EQU   20                                                       73100020
SENDACPT EQU   24                       SEND AND ACCEPT BITS            73200020
LCBTTCIN EQU   90                                                       73300020
SECOPCTL EQU   X'01'                                                    73400020
ALTDSTER EQU   X'20'                                                    73500020
INVLSRTD EQU   X'40'                                                    73600020
CDLSTNOW EQU   X'40'                                                    73700020
CORDLIST EQU   X'40'                                                    73800020
SINGLINE EQU   X'60'                                                    73900020
LOGTYPE  EQU   X'60'                                                    74000020
ILISTNOW EQU   X'80'                                                    74100020
ILISORTD EQU   X'80'                                                    74200020
ILISTOFF EQU   X'7F'                                                    74300020
CDLSTOFF EQU   X'BF'                                                    74400020
SYSCON   DC    C'SYSCON  '                                              74500020
         EJECT                                                          74600020
         TTRMD                                                          74700020
         EJECT                                                          74800020
         TTNTD                          TERMNAME TABLE MACRO            74900020
         EJECT                                                          75000020
         TQCBD                          QCB DSECT                       75100020
         EJECT                                                          75200020
         TAVTD 4                                                        75300020
         EJECT                                                          75400020
         DCBD  DSORG=TX                                                 75500020
         END                                                            75600020
