         TITLE '''IEDQOS'' INTRO ATTACH ROUTINE'                        00400020
IEDQOS   CSECT                                                          00800020
*                                                                     * 01200020
*STATUS - CHANGE LEVEL 0                                              * 01600020
*D308000,364000                                                  A44022 01800030
*                                                                     * 02000020
*FUNCTION/OPERATION - THIS ROUTINE TESTS TO SEE WHETHER OR NOT        * 02400020
*   THE ON-LINE TEST MODULE AND/OR THE COMMON WRITE MODULE IS         * 02800020
*   TO BE ATTACHED, AND IT UNCONDITIONALLY ATTACHES THE OPERATOR      * 03200020
*   CONTROL MODULE.  IEDQOS ALSO ISSUES THE EXTRACT AND QEDIT         * 03600020
*   MACROS TO SET UP THE COMMUNICATIONS PARAMETER LIST                * 04000020
*   INTERFACE BETWEEN TCAM AND THE OPERATING SYSTEM, AS WELL AS       * 04400020
*   LOADING THE SYSTEM DELAY ROUTINE (IEDQHI) IF A SYSTEM DELAY       * 04800020
*   INTERVAL IS SPECIFIED.  THE OPERATOR AWARENESS MESSAGE            * 05200020
*   ROUTER ROUTINE (IEDQNA) IS LOADED IF A PRIMARY OPERATOR           * 05600020
*   CONTROL TERMINAL IS DEFINED.                                      * 06000020
*                                                                     * 06400020
*ENTRY POINT - CALLED ONLY FROM 'IEDQOA'                              * 06800020
*                                                                     * 07200020
*INPUT                                                                * 07600020
*   R1  - ADDRESS OF THE AVT                                          * 08000020
*   R13 - ADDRESS OF AN 18 WORD SAVE AREA                             * 08400020
*                                                                     * 08800020
*OUTPUT - THOSE REQUESTED ROUTINES AND OPERATOR CONTROL WILL          * 09200020
*   HAVE BEEN ATTACHED.                                               * 09600020
*                                                                     * 10000020
*EXTERNAL ROUTINES - NONE                                             * 10400020
*                                                                     * 10800020
*EXITS - NORMAL                                                       * 11200020
*                                                                     * 11600020
*   RETURN IS MADE TO THE LINKING ROUTINE WITH REGISTER 15            * 12000020
*   CONTAINING A RETURN CODE OF ZERO.                                 * 12400020
*                                                                     * 12800020
*       ERROR - NONE                                                  * 13200020
*                                                                     * 13600020
*TABLES/WORKAREAS - THE ADDRESS VECTOR TABLE IS A RESIDENT VECTOR     * 14000020
*   LIST WHICH IS USED TO LOCATE THE ECB ADDRESSES FOR THOSE          * 14400020
*   ROUTINES WHICH ARE TO BE ATTACHED                                 * 14800020
*                                                                     * 15200020
*ATTRIBUTES - NON-RESIDENT, NON-REUSABLE, AND NON- REFRESHABLE        * 15600020
*                                                                     * 16000020
*NOTES - THIS ROUTINE IS ON SYS1.LINKLIB AND IS LINKED TO BY          * 16400020
*   IEDQOA, THE TCAM NON-RESIDENT START-UP ROUTINE WHICH WAS          * 16800020
*   ITSELF LINKED TO BY INTRO.                                        * 17200020
*                                                                     * 17600020
*                                                                     * 18000020
         EJECT                                                          18400020
*        REGISTER USAGE                                                 18800020
R0       EQU   0                                                        19200020
R1       EQU   1                        PARAMETER REGISTER              19600020
R2       EQU   2                        ECB ADDRESS REGISTER            20000020
R3       EQU   3                        AVT BEGINNING ADDRESS           20400020
R4       EQU   4                                                        20800020
R5       EQU   5                                                        21200020
R6       EQU   6                        ADDRESS OF TSO STAI ROUTINE     21400020
RAVT     EQU   9                        AVT BASE REGISTER               21600020
RBASE    EQU   12                       BASE OF THIS ROUTINE            22000020
R13      EQU   13                       SAVE AREA ADDRESS               22400020
R14      EQU   14                       RETURN ADDRESS REGISTER         22800020
R15      EQU   15                       RETURN CODE REGISTER            23200020
*                                                                       23600020
         USING IEDQAVTD,RAVT            AVT DSECT                       24000020
*                                                                       24400020
         SAVE  (14,12),,IEDQOS.INTRO.ATTACH.09/09/71             A44022 24800030
*                                                                       25200020
         BALR  RBASE,0                                                  25600020
         USING *,RBASE                                                  26000020
*                                                                       26400020
         LR    R3,R1                    COPY THE BEGINNING ADDRESS      26800020
*                                       OF THE AVT                      27200020
         LA    RAVT,3*AVTSVSIZ(R1)      POINT TO AVTSAVE4               27600020
         ST    R13,4(0,RAVT)            ADDRESS OF CALLERS SAVE AREA    28000020
         ST    RAVT,8(0,R13)            ADDRESS OF MY SAVE AREA         28400020
         L     R5,AVTCLOSB+8            LOAD THE ADDRESS OF THE         28800020
*                                         CLOSEDOWN/COMPLETION RTNE     29200020
         LA    R5,SIX(R5)               GET THE ADDRESS OF THE          29600020
*                                         FIRST INSTRUCTION             30000020
         L     R6,AVTTSOPT             ADDRESS OF TIME SHARING QCB      30080030
         L     R6,TSISTAE-IEDQTSI(,R6)  ADDRESS OF TSO STAE ROUTINE     30160030
         LA    R6,4(R6)                INCREMENT TO ENTRY POINT         30240030
*                                            FOR STAI EXITS             30320030
         EJECT                                                          30400020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     36800020
*                                                                 *     37200020
*        THIS SECTION OF CODE ATTACHES THE COMMON WRITE           *     37600020
*        ROUTINE, OPERATOR CONTROL, AND THE ON-LINE TEST          *     38000020
*                             FUNCTION                            *     38400020
*                                                                 *     38800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     39200020
*                                                                       39600020
ATTACHOL EQU   *                                                        40000020
         CLI   AVTOLTST,X'00'           IS THE ON-LINE TEST MODULE      40400020
*                                         TO BE ATTACHED                40800020
         BE    CWRATTCH                 NO, BRANCH                      41200020
         LA    R2,AVTOLECA              LOAD THE ADDRESS OF THE         41600020
*                                         ON-LINE TEST ECB              42000020
         TM    AVTBIT1,AVTTSON          IS TIME SHARING ACTIVE          42060020
         BO    ATCHOLTS                 BRANCH ON YES                   42120020
*                                                                       42180020
         ATTACH ECB=(2),ETXR=(5),MF=(E,(1)),SF=(E,OLLIST)               42240020
*                                                                       42300020
         B     ENDOLATC                                                 42360020
*                                                                       42420020
ATCHOLTS EQU   *                                                        42480020
*                                                                       42540020
         ATTACH ECB=(2),ETXR=(5),STAI=((6)),MF=(E,(1)),SF=(E,OLLIST)    42600020
*                                                                       42660020
ENDOLATC EQU   *                                                        42720020
         ST    R1,AVTOLTCB              TCB ADDRESS OF ATTACHED         42800020
*                                         TASK - ON-LINE TEST           43200020
         LR    R1,R3                    RESTORE THE AVT ADDRESS         43600020
         EJECT                                                          44000020
CWRATTCH EQU   *                                                        44400020
         TM    AVTCWFL1,AVTCOMWN        IS THE COMMON WRITE ROUTINE     44800020
*                                         TO BE ATTACHED                45200020
         BNO   ATTACHOC                 NO, BRANCH                      45600020
*                                                                       46000020
         LA    R2,AVTCWECA              LOAD THE  ADDRESS OF THE        46400020
*                                         COMMON WRITE ECB              46800020
         NI    AVTCWECA,X'00'           TURN OFF THE WAITING BIT IN     47200020
*                                         THE ECB                       47600020
         ATTACH EP=IEDQFW,ECB=(2),ETXR=(5),DPMOD=-1,MF=(E,(1))          48000020
*                                                                       48400020
         ST    R1,AVTCWTCB              STORE THE TCB ADDRESS OF THE    48800020
*                                         ATTACHED TASK                 49200020
         LR    R1,R3                    RESTORE THE AVT ADDRESS         49600020
         EJECT                                                          50000020
ATTACHOC EQU   *                                                        50400020
         LA    R2,AVTOPECA              LOAD THE ADDRESS OF THE         50800020
*                                         OPERATOR CONTROL ECB          51200020
         TM    AVTBIT1,AVTTSON          IS TIME SHARING ACTIVE          51260020
         BO    ATCHOCTS                 BRANCH ON YES                   51320020
*                                                                       51380020
         ATTACH ECB=(2),ETXR=(5),MF=(E,(1)),SF=(E,OCLIST)               51440020
*                                                                       51500020
         B     ENDOCATC                                                 51560020
*                                                                       51620020
ATCHOCTS EQU   *                                                        51680020
*                                                                       51740020
         ATTACH ECB=(2),ETXR=(5),STAI=((6)),MF=(E,(1)),SF=(E,OCLIST)    51800020
*                                                                       51860020
ENDOCATC EQU   *                                                        51920020
         ST    R1,AVTOCTCB              TCB ADDRESS OF ATTACHED         52800020
*                                         TASK - OPERATOR CONTROL       53200020
         EJECT                                                          53600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     54000020
*                                                                 *     54400020
*        THIS SECTION OF CODE ISSUES THE EXTRACT AND QEDIT        *     54800020
*        MACROS TO SET UP THE COMMUNICATIONS PARAMETER LIST       *     55200020
*        INTERFACE BETWEEN TCAM AND THE OPERATING SYSTEM          *     55600020
*                                                                 *     56000020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     56400020
         LA    R4,AVTCOMPT              LOAD THE ADDRESS OF THE         56800020
*                                         AVT ADDRESS FIELD             57200020
         LA    R1,12(,RAVT)             ADDRESS OF PARM LIST            57600020
         EXTRACT (R4),'S',FIELDS=COMM,MF=(E,(1)) ESTABLISH PARM LIST    58000020
*                                                                       58400020
*                                                                       58800020
         L     R1,AVTCOMPT              LOAD THE ADDRESS OF THE         59200020
*                                         COMMUNICATIONS PARAMETER      59600020
*                                         LIST                          60000020
         LA    R0,FOUR(R1)              LOAD THE ADDRESS OF THE         60400020
*                                         WORD TO HOLD THE CIB          60800020
*                                         CHAIN ADDRESS                 61200020
         SR    R1,R1                    CLEAR A COUNT REGISTER          61600020
         IC    R1,AVTCIB                LOAD THE NUMBER OF BUFFERS      62000020
*                                         REQUESTED                     62400020
         QEDIT CIBCTR=(1),ORIGIN=(0)    GET THE BUFFERS                 62800020
         EJECT                                                          63200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     63600020
*                                                                 *     64000020
*        THIS SECTION OF CODE LOADS THE SYSTEM DELAY ROUTINE      *     64400020
*                                                                 *     64800020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     65200020
         LH    R1,AVTINTLV              LOAD THE LENGTH OF THE          65600020
*                                         SYSTEM DELAY INTERVAL         66000020
         LTR   R1,R1                    IS THE DELAY ZERO               66400020
         BZ    TSTOPCON            NO, BRANCH                           66800020
*                                                                       67200020
         LOAD  EPLOC=SYSDELAY                                           67600020
*                                                                       68000020
         ST    R0,AVTHI                 STORE THE ENTRY POINT           68400020
*                                         ADDRESS IN THE AVT            68800020
         LR    R1,R0                    COPY THE ENTRY POINT ADDRESS    69200020
         A     R0,EIGHT(,R1)            LOAD THE ADDRESS OF THE         69600020
*                                         STCB FIELD                    70000020
         ST    R0,EIGHT(,R1)            STORE THIS ADDRESS IN THE       70400020
*                                         STCB ADDRESS POINTER          70800020
         EJECT                                                          71200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     71600020
*                                                                 *     72000020
*        THIS SECTION OF CODE LOADS THE OPERATOR AWARENESS        *     72400020
*                  MESSAGE ROUTER ROUTINE                         *     72800020
*                                                                 *     73200020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *     73600020
TSTOPCON EQU   *                                                        74000020
         LH    R1,AVTOPCON              LOAD THE TERMNAME TABLE         74400020
*                                         OFFSET TO THE PRIMARY         74800020
*                                         OPERATOR CONTROL TERMINAL     75200020
         LTR   R1,R1                    IS THIS OFFSET ZERO             75600020
         BZ    RETURN                   YES, BRANCH                     76000020
*                                                                       76400020
         LOAD  EPLOC=OPAMSGRT           LOAD THE AWARENESS ROUTINE      76800020
*                                                                       77200020
         ST    R0,AVTNX                 STORE THE ENTRY POINT           77600020
*                                         ADDRESS IN THE AVT            78000020
         EJECT                                                          78400020
RETURN   SR    R15,R15                                                  78800020
RTEND    EQU   *                                                        79200020
         L     R13,4(0,RAVT)            ADDRESS OF SAVED REGISTERS      79600020
         RETURN (14,12),T,RC=(15)                                       80000020
*                                                                       80400020
FOUR     EQU   4                                                        80800020
SIX      EQU   6                                                        81200020
EIGHT    EQU   8                                                        81600020
SYSDELAY DC    CL8'IEDQHI  '                                            82000020
OPAMSGRT DC    CL8'IEDQNX  '            OPERATOR AWARENESS ROUTINE      82400020
OLLIST   ATTACH EP=IEDQWA,DPMOD=-1,SF=L                                 82500020
OCLIST   ATTACH EP=IEDQCA,DPMOD=-1,SF=L                                 82600020
         EJECT                                                          82800020
         TAVTD 4                                                        83200020
         TTSID                                                          83400020
         END                                                            83600020
