         TITLE 'IECQBFG1  GET POOL'                                     00020000
         COPY  LCGASMSW                                                 00020402
*          RELEASE 17 DELETIONS                                         00022000
*2060009200,009400                                                DM0E  00023000
*2060005800                                                       7M379 00023500
*          RELEASE 18 DELETIONS                                         00024000
*          RELEASE 19 DELETIONS                                         00026000
*          RELEASE 20 DELETIONS                                         00028000
*          RELEASE 21 DELETIONS                                         00030000
*   REFER TO CODE FLAGGED XA03130                               SA66030 00038000
*                                                                       00038402
*          VS1-2 DELETIONS                                              00038802
* 0000                                                           XM0909 00038902
*          VS1-3 DELETIONS                                              00044100
*                                                               XA03130 00046100
*STATUS CHANGE LEVEL 004                                                00049600
*FUNCTION:THIS GETPOOL ROUTINE IS ENTERED VIA AN LINK SVC WHEN THE USER 00054800
*   ISSUES A GETPOOL MACRO. THE ROUTINE THEN GETS CORE AND BUILD      * 00060000
*   THE POOL OF BUFFERS.                                              * 00080000
*ENTRY POINT-BY LINK TO IECQBFG1                                        00100000
*INPUT:REGISTER 13  USER SAVE AREA ADDRESS                            * 00120000
*      REGISTER 14  RETURN ADDRESS                                    * 00140000
*      REGISTER 15  IECQBFG1 FIRST LOCATION ADDRESS                     00160000
*      REGISTER  0  HIARCHY SPECIFICATION (EITHER HI SPEED        DM0E  00162000
*                   STORAGE, LCS OR NEITHER,WHICH DEFAULTS TO HI  DM0E  00164000
*                   SPEED). C(REG0) SIGNIFICANCE                  DM0E  00166000
*                =X'00' HIARCHY NOT CODED ON GETPOOL(LOOK IN DCB) DM0E  00168000
*                   =X'01'    HIARCHY=0   (HI SPEED STORAGE)      DM0E  00170000
*                   =X'02'    HIARCHY=1   (LCS)                   DM0E  00172000
*      REGISTER  1  DCB ADDRESS FOR POOL ASSIGNMENT                     00180000
*                   IF REGISTER 1 IS POSITIVE, HIARCHY 0 WILL BE  7M379 00184000
*                   ASSUMED.                                      7M379 00188000
*                   IF REGISTER 1 IS NEGATIVE, REGISTER 0 WILL BE 7M379 00192000
*                   EXAMINED TO DETERMINE HIARCHY SPECIFICATION.  7M379 00196000
*              +22  NUMBER OF BUFFERS REQUESTED                         00200000
*              +24  LENGTH OF BUFFERS REQUESTED                         00220000
*OUTPUT:NUMBER AND ADDRESS OF BUILT BUFFERS IN DCB BUFNO AND BUFCB    * 00240000
*MODULE TYPE:QSAM ROUTINE LOADED BY LINKAGE EDITOR                    * 00260000
*EXTERNAL REFERENCES:DCB,USER SAVE AREA                               * 00280000
*EXITS-NORMAL:RETURN ON REGISTER 14 TO CALLER.  NUMBER AND ADDRESS OF * 00300000
*   BUILT BUFFERS IN DCB BUFNO AND BUFCB                              * 00320000
*EXITS-ERRORS:RETURN ON REGISTER 14 TO CALLER.  NO BUFFERS BUILT.     * 00340000
*   FORCE OPEN TO BUILD BUFFERS SINCE USER SPECIFIED 0 BUFFER         * 00360000
*   NUMBER OR LENGTH                                                  * 00380000
*ATTRIBUTES - REENTRANT                                                 00400000
*WORKAREAS - USERS SAVE AREA                                            00420000
*NOTES:THIS MODULE WAITS FOR AVAILABLE CORE IF NECESSARY DURING       * 00440000
*   GETMAIN OPERATION                                                 * 00460000
*                                                                       00480000
IECQBFG1 CSECT                                                          00500000
         SAVE  (14,6)                   SAVE REGISTERS                  00520000
         BALR  BASR,0                                                   00540000
         USING *,BASR                                                   00560000
         LCR   DCBR,BUFPTR              Q. DCB ADDR PASSED NEG    7M379 00563000
         BC    2,LCSTEST                BRANCH IF YES - NOTE THAT 7M379 00566000
*                                       BUFPTR REMAINS NEGATIVE   7M379 00569000
         LCR   DCBR,DCBR                NO, MAKE DCB ADDR POS     7M379 00572000
         B     SETH0                    ASSUME HIARCHY=0          7M379 00575000
LCSTEST  EQU   *                                                  7M379 00578000
         BCTR  BUFPAR,BUFPAR       DECREMENT FOR LTR CONVENIENCE. DM0E  00581000
         LTR   BUFPAR,BUFPAR           TEST PARM PASSED BY MACRO. DM0E  00582000
         BZ    SETH0                    HIARCHY=0 CODED ON GETPOOL.DM0E 00583000
SETH1    L     PLAYREG,LCS              SETUP FOR HIARCHY=1.      DM0E  00584000
         BP    H1OK                     BIF HIARCHY=1  ON GETPOOL. DM0E 00585000
* HIARCHY NOT CODED ON GETPOOL MACRO. GET IT FROM DCB.             DM0E 00586000
         TM    DCBBFTEK(DCBR),HIARCHY  IS LCS SPEC'D IN DCB.       DM0E 00587000
         BO    H1OK                                                DM0E 00588000
SETH0    SR    PLAYREG,PLAYREG         PARM NOT EQUAL TO -LCT IS A DM0E 00589000
*                                    REQUEST FOR HI SPEED STORAGE  DM0E 00590000
H1OK     EQU   *                                                   DM0E 00591000
* PLAYREG HOLDS THE HIARCHY PARM WHICH WILL BE PASSED TO GETMAIN INDM0E 00592000
* REG 0.                                                           DM0E 00593000
         LH    BUFNOR,22(DCBR)          PLACE NUMBER OF BUFFERS IN REG  00600000
         LH    LBUFLR,24(DCBR)          PLACE LENGTH OF BUFFERS IN REG  00620000
         LTR   BUFNOR,BUFNOR            Q-ZERO NUMBER REQUESTED         00640000
         BZ    RETURNA                  YES,RETURN                      00660000
         LTR   LBUFLR,LBUFLR            Q-ZERO LENGTH REQUESTED         00680000
         BZ    RETURNA                 YES, RETURN                      00700000
         LA    LBUFLR,7(LBUFLR)         ROUND LENGTH                    00720000
         SRL   LBUFLR,3                      TO MULTIPLE                00740000
         SLL   LBUFLR,3                      OF EIGHT                   00760000
         LR    BUFPTR,LBUFLR            ROUNDED LENGTH TIMES            00780000
         MR    BUFPAR,BUFNOR                 NUMBER FOR TOTAL LENGTH    00800000
         TM    32(DCBR),1               Q-FULL WORD ALIGNMENT SPECIFIED 00820000
         BO    POOL1                    YES                             00840000
         LA    BUFPAR,8(BUFPTR)         NO,ADD 8 TO LGN FOR BCB         00860000
         B     POOL2                                                    00880000
POOL1    LA    BUFPAR,16(BUFPTR)        YES,ADD 16 FOR BCB AND ALIGN    00900000
POOL2    LTR   PLAYREG,PLAYREG    TEST HIARCHY ID                  DM0E 00906000
         BZ    HID0               BRANCH HIARCHY=0                 DM0E 00912000
         AIF   ('&LIB' EQ 'LIB2').LIB01                          XM0909 00914002
         GETMAIN R,LV=(0),HIARCHY=1                                DM0E 00918000
.LIB01   ANOP                                                    XM0909 00920002
*                                                                XM0909 00922102
         AIF   ('&LIB' EQ 'LIB1').LIB02                          XM0909 00922502
         GETMAIN R,LV=(0)                                        XM0909 00922802
.LIB02   ANOP                                                    XM0909 00923202
         B     STORE                                               DM0E 00924000
HID0     GETMAIN R,LV=(0),HIARCHY=0                                DM0E 00930000
STORE    ST    BUFPTR,20(DCBR)    PLACE BUFCB IN DCB               DM0E 00940000
         STC   BUFNOR,20(DCBR)         PLACE BUFNO IN DCB               00960000
         STH   LBUFLR,24(DCBR)          PLACE ROUNDED LENGTH IN DCB     00980000
         TM    32(DCBR),1               Q-FULL WORD ALIGNMENT SPECIFIED 01000000
         BO    POOL3                    YES                             01020000
         LA    BUFPAR,8(BUFPTR)         NO,DETERMINE BCB LINK ADDR      01040000
         B     POOL4                                                    01060000
POOL3    LA    BUFPAR,12(BUFPTR)        YES,LINK ADDR AROUND ALIGN PAD  01080000
POOL4    ST    BUFPAR,0(BUFPTR)         PLACE LINK ADDR IN BCB          01100000
         STH   LBUFLR,6(BUFPTR)         PLACE LENGTH IN BCB             01120000
         STH   BUFNOR,4(BUFPTR)         PLACE NUMBER IN BCB             01140000
         TM    32(DCBR),1               FULL WORD ALIGNMENT     XA03130 01150003
         BNO   POOLLOOP                 NO, BRANCH              XA03130 01152003
         OI    4(BUFPTR),X'40'          SET EXTEND FLAG IN BCB  XA03130 01154003
POOLLOOP LR    BUFPTR,BUFPAR            UPDATE BUFFER ADDRESS POINTER   01160000
         BCT   BUFNOR,LOOP              Q-ALL BUFFERS BUILT             01180000
RETURN   MVC   0(4,BUFPTR),ZERO        CLEAR BUFFER LINK ADDRESS        01200000
RETURNA  RETURN (14,6)                  RETURN TO CALLER                01220000
LOOP     LA    BUFPAR,0(3,BUFPTR)       NO, CALCULATE NEXT BUFFER ADDR  01240000
         ST    BUFPAR,0(BUFPTR)         STORE BUFFER LINK ADDRESS       01260000
         BC    15,POOLLOOP              BUILD NEXT BUFFER               01280000
ZERO     DC    X'00000000'                                              01300000
         DS    0F                                                  DM0E 01305000
LCS      DC    X'80'               REG1 CONTENTS FOR GETMAIN FROM  DM0E 01310000
         DC    C'LCT'                  LCS. NOTE THE 'T'.          DM0E 01315000
BUFPAR   EQU   0                                                        01320000
BUFPTR   EQU   1                                                        01340000
BUFNOR   EQU   2                                                        01360000
LBUFLR   EQU   3                                                        01380000
DCBR     EQU   4                                                        01400000
SAVR     EQU   13                                                       01420000
RETR     EQU   14                                                       01440000
PLAYREG  EQU   5                        USED TO DEVELOP AND HOLD   DM0E 01442000
*                                     HIARCHY REQUEST UNTIL NEEDED DM0E 01444000
*                                       BY GETMAIN.                DM0E 01446000
DCBBFTEK EQU   32                      BFTEK OFFSET IN DCB.        DM0E 01448000
HIARCHY  EQU   X'80'               TEST DCBBFTEK FOR WHICH STORAGE DM0E 01450000
*                                       BOX, HI SPEED OR LCS.      DM0E 01452000
BASR     EQU   6                                                        01460000
         END   IECQBFG1                                                 01480000
