         TITLE 'IFG0193C/OMODVOL1 - STANDARD LABEL EDITING ROUTINE'     00400021
         COPY  LCGASMSW                                                 00450000
IFG0193C CSECT                                                          01600021
*********************************************************************** 02000021
*                                                                     * 02400021
*                                                                     * 02800021
*          RELEASE 25 DELETIONS/CHANGES                               * 03200021
*          RELEASE 24 DELETIONS/CHANGES                               * 03600021
*          RELEASE 23 DELETIONS/CHANGES                               * 04000021
*          RELEASE 22 DELETIONS/CHANGES                               * 04400021
*          RELEASE 21 DELETIONS/CHANGES                               * 04800021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 04850021
*0000756500-7585000                                             SA70384 04900021
*                                                                     * 05200021
* STATUS CHANGE LEVEL 000                                             * 05600021
*                                                                     * 06000021
* FUNCTION -                                                          * 06400021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 06800021
*    OPEN TAPE LABEL EDITOR FUNCTION.                                 * 07200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 07600021
*                                                                     * 08000021
* ENTRY POINTS -                                                      * 08400021
*    IFG0193C - ENTERED FROM ONE OF THE FOLLOWING--                   * 08800021
*       IFG0194J - VIA XCTL TO OMODVOL1 FOR LABEL OR DENSITY          * 09200021
*       CONFLICT.                                                     * 09600021
*       IFG0193D - IFG0193E - VIA THE RESIDENT ROUTINE XCTL WHEN      * 10000021
*       A REMOUNT IS NEEDED.                                          * 10400021
*                                                                     * 10800021
* INPUT -                                                             * 11200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11600021
*                                                                     * 12000021
* OUTPUT -                                                            * 12400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 12800021
*                                                                     * 13200021
* EXTERNAL REFERENCES -                                               * 13600021
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 14000021
*          WAIT.                                                      * 14400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 14800021
*                                                                     * 15200021
* EXITS, NORMAL -                                                     * 15600021
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO ONE OF THE FOLLOWING--     * 16000021
*       IFG0193D - TO DESTROY STANDARD LABEL.                         * 16400021
*       IFG0193E - TO CREATE STANDARD LABEL.                          * 16800021
*       IFG0194G - TO ISSUE MOUNT MESSAGE AND REPROCESS DCB.          * 17200021
*       IFG0194I - IMMEDIATELY EXIT ON DENSITY CONFLICT TO            * 17600021
*       CONTINUE NORMAL PROCESSING.                                   * 18000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 18400021
*                                                                     * 18800021
* EXITS, ERROR -                                                      * 19200021
*    NONE.                                                            * 19600021
*                                                                     * 20000021
* TABLES/WORK AREAS -                                                 * 20400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 20800021
*                                                                     * 21200021
* ATTRIBUTES -                                                        * 21600021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 22000021
*                                                                     * 22400021
* CHARACTER CODE DEPENDENCY -                                         * 22800021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 23200021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 23600021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 24000021
*                                                                     * 24400021
* NOTES -                                                             * 24800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 25200021
*                                                                     * 25600021
*********************************************************************** 26000021
         EJECT                                                          26400021
*********************************************************************** 26800021
*                                                                     * 27200021
*                          FUNCTION PROLOG                            * 27600021
*                                                                     * 28000021
*********************************************************************** 28400021
*                                                                     * 28800021
* FUNCTION NAME -                                                     * 29200021
*    OPEN TAPE LABEL EDITOR FUNCTION.                                 * 29600021
*                                                                     * 30000021
* (STATUS) -                                                          * 30400021
*    NOT APPLICABLE                                                   * 30800021
*                                                                     * 31200021
* FUNCTION -                                                          * 31600021
*    RESTORE RESIDENT ROUTINE SEQUENTIAL PROCESSING.                  * 32000021
*    RETURN TO NORMAL PROCESSING ON A DENSITY CONFLICT.               * 32400021
*    EXITS TO THE FUNCTION REQUIRED FOR A LABEL CONFLICT WITH         * 32800021
*    A NON-SPECIFIC VOLUME REQUEST.                                   * 33200021
*    FOR A LABEL CONFLICT ON A SPECIFIC VOLUME REQUEST, OR IF         * 33600021
*    THE CREATE OR DESTROY FUNCTIONS REQUIRE A REMOUNT, THE           * 34000021
*    VOLUME IS DEMOUNTED AND AN EXIT TAKEN FOR REMOUNT.               * 34400021
*                                                                     * 34800021
* ENTRY POINTS -                                                      * 35200021
*    ENTERED FROM THE FOLLOWING--                                     * 35600021
*    OPEN TAPE LABEL EDITOR INTERFACE FUNCTION FOR A LABEL OR         * 36000021
*    DENSITY CONFLICT.                                                * 36400021
*    OPEN TAPE CREATE LABEL FUNCTION OR OPEN TAPE DESTROY LABEL       * 36800021
*    FUNCTION WHEN A REMOUNT IS REQUIRED.                             * 37200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37600021
*                                                                     * 38000021
* INPUT -                                                             * 38400021
*    A POINTER TO EACH OF THE FOLLOWING--                             * 38800021
*       CURRENT PARAMETER LIST ENTRY.                                 * 39200021
*       DD ENTRY IN THE TIOT.                                         * 39600021
*       WTG TABLE.                                                    * 40000021
*       CURRENT WTG TABLE ENTRY.                                      * 40400021
*       DCB.                                                          * 40800021
*       OPEN WORK AREA.                                               * 41200021
*       RESIDENT ROUTINE.                                             * 41600021
*       UCB                                                           * 42000021
*    THE CONFLICT BITS IN THE JFCBMASK+5 MUST BE SET.                 * 42400021
*                                                                     * 42800021
* OUTPUT -                                                            * 43200021
*    A MOUNT MESSAGE IS CONSTRUCTED IN THE WORK AREA WHEN A           * 43600021
*    REMOUNT IS REQUIRED.                                             * 44000021
*                                                                     * 44400021
* EXTERNAL REFERENCES -                                               * 44800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 45200021
*                                                                     * 45600021
* EXITS, NORMAL -                                                     * 46000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 46400021
*    OPEN TAPE DESTROY LABEL FUNCTION TO DESTROY A STANDARD LABEL.    * 46800021
*    OPEN TAPE CREATE LABEL FUNCTION TO CREATE A STANDARD LABEL.      * 47200021
*    OPEN TAPE VOLUME MOUNTING FUNCTION FOR A REMOUNT.                * 47600021
*    OPEN TAPE FINAL COMMON FUNCTION TO CONTINUE NORMAL PROCESSING.   * 48000021
*                                                                     * 48400021
* EXITS, ERROR -                                                      * 48800021
*    NONE.                                                            * 49200021
*                                                                     * 49600021
* TABLES/WORK AREAS -                                                 * 50000021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 50400021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 50800021
*                                                                     * 51200021
* ATTRIBUTES -                                                        * 51600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 52000021
*                                                                     * 52400021
* CHARACTER CODE DEPENDENCY -                                         * 52800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 53200021
*                                                                     * 53600021
* NOTES -                                                             * 54000021
*                                                                     * 54400021
*********************************************************************** 54800021
         EJECT                                                          55200021
*                  SYMBOLIC REGISTER USAGE                              55600021
*                                                                       56000021
*                                                                       56400021
*                  ESTABLISH ADDRESSABILITY                             56800021
         BALR  RBASE,0                  SET BASE REGISTER               57200021
         USING *,RBASE                                                  57600021
         USING FORCORE,RCORE            WORK AREA                       58000021
         USING IHADCB,RDCB              DCB                             58400021
         USING UCBOB,RUCB               UCB                             58800021
         USING TIOENTRY,RTIOT           TIOT ENTRY                      59200021
*                                                                       59600021
         B     OTA19500(RET)            GO TO PROPER ENTRY              60000021
OTA19500 EQU   *                                                        60400021
         B     OTA19600                 INITAL ENTRY FOR ALL DCBS BUT   60800021
*                                       THE FIRST ONE                   61200021
         B     OTA19800                 REMOUNT ENTRY                   61600021
*              THE XCTL TO OMODVOL1 ENTERS HERE AND PROCESSING          62000021
*              FOR THE FIRST DCB STARTS AFTER RESTORING THE RESIDENT    62400021
*              ROUTINE ADDRESS AND THE WTG TABLE                        62800021
         LR    RES,RD                   RESTORE RES ROURINE POINTER     63200021
         MVC   K0(K8,RWTG),MODNAME      RESTORE MODULE NAME             63600021
OTA19600 EQU   *                                                        64000021
         SPACE                                                          64400021
*CHECK JFCB MASK TO DETERMINE IF PROCESSING IS REQUIRED ON THIS DCB     64800021
         TM    JFCBMASK+K5,LBLERR       TEST FOR CONFLICT IN LABEL      65200021
         BNZ   OTA19700                 BRANCH IF LABEL CONFLICT        65600021
         LA    RF,ID3C4I                POINT TO FINAL COMMON IDTTR     66000021
         B     OTA20100                 EXIT - DENSITY CONFLICT         66400021
         SPACE                                                          66800021
OTA19700 EQU   *                                                        67200021
*                                                                       67600021
         CLC   DXVOLMT1,SCRATCH1+K1     IS THIS A SCRATCH REQUEST       68000021
         BE    OTA20000                 YES, BRANCH                     68400021
*                                                                       68800021
         SPACE                                                          69200021
*INITIALIZE STANDARD PORTION OF MOUNT MESSAGE                           69600021
         SPACE                                                          70000021
OTA19800 EQU   *                                                        70400021
         XC    MSGTEXT(K9),MSGTEXT      CLEAR MESSAGE AREA              70800021
         MVC   MCSFLAGS(K12),FLAG91     INSERT BASIC MSG                71200021
         MVC   MSGUN,UCBNAME            UNIT NAME TO MSG BUFFER         71600021
         SPACE                                                          72000021
         LA    R1,K17                   LOAD MSG LENGTH                 72400021
         MVC   MSGLSTSZ+K17(K4),DESROUT1  MCS CODES IN MSG              72800021
         STH   R1,MSGLSTSZ              STORE MSG LENGTH IN MSG HDR     73200021
         LA    R1,MSGLSTSZ              LOAD ADDRESS OF MSG HDR         73600021
         WTO   MF=(E,(1))               ISSUE 'D' MSG                   74000021
         MVC   MSGIOSUP+K4(K5),VMCLMSGE  CHANGE MSG TO MOUNT            74400021
         MVC   MSGVOLSR-K1(K8),SCRATCH1  INSERT SCRATCH IN MSG          74800021
         CLC   JFCBVOLS(K6),BLANKS1     IS JFCB VOLSER BLANK            75200021
         BE    OTA19900                 YES, BRANCH                     75600021
         CLC   DXVOLMT1,SCRATCH1+1      IS IT A SCRATCH REQUEST SA70384 75650021
         BNE   OTA19850                 BRANCH IF NOT           SA70384 75700021
         MVC   JFCBVOLS(K6),BLANKS1     BLANK VOL=SER IN JFCB   SA70384 75750021
OTA19850 EQU   *                                                SA70384 75800021
         MVC   MSGVOLSR(K6),DXVOLMT1    NO, INSERT VOLSER FROM JFCB     76000021
OTA19900 EQU   *                                                        76400021
         OI    UCBDMCT,UCBMOUNT         SET MOUNT BIT ON                76800021
         LA    RC,K8                    BRANCH TABLE VALUE              77200021
         LNR   RC,RC                    NEGATE TO INDICATE OMOD ENTRY   77600021
         LA    R1,MSGLSTSZ              ADDRESS OF MESSAGE BUFFER       78000021
         L     RB,MCSDES91              MCS CODES                       78400021
         LA    RF,ID3C4G                POINT TO MSG MODULE IDTTR       78800021
         LA    RET,K12                  ENTRY VALUE FOR MSG MOD         79200021
         B     OTA20100                 GO WRITE MESSAGE                79600021
         SPACE                                                          80000021
OTA20000 EQU   *                                                        80400021
         LA    RET,K4                   ENTRY VALUE FOR NEXT LOAD       80800021
         LA    RF,ID3C3D                DESTROY LABEL MOD IDTTR         81200021
         TM    JFCBMASK+K5,JFCSLDES     DESTROY MOD NEEDED              81600021
         BO    OTA20100                 YES, BRANCH                     82000021
         LA    RF,ID3C3E                CREATE LABEL MOD IDTTR          82400021
*                                                                       82800021
OTA20100 EQU   *                                                        83200021
         IECRES XCTL,(RF),(RET)                                         83600021
         SPACE                                                          84000021
*PROGRAM CONSTANTS                                                      84400021
         SPACE                                                          84800021
MODNAME  DC    C'IFG0193C'              THIS MODULE NAME                85200021
FLAG91   DC    X'8000'                  MCS FLAG                        85600021
VMCLMSGD DC    C'IEC114E D '            BASIC DISMOUNT MSG              86000021
VMCLMSGE DC    C'01A M'                 INSERT FOR MOUNT MSG            86400021
REWCCW1  DC    X'20000001'              REWIND CCW                      86800021
SCRATCH1 DC    C',SCRTCH,'              SCRATCH VOL SER FOR MSG         87200021
BLANKS1  DC    C'      '                BLANKS TO TEST FOR VOL SER      87600021
*                                       IN JFCB                         88000021
         DS    0F                       FULL WORD ALIGNMENT             88400021
MCSDES91 DC    X'4000'                  MCS DESCRIPTOR CODE             88800021
DESROUT1 DC    X'2000'                  DESCRIPTOR CODE FOR DEMOUNT     89200021
*                                       ROUT CODE FOR MOUNT             89600021
         DC    X'2000'                  ROUT CODE FOR DEMOUNT           90000021
         LTORG                                                          90400021
XCTL3C   XCTLTABL ID=(ID3C4G,4G,ID3C3D,3D,ID3C4I,4I,ID3C3E,3E)          90800021
         IECDSECS CVT,TCB,TIOT,DCB,UCB,MAIN,WTG,EXPAND=YES              91200021
         IECEQU                                                         91600021
         END                                                            92000021
