         TITLE 'IFG0193E/OPEN - CREATE STANDARD LABEL'                  00200000
         COPY  LCGASMSW                                                 00250000
IFG0193E CSECT                                                          00800000
*********************************************************************** 01000000
*                                                                     * 01200000
*                                                                     * 01400000
*          RELEASE 25 DELETIONS/CHANGES                               * 01600000
*          RELEASE 24 DELETIONS/CHANGES                               * 01800000
*          RELEASE 23 DELETIONS/CHANGES                               * 02000000
*          RELEASE 22 DELETIONS/CHANGES                               * 02200000
*          RELEASE 21.7 DELETIONS/CHANGES                             * 02390001
*0000                                                           SA49476 02391001
*          RELEASE 21 DELETIONS/CHANGES                               * 02400000
*0000662000                                                      A39467 02500021
*                                                                     * 02600000
* STATUS CHANGE LEVEL 000                                             * 02800000
*                                                                     * 03000000
* FUNCTION -                                                          * 03200000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03400000
*    OPEN TAPE CREATE LABEL FUNCTION.                                 * 03600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 03800000
*                                                                     * 04000000
* ENTRY POINTS -                                                      * 04200000
*    IFG0193E - ENTRY POINT VIA THE RESIDENT XCTL FROM THE FOLLOWING--* 04400000
*       IFG0193C OR IFG0193D - TO CREATE A STANDARD LABEL.            * 04600000
*                                                                     * 04800000
* INPUT -                                                             * 05000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05200000
*                                                                     * 05400000
* OUTPUT -                                                            * 05600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05800000
*                                                                     * 06000000
* EXTERNAL REFERENCES -                                               * 06200000
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 06400000
*          WAIT.                                                      * 06600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06800000
*                                                                     * 07000000
* EXITS, NORMAL -                                                     * 07200000
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO ONE OF THE FOLLOWING--     * 07400000
*       IFG0193C - WHEN A REMOUNT IS REQUIRED.                        * 07600000
*       IFG0194F - TO REPROCESS THE DCB.                              * 07800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 08000000
*                                                                     * 08200000
* EXITS, ERROR -                                                      * 08400000
*    NONE.                                                            * 08600000
*                                                                     * 08800000
* TABLES/WORK AREAS -                                                 * 09000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 09200000
*                                                                     * 09400000
* ATTRIBUTES -                                                        * 09600000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 09800000
*                                                                     * 10000000
* CHARACTER CODE DEPENDENCY -                                         * 10200000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10400000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 10600000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 10800000
*                                                                     * 11000000
* NOTES -                                                             * 11200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11400000
*                                                                     * 11600000
*********************************************************************** 11800000
         EJECT                                                          12000000
*********************************************************************** 12200000
*                                                                     * 12400000
*                          FUNCTION PROLOG                            * 12600000
*                                                                     * 12800000
*********************************************************************** 13000000
*                                                                     * 13200000
* FUNCTION NAME -                                                     * 13400000
*    OPEN TAPE CREATE LABEL FUNCTION.                                 * 13600000
*                                                                     * 13800000
* (STATUS) -                                                          * 14000000
*    NOT APPLICABLE                                                   * 14200000
*                                                                     * 14400000
* FUNCTION -                                                          * 14600000
*    GET FROM THE OPERATOR PERMISSION TO CREATE THE LABEL AND THE     * 14800000
*    NECESSARY LABEL INFORMATION.                                     * 15000000
*    WRITE A STANDARD OR ASCII LABEL AN TAPE MARK.                    * 15200000
*    ASCII LABELS ARE TRANSLATED BEFORE THEY ARE WRITTEN.             * 15400000
*    EXIT FOR A REMOUNT IF AN I/O ERROR OCCURES WHEN WRITTING THE     * 15600000
*    LABEL OR TAPE MARK.                                              * 15800000
*                                                                     * 16000000
* ENTRY POINTS -                                                      * 16200000
*    ENTERED FROM THE FOLLOWING--                                     * 16400000
*    OPEN TAPE LABEL EDITOR FUNCTION OR OPEN TAPE DESTROY LABEL       * 16600000
*    FUNCTION TO CREATE A STANDARD LABEL.                             * 16800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 17000000
*                                                                     * 17200000
* INPUT -                                                             * 17400000
*    A POINTER TO EACH OF THE FOLLOWING--                             * 17600000
*       CURRENT PARAMETER LIST ENTRY.                                 * 17800000
*       DD ENTRY IN THE TIOT.                                         * 18000000
*       WTG TABLE.                                                    * 18200000
*       CURRENT WTG TABLE ENTRY.                                      * 18400000
*       DCB.                                                          * 18600000
*       OPEN WORK AREA.                                               * 18800000
*       RESIDENT ROUTINE.                                             * 19000000
*       UCB                                                           * 19200000
*                                                                     * 19400000
* OUTPUT -                                                            * 19600000
*    STANDARD OR ASCII VOLUME LABEL WRITTEN ON THE TAPE.              * 19800000
*    THE FOLLOWING MESSAGES ARE ISSUED WHEN REQUIRED--                * 20000000
*       IEC704A L - REQUEST LABEL INFORMATION.                        * 20200000
*       IEC112I I/O ERROR - I/O ERROR DURING WRITE OF LABEL OR        * 20400000
*       TAPE MARK.                                                    * 20600000
*                                                                     * 20800000
* EXTERNAL REFERENCES -                                               * 21000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 21200000
*                                                                     * 21400000
* EXITS, NORMAL -                                                     * 21600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 21800000
*    OPEN TAPE LABEL EDITOR FUNCTION WHEN A REMOUNT IS REQUIRED.      * 22000000
*    OPEN TAPE MOUNT VERIFICATION FUNCTION TO REPROCESS THE DCB.      * 22200000
*                                                                     * 22400000
* EXITS, ERROR -                                                      * 22600000
*    NONE.                                                            * 22800000
*                                                                     * 23000000
* TABLES/WORK AREAS -                                                 * 23200000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 23400000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 23600000
*                                                                     * 23800000
* ATTRIBUTES -                                                        * 24000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 24200000
*                                                                     * 24400000
* CHARACTER CODE DEPENDENCY -                                         * 24600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 24800000
*                                                                     * 25000000
* NOTES -                                                             * 25200000
*                                                                     * 25400000
*********************************************************************** 25600000
         EJECT                                                          25800000
*                                                                       26000000
         USING FORCORE,RCORE            WORK AREA                       26200000
         USING TIOENTRY,RTIOT           TIOT ENTRY                      26400000
         USING IHADCB,RDCB              DCB                             26600000
         USING UCBOB,RUCB               UCB                             26800000
         BALR  RBASE,0                  SET BASE REGISTER               27000000
         USING *,RBASE                                                  27200000
*                                                                       27400000
*                                                                       27600000
*  GET VOLUME LABEL INFORMATION                                         27800000
*                                                                       28000000
*  SET UP TO WRITE TO OPERATOR THE FOLLOWING MESSAGE                    28200000
*                                                                       28400000
*              IEC704A L DDD                                            28600000
*                                                                       28800000
*  WHERE L INDICATES THAT LABEL INFORMATION IS REQUIRED FOR THE         29000000
*  OUTPUT TAPE VOLUME MOUNTED ON DEVICE DDD.  OPERATOR RESPONSE-        29200000
*                                                                       29400000
*              REPLY XX, 'SER,OWNER'                                    29600000
*                                                                       29800000
*  WHERE SER IS THE 6-DIGIT VOLUME SERIAL NUMBER AND OWNER IS A         30000000
*  10 CHARACTER FIELD FOR OWNER'S NAME OR SIMILAR IDENTIFICATION.       30200000
*                                                                       30400000
OTA23300 EQU   *                        GET SERIAL NO FROM OPERATOR     30600000
         SPACE                                                          30800000
         MVI   MSGTEXT+K19,BLANK        CLEAR REPLY AREA                31000000
         MVC   MSGTEXT+K20(K27),MSGTEXT+K19  TO BLANKS                  31200000
         LA    R1,MSGTEXT+K19             PLACE ADDRESS FOR REPLY       31400000
         ST    R1,REPLYLTH              INTO WTOR REPLY ADDRESS         31600000
         MVI   REPLYLTH,K17             LENGTH OF REPLY IS 17 CHR       31800000
         TM    JFCBLTYP,JFCBAL          ANSI LABEL SPECIFIED            32000000
         BZ    OTA23400                 NO, BRANCH                      32200000
         MVI   REPLYLTH,K21             REPLY LENGTH IS 21 CHAR         32400000
OTA23400 EQU   *                                                        32600000
         LA    R1,DXECB                 PLACE ADDRESS OF ECB            32800000
         ST    R1,REPLYECB              INTO THE WTOR ECB ADDRESS       33000000
         ST    R1,MSGLSTSZ              INSURE ZEROS IN MSG LIST        33200000
         LA    R1,K17                   LENGTH OF MESS + LGN FLD        33400000
         STH   R1,MSGLSTSZ              STORE MESSAGE LENGTH            33600000
         MVC   MCSFLAGS,FLAG9T          TURN ON HI BIT FOR MCS          33800000
         MVC   MSGIOSUP(K10),IEC704A    MOVE IN BASIC MESSAGE           34000000
         MVC   MSGUN,UCBNAME            SYMBOLIC UNIT NAME TO MSG       34200000
         MVC   MSGUN+K3(K4),MCSRTDST    STORE ROUTING MCS INFO          34400000
         MVI   DXECB,K0                 CLEAR ECB COMPLETION BITS       34600000
         LR    R1,RCORE                 GET MESSAGE ADDR FOR WTOR       34800000
*                                       ASK OPERATOR FOR SERIAL         35000000
         WTOR  MF=(E,(1))               NUMBER AND OWNER INFO           35200000
         SPACE                                                          35400000
         WAIT  ECB=DXECB                WAIT FOR OPERATOR'S REPLY       35600000
         SPACE                                                          35800000
         MVI   VOLLABI,BLANK            CLEAR OUT FIRST PART            36000000
         MVC   VOLLABI+K1(51),VOLLABI   OF LABEL AREA                   36200000
         SPACE ,                                                        36400000
         OC    VOLLABI,MSGTEXT+K19      RETRIEVE 1ST TWO CHRS           36600000
         CLC   CHRM9T,VOLLABI           IF OPER WANTS DISMOUNT          36800000
         BE    OTA24400                 GO TO LOAD OMODVOL1             37000000
         SPACE ,                                                        37200000
         LA    RD,K7                    LOOK THRU 7 CHRS FOR COMMA      37400000
         LA    R1,VOLNO                 POINT IN FRONT OF VOLSER        37600000
         SPACE ,                                                        37800000
OTA23600 EQU   *                        LOOP TO CHECK REPLY             38000000
         SPACE ,                                                        38200000
         LA    R1,K1(R1)                POINT TO NEXT CHAR              38400000
         CLI   K48(R1),COMMA            IS THIS A COMMA                 38600000
         BNE   OTA23700                 NO, CONTINUE                    38800000
         MVC   VOLOWNER,K49(R1)         MOVE IN OWNER INFORMATION       39000000
         TM    JFCBLTYP,JFCBAL          ANSI LABELS SPECIFIED           39200000
         BZ    OTA24000                 NO, BRANCH                      39400000
         MVC   AVOLOWNR,K49(R1)         MOVE OWNER INFO TO LABEL        39600000
         B     OTA24000                 GO TEST LENGTH OF VOLSER        39800000
OTA23700 EQU   *                                                        40000000
         OC    K0(K1,R1),K48(R1)        FOLD CHAR INTO VOLSERNO         40200000
         TM    VOLLABI+K3,K1            HAS A BLANK BEEN FOUND          40400000
         BNO   OTA23800                 NO, GO CHECK FOR ONE NOW        40600000
         CLI   K0(R1),BLANK             IS IT AN EMBEDDED BLANK         40800000
         BNE   OTA23300                 YES, GO ISSUE MESSAGE AGAIN     41000000
         SPACE ,                                                        41200000
OTA23800 EQU   *                        CHECK FOR A FIRST BLANK         41400000
         SPACE ,                                                        41600000
         CLI   K0(R1),BLANK             IS THIS A BLANK                 41800000
         BNE   OTA23900                 NO, GO TEST FOR ALPHAMERIC      42000000
         SPACE ,                                                        42200000
         OI    VOLLABI+K3,K1            SET BLANK HAS BEEN FOUND        42400000
         SPACE ,                                                        42600000
OTA23900 EQU   *                        BR IF MORE CHRS TO CHECK        42800000
         SPACE ,                                                        43000000
         BCT   RD,OTA23600              GO TO NEXT CHR IF LESS THAN 7   43200000
         SPACE ,                                                        43400000
OTA24000 EQU   *                        SET UP TO MOVE VOLSERNO         43600000
         SPACE ,                                                        43800000
         CLI   VOLSERNO,BLANK           IS VOLSERNO BLANK               44000000
         BE    OTA23300                 YES, GO ISSUE MESSAGE AGAIN     44200000
*                                                                       44400000
*              AT THIS POINT THE OPERATOR HAS SUPPLIED A GOOD           44600000
*              VOLUME SERIAL NUMBER                                     44800000
*                                                                       45000000
         CLC   DXVOLMT1,SCRATC9T        IS THIS A NON-SPECIFIC VOL REQ  45200000
         BE    OTA24100                 YES, BRANCH TO WRITE LABEL      45400000
         SPACE                                                          45600000
         CLC   DXVOLMT1,VOLSERNO        DID THE OPERATOR SPECIFY THE    45800000
*                                       SAME VOL SER AS REQUESTED       46000000
         BNE   OTA24400                 NO, GO ASK FOR REMOUNT          46200000
         SPACE                                                          46400000
OTA24100 EQU   *                        SET UP TO WRITE LABEL           46600000
         SPACE                                                          46800000
         MVC   UCBVOLI,VOLSERNO         PUT VOL SER IN UCB              47000000
         MVC   DXCCW1,ACCWT             GET BASIC CCW FOR REWIND        47200000
         BAL   RB,OTA24600              REWIND TAPE TO LOAD POINT       47400000
         ST    RCORE,DXCCW1             ADDR OF LABEL AREA              47600000
         MVI   DXCCW1,CCWWRTAP          1ST CCW IS WRITE VOL1           47800000
*                                                                       48000000
*              BUILD VOLUME LABEL 1                                     48200000
*                                                                       48400000
         MVC   VOLLABI(L'AVOL1T),AVOL1T   PUT IN LABEL IDENTIFIER       48600000
         MVI   VOLSEC,CHAR0             SECURITY                        48800000
         MVI   VOLOWNER+K10,BLANK       CLEAR                           49000000
         MVC   VOLOWNER+K11(K28),VOLOWNER+K10   2ND AREA                49200000
         TM    JFCBLTYP,JFCBAL          ANSI LABEL SPECIFIED            49400000
         BZ    OTA24200                 NO, GO WRITE LABEL              49600000
*                                                                       49800000
*   MAKE CHANGES REQUIRED TO CREATE AN ANSI LABEL                       50000000
*                                                                       50200000
         MVI   VOLSEC,BLANK             ACCESSABILITY BYTE TO BLANK     50400000
         MVI   LABSTAND,CHAR1           SET LABEL STANDARD              50600000
*                                                                       50800000
*              TRANSLATE LABEL DATA TO ASCII CODE BEFORE WRITING        51000000
*                                                                       51200000
         XLATE DXLBL,K80,TO=A           TRANSLATE LABEL DATA            51400000
OTA24200 EQU   *                                                        51600000
         BAL   RB,OTA24600              GO ISSUE CHANNEL PROGRAM        51800000
         SPACE                                                          52000000
         MVC   DXCCW2,ACCWT             NEED ANOTHER CHAN PROG          52200000
         MVI   DXCCW1,CCWWTM            GET WRITE TAPE MARK OP CODE     52400000
         MVI   DXCCW1+K4,CCWCMDCH       CONNECT TO NEXT CCW             52600000
         MVI   DXCCW2,CCWNOP            GET NOP CODE                    52800000
         SPACE                                                          53000000
         BAL   RB,OTA24600              WRITE A TAPE MARK               53200000
         SPACE                                                          53400000
         OI    UCBDMCT,UCBMOUNT         INDICATE LABEL VERIFICATION     53600000
         MVC   JFCBVOLS(K6),UCBVOLI     MOVE VOLUME SERIAL TO JFCB      53800000
         NI    JFCBMASK+K5,LBWTRI9T     TURN OFF LBL ERR INDICATORS     54000000
         TM    JFCBLTYP,JFCBAL          ANSI LABEL SPECIFIED            54200000
         BZ    OTA24300                 NO SET STANDARD LABEL BIT       54400000
         OI    UCBSTAB,UCBBSTR          YES SET ANSI LABEL BIT          54600000
         NI    UCBSTAT,X'FF'-UCBDADI    RESET SL BIT OFF IN UCB         54800000
         B     OTA24400                 GO TO NEXT LOAD                 55000000
OTA24300 EQU   *                                                        55200000
         OI    UCBSTAT,UCBDADI          MARK UCB FOR STANDARD LBL       55400000
         NI    UCBSTAB,X'FF'-UCBBSTR    RESET AL BIT OFF IN UCB         55600000
OTA24400 EQU   *                                                        55800000
         LA    RF,ID3E4F                MOUNT VERIFICATION MOD IDTTR    56000000
         LA    RET,K0                   NORMAL ENTRY MNT VERIFY         56200000
         TM    JFCBMASK+K5,JFCSLCRE     IS REMOUNT NEEDED               56400000
         BZ    OTA24500                 NO, BRANCH                      56600000
         LA    RF,ID3E3C                LABEL EDITOR MODULE IDTTR       56800000
         LA    RET,K4                   ENTRY VALUE                     57000000
         B     OTA24550                 BR TO EXIT              SA49476 57050001
OTA24500 EQU   *                                                        57200000
         XC    UCBVOLI,UCBVOLI          ZERO UCBVOL TO SIMULATE SA49476 57250001
*                                       VOL REF FUNCTION INTER- SA49476 57251001
*                                       FACE TO MOUNT VERIFICAT SA49476 57252001
*                                       MOUNT BIT ON, UCBVOLI   SA49476 57253001
*                                       ZERO, THEREFORE UNIT    SA49476 57254001
*                                       ALREADY SELECTED FOR    SA49476 57255001
*                                       SCRATCH REQUEST         SA49476 57256001
OTA24550 EQU   *                                                SA49476 57300001
         IECRES XCTL,(RF),(RET)                                         57400000
*                                                                       57600000
OTA24600 EQU   *                                                        57800000
         SPACE                                                          58000000
         EXCP  DXIOB                    ISSUE I/O OPERATION             58200000
         SPACE                                                          58400000
         IECRES WAIT                                                    58600000
         SPACE                                                          58800000
         TM    DXECB,ECBNOERR           TEST FOR ERROR                  59000000
         BCR   1,RB                     NO ERROR - RETURN TO CALLER     59200000
         SPACE                                                          59400000
         TM    IOBSTAT0,CSWUNITX        CK FOR UNIT EXCEPTION           59600000
         BCR   1,RB                     YES - IGNORE FOR NOW            59800000
         SPACE                                                          60000000
         NI    DCBIFLGS,X'FF'-DCBIFPIO  TURN OFF ERROR FLAGS IN         60200000
*                                       DCB TO ISSUE REWIND             60400000
*                                       AND/OR UNLOAD COMMAND           60600000
*                                                                       60800000
*              OPEN HAS FOUND AN UNCORRECTABLE I/O ERROR, BUT WILL      61000000
*              ASK FOR NEW VOLUME RATHER THAN ABEND WITH '613'          61200000
*                                                                       61400000
OTA24700 EQU   *                        ASK FOR NEW VOLUME              61600000
         SPACE                                                          61800000
         MVC   MSGIOSUP(K16),ERRMSG9T   GET FIRST PART OF MESSAGE       62000000
         MVC   MSGUN+K6,UCBNAME         MOVE IN DEVICE ADDRESS          62200000
         MVI   MSGUN+K9,COMMA           PUT COMMA BETWEEN DDD & SER     62400000
         MVC   MSGVOLSR+K6,UCBVOLI      MOVE IN VOLUME SERIAL NUMBER    62600000
         MVC   MSGTEXT+K5(K4),MCSRTDS4  STORE ROUTING MCS INFO          62800000
         LA    R1,K30                   LOAD LENGTH OF MESSAGE          63000000
         STH   R1,MSGLSTSZ              STORE MESSAGE LENGTH            63200000
         LA    R1,MSGLSTSZ              GET ADDR OF MESSAGE AREA        63400000
         MVC   MCSFLAGS,FLAG9T          TURN ON HI BIT FOR MCS          63600000
         SPACE                                                          63800000
         WTO   MF=(E,(1))               WRITE TO OPERATOR               64000000
         SPACE                                                          64200000
         B     OTA24400                 GO TO REMOUNT                   64400000
*                                                                       64600000
         SPACE                                                          64800000
*                   CONSTANTS                                           65000000
ERRMSG9T DC    C'IEC112I I/O ERR '      BASIC ERROR MESSAGE             65200000
IEC704A  DC    C'IEC704A L '            BASIC LABEL MESSAGE             65400000
AVOL1T   DC    C'VOL1'                  VOL LABEL IDENTIFIER            65600000
ACCWT    DC    X'0700000020000050'      BASIC CCW - REWIND COMMAN       65800000
FLAG9T   DC    X'8000'                  MCS HI ORDER FLAG               66000000
MCSRTDST DC    X'40002000'              MSG IEC704A DESCRIPTOR   A39467 66100021
*                                       AND ROUTING CODES               66200021
MCSRTDS4 DC    X'10002040'              RTE TO TP POOL & ERR CONS       66400000
ONE9T    DC    X'0001'                  ONE                             66600000
SCRATC9T DC    C'SCRTCH'                UNSPECIFIED VOLUME              66800000
CHRM9T   DC    C'M '                    REMOUNT REPLY                   67000000
         LTORG                                                          67200000
XCTL3E   XCTLTABL ID=(ID3E3C,3C,ID3E4F,4F)                              67400000
         IECDSECS CVT,TCB,TIOT,DCB,UCB,MAIN,WTG,EXPAND=YES              67600000
         IECEQU                                                         67800000
         END                                                            68000000
