         TITLE 'IFG0194A/OPEN - DA MOUNT MESSAGE'                       00100021
         COPY  LCGASMSW                                                 00150000
IFG0194A CSECT                                                          00400021
*********************************************************************** 00500021
*                                                                     * 00600021
*                                                                     * 00660000
*          VS2 RELEASE 01 DELETIONS                                   * 00670000
*0000                                                            YM0871 00680000
*                                                                     * 00690000
*                                                                     * 00700021
*          RELEASE 25 DELETIONS/CHANGES                               * 00800021
*          RELEASE 24 DELETIONS/CHANGES                               * 00900021
*          RELEASE 23 DELETIONS/CHANGES                               * 01000021
*          RELEASE 22 DELETIONS/CHANGES                               * 01100021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 01170000
*0000179000,486000,489000                                       SA70424 01180021
*          RELEASE 21 DELETIONS/CHANGES                               * 01200021
*0000087000                                                      M1811  01250021
*                                                                     * 01300021
* STATUS CHANGE LEVEL 000                                             * 01400021
*                                                                     * 01500021
* FUNCTION -                                                          * 01600021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 01700021
*    OPEN DA VOLUME VERIFICATION FUNCTION                             * 01800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 01900021
*                                                                     * 02000021
* ENTRY POINTS -                                                      * 02100021
*         IFG0194A                                                    * 02200021
*                                                                     * 02300021
* INPUT -                                                             * 02400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02500021
*                                                                     * 02600021
* OUTPUT -                                                            * 02700021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02800021
*                                                                     * 02900021
* EXTERNAL REFERENCES -                                               * 03000021
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 03100021
*            WAIT.                                                    * 03200021
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 03300021
*                                                                     * 03400021
* EXITS, NORMAL -                                                     * 03500021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03600021
*                                                                     * 03700021
* EXITS, ERROR -                                                      * 03800021
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0190P, IF AN      * 03900021
*    ABEND SITUATION OCCURS IN THIS MODULE.                           * 04000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04100021
*                                                                     * 04200021
* TABLES/WORK AREAS -                                                 * 04300021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04400021
*                                                                     * 04500021
* ATTRIBUTES -                                                        * 04600021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 04700021
*                                                                     * 04800021
* CHARACTER CODE DEPENDENCY -                                         * 04900021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 05000021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05100021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05200021
*                                                                     * 05300021
* NOTES -                                                             * 05400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05500021
*                                                                     * 05600021
*********************************************************************** 05700021
         EJECT                                                          05800021
*********************************************************************** 05900021
*                                                                     * 06000021
*                          FUNCTION PROLOG                            * 06100021
*                                                                     * 06200021
*********************************************************************** 06300021
*                                                                     * 06400021
* FUNCTION NAME -                                                     * 06500021
*    OPEN DA VOLUME VERIFICATION FUNCTION                             * 06600021
*                                                                     * 06700021
* (STATUS) -                                                          * 06800021
*    NOT APPLICABLE                                                   * 06900021
*                                                                     * 07000021
* FUNCTION -                                                          * 07100021
*   *SCAN AGAIN THE UCB'S POINTED TO BY THE TIOT DD ENTRY FOR         * 07200021
*    A MATCHING VOLUME SERIAL NUMBER.                                 * 07300021
*   *SELECT A UNIT FROM THE TIOT DD ENTRY UCB LIST TO MOUNT THE       * 07400021
*    DESIRED VOLUME ON.                                               * 07500021
*   *INCREMENT UCB OPEN DCB DATA MANAGEMENT COUNTER TO HOLD THIS      * 07600021
*    UCB FOR THIS VOLUME.                                             * 07700021
*   *SET UP WORK DEB UCB ADDRESS AND EXTENT FOR SELECTED UNIT.        * 07800021
*   *ISSUE AN 'IEC106E R UUU,VOLSER' MESSAGE IF                       * 07900021
*    A PREVIOUS VOLUME MUST BE DEMOUNTED TO MAKE ROOM.                * 08000021
*   *ISSUE AN 'IEC101A M UUU,VOLSER,JOBNAME,STEPNAME,DSNAME'          * 08100021
*    MOUNT MESSAGE TO THE OPERATOR.                                   * 08200021
*   *READ THE VOLUME LABEL, VERIFY THAT IT IS THE CORRECT ONE,        * 08300021
*    MOVE THE VTOC TTR INTO THE UCB, AND TURN OFF THE MOUNT BIT.      * 08400021
*   *IF NONSPECIFIC REQUEST, MOVE NEW VOLUME SERIAL NUMBER INTO       * 08500021
*    JFCBVOLS.                                                        * 08600021
*   *IF WRONG VOLUME MOUNTED, ISSUE AN 'IEC111E D UUU,VOLSER'         * 08700021
*    MESSAGE, WHERE VOLSER IS THE VOLUME SERIAL NUMBER OF THE         * 08800021
*    VOLUME ACTUALLY MOUNTED.                                         * 08900021
*                                                                     * 09000021
* ENTRY POINTS -                                                      * 09100021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 09200021
*                                                                     * 09300021
* INPUT -                                                             * 09400021
*    REGISTERS -                                                      * 09500021
*       RTIOT 9 - CURRENT TIOT DD ENTRY.  MAY BE EACH OF SEVERAL      * 09600021
*          ENTRIES FOR CONCATENATED BPAM OR ISAM.                     * 09700021
*       RET  14 - ENTRY INDICATOR.                                    * 09800021
*    WORK AREAS -                                                     * 09900021
*       DXLBL (96 BYTES) - MUST BE AVAILABLE FOR USE AS WORK AREA     * 10000021
*          FOR WRITING MESSAGES, AND READING VOLUME LABEL.            * 10100021
*       DXJBF (176 BYTES) - USED FOR DSNAME AND 'TEMPORARY DATA SET'  * 10200021
*          INDICATOR IN MOUNT MESSAGE (BY IFG0190R) AND BY            * 10300021
*          PROBLEM DETERMINATION FOR ITS MESSAGE IF THERE IS AN ABEND.* 10400021
*       DXCCW2+4 - ADDRESS IN TIOT DD ENTRY UCB LIST OF FIRST         * 10500021
*          UCB POINTER THAT CAN BE USED.  PREVIOUS UCB                * 10600021
*          POINTERS ARE ALREADY LOCKED INTO PREVIOUS VOLUMES          * 10700021
*          OF A MULTIVOLUME MOUNT.                                    * 10800021
*       DXCCW1-DXCCW3 - ARE CONSIDERED AVAILABLE FOR USE BY THIS      * 10900021
*          FUNCTION.  DXCCW1-DXCCW2 DO NOT HAVE TO HAVE A             * 11000021
*          SEARCH ID EQ, TIC *-8 CHANNEL PROGRAM IN THEM, SINCE       * 11100021
*          IT WILL BE CONSTRUCED BY THIS FUNCTION.                    * 11200021
*       DXCCW4-DXCCW7 - WILL NOT BE TOUCHED.                          * 11300021
*       DXCCW8-DXCCW11 - ARE USED AS A REGISTER SAVE AREA.            * 11400021
*       DXVOLMT1 - CONTAINS THE VOLUME SERIAL NUMBER OF THE DESIRED   * 11500021
*          VOLUME.  IF THE REQUEST IS NONSPECIFIC, IT CONTAINS        * 11600021
*          'SCRTCH'.                                                  * 11700021
*       IF RET=4 OR 8 - THE WORK DEB MUST ALREADY BE SET UP FOR THE   * 11800021
*          UNIT SELECTED FOR THE VOLUME.                              * 11900021
*                                                                     * 12000021
* OUTPUT -                                                            * 12100021
*    REGISTERS -                                                      * 12200021
*       R0-R1 0-1 - ARE TO BE CONSIDERED UNDEFINED.                   * 12300021
*       RTIOT 9 - CURRENT TIOT DD ENTRY.  SAME AS AT ENTRY.           * 12400021
*       RUCB 10 - CURRENT MAIN OR SUB UCB ADDRESS.                    * 12500021
*       RB-RD 11-13 - ARE TO BE CONSIDERED UNDEFINED.                 * 12600021
*       RET  14 - SET TO 4 AS RETURN ENTRY INDICATOR.                 * 12700021
*    WORK AREAS -                                                     * 12800021
*       DXLBL (96 BYTES) - HAS VOLUME LABEL. ALL CURRENT CALLING      * 12900021
*          FUNCTIONS CONSIDER IT TO BE UNDEFINED.                     * 13000021
*       DXJBF (176 BYTES) - SAME AS AT ENTRY.                         * 13100021
*       DXCCW2+4 - ADDRESS IN TIOT DD ENTRY UCB LIST OF FIRST         * 13200021
*          UCB POINTER THAT CAN BE USED. SAME AS AT ENTRY.            * 13300021
*       DXCCW1-DXCCW3 - CONTAIN A SEARCH ID EQ, TIC *-8 CHANNEL       * 13400021
*          PROGRAM.                                                   * 13500021
*       DXCCW4-DXCCW7 - SAME AS AT ENTRY.                             * 13600021
*       DXCCW8-DXCCW11 - ARE USED AS A REGISTER SAVE AREA.            * 13700021
*       DXVOLMT1 - CONTAINS THE VOLUME SERIAL NUMBER OF THE DESIRED   * 13800021
*          VOLUME.  IF THE REQUEST WAS NONSPECIFIC, IT STILL CONTAINS * 13900021
*          'SCRTCH' AND NOT THE NAME OF THE NEW VOLUME.               * 14000021
*                                                                     * 14100021
* EXTERNAL REFERENCES -                                               * 14200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 14300021
*                                                                     * 14400021
* EXITS, NORMAL -                                                     * 14500021
*   *FINAL EXIT FROM THIS FUNCTION IS VIA XCTL TO THE MODULE WHOSE    * 14600021
*    IDTTR IS IN DXRETMOD.                                            * 14700021
*   *THIS PARTICULAR MODULE, IFG0194A, XCTLS TO                       * 14800021
*    IFG0190R IF A DSNAME IS NEEDED ON A MOUNT MESSAGE, OR ELSE TO    * 14900021
*    IFG0194C TO PERFORM THE REMAINER OF THIS FUNCTION.               * 15000021
*                                                                     * 15100021
* EXITS, ERROR -                                                      * 15200021
*   *413 ABEND VIA PROBLEM DETERMINATION MODULE IFG0190P IF           * 15300021
*    UNABLE TO DEMOUNT A VOLUME IN ORDER TO MOUNT THE DESIRED VOLUME. * 15400021
*   *413 ABEND VIA PROBLEM DETERMINATION MODULE IFG0190P IF           * 15500021
*    AN I/O ERROR WHILE READING THE VOLUME LABEL.                     * 15600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 15700021
*                                                                     * 15800021
* TABLES/WORK AREAS -                                                 * 15900021
*    THE FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY  * 16000021
*    THE DSECTS AT THE END OF THE LISTING.                            * 16100021
*                                                                     * 16200021
* ATTRIBUTES -                                                        * 16300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16400021
*                                                                     * 16500021
* CHARACTER CODE DEPENDENCY -                                         * 16600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16700021
*                                                                     * 16800021
* NOTES -                                                             * 16900021
*   *THIS FUNCTION MAY GO INTO A WAIT STATE UNTIL THE REQUESTED       * 17000021
*    VOLUME HAS BEEN MOUNTED.                                         * 17100021
*    A DISPLAY R COMMAND WILL INDICATE WHAT UCB IS BEING WAITED ON,   * 17200021
*    BECAUSE THE UCB MOUNT BIT WILL BE ON.                            * 17300021
*   *ONE OF THE MAIN CONSTRAINTS OF THIS FUNCTION IS TO USE AS LITTLE * 17400021
*    WORK AREA AS POSSIBLE, BECAUSE SOME OF THE FUNCTIONS THAT CALL   * 17500021
*    THIS FUNCTION HAVE VERY LITTLE WORK AREA TO SPARE.               * 17600021
*********************************************************************** 17700021
         EJECT                                                          17800021
         IECDSECS TIOT,UCB,MAIN,BASE    DEFINE DESIRED DSECTS   SA70424X17900021
                                        TO BE EXPANDED AT THE END       18000000
*                                                                       18100021
         IECEQU ,                       DEFINE EQUATES                  18200021
*                                                                       18300021
         USING FORCORE,RCORE            DEFINE BASE TO MAIN WORK AREA   18400021
         USING TIOENTRY,RTIOT           DEFINE BASE TO TIOT DD ENTRY    18500021
         USING UCBOB,RUCB               DEFINE BASE TO MAIN UCB         18600021
*                                                                       18700021
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         18800021
         USING *,RBASE                  DEFINE BASE REGISTER            18900021
*                                                                       19000021
         B     ODA60200(RET)            BR TO INDICATED FUNCTION        19100021
*                                                                       19200021
ODA60200 B     ODA60400                 RET=0 SEL UNIT,MNT MSG,VOL VER  19300021
         B     ODA63800                 RET=4 MOUNT MSG, VOL VERIFY     19400021
         B     ODA65600                 RET=8 VOLUME VERIFY             19500021
*                                                                       19600021
*********************************************************************** 19700021
*                                                                       19800021
*  TRY TO FIND UCB THAT HAS THE DESIRED VOLUME MOUNTED ON IT.           19900021
*                                                                       20000021
*  THIS IS A REPEAT TEST SINCE A PARALLEL OPEN FOR THE SAME VOLUME      20100021
*  MAY HAVE JUST SELECTED A PARTICULAR UNIT FOR THIS SAME VOLUME        20200021
*  AND NATURALLY THE SAME UNIT MUST BE USED FOR THE SAME VOLUME.        20300021
*                                                                       20400021
ODA60400 EQU   *                                                        20500021
         L     RC,DXCCW2+K4             POINT TO TIOT CURRENT UCB PTR   20600021
         LR    RF,RC                    SAVE ADDR FOR UCB ADDR SWAP     20700021
         SR    R0,R0                    GET LENGTH OF THIS              20800021
         IC    R0,TIOELNGH              TIOT DD ENTRY                   20900021
         AR    R0,RTIOT                 LAST PLUS ONE UCB ADDR          21000021
         B     ODA60800                 BR TO START UCB LOOP            21100021
*                                                                       21200021
ODA60600 EQU   *                                                        21300021
         LA    RC,K4(RC)                POINT TO NEXT TIOT UCB ADDR     21400021
         CR    RC,R0                    CHECK FOR MORE UCB ADDRS        21500021
         BNL   ODA61200                 BR IF NO MORE                   21600021
*                                                                       21700021
ODA60800 EQU   *                                                        21800021
         L     RUCB,0(RC)               LOAD UCB ADDR FROM TIOT         21900021
         CLI   UCBID,UCBMAIN            TEST FOR 2321                   22000021
         BE    ODA61000                 BR IF NOT 2321                  22100021
*                       2321 DATACELL PROCESSING                        22200021
         USING UCBDCELL,RUCB            SET BASE FOR DATACELL           22300021
         CLC   UCBDVOLI,DXVOLMT1        CHECK FOR CORRECT VOLUME        22400021
         BNE   ODA60600                 BR IF NO                        22500021
*                                                                       22600021
         BAL   RET,ODA62000             BR TO SET UP FOR 2321 SUB-UCB   22700021
*                                                                       22800021
         B     ODA65600                 BR TO VERIFY VOLUME TO BE SURE  22900021
*                                                                       23000021
*              NORMAL DIRECT ACCESS PROCESSING                          23100021
         USING UCBOB,RUCB               NORMAL MAIN UCB                 23200021
ODA61000 EQU   *                                                        23300021
         CLC   UCBVOLI,DXVOLMT1         CHECK IF CORRECT VOLUME         23400021
         BNE   ODA60600                 BR IF NOT                       23500021
*                                                                       23600021
         BAL   RET,ODA62200             BR TO SET UP FOR NORMAL UCB     23700021
*                                                                       23800021
         B     ODA65600                 BR TO VERIFY VOLUME TO BE SURE  23900021
*                                                                       24000021
*********************************************************************** 24100021
*                                                                       24200021
*  TRY TO FIND AN EMPTY UNIT TO MOUNT VOLUME ON.                        24300021
*                                                                       24400021
ODA61200 EQU   *                                                        24500021
         LR    RC,RF                    POINT TO TIOT CURRENT UCB PTR   24600021
         SR    R0,R0                    GET LENGTH OF CURRENT           24700021
         IC    R0,TIOELNGH              TIOT DD ENTRY                   24800021
         AR    R0,RTIOT                 LAST PLUS ONE UCB ADDR          24900021
         B     ODA61600                 BR TO START UCB LOOP            25000021
*                                                                       25100021
ODA61400 EQU   *                                                        25200021
         LA    RC,K4(RC)                POINT TO NEXT TIOT UCB ADDR     25300021
         CR    RC,R0                    CHECK FOR MORE UCB ADDRS        25400021
         BNL   ODA62400                 BR IF NO MORE                   25500021
*                                                                       25600021
ODA61600 EQU   *                                                        25700021
         L     RUCB,0(,RC)              LOAD UCB ADDR FROM TIOT         25800021
         CLI   UCBID,UCBMAIN            TEST FOR 2321                   25900021
         BE    ODA61800                 BR IF NOT 2321                  26000021
*                       2321 DATACELL PROCESSING                        26100021
         USING UCBDCELL,RUCB            SET BASE FOR DATACELL           26200021
         CLI   UCBDVOLI,K0              TEST IF EMPTY UNIT              26300021
         BNE   ODA61400                 BR IF NO                        26400021
*                                                                       26500021
         BAL   RET,ODA62000             BR TO SET UP FOR 2321 SUB-UCB   26600021
*                                                                       26700021
         B     ODA63800                 BR TO ISSUE MOUNT MESSAGE       26800021
*                                                                       26900021
*              NORMAL DIRECT ACCESS PROCESSING                          27000021
         USING UCBOB,RUCB               NORMAL MAIN UCB                 27100021
ODA61800 EQU   *                                                        27200021
         CLI   UCBVOLI,K0               TEST IF EMPTY UNIT              27300021
         BNE   ODA61400                 BR IF NOT                       27400021
*                                                                       27500021
         BAL   RET,ODA62200             BR TO SET UP FOR NORMAL UCB     27600021
*                                                                       27700021
         B     ODA63800                 BR TO ISSUE MOUNT MESSAGE       27800021
*                                                                       27900021
*********************************************************************** 28000021
*                                                                       28100021
*                       2321 DATACELL PROCESSING                        28200021
ODA62000 EQU   *                                                        28300021
         USING UCBDCELL,RUCB            SET BASE FOR DATACELL           28400021
         MVC   0(K4,RC),0(RF)           FIRST UCB ADDR TO CURRENT       28500021
         ST    RUCB,0(,RF)              CURRENT UCB ADDR TO FIRST       28600021
*                                                                       28700021
         LH    RD,UCBDBBNR              PICK UP BB NUMBER               28800021
         STH   RD,DXDEBBIN              STORE USER BB IN WORK AREA      28900021
         SLA   RD,K4                    MULTIPLY BB NUMBER BY 16        29000021
         LA    RD,UCBDCELL-UCBOB(RD)    (BB)(16)+MAIN UCB LENGTH        29100021
         LCR   RD,RD                    NEGATE OFFSET                   29200021
         LA    RD,0(RD,RUCB)            ZERO SET FILE MASK, MAIN UCB    29300021
         ST    RD,DXDEBUCB              STORE MAIN UCB ADDR IN WORK DEB 29400021
*                                                                       29500021
         AIF   ('&LIB' NE 'LIB1').LIB24A1                               29550000
         SSM   *+K1                     DISABLE INTERRUPTS              29600021
.LIB24A1 ANOP                                                           29650000
         AIF   ('&LIB' EQ 'LIB1').LIB14A1                               29670000
         MODESET ENABLE=NO              DISABLE INTERRUPTS       Y01082 29680000
.LIB14A1 ANOP                                                           29690000
         IC    RF,UCBDDMCT              INCREMENT UCB                   29700021
         LA    RF,K1(RF)                OPEN DCB COUNT                  29800021
         STC   RF,UCBDDMCT              BY 1                            29900021
         AIF   ('&LIB' NE 'LIB1').LIB24A2                               29950000
         SSM   ODA6800K                 RE-ENABLE INTERRUPTS            30000021
.LIB24A2 ANOP                                                           30050000
         AIF   ('&LIB' EQ 'LIB1').LIB14A2                               30060000
         MODESET ENABLE=YES             RE-ENABLE INTERRUPTS     Y01082 30070000
.LIB14A2 ANOP                                                           30080000
*                                                                       30100021
         BR    RET                      RETURN TO CALLER                30200021
*                                                                       30300021
*              NORMAL DIRECT ACCESS PROCESSING                          30400021
         USING UCBOB,RUCB               NORMAL MAIN UCB                 30500021
ODA62200 EQU   *                                                        30600021
         MVC   0(K4,RC),0(RF)           FIRST UCB ADDR TO CURRENT       30700021
         ST    RUCB,0(,RF)              CURRENT UCB ADDR TO FIRST       30800021
*                                                                       30900021
         MVC   DXDEBUCB+K1(K3),K1(RF)   MOVE UCB ADDR INTO WORK DEB     31000021
         XC    DXDEBBIN,DXDEBBIN        ZERO NOT APPLICABLE BIN NO.     31100021
*                                                                       31200021
         AIF   ('&LIB' NE 'LIB1').LIB24A3                               31250000
         SSM   *+K1                     DISABLE INTERRUPTS              31300021
.LIB24A3 ANOP                                                           31350000
         AIF   ('&LIB' EQ 'LIB1').LIB14A3                               31360000
         MODESET ENABLE=NO              DISABLE INTERRUPTS       Y01082 31370000
.LIB14A3 ANOP                                                           31380000
         IC    RF,UCBDMCT               INCREMENT UCB                   31400021
         LA    RF,K1(RF)                OPEN DCB COUNT                  31500021
         STC   RF,UCBDMCT               BY 1                            31600021
         AIF   ('&LIB' NE 'LIB1').LIB24A4                               31650000
         SSM   ODA6800K                 RE-ENABLE INTERRUPTS            31700021
.LIB24A4 ANOP                                                           31750000
         AIF   ('&LIB' EQ 'LIB1').LIB14A4                               31760000
         MODESET ENABLE=YES                                      Y01082 31770000
.LIB14A4 ANOP                                                           31780000
*                                                                       31800021
         BR    RET                      RETURN TO CALLER                31900021
*                                                                       32000021
*********************************************************************** 32100021
*                                                                       32200021
*  THE DESIRED VOLUME IS NOT MOUNTED OR BEING MOUNTED AND NO EMPTY      32300021
*  UNIT IS AVAILABLE FOR MOUNTING.  A UNIT MUST BE SELECTED FOR         32400021
*  DEMOUNTING SO THAT THIS VOLUME CAN BE MOUNTED.                       32500021
*                                                                       32600021
ODA62400 EQU   *                                                        32700021
         L     RC,DXCCW2+K4             POINT TO TIOT CURRENT UCB PTR   32800021
         LR    RF,RC                    SAVE ADDR FOR UCB ADDR SWAP     32900021
         SR    R0,R0                    GET LENGTH OF CURRENT           33000021
         IC    R0,TIOELNGH              TIOT DD ENTRY                   33100021
         AR    R0,RTIOT                 LAST PLUS ONE UCB ADDR          33200021
         B     ODA62800                 BR TO START UCB LOOP            33300021
*                                                                       33400021
ODA62600 EQU   *                                                        33500021
         LA    RC,K4(RC)                POINT TO NEXT TIOT UCB ADDR     33600021
         CR    RC,R0                    CHECK FOR MORE UCB ADDRS        33700021
         BNL   ODA65400                 BR IF NO MORE TO ABEND          33800021
*                                                                       33900021
ODA62800 EQU   *                                                        34000021
         L     RUCB,0(,RC)              LOAD UCB ADDR FROM TIOT         34100021
         CLI   UCBID,UCBMAIN            CHECK FOR 2321                  34200021
         BE    ODA63000                 BR IF NOT 2321                  34300021
*                       2321 DATACELL PROCESSING                        34400021
         USING UCBDCELL,RUCB            SET UP BASE FOR DATACELL        34500021
         TM    UCBDSTAT,UCBDRESV+UCBDPRES  TEST FOR RESERVED, PERM RES  34600021
         BNZ   ODA62600                 BR IF ANY                       34700021
         CLI   UCBDUSER,K1              CHECK FOR USER COUNT = 1        34800021
         BNE   ODA62600                 BRANCH IF NOT = 1               34900021
         TM    UCBDDMCT,X'FF'-UCBDDMNT  CHECK DATA MNGMT COUNT          35000021
         BNZ   ODA62600                 BR IF NOT ZERO, IT IS IN USE    35100021
*                                                                       35200021
         BAL   RET,ODA62000             BR TO SET UP FOR 2321 SUB-UCB   35300021
*                                                                       35400021
         B     ODA63200                 BRANCH TO CONT PROC             35500021
*                                                                       35600021
         USING UCBOB,RUCB               SET UP BASE FOR UCBOB           35700021
ODA63000 EQU   *                                                        35800021
         TM    UCBSTAT,UCBRESV+UCBPRES+UCBSYSR  TEST FOR RESERVED,      35900021
         BNZ   ODA62600                 PERM RES, SYS RES. BR IF ANY    36000021
         TM    UCBSTAB,UCBBSVL          TEST SHARED VOL BIT             36100021
         BZ    ODA62600                 BR IF NOT ON, CAN'T DEMOUNT     36200021
         TM    UCBDMCT,X'FF'-UCBMOUNT   CHECK DATA MGNT COUNT           36300021
         BNZ   ODA62600                 BR IF NOT ZERO, IT IS IN USE    36400021
*                                                                       36500021
         BAL   RET,ODA62200             BR TO SET UP FOR NORMAL UCB     36600021
*                                                                       36700021
*********************************************************************** 36800021
*                                                                       36900021
*  WRITE  'IEC106E R DDD,VOLSER'  MESSAGE TO OPERATOR TO TELL HIM       37000021
*  TO DEMOUNT THE OLD VOLUME AND SAVE IT SINCE ITS STATUS IS UNKNOWN.   37100021
*                                                                       37200021
ODA63200 EQU   *                                                        37300021
         MVC   MSGLSTSZ(ODA6780L),ODA6780K  SET UP DEMOUNT RETAIN MSG   37400021
*                                                                       37500021
         CLI   UCBID,UCBMAIN            CHECK FOR 2321                  37600021
         BE    ODA63400                 BR IF NOT 2321                  37700021
*                                                                       37800021
*                       2321 DATACELL PROCESSING                        37900021
         USING UCBDCELL,RUCB            SET UP BASE FOR SUB UCB         38000021
         MVC   MSGVOLSR,UCBDVOLI        ADD VOLUME SERIAL NO. TO MSG    38100021
         XC    UCBDVOLI,UCBDVOLI        CLEAR OLD VOL SER NO. FROM UCB  38200021
*        SHIFT ',VOLSER D&R' 2 PLACES RIGHT TO MAKE ROOM FOR /B         38300021
         MVC   MSGLSTSZ+ODA6780L+K2(K11),MSGUN+K3                       38400021
         MVC   MSGUN+K5(K11),MSGLSTSZ+ODA6780L+K2                       38500021
         MVI   MSGUN+K3,C'/'            MOVE / INTO MESSAGE             38600021
         MVC   MSGUN+K4(K1),UCBDBBNR+K1  MOVE BIN NUMBER INTO MESSAGE   38700021
         OI    MSGUN+K4,ZONEOF          CONVERT BIN NO. TO DECIMAL      38800021
         MVI   MSGLSTSZ+K1,K26          SET MSG LENGTH 2 BYTES LONGER   38900021
         L     RUCB,DXDEBUCB            LOAD MAIN UCB ADDRESS           39000021
         B     ODA63600                 BR AROUND NON-2321              39100021
*                                                                       39200021
         USING UCBOB,RUCB               ADDRESSING MAIN UCB             39300021
ODA63400 EQU   *                                                        39400021
         MVC   MSGVOLSR,UCBVOLI         ADD VOLUME SERIAL NO. TO MSG    39500021
         XC    UCBVOLI,UCBVOLI          CLEAR OLD VOL SER NO. FROM UCB  39600021
ODA63600 EQU   *                                                        39700021
         MVC   MSGUN,UCBNAME            ADD UCB UNIT NAME TO MESSAGE    39800021
*                                                                       39900021
         WTO   MF=(E,MSGLSTSZ)          WRITE DEMOUNT MSG TO OPERATOR   40000021
*                                                                       40100021
         OI    UCBFL1,UCBNOTRD          SET MAIN UCB NOT-READY BIT      40200021
*                                                                       40300021
*********************************************************************** 40400021
*  THIS WOULD MAKE A GOOD MODULE SPLIT POINT.                           40500021
*********************************************************************** 40600021
*                                                                       40700021
*  CONSTRUCT 'IEC101A M DDD,VOLSER,JOBNAME,STEPNAME' MOUNT MESSAGE      40800021
*                                                                       40900021
         IECDSECS CVT,TCB,JSCB,         DEFINE DESIRED DSECTS TO BE    X41000021
               PSCB,UPT                 EXPANDED AT THE END             41100021
*                                                                       41200021
         USING UCBOB,RUCB               ADDRESSING MAIN UCB             41300021
ODA63800 EQU   *                                                        41400021
         MVC   DXCCW3(K5),DXRETMOD      SAVE RETURN IDTTR ACROSS MSG    41500021
*                                                                       41600021
         L     RC,DXCCW2+K4             POINT TO TIOT CURRENT UCB PTR   41700021
         L     RUCB,0(,RC)              LOAD CURRENT UCB ADDRESS        41800021
*                                                                       41900021
         MVC   MCSFLAGS(ODA6700L),ODA6700K  MOVE IN BASIC MSG           42000021
*                                                                       42100021
         CLI   UCBID,UCBMAIN            CHECK FOR 2321                  42200021
         BE    ODA64200                 BR IF NO                        42300021
*                                                                       42400021
         USING UCBDCELL,RUCB            SET UP BASE FOR DATACELL        42500021
         MVI   MSGUN+K3,C'/'            SLASH AFTER UCB NAME            42600021
         MVC   MSGUN+K4(K1),UCBDBBNR+K1  BB IN MSG                      42700021
         OI    MSGUN+K4,ZONEOF          BB IN DECIMAL                   42800021
         MVI   MSGUN+K5,C','            COMMA AFTER BB                  42900021
         MVC   MSGUN+K6(K6),DXVOLMT1    VOL SER IN MSG                  43000021
         OI    UCBDDMCT,UCBDDMNT        SET MOUNT SWITCH ON             43100021
         MVC   UCBDVOLI,DXVOLMT1        SET UCB TO DESIRED VOL SER NO.  43200021
         USING UCBOB,RUCB               ADDRESSING MAIN UCB             43300021
         L     RUCB,DXDEBUCB            LOAD MAIN UCB ADDRESS           43400021
         MVC   MSGUN,UCBNAME            MOVE IN UCB NAME                43500021
         OI    UCBFL1,UCBNOTRD          SET MAIN UCB NOT-READY BIT      43600021
         L     RUCB,0(,RC)              LOAD CURRENT SUB UCB ADDR       43700021
         LA    R1,MSGVOLSR+K7           UP PTR TO LAST CHAR OF SER      43800021
         B     ODA64400                 BR TO DELIMT VOL SER NO.        43900021
*                                                                       44000021
ODA64000 CLI   0(R1),C' '               FIND THE LAST NON-BLANK CHAR    44100021
         BCR   7,RET                    BR WHEN FOUND                   44200021
         BCT   R1,ODA64000              DECR ADDR AND BR TO LOOK AGAIN  44300021
*                                                                       44400021
         USING UCBOB,RUCB               SET BASE FOR UCBOB              44500021
ODA64200 EQU   *                                                        44600021
         MVC   MSGVOLSR,DXVOLMT1        VOL SER IN MSG                  44700021
*                                                                       44800021
         OI    UCBDMCT,UCBMOUNT         SET MOUNT SWITCH ON             44900021
         MVC   UCBVOLI,DXVOLMT1         SET UCB TO DESIRED VOL SER NO.  45000021
*                                                                       45100021
         MVC   MSGUN,UCBNAME            MOVE IN UNIT ADDRESS            45200021
         MVI   MSGUN+L'MSGUN,C','       DELIMIT UNIT WITH COMMA         45300021
         LA    R1,MSGVOLSR+K5           UP PTR TO LAST CHAR OF SER      45400021
*                                                                       45500021
ODA64400 BAL   RET,ODA64000             GO REMOVE BLANKS                45600021
         MVI   K1(R1),C','              DELIMIT VOLUME SERIAL NO.       45700021
         MVI   K2(R1),C' '              BLANK OUT                       45800021
         MVC   K3(50,R1),K2(R1)         REMAINING BUFFER                45900021
*                                                                       46000021
         L     RF,CVTPTR                GET CVT ADDR                    46100021
         L     RF,CVTTCBP-CVT(,RF)      GET ADDR TCB POINTERS           46200021
         L     RF,K4(,RF)               GET CURRENT TCB ADDR            46300021
         L     RF,TCBTIO-TCB(,RF)       GET TIOT START ADDR             46400021
*                                                                       46500021
         MVC   K2(K8,R1),TIOCNJOB-TIOT(RF)  PUT THE JOB NAME IN MSG     46600021
         LA    R1,K9(R1)                ADVANCE BEYOND JOB NAME         46700021
         BAL   RET,ODA64000             GO REMOVE BLANKS                46800021
         MVI   K1(R1),C','              DELIMIT WITH A COMMA            46900021
*                                                                       47000021
         MVC   K2(K8,R1),TIOCSTEP-TIOT(RF)  PUT THE STEP NAME IN MSG    47100021
         LA    R1,K9(R1)                UPDATE MSG PTR                  47200021
         BAL   RET,ODA64000             GO REMOVE BLANKS                47300021
*                                                                       47400021
         LR    RF,R1                    DETERMINE LENGTH OF             47500021
         LA    R0,MSGLSTSZ-K1           PRESENT                         47600021
         SR    RF,R0                    MESSAGE                         47700021
         STH   RF,MSGLSTSZ              SAVE IN MSG LENGTH FIELD        47800021
*                                                                       47900021
         TM    JFCBIND2,JFCTEMP         IS DATA SET 'TEMPORARY'         48000021
         BO    ODA64600                 BR IF YES, DO NOT DISPLAY       48100021
*                                                                       48200021
         L     RF,CVTPTR                GET CVT ADDR                    48300021
         L     RF,CVTMSLT-CVT(RF)       GET MASTER SCHED LINK TBL ADDR  48400021
*                                                                       48500021
         USING BASE,RF                                                  48550021
         TM    MSSSB,MSSSDSN            IS 'DISPLAY DSN' ACTIVE SA70424 48600021
         BO    ODA65200                 BR IF YES, DSN IS REQUIRED      48700021
*                                                                       48800021
         TM    BAMONITR,BAMDSN          DO TERMINALS WANT DSN   SA70424 48900021
         BO    ODA65200                 BR IF YES, DSN IS REQUIRED      49000021
         DROP  RF                                                       49050021
*                                                                       49100021
ODA64600 EQU   *                                                        49200021
         MVC   K1(K4,R1),ODA6740K       MOVE IN MCS CODES AFTER MSG     49300021
*                                                                       49400021
         WTO   MF=(E,MSGLSTSZ)          WRITE MESSAGE TO OPERATOR       49500021
*                                                                       49600021
         ST    R1,REPLY+K4              SAVE MCS MESSAGE ID NUMBER      49700021
         MVI   REPLY+K4,LASTNTRY        INDICATE END OF MSG ID LIST     49800021
*                                                                       49900021
         L     RF,CVTPTR                GET CVT ADDR                    50000021
         L     RF,CVTTCBP-CVT(,RF)      GET ADDR TCB POINTERS           50100021
         L     RF,K4(,RF)               GET CURRENT TCB ADDR            50200021
*                                                                       50300021
         TM    TCBTSFLG-TCB(RF),TCBTSTSK  IS THIS A TIME SHARING TASK   50400021
         BNO   ODA65000                 BR IF NO                        50500021
*                                                                       50600021
         MVC   MSGLSTSZ(L'ODA6760K),ODA6760K  MOVE TSO MESSAGE TO BUFR  50700021
*                                                                       50800021
         L     RF,TCBJSCB-TCB(,RF)      LOCATE JSCB                     50900021
         USING IEZJSCB,RF               ADDRESSABILITY FOR JSCB         51000021
         LH    RET,JSCBTJID             LOCATE TJID                     51100021
         L     RF,JSCBPSCB              LOCATE PSCB                     51200021
         USING PSCB,RF                  ADDRESSABILITY FOR PSCB         51300021
         L     RF,PSCBUPT               LOCATE UPT                      51400021
         USING UPT,RF                   ADDRESSABILITY FOR UPT          51500021
*                                                                       51600021
         LA    R1,MSGLSTSZ              POINT TO START OF MESSAGE       51700021
         LA    R0,L'ODA6760K            LOAD LENGTH OF MESSAGE          51800021
*                                                                       51900021
         TM    UPTSWS,UPTMID            IS MESSAGE ID REQUIRED          52000021
         BO    ODA64800                 BR IF YES                       52100021
*                                                                       52200021
         LA    R1,MSGLSTSZ+K8           POINT TO MSG WITHOUT ID         52300021
         LA    R0,L'ODA6760K-K8         LENGTH OF SHORT MESSAGE         52400021
*                                                                       52500021
ODA64800 SLL   RET,K16                  PLACE TJID AND MSG LENGTH       52600021
         OR    R0,RET                   IN REG 0 FOR TPUT SVC CALL      52700021
*                                                                       52800021
         TPUT  (1),(0),R                SEND TSO MSG TO TERMINAL        52900021
*                                                                       53000021
         DROP  RF                                                       53100021
*                                                                       53200021
ODA65000 EQU   *                                                        53300021
         IECRES XCTL,ODA6960X,0         XCTL TO NEXT MOUNT MODULE       53400021
*                                                                       53500021
ODA65200 EQU   *                                                        53600021
         MVI   REPLY,K0                 IND WTO, DSNAME FROM JFCB       53700021
         L     RB,ODA6740K              LOAD DESC AND ROUTE CODES       53800021
         MVC   DXRETMOD,ODA6960X        IDTTR OF MODULE TO RETURN TO    53900021
         SR    RET,RET                  RETURN INDICATOR FOR MODULE     54000021
*                                                                       54100021
         IECRES XCTL,ODA6940X,(RET)     XCTL TO MESSAGE DSN MODULE      54200021
*                                                                       54300021
*********************************************************************** 54400021
*                                                                       54500021
ODA65400 EQU   *                                                        54600021
OABD026  EQU   26                       UNABLE TO DEMOUNT VOLUME        54700021
         DMABCOND OABD026,ODA6920X      XCTL TO PROB DET / ABEND        54800021
*                                                                       54900021
*********************************************************************** 55000021
*                                                                       55100021
         USING UCBOB,RUCB               SET BASE FOR UCBOB              55200021
ODA65600 EQU   *                                                        55300021
         IECRES XCTL,ODA6960X,4         XCTL TO NEXT LOAD OF MOUNT      55400021
*                                                                       55500021
*********************************************************************** 55600021
*                                                                       55700021
*        CONSTANTS                                                      55800021
*                                                                       55900021
ODA6700K DC    X'8000'                  MCS INDICATOR                   56000021
         DC    C'IEC101A M '            MOUNT MESSAGE                   56100021
ODA6700L EQU   *-ODA6700K               LENGTH OF MSG SEGMENT           56200021
*                                                                       56300021
ODA6740K DC    0F'0',X'4000'            DESC=2 IMMEDIATE ACTION REQUIRD 56400021
         DC    X'1000'                  ROUTCDE=(4) DIRECT ACCESS POOL  56500021
*                                                                       56600021
ODA6760K DC    C'IEC108I OPERATOR ACTION HAS BEEN REQUESTED FOR YOUR DAX56700021
               TA SET'                  TSO TERMINAL MESSAGE            56800021
*                                                                       56900021
ODA6780K WTO   'IEC106E R DDD,VOLSER',MF=L,  DEMOUNT RETAIN MSG        X57000021
               DESC=3,                  EVENTUAL ACTION REQUIRED       X57100021
               ROUTCDE=(4)              DIRECT ACCESS POOL              57200021
ODA6780L EQU   *-ODA6780K               TOTAL LENGTH OF MSG             57300021
*                                                                       57400021
         AIF   ('&LIB' NE 'LIB1').LIB24A5                               57450000
ODA6800K DC    X'FF'                    SSM MASK TO ENABLE INTERRUPTS   57500021
         XCTLTABL ID=(ODA6920X,0P,ODA6940X,0R,ODA6960X,4C)              57510000
.LIB24A5 ANOP                                                           57550000
*                                                                       57600021
         AIF   ('&LIB' EQ 'LIB1').LIB14A5                               57650000
         XCTLTABL ID=(ODA6920X,0P,ODA6940X,0R,ODA6960X,4C),            X57700000
               LENGTH=2048,PATCH=80                              YM0871 57710000
.LIB14A5 ANOP                                                           57750000
*                                                                       57800021
         IECDSECS EXPAND=YES            EXPAND DESIRED DSECTS HERE      57900021
*                                                                       58000021
         END                                                            58100021
