         TITLE 'IFG0194C/OPEN - DA MOUNT VERIFICATION'                  00200000
         GBLC  &LIB                     DEFINE GLOBAL CHAR VARIABLE     00400000
&LIB     SETC  'LIB1'                   SET VALUE FOR OS /360           00600000
IFG0194C CSECT                                                          00800000
*********************************************************************** 01000000
*                                                                     * 01200000
*                                                                     * 01400000
*          RELEASE 25 DELETIONS/CHANGES                               * 01600000
*          RELEASE 24 DELETIONS/CHANGES                               * 01800000
*          RELEASE 23 DELETIONS/CHANGES                               * 02000000
*          RELEASE 22 DELETIONS/CHANGES                               * 02200000
*          RELEASE 21 DELETIONS/CHANGES                               * 02400000
*0000178000,530000,696000                                        M1811  02500021
*                                                                     * 02600000
* STATUS CHANGE LEVEL 000                                             * 02800000
*                                                                     * 03000000
* FUNCTION -                                                          * 03200000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03400000
*    OPEN DA VOLUME VERIFICATION FUNCTION                             * 03600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 03800000
*                                                                     * 04000000
* ENTRY POINTS -                                                      * 04200000
*         IFG0194C                                                    * 04400000
*                                                                     * 04600000
* INPUT -                                                             * 04800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05000000
*                                                                     * 05200000
* OUTPUT -                                                            * 05400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05600000
*                                                                     * 05800000
* EXTERNAL REFERENCES -                                               * 06000000
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 06200000
*            WAIT.                                                    * 06400000
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 06600000
*                                                                     * 06800000
* EXITS, NORMAL -                                                     * 07000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07200000
*                                                                     * 07400000
* EXITS, ERROR -                                                      * 07600000
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0190P, IF AN      * 07800000
*    ABEND SITUATION OCCURS IN THIS MODULE.                           * 08000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 08200000
*                                                                     * 08400000
* TABLES/WORK AREAS -                                                 * 08600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 08800000
*                                                                     * 09000000
* ATTRIBUTES -                                                        * 09200000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 09400000
*                                                                     * 09600000
* CHARACTER CODE DEPENDENCY -                                         * 09800000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10000000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 10200000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 10400000
*                                                                     * 10600000
* NOTES -                                                             * 10800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11000000
*                                                                     * 11200000
*********************************************************************** 11400000
         EJECT                                                          11600000
*********************************************************************** 11800000
*                                                                     * 12000000
*                          FUNCTION PROLOG                            * 12200000
*                                                                     * 12400000
*********************************************************************** 12600000
*                                                                     * 12800000
* FUNCTION NAME -                                                     * 13000000
*    OPEN DA VOLUME VERIFICATION FUNCTION                             * 13200000
*       (CONTINUED FROM MODULE IFG0194A)                              * 13400000
*                                                                     * 13600000
* (STATUS) -                                                          * 13800000
*    NOT APPLICABLE                                                   * 14000000
*                                                                     * 14200000
* FUNCTION -                                                          * 14400000
*   *SCAN AGAIN THE UCB'S POINTED TO BY THE TIOT DD ENTRY FOR         * 14600000
*    A MATCHING VOLUME SERIAL NUMBER.                                 * 14800000
*   *SELECT A UNIT FROM THE TIOT DD ENTRY UCB LIST TO MOUNT THE       * 15000000
*    DESIRED VOLUME ON.                                               * 15200000
*   *INCREMENT UCB OPEN DCB DATA MANAGEMENT COUNTER TO HOLD THIS      * 15400000
*    UCB FOR THIS VOLUME.                                             * 15600000
*   *SET UP WORK DEB UCB ADDRESS AND EXTENT FOR SELECTED UNIT.        * 15800000
*   *ISSUE AN 'IEC106E R UUU,VOLSER' MESSAGE IF                       * 16000000
*    A PREVIOUS VOLUME MUST BE DEMOUNTED TO MAKE ROOM.                * 16200000
*   *ISSUE AN 'IEC101A M UUU,VOLSER,JOBNAME,STEPNAME,DSNAME'          * 16400000
*    MOUNT MESSAGE TO THE OPERATOR.                                   * 16600000
*   **THIS MODULE'S FUNCTION STARTS HERE.                             * 16800000
*   *READ THE VOLUME LABEL, VERIFY THAT IT IS THE CORRECT ONE,        * 17000000
*    MOVE THE VTOC TTR INTO THE UCB, AND TURN OFF THE MOUNT BIT.      * 17200000
*   *IF NONSPECIFIC REQUEST, MOVE NEW VOLUME SERIAL NUMBER INTO       * 17400000
*    JFCBVOLS.                                                        * 17600000
*   *IF WRONG VOLUME MOUNTED, ISSUE AN 'IEC111E D UUU,VOLSER'         * 17800021
*    MESSAGE, WHERE VOLSER IS THE VOLUME SERIAL NUMBER OF THE         * 18000000
*    VOLUME ACTUALLY MOUNTED.                                         * 18200000
*                                                                     * 18400000
* ENTRY POINTS -                                                      * 18600000
*    ENTERED VIA AN XCTL FROM IFG0194A, OR INDIRECTLY THRU IFG0190R.  * 18800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 19000000
*                                                                     * 19200000
* INPUT -                                                             * 19400000
*    REGISTERS -                                                      * 19600000
*       RTIOT 9 - CURRENT TIOT DD ENTRY.  MAY BE EACH OF SEVERAL      * 19800000
*          ENTRIES FOR CONCATENATED BPAM OR ISAM.                     * 20000000
*       RET  14 - ENTRY INDICATOR.                                    * 20200000
*    WORK AREAS -                                                     * 20400000
*       DXLBL (96 BYTES) - MUST BE AVAILABLE FOR USE AS WORK AREA     * 20600000
*          FOR WRITING MESSAGES, AND READING VOLUME LABEL.            * 20800000
*       DXJBF (176 BYTES) - USED FOR DSNAME AND 'TEMPORARY DATA SET'  * 21000000
*          INDICATOR IN MOUNT MESSAGE (BY IFG0190R) AND BY            * 21200000
*          PROBLEM DETERMINATION FOR ITS MESSAGE IF THERE IS AN ABEND.* 21400000
*       DXCCW2+4 - ADDRESS IN TIOT DD ENTRY UCB LIST OF FIRST         * 21600000
*          UCB POINTER THAT CAN BE USED.  PREVIOUS UCB                * 21800000
*          POINTERS ARE ALREADY LOCKED INTO PREVIOUS VOLUMES          * 22000000
*          OF A MULTIVOLUME MOUNT.                                    * 22200000
*       DXCCW1-DXCCW3 - ARE CONSIDERED AVAILABLE FOR USE BY THIS      * 22400000
*          FUNCTION.  DXCCW1-DXCCW2 DO NOT HAVE TO HAVE A             * 22600000
*          SEARCH ID EQ, TIC *-8 CHANNEL PROGRAM IN THEM, SINCE       * 22800000
*          IT WILL BE CONSTRUCED BY THIS FUNCTION.                    * 23000000
*       DXCCW4-DXCCW7 - WILL NOT BE TOUCHED.                          * 23200000
*       DXCCW8-DXCCW11 - ARE USED AS A REGISTER SAVE AREA.            * 23400000
*       DXVOLMT1 - CONTAINS THE VOLUME SERIAL NUMBER OF THE DESIRED   * 23600000
*          VOLUME.  IF THE REQUEST IS NONSPECIFIC, IT CONTAINS        * 23800000
*          'SCRTCH'.                                                  * 24000000
*       IF RET=4 OR 8 - THE WORK DEB MUST ALREADY BE SET UP FOR THE   * 24200000
*          UNIT SELECTED FOR THE VOLUME.                              * 24400000
*                                                                     * 24600000
* OUTPUT -                                                            * 24800000
*    REGISTERS -                                                      * 25000000
*       R0-R1 0-1 - ARE TO BE CONSIDERED UNDEFINED.                   * 25200000
*       RTIOT 9 - CURRENT TIOT DD ENTRY.  SAME AS AT ENTRY.           * 25400000
*       RUCB 10 - CURRENT MAIN OR SUB UCB ADDRESS.                    * 25600000
*       RB-RD 11-13 - ARE TO BE CONSIDERED UNDEFINED.                 * 25800000
*       RET  14 - SET TO 4 AS RETURN ENTRY INDICATOR.                 * 26000000
*    WORK AREAS -                                                     * 26200000
*       DXLBL (96 BYTES) - HAS VOLUME LABEL. ALL CURRENT CALLING      * 26400000
*          FUNCTIONS CONSIDER IT TO BE UNDEFINED.                     * 26600000
*       DXJBF (176 BYTES) - SAME AS AT ENTRY.                         * 26800000
*       DXCCW2+4 - ADDRESS IN TIOT DD ENTRY UCB LIST OF FIRST         * 27000000
*          UCB POINTER THAT CAN BE USED. SAME AS AT ENTRY.            * 27200000
*       DXCCW1-DXCCW3 - CONTAIN A SEARCH ID EQ, TIC *-8 CHANNEL       * 27400000
*          PROGRAM.                                                   * 27600000
*       DXCCW4-DXCCW7 - SAME AS AT ENTRY.                             * 27800000
*       DXCCW8-DXCCW11 - ARE USED AS A REGISTER SAVE AREA.            * 28000000
*       DXVOLMT1 - CONTAINS THE VOLUME SERIAL NUMBER OF THE DESIRED   * 28200000
*          VOLUME.  IF THE REQUEST WAS NONSPECIFIC, IT STILL CONTAINS * 28400000
*          'SCRTCH' AND NOT THE NAME OF THE NEW VOLUME.               * 28600000
*                                                                     * 28800000
* EXTERNAL REFERENCES -                                               * 29000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 29200000
*                                                                     * 29400000
* EXITS, NORMAL -                                                     * 29600000
*   *FINAL EXIT FROM THIS FUNCTION IS VIA XCTL TO THE MODULE WHOSE    * 29800000
*    IDTTR IS IN DXRETMOD.                                            * 30000000
*   *IF THE WRONG VOLUME IF MOUNTED, XCTLS BACK TO IFG0194A TO        * 30200000
*    REISSUE THE MOUNT MESSAGE.                                       * 30400000
*                                                                     * 30600000
* EXITS, ERROR -                                                      * 30800000
*    413 ABEND VIA PROBLEM DETERMINATION MODULE IFG0190P IF           * 31000000
*    AN I/O ERROR WHILE READING THE VOLUME LABEL.                     * 31200000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 31400000
*                                                                     * 31600000
* TABLES/WORK AREAS -                                                 * 31800000
*    THE FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY  * 32000000
*    THE DSECTS AT THE END OF THE LISTING.                            * 32200000
*                                                                     * 32400000
* ATTRIBUTES -                                                        * 32600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 32800000
*                                                                     * 33000000
* CHARACTER CODE DEPENDENCY -                                         * 33200000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 33400000
*                                                                     * 33600000
* NOTES -                                                             * 33800000
*   *THIS FUNCTION MAY GO INTO A WAIT STATE UNTIL THE REQUESTED       * 34000000
*    VOLUME HAS BEEN MOUNTED.                                         * 34200000
*    A DISPLAY R COMMAND WILL INDICATE WHAT UCB IS BEING WAITED ON,   * 34400000
*    BECAUSE THE UCB MOUNT BIT WILL BE ON.                            * 34600000
*   *ONE OF THE MAIN CONSTRAINTS OF THIS FUNCTION IS TO USE AS LITTLE * 34800000
*    WORK AREA AS POSSIBLE, BECAUSE SOME OF THE FUNCTIONS THAT CALL   * 35000000
*    THIS FUNCTION HAVE VERY LITTLE WORK AREA TO SPARE.               * 35200000
*********************************************************************** 35400000
         EJECT                                                          35600000
         IECDSECS CVT,TIOT,UCB,MAIN     DEFINE DESIRED DSECTS TO BE    X35800000
                                        EXPANDED AT THE END             36000000
*                                                                       36200000
         IECEQU ,                       DEFINE EQUATES                  36400000
*                                                                       36600000
         USING FORCORE,RCORE            DEFINE BASE TO MAIN WORK AREA   36800000
         USING TIOENTRY,RTIOT           DEFINE BASE TO TIOT DD ENTRY    37000000
         USING UCBOB,RUCB               DEFINE BASE TO MAIN UCB         37200000
*                                                                       37400000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         37600000
         USING *,RBASE                  DEFINE BASE REGISTER            37800000
*                                                                       38000000
         LR    RD,RET                   SAVE ENTRY INDICATOR            38200000
*                                                                       38400000
         B     ODA70200(RET)            BR TO INDICATED ENTRY           38600000
*                                                                       38800000
ODA70200 B     ODA70400                 RET=0 RETURN FROM MOUNT MSG     39000000
         B     ODA70600                 RET=4 NO MOUNT MSG ISSUED       39200000
*                                                                       39400000
*********************************************************************** 39600000
*                                                                       39800000
ODA70400 EQU   *                                                        40000000
         MVC   DXRETMOD,DXCCW3          RESTORE SAVED RETURN IDTTR      40200000
*                                                                       40400000
*********************************************************************** 40600000
*                                                                       40800000
*  READ THE VOLUME LABEL FROM RECORD 3 OF TRACK 0.                      41000000
*  WILL GO INTO A WAIT STATE UNTIL THE VOLUME IS MOUNTED.               41200000
*                                                                       41400000
ODA70600 EQU   *                                                        41600000
         XC    DXDAADDR,DXDAADDR        DA VOL LABEL ADDR CCHH = 0000   41800000
         MVC   DXDAADDR+K1(K2),DXDEBBIN  MOVE BIN NO. INTO DXDAADDR     42000000
         MVI   DXDAADDR+K7,K3           VOL LABEL IS ALWAYS RECORD 3    42200000
*                                                                       42400000
*        CONSTRUCT CHANNEL PROGRAM TO READ VOLUME LABEL.                42600000
*                                                                       42800000
*        SEARCH ID EQ                                                   43000000
*        TIC *-8                                                        43200000
*        READ DATA                                                      43400000
*                                                                       43600000
         L     R0,DXCCW2+K4             SAVE ADDR CURRENT TIOT UCB PTR  43800000
         XC    DXCCW1(K24),DXCCW1       CLEAR CCW AREA                  44000000
         LA    RF,DXDAADDR+K3           SEARCH ADDRESS                  44200000
         ST    RF,DXCCW1                                                44400000
         LA    RF,DXCCW1                TIC ADDRESS                     44600000
         ST    RF,DXCCW2                                                44800000
         LA    RF,DXLBL                 VOL LABEL INPUT BUFFER ADDR     45000000
         ST    RF,DXCCW3                                                45200000
         OC    DXCCW1(K24),ODA7440K     OR IN CMND CODE, FLAGS, LENGTH  45400000
         ST    R0,DXCCW2+K4             RESTORE ADDR CURRENT TIOT UCB   45600000
*                                                                       45800000
         EXCP  DXIOB                    READ VOLUME LABEL               46000000
*                                                                       46200000
         IECRES WAIT                    WAIT FOR MOUNT AND LABEL READ   46400000
*                                                                       46600000
         LTR   RD,RD                    IS DOM NECESSARY                46800000
         BNZ   ODA70800                 BR IF NO                        47000000
         DOM   MSGLIST=REPLY+K4         DELETE MSG                      47200000
*                                                                       47400000
ODA70800 EQU   *                                                        47600000
         TM    DXECB,ECBNOERR           CHECK FOR I/O ERROR             47800000
         BZ    ODA71600                 BR IF I/O ERROR                 48000000
*                                                                       48200000
         CLC   VOLSERNO,DXVOLMT1        CHECK FOR CORRECT VOLUME        48400000
         BE    ODA71800                 BR IF YES                       48600000
*                                                                       48800000
         CLC   ODA7400K,DXVOLMT1        CHECK IF SCRTCH REQUEST         49000000
         BNE   ODA71200                 BR IF NO TO DEMOUNT WRONG VOL   49200000
*                                                                       49400000
         MVC   JFCBVOLS(K6),VOLSERNO    MOVE VOL SER INTO JFCB          49600000
         OI    JFCBMASK+K4,JFCMJMOD     SET JFCB WRITE SW ON            49800000
*                                                                       50000000
         CLI   UCBID,UCBMAIN            CHECK FOR 2321                  50200000
         BE    ODA71000                 BR IF NOT 2321                  50400000
*                                                                       50600000
         USING UCBDCELL,RUCB            SET BASE FOR DATACELL           50800000
         MVC   UCBDVOLI,VOLSERNO        MOVE VOL SER INTO UCB           51000000
         B     ODA71800                 BR TO PUT VTOC TTR IN UCB       51200000
*                                                                       51400000
         USING UCBOB,RUCB               SET BASE FOR UCBOB              51600000
ODA71000 EQU   *                                                        51800000
         MVC   UCBVOLI,VOLSERNO         MOVE VOL SER INTO UCB           52000000
         B     ODA71800                 BR TO PUT VTOC TTR IN UCB       52200000
*                                                                       52400000
*********************************************************************** 52600000
*                                                                       52800000
*  WRITE  'IEC111E D DDD,VOLSER'  MESSAGE TO OPERATOR TO TELL HIM       53000021
*  TO DEMOUNT THE OLD VOLUME, BECAUSE IT IS THE WRONG ONE.              53200000
*                                                                       53400000
ODA71200 EQU   *                                                        53600000
         MVC   DXCCW1(K6),VOLSERNO      SAVE BAD VOLUME SERIAL NUMBER   53800000
         MVC   MSGLSTSZ(ODA7420L),ODA7420K  SET UP DEMOUNT MSG          54000000
         MVC   MSGVOLSR,DXCCW1          ADD VOLUME SERIAL NO. TO MSG    54200000
*                                                                       54400000
         CLI   UCBID,UCBMAIN            CHECK FOR 2321                  54600000
         BE    ODA71400                 BR IF NOT 2321                  54800000
*                                                                       55000000
*                       2321 DATACELL PROCESSING                        55200000
         USING UCBDCELL,RUCB            SET UP BASE FOR SUB UCB         55400000
*        SHIFT ',VOLSER D&R' 2 PLACES RIGHT TO MAKE ROOM FOR /B         55600000
         MVC   MSGLSTSZ+ODA7420L+K2(K11),MSGUN+K3                       55800000
         MVC   MSGUN+K5(K11),MSGLSTSZ+ODA7420L+K2                       56000000
         MVI   MSGUN+K3,C'/'            MOVE / INTO MESSAGE             56200000
         MVC   MSGUN+K4(K1),UCBDBBNR+K1  MOVE BIN NUMBER INTO MESSAGE   56400000
         OI    MSGUN+K4,ZONEOF          CONVERT BIN NO. TO DECIMAL      56600000
         MVI   MSGLSTSZ+K1,K26          SET MSG LENGTH 2 BYTES LONGER   56800000
         L     RUCB,DXDEBUCB            LOAD MAIN UCB ADDRESS           57000000
*                                                                       57200000
         USING UCBOB,RUCB               ADDRESSING MAIN UCB             57400000
ODA71400 EQU   *                                                        57600000
         MVC   MSGUN,UCBNAME            ADD UCB UNIT NAME TO MESSAGE    57800000
*                                                                       58000000
         WTO   MF=(E,MSGLSTSZ)          WRITE DEMOUNT MSG TO OPERATOR   58200000
*                                                                       58400000
         OI    UCBFL1,UCBNOTRD          SET MAIN UCB NOT-READY BIT      58600000
*                                                                       58800000
*                                       IND MOUNT MSG, VOLUME VERIFY    59000000
         IECRES XCTL,ODA7940X,4         XCTL BACK TO DA MOUNT MODULE    59200000
*                                                                       59400000
*********************************************************************** 59600000
*                                                                       59800000
ODA71600 EQU   *                                                        60000000
OABD027  EQU   27                       I/O ERROR READING DIRECT        60200000
*                                       ACCESS VOLUME LABEL             60400000
         DMABCOND OABD027,ODA7920X      XCTL TO PROB DET / ABEND        60600000
*                                                                       60800000
*********************************************************************** 61000000
*                                                                       61200000
*  CONVERT VTOC ADDR FROM MBBCCHHR TO TTR FORM                          61400000
*                                                                       61600000
         USING UCBOB,RUCB               BASE FOR MAIN UCB               61800000
ODA71800 EQU   *                                                        62000000
         MVC   DXDAADDR+K3(K5),VOLVTOC  GET CCHHR VTOC ADDR FROM VOL LB 62200000
         LR    RF,RDCB                  SAVE DCB REGISTER 2 IN 15       62400000
         STM   RTIOT,RF,DXREG9          SAVE REGISTERS 9-15             62600000
         L     RF,CVTPTR                GET CVT ADDR                    62800000
         LA    R1,DXDEB                 POINT TO OPEN WORK DEB          63000000
         LA    RDCB,DXDAADDR            POINT TO MBBCCHHR ADDR          63200000
         L     RF,CVTPRLTV-CVT(,RF)     ADDR OF IECPRLTV ROUTINE        63400000
         BALR  RET,RF                   BR TO CONVERT MBBCCHHR TO TTR   63600000
         LM    RTIOT,RF,DXREG9          RESTORE REGISTERS 9-15          63800000
         LR    RDCB,RF                  RESTORE DCB REGISTER 2 FROM 15  64000000
*                                                                       64200000
*  INSERT VTOC TTR ADDR IN UCB AND TURN OFF UCB MOUNT BIT.              64400000
*                                                                       64600000
         ST    R0,DXCCW3                TTR0 IN REG 0 ON RETURN         64800000
*                                                                       65000000
         CLI   UCBID,UCBMAIN            CHECK FOR 2321                  65200000
         BE    ODA72000                 BR IF NOT 2321                  65400000
*                                                                       65600000
         USING UCBDCELL,RUCB            SET BASE FOR DATACELL           65800000
         MVC   UCBDVTOC,DXCCW3          PLACE TTR OF VTOC INTO THE UCB  66000000
         NI    UCBDDMCT,X'FF'-UCBDDMNT  RESET MOUNT SWITCH              66200000
         B     ODA72200                 BR TO CONTINUE                  66400000
*                                                                       66600000
         USING UCBOB,RUCB               SET BASE FOR MAIN UCB           66800000
ODA72000 EQU   *                                                        67000000
         MVC   UCBVTOC(K3),DXCCW3       PLACE TTR OF VTOC INTO THE UCB  67200000
         NI    UCBDMCT,X'FF'-UCBMOUNT   RESET MOUNT SWITCH              67400000
*                                                                       67600000
ODA72200 EQU   *                                                        67800000
         IECRES XCTL,DXRETMOD,4         XCTL RETURN TO CALLING MODULE   68000000
*                                                                       68200000
*********************************************************************** 68400000
*                                                                       68600000
*        CONSTANTS                                                      68800000
*                                                                       69000000
ODA7400K DC    C'SCRTCH'                NONSPECIFIC VOL SER NO.         69200000
*                                                                       69400000
ODA7420K WTO   'IEC111E D DDD,VOLSER',MF=L,  DEMOUNT MSG         M1811 X69600021
               DESC=3,                  EVENTUAL ACTION REQUIRED       X69800000
               ROUTCDE=(4)              DIRECT ACCESS POOL              70000000
ODA7420L EQU   *-ODA7420K               TOTAL LENGTH OF MSG             70200000
*                                                                       70400000
*        CCW'S TO READ VOLUME LABEL                                     70600000
ODA7440K DC    X'3100000040000005'      SEARCH ID EQ                    70800000
         DC    X'0800000000000000'      TIC *-8                         71000000
         DC    X'0600000000000050'      READ DATA                       71200000
*                                                                       71400000
         XCTLTABL ID=(ODA7920X,0P,ODA7940X,4A)                          71600000
*                                                                       71800000
         IECDSECS EXPAND=YES            EXPAND DESIRED DSECTS HERE      72000000
*                                                                       72200000
         END                                                            72400000
