         TITLE 'IFG0194J - LABEL EDITOR INTERFACT FUNCTION (OMODVOL1)'  00050021
         GBLC  &LIB                                                     00800021
&LIB     SETC  'LIB1'                                                   01200021
IFG0194J CSECT                                                          01600021
*********************************************************************** 02000021
*                                                                     * 02400021
*                                                                     * 02800021
*          RELEASE 25 DELETIONS/CHANGES                               * 03200021
*          RELEASE 24 DELETIONS/CHANGES                               * 03600021
*          RELEASE 23 DELETIONS/CHANGES                               * 04000021
*          RELEASE 22 DELETIONS/CHANGES                               * 04400021
*          RELEASE 21 DELETIONS/CHANGES                               * 04800021
*0000                                                            A44128 04850021
*                                                                     * 05200021
* STATUS CHANGE LEVEL 000                                             * 05600021
*                                                                     * 06000021
* FUNCTION -                                                          * 06400021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 06800021
*    OPEN TAPE LABEL EDITOR INTERFACE FUNCTION.                       * 07200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 07600021
*                                                                     * 08000021
* ENTRY POINTS -                                                      * 08400021
*    IFG0194J - ENTRY POINT VIA THE RESIDENT XCTL FROM THE FOLLOWING--* 08800021
*       IFG0194H - DUE TO A LABEL CONFLICT.                           * 09200021
*       IFG0194I - DUE TO A DENSITY CONFLICT.                         * 09600021
*       IGG0190A - ALIAS ENTRY POINT WHEN RETURNING FROM THE USER     * 10000021
*          WRITTEN  OMODVOL1.                                         * 10400021
*                                                                     * 10800021
* INPUT -                                                             * 11200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11600021
*                                                                     * 12000021
* OUTPUT -                                                            * 12400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 12800021
*                                                                     * 13200021
* EXTERNAL REFERENCES -                                               * 13600021
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 14000021
*          WAIT.                                                      * 14400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 14800021
*                                                                     * 15200021
* EXITS, NORMAL -                                                     * 15600021
*    EXIT VIA XCTL TO OMODVOL1.                                       * 16000021
*    OMODVOL1 IS THE ALIAS NAME FOR IFG0193C WHICH WILL BE            * 16400021
*    ENTERED IF THE USER HAS NOT PROVIDED HIS OWN OMODVOL1.           * 16800021
*    IF THE USER HAS PROVIDED HIS OWN OMODVOL1 THIS MODULE WILL EXIT  * 17200021
*    AFTER HIS RETURN TO IFG0194F TO REPROCESS THE DCB.               * 17600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 18000021
*                                                                     * 18400021
* EXITS, ERROR -                                                      * 18800021
*    NONE.                                                            * 19200021
*                                                                     * 19600021
* TABLES/WORK AREAS -                                                 * 20000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 20400021
*                                                                     * 20800021
* ATTRIBUTES -                                                        * 21200021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 21600021
*                                                                     * 22000021
* CHARACTER CODE DEPENDENCY -                                         * 22400021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 22800021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 23200021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 23600021
*                                                                     * 24000021
* NOTES -                                                             * 24400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 24800021
*                                                                     * 25200021
*********************************************************************** 25600021
         EJECT                                                          26000021
*********************************************************************** 26400021
*                                                                     * 26800021
*                          FUNCTION PROLOG                            * 27200021
*                                                                     * 27600021
*********************************************************************** 28000021
*                                                                     * 28400021
* FUNCTION NAME -                                                     * 28800021
*    OPEN TAPE LABEL EDITOR INTERFACE FUNCTION.                       * 29200021
*                                                                     * 29600021
* (STATUS) -                                                          * 30000021
*    NOT APPLICABLE                                                   * 30400021
*                                                                     * 30800021
* FUNCTION -                                                          * 31200021
*    INITIAL ENTRY--                                                  * 31600021
*    SYNCHRONIZE ALL DCBS. SET UP ALL THE CONDITIONS TO RETURN TO     * 32000021
*    PARALLEL PROCESSING MODE INCASE THE USER HAS PROVIDED HIS OWN    * 32400021
*    LABEL EDITOR. EXIT TO THE LABEL EDITOR.                          * 32800021
*    RETURN ENTRY--                                                   * 33200021
*    THIS SECTION IS ONLY ENTERED WHEN THE USER HAS PROVIDED HIS OWN  * 33600021
*    LABEL EDITOR ROUTINE (OMODVOL1). RESET THE CONDITIONS TO         * 34000021
*    RETURN TO RESIDENT ROUTINE SERIAL PROCESSING. EXIT TO REPROCESS  * 34400021
*    THE DCBS.                                                        * 34800021
*                                                                     * 35200021
* ENTRY POINTS -                                                      * 35600021
*    ENTERED FROM THE FOLLOWING--                                     * 36000021
*    OPEN TAPE VOLUME VERIFICATION FUNCTION DUE TO A LABEL CONFLICT.  * 36400021
*    OPEN TAPE FINAL COMMON FUNCTION DUE TO A DENSITY CONFLICT.       * 36800021
*    USER WRITTEN LABEL EDITOR ROUTINE TO RETURN TO NORMAL PROCESSING.* 37200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37600021
*                                                                     * 38000021
* INPUT -                                                             * 38400021
*    A POINTER TO EACH OF THE FOLLOWING--                             * 38800021
*       CURRENT PARAMETER LIST ENTRY.                                 * 39200021
*       DD ENTRY IN THE TIOT.                                         * 39600021
*       WTG TABLE.                                                    * 40000021
*       CURRENT WTG TABLE ENTRY.                                      * 40400021
*       DCB.                                                          * 40800021
*       OPEN WORK AREA.                                               * 41200021
*       RESIDENT ROUTINE.                                             * 41600021
*       UCB                                                           * 42000021
*                                                                     * 42400021
* OUTPUT -                                                            * 42800021
*    A DUAL INTERFACE HAS BEEN SET UP SO THAT THE SYSTEM, OR A USER   * 43200021
*    WRITTEN, LABEL EDITOR MAY BE ENTERED.                            * 43600021
*                                                                     * 44000021
* EXTERNAL REFERENCES -                                               * 44400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 44800021
*                                                                     * 45200021
* EXITS, NORMAL -                                                     * 45600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 46000021
*    OPEN TAPE LABEL EDITOR FUNCTION FOR LABEL OR DENSIT CONFLICTS.   * 46400021
*    (USER WRITTEN LABEL EDITOR IF ONE EXISTS.)                       * 46800021
*    OPEN TAPE MOUNT VERIFICATION FUNCTION TO REPROCESS THE DCB.      * 47200021
*    (ONLY WHEN THE USER HAS PROVIDED HIS OWN LABEL EDITOR ROUTINE.)  * 47600021
*                                                                     * 48000021
* EXITS, ERROR -                                                      * 48400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 48800021
*                                                                     * 49200021
* TABLES/WORK AREAS -                                                 * 49600021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 50000021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 50400021
*                                                                     * 50800021
* ATTRIBUTES -                                                        * 51200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 51600021
*                                                                     * 52000021
* CHARACTER CODE DEPENDENCY -                                         * 52400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 52800021
*                                                                     * 53200021
* NOTES -                                                             * 53600021
*                                                                     * 54000021
*********************************************************************** 54400021
         EJECT                                                          54800021
         USING FORCORE,RCORE            WORK AREA                       55200021
         BALR  RBASE,0                  SET BASE REGISTER               55600021
         USING *,RBASE                                                  56000021
*                                                                       56400021
         B     OTA18500(RET)            GO TO PROPER ENTRY              56800021
OTA18500 EQU   *                                                        57200021
         NOP   OTA18600                 UNUSED   ENTRY                  57600021
OTA18600 EQU   *                                                        58000021
         B     OTA18700                 INITAL ENTRY                    58400021
         B     OTA19100                 RETURN FROM USER WRITTEN OMOD   58800021
*                                                                       59200021
OTA18700 EQU   *                                                        59600021
         STM   RTIOT,RUCB,DXXCTL        SAVE REGISTERS                  60000021
         IECRES SYNCHDCB                                                60400021
         LR    RD,RES                   SAVE RES ROUTINE POINTER        60800021
         L     RPAR,K16(RWTG)           POINT TO ECB LIST               61200021
         L     RPAR,K0(RPAR)            GET PARM LIST POINTER           61600021
         LR    RB,RPAR                  GET FIRST ENTRY IN LIST         62000021
         LA    RC,K32(RWTG)             GET FIRST WTG ENTRY             62400021
OTA18800 EQU   *                                                        62800021
         CLC   K0(K2,RC),THISID         THIS DCB NEED OMOD              63200021
         BNE   OTA18900                 NO, BRANCH                      63600021
         MVC   K0(K5,RC),ID4J3C         MOVE IN OMOD IDTTR              64000021
         L     RF,K4(RC)                GET WORK AREA ADDRESS           64400021
         SR    RET,RET                  ENTRY FOR SYSTEM OMOD           64800021
         ST    RET,DXREGE-FORCORE(RF)   SAVE ENTRY IN WORK AREA         65200021
OTA18900 EQU   *                                                        65600021
         TM    K0(RB),LASTNTRY          IS THIS THE LAST DCB            66000021
         BO    OTA19000                 YES, BRANCH                     66400021
         LA    RB,K4(RB)                POINT TO NEXT DCB               66800021
         LA    RC,K8(RC)                NEXT WTG ENTRY                  67200021
         B     OTA18800                 GO CHECK NEXT DCB               67600021
OTA19000 EQU   *                                                        68000021
         LA    RET,K8                   SET BRANCH VALUE FOR RETURN     68400021
         MVC   K0(K8,RWTG),OMODVOL1     MOVE OMOD NAME TO WTG TABLE     68800021
         LA    RF,DXCCW12               XCTL WORK AREA                  69200021
         XCTL  EPLOC=(RWTG),DCB=0,SF=(E,(15))                           69600021
*                                                                       70000021
*              THE FOLLOWING CODE IS EXECUTED WHEN THE USER HAS         70400021
*              SUPPLIED A COPY OF OMODVOL1. HIS RETURN TO MODULE        70800021
*              IGG0190A WILL ENTER HERE.                                71200021
*                                                                       71600021
OTA19100 EQU   *                                                        72000021
         MVC   K0(K8,RWTG),MODNM4J      RESTORE IFG019 TO WTG           72400021
         LR    RPARC,RPAR               GET FIRST ENTRY IN PARM LIST    72800021
         LA    RWTGC,K32(RWTG)          GET FIRST WTG ENTRY             73200021
OTA19200 EQU   *                                                        73600021
         L     RCORE,K4(RWTGC)          WORK AREA POINTER               74000021
         L     RDCB,K0(RPARC)           DCB ADDRESS                     74400021
         CLC   K0(K2,RWTGC),ID4J3C      THIS DCB USE OMOD               74800021
         BNE   OTA19300                 NO, BRANCH                      75200021
         NI    JFCBMASK+5,X'FF'-JFCSTAND-JFCSLCRE-JFCSLDES-JFCDUAL      75250021
*                                       RESET OMOD INDICATORS TO A44128 75300021
*                                       PERMIT USER'S OMOD TO    A44128 75350021
*                                       PROCESS NEXT TAPE, IF    A44128 75400021
*                                       CONFLICT STILL EXISTS    A44128 75450021
         MVC   K0(K5,RWTGC),ID4J4F      MOUNT VERIFY IDTTR              75600021
         MVC   DXREG9(K8),DXXCTL        RESTORE RTIOT AND RUCB          76000021
         SR    RET,RET                  ZERO BR TABLE REG FOR    A44128 76050021
*                                       NORMAL ENTRY FOR MOUNT   A44128 76100021
*                                       VERIFICATION FUNCTION    A44128 76150021
         ST    RET,DXREGE               INSERT IN REG SAVE AREA  A44128 76200021
OTA19300 EQU   *                                                        76400021
         TM    K0(RPARC),LASTNTRY       LAST DCB IN PARM LIST           76800021
         BO    OTA19400                 YES, BRANCH                     77200021
         LA    RPARC,K4(RPARC)          GET NEXT ENTRY IN LIST          77600021
         LA    RWTGC,K8(RWTGC)          GET NEXT WTG ENTRY              78000021
         B     OTA19200                 GO CHECK NEXT DCB               78400021
OTA19400 EQU   *                                                        78800021
         LR    RES,RD                   RESTORE RES RTN POINTER         79200021
         LM    RTIOT,RET,DXREG9         RESTORE FOR RES RTN SAVE A44128 79600021
         LM    R0,R1,DXREG0             RESTORE FOR RES RTN SAVE A44128 79650021
         IECRES XCTL                                                    80000021
*                                                                       80400021
*              CONSTANTS                                                80800021
*                                                                       81200021
THISID   DC    C'4J'                    THIS MODULES ID                 81600021
OMODVOL1 DC    C'OMODVOL1'              OMOD NAME FOR XCTL              82000021
MODNM4J  DC    C'IFG0194J'              TO RESTORE WTG MOD NAME         82400021
*                                                                       82800021
XCTL4J   XCTLTABL ID=(ID4J3C,3C,ID4J4F,4F)                              83200021
         IECDSECS CVT,TCB,TIOT,DCB,UCB,MAIN,WTG,EXPAND=YES              83600021
         IECEQU                                                         84000021
         END                                                            84400021
