         TITLE 'IFG0194R - OPEN TAPE SL POSITIONING ERROR RECOVERY'     00200000
         COPY  LCGASMSW                                                 00400000
IFG0194R CSECT                                                          00600000
*********************************************************************** 00800000
*                                                                     * 01000000
*                                                                     * 01200000
*          VS1 RELEASE 04.0 DELETIONS/CHANGES                         * 01400000
*          VS1 RELEASE 03.1 DELETIONS/CHANGES                         * 01600000
*SEE SA69190                                                    XA05166 01800000
*                                                                     * 02000000
*          RELEASE 21.8 DELETIONS/CHANGES                             * 02200000
*0000                                                           SA69190 02400000
*0000                                                           SA69926 02600000
*                                                                     * 02800000
* STATUS CHANGE LEVEL 000                                             * 03000000
*                                                                     * 03200000
* FUNCTION -                                                          * 03400000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03600000
*    OPEN TAPE SL POSITION FUNCTION.                                  * 03800000
*                                                                     * 04000000
* ENTRY POINTS -                                                      * 04200000
*    IFG0194R - VIA THE RESIDENT ROUTINE XCTL FROM THE FOLLOWING-     * 04400000
*       IFG0195B - RET=0  EOV1 ENCOUNTERED AND MORE VOLSER EXIST.     * 04600000
*       IFG0195H - RET=4  DSNAME IS BAD OR FILE SEQUENCE LESS THAN    * 04800000
*              TAPE AND ARE OPENING FOR RDBACK OR OUTPUT DISP=MOD     * 05000000
*              AND THIS IS NOT THE FIRST VOLSER.                      * 05200000
*                                                                     * 05400000
* INPUT -                                                             * 05600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05800000
*                                                                     * 06000000
* OUTPUT -                                                            * 06200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06400000
*                                                                     * 06600000
* EXTERNAL REFERENCES -                                               * 06800000
*    IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND WAIT.    * 07000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07200000
*                                                                     * 07400000
* EXITS, NORMAL -                                                     * 07600000
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING--            * 07800000
*         IFG0193A - TO GET NEXT OR PREVIOUS VOLSER NO. AND VOLUME.   * 08000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 08200000
*                                                                     * 08400000
* EXITS, ERROR -                                                      * 08600000
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0190P, IF AN      * 08800000
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 09000000
*    'FUNCTION PROLOG(S)'.                                            * 09200000
*                                                                     * 09400000
* TABLES/WORK AREAS -                                                 * 09600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 09800000
*                                                                     * 10000000
* ATTRIBUTES -                                                        * 10200000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 10400000
*                                                                     * 10600000
* CHARACTER CODE DEPENDENCY -                                         * 10800000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 11000000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 11200000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 11400000
*                                                                     * 11600000
* NOTES -                                                             * 11800000
*    THIS MODULE WAS CREATED IN OS RELEASE 21.8 (VS1-03.1) BY A       * 12000000
*    SPLIT OF IFG0195B FOR SA69190 (XA05166).                         * 12200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 12400000
*                                                                     * 12600000
*********************************************************************** 12800000
         EJECT                                                          13000000
*********************************************************************** 13200000
*                                                                     * 13400000
*                          FUNCTION PROLOG                            * 13600000
*                                                                     * 13800000
*********************************************************************** 14000000
*                                                                     * 14200000
* FUNCTION NAME -                                                     * 14400000
*    OPEN TAPE SL POSITIONING FUNCTION.                               * 14600000
*       (CONTINUED FROM IFG0195B)                                     * 14800000
*                                                                     * 15000000
* (STATUS) -                                                          * 15200000
*    NOT APPLICABLE                                                   * 15400000
*                                                                     * 15600000
* FUNCTION -                                                          * 15800000
*    ZERO THE DCB BLOCK COUNT.                                        * 16000000
*    TEST THE UCB FILE SEQUENCE NUMBER. IF IT IS ZERO, THEN THE       * 16200000
*    FIRST HEADER LABEL IS READ AND THE FILE SEQUENCE NUMBER          * 16400000
*    FROM THE LABEL IS PLACED IN THE UCB.                             * 16600000
*    POSITIONING IS DETERMINED BY COMPARING THE UCB AND JFCB FILE     * 16800000
*    SEQUENCE NUMBERS. THE TAPE IS FOWARD OR BACK SPACED AS NECESSARY * 17000000
*    TO POSITION TO THE REQUESTED FILE.                               * 17200000
*    THE TAPE IS POSITIONED TO THE HEADER 1 LABEL FOR NORMAL INPUT    * 17400000
*    OPERATIONS. IT IS POSITIONED TO THE TRAILER 1 LABEL FOR RDBACK   * 17600000
*    OR DISP=MOD PROCESSING.                                          * 17800000
*                                                                     * 18000000
* ENTRY POINTS -                                                      * 18200000
*    ENTERED FROM THE FOLLOWING--                                     * 18400000
*    OPEN TAPE FINAL COMMON FUNCTION FOR SL OR AL POSITIONING.        * 18600000
*    OPEN TAPE VOLUME REFERENCE FUNCTION.                             * 18800000
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 19000000
*                                                                     * 19200000
* INPUT -                                                             * 19400000
*    A POINTER TO EACH OF THE FOLLOWING--                             * 19600000
*       CURRENT PARAMETER LIST ENTRY.                                 * 19800000
*       DD ENTRY IN THE TIOT.                                         * 20000000
*       WTG TABLE.                                                    * 20200000
*       CURRENT WTG TABLE ENTRY.                                      * 20400000
*       DCB.                                                          * 20600000
*       OPEN WORK AREA.                                               * 20800000
*       RESIDENT ROUTINE.                                             * 21000000
*       UCB                                                           * 21200000
*                                                                     * 21400000
* OUTPUT -                                                            * 21600000
*    THE TAPE IS POSITIONED TO THE REQUESTED FILE.                    * 21800000
*    WTP INFO ERROR MSG IEC140I START/END DATA SET NOT ON VOLUME.     * 22000000
*                                                                     * 22200000
* EXTERNAL REFERENCES -                                               * 22400000
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 22600000
*                                                                     * 22800000
* EXITS, NORMAL -                                                     * 23000000
*    OPEN TAPE SL INPUT/MOD HEADER LABEL 1 FUNCTION FOR FILE          * 23200000
*    LABEL 1 VERIFICATION.                                            * 23400000
*    OPEN MERGE JFCB FUNCTION TO CONTINUE OUTPUT PROCESSING.          * 23600000
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 23800000
*                                                                     * 24000000
* EXITS, ERROR -                                                      * 24200000
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 24400000
*    EXIT WITH ONE OF THE FOLLOWING INTERNAL CODES--                  * 24600000
*        9 - 613-04 ABEND - I/O ERROR POSITIONING TAPE.               * 24800000
*       10 - A13-04 ABEND - BACKSPACED INTO LOAD POINT DUE TO A       * 25000000
*            INCORRECT UCB FILE SEQUENCE COUNT OR TAPE POSITION.      * 25200000
*       11 - 613-08 ABEND - I/O ERROR READING LABEL. (RECOVERABLE)    * 25400000
*      152 - A13-08 ABEND - FILE SEQUENCE BEFORE START OF VOLUME      * 25600000
*            WHILE POSITIONING TO START OF FILE.                      * 25800000
*      153 - A13-0C ABEND - FILE SEQUENCE BEFORE START OF VOLUME      * 26000000
*            WHILE POSITIONING TO END OF FILE.                        * 26200000
*      154 - A13-10 ABEND - TM INSTEAD OF HDR1 DURING FSF POSITIONING.* 26400000
*      156 - A13-18 ABEND - EOV1 ON LAST OR ONLY VOLUME AND           * 26600000
*            DESIRED FILE SEQUENCE IS GREATER THAN EOV1'S.            * 26800000
*                                                                     * 27000000
* TABLES/WORK AREAS -                                                 * 27200000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 27400000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 27600000
*                                                                     * 27800000
* ATTRIBUTES -                                                        * 28000000
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 28200000
*                                                                     * 28400000
* CHARACTER CODE DEPENDENCY -                                         * 28600000
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 28800000
*                                                                     * 29000000
* NOTES -                                                             * 29200000
*                                                                     * 29400000
*********************************************************************** 29600000
         EJECT                                                          29800000
*        USING IHADCB,RDCB              DEFINE BASE TO USER'S DCB       30000000
         USING FORCORE,RCORE            DEFINE BASE TO MAIN WORK AREA   30200000
         USING TIOENTRY,RTIOT           DEFINE BASE TO TIOT DD ENTRY    30400000
         USING UCB,RUCB                 DEFINE BASE TO UCB              30600000
*                                                                       30800000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         31000000
         USING *,RBASE                  DEFINE BASE REGISTER            31200000
*                                                                       31400000
         B     OTA27700(RET)            BR TO INDICATED FUNCTION        31600000
*                                                                       31800000
OTA27700 B     OTA27720                 RET=0 EOV1 ENCOUNTERED          32000000
         B     OTA27740                 RET=4 FSEQ BEFORE TAPE RECOVERY 32200000
*                                                                       32400000
*********************************************************************** 32600000
*                                                                       32800000
*  EOV1 LABEL ENCOUNTERED IN FRONT OF OR AT END OF DESIRED FILE.        33000000
*  IF POSITIONING TO START OF FILE, TRY TO GO TO NEXT TAPE AND          33200000
*  CONTINUE FSF TO CORRECT FILE.                                        33400000
*  IF POSITIONING TO END OF FILE, ABEND UNLESS EOV1 IS FOR DESIRED      33600000
*  FILE AND SO CAN TREAT AS EOF.                                        33800000
*  (CONTINUED FROM IFG0195B)                                            34000000
*                                                                       34200000
*              R0 CONTAINS OABD152 A13-08 ABEND CODE                    34400000
OTA27720 EQU    *                       POS TO START OF FILE    SA55582 34600000
         LH    RB,JFCBVLSQ              LOAD VOLUME SEQUENCE NO SA55582 34800000
         LTR   RB,RB                    TEST IT                 SA55582 35000000
         BNZ   OTA27730                 BR IF NOT ZERO          SA55582 35200000
         LA    RB,K1                    ELSE SET IT TO 1        SA55582 35400000
OTA27730 EQU   *                                                SA55582 35600000
         SR    RC,RC                    ZERO REG                SA68161 35800000
         IC    RC,JFCBNVOL              LOAD NUMBER OF VOLS     SA68161 36000000
         CR    RC,RB                    IS VOLSEQ = NO. OF VOLS SA68161 36200000
         BE    OTA27780                 BR IF YES TO ABEND      SA68161 36400000
         LA    RB,K1(,RB)               INCREMENT VOLSEQ BY 1   SA55582 36600000
         STH   RB,JFCBVLSQ              AND STORE IT BACK       SA55582 36800000
*                                                                       37000000
*  WRITE MSG 'IEC140I DDNAMEXX,VOLIDX START OF DATA SET NOT ON VOLUME'  37200000
*         OR 'IEC140I DDNAMEXX,VOLIDX   END OF DATA SET NOT ON VOLUME'  37400000
*                                                                       37600000
         MVC   MSGLSTSZ(OTA2779L),OTA2779M  MOVE MSG WORK AREA  SA55582 37800000
         B     OTA27750                 BR TO COMPLETE MSG      SA69190 38000000
*                                                                       38200000
OTA27740 EQU   *                                                SA69190 38400000
         MVC   MSGLSTSZ(OTA2779L),OTA2779M  MOVE MSG WORK AREA  SA69190 38600000
         MVC   MSGVOLSR+K10(K5),OTA27799  SET MSG TO '  END'    SA69190 38800000
OTA27750 EQU   *                                                SA69190 39000000
         MVC   MSGACTN(L'TIOEDDNM),TIOEDDNM  DDNAME TO MSG      SA55582 39200000
         MVC   MSGVOLSR+K3,UCBVOLI      VOLID TO MESSAGE        SA55582 39400000
         WTO   MF=(E,MSGLSTSZ)          WRITE MSG TO PROGRAMMER SA55582 39600000
*                                                                       39800000
*              ROTATE UCB POINTERS IN TIOT TO SPREAD OUT USAGE          40000000
*              OF ALLOCATED UNITS. THIS ALLOWS THE NEXT TAPE TO         40200000
*              BE MOUNTED IMMEDIATELY, RATHER THAN HAVE TO WAIT FOR     40400000
*              THIS UNIT TO BE REWOUND AND UNLOADED FROM END OF REEL    40600000
*              (2 MINUTES). THIS ASSUMES OTHER TAPE DRIVES ARE UNLOADED 40800000
*              OR AT LOAD POINT, OTHERWISE NO SAVING OR LOSS OF TIME.   41000000
*                                                                       41200000
         SR    RB,RB                    ZERO REG B               YM5583 41400000
         IC    RB,TIOELNGH              GET DD ENTRY LENGTH      YM5583 41600000
         LA    RC,TIOESTTB-TIOENTRY+K1  GET NON UNIT LENGTH + 1  YM5583 41800000
         SR    RB,RC                    GET UNIT LENGTH - 1      YM5583 42000000
         EX    RB,OTA27760              MOVE UCB ADDR LEFT       YM5583 42200000
         ST    RUCB,TIOESTTB-K3(RB)     OLD UCB PT TO LAST POS   YM5583 42400000
         MVI   UCBDMCT,K0               RESET DATA MGMT COUNT    YM5583 42600000
*                                                                       42800000
         AIF   ('&LIB' NE 'LIB1').LIB24R1                       SA69926 43000000
*  RESTORE UCB ADDR AND EXTENT OF SYS1.SYSJOBQE JFCB IN WORK DEB.       43200000
*                                                                       43400000
         IECDSECS CVT,DCB               REQUEST EXTRA DSECTS    SA69926 43600000
         L     R1,CVTPTR                GET CVT ADDRESS         SA69926 43800000
         L     R1,CVTJOB-CVT(,R1)       JOB SCHED JOBQUE DCB    SA69926 44000000
         L     R1,DCBDEBAD-IHADCB(,R1)  GET JOB SCHED DEB ADDR  SA69926 44200000
         MVC   DXDEBUCB(K16),K32(R1)    COPY UCB ADDR + EXTENT  SA69926 44400000
*                                                                       44600000
*  RESTORE CCW'S TO SEARCH ID EQ, TIC *-8 SO JFCB EXTENSION             44800000
*  CAN BE READ BY IFG0193A. (NOT WORTH SETING UP RPS CCWS)              45000000
*                                                                       45200000
         XC    DXCCW1(K16),DXCCW1       CLEAR 2 CCW'S           SA69926 45400000
         LA    RF,DXDAADDR+K3           SEARCH ID ADDRESS       SA69926 45600000
         ST    RF,DXCCW1                INTO CCW1               SA69926 45800000
         LA    RF,DXCCW1                TIC ADDRESS             SA69926 46000000
         ST    RF,DXCCW2                INTO CCW2               SA69926 46200000
         OC    DXCCW1(K9),OTA2779S      OR IN CMND,FLAGS,LENGTH SA69926 46400000
*                                       UCB ADDR, EXT SET IN IFG0193A   46600000
.LIB24R1 ANOP                                                   SA69926 46800000
*                                                                       47000000
         IECRES XCTL,ID4R3A,12          XCTL TO IFG0193A                47200000
*                                                                       47400000
OTA27760 MVC   TIOESTTB(*-*),TIOESTTB+K4  SHIFT UCB LIST LEFT           47600000
*                                                                       47800000
*********************************************************************** 48000000
*                                                                       48200000
OTA27780 EQU   *                        ERROR CONDITION ENCOUNTERED     48400000
         MVI   UCBDMCT,K0               ZERO UCB DATA MANAGEMENT COUNT  48600000
         DMABCOND (0),ID4R0P            XCTL TO PROB DET / ABEND        48800000
*                                                                       49000000
*********************************************************************** 49200000
         EJECT                                                          49400000
*********************************************************************** 49600000
*                                                                       49800000
*        CONSTANTS                                                      50000000
*                                                                       50200000
OTA2779M WTO  'IEC140I DDNAMEXX,VOLIDX START OF DATA SET NOT ON VOLUME'X50400000
               ,MF=L,DESC=6,            JOB STATUS              SA69190*50600000
               ROUTCDE=11               PROGRAMMER INFORMATION  SA55582 50800000
OTA2779L EQU   *-OTA2779M               LENGTH OF ERROR MESSAGE SA55582 51000000
OTA27799 DC    C'  END'                 TO SET MSG TO 'END OF'  SA69190 51200000
         AIF   ('&LIB' NE 'LIB1').LIB24R2                       SA69926 51400000
OTA2779S DC    X'3100000040000005'      SEARCH ID EQ            SA69926 51600000
         DC    X'08'                    TIC *-8                 SA69926 51800000
.LIB24R2 ANOP                                                   SA69926 52000000
*                                                                       52200000
         XCTLTABL ID=(ID4R0P,0P,ID4R3A,3A)                              52400000
         EJECT                                                          52600000
         IECEQU ,                       DEFINE EQUATES                  52800000
         IECDSECS TIOT,UCB,MAIN,EXPAND=YES                              53000000
         END                                                            53200000
