         TITLE 'IFG0195G/OPEN - DA, EXPIRATION DATE NOT EXPIRED, 213 ABX00200000
               END EXIT'                                                00400000
         GBLC  &LIB                     DEFINE GLOBAL CHAR VARIABLE     00600000
&LIB     SETC  'LIB1'                   SET VALUE FOR OS /360           00800000
IFG0195G CSECT                                                          01000000
*********************************************************************** 01200000
*                                                                     * 01400000
*                                                                     * 01600000
*          RELEASE 25 DELETIONS/CHANGES                               * 01800000
*          RELEASE 24 DELETIONS/CHANGES                               * 02000000
*          RELEASE 23 DELETIONS/CHANGES                               * 02200000
*          RELEASE 22 DELETIONS/CHANGES                               * 02400000
*          RELEASE 21 DELETIONS/CHANGES                               * 02600000
*                                                                     * 02800000
* STATUS CHANGE LEVEL 000                                             * 03000000
*                                                                     * 03200000
* FUNCTION -                                                          * 03400000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03600000
*    OPEN DA EXPIRATION DATE ERROR FUNCTION                           * 03800000
*    OPEN DA MISSING DSCB 213 ABEND EXIT FUNCTION                     * 04000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 04200000
*                                                                     * 04400000
* ENTRY POINTS -                                                      * 04600000
*         IFG0195G                                                    * 04800000
*                                                                     * 05000000
* INPUT -                                                             * 05200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05400000
*                                                                     * 05600000
* OUTPUT -                                                            * 05800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06000000
*                                                                     * 06200000
* EXTERNAL REFERENCES -                                               * 06400000
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 06600000
*            WAIT.                                                    * 06800000
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 07000000
*                                                                     * 07200000
* EXITS, NORMAL -                                                     * 07400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07600000
*                                                                     * 07800000
* EXITS, ERROR -                                                      * 08000000
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0190P, IF AN      * 08200000
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 08400000
*    'FUNCTION PROLOG(S)'.                                            * 08600000
*                                                                     * 08800000
* TABLES/WORK AREAS -                                                 * 09000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 09200000
*                                                                     * 09400000
* ATTRIBUTES -                                                        * 09600000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 09800000
*                                                                     * 10000000
* CHARACTER CODE DEPENDENCY -                                         * 10200000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10400000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 10600000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 10800000
*                                                                     * 11000000
* NOTES -                                                             * 11200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11400000
*                                                                     * 11600000
*********************************************************************** 11800000
         EJECT                                                          12000000
*********************************************************************** 12200000
*                                                                     * 12400000
*                          FUNCTION PROLOG                            * 12600000
*                                                                     * 12800000
*********************************************************************** 13000000
*                                                                     * 13200000
* FUNCTION NAME -                                                     * 13400000
*    OPEN DA EXPIRATION DATE ERROR FUNCTION                           * 13600000
*                                                                     * 13800000
* (STATUS) -                                                          * 14000000
*    NOT APPLICABLE                                                   * 14200000
*                                                                     * 14400000
* FUNCTION -                                                          * 14600000
*    REQUEST PERMISSION FROM THE OPERATOR TO WRITE ON A DATA SET      * 14800000
*    WHOSE EXPIRATION DATE HAS NOT YET EXPIRED.                       * 15000000
*                                                                     * 15200000
* ENTRY POINTS -                                                      * 15400000
*    IFG0195G WITH RET = 0 - ODA90400                                 * 15600000
*                                                                     * 15800000
* INPUT -                                                             * 16000000
*    A REPLY OF 'U' TO USE THE DATA SET.                              * 16200000
*    A REPLY OF 'M' TO NOT USE THE DATA SET.  THIS WILL CAUSE A       * 16400000
*    713 ABEND TO BE ISSUED BY PROBLEM DETERMINATION.                 * 16600000
*                                                                     * 16800000
* OUTPUT -                                                            * 17000000
*    IEC107D E DDD,VOLSER,JOBNAME,STEPNAME,DSNAME  ERROR MESSAGE      * 17200000
*    WRITTEN TO THE OPERATOR REQUESTING PERMISSION TO USE THE DATA    * 17400000
*    SET.                                                             * 17600000
*                                                                     * 17800000
* EXTERNAL REFERENCES -                                               * 18000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18200000
*                                                                     * 18400000
* EXITS, NORMAL -                                                     * 18600000
*    IF THE REPLY WAS 'U', XCTL BACK TO IFG0195A TO RESUME            * 18800000
*    PROCESSING OF THE DATA SET.                                      * 19000000
*                                                                     * 19200000
* EXITS, ERROR -                                                      * 19400000
*    IF THE REPLY WAS 'M', XCTL TO IFG0190P WITH OPEN INTERNAL        * 19600000
*    ABEND CODE 028 TO GIVE AN 713-08 ABEND.                          * 19800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 20000000
*                                                                     * 20200000
* TABLES/WORK AREAS -                                                 * 20400000
*    THE FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY  * 20600000
*    THE DSECTS AT THE END OF THE LISTING.                            * 20800000
*                                                                     * 21000000
* ATTRIBUTES -                                                        * 21200000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 21400000
*                                                                     * 21600000
* CHARACTER CODE DEPENDENCY -                                         * 21800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 22000000
*                                                                     * 22200000
* NOTES -                                                             * 22400000
*                                                                     * 22600000
*********************************************************************** 22800000
         EJECT                                                          23000000
         IECDSECS CVT,TCB,TIOT,UCB,     DEFINE DESIRED DSECTS TO BE    X23200000
               DCB,MAIN                 EXPANDED AT THE END             23400000
*                                                                       23600000
         IECEQU ,                       DEFINE EQUATES                  23800000
*                                                                       24000000
         USING IHADCB,RDCB              DEFINE BASE TO USER'S DCB       24200000
         USING FORCORE,RCORE            DEFINE BASE TO MAIN WORK AREA   24400000
         USING TIOENTRY,RTIOT           DEFINE BASE TO TIOT DD ENTRY    24600000
         USING UCBOB,RUCB               DEFINE BASE TO MAIN UCB         24800000
*                                                                       25000000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         25200000
         USING *,RBASE                  DEFINE BASE REGISTER            25400000
*                                                                       25600000
         B     ODA90200(RET)            BR TO INDICATED FUNCTION        25800000
*                                                                       26000000
ODA90200 B     ODA90400                 RET=0 EXPIRATION DATE ERROR     26200000
         B     ODA91200                 RET=4 EXP DATE WTOR MSG RETURN  26400000
         B     ODA92000                 RET=8 MISSING FMT 1 DSCB        26600000
*                                                                       26800000
*********************************************************************** 27000000
*                                                                       27200000
*  WRITE  'IEC107D E DDD,VOLSER,JOBNAME,STEPNAME,DSNAME'  MESSAGE       27400000
*  TO THE OPERATOR AND REQUEST HIM TO REPLY U OR M.                     27600000
*                                                                       27800000
ODA90400 EQU   *                                                        28000000
         LA    RF,REPLY                 PTR TO REPLY BUFFER             28200000
         ST    RF,REPLYLTH              STORE REPLY PTR IN MSG BUFF     28400000
         MVI   REPLYLTH,K1              INDICATE REPLY LENGTH OF 1      28600000
         LA    RF,DXECB                                                 28800000
         ST    RF,REPLYECB              STORE ECB PTR IN MSG BUFF       29000000
         MVI   DXECB,K0                 CLEAR ECB POST CODE             29200000
         MVC   MCSFLAGS(K16),ODA9400K   MOVE IN BASIC MSG               29400000
*                       2321 DATACELL PROCESSING                        29600000
         CLI   UCBID,UCBMAIN            CHECK IF 2321                   29800000
         BE    ODA90800                 BRANCH IF NOT 2321              30000000
         USING UCBDCELL,RUCB            SET UP BASE FOR DATACELL        30200000
         MVI   MSGUN+K3,C'/'            PUT SLASH IN MSG                30400000
         MVC   MSGUN+K4(K1),UCBDBBNR+K1  MOVE IN BIN NUMBER             30600000
         OI    MSGUN+K4,ZONEOF          CONVERT TO DECIMAL              30800000
         MVI   MSGUN+K5,C','            PUT COMMA IN MSG                31000000
         MVC   MSGVOLSR+K2,DXVOLMT1     PUT VOL SER IN MSG              31200000
         L     RF,DXDEBUCB              GET ADDR OF MAIN UCB            31400000
         MVC   MSGUN,UCBNAME-UCBOB(RF)  PUT UNIT ADDR IN MSG            31600000
         LA    R1,MSGVOLSR+K7           POINT TO LAST CHAR OF SER       31800000
         B     ODA91000                 BR TO DELIMIT VOL SER NO.       32000000
*                                                                       32200000
ODA90600 CLI   0(R1),C' '               FIND THE LAST NON-BLANK CHAR    32400000
         BCR   7,RET                    BR WHEN FOUND                   32600000
         BCT   R1,ODA90600              DECR ADDR AND BR TO LOOK AGAIN  32800000
*                                                                       33000000
         USING UCBOB,RUCB               SET UP BASE FOR UCBOB           33200000
ODA90800 EQU   *                                                        33400000
         MVC   MSGUN,UCBNAME            PUT UNIT ADDR IN MSG            33600000
         MVC   MSGVOLSR,DXVOLMT1        PUT VOL SER IN MSG              33800000
         LA    R1,MSGVOLSR+K5           POINT TO LAST CHAR OF SER       34000000
*                                                                       34200000
ODA91000 EQU   *                                                        34400000
         MVI   K1(R1),C','              DELIMIT VOLUME SERIAL NO.       34600000
         MVI   K2(R1),C' '              BLANK OUT                       34800000
         MVC   K3(K50,R1),K2(R1)        REMAINING BUFFER                35000000
*                                                                       35200000
         L     RF,CVTPTR                GET CVT ADDR                    35400000
         L     RF,CVTTCBP-CVT(,RF)      GET ADDR TCB POINTERS           35600000
         L     RF,K4(,RF)               GET CURRENT TCB ADDR            35800000
         L     RF,TCBTIO-TCB(,RF)       GET TIOT START ADDR             36000000
*                                                                       36200000
         MVC   K2(K8,R1),TIOCNJOB-TIOT(RF)  PUT THE JOB NAME IN MSG     36400000
         LA    R1,K9(R1)                ADVANCE BEYOND JOB NAME         36600000
         BAL   RET,ODA90600             GO REMOVE BLANKS                36800000
         MVI   K1(R1),C','              DELIMIT WITH A COMMA            37000000
*                                                                       37200000
         MVC   K2(K8,R1),TIOCSTEP-TIOT(RF)  PUT THE STEP NAME IN MSG    37400000
         LA    R1,K9(R1)                UPDATE MSG PTR                  37600000
         BAL   RET,ODA90600             GO REMOVE BLANKS                37800000
*                                                                       38000000
         LR    RF,R1                    DETERMINE LENGTH OF             38200000
         LA    R0,MSGLSTSZ-K1           PRESENT                         38400000
         SR    RF,R0                    MESSAGE                         38600000
         STH   RF,MSGLSTSZ              SAVE IN MSG LENGTH FIELD        38800000
*                                                                       39000000
         MVI   REPLY,X80                IND WTOR, DSNAME FROM JFCB      39200000
         L     RB,ODA9440K              PASS MCS CODES                  39400000
         MVC   DXRETMOD,ODA9940X        RETURN IDTTR                    39600000
*                                                                       39800000
         IECRES XCTL,ODA9970X,4         XCTL TO DSNAME MODULE           40000000
*                                                                       40200000
*********************************************************************** 40400000
*                                                                       40600000
ODA91200 EQU   *                                                        40800000
         WAIT  ECB=DXECB                WAIT ON OPERATOR REPLY          41000000
*                                                                       41200000
         LTR   RB,RB                    ONE LINE WTOR                   41400000
         BZ    ODA91400                 BR IF YES, NO DOM NEEDED        41600000
         DOM   MSGLIST=REPLY+K4         DELETE FIRST LINE OF MSG        41800000
*                                                                       42000000
ODA91400 EQU   *                                                        42200000
         CLI   REPLY,C'U'               IGNORE EXP CHECK                42400000
         BE    ODA91800                 YES, GO RESTORE DSCB AREA       42600000
         CLI   REPLY,C'M'               OPERATOR REPLY TO TERMINATE     42800000
         BE    ODA91600                 BR IF YES                       43000000
         B     ODA90400                 RECONSTRUCT AND REISSUE MSG     43200000
*                                                                       43400000
ODA91600 EQU   *                                                        43600000
OABD028  EQU   28                       DATA SET DATE NOT EXPIRED       43800000
         DMABCOND OABD028,ODA9920X      XCTL TO PROB DET / ABEND        44000000
*                                                                       44200000
*********************************************************************** 44400000
*                                                                       44600000
*  THE DSCB MUST BE RE-READ, BECAUSE THE ERROR MESSAGE WAS              44800000
*  CONSTRUCTED OVER IT.  IT IS READ DIRECTLY BY THE CCHHR IN            45000000
*  DXCCW7, WHICH WAS SAVED THERE BY EITHER THE DIRECT DSCB TTR          45200000
*  READ OR FULL VTOC SEARCH.                                            45400000
*                                                                       45600000
*        CONSTRUCT CHANNEL PROGRAM TO READ FORMAT 1 DSCB DIRECTLY.      45800000
*                                                                       46000000
*        SEARCH ID EQ                                                   46200000
*        TIC *-8                                                        46400000
*        READ DATA  (DSCB)                                              46600000
*                                                                       46800000
ODA91800 EQU   *                                                        47000000
         MVC   DXDAADDR+K3(K5),DXCCW7   CCHHR OF DSCB TO RE-READ        47200000
*                                                                       47400000
         XC    DXCCW3,DXCCW3            CLEAR THIRD CCW                 47600000
         LA    RF,DXDSCB                ADDR TO READ DSCB INTO          47800000
         ST    RF,DXCCW3                                                48000000
         OC    DXCCW3,ODA9460K          OR IN CMND, FLAGS, LENGTH       48200000
*                                                                       48400000
         EXCP  DXIOB                    READ DSCB                       48600000
*                                                                       48800000
         IECRES WAIT                    WAIT FOR READ OF DSCB           49000000
*                                                                       49200000
         TM    DXECB,ECBNOERR           ANY ERRORS                      49400000
         BZ    ODA92000                 BR IF YES TO MISSING DSCB       49600000
*                                       213 ABEND EXIT ERROR RECOVERY   49800000
*                                                                       50000000
         IECRES XCTL,ODA9960X,12        XCTL BACK TO RESUME OPEN        50200000
*                                                                       50400000
*********************************************************************** 50600000
*                                                                       50800000
         EJECT                                                          51000000
*********************************************************************** 51200000
*                                                                     * 51400000
*                          FUNCTION PROLOG                            * 51600000
*                                                                     * 51800000
*********************************************************************** 52000000
*                                                                     * 52200000
* FUNCTION NAME -                                                     * 52400000
*    OPEN DA MISSING DSCB 213 ABEND EXIT FUNCTION                     * 52600000
*                                                                     * 52800000
* (STATUS) -                                                          * 53000000
*    NOT APPLICABLE                                                   * 53200000
*                                                                     * 53400000
* FUNCTION -                                                          * 53600000
*    SEARCH THE USER'S DCB EXIT LIST FOR AN X'09' ENTRY.              * 53800000
*    IF FOUND, BYPASS GOING TO IFG0190P TO ISSUE A 213 ABNED, AND     * 54000000
*    INSTEAD STOP PROCESSING THIS DCB AND ALLOW A NORMAL RETURN TO    * 54200000
*    THE CALLER OF OPEN.                                              * 54400000
*    IF NOT FOUND, GO TO IFG0190P TO ISSUE THE 213 ABEND.             * 54600000
*                                                                     * 54800000
* ENTRY POINTS -                                                      * 55000000
*    IFG0195G WITH RET = 08 - ODA92000                                * 55200000
*                                                                     * 55400000
* INPUT -                                                             * 55600000
*    DCB USER EXIT LIST.                                              * 55800000
*                                                                     * 56000000
* OUTPUT -                                                            * 56200000
*    NONE.                                                            * 56400000
*                                                                     * 56600000
* EXTERNAL REFERENCES -                                               * 56800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 57000000
*                                                                     * 57200000
* EXITS, NORMAL -                                                     * 57400000
*    IF THE X'09' ENTRY IS FOUND, XCTL TO IFG0198N TO FINISH OPEN.    * 57600000
*                                                                     * 57800000
* EXITS, ERROR -                                                      * 58000000
*    IF THE X'09' ENTRY IS NOT FOUND, XCTL TO IFG0190P WITH           * 58200000
*    OPEN INTERNAL ABEND CODE 030 TO GIVE A 213-04 ABEND.             * 58400000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 58600000
*                                                                     * 58800000
* TABLES/WORK AREAS -                                                 * 59000000
*    THE FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY  * 59200000
*    THE DSECTS AT THE END OF THE LISTING.                            * 59400000
*                                                                     * 59600000
* ATTRIBUTES -                                                        * 59800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 60000000
*                                                                     * 60200000
* CHARACTER CODE DEPENDENCY -                                         * 60400000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 60600000
*                                                                     * 60800000
* NOTES -                                                             * 61000000
*    THE X'09' EXIT IS NOT AN EXTERNALLY DOCUMENTED EXIT FOR USE BY   * 61200000
*    ORDINARY USER PROBLEM PROGRAMS.  IT WAS ORIGINALLY USED BY       * 61400000
*    SYSOUT WRITER PROGRAMS IN ORDER TO AVOID ABENDING WHEN A DATA    * 61600000
*    SET HAD BEEN DELETED BEFORE IT WAS PRINTED.                      * 61800000
*    THE SAME RESULT CAN NOW BE ACHIEVED BY USING THE X'11' EXIT      * 62000000
*    AND SPECIFYING BYPASS THE ABEND IN THE EXIT ROUTINE.             * 62200000
*                                                                     * 62400000
*********************************************************************** 62600000
         EJECT                                                          62800000
         IECDSECS DCB,MAIN,WTG          DEFINE DESIRED DSECTS TO BE    X63000000
                                        EXPANDED AT THE END             63200000
*                                                                       63400000
         IECEQU ,                       DEFINE EQUATES                  63600000
*                                                                       63800000
         USING IHADCB,RDCB              DEFINE BASE TO USER'S DCB       64000000
         USING FORCORE,RCORE            DEFINE BASE TO MAIN WORK AREA   64200000
         USING UCBOB,RUCB               DEFINE BASE TO MAIN UCB         64400000
*                                                                       64600000
*********************************************************************** 64800000
*                                                                       65000000
*  DECREMENT THE OPEN DCB COUNT IN THE CURRENT UCB SO THAT THE          65200000
*  CURRENT VOLUME MAY BE DEMOUNTED LATER IF SO DESIRED.                 65400000
*                                                                       65600000
ODA92000 EQU   *                                                        65800000
         SR    RF,RF                    SET UP FOR TEST FOR ZERO        66000000
         SSM   *+K1                     DISABLE INTERRUPTS              66200000
         CLI   UCBID,UCBMAIN            IS THIS 2321                    66400000
         BE    ODA92200                 BR IF NO                        66600000
*                                                                       66800000
         USING UCBDCELL,RUCB            DEFINE BASE TO SUB UCB          67000000
         IC    RF,UCBDDMCT              GET 2321 UCB OPEN DCB COUNT     67200000
         LTR   RF,RF                    TEST IF ZERO (SAFETY CHECK)     67400000
         BZ    ODA92400                 BR IF ZERO, DO NOT DECREMENT    67600000
         BCTR  RF,0                     DECR COUNT BY 1                 67800000
         STC   RF,UCBDDMCT              STORE COUNT BACK IN UCB         68000000
         B     ODA92400                 BR TO RE-ENABLE INTERRUPTS      68200000
*                                                                       68400000
         USING UCBOB,RUCB               DEFINE BASE TO MAIN UCB         68600000
ODA92200 EQU   *                                                        68800000
         IC    RF,UCBDMCT               GET UCB OPEN DCB COUNT          69000000
         LTR   RF,RF                    TEST IF ZERO (SAFETY CHECK)     69200000
         BZ    ODA92400                 BR IF ZERO, DO NOT DECREMENT    69400000
         BCTR  RF,0                     DECR COUNT BY 1                 69600000
         STC   RF,UCBDMCT               STORE COUNT BACK IN UCB         69800000
ODA92400 SSM   ODA9480K                 RE-ENABLE INTERRUPTS            70000000
*                                                                       70200000
*********************************************************************** 70400000
*                                                                       70600000
*  CHECK FOR DCB EXIT. IF NONE, GO THROUGH NORMAL PROBLEM               70800000
*  DETERMINATION ERROR RECOVERY, WHICH WILL USUALLY RESULT IN A         71000000
*  213 ABEND, BECAUSE NO RECOVERY WAS SPECIFIED BY THE USER.            71200000
*                                                                       71400000
         TM    DCBMACRF,DCBMEXCP        CHECK FOR EXCP                  71600000
         BZ    ODA92600                 BR IF NO                        71800000
         TM    DCBMACRF,DCBMFOUN        CHECK FOR FOUNDATION EXTENSION  72000000
         BZ    ODA93400                 BR IF NOT PRESENT               72200000
*                                                                       72400000
ODA92600 EQU   *                                                        72600000
         L     R1,DCBEXLST              IS ADDR OF EXIT LIST 0 OR 1     72800000
         LA    R1,0(,R1)                                                73000000
         LA    R0,K1                                                    73200000
         CR    R1,R0                                                    73400000
         BNH   ODA93400                 BR IF NO LIST SPECIFIED         73600000
*                                                                       73800000
ODA92800 EQU   *                                                        74000000
         CLI   0(R1),XL213ABD           CHECK FOR ACTIVE X'09' DCB EXIT 74200000
         BE    ODA93000                 BR IF YES                       74400000
         CLI   0(R1),XL213ABD+LASTNTRY  CHECK FOR ACTIVE X'89' DCB EXIT 74600000
         BE    ODA93000                 BR IF YES                       74800000
         TM    0(R1),LASTNTRY           IS THIS END OF LIST             75000000
         LA    R1,K4(,R1)               INCREMENT TO NEXT ENTRY IN LIST 75200000
         BZ    ODA92800                 BR IF NO                        75400000
*                                                                       75600000
         B     ODA93400                 BR TO PROBLEM DET / ABEND       75800000
*                                                                       76000000
*********************************************************************** 76200000
*                                                                       76400000
*  SINCE A 213 EXIT WAS FOUND, GO TO THE LAST OPEN LOADS TO CLEAN UP.   76600000
*  THEY WILL FREEMAIN THE WORK AREAS AND RETURN TO THE CALLER OF OPEN.  76800000
*  OTHER DCB'S MAY CONTINUE TO BE OPENED.                               77000000
*  NO 213 ABEND WILL BE ISSUED.  ANY ADDRESS IN THE EXIT LIST ENTRY     77200000
*  IS NOT USED.  CONTROL WILL RETURN TO THE NORMAL RETURN ADDRESS       77400000
*  OF THE CALLER OF OPEN.  HE SHOULD THEN TEST THE DCBOFLGS OPEN BIT.   77600000
*  THE DCB IS LEFT IN A PARTIALLY OPEN STATE AND SO CAN NOT BE          77800000
*  USED AGAIN WITHOUT COMPLETE REINITIALIZATION BY THE USER.            78000000
*                                                                       78200000
ODA93000 EQU   *                                                        78400000
         NI    DCBOFLGS,X'FF'-DCBOBUSY  CLEAR DCB BUSY BIT TO STOP OPEN 78600000
*                                                                       78800000
         IECRES XCTL,ODA9980X,4         XCTL TO END OF OPEN             79000000
*                                                                       79200000
*********************************************************************** 79400000
*                                                                       79600000
*  XCTL TO IFG0190P PROBLEM DETERMINATION MODULE.                       79800000
*  THERE, IF THE USER HAS A X'11' EXIT, HE MAY RECOVER FROM THIS        80000000
*  213 ABEND BY SPECIFYING A NEW VOLUME SERIAL NUMBER TO USE.           80200000
*  IF SO, PROBLEM DETERMINATION WILL XCTL TO IFG0194E TO TRY TO         80400000
*  RECOVERY WITH THE NEW VOLUME SERIAL NUMBER.                          80600000
*  PD WILL HAVE PLACED THE NEW VOLUME SERIAL NUMBER SPECIFIED BY THE    80800000
*  USER IN DXVOLMT1.                                                    81000000
*                                                                       81200000
ODA93400 EQU   *                                                        81400000
OABD030  EQU   30                       FORMAT 1 DSCB MISSING IN VTOC   81600000
         DMABCOND OABD030,ODA9920X,     XCTL TO PROBLEM DET / ABEND    X81800000
               RETURN=ODA9930X,RETCODE=0  IF USER SPECIFIES RECOVERY    82000000
*                                                                       82200000
*********************************************************************** 82400000
*                                                                       82600000
*        CONSTANTS                                                      82800000
*                                                                       83000000
ODA9400K DC    X'8000'                  WTOR PREFIX                     83200000
ODA9420K DC    C'IEC107D E DDD,'        BASIC MSG                       83400000
*                                                                       83600000
ODA9440K DC    0F'0',X'4000'            DESC=2 IMMEDIATE ACTION REQUIRD 83800000
         DC    X'9000'                  ROUTCDE=(1,4) MASTER CONSOLE,   84000000
*                                       DIRECT ACCESS POOL              84200000
*                                                                       84400000
ODA9460K DC    X'0600000000000060'      READ DATA  (DSCB)               84600000
*                                                                       84800000
ODA9480K DC    X'FF'                    SSM MASK TO ENABLE INTERRUPTS   85000000
*                                                                       85200000
         XCTLTABL ID=(ODA9920X,0P,ODA9930X,4E,ODA9940X,5G,             X85400000
               ODA9960X,5A,ODA9970X,0R,ODA9980X,8N)                     85600000
*                                                                       85800000
         IECDSECS EXPAND=YES            EXPAND DESIRED DSECTS HERE      86000000
*                                                                       86200000
         END                                                            86400000
