         TITLE 'IFG0195V/OPEN, EOV, SCRATCH, RENAME - TSO AUTOMATIC SECX00200021
               URITY PASSWORD'                                          00400021
         GBLC  &LIB                     DEFINE GLOBAL CHAR VARIABLE     00600021
&LIB     SETC  'LIB1'                   SET VALUE FOR OS /360           00800021
IFG0195V CSECT                                                          01000021
*********************************************************************** 01200021
*                                                                     * 01400021
*                                                                     * 01600021
*          RELEASE 25 DELETIONS/CHANGES                               * 01800021
*          RELEASE 24 DELETIONS/CHANGES                               * 02000021
*          RELEASE 23 DELETIONS/CHANGES                               * 02200021
*          RELEASE 22 DELETIONS/CHANGES                               * 02400021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 02402021
*0000620700                                                     SA70617 02404021
*          RELEASE 21 DELETIONS/CHANGES                               * 02600021
*0000148000,150000-152000,166000,598000-600000                   M0113  02700021
*0000774000                                                      M1556  02720021
*0000620000                                                      A42915 02750021
*                                                                     * 02800021
* STATUS CHANGE LEVEL 000                                             * 03000021
*                                                                     * 03200021
* FUNCTION -                                                          * 03400021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03600021
*    OPEN SECURITY TSO PASSWORD FUNCTION                              * 03800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 04000021
*                                                                     * 04200021
* ENTRY POINTS -                                                      * 04400021
*         IFG0195V                                                    * 04600021
*                                                                     * 04800021
* INPUT -                                                             * 05000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05200021
*                                                                     * 05400021
* OUTPUT -                                                            * 05600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05800021
*                                                                     * 06000021
* EXTERNAL REFERENCES -                                               * 06200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06400021
*                                                                     * 06600021
* EXITS, NORMAL -                                                     * 06800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07000021
*                                                                     * 07200021
* EXITS, ERROR -                                                      * 07400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07600021
*                                                                     * 07800021
* TABLES/WORK AREAS -                                                 * 08000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 08200021
*                                                                     * 08400021
* ATTRIBUTES -                                                        * 08600021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 08800021
*                                                                     * 09000021
* CHARACTER CODE DEPENDENCY -                                         * 09200021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 09400021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 09600021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 09800021
*                                                                     * 10000021
* NOTES -                                                             * 10200021
*    THIS MODULE IS ONLY USED BY TIME SHARING (TSO) TASKS.            * 10400021
*    THIS MODULE IS ONLY PRESENT IN A SYSTEM IF SYSGENED TO INCLUDE   * 10600021
*    TSO.                                                             * 10800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11000021
*                                                                     * 11200021
*********************************************************************** 11400021
         EJECT                                                          11600021
*********************************************************************** 11800021
*                                                                     * 12000021
*                          FUNCTION PROLOG                            * 12200021
*                                                                     * 12400021
*********************************************************************** 12600021
*                                                                     * 12800021
* FUNCTION NAME -                                                     * 13000021
*    OPEN SECURITY TSO PASSWORD FUNCTION                              * 13200021
*                                                                     * 13400021
* (STATUS) -                                                          * 13600021
*    NOT APPLICABLE                                                   * 13800021
*                                                                     * 14000021
* FUNCTION -                                                          * 14200021
*   *SEARCH FOR A DSE WITH A MATCHING DSNAME.  IF FOUND, USE          * 14400021
*    THE TTR TO READ THE RECORD IT POINTS TO IN THE PASSWORD DATA SET.* 14600021
*    CHECK THAT THE DSNAME IN THE RECORD MATCHES THE DSNAME OF THE    * 14800021
*    DATA SET.  FOR SCRATCH/RENAME THE MODE INDICATOR MUST BE WRITE.  * 15000021
*    FOR OPEN/EOV THE MODE INDICATOR MUST CORRESPOND                  * 15200021
*    WITH THE MODE OF USE OF THE DATA SET.                            * 15400021
*    FOR OPEN/EOV THE PASSWORD RECORD USE COUNTER IS INCREMENTED      * 15600021
*    BY 1 AND THE RECORD WRITTEN BACK.                                * 15800021
*   *IF THE ABOVE DOES NOT WORK, THE TJBX IS CHECKED FOR A MASTER     * 16000021
*    LOGON PASSWORD.  IF ONE EXISTS, IT IS PASSED ON TO               * 16200021
*    IFG0195U OR SECLOADA TO SEARCH THE PASSWORD DATA SET.            * 16400021
*   *IF NONE EXISTS, CONTROL XCTLS TO READPSWD TO PROMPT THE          * 16600021
*    TSO TERMINAL FOR THE PASSWORD.                                   * 16800021
*                                                                     * 17000021
* ENTRY POINTS -                                                      * 17200021
*          IFG0195V                                                   * 17400021
*                                                                     * 17600021
* INPUT -                                                             * 17800021
*    REGISTER  4 RCORE - POINTER TO DXCORE WORK AREA IF OPEN/EOV.     * 18000021
*    REGISTER  4 RCORE - POINTER TO DXCCW1 WORK AREA IF SCRATCH/RENAME* 18200021
*    REGISTER  5 RES    - POINTER TO RESIDENT ROUTINE IF OPEN/EOV.    * 18400021
*    REGISTER  5 RWKIOB - POINTER TO WORK IOB IF SCRATCH/RENAME.      * 18600021
*    REGISTER  6 RWTG - WTG TABLE ADDR IF OPEN/EOV.                   * 18800021
*    REGISTER  7 RPARC  - POINTER TO DCB PARM ENTRY IF OPEN/EOV.      * 19000021
*    REGISTER  7 RWKECB - POINTER TO WORK ECB IF SCRATCH/RENAME.      * 19200021
*    REGISTER 11 RB - POINTER TO 44 CHARACTER DSNAME.                 * 19400021
*    REGISTER 13 RD - POINTER TO SECURITY WORK AREA.                  * 19600021
*    SECURITY WORK AREA DEB ALREADY CHAINED TO WORK DCB.              * 19800021
*    ADDRESS OF DXCCW1 ALREADY IN IOB START ADDRESS.                  * 20000021
*                                                                     * 20200021
* OUTPUT -                                                            * 20400021
*    EXIT CODE IN MYCODE2.                                            * 20600021
*    MASTER LOGON PASSWORD IN MYREPLY IF EXIT CODE = 2.               * 20800021
*                                                                     * 21000021
* EXTERNAL REFERENCES -                                               * 21200021
*         IECPCNVT - SUBROUTINE TO CONVERT A RELATIVE DIRECT ACCESS   * 21210021
*                    ADDRESS AND CONCATENATION NUMBER, TTRN,          * 21220021
*                    INTO ITS ABSOLUTE EQUIVALENT, MBBCCHHR.          * 21230021
*                    IT IS RESIDENT IN THE NUCLEUS.                   * 21240021
*                       REGISTER      ENTRY                  EXIT     * 21250021
*                         0     - ACTUAL TTRN             DESTROYED   * 21260021
*                         1     - DEB ADDRESS             TRANSPARENT * 21270021
*                         2     - ADDRESS OF 8 BYTE       TRANSPARENT * 21280021
*                                 AREA FOR MBBCCHHR                   * 21290021
*                         3-8   - IGNORED                 TRANSPARENT * 21300021
*                         9-13  - IGNORED                 DESTROYED   * 21310021
*                         14    - RETURN ADDRESS          TRANSPARENT * 21320021
*                         15    - ENTRY ADDRESS           ERROR CODE  * 21330021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 21400021
*                                                                     * 21600021
* EXITS, NORMAL -                                                     * 21800021
*   *IF DSE TTR WAS GOOD,                                             * 22000021
*    XCTL TO IFG0195T FOR OPEN/EOV, OR                                * 22200021
*    XCTL TO SECLOADA FOR SCRATCH/RENAME.                             * 22400021
*   *IF MASTER LOGON PASSWORD IS AVAILABLE,                           * 22600021
*    XCTL TO IFG0195U FOR OPEN/EOV TO CHECK IT, OR                    * 22800021
*    XCTL TO SECLOADA FOR SCRATCH/RENAME TO CHECK IT.                 * 23000021
*   *OTHERWISE, XCTL TO READPSWD TO READ A PASSWORD.                  * 23200021
*                                                                     * 23400021
* EXITS, ERROR -                                                      * 23600021
*    XCTL TO IFG0195U FOR OPEN/EOV IF I/O ERROR WHILE UPDATING        * 23800021
*    VALID PASSWORD RECORD.                                           * 24000021
*                                                                     * 24200021
* TABLES/WORK AREAS -                                                 * 24400021
*    THE FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY  * 24600021
*    THE DSECTS AT THE END OF THE LISTING.                            * 24800021
*                                                                     * 25000021
* ATTRIBUTES -                                                        * 25200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 25400021
*                                                                     * 25600021
* CHARACTER CODE DEPENDENCY -                                         * 25800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 26000021
*                                                                     * 26200021
* NOTES -                                                             * 26400021
*   *ALTHOUGH THE FORCORE OPEN/CLOSE/EOV DSECT IS USED TO DESCRIBE    * 26600021
*    DXCCW1-12 AND THE WORK DEB, DCB, AND IOB, THE WORK AREA PASSED   * 26800021
*    BY SCRATCH/RENAME IS ACTUALLY DIFFERENT.                         * 27000021
*    THE DISPLACEMENTS BETWEEN THESE BLOCKS ARE DIFFERENT.            * 27200021
*    THEREFORE ADDRESSABILITY MUST BE ESTABLISHED SEPERATELY FOR      * 27400021
*    EACH BLOCK.                                                      * 27600021
*    BE VERY CAREFUL WHICH BASE REGISTER IS BEING USED, BECAUSE THE   * 27800021
*    CONTROL BLOCKS OVERLAP IN THEIR DSECT DEFINITION.  THIS ERROR    * 28000021
*    IS MOST LIKELY WTIH DXDAADDR+4,5,6,7 CONFLICTING WITH THE DEB.   * 28200021
*                                                                     * 28400021
*********************************************************************** 28600021
         EJECT                                                          28800021
         IECDSECS CVT,TSCVT,TCB,JSCB,   DEFINE DESIRED DSECTS TO BE    X29000021
               TJB,TJBX,DCB,DEB,MAIN,   EXPANDED AT THE END            X29200021
               SECCORE,DSE,WTG                                          29400021
*                                                                       29600021
         IECEQU ,                       DEFINE EQUATES                  29800021
*                                                                       30000021
         USING FORCORE,RCORE            DEFINE BASE TO MAIN WORK AREA   30200021
         USING WTG,RWTG                 DEFINE BASE TO XCTL/WTG TABLE   30400021
         USING SECCORE,RD               DEFINE BASE TO SECURITY WK AREA 30600021
*                                                                       30800021
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         31000021
         USING *,RBASE                  DEFINE BASE REGISTER            31200021
*                                                                       31400021
*********************************************************************** 31600021
*                                                                     * 31800021
*        TRY COUNT 1 ACTION FOLLOWS                                   * 32000021
*        CHECK FOR TTR IN DSE FOR TSO TASK                            * 32200021
*                                                                     * 32400021
*        ENTRY FROM IFG0195T OR SECLOADA                              * 32600021
*              TRY COUNT WAS 0 IN MYCODE2, AND                        * 32800021
*              THIS IS A TSO TASK                                     * 33000021
*                                                                     * 33200021
*********************************************************************** 33400021
*                                                                       33600021
*  INITIALIZE OPEN/EOV REGISTERS SO THAT THEY ARE THE SAME AS           33800021
*  THOSE FROM SCRATCH/RENAME SO THAT THIS MODULE DOE NOT HAVE           34000021
*  TO KNOW WHICH KIND OF WORK AREA IT HAS WHEN IT DOES I/O.             34200021
*                                                                       34400021
         CLI   MYCODE1,K1               IS THIS OPEN OR EOV             34600021
         BH    OSQ30200                 BR IF NO, SCRATCH/RENAME        34800021
*                                                                       35000021
         ST    RES,DXCCW10              SAVE OPEN/EOV REG 5             35200021
         ST    RPARC,DXCCW10+K4         SAVE OPEN/EOV REG 7             35400021
         LA    R5,DXIOB                 POINT TO OPEN/EOV IOB           35600021
         LA    R7,DXECB                 POINT TO OPEN/EOV ECB           35800021
         LA    RCORE,DXCCW1             POINT TO OPEN/EOV CCWS          36000021
*                                                                       36200021
         USING DXCCW1,RCORE             DEFINE BASE TO DXCCW1-DXCCW12   36400021
         USING DXIOB,R5                 DEFINE BASE REG 5 TO IOB        36600021
         USING DXECB,R7                 DEFINE BASE REG 7 TO ECB        36800021
*                                                                       37000021
*********************************************************************** 37200021
*                                                                       37400021
*  CALCULATE ADDRESS OF TJBX AND DSE FOR THIS TSO TASK.                 37600021
*                                                                       37800021
OSQ30200 EQU   *                                                        38000021
         MVI   MYCODE2,K1               SET TRY COUNT TO 1              38200021
         L     R1,CVTPTR                GET ADDRESS OF CVT              38400021
         L     RET,CVTTCBP-CVT(,R1)     LOAD TCB POINTER ADDR           38600021
         L     RET,K4(,RET)             LOAD CURRENT TCB                38800021
         L     RET,TCBJSCB-TCB(,RET)    GET JSCB ADDRESS                39000021
         LH    RET,JSCBTJID-IEZJSCB(,RET)  GET TJID                     39200021
*                                                                       39400021
         L     R1,CVTTSCVT-CVT(,R1)     GET ADDRESS OF TSCVT            39600021
         MH    RET,TSCVTSZU-TSCVT(,R1)  CALC TJB OFFSET                 39800021
         L     RF,TSCVTTJB-TSCVT(,R1)   GET TJB STARTING ADDRESS        40000021
         AR    RF,RET                   CALC ADDR OF CORRESPONDING TJB  40200021
*                                                                       40400021
         L     RF,TJBEXTNT-TJB(,RF)     GET TJBX ADDRESS                40600021
         ST    RF,DXCCW5                SAVE TJBX POINTER               40800021
         L     R1,TJBXDSE-TJBX(,RF)     GET DSE ADDRESS                 41000021
         USING DSE,R1                   DSE BASE                        41200021
*                                                                       41400021
*********************************************************************** 41600021
*                                                                       41800021
*  SEARCH DSE'S FOR ONE WITH MATCHING DSNAME, IF ANY.                   42000021
*                                                                       42200021
OSQ30400 EQU   *                                                        42400021
         LA    R1,0(R1)                 CLEAR HIGH ORDER BYTE           42600021
         LTR   R1,R1                    END OF CHAIN OR NO DSE          42800021
         BZ    OSQ33000                 BRANCH IF YES                   43000021
         IC    RF,DSEDSLNG              GET LENGTH OF DSNAME FIELD      43200021
         BCTR  RF,0                     DECREMENT FOR COMPARE           43400021
         EX    RF,OSQ30600              CHECK FOR CORRECT DSE           43600021
         BE    OSQ30800                 BR IF FOUND                     43800021
         L     R1,DSEFORWD              NEXT DSE IN FORWD CHAIN         44000021
         B     OSQ30400                 BR TO CONTINUE SEARCH           44200021
*                                                                       44400021
OSQ30600 CLC   DSEDSNAM(*-*),0(RB)      COMPARE DSNAMES                 44600021
*                                                                       44800021
OSQ30800 EQU   *                                                        45000021
         L     R0,DSETTRPW              PUT TTR IN PARM REG             45200021
         LTR   R0,R0                    CHECK FOR TTR IN DSE            45400021
         BZ    OSQ33000                 BR IF NO                        45600021
*                                                                       45800021
*********************************************************************** 46000021
*                                                                       46200021
*  CONVERT DSE TTR OF PASSWORD RECORD TO MBBCCHHR                       46400021
*                                                                       46600021
         STM   RTIOT,RD,DXCCW1          SAVE REGISTERS 9-13             46800021
         LA    R1,MYDEB                 POINT TO SECURITY WORK DEB      47000021
         LA    RDCB,DXDAADDR            POINT TO MBBCCHHR RESULT FIELD  47200021
         L     RF,CVTPTR                GET CVT ADDR                    47400021
         L     RF,CVTPCNVT-CVT(,RF)     GET ADDR OF IECPCNVT ROUTINE    47600021
         BALR  RET,RF                   LINK TO CONVERT ROUTINE         47800021
         LM    RTIOT,RD,DXCCW1          RESTORE REGISTERS 9-13          48000021
*                                                                       48200021
*********************************************************************** 48400021
*                                                                       48600021
*  CONSTRUCT CHANNEL PROGRAM TO READ KEY AND DATA OF RECORD POINTED     48800021
*  TO BY DSE TTR.                                                       49000021
*                                                                       49200021
*        SEARCH ID EQ                                                   49400021
*        TIC *-8                                                        49600021
*        READ KEY+DATA, KEY TO MYDSNAM1                                 49800021
*        DATA TO MYLOGFLD                                               50000021
*                                                                       50200021
         XC    DXCCW1(K32),DXCCW1       CLEAR CCW AREA                  50400021
         LA    R1,DXDAADDR+K3           SEARCH ID ADDRESS               50600021
         ST    R1,DXCCW1                                                50800021
         LA    R1,DXCCW1                TIC *-8                         51000021
         ST    R1,DXCCW2                                                51200021
         LA    R1,MYDSNAM1              READ KEY ADDR (MYDSNAM1)        51400021
         ST    R1,DXCCW3                                                51600021
         LA    R1,MYLOGFLD              READ DATA ADDR (MYLOGFLD)       51800021
         ST    R1,DXCCW4                                                52000021
         OC    DXCCW1(K32),OSQ3800K     OR IN CMND, FLAGS, LENGTH       52200021
*                                                                       52400021
*        ESTABLISH ENQ/DEQ LIST IN SECURITY WORK AREA                   52600021
*                                                                       52800021
         CLI   MYCODE1,K2               IS THIS SCRATCH/RENAME          53000021
         BNL   OSQ31400                 BR IF YES, THEY DO NOT ENQ      53200021
*                                                                       53400021
         MVC   MYENQSW1,OSQ3820K        MOVE ENQ/DEQ LIST TO WORK AREA  53600021
         MVC   MYENQSW4,OSQ3830K        MOVE QNAME TO WORK AREA         53800021
         LA    R1,MYENQSW4              ADDR OF QNAME                   54000021
         ST    R1,MYENQSW2                                              54200021
         ST    RB,MYENQSW3              ADDR OF RNAME - CURRENT DSNAME  54400021
*                                                                       54600021
*        BEFORE READING OF THE PASSWORD ENTRY, ENQ BY DATA SET NAME     54800021
*                                                                       55000021
         ENQ   MF=(E,MYENQSW1)          ENQ ON DSNAME                   55200021
*                                                                       55400021
*        READ PASSWORD ENTRY                                            55600021
*                                                                       55800021
OSQ31400 EQU   *                                                        56000021
         EXCP  DXIOB                    READ KEY AND DATA OF RCD        56200021
*                                                                       56400021
         WAIT  ECB=DXECB                WAIT FOR READ TO COMPLETE       56600021
*                                                                       56800021
         XC    MYREPLY1,MYREPLY1        HIDE PASSWORD BY ZEROING IT     57000021
*                                                                       57200021
         TM    DXECB,ECBNOERR           CHECK FOR I/O ERROR             57400021
         BZ    OSQ32200                 BR IF YES                       57600021
*                                                                       57800021
         CLC   MYDSNAM1,0(RB)           ARE DSNAMES EQUAL               58000021
         BNE   OSQ32200                 BR IF NO, WRONG PASSWORD RCD    58200021
*                                                                       58400021
*********************************************************************** 58600021
*                                                                       58800021
*  CHECK THAT MODE INDICATOR IN PASSWORD RECORD CORRESPONDS TO MODE     59000021
*  OF USE OF THE DATA SET.                                              59200021
*                                                                       59400021
         CLI   MYCODE1,K2               IS THIS SCRATCH/RENAME          59600021
         BL    OSQ31500                 BR IF NO                 M0113  59670021
*                                                                       59740021
         TM    MYMODE,X01               IS MODE READ AND WRITE   M0113  59810021
         BO    OSQ32000                 BR IF YES                M0113  59880021
         B     OSQ32200                 BR READ ONLY MODE IS BAD M0113  59950021
*                                                                       60020021
OSQ31500 EQU   *                                                 M0113  60090021
         TM    MYMODE,K1                IS MODE READ AND WRITE          60200021
         BO    OSQ31800                 BR IF YES                       60400021
*                                                                       60600021
         L     RF,DXCCW10+K4            RESTORE OPEN/EOV RPARC          60800021
         CLI   MYCODE1,K0               IS THIS OPEN                    61000021
         BNE   OSQ31600                 BR IF NO, EOV                   61200021
*                                                                       61400021
         TM    0(RF),X'0E'              IS OPEN FOR INPUT OR RDBACK     61600021
         BNZ   OSQ32200                 BR IF NO, INCONSISTENT MODE     61800021
*  CHECK FOR ISAM OUTPUT DCB, WHICH CAN BE HAD BY OPENING FOR INPUT     61830021
*  WITH MACRF = P OR W.  ISAM DOES NOT GO THROUGH EOV.                  61860021
         L     RDCB,PLISTDCB(,RF)       RESTORE DCB ADDR         A42915 61890021
         USING IHADCB,RDCB              DEFINE BASE TO USER DCB  A42915 61920021
         TM    DCBMACRF,DCBMEXCP        IS THIS AN EXCP DCB      A42915 61950021
         BO    OSQ31800                 BR IF YES, NOT ISAM      A42915 61980021
         TM    DCBDSORG,DCBORGIS        IS THIS AN ISAM DCB      A42915 62010021
         BZ    OSQ31800                 BR IF NO                 A42915 62040021
         TM    DCBMACRF+K1,ALLBITS-DCBMSETK-DCBMSETL-DCBMSETI   SA70617 62070021
*                                       ANY OUTPUT MACRF BIT ON SA70617 62072021
         BZ    OSQ31800                 BR IF NO                 A42915 62100021
         B     OSQ32200                 BR INCONSISTENT MODE     A42915 62130021
         DROP  RDCB                     DROP DCB BASE REGISTER   A42915 62160021
*                                                                       62200021
OSQ31600 L     RDCB,0(,RF)              RESTORE EOV DCB ADDR            62400021
         L     RF,DCBDEBAD-IHADCB(,RDCB)  GET DEB ADDR FROM USER'S DCB  62600021
         TM    DEBOPATB-DEB(RF),DEBOPOUT-DEBOPRBK  OPEN INPUT OR RDBACK 62800021
         BNZ   OSQ32200                 BR IF NO, INCONSISTENT MODE     63000021
*                                                                       63200021
OSQ31800 EQU   *                                                        63400021
         LA    R1,K1                    GET INCREMENTING FACTOR         63600021
         AH    R1,MYCNTR                ADD 1 TO USE COUNT              63800021
         STH   R1,MYCNTR                STORE IT BACK                   64000021
*                                                                       64200021
*********************************************************************** 64400021
*                                                                       64600021
*        CONSTRUCT CHANNEL PROGRAM TO WRITE BACK PASSWORD RECORD        64800021
*                                                                       65000021
*        SEARCH ID EQ                                                   65200021
*        TIC *-8                                                        65400021
*        WRITE DATA                                                     65600021
*                                                                       65800021
         MVC   DXCCW3,DXCCW4            CHANGE READ DATA CCW TO         66000021
         MVI   DXCCW3,CCWWRTDA          WRITE DATA                      66200021
*                                                                       66400021
         EXCP  DXIOB                    WRITE BACK DATA RCD             66600021
*                                                                       66800021
         WAIT  ECB=DXECB                WAIT FOR WRITE TO COMPLETE      67000021
*                                                                       67200021
         DEQ   MF=(E,MYENQSW1)          DEQ PREVIOUS ENQ ON DSNAME      67400021
*                                                                       67600021
         MVI   MYCODE2,K8               SET TRY COUNT TO 8 FOR ERROR    67800021
         TM    DXECB,ECBNOERR           TEST IF I/O ERROR               68000021
         BZ    OSQ34000                 BR IF YES TO XCTL TO IFG0195U   68200021
*                                                                       68400021
OSQ32000 EQU   *                                                        68600021
         MVI   MYCODE2,K5               SET TRY COUNT TO 5              68800021
         B     OSQ34000                 BR XCTL TO IFG0195T / SECLOADA  69000021
*                                                                       69200021
*********************************************************************** 69400021
*                                                                       69600021
*  DEQ UNSUCCESSFUL PASSWORD RECORD                                     69800021
*                                                                       70000021
OSQ32200 EQU   *                                                        70200021
         CLI   MYCODE1,K2               IS THIS SCRATCH/RENAME          70400021
         BNL   OSQ33000                 BR IF YES, THEY DID NOT ENQ     70600021
*                                                                       70800021
         DEQ   MF=(E,MYENQSW1)          DEQ PREVIOUS ENQ ON DSNAME      71000021
*                                                                       71200021
*********************************************************************** 71400021
*                                                                     * 71600021
*        TRY COUNT 2 ACTION FOLLOWS                                   * 71800021
*        CHECK USER'S GENERAL PASSWORD IN TJBX FOR TSO TASK           * 72000021
*                                                                     * 72200021
*********************************************************************** 72400021
*                                                                       72600021
*  GET ANY MASTER LOGON PASSWORD FROM TJBX                              72800021
*                                                                       73000021
OSQ33000 EQU   *                                                        73200021
         L     RF,DXCCW5                RESTORE TJBX POINTER            73400021
         CLI   TJBXPSWD-TJBX(RF),BLANK  CHECK FOR LOGON PASSWORD        73600021
         BE    OSQ34000                 BR IF NO PASSWORD FOUND         73800021
*                                                                       74000021
         MVC   MYREPLY,TJBXPSWD-TJBX(RF)  MOVE PASSWORD TO SEARCH AREA  74200021
         MVI   MYCODE2,K2               SET TRY COUNT TO 2              74400021
*                                                                       74600021
*********************************************************************** 74800021
*                                                                       75000021
*  SET UP XCTL TO NEXT MODULE                                           75200021
*                                                                       75400021
OSQ34000 EQU   *                                                        75600021
         CLI   MYCODE1,K1               IS THIS OPEN OR EOV             75800021
         BH    OSQ35000                 BR IF NO                        76000021
*                                                                       76200021
         LA    R1,DXCCW1-FORCORE        RESTORE NORMAL OPEN/EOV         76400021
         SR    RCORE,R1                 RCORE ADDRESS                   76600021
         USING FORCORE,RCORE            DEFINE BASE TO MAIN WORK AREA   76800021
         DROP  R5,R7                                             M1556  76900021
         L     RES,DXCCW10              RESTORE OPEN/EOV REG 5          77000021
         L     RPARC,DXCCW10+K4         RESTORE OPEN/EOV REG 7          77200021
*                                                                       77600021
         CLI   MYCODE2,K1               DID NOTHING WORK                77800021
         BE    OSQ34400                 BR IF YES, XCTL TO READPSWD     78000021
*                                                                       78200021
         MVC   WTGMODID,OSQ3900X        SET WTG TABLE NAME TO IFG0195T  78400021
         MVC   WTGTTR,OSQ3900X+K2       SET WTG TABLE TTR               78600021
         LA    RET,K8                   SET GOOD PASSWORD RETURN IND    78800021
*                                                                       79000021
         CLI   MYCODE2,K5               WAS DSE TTR SUCCESSFUL          79200021
         BE    OSQ34200                 BR IF YES                       79400021
*                                                                       79600021
*                                       TRY CODE MUST BE 2 OR 8         79800021
         MVC   WTGMODID,OSQ3920X        SET WTG TABLE NAME TO IFG0195U  80000021
         MVC   WTGTTR,OSQ3920X+K2       SET WTG TABLE TTR               80200021
*                                                                       80400021
OSQ34200 EQU   *                                                        80600021
         CLI   WTGTTR+K2,K0             IS R OF TTR ZERO                80800021
         BE    OSQ34600                 BR IF YES TO XCTL BY NAME       81000021
*                                                                       81200021
         XCTL  DE=(RWTG),SF=(E,DXXCTL)  XCTL TO IFG0195T OR IFG0195U    81400021
*                                                                       81600021
OSQ34400 EQU   *                                                        81800021
         MVC   WTGMODNM,OSQ3860K        SET WTG TABLE NAME TO READPSWD  82000021
         SR    RUCB,RUCB                INDICATE NOT SCRATCH/RENAME     82200021
*                                       INITIAL ENTRY                   82400021
*                                                                       82600021
OSQ34600 EQU   *                                                        82800021
         XCTL  EPLOC=(RWTG),SF=(E,DXXCTL)  XCTL BY NAME                 83000021
*                                                                       83200021
*********************************************************************   83400021
*                                                                       83600021
OSQ35000 EQU   *                                                        83800021
         CLI   MYCODE2,K1               DID NOTHING WORK                84000021
         BE    OSQ35400                 BR IF YES, XCTL TO READPSWD     84200021
*                                                                       84400021
*                                       TRY COUNT MUST BE 2, 5, OR 8    84600021
OSQ35200 EQU   *                                                        84800021
         MVC   MYMODNM,OSQ3850K         SET MODULE NAME TO SECLOADA     85000021
         B     OSQ35600                 BR TO XCTL TO SECLOADA          85200021
*                                                                       85400021
OSQ35400 EQU   *                                                        85600021
         MVC   MYMODNM,OSQ3860K         SET MODULE NAME TO READPSWD     85800021
*                                                                       86000021
OSQ35600 EQU   *                                                        86200021
         SR    RUCB,RUCB                INDICATE NOT SCRATCH/RENAME     86400021
*                                       INITIAL ENTRY                   86600021
         XC    MYXCTL+K4(K4),MYXCTL+K4  ZERO XCTL HIARCHY AND DCB ADDR  86800021
         XCTL  EPLOC=MYMODNM,SF=(E,MYXCTL)  XCTL BY NAME                87000021
*                                                                       87200021
*********************************************************************** 87400021
*                                                                       87600021
*        CONSTANTS                                                      87800021
*                                                                       88000021
*        CCW'S TO READ KEY+DATA OF PASSWORD RECORD POINTED              88200021
*        BY A TSO DSE TTR                                               88400021
OSQ3800K DC    X'3100000040000005'      SEARCH ID EQ                    88600021
         DC    X'0800000000000000'      TIC *-8                         88800021
         DC    X'0E00000080000034'      READ KEY+DATA, KEY TO MYDSNAM1  89000021
         DC    X'0000000020000050'      DATA TO MYLOGFLD  (SLI)         89200021
*                                                                       89400021
*        ENQ PARM LIST IS EQUIVALENT TO  ENQ (,,E,44,SYSTEM),MF=L       89600021
OSQ3820K DC    X'FF2C4000'              ENQ PARAMETER LIST              89800021
OSQ3830K DC    C'SYSPSWRD'              MAJOR ENQ NAME                  90000021
*                                                                       90200021
OSQ3850K DC    C'SECLOADA'              SCRATCH/RENAME MODULE NAME      90400021
OSQ3860K DC    C'READPSWD'              PASSWORD READING MODULE NAME    90600021
*                                                                       90800021
         XCTLTABL ID=(OSQ3900X,5T,OSQ3920X,5U)                          91000021
*                                                                       91200021
         IECDSECS EXPAND=YES            EXPAND DESIRED DSECTS HERE      91400021
*                                                                       91600021
         END                                                            91800021
