         TITLE 'IFG0196O/OPEN - NSL OUTPUT'                             00400000
         GBLC  &LIB                                                     00800000
&LIB     SETC  'LIB1'                                                   01200000
IFG0196O CSECT                                                          01600000
*********************************************************************** 02000000
*                                                                     * 02400000
*                                                                     * 02800000
*          RELEASE 25 DELETIONS/CHANGES                               * 03200000
*          RELEASE 24 DELETIONS/CHANGES                               * 03600000
*          RELEASE 23 DELETIONS/CHANGES                               * 04000000
*          RELEASE 22 DELETIONS/CHANGES                               * 04400000
*          RELEASE 21 DELETIONS/CHANGES                               * 04800000
*0000908000                                                      M0114  05000021
*                                                                     * 05200000
* STATUS CHANGE LEVEL 000                                             * 05600000
*                                                                     * 06000000
* FUNCTION -                                                          * 06400000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 06800000
*    OPEN TAPE NSL OUTPUT INTERFACE FUNCTION.                         * 07200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 07600000
*                                                                     * 08000000
* ENTRY POINTS -                                                      * 08400000
*    IFG0196O - VIA THE RESIDENT ROUTINE XCTL FROM THE FOLLOWING--    * 08800000
*         IFG0194I - RETURN FROM A REMOUNT.                           * 09200000
*         IFG0196M - NORMAL ENTRY TO PROCESS NSL OUTPUT LABELS.       * 09600000
*    IGG0190R - ALIAS ENTRY POINT VIA XCTL FROM NSLOHDRO - RETURN     * 10000000
*              FROM NSL ROUTINE.                                      * 10400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 10800000
*                                                                     * 11200000
* INPUT -                                                             * 11600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 12000000
*                                                                     * 12400000
* OUTPUT -                                                            * 12800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 13200000
*                                                                     * 13600000
* EXTERNAL REFERENCES -                                               * 14000000
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 14400000
*          WAIT.                                                      * 14800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 15200000
*                                                                     * 15600000
* EXITS, NORMAL -                                                     * 16000000
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING--            * 16400000
*         IFG0194G - REMOUNT REJECTED VOLUME.                         * 16800000
*         IFG0196V - CONTINUE NORMAL PROCESSING.                      * 17200000
*    EXIT VIA XCTL TO NSLOHDRO TO PROCESS NSL OUTPUT LABELS.          * 17600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 18000000
*                                                                     * 18400000
* EXITS, ERROR -                                                      * 18800000
*    NONE.                                                            * 19200000
*                                                                     * 19600000
* TABLES/WORK AREAS -                                                 * 20000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 20400000
*                                                                     * 20800000
* ATTRIBUTES -                                                        * 21200000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 21600000
*                                                                     * 22000000
* CHARACTER CODE DEPENDENCY -                                         * 22400000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 22800000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 23200000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 23600000
*                                                                     * 24000000
* NOTES -                                                             * 24400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 24800000
*                                                                     * 25200000
*********************************************************************** 25600000
         EJECT                                                          26000000
*********************************************************************** 26400000
*                                                                     * 26800000
*                          FUNCTION PROLOG                            * 27200000
*                                                                     * 27600000
*********************************************************************** 28000000
*                                                                     * 28400000
* FUNCTION NAME -                                                     * 28800000
*    OPEN TAPE NSL OUTPUT INTERFACE FUNCTION.                         * 29200000
*                                                                     * 29600000
* (STATUS) -                                                          * 30000000
*    NOT APPLICABLE                                                   * 30400000
*                                                                     * 30800000
* FUNCTION -                                                          * 31200000
*    INTERFACE WITH THE USER SUPPLIED NSL OUTPUT ROUTINE (NSLOHDRO).  * 31600000
*    SYCHRONIZE ALL DCBS, SET UP THE CONDITIONS TO PROCESS THE DCBS   * 32000000
*    IN PARALLEL BEFORE EXITING TO THE NSL ROUTINE.                   * 32400000
*    ON RETURN FROM THE NSL ROUTINE, RESET TO PROCESS SERIALLY VIA    * 32800000
*    THE RESIDENT ROUTINE.                                            * 33200000
*    REJECT TAPE VOLUMES AND REMOUNT. TAPE VOLUMES ARE REJECTED       * 33600000
*    BASED ON THE DISPOSITION OF THE MOUNT BIT IN THE UCB (BIT 0 AT   * 34000000
*    OFFSET 35). VOLUMES ARE REJECTED IF THE BIT IS SET.              * 34400000
*                                                                     * 34800000
* ENTRY POINTS -                                                      * 35200000
*    ENTERED FROM THE FOLLOWING--                                     * 35600000
*    OPEN TAPE FINAL COMMON FUNCTION ON RETURN FROM A REMOUNT.        * 36000000
*    OPEN MERGE DCB TO JFCB FUNCTION FOR NORMAL NSL PROCESSING.       * 36400000
*    NSL ROUTINE (NSLOHDRO) ON RETURN FROM NSL PROCESSING.            * 36800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37200000
*                                                                     * 37600000
* INPUT -                                                             * 38000000
*    A POINTER TO EACH OF THE FOLLOWING--                             * 38400000
*       CURRENT PARAMETER LIST ENTRY.                                 * 38800000
*       DD ENTRY IN THE TIOT.                                         * 39200000
*       WTG TABLE.                                                    * 39600000
*       CURRENT WTG TABLE ENTRY.                                      * 40000000
*       DCB.                                                          * 40400000
*       OPEN WORK AREA.                                               * 40800000
*       RESIDENT ROUTINE.                                             * 41200000
*       UCB                                                           * 41600000
*                                                                     * 42000000
* OUTPUT -                                                            * 42400000
*    ON EXIT TO THE NSL ROUTINE THE FULL PARAMETER LIST IS PASSED     * 42800000
*    FOR PARALLEL PROCESSING.                                         * 43200000
*    ON FINAL EXIT THE TAPES HAVE BEEN VERIFIED AND POSITIONED BY     * 43600000
*    THE NSL ROUTINE.                                                 * 44000000
*                                                                     * 44400000
* EXTERNAL REFERENCES -                                               * 44800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 45200000
*                                                                     * 45600000
* EXITS, NORMAL -                                                     * 46000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 46400000
*    OPEN TAPE VOLUME MOUNTING FUNCTION FOR A REMOUNT OF REJECTED     * 46800000
*    VOLUMES.                                                         * 47200000
*    OPEN AM EXECUTOR DETERMINATION FUNCTION TO CONTINUE NORMAL       * 47600000
*    PROCESSING.                                                      * 48000000
*    NSL ROUTINE (NSLOHDRO) TO VERIFY AND POSITION NSL VOLUMES.       * 48400000
*                                                                     * 48800000
* EXITS, ERROR -                                                      * 49200000
*    NONE.                                                            * 49600000
*                                                                     * 50000000
* TABLES/WORK AREAS -                                                 * 50400000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 50800000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 51200000
*                                                                     * 51600000
* ATTRIBUTES -                                                        * 52000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 52400000
*                                                                     * 52800000
* CHARACTER CODE DEPENDENCY -                                         * 53200000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 53600000
*                                                                     * 54000000
* NOTES -                                                             * 54400000
*                                                                     * 54800000
*********************************************************************** 55200000
         EJECT                                                          55600000
*                                                                       56000000
         USING FORCORE,RCORE            WORK AREA                       56400000
         USING TIOENTRY,RTIOT           TIOT ENTRY                      56800000
         USING IHADCB,RDCB              DCB                             57200000
         USING UCBOB,RUCB               UCB                             57600000
         USING WTG,RWTG                 WHERE TO GO TABLE               58000000
*                                                                       58400000
         BALR  RBASE,0                  SET BASE REGISTER               58800000
         USING *,RBASE                                                  59200000
*                                                                       59600000
         B     OTA70000(RET)            GO TO PROPER ENTRY              60000000
OTA70000 EQU   *                                                        60400000
         B     OTA70200                 RETURN FROM NSL                 60800000
         B     OTA70100                 INITAL ENTRY                    61200000
         B     OTA70500                 CHECK NSL RETURN                61600000
OTA70100 EQU   *                                                        62000000
         STM   RTIOT,RUCB,DXXCTL        SAVE REGS FOR RETURN FROM NSL   62400000
         IECRES SYNCHDCB                                                62800000
         NI    WTGPATHS+K1,ALLBITS-K2   TURN OFF REJECT SWITCH          63200000
         LR    RD,RES                   SAVE RESIDENT PTR FOR RETURN    63600000
         L     RPAR,WTGECBAD            POINT TO ECB LIST               64000000
         L     RPAR,K0(RPAR)            PARAMETER LIST POINTER          64400000
         LA    RET,K0                   RE-ENTRY FORM NSL               64800000
         MVC   WTGMODNM,NSLRTN6O        NSL ROUTINE NAME                65200000
         LA    RF,DXCCW12               XCTL WORK AREA                  65600000
         XCTL  EPLOC=(RWTG),DCB=0,SF=(E,(15))                           66000000
*                                                                       66400000
OTA70200 EQU   *                                                        66800000
         MVC   WTGMODNM,MODNM6O         RESTORE IFG019 NAME             67200000
         LR    RPAR,RPARC               GET FIRST NSL PARM PTR          67600000
         LR    RB,RWTGC                 GET FIRST NSL WTG ENTRY PTR     68000000
OTA70300 EQU   *                                                        68400000
         TM    K0(RPAR),LASTNTRY        IS THIS THE LAST DCB IN LIST    68800000
         BO    OTA70400                 YES, GO CHECK FIRST DCB         69200000
         LA    RPAR,K4(RPAR)            GET NEXT PARM POINTER           69600000
         LA    RB,K8(RB)                GET NEXT WTG ENTRY POINTER      70000000
         CLC   K0(K2,RB),NSLOUT6O       THIS A NSL OUT DCB              70400000
         BNE   OTA70300                 NO, BRANCH                      70800000
         L     RC,K4(RB)                GET WORK AREA POINTER           71200000
*                                       RESTORE RTIOT AND RUCB TO       71600000
*                                       REGISTER SAVE AREA              72000000
         MVC   DXREG9-FORCORE(K8,RC),DXXCTL-FORCORE(RC)                 72400000
         LA    RET,K8                   ENTRY TO THIS LOAD AFTER        72800000
*                                       FIRST DCB HAS COMPLETED         73200000
         ST    RET,DXREGE-FORCORE(RC)   SAVE ENTRY VALUE                73600000
         B     OTA70300                 CHECK NEXT DCB                  74000000
OTA70400 EQU   *                                                        74400000
         LR    RES,RD                   RESTORE RESIDENT POINTER        74800000
*                                                                       75200000
OTA70500 EQU   *                                                        75600000
*                                                                       76000000
         TM    UCBDMCT,UCBMOUNT         CK FOR MOUNT SW FOR NSL         76400000
         BO    OTA70800                 BR IF ON                        76800000
         IECRES SYNCHDCB                                                77200000
         LA    RET,K8                   ENTRY FOR EXECUTOR INTERFACE    77600000
         LA    RF,EXLOAD6O              EXECUTOR INTERFACE LOAD IDTTR   78000000
         TM    WTGPATHS+K1,K2           IS ANY TAPE BEING REJECTED      78400000
         BZ    OTA70600                 NO, BRANCH                      78800000
         LA    RET,K4                   FOR RE-ENTRY TO THIS LOAD       79200000
         LA    RF,NSLOUT6O              THIS LOAD IDTTR                 79600000
         MVC   WTGMODID,BLNKID6O        BLANK MOD ID TO FORCE XCTL      80000000
OTA70600 EQU   *                                                        80400000
         LR    RB,RPARC                 GET CURRENT PARM LIST ENTRY     80800000
         LR    RC,RWTGC                 GET CURRENT WTG ENTRY           81200000
OTA70700 EQU   *                                                        81600000
         TM    K0(RB),LASTNTRY          LAST DCB IN PARM LIST           82000000
         BO    OTA70900                 YES, GO SET FIRST DCB EXIT      82400000
         LA    RB,K4(RB)                GET NEXT ENTRY IN PARM LIST     82800000
         LA    RC,K8(RC)                GET NEXT WTG ENTRY              83200000
         CLC   K0(K2,RC),NSLOUT6O       IS IT A NSL OUTPUT DCB          83600000
         BNE   OTA70700                 NO, BRANCH                      84000000
         L     RD,K4(RC)                GET WORK AREA ADDRESS           84400000
         NI    JFCBMASK+K5,ALLBITS-K8   RESET REJECT SWITCH             84800000
         ST    RET,DXREGE-FORCORE(RD)   SET ENTRY VALUE                 85200000
         MVC   K0(K5,RC),K0(RF)         MOVE IN NEXT MODULE IDTTR       85600000
         B     OTA70700                 GO CHECK FOR MORE DCBS          86000000
*                                                                       86400000
*                                                                       86800000
OTA70800 EQU   *                                                        87200000
         OI    WTGPATHS+K1,K2           INDICATE REJECT                 87600000
         OI    JFCBMASK+K5,K8           SET REJECT SW ON                88000000
         MVI   UCBDMCT,K0               ZERO OUT DMCT                   88400000
         LA    RET,K20                  REJECT ENTRY                    88800000
         LA    RF,REJECT6O              MESSAGE MODULE IDTTR            89200000
OTA70900 EQU   *                                                        89600000
         IECRES XCTL,(RF),(RET)                                         90000000
*                                                                       90400000
MODNM6O  DC    C'IFG0196O'              CURRENT MODULE           M0114  90800021
NSLRTN6O DC    C'NSLOHDRO'              NSL OUTPUT HEADER LABEL ROUTINE 91200000
BLNKID6O DC    C'  '                    BLANK MOD ID TO FORCE XCTL      91600000
*                                                                       92000000
XCTL6O   XCTLTABL ID=(NSLOUT6O,6O,EXLOAD6O,6V,REJECT6O,4G)              92400000
*                                                                       92800000
         IECDSECS TIOT,DCB,UCB,MAIN,WTG,EXPAND=YES                      93200000
         IECEQU                                                         93600000
         END                                                            94000000
