         TITLE 'IFG0196Q/OPEN - OUTPUT DATE CHECK AND REWRITE VOL LBL'  00200021
         COPY  LCGASMSW                                                 00250000
IFG0196Q CSECT                                                          00800021
*********************************************************************** 01000021
*                                                                     * 01200021
*                                                                     * 01400021
*          RELEASE 25 DELETIONS/CHANGES                               * 01600021
*          RELEASE 24 DELETIONS/CHANGES                               * 01800021
*          RELEASE 23 DELETIONS/CHANGES                               * 02000021
*          RELEASE 22 DELETIONS/CHANGES                               * 02200021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 02250000
*0000834000                                                     SA68416 02300000
*          RELEASE 21 DELETIONS/CHANGES                               * 02400021
*                                                                     * 02600021
* STATUS CHANGE LEVEL 000                                             * 02800021
*                                                                     * 03000021
* FUNCTION -                                                          * 03200021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03400021
*    OPEN TAPE SL DATE PROTECTION FUNCTION.                           * 03600021
*    OPEN TAPE SL REWRITE VOLUME LABEL FUNCTION.                      * 03800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 04000021
*                                                                     * 04200021
* ENTRY POINTS -                                                      * 04400021
*         IFG0196Q - VIA RESIDENT ROUTINE XCTL FROM THE FOLLOWING--   * 04600021
*             IFG0196N - TO CHECK THE EXPIRATION DATE OR REWRITE      * 04800021
*                        THE VOLUME LABEL.                            * 05000021
*                                                                     * 05200021
* INPUT -                                                             * 05400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05600021
*                                                                     * 05800021
* OUTPUT -                                                            * 06000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06200021
*                                                                     * 06400021
* EXTERNAL REFERENCES -                                               * 06600021
*         IFG019RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 06800021
*                    WAIT.                                            * 07000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07200021
*                                                                     * 07400021
* EXITS, NORMAL -                                                     * 07600021
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING--            * 07800021
*         IFG0195T - TO READ THE PASSWORD.                            * 08000021
*         IFG0196T - TO WRITE HEADER LABELS.                          * 08200021
*         IFG0194G - FOR A REMOUNT.                                   * 08400021
*         IFG0190R - TO INSERT THE DATA SET NAME ON THE DATE PROTECT  * 08600021
*                    MESSAGE.                                         * 08800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 09000021
*                                                                     * 09200021
* EXITS, ERROR -                                                      * 09400021
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0190P, IF AN      * 09600021
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 09800021
*    'FUNCTION PROLOG(S)'.                                            * 10000021
*                                                                     * 10200021
* TABLES/WORK AREAS -                                                 * 10400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 10600021
*                                                                     * 10800021
* ATTRIBUTES -                                                        * 11000021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 11200021
*                                                                     * 11400021
* CHARACTER CODE DEPENDENCY -                                         * 11600021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 11800021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 12000021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 12200021
*                                                                     * 12400021
* NOTES -                                                             * 12600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 12800021
*                                                                     * 13000021
*********************************************************************** 13200021
         EJECT                                                          13400021
*********************************************************************** 13600021
*                                                                     * 13800021
*                          FUNCTION PROLOG                            * 14000021
*                                                                     * 14200021
*********************************************************************** 14400021
*                                                                     * 14600021
* FUNCTION NAME -                                                     * 14800021
*    OPEN TAPE SL DATE PROTECTION FUNCTION.                           * 15000021
*                                                                     * 15200021
* (STATUS) -                                                          * 15400021
*    NOT APPLICABLE                                                   * 15600021
*                                                                     * 15800021
* FUNCTION -                                                          * 16000021
*    CHECK TO SEE IF THE EXPIRATION DATE IN THE LABEL HAS PASSED.     * 16200021
*    IF NOT GET THE OPERATORS DECISION AS TO USE THE TAPE OR REMOUNT. * 16400021
*                                                                     * 16600021
* ENTRY POINTS -                                                      * 16800021
*    ENTERED FROM THE FOLLOWING--                                     * 17000021
*    OPEN TAPE SL OUTPUT SECURITY FUNCTION TO CHECK EXPIRATION DATE.  * 17200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 17400021
*                                                                     * 17600021
* INPUT -                                                             * 17800021
*    A POINTER TO EACH OF THE FOLLOWING--                             * 18000021
*       CURRENT PARAMETER LIST ENTRY.                                 * 18200021
*       DD ENTRY IN THE TIOT.                                         * 18400021
*       WTG TABLE.                                                    * 18600021
*       CURRENT WTG TABLE ENTRY.                                      * 18800021
*       DCB.                                                          * 19000021
*       OPEN WORK AREA.                                               * 19200021
*       RESIDENT ROUTINE.                                             * 19400021
*       UCB                                                           * 19600021
*                                                                     * 19800021
* OUTPUT -                                                            * 20000021
*    THE FOLLOWING MESSAGE MAY BE ISSUED VIA THE DSNAME WTO FUNCTION--* 20200021
*       IEC107D E - DATE PROTECTION MESSAGE.                          * 20400021
*                                                                     * 20600021
* EXTERNAL REFERENCES -                                               * 20800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 21000021
*                                                                     * 21200021
* EXITS, NORMAL -                                                     * 21400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 21600021
*    OPEN SECURITY INITIALIZATION FUNCTION TO READ THE PASSWORD.      * 21800021
*    OPEN TAPE SL REWRITE VOLUME LABEL FUNCTION.                      * 22000021
*    OPEN TAPE SL HEADER LABEL WRITING FUNCTION.                      * 22200021
*    OPEN TAPE VOLUME MOUNTING FUNCTION TO REMOUNT.                   * 22400021
*    DISPLAY DSNAME WTO FUNCTION TO ISSUE MESSAGE.                    * 22600021
*                                                                     * 22800021
* EXITS, ERROR -                                                      * 23000021
*    NONE.                                                            * 23200021
*                                                                     * 23400021
* TABLES/WORK AREAS -                                                 * 23600021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 23800021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 24000021
*                                                                     * 24200021
* ATTRIBUTES -                                                        * 24400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 24600021
*                                                                     * 24800021
* CHARACTER CODE DEPENDENCY -                                         * 25000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 25200021
*                                                                     * 25400021
* NOTES -                                                             * 25600021
*    NOT APPLICABLE                                                   * 25800021
*                                                                     * 26000021
*********************************************************************** 26200021
         EJECT                                                          26400021
*                                                                     * 26600021
         SPACE 1                                                        26800021
*                   ADDRESSABILITY                                      27000021
         SPACE 1                                                        27200021
         BALR  RBASE,0                  LOAD BASE REGISTER              27400021
         USING *,RBASE                  ESTABLISH ADDRESSABILITY        27600021
*                                                                       27800021
         USING FORCORE,RCORE            WORK AREA ADDRESSABILITY        28000021
         USING IHADCB,RDCB              DCB ADDRESSABILITY              28200021
         USING SRT,RUCB                 UCB ADDRESSABILITY              28400021
         USING TIOENTRY,RTIOT           TIOT ADDRESSABILITY             28600021
         USING CVT,RB                   CVT ADDRESSABILITY              28800021
*                                                                       29000021
         B     OTA40600(RET)            GO TO PROPER ENTRY              29200021
OTA40600 EQU   *                                                        29400021
         B     OTA41300                 WAIT FOR WTOR REPLY             29600021
         B     OTA41800                 REWRITE VOL LABEL               29800021
         SPACE 1                                                        30000021
*                   VERIFY THAT RETENTION IS EXPIRED                    30200021
         SPACE 1                                                        30400021
         L     RB,CVTPTR                ADDR OF CVT                     30600021
         PACK  DXCCW2+K5(K3),FL1EXPDT+K1(K5)  PACK EXPIRATION DATE FROM 30800021
         CLC   DXCCW2+K5(K3),CVTDATE+K1  IS RETENTION EXPIRED           31000021
         BNH   OTA41600                 YES, GO CHECK SECURITY          31200021
*                   NOTIFY THE OPERATOR THAT RETENTION NOT EXPIRED      31400021
         SPACE 1                                                        31600021
OTA40700 EQU   *                                                        31800021
         SPACE                                                          32000021
         MVC   DXCCW5(K17),FL1ID        SAVE DSNAME FROM FL1ID          32200021
         MVC   DXCCW7+K1(K1),FL1FSEC    SAVE SECURITY INDICATOR         32400021
OTA40800 EQU   *                                                        32600021
         MVC   MCSFLAGS(K16),FLAG190P   MOVE IN BASIC MSG               32800021
         MVC   MSGVOLSR,UCBVOLI         VOLUME SERIAL NUMBER            33000021
         LA    RB,REPLY                 PLACE ADDRESS FOR REPLY         33200021
         ST    RB,REPLYLTH              INTO WTOR REPLY ADDRESS         33400021
         MVI   REPLYLTH,K1              LENGTH OF REPLY IS 1 CHAR       33600021
         LA    RB,DXECB                 PLACE ADDRESS OF ECB            33800021
         ST    RB,REPLYECB              INTO THE WTOR ECB ADDRESS       34000021
         MVI   DXECB,X'00'              CLEAR ECB COMPLTION BITS        34200021
         LA    R1,MSGLSTSZ              PTR TO MSG                      34400021
         O     R1,EXPMSGP               INDICATE MSG IS TO BE WTOR      34600021
         L     RB,MSGDESCP              PASS MCS CODES                  34800021
         USING CVT,RF                                                   35000021
         USING TCB,RWTGC                                                35200021
         STM   RPARC,RET,DXCCW8         SAVE REGS                       35400021
         L     RF,CVTPTR                GET PTR TO CVT                  35600021
         L     RF,0(RF)                 GET POINTER TO TCB ADDRESSES    35800021
         L     RWTGC,K4(RF)             GET TCB ADDRESS                 36000021
         L     RTIOT,K12(RWTGC)         SAVE TIOT POINTER               36200021
         LR    RC,R1                    SAVE THE MSG PTR                36400021
         XC    0(K2,RC),0(RC)           INIT LENGTH BYTES               36600021
         MVC   K14(K3,RC),UCBNAME       MOVE IN UNIT ADDRESS            36800021
         MVI   K17(RC),COMMA            DELIMIT UNIT WITH COMMA         37000021
         LA    R1,K23(R1)               UP PTR TO LAST CHAR OF SER      37200021
         BAL   RF,OTA41100              GO REMOVE BLANKS                37400021
         MVI   K1(R1),COMMA             DELIMIT VOL SET                 37600021
         MVI   K2(R1),BLANK             BLANK OUT                       37800021
         MVC   K3(K50,R1),K2(R1)        REMAINING BUFFER                38000021
         ST    RC,K76(RC)               STORE MSG POINTER               38200021
OTA40900 EQU   *                                                        38400021
         MVC   K2(K8,R1),0(RTIOT)       PUT THE JOBNAME IN MESSAGE      38600021
         LA    R1,K9(R1)                UPDATE POINTER                  38800021
         BAL   RF,OTA41100              REMOVE BLANKS                   39000021
         MVI   K1(R1),COMMA             DELIMIT WITH COMMA              39200021
         MVC   K2(K8,R1),K8(RTIOT)      PUT THE STEPNAME IN MESSAGE     39400021
         LA    R1,K9(R1)                UPDATE MSG PTR                  39600021
         BAL   RF,OTA41100              GO REMOVE BLANKS                39800021
OTA41000 EQU   *                                                        40000021
         LR    RD,R1                    DETERMINE LENGTH OF             40200021
         SR    RD,RC                    PRESENT MSG                     40400021
         LA    RD,K1(RD)                NUMBER OF CHARS IN MSG          40600021
         STC   RD,K1(RC)                SET UP MSG LENGTH               40800021
         B     OTA41200                 GO FINISH MSG                   41000021
OTA41100 EQU   *                                                        41200021
         CLI   0(R1),BLANK              FIND THE LAST CHAR              41400021
         BNE   0(RF)                    WHEN FOUND BRANCH               41600021
         BCT   R1,OTA41100              LOOK AGAIN                      41800021
OTA41200 EQU   *                                                        42000021
         LM    RPARC,RD,DXCCW8          RESTORE REGS                    42200021
         SR    RET,RET                  SET FOR RETURN                  42400021
         MVC   DXRETMOD,ID6Q6Q          RETURN ID TTR                   42600021
         LA    RF,ID6Q0R                WTO MODULE IDTTR                42800021
         B     OTA42400                 GO TO WTO                       43000021
OTA41300 EQU   *                        WAIT FOR REPLY                  43200021
         SPACE                                                          43400021
         IECRES WAIT                                                    43600021
         CLI   REPLY,CHARU              OPERATOR SAY TO USE             43800021
         BE    OTA41500                 BF IF YES TO USE TAPE           44000021
         SPACE                                                          44200021
         CLI   REPLY,CHARM              OPERATOR SAY TO REMOUNT         44400021
         BC    6,OTA40800               NO, GO REISSUE MESSAGE          44600021
OTA41400 EQU   *                                                        44800021
         CLC   DXVOLMT1,SCRATC9P        SCRATCH REQUEST         SA68416 44850000
         LA    R0,K13                   LOAD 713-04 ABEND CODE  SA68416 44900000
         BNE   OTA42750                 NO, BR TO PROB/DET      SA68416 44950000
         B     OTA42800                 GO REJECT VOLUME                45000021
OTA41500 EQU   *                                                        45200021
         MVC   FL1ID(K17),DXCCW5        REFRESH DSNAME FIELD            45400021
         MVC   FL1FSEC(K1),DXCCW7+K1    RESFRESH SECURITY INDCTR        45600021
         SPACE 1                                                        45800021
OTA41600 EQU   *                                                        46000021
         TM    JFCBMASK+K4,DS1WRSEC     SECURITY LOAD NEEDED            46200021
         BNO   OTA41700                 NO, BRANCH                      46400021
         LA    RET,K0                   ENTRY VALUE                     46600021
         SR    RUCB,RUCB                ZERO FOR SEQURITY LOAD          46800021
         LA    RF,ID6Q5T                SECURITY LOAD IDTTR             47000021
         B     OTA42400                 GO TO SECURITY LOAD             47200021
OTA41700 EQU   *                                                        47400021
         CLC   JFCBFLSQ,CONONE9P        FILE SEQ GREATER THAN ONE       47600021
         LA    RET,K0                   NO WAIT ENTRY                   47800021
         BH    OTA42300                 YES, BRANCH                     48000021
         EJECT                                                          48200021
*********************************************************************** 48400021
*                                                                     * 48600021
*                          FUNCTION PROLOG                            * 48800021
*                                                                     * 49000021
*********************************************************************** 49200021
*                                                                     * 49400021
* FUNCTION NAME -                                                     * 49600021
*    OPEN TAPE SL REWRITE VOLUME LABEL FUNCTION.                      * 49800021
*                                                                     * 50000021
* (STATUS) -                                                          * 50200021
*    NOT APPLICABLE                                                   * 50400021
*                                                                     * 50600021
* FUNCTION -                                                          * 50800021
*    READ AND REWRITE THE VOLUME LABEL.                               * 51000021
*    PUT OUT A MESSAGE INFORMING THE OPERATOR WHAT THE TAPE           * 51200021
*    ATTRIBUTES ARE.                                                  * 51400021
*                                                                     * 51600021
* ENTRY POINTS -                                                      * 51800021
*    ENTERED FROM THE FOLLOWING--                                     * 52000021
*    OPEN TAPE SL OUTPUT SECURITY FUNCTION OR                         * 52200021
*    OPEN TAPE SL DATE PROTECTION FUNCTION TO REWRITE THE VOLUME      * 52400021
*    LABEL.                                                           * 52600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 52800021
*                                                                     * 53000021
* INPUT -                                                             * 53200021
*    A POINTER TO EACH OF THE FOLLOWING--                             * 53400021
*       CURRENT PARAMETER LIST ENTRY.                                 * 53600021
*       DD ENTRY IN THE TIOT.                                         * 53800021
*       WTG TABLE.                                                    * 54000021
*       CURRENT WTG TABLE ENTRY.                                      * 54200021
*       DCB.                                                          * 54400021
*       OPEN WORK AREA.                                               * 54600021
*       RESIDENT ROUTINE.                                             * 54800021
*       UCB.                                                          * 55000021
*                                                                     * 55200021
* OUTPUT -                                                            * 55400021
*    THE FOLLOWING MESSAGE MAY BE ISSUED--                            * 55600021
*       IEC705I TAPE ON - TAPE ATTRIBUTES MESSAGE.                    * 55800021
*       IEC112I I/O ERROR - ERROR DURING READ OR WRITE OF VOLUME      * 56000021
*               LABEL.                                                * 56200021
*                                                                     * 56400021
* EXTERNAL REFERENCES -                                               * 56600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 56800021
*                                                                     * 57000021
* EXITS, NORMAL -                                                     * 57200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 57400021
*    OPEN TAPE SL HEADER LABEL WRITING FUNCTION.                      * 57600021
*    OPEN TAPE VOLUME MOUNTING FUNCTION TO REMOUNT.                   * 57800021
*                                                                     * 58000021
* EXITS, ERROR -                                                      * 58200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 58400021
*    EXIT WITH ONE OF THE FOLLOWING INTERNAL CODES--                  * 58600021
*       15 - 613 ABEND - I/O ERROR WRITING VOLUME LABEL.              * 58800021
*                                                                     * 59000021
* TABLES/WORK AREAS -                                                 * 59200021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 59400021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 59600021
*                                                                     * 59800021
* ATTRIBUTES -                                                        * 60000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 60200021
*                                                                     * 60400021
* CHARACTER CODE DEPENDENCY -                                         * 60600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 60800021
*                                                                     * 61000021
* NOTES -                                                             * 61200021
*    NOT APPLICABLE                                                   * 61400021
*                                                                     * 61600021
*********************************************************************** 61800021
         EJECT                                                          62000021
OTA41800 EQU   *                                                        62200021
*   SET UP MESSAGE TO TELL THE OPERATOR WHAT THE TAPE ATTRIBUTES        62400021
*   ARE FOR THE MOUNTED VOLUME.                                         62600021
         MVC   MSGIOSUP(K16),INFMSG     GET FIRST PART OF MESSAGE       62800021
         MVC   MSGUN+K6,UCBNAME         GET DEVICE                      63000021
         MVI   MSGUN+K9,COMMA           ADD COMMA                       63200021
         MVC   MSGVOLSR+K6,UCBVOLI      GET VOLUME SERIAL NUMBER        63400021
         MVC   MSGTEXT+K5(K19),ISETC    GET LAST PART OF MESSAGE        63600021
         TM    UCBSTAB,UCBBSTR          TEST FOR ANSI LABELS            63800021
         BNO   OTA41900                 NO, TEST FOR DENSITY            64000021
         MVC   MSGTEXT+K9(K2),ALTYP9P   YES INDICATE AL IN MSG          64200021
OTA41900 EQU   *                                                        64400021
         TM    DXDEBMOD,DEN800          MESSAGE HAS 800 BPI             64600021
         BO    OTA42100                 BRANCH IF 800 OK                64800021
OTA42000 EQU   *                        DENSITY NOT 800 BPI             65000021
         MVC   MSGTEXT+K13(K4),C6250    PUT 6250 BPI IN MSG             65050000
         TM    DXDEBMOD,DEN6250         CHECK IF 6250 BPI IS OK   99223 65100000
         BO    OTA42100                 YES BRANCH BACK           99223 65150000
         MVC   MSGTEXT+K13(K4),C1600    PUT 1600 BPI IN MESSAGE   99223 65200000
         TM    DXDEBMOD,DEN1600         CHECK IF 1600 BPI IS CORRECT    65400021
         BO    OTA42100                 YES BRANCH BACK                 65600021
         MVC   MSGTEXT+K13(K4),C556     PUT 556 BPI IN MESSAGE          65800021
         TM    DXDEBMOD,DCBDEN05        CHECK IF 556 BPI IS CORRECT     66000021
         BO    OTA42100                 YES BRANCH BACK                 66200021
         MVC   MSGTEXT+K13(K4),C200     PUT 200 BPI IN MESSAGE          66400021
OTA42100 EQU   *                        SET UP WTO                      66600021
         LA    R1,K45                   LENGTH OF THIS MESSAGE          66800021
         STH   R1,MSGLSTSZ              PUT LGTH IN MESSAGE AREA        67000021
         LA    R1,MSGLSTSZ              GET ADDRESS OF MESSAGE AREA     67200021
         MVC   MCSFLAGS,FLAG9P          TURN ON HIGH BIT FOR MCS        67400021
         WTO   MF=(E,(1))               WRITE TO OPERATOR               67600021
         SPACE 1                                                        67800021
*   REWRITE VOLUME LABEL                                                68000021
         MVC   DXCCW1,ACCW9P            MOVE IN BASIC CCW               68200021
         BAL   RB,OTA42500              GO REWIND TAPE                  68400021
         ST    RCORE,DXCCW1             GET ADDRESS OF LBL AREA         68600021
         MVI   DXCCW1,CCWRDTAP          ADD READ OP CODE                68800021
         BAL   RB,OTA42500              GO READ THE LABEL               69000021
         CLI   VOLLABI,CHARV            CHECK TAPE HAS VOL ID           69200021
         BE    OTA42200                 YES GO TO BUILD CHAN PROG       69400021
         CLI   VOLLABI,ASCIIV           CHECK TAPE FOR ANSI VOL ID      69600021
         BE    OTA42200                 YES GO TO BUILD CHAN PROG       69800021
         MVI   VOLLABI,BLANK            CLEAR                           70000021
         MVC   VOLLABI+1(K79),VOLLABI   LABEL AREA                      70200021
         MVC   VOLLABI(K4),AVOL19P      VOL LBL IDENTIFIER              70400021
         MVC   VOLSERNO,UCBVOLI         VOLUME SERIAL NUMBER            70600021
         MVI   VOLSEC,K0                SECURITY CODE                   70800021
         TM    JFCBLTYP,JFCBAL          ANSI LABEL SPECIFIED            71000021
         BZ    OTA42200                 NO GO TO REWIND                 71200021
         MVI   VOLSEC,BLANK             SECURITY CODE TO BLANK          71400021
         MVI   LABSTAND,K1              SET LABEL STANDARD LEVEL        71600021
         XLATE DXLBL,K80,TO=A           TRANSLATE LABEL DATA            71800021
OTA42200 EQU   *                        BUILD CHANNEL PROGRAM           72000021
         MVI   DXCCW1,CCWREW            GET REWIND COMMAND              72200021
         BAL   RB,OTA42500              GO ISSUE CHANNEL PROGRAM        72400021
         MVI   DXCCW1,CCWWRTAP          SET CCW TO WRITE                72600021
*        ISSUE I/O HERE AND WAIT FOR COMPLETION IN NEXT LOAD            72800021
         EXCP  DXIOB                                                    73000021
         LA    RET,K4                   WAIT ENTRY                      73200021
OTA42300 EQU   *                                                        73400021
         LA    RF,ID6Q6T                HEADER WRITTING MOD IDTTR       73600021
         SPACE 1                                                        73800021
OTA42400 EQU   *                                                        74000021
         IECRES XCTL,(RF),(RET)                                         74200021
*                   CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS           74400021
         SPACE 1                                                        74600021
*                        IT IS ASSUMED THAT ALL CONTROL BLOCKS          74800021
*                        HAVE ALREADY BEEN SET UP                       75000021
         SPACE 1                                                        75200021
*                             BAL  RA,PRHR50                            75400021
*                             RETURN                                    75600021
         SPACE 1                                                        75800021
OTA42500 EQU   *                                                        76000021
         EXCP  DXIOB                    ISSUE I/O OPERATION             76200021
         IECRES WAIT                                                    76400021
         TM    DXECB,ECBNOERR           IS THERE AN UNUSUAL CONDITION   76600021
         BCR   1,RB                     NO - RETURN TO CALLER           76800021
         TM    IOBSTAT0,CSWUNITX        CK FOR UNIT EXCEPTION           77000021
         BCR   1,RB                     YES - IGNORE FOR NOW            77200021
         SPACE                                                          77400021
         NI    DCBIFLGS,X'FF'-DCBIFPIO  TURN OFF ERROR FLAGS IN         77600021
*                                       DCB TO ISSUE REWIND             77800021
*                                       AND/OR UNLOAD COMMAND           78000021
         SPACE                                                          78200021
*  OPEN HAS FOUND AN UNCORRECTABLE I/O ERROR, BUT WILL ASK FOR NEW      78400021
*  VOLUME RATHER THAN ABEND WITH '613' UNLESS THIS IS NOT THE FIRST     78600021
*  DATA SET ON THE TAPE                                                 78800021
         SPACE                                                          79000021
OTA42600 EQU   *                        ASK FOR NEW VOLUME              79200021
         SPACE                                                          79400021
         SPACE                                                          79600021
         MVC   MSGIOSUP(K16),ERRMSG9P   GET FIRST PART OF MESSAGE       79800021
         MVC   MSGUN+K6,UCBNAME         GET DEVICE                      80000021
         MVI   MSGUN+K9,COMMA           PUT COMMA BTW DDD & SER         80200021
         MVC   MSGVOLSR+K6,UCBVOLI      VOLUME SERIAL NUMBER            80400021
         MVC   MSGTEXT+K5(K4),MCSRTDS9  PUT IN DESC AND ROUTING         80600021
         LA    R1,K30                   ADD LENGTH OF MESSAGE           80800021
         STH   R1,MSGLSTSZ              PUT IT IN MESSAGE AREA          81000021
         MVC   MCSFLAGS,FLAG9P          TURN ON HI BIT FOR MCS          81200021
         LA    R1,MSGLSTSZ              GET ADDR OF MESSAGE AREA        81400021
         SPACE                                                          81600021
         WTO   MF=(E,(1))               WRITE TO OPERATOR               81800021
         SPACE                                                          82000021
         CLC   JFCBVLSQ,CONONE9P        VOL SEQ GREATER THAN ONE        82200021
         BH    OTA42700                 YES, BRANCH                     82400021
         CLC   JFCBFLSQ,CONONE9P        IF THIS IS NOT 1ST DS           82600021
         BNH   OTA42800                 GO REJECT VOLUME                82800021
OTA42700 EQU   *                                                        83000021
         LA    R0,K15                   LOAD 613-10 ABEND CODE  SA68416 83050000
OTA42750 EQU   *                                                SA68416 83100000
         LA    RET,K4                   REJECT ENTRY MNT VERIFY         83200021
         DMABCOND (0),ID6Q0P,RETURN=ID6Q4F                      SA68416 83400000
OTA42800 EQU   *                        MUST ABEND                      83600021
         OI    JFCBMASK+K5,K8           SET REJECT SWITCH               83800021
         MVI   UCBDMCT,K0               ZERO DM COUNT                   84000021
         MVC   DXVOLMT1,SCRATC9P        SET FOR MOUNT SCRATCH           84200021
         MVI   JFCBVOLS,BLANK           BLANK JFCB VOL SER              84400021
         MVC   JFCBVOLS+K1(K5),JFCBVOLS  CLEAR REMAINDER OF VOL SER     84600021
         LA    RET,K20                  REMOUNT ENTRY TO MSG MOD        84800021
         LA    RF,ID6Q4G                MSG MODULE IDTTR                85000021
         B     OTA42400                 GO REJECT VOLUME                85200021
         SPACE 1                                                        85400021
*                   CONSTANTS                                           85600021
         SPACE 1                                                        85800021
FLAG190P DC    X'8000'                  MCSFLAG FOR 190P                86000021
ARETENP  DC    C'IEC107D E UUU,'        BASIC EXP MSG                   86200021
EXPMSGP  DC    X'C0000000'              MASK TO OR INDICATOR BIT        86400021
MSGDESCP DC    X'4000'                  MCS WTOR DESCRIPTOR CODE        86600021
MSGROUTP DC    X'A000'                  MCS ROUTING CODE                86800021
FLAG9P   DC    X'8000'                  MCS HI ORDER FLAG               87000021
ERRMSG9P DC    C'IEC112I I/O ERR '      BASIC ERROR MESSAGE             87200021
MCSRTDS9 DC    X'10002040'              RTE TO TP POOL & ERR CONS       87400021
SCRATC9P DC    C'SCRTCH'                NON-SPECIFIC VOLUME INDIC       87600021
ACCW9P   DC    X'0700000020000050'      BASIC CCW - REWIND              87800021
AVOL19P  DC    C'VOL1'                  VOLUME LABEL ID                 88000021
INFMSG   DC    C'IEC705I TAPE ON '      BASIC TAPE INFO MESSAGE         88200021
ISETC    DC    C' IS SL, 800 BPI'       COMMONEST INFO MESSAGE          88400021
MCSRT9P3 DC    X'10002000'              ROUTE TO TAPE POOL              88600021
*                                       MUST FOLLOW 'ISETC'             88800021
ALTYP9P  DC    C'AL'                    ANSI LABEL                      89000021
C6250    DC    C'6250'                  6250 BPI                  99223 89050000
C1600    DC    C'1600'                  1600 BPI RLW=GRT                89200021
C200     DC    C'200 '                  200 BPI                         89400021
C556     DC    C'556 '                  556 BPI                         89600021
CONONE9P DC    X'0001'                  CONSTANT OF ONE                 89800021
         SPACE                                                          90000021
XCTL6Q   XCTLTABL ID=(ID6Q4F,4F,ID6Q4G,4G,ID6Q5T,5T,ID6Q6T,6T,         X90200021
               ID6Q0P,0P,ID6Q6Q,6Q,ID6Q0R,0R)                           90400021
         IECDSECS CVT,TCB,TIOT,DCB,UCB,MAIN,WTG,EXPAND=YES              90600021
         IECEQU                                                         90800021
         END                                                            91000021
