         TITLE 'IFG0199E - OPENCLOSE/EOV PROBLEM DETERMINATION USER EXI*00100000
               T PROCESSING ROUTINE'                                    00200000
         COPY  LCGASMSW                                                 00200100
IFG0199E CSECT                                                          00500000
*********************************************************************** 00600000
*                                                                       00700000
         AIF   ('&LIB' EQ 'LIB1').LIB19E0                               00750000
*          VS2 RELEASE 01.6 DELETIONS                                   00752001
*0000                                                           YA00307 00754001
*0000                                                           YA00321 00754401
*                                                                       00756001
*          VS2 RELEASE 01 DELETIONS                                   * 00760000
*0000617500,617941,617981,617986,617990                          YM0899 00770000
*0000                                                            YM0869 00780000
*0000                                                            YM0871 00782000
*                                                                     * 00784000
*                                                                     * 00786002
*        VS1 RELEASE 02 DELETIONS                                     * 00788002
*                                                                     * 00788402
*0000                                                            XM0162 00788802
*0000                                                            XM0855 00788902
*                                                                     * 00789202
.LIB19E0 ANOP                                                           00790000
*                                                                       00800000
*          RELEASE 21 DELETIONS/CHANGES                                 00900000
*0000273000                                                      M0178  00920021
*                                                                M0012  00950021
*                                                                M0119  00960021
*                                                                M0646  00970021
*0000329000-335000,336000                                        M0964  00980021
*0000617000                                                      A51158 00990000
*          RELEASE 22 DELETIONS/CHANGES                                 01000000
*          RELEASE 23 DELETIONS/CHANGES                                 01100000
*          RELEASE 24 DELETIONS/CHANGES                                 01200000
*          RELEASE 25 DELETIONS/CHANGES                                 01300000
*                                                                       01400000
* STATUS CHANGE LEVEL 000                                               01500000
*                                                                       01600000
* FUNCTION -                                                            01700000
*    THIS MODULE IS THE FINAL ROUTINE OF ABEND INTERPRETATION           01800000
*    AND RECOVERY.  IT DETERMINES IF THE USER HAS SPECIFIED             01900000
*    A DCB EXIT LIST ADDRESS, AND IF HE HAS, IF ONE OF THE              02000000
*    ENTRIES IS AN ABEND EXIT (CODE X'11').                             02100000
*    IF NO ABEND EXIT IS SPECIFIED, THEN OPEN/CLOSE/EOV                 02200000
*    REGISTERS ARE RESTORED, AND ABEND IS ISSUED.  THE                  02300000
*    COMPLETION CODE IS THAT PASSED TO THE ROUTINE IN                   02400000
*    PDABCODE IN PDDSECT.  PDRETCODE, ALSO IN PDDSECT,                  02500000
*    CONTAINS A RETURN CODE WHICH IS PUT IN REGISTER 15                 02600000
*    PRIOR TO ISSUING THE ABEND.                                        02700000
*                                                                       02800000
*    IF AN ABEND EXIT IS SPECIFIED, THEN THE USER'S REGISTERS           02900000
*    2-13 ARE RESTORED, REGISTER 1 IS LOADED WITH A POINTER             03000000
*    TO A PARAMETER LIST (DESCRIBED IN THE FUNCTION PROLOGUE            03100000
*    FOLLOWING LABEL PDF04040), AND A SYNCH TO THE USER'S               03200000
*    EXIT ROUTINE IS ISSUED.  UPON RETURN FROM THE USER,                03300000
*    HIS OPTION (TO DELAY THE ABEND, IGNORE IT, OR ATTEMPT              03400000
*    TO RECOVER FROM IT) IS INTERROGATED, AND IF VALID FOR              03500000
*    THE PARTICULAR ABEND, IS PERFORMED.                                03600000
*                                                                       03700000
*    IF HE CHOOSES TO ATTEMPT RECOVERY, HE MAY SUPPLY                   03800000
*    NEW DATA WITH WHICH RECOVERY WILL BE ATTEMPTED.                    03900000
*    THIS DATA CONSISTS OF NEW VOLUME SERIAL NUMBER(S).                 04000000
*    THE JFCB AND/OR EXTENSION BLOCK(S) WILL BE UPDATED                 04100000
*    WITH THESE VOLUME(S) STARTING WITH THE CURRENT ONE.                04200000
*    THE JFCB EXTENSION BLOCKS WILL BE WRITTEN BACK, OPEN'S             04300000
*    REGISTERS WILL BE RESTORED, AND CONTROL WILL BE RETURNED           04400000
*    TO THE RESIDENT ROUTINE WITH THE ID AND TTR OF THE                 04500000
*    NEXT MODULE TAKEN FROM DXRETMOD (IN THE OPEN WORK AREA).           04600000
*    IF AN I/O ERR IS ENCOUNTERED EITHER READING OR WRITING             04700000
*    A JFCB EXTENSION BLOCK, MSG IEC901I IS ISSUED VIA                  04800000
*    WRITE-TO-PROGRAMMER. THE USER'S EXIT ROUTINE IS AGAIN              04900000
*    GIVEN CONTROL. THIS TIME, HOWEVER, HE MAY ONLY CHOOSE TO           05000000
*    IGNORE OR DELAY THE ABEND.                                         05100000
*                                                                       05200000
*    IF HE TO IGNORE THE ABEND, THE BUSY BIT IN                         05300000
*    DCBOFLGS IS SET TO ZERO, OPEN/CLOSE/EOV REGISTERS ARE              05400000
*    RESTORED, AND CONTROL IS RETURNED TO THE RESIDENT                  05500000
*    ROUTINE.  THE ID AND TTR OF THE RETURN MODULE IS MOVED             05600000
*    TO THE CURRENT WTG TABLE ENTRY BY THE FIRST LOAD OF                05700000
*    PROBLEM DETERMINATION (IFG0190P,IFG0200P, IFG0230P)                05800000
*                                                                       05900000
*    IF HE REQUESTS A DELAYED ABEND (INVALID FOR EOV), THE              06000000
*    PROBLEM DETERMINATION WKAREA IS FREED, THE ABEND CODE              06100000
*    AND RETURN CODE ARE MOVED TO THE OPEN/CLOSE WKAREA,                06200000
*    A BIT IS SET IN THE JFCB TO INDICATE A DELAYED                     06300000
*    ABEND, A CODE OF 4 IS PUT IN REG 14, AND CONTROL IS                06400000
*    RETURNED TO THE RESIDENT ROUTINE.                                  06500000
*                                                                       06600000
* ENTRY POINTS -                                                        06700000
*    IFG0199E VIA XCTL FROM IFG0199D                                    06800000
*    IFG0209E VIA XCTL FROM IFG0209D                                    06900000
*    IFG0239E VIA XCTL FROM IFG0239D                                    07000000
*    IFG0559E VIA XCTL FROM IFG0559D                                    07100000
*                                                                       07200000
* INPUT -                                                               07300000
*    R1 POINTS TO PROBLEM DETERMINATION WKAREA AS DESCRIBED             07400000
*       AT THE END OF THE LISTING                                       07500000
*    R2, AND R4-R10 ARE AS THEY WERE WHEN PROBLEM                       07600000
*       DETERMINATION WAS CALLED                                        07700000
*                                                                       07800000
* OUTPUT -                                                              07900000
*    WHEN RECOVERY IS ATTEMPTED, THE JFCB AND/OR EXTENSION              08000000
*    BLOCKS ARE UPDATED WITH NEW VOLUME SERIAL NUMBER(S)                08100000
*                                                                       08200000
* EXTERNAL REFERENCES - N/A                                             08300000
*                                                                       08400000
* EXITS, NORMAL - N/A                                                   08500000
*                                                                       08600000
* EXITS, ERROR -                                                        08700000
*    SVC 13 (ABEND) IS ISSUED IF THE USER DOES NOT PROVIDE              08800000
*    AN ABEND EXIT, IF HE REQUESTS AN INVALID OPTION FOR                08900000
*    THE PARTICULAR ABEND CODE, OR IF IN ATTEMPTING RECOVERY            09000000
*    AN I/O ERROR IS ENCOUNTERED.  THE ABEND CODE IS THAT               09100000
*    PASSED IN THE PROBLEM DETERMINATION WKAREA IN PDABCODE.            09200000
*    A RETURN CODE WILL BE PASSED IN REG15.  IT IS TAKEN FROM           09300000
*    PDCODE IN THE PROB DET WKAREA.  THE ABEND CODE AND                 09400000
*    RETURN CODE ARE SUPPLIED BY THE FIRST LOAD OF                      09500000
*    PROBLEM DETERMINATION                                              09600000
*                                                                       09700000
* TABLES/WORK AREAS -                                                   09800000
*    REFER TO THE DSECTS AT THE END OF THE LISTING.                     09900000
*                                                                       10000000
* ATTRIBUTES -                                                          10100000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVELEGED             10200000
*                                                                       10300000
* CHARACTER CODE DEPENDENCY                                             10400000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC                   10500000
*    CHARACTER CODE WAS USED FOR ASSEMBLY.  THE MODULE MUST             10600000
*    BE REASSEMBLED IF A DIFFERENT CHARACTER DET IS USED                10700000
*    FOR EXECUTION.                                                     10800000
*                                                                       10900000
* NOTES - N/A                                                           11000000
*                                                                       11100000
*********************************************************************** 11200000
         EJECT                                                          11300000
R0       EQU   0                        WORK/PARAMETER REG              11400000
R1       EQU   1                        WORK/PARAMETER REG              11500000
RDCB     EQU   2                        PTR TO DCB                      11600000
RBASE    EQU   3                        BASE REG                        11700000
RCORE    EQU   4                        PTR TO O/C/EOV WKAREA           11800000
RES      EQU   5                        PTR TO RESIDENT RTN             11900000
RWTG     EQU   6                        PTR TO WTG TABLE                12000000
RPARC    EQU   7                        PTR TO PARALIST CURRENT ENTRY   12100000
RWTGC    EQU   8                        PTR TO WTG TABLE CURRENT ENTRY  12200000
RTIOT    EQU   9                        TIOT ENTRY                      12300000
RUCB     EQU   10                       PTR TO UCB                      12400000
RB       EQU   11                       WORK/PARAMETER REG              12500000
RC       EQU   12                       WORK/PARAMETER REG              12600000
RD       EQU   13                       WORK/PARAMETER REG              12700000
RET      EQU   14                       WORK/PARAMETER REG              12800000
RF       EQU   15                       WORK/PARAMETER REG              12900000
ZERO     EQU   0                        WORK VALUE                      13000000
THREE    EQU   3                        WORK VALUE                      13100000
ONE      EQU   1                        WORK VALUE                      13200000
ORG      EQU   0                        WORK VALUE                      13300000
ABEXCOD  EQU   X'11'                    DCB ABEND EXIT CODE             13400000
LAST     EQU   X'80'                    BIT FOR LAST ENTRY IN LIST      13500000
FOUR     EQU   4                        WORK VALUE                      13600000
SVRBEXSA EQU   96                       OFFSET OF SVRB EXT S/A IN SVRB  13700000
SIXTY    EQU   60                       WORK VALUE                      13800000
CODLNG   EQU   1                        LNG OF PDCODE FIELD IN IECPDSCT 13900000
EIGHT    EQU   8                        WORK VALUE                      14000000
LEGALOPT EQU   X'0C'                    VALID BIT COMBINATIONS FOR USER 14100000
*                                       ON RETURN FROM ABEND EXIT       14200000
TWO      EQU   2                        WORK VALUE                      14300000
BLANK    EQU   C' '                     BLANK CHARACTER                 14400000
DSNLNG   EQU   44                       MAXIMUM LNG OF DSNAME           14500000
CHNGVOLS EQU   X'40'                    USER OPTION TO CHANGE VOLUMES   14600000
CCWLNG   EQU   8                        LNG OF A CCW                    14700000
TWENTY4  EQU   24                       WORK VALUE                      14800000
GOODIO   EQU   X'7F'                    ECB COMP CODE FOR SUCCESSFUL IO 14900000
ABCODLNG EQU   2                        LNG OF ABEND CODE               15000000
JFCABEND EQU   X'02'                    BIT INDICATING DELAYED ABEND    15100000
FULL     EQU   X'FF'                    ALL BITS IN BYTE SET TO ONE     15200000
DCBBUSY  EQU   X'01'                    DCBOFLGS BUSY BIT               15300000
DCBLOCK  EQU   X'02'                    DCBOFLGS LOCK BIT               15400000
DCBMEXCP EQU   X'80'                    EXCP DCB IN MACRF       SA59750 15450001
DCBMEXT  EQU   X'40'                    FOUNDATION EXTENSION    SA59750 15460001
*                                       EXISTS IN EXCP DCB      SA59750 15470001
OPEN     EQU   X'10'                    DCBOFLGS OPEN BIT               15500000
FIVE     EQU   5                        WORK VALUE                      15600000
SVRBSA   EQU   32                       OFFSET OF SVRB S/A IN SVRB      15700000
SIX      EQU   6                        WORK VALUE                      15800000
WTGPATH  EQU   30                       OFFSET OF WTGPATHS IN WTG TBL   15900000
TWELVE   EQU   12                       WORK VALUE                      16000000
RDCODE   EQU   X'06'                    READ COMMAND CODE               16100000
THIRTY2  EQU   32                       WORK VALUE                      16200000
WRTCODE  EQU   X'05'                    WRITE COMMAND CODE              16300000
FREEBUF  EQU   X'80'                    USER OPTION TO FREE BUFFER      16400000
TWENTY8  EQU   28                       WORK VALUE                      16500000
RECOVRY  EQU   X'08'                    RECOVERY OPTION VALID BIT       16600000
IGN      EQU   X'04'                    IGNORE OPTION VALID BIT         16700000
DEL      EQU   X'02'                    DELAY OPTION VALID BIT          16800000
RESXCTL  EQU   4                        BRANCH TABLE OFFSET TO XCTL     16900000
EOV      EQU   X'03'                    EOV ABEND CODES ARE X37  A51158 16902000
*                                       LEFT JUSTIFIED IN A      A51158 16904000
*                                       HALFWORD                 A51158 16904400
         AIF   ('&LIB' EQ 'LIB1').LIB19E1                               16906000
K24      EQU   24                       CONSTANT  24                    16912000
K4       EQU   4                        CONSTANT  4                     16918000
K1       EQU   1                        CONSTANT  1                     16924000
K8       EQU   8                        CONSTANT  8                     16930000
QMIJFCB  EQU   544                      LENGTH OF READ JECB MACRO WORK  16936000
JFCBEXT1 EQU   96                       LENGTH OF JFCB EXTENTION        16942000
JESWORK  EQU   256                      LENGTH OF JES WORK AREA         16948000
QMLIST   EQU   24                       LENGTH OF PARAMETER LIST        16954000
RQM      EQU   10                       BASE REGISTER FOR PARAMETER     16960000
RDRETSAV EQU   456                      SAVE AREA OFFSET FOR RD,RET     16966000
REGSAVE  EQU   464                      QMNGRIO REG SAVE AREA           16972000
*                                       DSECT                           16978000
.LIB19E1 ANOP                                                           16984000
*                                       IN RESIDENT RTN                 17000000
SUBPL250 EQU   250                      SUBPOOL 250 = 0 IN P/P STATE    17100000
         BALR  RBASE,R0                 ESTABLISH ADDRESSABILITY        17200000
         USING *,RBASE                                                  17300000
         USING PDDSECT,R1                                               17400000
         USING FORCORE,RCORE                                            17500000
         USING IHADCB,RDCB                                              17600000
         NC    PDABCODE,PDABCODE        IS THIS A REAL ABEND            17700000
         BZ    PDF04520                 NO, DO NOT GO TO USER EXIT RTN  17800000
PDF04010 EQU   *                                                        17900000
         TM    DCBMACRF,DCBMEXCP        EXCP DCB                SA59750 17950001
         BNO   PDF04015                 NO, FOUNDATION          SA59750 17960001
*                                       EXTENSION EXISTS        SA59750 17970001
         TM    DCBMACRF,DCBMEXT         DOES FOUNDATION         SA59750 17980001
*                                       EXTENSION EXIST         SA59750 17990001
         BNO   PDF04480                 NO, MUST ABEND          SA59750 17992001
PDF04015 EQU   *                                                SA59750 17994001
         L     RB,DCBEXLST              PTR TO DCB EXIT LIST            18000000
         LA    RB,ORG(RB)               CLEAR HI-ORDER BYTE             18100000
         LTR   RB,RB                    EXIT LIST ADDR SPECIFIED        18200000
         BZ    PDF04480                 NO, MUST ABEND                  18300000
PDF04020 CLI   ORG(RB),ABEXCOD          ABEND EXIT                      18400000
         BE    PDF04040                 YES                             18500000
         CLI   ORG(RB),ABEXCOD+LAST     ABEND EXIT                      18600000
         BE    PDF04040                 YES                             18700000
         TM    ORG(RB),LAST             LAST ENTRY IN LIST              18800000
         BO    PDF04480                 YES, MUST ABEND                 18900000
         LA    RB,FOUR(RB)              BUMP ENTRY PTR                  19000000
         B     PDF04020                 TRY AGAIN                       19100000
         EJECT                                                          19200000
*********************************************************************** 19300000
*                                                                     * 19400000
*                          FUNCTION PROLOG                            * 19500000
*                                                                     * 19600000
*********************************************************************** 19700000
*                                                                     * 19800000
* FUNCTION NAME - SYNCH TO USER ABEND EXIT                            * 19900000
*                                                                     * 20000000
* (STATUS) -                                                          * 20100000
*    NOT APPLICABLE                                                   * 20200000
*                                                                     * 20300000
* FUNCTION -                                                          * 20400000
*    THE FOLLOWING ROUTINE RESTORES THE USER'S REGS 2-13, LOADS A PTR   20500000
*    TO A PARAMETER LIST INTO REG1, AND SYNCHS TO THE USER'S DCB ABEND  20600000
*    EXIT.                                                              20700000
*    THE FORMAT OF THE PARAMETER LIST PASSED TO THE USER IS AS FOLLOWS  20800000
*       BYTE 0-1    ABEND CODE, 12 BITS LEFT JUSTIFIED                  20900000
*       BYTE 2      RETURN CODE                                         21000000
*       BYTE 3      OPTION MASK GIVING VALID OPTIONS FOR THE PARTICULAR 21100000
*                   ABEND.                                              21200000
*                   BITS 0-3  RESERVED                                  21300000
*                   BIT 4     RECOVERY PERMITTED FOR THIS ABEND         21400000
*                   BIT 5     IGNORE OPTION VALID                       21500000
*                   BIT 6     DELAY OPTION VALID                        21600000
*                   BIT 7     RESERVED                                  21700000
*       BYTE 4-7    ADDR OF DCB IN ERROR                                21800000
*       BYTE 12-15  ZEROES                                              21900000
*    THE USER IN HIS EXIT ROUTINE SHOULD EXAMINE THE OPTIONS VALID FOR  22000000
*    THE ABEND AND CHOOSE ONE OF THEM.                                  22100000
*                                                                     * 22200000
* ENTRY POINTS -                                                      * 22300000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 22400000
*                                                                     * 22500000
* INPUT -                                                             * 22600000
*    REG 11 POINTS TO THE ABEND EXIT ENTRY IN THE EXIT LIST             22700000
*                                                                     * 22800000
* OUTPUT -                                                            * 22900000
*    USER'S OPTION IS PLACED IN REGISTER 14                             23000000
*                                                                     * 23100000
* EXTERNAL REFERENCES -                                               * 23200000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 23300000
*                                                                     * 23400000
* EXITS, NORMAL -                                                     * 23500000
*    A BRANCH TO THE ROUTINE TO PROCESS ACCORDING TO OPTION SELECTED    23600000
*    BY THE USER, IF VALID.                                             23700000
*                                                                     * 23800000
* EXITS, ERROR -                                                      * 23900000
*    BRANCH TO ISSUE ABEND IF THE OPTION SELECTED IS INVALID            24000000
*                                                                     * 24100000
* TABLES/WORK AREAS -                                                 * 24200000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 24300000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 24400000
*                                                                     * 24500000
* ATTRIBUTES -                                                        * 24600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 24700000
*                                                                     * 24800000
* CHARACTER CODE DEPENDENCY -                                         * 24900000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 25000000
*                                                                     * 25100000
* NOTES - N/A                                                           25200000
*                                                                     * 25300000
*********************************************************************** 25400000
         EJECT                                                          25500000
PDF04040 EQU   *                                                        25600000
         L     RF,ORG(RB)               PTR TO EXIT RTN                 25700000
         L     RET,CVTPTR               PTR TO CVT                      25800000
         L     RET,CVTTCBP-CVT(RET)     PTR TO TCB DBLWD                25900000
         L     RET,FOUR(RET)            PTR TO MY TCB                   26000000
         L     RET,TCBRBP-TCB(RET)      PTR TO SVRB                     26100000
         ST    R1,SVRBEXSA+TWENTY4(RET) SAVE REG1 IN EXT S/A            26200000
         LA    R1,PDABCODE              PTR TO PARMLIST FOR USER        26300000
         DROP  R1                                                       26400000
         USING PDABCODE,R1                                              26500000
         MVC   PDCODE,PDABCODE+ONE      MOVE VALID OPTIONS TO PARALIST  26600000
         NI    PDCODE,RECOVRY+DEL+IGN   TURN OFF ANY OTHER BITS         26700000
         MVC   SVRBEXSA+TWENTY8(THREE,RET),PDABCODE                     26800000
*                                       SAVE ABEND CODE AND RETURN CODE 26900000
         ST    RBASE,SVRBEXSA+THIRTY2(RET)                              27000000
*                                       SAVE MY BASE REG                27100000
         LA    RCORE,ORG(RCORE)         ZERO HI-ORDER BYTE       M0178  27150021
         ST    RCORE,PDFORCOR           STORE WKAREA PTR FOR USER       27200000
         ST    RDCB,PDDCBPTR            STORE DCB ADDR IN PARM   M0178  27230021
*                                       LIST                     M0178  27260021
         NI    PDABCODE+1,FULL-RECOVRY-IGN-DEL-ONE               M0178  27290021
*                                       TURN OFF LOW-ORDER BITS IN      27320021
*                                       ABEND CODE                      27350021
         NI    DCBOFLGS,FULL-DCBLOCK    TURN OFF LOCK BIT BEFORE GOING  27400000
*                                       TO USER                         27500000
         LM    RDCB,RD,SVRBSA+EIGHT(RET)                                27600000
*                                       RESTORE USER REGS 2-13          27700000
         SYNCH (15)                     GO TO USER EXIT RTN             27800000
         L     RET,CVTPTR               PTR TO CVT                      27900000
         L     RET,CVTTCBP-CVT(RET)     TCB DBLWD                       28000000
         L     RET,FOUR(RET)            MY TCB                          28100000
         L     RF,TCBRBP-TCB(RET)       SVRB                            28200000
         L     RDCB,SVRBEXSA(RF)        RESTORE REG 2                   28300000
         OI    DCBOFLGS,DCBLOCK         SET LOCK BIT                    28400000
         LM    RCORE,RWTGC,SVRBEXSA+FOUR(RF)                            28500000
*                                       RESTORE REGS 4-8                28600000
         LM    RTIOT,RUCB,DXREG9        RESTORE REGS 9-10               28700000
         L     RBASE,SVRBEXSA+THIRTY2(RF)                               28800000
*                                       RESTORE MY BASE REG             28900000
         L     R1,SVRBEXSA+TWENTY4(RF)  PD WKAREA PTR                   29000000
         DROP  R1                                                       29100000
         USING PDDSECT,R1                                               29200000
         MVC   PDABCODE(THREE),SVRBEXSA+TWENTY8(RF)                     29300000
*                                       RESTORE ABEND CODE              29400000
         NI    PDCODE,LEGALOPT          INSURE OPTION SELECTED IS LEGAL 29500000
         SR    RET,RET                  ZERO WKREG                      29600000
         IC    RET,PDCODE               PUT OPTION CODE IN REG          29700000
         B     PDF04060(RET)            USE FOR BRANCH TABLE            29800000
PDF04060 EQU   *                                                        29900000
         B     PDF04480                 ABEND                           30000000
         B     PDF04440                 IGNORE ERR                      30100000
         B     PDF04420                 DELAY ERR                       30200000
PDF04080 EQU   *                        ATTEMPT RECOVERY                30300000
         TM    PDABCODE+ONE,RECOVRY     WAS RECOVERY POSSIBLE           30400000
         BNO   PDF04480                 NO, MUST ABEND                  30500000
         TM    JFCBMASK+FOUR,JFCABEND   HAS RECOVERY BEEN PERFORMED     30600000
*                                       ON THIS DCB PREVIOUSLY          30700000
         BO    PDF04480                 YES, DO NOT TRY AGAIN           30800000
*                                       WILL ABEND INSTEAD              30900000
         OI    JFCBMASK+FOUR,JFCABEND   SET RECOVERY BIT IN JFCB MASK   31000000
         L     RB,PDUSRAR               PTR TO USER BUFFER              31100000
         LA    RB,ORG(RB)               ZERO HI-ORDER BYTE              31200000
         LTR   RB,RB                    BUFFER ADDR SUPPLIED            31300000
         BZ    PDF04520                 NO, USE SAME DATA               31400000
*                                       IF USER HAS NOT SUPPLIED NEW    31500000
*                                       VOLIDS, THEN RECOVERY WILL      31600000
*                                       BE ATTEMPTED WITH ORIGINAL VOLS 31700000
         TM    TWO(RB),CHNGVOLS         VALID REQUEST                   31800000
         BZ    PDF04480                 NO, ABEND                       31900000
*                                                                       32000000
         LA    RD,FOUR(RB)              POINT TO 1ST DATA IN BUFFER     32100000
         SR    RC,RC                    ZERO WKREG                      32300000
         IC    RC,ORG(RD)               NO. OF VOLS TO BE CHANGED       32400000
         LTR   RC,RC                    IS NO VOLS TO BE CHANGED ZERO   32500000
         BZ    PDF04320                 YES, TEST IF BUFFER TO BE FREED 32600000
         LA    RD,ONE(RD)               UPDATE USER BUFFER PTR          32700000
         XC    DXVOLMT1,DXVOLMT1        ZERO CURRENT VOLID       M0119  32800021
         LH    RET,JFCBVLSQ             GET JFCBVLSQ             M0964  33600021
         CLI   JFCBVLSQ+ONE,ZERO        IS VOL SEQ NO. ZERO             33700000
         BNE   PDF04120                 NO                              33800000
         LA    RET,ONE(RET)             YES, ONE IMPLIED                33900000
*                                       THIS SHOULD LEAVE THE SEQUENCE  34000000
*                                       NUMBER FOR THE CURRENT VOLUME   34100000
PDF04120 EQU   *                                                        34200000
         CH    RET,CONH5                IS SEQ NO. GREATER THAN 5       34300000
         BNH   PDF04140                 NO START WITH MAIN JFCB         34400000
         SH    RET,CONH5                SUBTRACT NO. VOLS IN MAIN JFCB  34500000
         B     PDF04160                 GO READ JFCB EXTENSION          34600000
PDF04140 EQU   *                                                        34700000
         MVC   PDMSGLNG(TWO),CONH6      MOVE CONSTANT TO WKAREA         34800000
         BAL   RF,PDF04360              GO TO COMMON RTN TO DETERMINE   34900000
*                                       NO. VOLS TO BE MOVED INTO JFCB. 35000000
*                                       CALCULATE LNG OF MOVE AND       35100000
*                                       START POINT                     35200000
         LR    RF,R0                    R0 CONTAINS LNG OF FIELD TO BE  35300000
*                                       MOVED TO JFCBVOLS               35400000
         EX    RF,PDF04280              MOVE VOLS TO MAIN JFCB          35500000
         SR    RCORE,RET                RESTORE WKAREA PTR              35600000
*                                       RCORE IS BUMPED BY VALUE IN RET 35700000
*                                       BY SUBRTN AT PDF04360           35800000
         MVC   DXVOLMT1,ORG(RD)         MOVE CURRENT VOL TO DXVOLMT1    35900000
         LA    RET,ONE                  SET VOL SEQ NO. TO ONE          36000000
         LA    RD,TWO(RF,RD)            BUMP PTR TO USER BUFFER         36100000
         LTR   RC,RC                    HAVE ALL VOLS BEEN MOVED        36200000
         BZ    PDF04320                 YES, TEST IF BUFFER TO BE FREED 36300000
         AIF   ('&LIB' NE 'LIB1').LIB29E1                               36350000
PDF04160 EQU   *                                                        36400000
*                                       THE FOLLOWING ROUTINE BUILDS    36500000
*                                       THE CHANNEL PROGRAM TO READ     36600000
*                                       THE JFCB EXTENSION BLOCK        36700000
         XC    DXCCW1(CCWLNG*THREE),DXCCW1                              36800000
*                                       ZERO CCWS IN O/C/EOV WKAREA     36900000
         LA    RF,DXDAADDR+THREE        SID ADDR                        37000000
         ST    RF,DXCCW1                STORE IN 1ST CCW                37100000
         LA    RF,DXCCW1                TIC ADDR                        37200000
         ST    RF,DXCCW2                STORE IN 2ND CCW                37300000
         LA    RF,DXDSCB                DATA ADDR                       37400000
         ST    RF,DXCCW3                STORE IN 3RD CCW                37500000
         OC    DXCCW1(CCWLNG*THREE),CCWS                                37600000
*                                       PUT COMMAND CODES, LENGTHS,     37700000
*                                       AND FLAGS INTO CHANNEL PGM      37800000
         L     R0,JFCBEXAD-ONE          TTR OF EXTENSION BLOCK          37900000
         SLL   R0,EIGHT                 PUT IN HI-ORDER 3 BYTES OF REG  38000000
PDF04180 EQU   *                                                        38100000
         L     RF,CVTPTR                POINT TO CVT                    38200000
         L     RF,CVTJOB-CVT(RF)        PTR TO T.S. DCB                 38300000
         ST    RF,IOBDCBPT-ONE          STORE IN IOB                    38400000
         STM   RWTGC,RDCB,PDDSECT       STORE REGS PRIOR TO GOING TO    38500000
*                                       TTR CONVERT RTN                 38600000
         LR    RWTGC,R1                 SAVE PDWKAREA PTR               38700000
         L     R1,DCBDEBAD-IHADCB(RF)   ADDR OF DEB                     38800000
         LA    RDCB,DXDAADDR            ADDR OF RESULT FIELD            38900000
         L     RF,CVTPTR                POINT TO CVT                    39000000
         L     RF,CVTPCNVT-CVT(RF)      ADDR OF TTR CONVERT RTN         39100000
         BALR  RET,RF                   GO TO CONVERT RTN               39200000
         LM    RWTGC,RDCB,PDDSECT-PDDSECT(RWTGC)                        39300000
*                                       RESTORE REGS                    39400000
*                                       NOTE--RUCB IS BEING USED        39500000
*                                             AS A LINKAGE REG          39600000
         BAL   RUCB,PDF04400            GO TO READ EXTENSION BLOCK      39700000
*                                                                       39800000
*                                       IF VOL SEQ NO. IS GREATER THAN  39900000
*                                       15 THEN ANOTHER EXTENSION BLOCK 40000000
*                                       MUST BE READ                    40100000
*                                                                       40200000
.LIB29E1 ANOP                                                           40202000
         AIF   ('&LIB' EQ 'LIB1').LIB19E2                               40204000
PDF04160 EQU   *                                                        40206000
         LR    RTIOT,R1                 SAVE PTR TO WORK AREA           40208000
*                                                                       40210000
* CREATE PARAMETER LIST FOR READ/WRITE JFCB MACRO                       40212000
*                                                                       40214000
         LA    R0,QMIJFCB               SIZE OF QMI WORK AREA           40216000
         GETMAIN R,LV=(0)               GET CORE FOR JES WORKAREA       40218000
         LR    RQM,R1                   ESTABLISH BASE FOR QMIOLIST     40220000
         USING QMIOP,RQM                                                40222000
*                                                                       40224000
         LA    R1,K24(R1)               POINT TO JES WORK AREA          40226000
         ST    R1,QMIWRKAD              STORE ADDRESS OF WORK AREA      40228000
*                                                                       40230000
         L     RF,CVTPTR                POINT TO CVT                    40232000
         L     RF,CVTTCBP-CVT(RF)       POINT TO TCB POINTERS           40234000
         L     RF,K4(RF)                POINT TO CURRENT TCB            40236000
*                                                                       40238000
         ST    RF,QMITCBAD              PUT TCB ADDRESS INTO PARM LIST  40240000
*                                                                       40242000
         LA    R1,JESWORK(R1)           POINT TO JFCB EXT AREA          40244000
         ST    R1,QMIRECAD              PUT BUFFER ADDRESS IN PARM LIST 40246000
*                                                                       40248000
         L     R0,JFCBEXAD-K1           JFCB EXTENSION TTR              40250000
         SLL   R0,K8                    PUT IN HI-ORDER 3 BYTES         40252000
         XC    QMIRECL,QMIRECL          CLEAR LENGTH                    40254000
         MVI   QMIRECL+K1,JFCBLGTH      SETUP READ LENGTH               40256000
         MVI   QMIFLAGS,QMIOREAD        INDICATE READ OPERATION         40258000
*                                                                       40260000
PDF04165 EQU   *                                                        40262000
         ST    R0,QMIDSKAD              PUT TTR INTO PARM LIST          40264000
*                                                                       40266000
         STM   RD,RET,RDRETSAV(RQM)     SAVE REG 13,14 CONTENTS         40268000
         LR    R1,RQM                   POINT TO PARAMETER LIST         40270000
         LA    RD,REGSAVE(RQM)          POINT REG 13 TO QMNGRIO REG     40272000
*                                       SAVE AREA                       40274000
*                                                                       40276000
* ISSUE READ/WRITE JFCB MACRO                                           40278000
*                                                                       40280000
         QMNGRIO                                                        40282000
         LM    RD,RET,RDRETSAV(RQM)     RESTORE REGISTER SAVE AREA      40284000
*                                                                       40286000
         MVC   DXDSCB,QMLIST+JESWORK(RQM) MOVE JFCB EXTENSION TO OPEN   40288000
*                                        AREA                           40290000
         LTR   RF,RF                    GOOD READ/WRITE                 40292000
         BNZ   PDF04500                 NO PRINT MESSAGE AND ABEND      40294000
.LIB19E2 ANOP                                                           40296000
         CH    RET,CONH15               SEQ NO. GREATER THAN 15         40300000
         BNH   PDF04220                 NO, USE THIS EXTENSION          40400000
         SH    RET,CONH15               SUBTR NO. VOLS IN EXT BLK       40500000
PDF04200 EQU   *                                                        40600000
         L     R0,DXDSCB                PUT TTR OF NEXT EXT BLK IN REG  40700000
         AIF   ('&LIB' NE 'LIB1').LIB29E2                               40750000
         B     PDF04180                 SET UP FOR CONVERT RTN          40800000
.LIB29E2 ANOP                                                           40820000
         AIF   ('&LIB' EQ 'LIB1').LIB19E3                               40840000
         B     PDF04165                 SET UP TO READ ANOTHER EXT      40860000
.LIB19E3 ANOP                                                           40880000
PDF04220 EQU   *                                                        40900000
         MVC   PDMSGLNG(TWO),CONH16     MOVE CONSTANT TO WKAREA         41000000
         BAL   RF,PDF04360              GO TO COMMON RTN TO DETERMINE   41100000
*                                       NO. VOLS TO BE MOVED INTO JFCB  41200000
*                                       CALCULATE LNG OF MOVE AND       41300000
*                                       START POINT                     41400000
         LR    RF,R0                    R0 CONTAINS LNG OF FIELD TO BE  41500000
*                                       MOVED TO EXTENSION BLOCK        41600000
         EX    RF,PDF04300              MOVE VOLS TO EXTENSION BLOCK    41700000
         SR    RCORE,RET                RESTORE WKAREA PTR              41800000
*                                       RCORE IS BUMPED BY VALUE IN RET 41900000
*                                       BY SUBRTN AT PDF04360           42000000
         CLI   DXVOLMT1,ZERO            HAS CURRENT VOL BEEN UPDATED    42100000
         BNE   PDF04240                 YES, DON'T UPDATE AGAIN  M0119  42200021
*                                       IF DXVOLMT1 IS NOT X'00',       42300000
*                                       THEN IT HAS ALREADY BEEN        42400000
*                                       UPDATED BY THIS RECOVERY RTN    42500000
         MVC   DXVOLMT1,ORG(RD)         UPDATE CURRENT VOL              42600000
PDF04240 EQU   *                                                        42700000
         LA    RET,ONE                  SET VOL SEQ  TO ONE             42800000
         LA    RD,ONE(RF,RD)            BUMP PTR TO USER BUFFER         42900000
         AIF   ('&LIB' NE 'LIB1').LIB29E3                               42950000
         MVI   DXCCW3,WRTCODE           MOVE WRITE COM'D CODE TO CCW    43000000
*                                       THE SAME CHANNEL PGM CAN BE     43100000
*                                       USED TO WRITE BACK THE JFCB     43200000
*                                       EXTENSION BLOCK BY CHANGING THE 43300000
*                                       READ COM'D CODE TO A WRITE      43400000
*                                                                       43500000
*                                                                       43600000
*                                       NOTE--RUCB IS BEING USED        43700000
*                                             AS A LINKAGE REG          43800000
         BAL   RUCB,PDF04400            GO WRITE BACK JFCB EXTENSION    43900000
.LIB29E3 ANOP                                                           43906000
         AIF   ('&LIB' EQ 'LIB1').LIB19E4                               43912000
         MVC   QMLIST+JESWORK(JFCBEXT1,RQM),DXDSCB MOVE NEW VOLUME      43918000
*                                       NUMBERS TO MACRO WORK AREA      43924000
         MVI   QMIFLAGS,QMIOWRTE        SET PARM LIST TO INDICATE WRITE 43930000
         STM   RD,RET,RDRETSAV(RQM)     SAVE CONTENTS OF REG 13,14      43936000
         LA    RD,REGSAVE(RQM)          SETUP POINTER TO QMNGRIO REG    43942000
*                                       SAVE AREA                       43948000
         LR    R1,RQM                   POINTER TO QMNGRIO PARM LIST    43954000
         QMNGRIO                                                        43960000
         LM    RD,RET,RDRETSAV(RQM)     RESTORE REG. 13,14              43966000
         LR    R1,RTIOT                 RESTORE POINTER TO 9E WORK AREA 43972000
         LTR   RF,RF                    IO ERROR                        43978000
         BNZ   PDF04500                 BRANCH IF YES                   43984000
.LIB19E4 ANOP                                                           43990000
*                                                                       44000000
         LTR   RC,RC                    HAVE ALL VOLS BEEN MOVED        44100000
         BZ    PDF04320                 YES, TEST IF BUFFER TO BE FREED 44200000
         MVI   DXCCW3,RDCODE            RESTORE READ CODE               44300000
         B     PDF04200                 GO FILL NEXT EXTENSION BLK      44400000
PDF04280 MVC   JFCBVOLS(ZERO),ORG(RD)                                   44500000
PDF04300 MVC   DXDSCB+FOUR(ZERO),ORG(RD)                                44600000
PDF04320 EQU   *                                                        44700000
         TM    TWO(RB),FREEBUF          USER BUFFER TO BE FREED         44800000
         BNO   PDF04520                 NO, GO FREE P.D. WKAREA         44900000
         LR    RD,R1                    SAVE PD WKAREA PTR              45000000
         CLI   THREE(RB),ZERO           IS IT SUBPOOL ZERO              45100000
         BNE   PDF04327                 NO, USE SUBPOOL NO SUPPLIED     45200000
         LA    R0,SUBPL250              YES, EQUALS 250 IN SUP STATE    45300000
         B     PDF04334                 CONTINUE PROCESSING             45400000
PDF04327 EQU   *                                                        45500000
         IC    R0,THREE(RB)             SUBPOOL NO.                     45600000
PDF04334 EQU   *                                                        45700000
         LH    R1,ORG(RB)               BUFFER LNG                      45800000
         SLL   R1,EIGHT                 SHIFT LNG AND SUBPOOLNO. TO     45900000
         SLDL  R0,TWENTY4               PROPER POSITIONS IN REG 0       46000000
         LR    R1,RB                    BUFFER PTR                      46100000
         LA    RET,PDF04520             LOAD RET ADDR FOR FREEMAIN RTN  46200000
PDF04340 EQU   *                                                        46300000
         FREEMAIN R,LV=(0),A=(1)        FREE USER BUFFER                46400000
         LR    R1,RD                    RESTORE WKAREA PTR              46500000
         BR    RET                      RETURN TO SUPERVISOR STATE      46600000
         EJECT                                                          46700000
*********************************************************************** 46800000
*                                                                     * 46900000
*                          FUNCTION PROLOG                            * 47000000
*                                                                     * 47100000
*********************************************************************** 47200000
*                                                                     * 47300000
* FUNCTION NAME -                                                       47400000
*    CALCULATE NO. OF VOLUMES TO BE MOVED AND NO OF SLOTS               47500000
*    OPEN IN JFCB OR JFCB EXTENSION BLOCK                               47600000
*                                                                     * 47700000
* (STATUS) -                                                          * 47800000
*    NOT APPLICABLE                                                   * 47900000
*                                                                     * 48000000
* FUNCTION -                                                          * 48100000
*    THE NUMBER OF SLOTS TO BE FILLED IS CALCULATED BY SUBTRACTING      48200000
*    FROM THE VOLUME SEQUENCE NUMBER, 6(THE CAPACITY OF A JFCB + 1),    48300000
*    OR 16( THE CAPACITY OF A JFCB EXTENSION BLOCK + 1), AND MAKING     48400000
*    THE RESULT POSITIVE.  THIS IS THE NUMBER OF SLOTS AVAILABLE IN     48500000
*    THE JFCB OR CURRENT EXTENSION BLOCK.  THEN THIS NUMBER IS          48600000
*    SUBTRACTED FROM THE NUMBER OF VOLS TO BE CHANGED.  IF THIS RESULT  48700000
*    IS POSITIVE, THEN THERE ARE MORE SLOTS AVAILABLE THAN THERE ARE    48800000
*    VOLS TO BE CHANGED, AND THE NUMBER OF SLOTS IS SET EQUAL TO THE    48900000
*    NUMBER OF VOLS TO BE CHANGED.  IF THE RESULT IS NEGATIVE, THE      49000000
*    NUMBER OF SLOTS OPEN IS USED TO CALCULATE THE LENGTH OF THE FIELD  49100000
*    TO BE MOVED.                                                       49200000
*                                                                       49300000
*    THE VALUE CALCULATED IS MULTIPLIED BY 6, AND 1 IS SUBTRACTED FROM  49400000
*    IT.  THIS IS THE LENGTH OF THE FIELD TO BE MOVED TO THE JFCB OR    49500000
*    EXTENSION.                                                         49600000
*                                                                       49700000
*    THE VOLUME SEQUENCE NUMBER IS RESTORED IN A REGISTER, AND          49800000
*    MULTIPLIED BY 6.  THIS IS USED AS AN INDEX INTO THE JFCB OR        49900000
*    EXTENSION BLOCK.  IT IS ADDED TO RCORE, THE O/C/EOV WKAREA PTR SO  50000000
*    THAT REFERRING TO THE FIELDS BY SYMBOLIC NAME WILL AUTOMATICALLY   50100000
*    GET THE PROPER LOCATION.  THE PTR WILL BE RESTORED BY THE CALLING  50200000
*    RTN.                                                               50300000
*                                                                     * 50400000
* ENTRY POINTS -                                                      * 50500000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 50600000
*                                                                     * 50700000
* INPUT -                                                             * 50800000
*    PDMSGLNG CONTAINS A HALFWORD CONSTANT OF 6(JFCB) OR 16(JFCB        50900000
*       EXTENSION BLOCK.                                                51000000
*    REG 14 CONTAINS THE VOL SEQ NO. OF FIRST VOL TO BE CHANGED         51100000
*    REG 12 CONTAINS THE NUMBER OF VOLS TO BE CHANGED                   51200000
*    RCORE POINTS TO THE O/C/EOV WKAREA                                 51300000
*                                                                     * 51400000
* OUTPUT -                                                            * 51500000
*    REG 0 CONTAINS THE LNG OF THE FIELD TO BE MOVED TO THE JFCB        51600000
*       OR EXTENSION BLOCK                                              51700000
*    RCORE IS UPDATED BY AN INDEX FACTOR DESCRIBED UNDER FUNCTION       51800000
*                                                                     * 51900000
* EXTERNAL REFERENCES -                                               * 52000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 52100000
*                                                                     * 52200000
* EXITS, NORMAL -                                                     * 52300000
*    RETURN TO CALLER VIA REG 15                                        52400000
*                                                                     * 52500000
* EXITS, ERROR -                                                      * 52600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 52700000
*                                                                     * 52800000
* TABLES/WORK AREAS -                                                 * 52900000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 53000000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 53100000
*                                                                     * 53200000
* ATTRIBUTES -                                                        * 53300000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 53400000
*                                                                     * 53500000
* CHARACTER CODE DEPENDENCY -                                         * 53600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 53700000
*                                                                     * 53800000
* NOTES -                                                             * 53900000
*                                                                     * 54000000
*********************************************************************** 54100000
         EJECT                                                          54200000
PDF04360 EQU   *                                                        54300000
         SH    RET,PDMSGLNG             SUBTR CONST (6 FOR MAIN JFCB,   54400000
         LPR   RET,RET                  16 FOR EXTENSION) AND FIND      54500000
*                                       THAT CONSTANT'S COMPLEMENT OF   54600000
*                                       VOL SEQ NO.  THAT WILL BE THE   54700000
*                                       NO. OF SLOTS OPEN IN THE JFCB   54800000
*                                       OR EXTENSION BLOCK.             54900000
         SR    RC,RET                   SUBTR NO. SLOTS OPEN FROM NO.   55000000
*                                       VOLS TO BE CHANGED              55100000
         LR    R0,RET                   NO. SLOTS TO BE FILLED          55200000
         BNM   PDF04380                 IF RESULT IS NOT NEGATIVE       55300000
*                                       FIND START OF MOVE              55400000
         AR    RET,RC                   IF NEGATIVE, THERE ARE MORE     55500000
*                                       SLOTS THAN VOLS. REDUCE NO.     55600000
*                                       SLOTS TO EQUAL NO. VOLS.        55700000
*                                       COUNT EQUAL TO ZERO.            55800000
         LR    R0,RET                   NO. SLOTS TO BE FILLED          55900000
         SR    RET,RC                   RESTORE COMPLEMENT OF VOL SEQ   56000000
*                                       NUMBER                          56100000
         SR    RC,RC                    VOL COUNT = 0                   56200000
PDF04380 EQU   *                                                        56300000
         MH    R0,CONH6                 MULTIPLY BY VOLID LNG           56400000
         BCTR  R0,ZERO                  SUBTR ONE FOR EX                56500000
         SH    RET,PDMSGLNG             RESTORE VOLUME                  56600000
         LPR   RET,RET                  SEQUENCE NUMBER                 56700000
         BCTR  RET,ZERO                 SUBTR ONE FOR USE AS INDEX      56800000
         MH    RET,CONH6                MULTIPLY BY VOLID LNG           56900000
         AR    RCORE,RET                ADD TO WKAREA PTR FOR USE       57000000
*                                       AS INDEX                        57100000
         BR    RF                       RETURN TO CALLER                57200000
         AIF   ('&LIB' NE 'LIB1').LIB29E4                               57250000
         EJECT                                                          57300000
PDF04400 EQU   *                                                        57400000
*                                       RTIOT IS USED TO SAVE           57500000
*                                       WKAREA PTR                      57600000
         LR    RTIOT,R1                 SAVE PTR TO PD WKAREA           57700000
         EXCP  DXIOB                    ISSUE I/O TO JFCB EXT BLOCK     57800000
         WAIT  ECB=DXECB                WAIT ON I/O                     57900000
         LR    R1,RTIOT                 RESTORE WKAREA PTR              58000000
         L     RTIOT,DXREG9             RESTORE RTIOT                   58100000
         TM    DXECB,GOODIO             I/O SUCCESSFUL                  58200000
         BNO   PDF04500                 NO                              58300000
*                                       NOTE--RUCB IS BEING USED        58400000
*                                             AS A LINKAGE REG          58500000
         BR    RUCB                     YES, RETURN TO CALLER           58600000
.LIB29E4 ANOP                                                           58650000
*                                                                       58700000
PDF04420 EQU   *                                                        58800000
         TM    PDABCODE+ONE,DEL         IS DELAY VALID FOR THIS ABEND   58900000
         BNO   PDF04480                 NO, ABEND                       59000000
         MVC   DXABCODE(ABCODLNG),PDABCODE                              59100000
*                                       MOVE ABEND CODE TO WKAREA       59200000
         MVC   DXRETCOD,PDRETCOD        MOVE RETURN CODE TO WKAREA      59300000
         L     R0,BUFLENSP              LNG OF P. D. WKAREA             59400000
         BAL   RET,PDF04340             GO FREE PD WKAREA               59500000
         OI    JFCBMASK+FOUR,JFCABEND   INDICATE A DELAYED ABEND EXISTS 59600000
         NI    DCBOFLGS,FULL-DCBBUSY    TURN OFF BUSY BIT               59700000
*                                       THE COMBINATION OF JFCABEND BIT 59800000
*                                       ON AND DCBOFLGS BUSY BIT OFF    59900000
*                                       INDICATES A DELAYED ABEND       60000000
         LA    RET,FOUR                 LOAD BR TABLE ERR CODE          60100000
         B     PDF04540                 GETOUT                          60200000
PDF04440 EQU   *                                                        60300000
         TM    PDABCODE+ONE,IGN         CAN THIS ERROR BE IGNORED       60400000
         BNO   PDF04480                 NO, ABEND                       60500000
PDF04460 EQU   *                                                        60600000
         L     R0,BUFLENSP              LNG OF P. D. WKAREA             60700000
         BAL   RET,PDF04340             GO FREE PD WKAREA               60800000
         NI    DCBOFLGS,FULL-DCBBUSY    TURN OFF BUSY BIT               60900000
         LA    RET,FOUR                 LOAD BR TABLE ERR CODE          61000021
         B     PDF04540                 GET OUT                         61100000
PDF04480 EQU   *                                                        61200000
         L     RF,CVTPTR                POINT TO CVT                    61300000
         L     RF,CVTTCBP-CVT(RF)       TCB DOUBLE WORDS                61400000
         L     RF,FOUR(RF)              POINT TO CURRENT TCB            61500000
         TM    TCBFLGS1-TCB(RF),TCBFA   IS ABEND IN CONTROL             61600000
         AIF   ('&LIB' NE 'LIB1').LIB29E5                               61650000
         BNO   PDF04490                 NO, ISSUE ABEND          A51158 61750000
.LIB29E5 ANOP                                                           61751600
         AIF   ('&LIB' EQ 'LIB1').LIB19E5                               61752000
         BNO   PDF04485                 NO,ISSUE ABEND           YM0899 61753600
.LIB19E5 ANOP                                                           61755600
         TM    PDABCODE,EOV             EOV CALLED BY ABEND      A51158 61760000
         BNO   PDF04460                 NO, IGNORE ERROR         A51158 61760500
*                                       IF EOV IGNORES ERROR     A51158 61760900
*                                       WHEN CALLED BY ABEND, IT A51158 61761300
*                                       MAY CAUSE ABEND TO PROG  A51158 61763400
*                                       PROG CHECK BECAUSE ABEND A51158 61766400
*                                       DOESN'T EXPECT TO GET    A51158 61766800
*                                       CONTROL BACK WITH A      A51158 61767200
*                                       CLOSED DCB               A51158 61767600
         AIF   ('&LIB' EQ 'LIB1').LIB19E6                               61767900
PDF04485 EQU   *                                                 YM0899 61769900
         USING WTG,RWTG                                          Y01018 61772400
         L     RTIOT,CVTPTR             GET CVT ADDR             Y01018 61775100
         L     RF,CVTTCBP-CVT(,RTIOT)   GET TCB DOUBLE WORDS    YA00307 61777601
         L     RF,FOUR(RF)              POINT TO CURRENT TCB    YA00307 61779601
         USING CVT,RTIOT                DEFINE CVT BASE          Y01018 61780100
         USING TCB,RF                   DEFINE TCB BASE          Y01018 61790100
         TM    CVTDCB,CVT4MS1           MVT SYSTEM?              Y01018 61792100
         BNO   PDF04487                 NO, BR TO IGNORE DEQ     YM0899 61794100
         TM    TCBTSFLG,TCBTSTSK        TSO TASK?                Y01018 61796100
         BNO   PDF04487                 NO, BR TO IGNORE DEQ     YM0899 61798100
         TM    WTGPATHS+K1,WTGTSENQ     WAS ENQ SUCCESSFUL?      Y01018 61798500
         BZ    PDF04487                 NO, BR TO IGNORE DEQ     YM0899 61798600
         MVC   WTG(PDF0467L),PDF0460K                            Y01018 61798700
         LR    RB,R1                    SAV REG1 BEFORE DEQ     YA00321 61806201
         DEQ   (WTG+PDF0465K-PDF0460K,                           Y01018*61814201
               WTG+PDF0466K-PDF0460K),MF=(E,WTG)                 Y01018 61821701
         LR    R1,RB                    RESTORE REG1 AFTER DEQ  YA00321 61823701
PDF04487 EQU   *                                                 YM0899 61829201
         DROP  RTIOT                                             Y01018 61836701
         DROP  RF                                                Y01018 61844201
.LIB19E6 ANOP                                                           61851701
PDF04490 EQU   *                                                 A51158 61859201
         LM    RTIOT,RET,DXREG9         LOAD CALLER REGS 9-14           61866700
         SR    RF,RF                    ZERO RETURN CODE REG            61900000
         IC    RF,PDRETCOD              RETURN CODE IN REG 15           62000000
         LH    R1,PDABCODE              ABEND CODE IN REG 1             62100000
         SRL   R1,FOUR                  ZERO MASK BITS                  62200000
         SLL   R1,TWELVE                SHIFT FOR SYSTEM ABEND          62300000
         LA    R1,ORG(R1)               CLEAR HI-ORDER BYTE      M0646  62350021
         ABEND (1),DUMP                                                 62400000
PDF04500 EQU   *                                                        62500000
         AIF   ('&LIB' EQ 'LIB1').LIB19E7                               62520000
         LR    R1,RTIOT                 RESTORE WORK AREA POINTER       62540000
         L     RTIOT,DXREG9             RESTORE TIOT POINTER            62560000
.LIB19E7 ANOP                                                           62580000
         MVC   PDMSGLNG(ENDMSG-RECERMSG+FOUR),RECERMSG                  62600000
*                                       MOVE ERR MSG TO WKAREA          62700000
         LR    RUCB,R1                  SAVE PD WKAREA PTR              62800000
         WTO   MF=(E,(1))               ISSUE WRITE TO PROG             62900000
         LR    R1,RUCB                  RESTORE PD WKAREA PTR           63000000
         NI    PDABCODE+ONE,FULL-RECOVRY                                63100000
*                                       DISALLOW RECOVERY WHEN          63200000
*                                       RECYCLING TO USER               63300000
         B     PDF04010                 GO BACK TO USER EXIT            63400000
PDF04520 EQU   *                                                        63500000
         L     R0,BUFLENSP              LNG OF P. D. WKAREA             63600000
         BAL   RET,PDF04340             GO FREE PD WKAREA               63700000
         MVC   ORG(FIVE,RWTGC),DXRETMOD MOVE RETURN MOD ID TO WTG TBL   63800000
         L     RET,DXREGE               RESTORE REG 14                  63900000
PDF04540 EQU   *                                                        64000000
         AIF   ('&LIB' EQ 'LIB1').LIB19EX                               64050002
         XC    TWO(THREE,RWTGC),TWO(RWTGC)                       XM0162 64060002
*                                       CLEAR TTR TO ENABLE      XM0162 64070002
*                                       XCTLING BY NAME          XM0162 64080002
.LIB19EX ANOP                                                           64090002
         LA    RF,DXDCB                 PTR TO WKAREA DCB               64100000
         ST    RF,IOBDCBPT-ONE          RESTORE IOB DCB PTR             64200000
*                                       IN CASE IT WAS MODIFIED         64300000
*                                       TRYING TO RECOVER               64400000
         LM    RTIOT,RD,DXREG9          RESTORE REGS 9-13               64500000
         LM    R0,R1,DXREG0             RESTORE REGS 0-1                64600000
         IECRES XCTL                                                    64700000
         DS    0F                                                       64800000
         AIF   ('&LIB' NE 'LIB1').LIB19EG                               64850002
BUFLENSP DC    AL1(250)                 SUBPOOL NO.                     64900000
         DC    AL3(128)                 LENGTH OF PD WKAREA             65000000
.LIB19EG ANOP                                                           65050002
         AIF   ('&LIB' EQ 'LIB1').LIB29EG                               65060002
BUFLENSP DC    AL1(250)                 SUBPOOL NO.              XM0855 65062002
         DC    AL3(176)                 LENGTH OF PD WKAREA      XM0855 65064002
.LIB29EG ANOP                                                           65070002
CONH5    DC    H'5'                     CONST USED IN RECOVERY          65100000
CONH6    DC    H'6'                     CONST USED IN RECOVERY          65200000
CONH15   DC    H'15'                    CONST USED IN RECOVERY          65300000
CONH16   DC    H'16'                    CONST USED IN RECOVERY          65400000
CCWS     DC    X'3100000040000005'      SID, COM'D CHN, LNG             65500000
         DC    X'0800000000000000'      TIC                             65600000
         DC    X'060000002000005E'      RD DATA, SILI, LNG              65700000
         AIF   ('&LIB' EQ 'LIB1').LIB19E8                               65750000
PDF0460K DEQ   (,,4,STEP),RET=HAVE,MF=L                          Y01018 65760000
PDF0465K DC    CL8'SYSTIOT'             QNAME FOR DEQ            Y01018 65770000
PDF0466K DC    C'TIOT'                  RNAME FOR DEQ            Y01018 65780000
PDF0467L EQU   *-PDF0460K                                        Y01018 65790000
.LIB19E8 ANOP                                                           65792000
RECERMSG DC    AL2(ENDMSG-*)            LNG OF ERROR MSG                65800000
         DC    X'8000'                  MCS FLAGS                       65900000
         DC    C'IEC901I UNABLE TO RECOVER DUE TO I/O ERR ON JOBQUEUE'  66000000
*                                       MSG ISSUED ON ERR IN RECOVERY   66100000
ENDMSG   EQU   *                                                        66200000
         DC    X'04000020'              ROUT, DESC CODES                66300000
         AIF   ('&LIB' NE 'LIB1').LIB29E6                               66350000
         XCTLTABL SVC=019,LENGTH=1024                                   66400000
.LIB29E6 ANOP                                                           66450000
         AIF  ('&LIB' EQ 'LIB1').LIB19E9                                66452000
         XCTLTABL SVC=019,LENGTH=2048,PATCH=100                  YM0871 66460000
.LIB19E9 ANOP                                                           66470000
         IECPDSCT                                                       66500000
         AIF   ('&LIB' EQ 'LIB1').LIB19EA                               66520000
         IEFQMIOP                                                       66540000
         IEFJESCT                                                       66560000
.LIB19EA ANOP                                                           66580000
         IECDSECS MAIN,TCB,CVT,DCB,TIOT,WTG,EXPAND=YES                  66600000
         END                                                            66700000
