         TITLE 'IFG019RA--OPEN/CLOSE/END OF VOLUME RESIDENT ROUTINE'    00200000
         COPY  LCGASMSW                                                 00250000
IFG019RA CSECT                                                          00400000
*********************************************************************** 00500000
*                                                                     * 00600000
*                                                                     * 00700000
*          RELEASE 25 DELETIONS/CHANGES                               * 00800000
*          RELEASE 24 DELETIONS/CHANGES                               * 00900000
*          RELEASE 23 DELETIONS/CHANGES                               * 01000000
*          RELEASE 21.6 DELETIONS/CHANGES                               01100000
*                                                                       01150000
*0000                                                            SM4377 01160000
*          RELEASE 21 DELETIONS/CHANGES                               * 01200000
*0000023000-025000,080000-083000,117000                          S21940 01250021
*                                                                     * 01300000
* STATUS CHANGE LEVEL 000                                             * 01400000
*                                                                     * 01500000
* FUNCTION -                                                          * 01600000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 01700000
*    OPEN/CLOSE/EOV RESIDENT ROUTINE FUNCTION.                        * 01800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 01900000
*                                                                     * 02000000
* ENTRY POINTS -                                                      * 02100000
*         IFG019RA                                                    * 02200000
*                                                                     * 02600000
* INPUT -                                                             * 02700000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02800000
*                                                                     * 02900000
* OUTPUT -                                                            * 03000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03100000
*                                                                     * 03200000
* EXTERNAL REFERENCES -                                               * 03300000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03400000
*                                                                     * 03500000
* EXITS, NORMAL -                                                     * 03600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03700000
*                                                                     * 03800000
* EXITS, ERROR -                                                      * 03900000
*    NONE                                                             * 04000000
*                                                                     * 04100000
* TABLES/WORK AREAS -                                                 * 04200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04300000
*                                                                     * 04400000
* ATTRIBUTES -                                                        * 04500000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED,          * 04600000
*    ONLY LOADABLE                                                    * 04700000
*                                                                     * 04800000
* CHARACTER CODE DEPENDENCY -                                         * 04900000
*    CLASS TWO CHARACTER CODE DEPENDENCY - THE EBCIDIC CHARACTER SET  * 05000000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE MODIFIED IF A         * 05100000
*    DIFFERENT CHARACTER SET IS TO BE USED DURING EXECUTION.  THE     * 05200000
*    CHARACTER SET CHARACTERISTICS THAT THIS MODULE IS DEPENDENT      * 05300000
*    UPON ARE -                                                       * 05400000
*       1. X'FF' IS NOT AN ALPHANUMERIC.                              * 05500000
*       2. X'00' IS NOT AN ALPHANUMERIC.                              * 05600000
*       3. A-Z,0-9 ARE IN COLLATING SEQUENCE, IN THAT ORDER.          * 05700000
*    THESE CHARACTERISTICS ARE USED IN DETERMINING WHICH MODULE IS    * 05800000
*    TO BE XCTLED TO, AND APPLY TO THE TWO BYTE MODULE ID.  THE       * 05900000
*    MODULE ID IS THE LAST TWO CHARACTERS OF THE MODULE NAME, FOR     * 06000000
*    MODULES THAT ARE PART OF OPEN/CLOSE/EOV.                         * 06100000
*                                                                     * 06200000
* NOTES -                                                             * 06300000
*    A CHARACTER CODE DEPENDENCY FLAG OF 'CC' APPEARS IN COLUMNS 70,  * 06400000
*    71 OF ALL STATEMENTS DEPENDENT ON THE CHARACTER CODE.            * 06500000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06600000
*                                                                     * 06700000
*********************************************************************** 06800000
         EJECT                                                          06900000
*********************************************************************** 07000000
*                                                                     * 07100000
*                             FUNCTION PROLOG                         * 07200000
*                                                                     * 07300000
*********************************************************************** 07400000
*                                                                     * 07500000
* FUNCTION NAME -                                                     * 07600000
*    OPEN/CLOSE/EOV RESIDENT ROUTINE FUNCTION                         * 07700000
*                                                                     * 07800000
* FUNCTION -                                                          * 07900000
*    THIS MODULE IS RESIDENT IN THE NUCLEUS, LOCATED BY A POINTER     * 08000021
*    IN THE CVT.  OPEN, CLOSE, AND END OF VOLUME USE THIS ROUTINE.    * 08100021
*                                                                     * 08400000
*    THE RESIDENT ROUTINE PERFORMS THE FUNCTION OF AN INPUT/OUTPUT    * 08500000
*    SUPERVISOR FOR THE COMPONENT,  ESSENTIALLY ALLOWING THE          * 08600000
*    COMPONENT TO PROCESS PARALLEL DCB'S IN A SERIAL MANNER WITHIN    * 08700000
*    PARTICULAR MODULES.  THE RESIDENT ROUTINE CONTROLS PROCESSING    * 08800000
*    BY ISSUING ALL WAIT'S, XCTL'S, AND SWITCHING DCB'S TO BE         * 08900000
*    PROCESSED BY MODIFYING REGISTERS.                                * 09000000
*                                                                     * 09100000
*    A MODULE DESIRING TO ISSUE A WAIT FOR A DCB BRANCHES TO THE      * 09200000
*    RESIDENT ROUTINE FOR THIS PURPOSE.  THE RESIDENT ROUTINE THEN    * 09300000
*    RETURNS TO THE MODULE WITH ANOTHER DCB IMMEDIATELY, RATHER       * 09400000
*    THAN ISSUING A WAIT.  WHEN ALL DCB'S HAVE A WAIT PENDING,        * 09500000
*    THE RESIDENT ROUTINE ISSUES A MULTIPLE WAIT, RETURNING TO THE    * 09600000
*    MODULE WITH THE DCB WHOSE ECB WAS FIRST POSTED.  THIS ALLOWS     * 09700000
*    OVERLAP OF I/O BETWEEN DCB'S IN THE MODULE.                      * 09800000
*                                                                     * 09900000
*    RATHER THAN A DCB ISSUING AN XCTL WITHIN A MODULE, THE DCB       * 10000000
*    INDICATES WHICH MODULE IT WOULD LIKE TO XCTL TO BY PLACING       * 10100000
*    THAT MODULE'S TWO BYTE MODULE ID AND TTR IN ITS WHERE-TO-GO      * 10200000
*    (WTG) TABLE ENTRY AND BRANCHING TO THE RESIDENT ROUTINE.         * 10300000
*    THE RESIDENT ROUTINE THEN CHECKS WHETHER ANY DCB'S REMAIN        * 10400000
*    IN NEED OF THE CURRENT MODULE IN THE TRANSIENT AREA (CHECKS      * 10500000
*    WHETHER ANY DCB'S ARE 'ACTIVE').  IT DOES THIS BY COMPARING      * 10600000
*    THE MODULE ID'S IN THE WTG TABLE BASIC SECTION AND THE WTG       * 10700000
*    TABLE DCB ENTRY.  IF THE ID'S MATCH, THE DCB IS ACTIVE.          * 10800000
*                                                                     * 10900000
*    AN ACTIVE DCB IS RETURNED TO THE MODULE.  IF NONE ARE ACTIVE,    * 11000000
*    THE ID THAT IS LOWEST IN COLLATING SEQUENCE OF THE ID'S IN       * 11100000
*    THE WTG ENTRIES IS FOUND, THE FIRST DCB ACTIVE IN THAT MODULE    * 11200000
*    WITH THE LOWEST ID IS FOUND, AND AN XCTL IS ISSUED TO THAT       * 11300000
*    MODULE.                                                          * 11400000
*                                                                     * 11500000
*    IN SOME INSTANCES, SUCH AS INTERFACING WITH MODULES NOT USING    * 11600000
*    THE RESIDENT ROUTINE, IT IS DESIRABLE TO EXIT FROM THE           * 11700021
*    RESIDENT ROUTINE'S CONTROL OF DCB LOOPING, ETC.                  * 11800000
*    THIS IS ACCOMPLISHED BY THE DCB SYNCHRONIZATION FACILITY         * 11900000
*    OF THE RESIDENT ROUTINE, THAT OPERATES SIMILARLY TO THE WAIT     * 12000000
*    FACILITY.  RATHER THAN A DCB IN CONTROL IN A MODULE              * 12100000
*    BRANCHING TO THE RESIDENT ROUTINE FOR A WAIT, A BRANCH IS        * 12200000
*    TAKEN FOR A PSEUDO-WAIT.  IN THIS CASE, WHEN ALL DCB'S HAVE      * 12300000
*    PSEUDO-WAITS, A WAIT IS NOT ISSUED, BUT CONTROL IS RETURNED      * 12400000
*    TO THE MODULE, WITH REGISTERS POINTING TO THE FIRST ACTIVE       * 12500000
*    DCB IN THE OPEN/CLOSE PARAMETER LIST.  THIS ENSURES              * 12600000
*    THAT ALL DCB'S ACTIVE IN THE MODULE HAVE COMPLETED EXECUTION UP  * 12700000
*    TO THAT POINT AND EFFECTIVELY EXITS FROM RESIDENT ROUTINE        * 12800000
*    CONTROL.  RESIDENT ROUTINE CONTROL MAY BE RE-ESTABLISHED BY RE-  * 12900000
*    ESTABLISHING THE BASE REGISTER IN THE MODULE, AS THE RESIDENT    * 13000000
*    ROUTINE USES THE MODULE'S BASE REGISTER TO DETERMINE THE         * 13100000
*    BEGINNING OF THE MODULE.  DETAILS ARE SIMILAR TO THE WAIT        * 13200000
*    FACILITY.                                                        * 13300000
*                                                                     * 13400000
*    A DUMMY DCB IS INDICATED BY A MODULE ID OF X'00'.  THIS WILL     * 13500000
*    RESULT IN THE DCB NEVER BEING ACTIVE, AS NO MODULE HAS AN ID OF  * 13600000
*    X'00'.                                                           * 13700000
*                                                                     * 13800000
*    IF THE RESIDENT ROUTINE IS ENTERED FOR AN XCTL, THE OPTIONAL     * 13900000
*    TRACE ROUTINE IS IN CORE, AND TRACE IS REQUESTED FOR THE DCB     * 14000000
*    ENTERING THE RESIDENT ROUTINE, THE TRACE ROUTINE IS CALLED BY    * 14100000
*    THE RESIDENT ROUTINE VIA A BALR.  THE TRACE ROUTINE RETURNS      * 14200000
*    CONTROL TO THE RESIDENT ROUTINE AT THE LINK ADDRESS AFTER        * 14300000
*    TRACING REGISTER AND STORAGE CONTENTS.                           * 14400000
*                                                                     * 14500000
* ENTRY POINTS -                                                      * 14600000
*                                                                     * 14700000
*    ENTRY TO THIS MODULE IS MADE BY A DIRECT BRANCH FROM ANY MODULE  * 14800000
*    IN THE COMPONENT.  THERE ARE THREE ENTRY POINTS--                * 14900000
*         IFG019RA   - ENTRY FOR WAIT FACILITY                        * 15000000
*         IFG019RA+4 - ENTRY FOR XCTL FACILITY                        * 15100000
*         IFG019RA+8 - ENTRY FOR DCB SYNCHRONIZATION FACILITY         * 15200000
*                                                                     * 15300000
* INPUT -                                                             * 15400000
*    REGISTERS -                                                      * 15500000
*        0 - SAVED BY RESIDENT ROUTINE IN WORK AREA                   * 15600000
*        1 - SAVED BY RESIDENT ROUTINE IN WORK AREA                   * 15700000
*        3 - BASE REGISTER OF CALLING MODULE                          * 15800000
*        4 - ADDRESS OF DCB'S WORK AREA                               * 15900000
*        6 - WHERE-TO-GO TABLE ADDRESS                                * 16000000
*        9 - SAVED BY RESIDENT ROUTINE IN WORK AREA                   * 16100000
*       10 - SAVED BY RESIDENT ROUTINE IN WORK AREA                   * 16200000
*       11 - SAVED BY RESIDENT ROUTINE IN WORK AREA                   * 16300000
*       12 - SAVED BY RESIDENT ROUTINE IN WORK AREA                   * 16400000
*       13 - SAVED BY RESIDENT ROUTINE IN WORK AREA                   * 16500000
*       14 - RETURN ADDRESS TO CALLING MODULE FOR WAIT FACILITY AND   * 16600000
*            DCB SYNCHRONIZATION FACILITY (MAY BE A BRANCH TABLE      * 16700000
*            OFFSET FOR THE NEXT MODULE WHEN XCTLING).  SAVED BY      * 16800000
*            RESIDENT ROUTINE IN WORK AREA.                           * 16900000
*                                                                     * 17000000
*    WHERE-TO-GO TABLE BASIC SECTION -                                * 17100000
*       + 0 - EIGHT BYTE CURRENT MODULE NAME                          * 17200000
*       + 6 - TWO BYTE CURRENT MODULE ID                              * 17300000
*       +16 - FULLWORD WITH RESIDENT ROUTINE WORK AREA ADDRESS        * 17400000
*             IN LOW ORDER THREE BYTES                                * 17500000
*       +31 - (WTGPATHS+1) TRACE ROUTINE INDICATOR                    * 17600000
*                                                                     * 17700000
*    WHERE-TO-GO TABLE DCB ENTRY -                                    * 17800000
*       + 0 - TWO BYTE MODULE ID                                      * 17900000
*       + 2 - THREE BYTE MODULE TTR                                   * 18000000
*       + 5 - DCB WORK AREA ADDRESS                                   * 18100000
*                                                                     * 18200000
*    WORK AREA -                                                      * 18300000
*       JFCBMASK+6 - TRACE ROUTINE DCB INDICATOR                      * 18400000
*       DXREG9   - REGISTER SAVE AREA (REGISTER 9)                    * 18500000
*       DXREGA   - REGISTER SAVE AREA (REGISTER 10)                   * 18600000
*       DXREGB   - REGISTER SAVE AREA (REGISTER 11)                   * 18700000
*       DXREGC   - REGISTER SAVE AREA (REGISTER 12)                   * 18800000
*       DXREGD   - REGISTER SAVE AREA (REGISTER 13)                   * 18900000
*       DXREGE   - REGISTER SAVE AREA (REGISTER 14)                   * 19000000
*       DXREG0   - REGISTER SAVE AREA (REGISTER 0)                    * 19100000
*       DXREG1   - REGISTER SAVE AREA (REGISTER 1)                    * 19200000
*       DXRESIND -                                                    * 19300000
*          X'80' - WAIT PENDING BIT                                   * 19400000
*          X'40' - PSUEDO-WAIT BIT                                    * 19500000
*       DXECB    - ECB                                                * 19600000
*                                                                     * 19700000
*    RESIDENT ROUTINE WORK AREA                                       * 19800000
*       - 8 - PREFIX FOR OPTIONAL TRACE FUNCTION, ADDRESS OF          * 19900000
*             OPTIONAL TRACE ROUTINE                                  * 20000000
*       + 0 - FULLWORD WITH PARAMETER LIST ADDRESS                    * 20100000
*       + 4 - MULTIPLE WAIT ECBLIST                                   * 20200000
*                                                                     * 20300000
* OUTPUT -                                                            * 20400000
*                                                                     * 20500000
*    REGISTERS -                                                      * 20600000
*        0 - CONTENTS OF DXREG0                                       * 20700000
*        1 - CONTENTS OF DXREG1                                       * 20800000
*        2 - DCB ADDRESS (FROM OPEN/CLOSE PARAMETER LIST)             * 20900000
*        4 - DCB WORK AREA ADDRESS (FROM WTG TABLE DCB ENTRY)         * 21000000
*        7 - ADDRESS OF CURRENT PARAMETER LIST ENTRY                  * 21100000
*        8 - ADDRESS OF CURRENT WTG DCB ENTRY                         * 21200000
*        9 - (ADDRESS OF OPTIONAL TRACE FUNCTION PREFIX TO THE        * 21300000
*            RESIDENT ROUTINE WORK AREA WHEN CALLING THE OPTIONAL     * 21400000
*            TRACE ROUTINE.)                                          * 21500000
*        9 - CONTENTS OF DXREG9                                       * 21600000
*       10 - CONTENTS OF DXREGA                                       * 21700000
*       11 - CONTENTS OF DXREGB                                       * 21800000
*       12 - CONTENTS OF DXREGC                                       * 21900000
*       13 - CONTENTS OF DXREGD                                       * 22000000
*       14 - CONTENTS OF DXREGE                                       * 22100000
*                                                                     * 22200000
*    WHERE-TO-GO TABLE BASIC SECTION -                                * 22300000
*       + 0 - EIGHT BYTE MODULE NAME                                  * 22400000
*       +14 - THREE BYTE TTR                                          * 22500000
*                                                                     * 22600000
*    WORK AREA -                                                      * 22700000
*       DXREG9   - REGISTER SAVE AREA (REGISTER 9)                    * 22800000
*       DXREGA   - REGISTER SAVE AREA (REGISTER 10)                   * 22900000
*       DXREGB   - REGISTER SAVE AREA (REGISTER 11)                   * 23000000
*       DXREGC   - REGISTER SAVE AREA (REGISTER 12)                   * 23100000
*       DXREGD   - REGISTER SAVE AREA (REGISTER 13)                   * 23200000
*       DXREGE   - REGISTER SAVE AREA (REGISTER 14)                   * 23300000
*       DXREG0   - REGISTER SAVE AREA (REGISTER 0)                    * 23400000
*       DXREG1   - REGISTER SAVE AREA (REGISTER 1)                    * 23500000
*       DXRESIND -                                                    * 23600000
*          X'80' - WAIT-PENDING BIT                                   * 23700000
*          X'40' - PSEUDO-WAIT  BIT                                   * 23800000
*                                                                     * 23900000
* EXTERNAL REFERENCES -                                               * 24000000
*    THE OPTIONAL TRACE ROUTINE IS CALLED ON XCTL, WHEN REQUESTED.    * 24100000
*    CONTROL IS RETURNED TO THIS FUNCTION AT THE FOLLOWING            * 24200000
*    INSTRUCTION.                                                     * 24300000
*                                                                     * 24400000
* EXITS, NORMAL -                                                     * 24500000
*    TO CALLING MODULE - AT BASE REGISTER ADDRESS (REGISTER 3)        * 24600000
*                      - AT RETURN REGISTER ADDRESS (REGISTER 14)     * 24700000
*    TO NEXT MODULE IN COMPONENT DETERMINED BY WTG TABLE ENTRY        * 24800000
*    CONTENTS (VIA XCTL)                                              * 24900000
*                                                                     * 25000000
* EXITS, ERROR - NONE                                                 * 25100000
*                                                                     * 25200000
* TABLES/WORKAREAS -                                                  * 25300000
*    THE FORMAT AND CONTENTS OF THE WORKAREA USED ARE DESCRIBED BY    * 25400000
*    THE DSECT AT THE END OF THE LISTING.                             * 25500000
*                                                                     * 25600000
*    THE WHERE-TO-GO TABLE IS DESCRIBED BY THE OPEN/CLOSE/EOV PLM.    * 25700000
*                                                                     * 25800000
*    THE RESIDENT ROUTINE WORK AREA CONSISTS OF A FULLWORD            * 25900000
*    CONTAINING THE OPEN/CLOSE PARAMETER LIST ADDRESS FOLLOWED BY     * 26000000
*    A NORMAL ECBLIST FOR MULTIPLE WAIT, WITH FOUR BYTES FOR EACH     * 26100000
*    DCB BEING PROCESSED IN PARALLEL.  IF THE OPTIONAL TRACE FUNCTION * 26200000
*    IS SPECIFIED, THE FIRST WORD OF AN EIGHT BYTE PREFIX  TO THE     * 26300000
*    RESIDENT ROUTINE WORK AREA CONTAINS THE TRACE ROUTINE ADDRESS.   * 26400000
*                                                                     * 26500000
* CHARACTER CODE DEPENDENCY -                                         * 26600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 26700000
*                                                                     * 26800000
* ATTRIBUTES -                                                        * 26900000
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 27000000
*                                                                     * 27100000
*********************************************************************** 27200000
         EJECT                                                          27300000
         IECEQU                                                         27400000
*********************************************************************** 27500000
*                                                                     * 27600000
* ENTRY TO RESIDENT ROUTINE                                           * 27700000
*                                                                     * 27800000
*********************************************************************** 27900000
         USING *,RES                    ADDRESS OF THIS MODULE          28000000
         USING FORCORE,RCORE            WORK AREA ADDRESS               28100000
         USING WTG,RWTG                 ADDRESS OF WTG TABLE            28200000
         USING WTGENTRY,RWTGC           WTG TABLE ENTRY ADDR            28300000
RES00100 B     RES00500                 ENTRY FOR WAIT                  28400000
RES00200 B     RES01900                 ENTRY FOR XCTL                  28500000
RES00300 EQU   *                        ENTRY FOR EXITING RESIDENT      28600000
*                                       ROUTINE CONTROL OF LOOPING      28700000
*********************************************************************** 28800000
*                                                                     * 28900000
* WAIT AND PSEUDO WAIT HANDLING SECTION OF RESIDENT ROUTINE           * 29000000
*                                                                     * 29100000
* THIS SECTION RECIEVES CONTROL FROM THE CALLING MODULE WHEN THE      * 29200000
* CALLING MODULE REQUESTS A WAIT OR PSEUDO-WAIT FOR A PARTICULAR DCB  * 29300000
* AND FROM THE XCTL SECTION OF THE RESIDENT ROUTINE WHEN THERE REMAINS* 29400000
* ONE OR MORE ACTIVE DCB'S IN THE CALLING MODULE SO THAT AN XCTL MAY  * 29500000
* NOT BE TAKEN.                                                       * 29600000
*                                                                     * 29700000
* THE WAIT-PENDING BIT OR THE PSEUDO-WAIT BIT IS SET AS APPROPRIATE.  * 29800000
* ALL ACTIVE DCB'S ARE SCANNED, SEARCHING FOR A DCB WITH NEITHER A    * 29900000
* WAIT-PENDING NOR A PSEUDO-WAIT WHILE SIMULTANEOUSLY BUILDING AN     * 30000000
* ECBLIST FOR DCB'S WITH A WAIT PENDING.  UPON ENCOUNTERING AN ACTIVE * 30100000
* DCB WITH NEITHER A WAIT PENDING OR A PSEUDO-WAIT, OR A DCB WITH A   * 30200000
* WAIT PENDING THAT IS ALREADY POSTED, CONTROL IS RETURNED TO THE     * 30300000
* CALLING MODULE FOR THAT DCB.  OTHERWISE, IF THERE ARE ANY DCB'S     * 30400000
* WITH A WAIT PENDING, A MULTIPLE WAIT IS ISSUED ON THE ECBLIST,      * 30500000
* THE POSTED DCB IS FOUND ON RETURN FROM WAIT, AND A RETURN IS TAKEN  * 30600000
* TO THE CALLING MODULE.  IF THERE ARE NO WAITS PENDING, ALL ACTIVE   * 30700000
* DCB'S MUST HAVE PSEUDO-WAITS SO THE PSEUDO-WAIT BITS FOR ALL THE    * 30800000
* DCB'S ARE RESET AND A RETURN IS TAKEN TO THE CALLING MODULE FOR     * 30900000
* THE FIRST ACTIVE DCB.                                               * 31000000
*                                                                     * 31100000
*********************************************************************** 31200000
*                                                                       31300000
* ENTRY FOR EXITING RESIDENT ROUTINE CONTROL                            31400000
*                                                                       31500000
RES00400 EQU   *                                                        31600000
         MVI   DXRESIND,PSEUDOWT        SET PSEUDO-WAIT (SYNCH) BIT     31700000
         B     RES02000                 GO PROCESS AS IF THIS WAS AN    31800000
*                                       XCTL REQUEST SO THAT THE TRACE  31900000
*                                       RTN MAY BE CALLED.  THE XCTL    32000000
*                                       ENTRY WILL FIND AN ACTIVE DCB   32100000
*                                       SO IT WILL GO TO THE ENTRY      32200000
*                                       FOR WAIT (RES00500).            32300000
* ENTRY FOR WAIT                                                        32400000
*                                                                       32500000
RES00500 EQU   *                                                        32600000
         MVI   DXRESIND,WAITBIT         SET WAIT PENDING BIT            32700000
         BAL   R7,RES03000              GO SAVE REGS                    32800000
         BAL   RET,RES03100             GO INITIALIZE                   32900000
* SCAN THE DCB'S FOR WAIT-PENDING AND PSEUDO-WAIT CONDITION TO          33000000
* DETERMINE WHETHER A DCB MAY BE PROCESSED WITHOUT WAITING.  IF YES,    33100000
* SWITCH DCB'S AND RETURN.  IF NOT, BUILD ECBLIST AND ISSUE MULTIPLE    33200000
* WAIT.  IF NO DCB MAY BE STARTED AND NONE HAVE A WAIT PENDING, ALL     33300000
* DCB'S MUST HAVE A PSEUDO-WAIT, IN WHICH CASE GO RESET PSEUDO-WAIT     33400000
* BITS PREPATORY TO RETURNING TO THE CALLING MODULE                     33500000
*                                                                       33600000
RES00600 EQU   *                                                        33700000
RES00700 CLC   WTGMODID,WTGIDTTR        IS THIS DCB ACTIVE              33800000
*                                       (MODULE ID'S EQUAL)             33900000
         BNE   RES00800                 NO, GO CHECK FOR LAST ENTRY     34000000
         TM    DXRESIND,WAITBIT         YES, IS A WAIT PENDING          34100000
         BO    RES01000                 YES, GO SEE IF POSTED           34200000
         TM    DXRESIND,PSEUDOWT        NO, IS IT A PSEUDO-WAIT         34300000
         BNO   RES01200                 NO, GO RETURN TO BEGINNING OF   34400000
*                                       CALLING MODULE                  34500000
RES00800 EQU   *                                                        34600000
         TM    PLISTOPT(RPARC),LASTNTRY  YES, IS THIS LAST PARAMETER    34700000
*                                       LIST ENTRY                      34800000
         BNO   RES01100                 NO, GO INCREMENT AND LOOP       34900000
         C     RTIOT,WTGECBAD           YES, HAS ECBLIST PTR BEEN       35000000
*                                       INCREMENTED (IE HAVE THERE      35100000
*                                       BEEN ANY WAIT'S PENDING WITH    35200000
*                                       CORRESPONDING ENTRIES IN THE    35300000
*                                       ECBLIST)                        35400000
         BE    RES01500                 NO, MUST HAVE ALL PSEUDO-WAITS, 35500000
*                                       GO INITIALIZE AND RESET ALL     35600000
*                                       PSEUDO-WAIT BITS                35700000
RES00900 EQU   *                                                        35800000
         OI    0(RTIOT),LASTNTRY        YES, HAVE WAIT'S PENDING AND    35900000
*                                       NO DCB'S TO PROCESS, INDICATE   36000000
*                                       END OF ECBLIST                  36100000
         BAL   RET,RES03100             INITIALIZE AND RESET ECBLIST    36200000
*                                       ADDRESS                         36300000
         WAIT  1,ECBLIST=ECBLIST(RTIOT)  MULTIPLE WAIT ON ANY ECB IN    36400000
*                                       ECBLIST                         36500000
         B     RES00600                 GO FIND THE DCB WITH A POSTED   36600000
*                                       ECB                             36700000
RES01000 EQU   *                                                        36800000
         TM    DXECB,ECBPOST            IS ECB POSTED ALREADY           36900000
         BO    RES01300                 YES, GO RETURN TO CALLING       37000000
*                                       MODULE                          37100000
         LA    RTIOT,K4(,RTIOT)         NO, INCREMENT TO NEXT ECBLIST   37200000
*                                       ENTRY                           37300000
         LA    RUCB,DXECB               GET ECB ADDRESS FOR THIS DCB    37400000
         ST    RUCB,0(,RTIOT)           ADD ECB ADDRESS TO ECBLIST      37500000
         TM    PLISTOPT(RPARC),LASTNTRY  IS THIS LAST PARAMETER LIST    37600000
*                                       ENTRY                           37700000
         BO    RES00900                 YES, GO WAIT ON ECBLIST         37800000
*                                       NO, INCREMENT AND LOOP          37900000
RES01100 EQU   *                                                        38000000
         BAL   RET,RES03200             INCREMENT TO NEXT DCB           38100000
         B     RES00600                 LOOP TO CHECK NEXT DCB          38200000
*                                                                       38300000
* RETURN TO START OF CALLING MODULE SINCE THERE WAS NO WAIT PENDING     38400000
* OR PSEUDO-WAIT FOR THIS DCB.                                          38500000
*                                                                       38600000
RES01200 EQU   *                                                        38700000
         L     RDCB,0(,RPARC)           GET DCB ADDRESS FROM PARAMETER  38800000
*                                       LIST ENTRY                      38900000
         LM    RTIOT,RET,DXREG9         RESTORE REGISTERS 9 THROUGH 14  39000000
         LM    R0,R1,DXREG0             RESTORE REGISTERS 0 AND 1       39100000
         BR    RBASE                    RETURN TO START OF CALLING      39200000
*                                       MODULE VIA CALLING MODULE'S     39300000
*                                       BASE REGISTER                   39400000
*                                                                       39500000
* RESET WAIT PENDING BIT                                                39600000
*                                                                       39700000
RES01300 EQU   *                                                        39800000
         NI    DXRESIND,X'FF'-WAITBIT   RESET WAIT PENDING BIT          39900000
*                                                                       40000000
* RETURN TO CALLING MODULE VIA CALLING MODULE'S LINK REGISTER           40100000
*                                                                       40200000
RES01400 EQU   *                                                        40300000
         L     RDCB,0(,RPARC)           GET DCB ADDRESS FROM PARAMETER  40400000
*                                       LIST ENTRY                      40500000
         LM    RTIOT,RET,DXREG9         RESTORE REGISTERS 9 THROUGH 14  40600000
         LM    R0,R1,DXREG0             RESTORE REGISTERS 0 AND 1       40700000
         BR    RET                      RETURN TO CALLING MODULE VIA    40800000
*                                       CALLING MODULE'S LINK REGISTER  40900000
*                                                                       41000000
* RESET ALL PSEUDO-WAIT BITS AND FIND THE FIRST ACTIVE DCB IN THE       41100000
* PARAMETER LIST FOR THE RETURN.                                        41200000
*                                                                       41300000
RES01500 EQU   *                                                        41400000
         BAL   RET,RES03100             INITIALIZE                      41500000
RES01600 EQU   *                                                        41600000
         EX    0,RES00700               IS THIS DCB ACTIVE              41700000
*                                       (MODULE ID'S EQUAL)             41800000
         BNE   RES01700                 NO, GO INCREMENT AND LOOP       41900000
         TM    DXRESIND,PSEUDOWT        YES, IS PSEUDO-WAIT BIT ON      42000000
         BNO   RES01400                 NO, GO RETURN VIA LINK REGISTER 42100000
         NI    DXRESIND,X'FF'-PSEUDOWT  YES, RESET PSEUDO-WAIT BIT      42200000
RES01700 TM    PLISTOPT(RPARC),LASTNTRY  IS THIS LAST PARAMETER LIST    42300000
*                                       ENTRY                           42400000
         BNO   RES01800                 NO, GO INCREMENT AND LOOP       42500000
         B     RES01500                 YES, INITIALIZE TO START OF     42600000
*                                       PARAMETER LIST AND LOOP         42700000
RES01800 EQU   *                                                        42800000
         BAL   RET,RES03200             INCREMENT TO NEXT DCB           42900000
         B     RES01600                 GO LOOP                         43000000
*********************************************************************** 43100000
*                                                                     * 43200000
* XCTL-HANDLING SECTION OF RESIDENT ROUTINE                           * 43300000
*                                                                     * 43400000
* THIS SECTION OF CODE DETERMINES WHETHER THERE ARE ANY ACTIVE DCB'S  * 43500000
* FOR THE CALLING MODULE.  IF THERE IS, THE WAIT-HANDLING SECTION OF  * 43600000
* THE RESIDENT ROUTINE TAKES OVER.  IF THERE ARE NO ACTIVE DCB'S,     * 43700000
* THE LOWEST NEXT MODULE ID IS FOUND, A DCB THAT IS ACTIVE IN THAT    * 43800000
* LOWEST NEXT MODULE IS FOUND, AND AN XCTL IS TAKEN.                  * 43900000
*                                                                     * 44000000
*********************************************************************** 44100000
*                                                                       44200000
* ENTRY FOR XCTL                                                        44300000
*                                                                       44400000
RES01900 EQU   *                                                        44500000
         MVI   DXRESIND,K0              ENSURE WAIT, PSUEDO-WAIT OFF    44600000
RES02000 EQU   *                                                        44700000
         BAL   R7,RES03000              GO SAVE REGS                    44800000
         TM    WTGPATHS+1,WTGTRACE      IS TRACE RTN  SPECIFIED AND     44900000
*                                       IN CORE                         45000000
         BNO   RES02100                 NO, SKIP TRACE                  45100000
         TM    JFCBMASK+6,JFCTRACE      IS TRACE REQUESTED FOR THIS DCB 45200000
         BNO   RES02100                 NO, SKIP TRACE                  45300000
         L     RTIOT,WTGECBAD           YES, GET RESIDENT ROUTINE       45400000
*                                       WORK AREA ADDR                  45500000
         SH    RTIOT,RRWAPRFX           BACK UP TO TRACE RTN PTR IN     45600000
*                                       PREFIX TO RESIDENT ROUTINE      45700000
*                                       WORK AREA                       45800000
         L     RF,0(,RTIOT)             TRACE RTN PTR                   45900000
         BALR  RET,RF                   GO TO TRACE RTN TO TRACE        46000000
*                                       THIS DCB AND RETURN.            46100000
*                                                                       46200000
* RETURN FROM THE OPTIONAL TRACE ROUTINE                                46300000
*                                                                       46400000
RES02100 EQU   *                                                        46500000
         BAL   RET,RES03100             GO INITIALIZE                   46600000
*                                                                       46700000
* SCAN DCB'S FOR A DCB ACTIVE IN THIS MODULE.  IF ONE IS FOUND, LET     46800000
* WAIT SECTION HANDLE IT.                                               46900000
*                                                                       47000000
RES02200 EQU   *                                                        47100000
         EX    0,RES00700               IS THIS DCB ACTIVE              47200000
*                                       (MODULE ID'S EQUAL)             47300000
         BE    RES00600                 YES, LET WAIT SECTION HANDLE IT 47400000
         TM    PLISTOPT(RPARC),LASTNTRY  NO, IS THIS LAST PARAMETER     47500000
*                                       LIST ENTRY                      47600000
         BO    RES02300                 YES, NONE ACTIVE, GO INITIALIZE 47700000
         BAL   RET,RES03200             NO, INCREMENT TO NEXT DCB       47800000
         B     RES02200                 GO LOOP TO CHECK NEXT DCB       47900000
RES02300 EQU   *                                                        48000000
         BAL   RET,RES03100             INITIALIZE                      48100000
HIGHID   EQU   X'FF'                    HIGH ID (GRATER THAN ALL     CC 48200000
*                                       ALPHANUMERIC CHARACTERS)     CC 48300000
         MVI   WTGMODID,HIGHID          SET HIGH ID IN WTG TABLE     CC 48400000
*                                       BASIC SECTION SO PRESENT     CC 48500000
*                                       MODULE IN BASIC SECTION WILL CC 48600000
*                                       NOT BE LOWEST ID.            CC 48700000
*                                                                       48800000
* SCAN DCB'S TO FIND LOWEST NEXT MODULE ID.  WHEN FINISHED (LAST        48900000
* PARAMETER LIST ENTRY), GO EXIT VIA XCTL.                              49000000
*                                                                       49100000
*                                                                       49200000
* COMPARE NEXT MODULE ID IN WTG ENTRY WITH THAT IN WTG BASIC SECTION.   49300000
* IF ID IN ENTRY IS SMALLER, GO MOVE IT INTO BASIC SECTION.             49400000
*                                                                       49500000
RES02400 EQU   *                                                        49600000
         EX    0,RES00700               IS ID IN BASIC SECTION LESS  CC 49700000
*                                       THAN ID IN ENTRY             CC 49800000
         BL    RES02500                 YES, GO LOOP                 CC 49900000
         CLI   WTGIDTTR,CHAR00          IS MOD ID BINARY ZEROS IN    CC 50000000
*                                       ENTRY (IGNORED DCB)          CC 50100000
         BE    RES02500                 YES, DO NOT MOVE MOD ID      CC 50200000
*                                       TO BASIC SECTION OF WTG      CC 50300000
*                                       TABLE                        CC 50400000
*                                                                       50500000
* MOVE NEXT ID AND TTR FROM WTG TABLE ENTRY TO WTG TABLE BASIC SECTION. 50600000
*                                                                       50700000
         MVC   WTGMODID,WTGIDTTR        MOVE MODULE ID FROM WTG         50800000
*                                       ENTRY TO WTG BASIC SECTION      50900000
         MVC   WTGTTR,WTGIDTTR+L'WTGMODID  MOVE MODULE TTR FROM WTG     51000000
*                                       ENTRY TO WTG BASIC SECTION      51100000
RES02500 EQU   *                                                        51200000
         TM    PLISTOPT(RPARC),LASTNTRY  IS THIS LAST PARAMETER LIST    51300000
*                                       ENTRY                           51400000
         BO    RES02600                 YES, GO EXIT VIA XCTL           51500000
*                                       NO, COMPARE MODULE ID'S         51600000
         BAL   RET,RES03200             GO INCREMENT TO NEXT DCB        51700000
         B     RES02400                 GO LOOP                         51800000
*                                                                       51900000
* FIND THE FIRST ACTIVE DCB AND EXIT VIA XCTL                           52000000
*                                                                       52100000
RES02600 EQU   *                                                        52200000
         BAL   RET,RES03100             INITIALIZE                      52300000
RES02700 EQU   *                                                        52400000
         EX    0,RES00700               IS THIS DCB ACTIVE              52500000
         BE    RES02800                 YES, GO XCTL                    52600000
         BAL   RET,RES03200             NO, GO INCREMENT TO NEXT DCB    52700000
         B     RES02700                 GO LOOP TO CHECK NEXT DCB       52800000
RES02800 EQU   *                                                        52900000
         L     RDCB,0(,RPARC)           GET DCB ADDRESS FROM PARAMETER  53000000
*                                       LIST ENTRY                      53100000
*********************************************************************** 53106021
*                                                                     * 53112021
* THE FOLLOWING INSTRUCTION IS A MODIFIABLE NOP BRANCH TO A WTO       * 53118021
* MODULE TRACE ROUTINE RESIDING IN THE MAINTENANCE SPACE OF THIS      * 53124021
* MODULE.                                                             * 53130021
*                                                                     * 53136021
* CHANGE THIS INSTRUCTION TO AN UNCONDITIONAL BRANCH X'47F0' TO       * 53142021
* ENABLE THE MODULE TRACE.  THE ADDRESS OF THIS MODULE MAY BE         * 53148021
* FOUND IN THE CVT WORD CVTDMSVR AT CVT OFFSET X'110'.                * 53154021
*                                                                     * 53160021
* FURTHER DESCRIPTION PRECEDES THE WTO MODULE TRACE ROUTINE BELOW.    * 53166021
*                                                                     * 53172021
*********************************************************************** 53178021
RESTRACE NOP   RES03300                 GO TO MODULE TRACE RTN   S21940 53184021
RES02850 EQU   *                        RETURN FROM MOD TRACE    S21940 53190021
         LM    RTIOT,RET,DXREG9         RESTORE REGISTERS 9 THROUGH 14  53200000
         LM    R0,R1,DXREG0             RESTORE REGISTERS 0 AND 1       53300000
         LA    RF,DXXCTL                ADDRESS OF SUPERVISOR           53400000
*                                       USE AREA IN WORK AREA FOR       53500000
*                                       THE SUPERVISOR PARAMATER LIST   53600000
*                                       RWTG HAS ADDRESS OF SIMULATED   53700000
*                                       BLDL LIST IN BASIC SECTION OF   53800000
*                                       WTG TABLE                       53900000
         CLI   WTGTTR+2,K0              IS TTR ZERO (IE IS R ZERO)      54000000
         BZ    RES02900                 YES, XCTL BY NAME               54100000
         AIF   ('&LIB' EQ 'LIB1').LIB1BW  TEST FOR LIB1(OS)             54105000
*                                                                       54110000
* CALCULATE BYTE LENGTH OF MODULE FROM DWD LENGTH                       54115000
* GIVEN IN REGISTER 14 (RET)                                            54120000
*                                                                       54125000
         SRL   RET,K24                   SHIFT DWD LENGTH AND           54130000
*                                        CLEAR HI ORDER BYTES           54135000
         SLL   RET,K3                    MULTIPLY  Y EIGHT              54140000
         C     RET,ONEK                  IS MODULE UNDER 1K             54145000
         BH    TRULEN                    NO                             54150000
         L     RET,ONEK                  YES, MAKE IT ONE K             54155000
TRULEN   SLL   RET,K8                    MOVE LEFT ONE BYTE             54160000
         ST    RET,WTGMODSZ              PUT LENGTH AND                 54165000
         MVC   WTGTXTLN,WTGMODSZ+K1      SIZE IN WTG TABLE              54170000
         L     RET,DXREGE                RESTORE R14 AGAIN              54175000
         LA    RET,K0(RET)              CLEAR HIGH ORDER LENGTH BYTE    54180000
*                                                                       54185000
         ST    RET,DXREGE               SAVE REGISTER 14                54187000
.LIB1BW  ANOP                                                           54190000
         XCTL  DE=(RWTG),SF=(E,(15))                                    54200000
RES02900 EQU   *                                                        54300000
         XCTL  EPLOC=(RWTG),SF=(E,(15))                                 54400000
*********************************************************************** 54500000
*                                                                     * 54600000
* ROUTINE TO SAVE REGISTERS                                           * 54700000
*                                                                     * 54800000
*********************************************************************** 54900000
*                                                                       55000000
RES03000 EQU   *                                                        55100000
         STM   RTIOT,RET,DXREG9         SAVE REGISTERS 9 THROUGH 14     55200000
*                                       IN THE WORK AREA.               55300000
         STM   R0,R1,DXREG0             SAVE REGISTERS 0 AND 1 IN THE   55400000
*                                       WORK AREA.                      55500000
         BR    R7                       RETURN                          55600000
*********************************************************************** 55700000
*                                                                     * 55800000
* ROUTINE TO INITIALIZE WTG TABLE ENTRY PTR, PARAMETER LIST ENTRY     * 55900000
* PTR, RESIDENT ROUTINE WORK AREA ADDRESS, AND WORK AREA ADDRESS      * 56000000
*                                                                     * 56100000
*********************************************************************** 56200000
*                                                                       56300000
RES03100 EQU   *                                                        56400000
         L     RTIOT,WTGECBAD           ECBLIST PREFIX ADDR FROM WTG    56500000
         L     RPARC,ECBPARM(,RTIOT)    PARAMETER LIST ADDRESS FROM     56600000
*                                       ECBLIST PREFIX                  56700000
         DROP  RWTGC                    DROP TO LOAD BASE REG           56800000
         LA    RWTGC,WTGENTRY           PTR TO FIRST WTG ENTRY          56900000
         USING WTGENTRY,RWTGC           WTG TABLE ENTRY ADDR            57000000
         L     RCORE,WTGCORE-1          PTR TO WORK AREA FROM THIS      57100000
*                                       DCB'S WTG ENTRY                 57200000
         BR    RET                      RETURN                          57300000
*********************************************************************** 57400000
*                                                                     * 57500000
* ROUTINE TO INCREMENT TO THE NEXT DCB THE PARAMETER LIST ENTRY AND   * 57600000
* THE WTG TABLE ENTRY, AND GET THE WORK AREA ADDRESS OF THAT DCB.     * 57700000
*                                                                     * 57800000
*********************************************************************** 57900000
*                                                                       58000000
RES03200 EQU   *                                                        58100000
         LA    RPARC,K4(,RPARC)         INCREMENT TO NEXT PARAMETER     58200000
*                                       LIST ENTRY                      58300000
         LA    RWTGC,L'WTGENTRY(,RWTGC)  INCREMENT TO NEXT WTG TABLE    58400000
*                                       ENTRY                           58500000
         L     RCORE,WTGCORE-1          PTR TO WORK AREA FROM THIS      58600000
*                                       DCB'S WTG ENTRY                 58700000
         BR    RET                      RETURN                          58800000
*********************************************************************** 58900000
*                                                                     * 59000000
* CONSTANTS                                                           * 59100000
*                                                                     * 59200000
*********************************************************************** 59300000
         AIF   ('&LIB' EQ 'LIB1').LIB1BX  TEST FOR LIB1(OS)             59310000
*                                                                       59320000
         DS    0F                       FULL WORD ALIGN                 59330000
ONEK     DC    X'00000400'              1024 BYTES FOR LENGTH CALC      59340000
*                                                                       59350000
.LIB1BX  ANOP                                                           59360000
RRWAPRFX DC    H'8'                     RESIDENT ROUTINE WORK AREA      59400000
*                                       OPTIONAL TRACE FUNCTION         59500000
*                                       PREFIX LENGTH                   59600000
*********************************************************************** 59700000
*                                                                     * 59800000
* MAINTENANCE SPACE                                                   * 59900000
*                                                                     * 60000000
*********************************************************************** 60100000
*                                                                       60101021
*********************************************************************** 60102021
*                                                                     * 60103021
* WTO MODULE TRACE ROUTINE RESIDING IN MAINTENANCE SPACE              * 60104021
*                                                                     * 60105021
* THIS ROUTINE ISSUES A WRITE TO OPERATOR OF THE NAME OF THE          * 60106021
* MODULE THAT WILL BE XCTL'D TO NEXT.                                 * 60107021
*                                                                     * 60108021
* ONLY OPEN/CLOSE/EOV MODULES USING THIS RESIDENT ROUTINE (IFG019RA)  * 60109021
* WILL HAVE THE NAME OF THE MODULE BEING XCTL'D TO TRACED.            * 60110021
* INITIAL LOADS, ACCESS METHOD EXECUTORS, AND OPEN/CLOSE/             * 60111021
* EOV MODULES INTERFACING WITH OTHER FUNCTIONS, SUCH AS NSL           * 60112021
* MODULES, ISSUE THEIR OWN XCTL.  IN THESE CASES, THE NAME OF THE     * 60113021
* MODULE XCTL'D TO WILL NOT APPEAR.                                   * 60114021
*                                                                     * 60115021
* THIS TRACE ROUTINE MAY BE ENABLED BY CHANGING THE NOP BRANCH        * 60116021
* INSTRUCTION AT LABEL RESTRACE TO AN UNCONDITIONAL BRANCH            * 60117021
* X'47F0'.  THE ADDRESS OF THIS MODULE MAY BE FOUND IN THE CVT        * 60118021
* WORD NAMED CVTDMSVR AT CVT OFFSET X'110'.                           * 60119021
*                                                                     * 60120021
RESNOP   EQU   RESTRACE                 LOCATION OF NOP BRANCH   S21940 60121021
*                                                                     * 60122021
* THE EIGHT BYTE MESSAGE IS ROUTED TO THE CONSOLE (BIT 1, FIRST       * 60123021
* BYTE OF ROUTE CODE) AND THE PROGRAMMER (BIT 2, SECOND BYTE OF       * 60124021
* ROUTE CODE).  THE ROUTING MAY BE CHANGED BY MODIFYING THE ROUTE     * 60125021
* CODE.                                                               * 60126021
*                                                                     * 60127021
* NOTE THAT THESE MESSAGES ARE ISSUED BY THIS ROUTINE                 * 60128021
* OPERATING IN A NON-REENTRANT MANNER.  IF THE MESSAGE                * 60129021
* BUFFER IS FILLED, AND TWO TASKS ARE CONCURRENTLY USING              * 60130021
* THIS ROUTINE, SOME MESSAGES MAY BE OVERLAID.  IN ANY EVENT,         * 60131021
* THE SIMULTANEOUS TRACE OF MORE THAN ONE TASK WOULD TEND TO          * 60132021
* GIVE A CONFUSING TRACE.                                             * 60133021
*                                                                     * 60134021
* IF SMF IS ACTIVE, EOV MAY TRANSFER CONTROL TO SEVERAL CLOSE         * 60135021
* MODULES IN ORDER TO PROCESS SMF RECORDS. THIS RESULTS IN CLOSE      * 60136021
* MODULE NAMES APPEARING BETWEEN EOV MODULE NAMES. IN ADDITION,       * 60137021
* SINCE THE SMF FACILITY INVOKES TCLOSE, TCLOSE MODULE NAMES WILL     * 60138021
* APPEAR BETWEEN THE CLOSE SMF-PROCESSING MODULE NAMES.               * 60139021
*                                                                     * 60140021
* AT THE TIME THIS MODULE TRACE ROUTINE GAINS CONTROL, REGISTER       * 60141021
* CONTENTS ARE AS FOLLOWS--                                           * 60142021
*    REG  2 - PTR TO DCB THAT WILL FIRST BE PROCESSED AFTER THE XCTL  * 60143021
*    REG  3 - BASE ADDRESS OF CURRENT MODULE IN CONTROL IN THE        * 60144021
*             TRANSIENT AREA                                          * 60145021
*    REG  4 - PTR TO DCB WORK AREA FOR DCB THAT WILL FIRST BE         * 60146021
*             PROCESSED (ADDR IN REGISTER 2)                          * 60147021
*    REG  5 - BASE REGISTER FOR THIS MODULE                           * 60148021
*    REG  6 - WHERE-TO-GO TABLE ADDRESS (FIRST EIGHT BYTES ARE        * 60149021
*              MODULE NAME                                            * 60150021
*    REG  7 - ADDRESS OF PARAMETER LIST ENTRY FOR NEXT DCB (ADDR      * 60151021
*             IN REGISTER 2)                                          * 60152021
*    REG  8 - ADDRESS OF WHERE-TO-GO TABLE ENTRY FOR NEXT DCB         * 60153021
*                                                                     * 60154021
* IF THIS ROUTINE IS MODIFIED TO PERFORM ADDITIONAL FUNCTION,         * 60155021
* REGISTERS 0,1,3,9-15 MAY BE USED WITHOUT BEING SAVED OR             * 60156021
* RESTORED.                                                           * 60157021
*                                                                     * 60158021
*********************************************************************** 60159021
*                                                                       60160021
RES03300 EQU   *                        ENTRY TO TRACE RTN       S21940 60161021
         MVC   MODNAME,WTGMODNM         MOVE NEXT MODULE'S NAME  S21940 60162021
*                                       TO WTO MESSAGE                  60163021
         WTO   MF=(E,MESSAGE)           ISSUE MESSAGE            S21940 60164021
         B     RES02850                 RETURN TO XCTL           S21940 60165021
*                                                                       60166021
* MESSAGE                                                               60167021
*                                                                       60168021
         DS    0F                                                S21940 60169021
MESSAGE  DC    H'12'                    MESSAGE LENGTH           S21940 60170021
         DC    X'8000'                  MCS FLAGS                S21940 60171021
MODNAME  DC    CL8'IFG019RA'            MODULE NAME              S21940 60172021
         DC    X'0100'                  DESCRIPTOR CODE          S21940 60173021
         DC    X'40'                    ROUTE TO MASTER CONSOLE  S21940 60174021
         DC    X'20'                    ROUTE TO PROGRAMMER      S21940 60175021
*                                                                       60176021
         AIF   ('&LIB' EQ 'LIB1').LIB1RA1                               60186000
PATCH9RA EQU   IFG019RA+540-*              NO. BYTES LEFT IN MODULE     60200000
.LIB1RA1 ANOP                                                           60250000
         AIF   ('&LIB' NE 'LIB1').LIB1RA2                               60260000
PATCH9RA EQU   IFG019RA+504-*           NO. BYTES LEFT IN MODULE SM4377 60270000
.LIB1RA2 ANOP                                                           60280000
         DC    (PATCH9RA)X'00'          REMAINDER OF MODULE IS          60300000
*                                       ZEROED MAINTENANCE SPACE        60400000
*********************************************************************** 60500000
*                                                                     * 60600000
* DESECTS                                                             * 60700000
*                                                                     * 60800000
*********************************************************************** 60900000
         IECDSECS MAIN,WTG,EXPAND=YES                                   61000000
         END                                                            61100000
