         TITLE 'IFG019TR - OPEN/CLOSE/EOV OPTIONAL TRACE ROUTINE'       00600000
         GBLC  &LIB                     DEFINE GLOBAL CHAR VARIABLE     01200000
&LIB     SETC  'LIB1'                   SET VALUE FOR &LIB              01800000
*********************************************************************** 02400000
*                                                                       03000000
*                                                                       03600000
*          RELEASE 21 DELETIONS/CHANGES                                 04200000
*0000870000                                                      M0037  04500021
*          RELEASE 22 DELETIONS/CHANGES                                 04800000
*          RELEASE 23 DELETIONS/CHANGES                                 05400000
*          RELEASE 24 DELETIONS/CHANGES                                 06000000
*          RELEASE 25 DELETIONS/CHANGES                                 06600000
*                                                                       07200000
* STATUS CHANGE LEVEL 000                                               07800000
*                                                                       08400000
* FUNCTION -                                                            09000000
*    THIS MODULE TRACES THE USER'S DCB AND THE OPEN/CLOSE/EOV           09600000
*    WKAREA ON A MODULE BY MODULE BASIS THROUGHOUT MAINLINE             10200000
*    OPEN/CLOSE/EOV.  IT USES THE GTRACE MACRO TO CALL GTF              10800000
*    TO PERFORM THE TRACE FUNCTION.  UPON ENTRY, IT PICKS               11400000
*    UP THE BUFFER POINTER FROM OFFSET -4 OF THE ECBLIST.               12000000
*    IT MOVES THE DCB POINTED TO BY RDCB TO THE BUFFER AND              12600000
*    ISSUES GTRACE.  IT THEN TRACES THE OPEN/CLOSE/EOV WKAREA           13200000
*    IN FOUR PARTS IN A SIMILAR MANNER.  FINALLY IT TRACES              13800000
*    THE WTG TABLE AND CURRENT ENTRY FROM REGS 6 AND 8 AND              14400000
*    RETURNS TO THE RESIDENT ROUTINE.                                   15000000
*                                                                       15600000
* ENTRY POINTS -                                                        16200000
*    IFG019TR VIA BALR FROM IFG019RA                                    16800000
*                                                                       17400000
* INPUT -                                                               18000000
*    RDCB POINTS TO THE USER'S DCB                                      18600000
*    RCORE POINTS TO THE OPEN/CLOSE/EOV WKAREA                          19200000
*    RWTG POINTS POINTS TO THE WTG TABLE                                19800000
*    RWTGC POINTS TO THE CURRENT ENTRY IN THE WTG TABLE                 20400000
*    RTIOT POINTS TO TRACE PARALIST                                     21000000
*                                                                       21600000
* OUTPUT -                                                              22200000
*    DCB, WORKAREA WTG TABLE BASE AND CURRENT ENTRY ARE TRACED VIA GTF  22800000
*                                                                       23400000
* EXTERNAL REFERENCES - N/A                                             24000000
*                                                                       24600000
* EXITS, NORMAL -                                                       25200000
*    RETURN VIA REG 14 TO CALLER                                        25800000
*                                                                       26400000
* EXITS, ERROR - N/A                                                    27000000
*                                                                       27600000
* TABLES/WORK AREAS -                                                   28200000
*    REFER TO THE DSECTS AT THE END OF THE LISTING.                     28800000
*                                                                       29400000
* ATTRIBUTES -                                                          30000000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVELEGED             30600000
*                                                                       31200000
* CHARACTER CODE DEPENDENCY                                             31800000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC                   32400000
*    CHARACTER CODE WAS USED FOR ASSEMBLY.  THE MODULE MUST             33000000
*    BE REASSEMBLED IF A DIFFERENT CHARACTER SET IS USED                33600000
*    FOR EXECUTION.                                                     34200000
*                                                                       34800000
* NOTES - N/A                                                           35400000
*                                                                       36000000
*********************************************************************** 36600000
         EJECT                                                          37200000
IFG019TR CSECT                                                          37800000
R0       EQU   0                        WORK/PARAMETER REG              38400000
R1       EQU   1                        WORK/PARAMETER REG              39000000
RDCB     EQU   2                        PTR TO DCB                      39600000
RBASE    EQU   3                        BASE REG                        40200000
RCORE    EQU   4                        PTR TO O/C/EOV WKAREA           40800000
RES      EQU   5                        PTR TO RESIDENT RTN             41400000
RWTG     EQU   6                        PTR TO WTG TABLE                42000000
RPARC    EQU   7                        PTR TO PARALIST CURRENT ENTRY   42600000
RWTGC    EQU   8                        PTR TO WTG TABLE CURRENT ENTRY  43200000
RTIOT    EQU   9                        PTR TO TIOT ENTRY               43800000
RUCB     EQU   10                       PTR TO UCB                      44400000
RB       EQU   11                       WORK/PARAMETER REG              45000000
RC       EQU   12                       WORK/PARAMETER REG              45600000
RD       EQU   13                       WORK/PARAMETER REG              46200000
RET      EQU   14                       WORK/PARAMETER REG              46800000
RF       EQU   15                       WORK/PARAMETER REG              47400000
FOUR     EQU   4                        WORK VALUE                      48000000
EIGHT    EQU   8                        WORK VALUE                      48600000
ORG      EQU   0                        WORK VALUE                      49200000
NINE     EQU   9                        WORK VALUE                      49800000
ONE      EQU   1                        WORK VALUE                      50400000
DCBLNG   EQU   96                       LNG OF DCB TRACED               51000000
WKAREA1  EQU   72                       TRACE CODE FOR START OF WKAREA  51600000
WKAREA2  EQU   76                       TRACE CODE FOR 2ND PART OF      52200000
*                                       O/C/EOV WKAREA                  52800000
WKAREA3  EQU   80                       TRACE CODE FOR THIRD PART OF    53400000
*                                       O/C/EOV WKAREA                  54000000
WKAREA4  EQU   84                       TRACE CODE FOR FOURTH PART OF   54600000
*                                       O/C/EOV WKAREA                  55200000
WTGCOD   EQU   X'60'                    TRACE CODE FOR WTG TABLE        55800000
DCBTCODE EQU   40                       TRACE CODE FOR DCB              56400000
EQUAL    EQU   8                        BRANCH CONDITION                57000000
         BALR  RC,R0                    USE R 12 AS BASE SO AS NOT TO   57600000
*                                       DESTROY REG 3                   58200000
         USING *,RC                                                     58800000
         USING FORCORE,RCORE                                            59400000
         USING WTG,RWTG                                                 60000000
         L     R1,FOUR(RTIOT)           PTR TO TRACE BUFFER             60600000
         LA    RF,DCBLNG+ONE            LENGTH OF DCB TO BE TRACED      61200000
         STH   RF,ORG(R1)               STORE IN TRACE PARALIST         61800000
         MVI   EIGHT(R1),DCBTCODE       MOVE DCB CODE TO BUFFER         62400000
         MVC   NINE(DCBLNG,R1),ORG(RDCB)                                63000000
*                                       MOVE DCB TO TRACE BUFFER        63600000
         BAL   RD,PDF80010              TRACE DCB                       64200000
         LA    RF,DXJBF-DXDSCB+ONE      LNG OF 1ST PART OF WKAREA       64800000
*                                       TO BE TRACED                    65400000
         STH   RF,ORG(R1)               STORE IN TRACE PARMLIST         66000000
         MVI   EIGHT(R1),WKAREA1        MOVE CODE TO BUFFER             66600000
         MVC   NINE(DXJBF-DXDSCB,R1),DXDSCB                             67200000
*                                       MOVE DSCB FROM WKAREA TO BUFFER 67800000
         BAL   RD,PDF80010              TRACE DSCB                      68400000
         LA    RF,JFCBEND-DXJBF+ONE     LNG OF JFCB                     69000000
         STH   RF,ORG(R1)               STORE IN BUFFER                 69600000
         MVI   EIGHT(R1),WKAREA2        MOVE CODE TO BUFFER             70200000
         MVC   NINE(JFCBEND-DXJBF,R1),DXJBF                             70800000
*                                       MOVE JFCB TO BUFFER             71400000
         BAL   RD,PDF80010              TRACE JFCB                      72000000
         LA    RF,DXCCW-DXECB+ONE       LNG OF ECB, IOB, DEB            72600000
         STH   RF,ORG(R1)               STORE IN BUFFER                 73200000
         MVI   EIGHT(R1),WKAREA3        MOVE CODE TO WKAREA             73800000
         MVC   NINE(DXCCW-DXECB,R1),DXECB                               74400000
*                                       MOVE ECB, IOB, DEB TO BUFFER    75000000
         BAL   RD,PDF80010              TRACE ECB, IOB, DEB             75600000
         LA    RF,DXDCBLST+FOUR-DXCCW+ONE                               76200000
*                                       LNG OF CCWS AND EXTENDED W/A    76800000
         STH   RF,ORG(R1)               STORE IN BUFFER                 77400000
         MVI   EIGHT(R1),WKAREA4        MOVE CODE TO BUFFER             78000000
         MVC   NINE(DXDCBLST+FOUR-DXCCW,R1),DXCCW                       78600000
*                                       MOVE CCWS TO WKAREA             79200000
         BAL   RD,PDF80010              GO TRACE CCWS                   79800000
         LA    RB,DXXAREA               PTR TO EOV WTG TABLE            80400000
         CR    RWTG,RB                  ARE WE IN EOV                   81000000
         BCR   EQUAL,RET                IF YES, RETURN TO CALLER        81600000
*                                       WTG TABLE FOR EOV IS INCLUDED   82200000
*                                       IN THE EOV WKAREA               82800000
         LA    RF,WTGENTRY-WTG+EIGHT+ONE                                83400000
*                                       LENGHT OF WTG TABLE TRACE       84000000
         STH   RF,ORG(R1)               STORE IN BUFFER                 84600000
         MVI   EIGHT(R1),WTGCOD         MOVE CODE OF WTGTBL TO BUFFER   85200000
         MVC   NINE(WTGENTRY-WTG,R1),WTG                                85800000
*                                       MOVE WTG TBL BASE TO BUFFER     86400000
         MVC   WTGENTRY-WTG+NINE(EIGHT,R1),ORG(RWTGC)            M0037  87000021
*                                       MOVE CURRENT ENTRY TO BUFFER    87600000
         BAL   RD,PDF80010              TRACE WTG TABLE                 88200000
         BR    RET                      RETURN TO RESIDENT RTN          88800000
PDF80010 EQU   *                                                        89400000
         GTRACE ID=4095,MF=(E,(1))      TRACE DATA IN BUFFER            90000000
         BR    RD                       RETURN TO CALLER                90600000
         IECDSECS MAIN,WTG,EXPAND=YES                                   91200000
         END                                                            91800000
