         TITLE 'IFG0202A - USER LABEL TAPE TRAILER PROCESSING'          00100000
         COPY  LCGASMSW                                                 00200000
IFG0202A CSECT                                                          00400021
*********************************************************************** 00500021
*                                                                     * 00600021
*          VS1 RELEASE 03.1 DELETIONS/CHANGES                         * 00650021
*SEE SA69185                                                    XA04640 00660021
*                                                                     * 00700021
*          RELEASE 25 DELETIONS/CHANGES                               * 00800021
*          RELEASE 24 DELETIONS/CHANGES                               * 00900021
*          RELEASE 23 DELETIONS/CHANGES                               * 01000021
*          RELEASE 22 DELETIONS/CHANGES                               * 01100021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 01110021
*0000420000,425000-434000                                       SA69185 01120021
*          RELEASE 21 DELETIONS/CHANGES                               * 01200021
*0000431000                                                     SA55619 01250000
*0000330000-331000,340000,344000,345000,368000,370000,          SA57218 01260001
*    374000-384000                                              SA57218 01270001
*                                                                     * 01300021
* STATUS CHANGE LEVEL 000                                             * 01400021
*                                                                     * 01500021
* FUNCTION -                                                          * 01600021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 01700021
*    CLOSE TAPE STANDARD USER LABEL FUNCTION.                         * 01800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 01900021
*                                                                     * 02000021
* ENTRY POINTS -                                                      * 02100021
*         IFG0202A - ENTRY POINT VIA AN XCTL FROM THE FOLLOWING--     * 02200021
*             INITIAL ENTRY--                                         * 02300021
*                IFG0200Z - PROCESS CLOSE TAPE STANDARD USER LABEL    * 02400021
*                           FUNCTION.                                 * 02500021
*             SECOND ENTRY--                                          * 02600021
*                IFG0200Y - PROCESS CLOSE TAPE STANDARD USER LABEL    * 02700021
*                           FUNCTION.                                 * 02800021
*             THIRD ENTRY--                                           * 02900021
*                IFG0200P - CONTINUE PROCESSING CLOSE TAPE STANDARD   * 03000021
*                           USER LABEL FUNCTION.                      * 03100021
*                                                                     * 03200021
* INPUT -                                                             * 03300021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03400021
*                                                                     * 03500021
* OUTPUT -                                                            * 03600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03700021
*                                                                     * 03800021
* EXTERNAL REFERENCES -                                               * 03900021
*         IFG020RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 04000021
*                    WAIT.                                            * 04100021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04200021
*                                                                     * 04300021
* EXITS, NORMAL -                                                     * 04400021
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING--            * 04500021
*         IFG0202F - PROCESS CLOSE TAPE VOLUME STATISTICS FUNCTION.   * 04600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04700021
*                                                                     * 04800021
* EXITS, ERROR -                                                      * 04900021
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0200P, IF AN      * 05000021
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 05100021
*    'FUNCTION PROLOG(S)'.                                            * 05200021
*                                                                     * 05300021
* TABLES/WORK AREAS -                                                 * 05400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05500021
*                                                                     * 05600021
* ATTRIBUTES -                                                        * 05700021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 05800021
*                                                                     * 05900021
* CHARACTER CODE DEPENDENCY -                                         * 06000021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 06100021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 06200021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 06300021
*                                                                     * 06400021
* NOTES -                                                             * 06500021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06600021
*                                                                     * 06700021
*********************************************************************** 06800021
         EJECT                                                          06900021
         USING IHADCB,RDCB                                              07000021
         USING FORCORE,RCORE                                            07100021
         USING TCB,RET                                                  07200021
         USING CVT,RD                                                   07300021
         USING DEB,RDEB                                                 07400021
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         07500021
         USING *,RBASE                                                  07600021
         EJECT                                                          07700021
*********************************************************************** 07750021
*                                                                     * 07800021
*                          FUNCTION PROLOG                            * 07900021
*                                                                     * 08000021
*********************************************************************** 08100021
*                                                                     * 08200021
* FUNCTION NAME -                                                     * 08300021
*    CLOSE TAPE STANDARD USER LABEL FUNCTION.                         * 08400021
*                                                                     * 08500021
* (STATUS) -                                                          * 08600021
*    NOT APPLICABLE                                                   * 08700021
*                                                                     * 08800021
         AIF   ('&LIB' NE 'LIB1').LIB22A0                               08850000
* FUNCTION -                                                          * 08900021
*    DETERMINE IF USER LABEL PROCESSING IS REQUIRED.                  * 09000021
*    GET MAIN FOR AREA TO BE USED FOR -                               * 09100021
*    1) 72 BYTE WORK AREA                                             * 09200021
*    2) 80 BYTE LABEL BUFFER                                          * 09300021
*    3) 16 BYTE PARAMETER LIST                                        * 09400021
*    IF INPUT HEADER OR TRAILER ARE REQUESTED, THIS FUNCTION READS    * 09500021
*    THE USER LABELS AND PASSES THEM IN LABEL BUFFER TO APPROPRIATE   * 09600021
*    USER EXIT VIA THE SYNCH MACRO. UPON RETURN, A CONDITION CODE     * 09700021
*    IS EXAMINED. IF 4, CONTINUE TO READ LABELS, IF 0, EXIT.          * 09800021
*    IF OUTPUT HEADER OR TRAILER ARE REQUESTED, THIS FUNCTION FIRST   * 09900021
*    SYNCHS TO APPROPRIATE USER EXIT TO FORMAT USER LABELS AND UPON   * 10000021
*    RETURN, REACTS ACCORDING TO THE CODE RETURNED BY THE USER -      * 10100021
*    0 - DO NOT WRITE LABEL, DISCONTINUE USER LABEL PROCESSING (I.E.  * 10200021
*        RETURN TO CALLER OF THIS ROUTINE),                           * 10300021
*    4 - WRITE LABEL, THEN DISCONTINUE UL PROCESSING,                 * 10400021
*    8 - WRITE LABEL, AND IF LESS THAN 8 LABELS HAVE BEEN CREATED,    * 10500021
*        RETURN TO USER. IF 8 LABELS HAVE BEEN CREATED, UL PROCESSING * 10600021
*        IS ENDED.                                                    * 10700021
*    FOR ASCII TAPE, LABELS ARE TRANSLATED BEFORE WRITING.            * 10800021
*                                                                     * 10900021
.LIB22A0 ANOP                                                           10910000
         AIF   ('&LIB' EQ 'LIB1').LIB12A0                               10920000
* FUNCTION -                                                          * 10950000
*    DETERMINE IF USER LABEL PROCESSING IS REQUIRED.                  * 10960000
*    GET MAIN FOR AREA TO BE USED FOR -                               * 10970000
*    1) 72 BYTE WORK AREA                                             * 10980000
*    2) 80 BYTE LABEL BUFFER                                          * 10990000
*    3) 16 BYTE PARAMETER LIST                                        * 10992000
*    IF INPUT HEADER OR TRAILER ARE REQUESTED, THIS FUNCTION READS    * 10994000
*    THE USER LABELS AND PASSES THEM IN LABEL BUFFER TO APPROPRIATE   * 10996000
*    USER EXIT VIA THE SYNCH MACRO. UPON RETURN, A CONDITION CODE     * 10998000
*    IS EXAMINED. IF 4, CONTINUE TO READ LABELS, IF 0, EXIT.          * 10998400
*    IF OUTPUT HEADER OR TRAILER ARE REQUESTED, THIS FUNCTION FIRST   * 10998800
*    SYNCHS TO APPROPRIATE USER EXIT TO FORMAT USER LABELS AND UPON   * 10999200
*    RETURN, REACTS ACCORDING TO THE CODE RETURNED BY THE USER -      * 10999600
*    0 - DO NOT WRITE LABEL, DISCONTINUE USER LABEL PROCESSING (I.E.  * 10999700
*        RETURN TO CALLER OF THIS ROUTINE),                           * 10999800
*    4 - WRITE LABEL, THEN DISCONTINUE UL PROCESSING,                 * 10999900
*    8 - WRITE LABEL, AND IF LESS THAN 8 LABELS HAVE BEEN CREATED,    * 11033200
*        RETURN TO USER. IF 8 LABELS HAVE BEEN CREATED, UL PROCESSING * 11043200
*        IS ENDED.                                                    * 11053200
*    FOR ASCII TAPE, LABELS ARE TRANSLATED BEFORE WRITING.            * 11063200
*    DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A DEB VALIDITY CHECK   * 11063600
*    ROUTINE WHICH MAINTAINS AND UPDATES A TABLE OF VALID DEB POINTERS* 11064000
*    IN PROTECTED CORE (LSQS).                                        * 11064400
*                                                                     * 11065200
.LIB12A0 ANOP                                                           11065600
* ENTRY POINTS -                                                      * 11066700
*    ENTERED FROM THE FOLLOWING--                                     * 11100021
*    CLOSE TAPE ACCESS METHOD EXECUTOR INTERFACE FUNCTION.            * 11200021
*    CLOSE TAPE STANDARD TRAILER LABEL FUNCTION.                      * 11300021
*                                                                     * 11400021
* INPUT -                                                             * 11500021
*    A POINTER TO EACH OF THE FOLLOWING--                             * 11600021
*       CURRENT PARAMETER LIST ENTRY.                                 * 11700021
*       DD ENTRY IN THE TIOT.                                         * 11800021
*       WTG TABLE.                                                    * 11900021
*       CURRENT WTG TABLE ENTRY.                                      * 12000021
*       DCB.                                                          * 12100021
*       CLOSE WORK AREA.                                              * 12200021
*       RESIDENT ROUTINE.                                             * 12300021
*       UCB.                                                          * 12400021
*       DEB.                                                          * 12500021
*                                                                     * 12600021
* OUTPUT -                                                            * 12700021
*    USER LABELS READ OR WRITTEN ON TAPE FOR USER.                    * 12800021
*    THE TAPE IS LEFT POSITIONED -                                    * 12900021
*    1) BEYOND THE LAST UL PROCESSED, OR                              * 13000021
*    2) IF NO UL, BEYOND THE DATA SET LABELS.                         * 13100021
*                                                                     * 13200021
* EXTERNAL REFERENCES -                                               * 13300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 13400021
*    USER'S EXIT ROUTINES - ENTERED BY MEANS OF SYNCHRONOUS EXIT      * 13500021
*    (SVC 12).                                                        * 13600021
*                                                                     * 13700021
* EXITS, NORMAL -                                                     * 13800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 13900021
*    CLOSE TAPE VOLUME STATISTICS FUNCTION.                           * 14000021
*                                                                     * 14100021
* EXITS, ERROR -                                                      * 14200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 14300021
*    EXIT WITH THE FOLLOWING INTERNAL CODE--                          * 14400021
*       64 - 214 ABEND - ERROR IN READING USER LABEL.                 * 14500021
*    IF THERE IS A READ/WRITE ERROR, THIS FUNCTION SYNCHS TO USER     * 14600021
*    WITH A PARAMETER LIST WHICH (IN THE THIRD ENTRY) CONTAINS AN     * 14700021
*    ERROR FLAG AND A POINTER TO STATUS INFO (CSW STATUS). AFTER THE  * 14800021
*    USER HAS HAD THE OPPORTUNITY TO EXAMINE ERROR INFO, THIS         * 14900021
*    FUNCTION REACTS AS FOLLOWS -                                     * 15000021
*    1) OUTPUT ERROR - UL PROCESSING IS ENDED                         * 15100021
*    2) INPUT ERROR - USER RETURNS A CODE OF 0 OR 4                   * 15200021
*       0 - DISCONTINUE UL PROCESSING                                 * 15300021
*       4 - READ NEXT LABEL IF LESS THAN 8 HAVE BEEN READ. IF 8 UL    * 15400021
*           HAVE BEEN READ, UL PROCESSING IS ENDED.                   * 15500021
*                                                                     * 15600021
* TABLES/WORK AREAS -                                                 * 15700021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 15800021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 15900021
*                                                                     * 16000021
* ATTRIBUTES -                                                        * 16100021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16200021
*                                                                     * 16300021
* CHARACTER CODE DEPENDENCY -                                         * 16400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16500021
*                                                                     * 16600021
* NOTES -                                                             * 16700021
*    NOT APPLICABLE                                                   * 16800021
*                                                                     * 16900021
*********************************************************************** 17000021
         EJECT                                                          17100021
         B     CTA03000(RET)            USE BRANCH TABLE                17200021
CTA03000 EQU   *                                                        17300021
         B     CTA03200                 ENTRY FROM SL PROCESSING        17400021
         B     CTA03100                 ENTRY FROM RETURN OF EXECUTOR   17500021
         B     CTA03300                 ENTRY FROM P.D. MOD             17600021
CTA03100 EQU   *                                                        17700021
         LA    RC,SLPSUP                PT TO 'DEFERRED PROCESSING'     17800021
         B     CTA03400                 BR TO CHK EXIT LIST FOR CODE    17900021
CTA03200 EQU   *                                                        18000021
         IECRES WAIT                    WAIT FOR TRL2                   18100021
         TM    IOBSTAT0,CSWUNITX        UNIT EXCEPTION                  18200021
         BO    CTA03300                 BRANCH IF YES                   18300021
         TM    DXECB,ECBNOERR           PERM. I/O ERROR                 18400021
         BC    12,CTA06500              BRANCH IF ERROR                 18500021
CTA03300 EQU   *                                                        18600021
*                                                                       18700021
*****          INITIALIZE FOR SUL EXIT-LIST CODE CHECK                  18800021
*                                                                       18900021
         LA    RC,EXIT4                 PT TO OUTPUT USER TRAILER LABEL 19000021
CTA03400 EQU   *                                                        19100021
         L     RF,DCBEXLST              LOAD EXIT LIST ADDR FROM DCB    19200021
         LA    RF,0(,RF)                ZERO HIGH-ORDER BYTE OF EXLST   19300021
         LTR   RF,RF                    IS THE EXIT LIST ADDR ZERO-     19400021
         BZ    CTA05300                 YES, DON'T PROCESS USER LABELS  19500021
CTA03500 EQU   *                                                        19600021
         CLC   0(K1,RF),0(RC)           DO CODE BYTES MATCH-            19700021
         BE    CTA03600                 BR IF YES TO PROCESS USER       19800021
         CLC   0(K1,RF),K1(RC)          CHECK AGAIN ('LAST ENTRY' BIT)  19900021
         BE    CTA03600                 BR IF YES TO PROCESS USER       20000021
         TM    0(RF),LASTNTRY           TEST FOR LAST EXIT LIST ENTRY-  20100021
         LA    RF,K4(,RF)               INCREMENT TO NEXT ENTRY         20200021
         BC    12,CTA03500              BR IF NOT LAST TO CHK NEXT      20300021
         B     CTA05300                 BR TO POSITION TAPE- NO UL      20400021
CTA03600 EQU   *                                                        20500021
         L     RC,0(,RF)                EXIT LIST ENTRY                 20600021
         LA    RF,0(,RC)                ZERO HI-ORDER BYTE              20700021
         LTR   RF,RF                    IS EXIT ADDRESS ZERO-           20800021
         BZ    CTA05300                 YES, DON'T PROCESS USER LABELS  20900021
         GETMAIN R,LV=USERL,SP=250      GETMAIN FOR UL WORKAREA         21000021
*                                                                       21100021
         USING ULWK,R1                                                  21200021
         STM   RES,RC,ULWK              SAVE REGS (INCLUDES DCB EXIT    21300021
*                                 LIST ENTRY FOR USER LABEL PROCESSING) 21400021
         DROP  R1                                                       21500021
         LR    RC,R1                    POINT TO AREA OBTAINED          21600021
         USING ULWK,RC                                                  21700021
         LA    R1,CHAR0                 INITIALIZE COUNT                21800021
         STH   R1,ULCNT                 AND SAVE FOR LATER USE          21900021
         NI    ULREQ,X'FF'-LASTNTRY     ZERO HI-ORDER BIT OF UL ENTRY   22000021
*******************************************************************     22100021
*        TEST FOR NEW CODE BYTE X'0C' . IF PRESENT,LABEL PROCESS-       22200021
*        ING WILL BE DEFERRED AT EOF AND NOT AT EOV.                    22300021
*******************************************************************     22400021
         CLI   ULREQ,XLDEFSL            DEFERRED LABEL PROCESSING       22500021
         BE    CTA04300                 YES,PERFORM NORMAL PROCESSING   22600021
*                                       SINCE THIS MODULE WILL NOT      22700021
*                                       BE ENTERED AT EOF(DEFERRED).    22800021
         EJECT                                                          22900021
*  OUTPUT LABEL PROCESSING                                              23000021
         MVI   ULBUFR,BLANK             SET LABEL BUFFER AREA           23100021
         MVC   ULBUFR+K1(L'ULBUFR-K1),ULBUFR  TO BLANKS                 23200021
CTA03700 EQU   *                                                        23300021
         TM    JFCBLTYP,JFCBAL+JFCBUL   ANSI USER LABELS SPEC.          23400021
         BO    CTA03800                 YES,SKIP LABEL COUNTING         23500021
         LH    R1,ULCNT                 PICK UP PREVIOUS COUNT          23600021
         LA    R1,K1(,R1)               INCREMENT BY 1                  23700021
         STH   R1,ULCNT                 SAVE UPDATED COUNT              23800021
         CLI   ULCNT+K1,MAXNOLAB        TEST,BR IF MAX NBR OF UL        23900021
         BH    CTA05200                 ALREADY PROCESSED               24000021
CTA03800 EQU   *                        INITIALIZE BUFFER HEADING       24100021
         MVC   ULBUFR(K3),UTLCON        INITIALIZE FIRST 4 CHAR OF      24200021
         MVC   ULBUFR+K3(K1),ULCNT+K1   ESTABLISH LABEL NUMBER IN BUFFR 24300021
         BAL   RB,CTA05400              GO TO SYNCH TO USER             24400021
*                                                                       24500021
*                                                                       24600021
         LTR   RF,RF                    TEST,BR IF LABEL NOT            24700021
         BZ    CTA05200                 TO BE WRITTEN                   24800021
*                                                                       24900021
*  RESET FIRST 4 CHAR OF LABEL THEN                                     25000021
*  ESTABLISH CHANNEL PROGRAM TO WRITE USER LABEL                        25100021
*                                                                       25200021
         MVC   ULBUFR(K3),UTLCON        SET 'UTL' IN LABEL              25300021
         TM    JFCBLTYP,JFCBAL+JFCBUL   IF 'AUL' SPECIFIED,BYPASS       25400021
         BO    CTA03900                 RESTORING LABEL NUMBER          25500021
         MVC   ULBUFR+K3(K1),ULCNT+K1   LABEL NUMBER IN LABEL           25600021
CTA03900 EQU   *                        POINT TO LABEL BUFFER           25700021
         LA    R1,ULBUFR                POINT CCW TO LABEL BUFFER       25800021
         ST    R1,DXCCW1                STORE IN CCW                    25900021
         MVI   DXCCW1,CCWWRTAP          WRITE OP-CODE TO CCW            26000021
         MVC   DXCCW1+K4(K4),LENGTH     80-CHAR LENGTH                  26100021
         TM    JFCBLTYP,JFCBAL+JFCBUL   ANSI USER LABELS SPEC.          26200021
         BNO   CTA04000                 NO,BYPASS TRANSLATE             26300021
* TRANSLATE LABEL BUFFER DATA BEFORE WRITING                            26400021
         XLATE (R1),K80,TO=A            TRANSLATE USER LABEL            26500021
CTA04000 EQU   *                        GO WRITE LABEL                  26600021
         BAL   RB,CTA06300              GO TO ISSUE EXCP                26700021
*  ERROR CHECKING                                                       26800021
         BZ    CTA04100                 BR IF NO UNIT EXCEPTION (I.E.   26900021
*                                       WRITING BEYOND EOT REFLECTOR)   27000021
         OI    DXECB,ECBCOD7F           IGNORE UF FOR TRAILERS          27100021
CTA04100 TM    DXECB,ECBNOERR           TEST FOR UNCORRECTABLE I/O ERR  27200021
         BNZ   CTA04200                 NO ERROR ENCOUNTERED.           27300021
*                                                                       27400021
*  ERROR WHEN ATTEMPTING TO WRITE LABEL.  GO TO USER WITH ERROR         27500021
*  INDICATIONS, THEN TERMINATE UL PROCESSING (RETURN CODE NOT           27600021
*  EXAMINED).                                                           27700021
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   27800021
         ST    R1,ULERRPTR              IN PARAMETER LIST               27900021
         OI    ULERRPTR,ERROR           FLAG IN ERROR                   28000021
         BAL   RB,CTA05500              GO TO SYNCH TO USER (BUFFER     28100021
*                                       CONTAINS LABEL UNABLE TO WRITE) 28200021
*                                                                       28300021
*  NOTE - CLOSE (AND TCLOSE) PROCESS USER LABELS PRIOR TO               28400021
*  TURNING OFF OPENED BIT IN DCBOFLGS.                                  28500021
         B     CTA05200                 UL PROCESSING COMPLETED         28600021
CTA04200 EQU   *                                                        28700021
         CLI   ULRETCOD,WRITNEXT        TEST,BR IF USER RETURNED A CODE 28800021
         BE    CTA03700                 TO CONTINUE UL PROCESSING       28900021
*  OTHERWISE, IT IS ASSUMED THE USER RETURNED A CODE = 4, I.E. NO       29000021
*  FURTHER UL PROCESSING.                                               29100021
         B     CTA05200                 UNCONDITIONAL BRANCH            29200021
         EJECT                                                          29300021
CTA04300 EQU   *                                                        29400021
*  INPUT LABEL PROCESSING                                               29500021
*                                                                       29600021
*                                                                       29700021
         LA    R1,ULBUFR                POINT CCW TO LABEL BUFFER       29800021
         ST    R1,DXCCW1                STORE IN CCW                    29900021
         MVI   DXCCW1,CCWRDTAP          READ OP-CODE TO CCW             30000021
         MVC   DXCCW1+K4(K4),LENGTH     80-CHAR LENGTH                  30100021
CTA04400 EQU   *                                                        30200021
         BAL   RB,CTA06300              GO TO ISSUE EXCP                30300021
*                                                                       30400021
         BO    CTA04900                 BR IF UNIT EXCEPTION ON READ    30500021
*                                       (READ TAPE MARK)                30600021
         TM    DXECB,ECBNOERR           TEST,BR IF PERM I/O ERR         30700021
         BZ    CTA04800                 ENCOUNTERED                     30800021
*                                                                       30900021
         TM    JFCBLTYP,JFCBAL+JFCBUL   ANSI USER LABELS SPEC.          31000021
         BNO   CTA04500                 NO,BYPASS TRANSLATE             31100021
*  TRANSLATE LABEL BEFORE PROCESSING                                    31200021
         XLATE ULBUFR,K80               TRANSLATE                       31300021
CTA04500 EQU   *                        CHECK LABEL TYPE                31400021
         CLC   ULBUFR(K3),UHLCON        TEST, BR IF USER HEADER LABEL   31500021
         BE    CTA04600                 WAS READ                        31600021
         CLC   ULBUFR(K3),UTLCON        TEST, BR IF USER TRAILER LABEL  31700021
         BE    CTA04600                 WAS READ                        31800021
*  NOTE - INPUT TRAILER LABEL PROCESSING LEAVES TAPE POSITIONED BETWEEN 31900021
*  FIRST AND SECOND DATA SET TRAILER.                                   32000021
*  THE FOLLOWING ALLOWS PROCESSING OF USER LABELS EVEN THOUGH THE       32100021
*  TAPE MAY CONTAIN MORE DATA SET LABELS THAN CAN CURRENTLY BE          32200021
*  CREATED UNDER O/S.                                                   32300021
         CLC   ULBUFR(K3),EOV           TEST, BR(I.E., READ AGAIN)      32400021
         BE    CTA04400                 IF TRAILER WAS READ             32500021
         CLC   ULBUFR(K3),AEOF          TEST, BR(I.E., READ AGAIN)      32600021
         BE    CTA04400                 IF TRAILER WAS READ             32700021
         CLC   ULBUFR(K3),HDR           TEST  BR(I.E., READ AGAIN)      32800021
         BE    CTA04400                 IF HEADER WAS READ              32900021
         B     CTA05200                 UNCONDITIONAL BRANCH    SA57218 33100001
*                                                                       33200021
*                                                                       33300021
*                                                                       33400021
CTA04600 EQU   *                                                        33500021
         MVC   ULCNT+K1(K1),ULBUFR+K3   SAVE LABEL NUMBER               33600021
         BAL   RB,CTA05400              GO TO SYNCH TO USER             33700021
CTA04700 EQU   *                                                        33800021
         CLI   ULRETCOD,READNEXT        TEST,BR IF USER DID NOT RETURN  33900021
         BNE   CTA04750                 CODE TO READ NEXT LABEL SA57218 34000001
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI LABELS SPEC.          34100021
         BO    CTA04400                 YES,GO READ ANOTHER             34200021
         CLI   ULCNT+K1,MAXNOLAB        TEST,BR IF MAX NBR OF USER      34300021
         BL    CTA04400                 BR TO READ NEXT RECORD  SA57218 34500001
*                                                                       34550001
* DONE WITH LABEL PROCESSING, BUT HAVE NOT READ A TAPE MARK.    SA57218 34560001
* NOW POSITION TO LOGICAL END OF FILE BY SPACING PAST THE       SA57218 34570001
* TAPEMARK AT THE END OF THE TRAILER LABEL SET.                 SA57218 34580001
*                                                                       34590001
CTA04750 EQU   *                                                SA57218 34592001
         MVI   DXCCW1,CCWFSF            FORWARD SPACE OPCODE    SA57218 34594001
         MVI   DXCCW1+K7,K1             SET COUNT TO ONE        SA57218 34596001
         BAL   RB,CTA06300              GO TO ISSUE EXCP        SA57218 34598001
*        THE ABOVE IMMEDIATE OPERATION MAY RETURN               SA57218 34598401
*        A CONTROL UNIT OR DEVICE ERROR AFTER CHANNEL END       SA57218 34598801
*        HAS BEEN POSTED.                                       SA57218 34599201
         TM    DXECB,ECBNOERR           TEST FOR I/O ERROR      SA57218 34599601
         BNO   CTA06400                 GO TO ABEND ROUTINE     SA57218 34599701
         B     CTA05200                 FREEMAIN IF NO ERROR    SA57218 34599801
*                                                                       34600021
CTA04800 EQU   *                                                        34700021
*  ERROR ENCOUNTERED DURING READ                                        34800021
*                                                                       34900021
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   35000021
         ST    R1,ULERRPTR              IN PARAMETER LIST               35100021
         OI    ULERRPTR,ERROR           FLAG ERROR                      35200021
         LH    R1,ULCNT                 UPDATE LABEL NUMBER             35300021
         LA    R1,K1(,R1)               BY 1                            35400021
         STH   R1,ULCNT                 SAVE UPDATED LABEL NUMBER       35500021
         STC   R1,ULBUFR+K3             PASS NO OF LABEL UNABLE TO READ 35600021
         LA    RB,CTA04700              TO USER - SYNCH TO USER THEN    35700021
         B     CTA05500                 RETURN TO TEST RETURN CODE.     35800021
*                                                                       35900021
CTA04900 EQU   *                                                        36000021
*  TAPE MARK READ.  IF USER HAS PROCESSED ANY PREVIOUS LABELS,          36100021
*  FREEMAIN AND RETURN TO CALLER.                               SA57218 36200001
*  IF USER HAS NOT PROCESSED ANY PREVIOUS LABELS, SYNCH TO USER         36300021
*  WITH LABEL BUFFER POINTER SET TO ZERO, THEN                  SA57218 36400001
*  FREEMAIN AND RETURN TO CALLER.                                       36500021
*                                                                       36600021
         CLI   ULCNT+K1,CHAR0           TEST,BR IF PREVIOUS LABELS      36700021
         BH    CTA05200                 HAVE BEEN PROCESSED     SA57218 36800001
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE AUL'S SPECIFIED            36900021
         BO    CTA05200                 YES, BRANCH-CONTINUE    SA57218 37000001
         XC    ULERRPTR,ULERRPTR        ZERO ERROR PARM                 37100021
         SR    R1,R1                    ZERO BUFFER PTR                 37200021
         BAL   RB,CTA05600              GO TO SYNCH TO USER             37300021
*                                                                       38500021
CTA05200 EQU   *                                                        38600021
*  ESTABLISH NAME OF ROUTINE WHICH CALLED THIS ROUTINE, THEN            38700021
*  FREEMAIN AND RETURN TO CALLER.                                       38800021
*                                                                       38900021
         LR    R1,RC                    PTR TO AREA TO BE FREED         39000021
         LM    RES,RC,ULWK              RESTORE REGS 5-10 AND 12        39100021
         FREEMAIN R,LV=USERL,SP=250,A=(1)  FREE USER LABEL WORK AREA,   39200021
*                                  LABEL BUFFER AND PARAMETER LIST AREA 39300021
*                                                                       39400021
*****          TEST FOR RETURN FROM UL PROCESSING ROUTINES              39500021
*                                                                       39600021
CTA05300 EQU   *                                                        39700021
         SR    RET,RET                  SET UP FOR BRANCH TABLE         39800021
         IECRES XCTL,VOLDPMOD,(RET)     XCTL TO VOLDPMOD                39900021
         EJECT                                                          40000021
CTA05400 EQU   *                                                        40100021
         XC    ULERRPTR,ULERRPTR        ZERO ERROR IND                  40200021
CTA05500 EQU   *                                                        40300021
         LA    R1,ULBUFR                POINT TO LABEL BUFFER           40400021
CTA05600 EQU   *                                                        40500021
         STM   R1,RDCB,ULPARM           PTRS TO LABEL BUFFER AND DCB IN 40600021
*                                       PARAMETER LIST                  40700021
         XC    ULTOTPTR,ULTOTPTR        ZERO TOTALING ENTRY             40800021
         MVI   ULDCBPTR,K0              CLEAR FLAG BYTE                 40900021
         AIF   ('&LIB' NE 'LIB1').LIB22A1                               40950000
         L     R7,DCBDEBAD              GET ADDRESS OF USER'S DEB       41000021
*                                       WITHOUT SETTING EOF FLAG        41100021
.LIB22A1 ANOP                                                           41150000
         AIF   ('&LIB' EQ 'LIB1').LIB12A1                               41160000
         L     R7,DXPDEBAD              LOAD PROTECTED DEB ADDR  Y01021 41170000
.LIB12A1 ANOP                                                           41180000
         CLC   0(K3,R1),UTLCON          CK IF PROCESSING TRLRS          41200021
         BE    CTA05700                 TRLRS,BR TO CK FOR EOF          41300021
*                                                                       41400021
         TM    DCBOFLGS,DCBOWRIT        IS IT OUTPUT                    41500021
         BO    CTA06000                 YES, BR WITH NO EOF FLAG        41600021
         TM    DEBOPATB-DEB(R7),DEBOPRBK  IS DCB OPEN FOR RDBACK        41700021
         BNM   CTA05700                 NO,BR TO CHK FOR EOF            41800021
*                                                                       41900021
         LH    R1,DEBTVLSQ-DEB(R7)      GET DEB VOL SEQ NUMBER  SA69185 42000021
         BCT   R1,CTA06000              DECREMENT--IF NOT ZERO          42100021
         B     CTA05900                 IF ZERO, BR TO INDIC EOF        42200021
*                                                                       42300021
CTA05700 EQU   *                                                        42400021
         CLC   JFCBNVOL(K1),DEBTVLSQ+K1-DEB(R7)  ALL VOLS USED  SA69185 43400021
         BE    CTA05900                 IF EQ INDICATE EOF              43500021
         CLC   VOLLABI,AEOF             CHK FOR EOF IF ON OTHER         43600021
*                                       THAN THE LAST VOLUME OF         43700021
*                                       A MULTI-VOLUME DATA SET         43800021
         BNE   CTA06000                 IF NOT EQ, BR TO INDICATE EOV   43900021
CTA05900 EQU   *                                                        44000021
         OI    ULDCBPTR,EOFFLG          SET FLAG TO INDICATE EOF        44100021
*                                                                       44200021
CTA06000 EQU   *                                                        44300021
         TM    DCBMACRF,DCBMEXCP        CK IF USING EXCP                44400021
         BO    CTA06100                 EXCP, SKIP TOTALING             44500021
         TM    DEBOPATB-DEB(R7),DEBOPOUT-DEBOPRBK  OPENED FOR INPT/RDBK 44600021
         BZ    CTA06100                 YES, SKIP TOTALING              44700021
         TM    DCBOPTCD,DCBOPTT         CK IF TOTALING SPECIFIED        44800021
         BZ    CTA06100                 BR IF NO TOTALING               44900021
*                                                                       45000021
         L     R7,K40(R7)               GET PTR TO TOTALING AREA        45100021
         USING TOTSAVWA,R7              ESTABLISH BASE FOR AREA         45200021
         MVC   ULTOTPTR,TOTEOVPT        TOTLING PTR TO PARM LIST        45300021
         DROP  R7                       DROP BASE                       45400021
*                                                                       45500021
CTA06100 EQU   *                                                        45600021
         LA    R1,ULPARM                POINT TO PARAMETER LIST         45700021
*  FIND  SVRB                                                           45800021
*     SAVE REGS                                                         45900021
*         LOAD USER REGS,SET LOCK BIT                                   46000021
*               SYNCH TO USER                                           46100021
*         RESTORE REGS,RESET LOCK BIT                                   46200021
*     RETURN TO CALLER                                                  46300021
*                                                                       46400021
         L     RF,ULREQ                 PTR TO USER'S LABEL ROUTINE     46500021
         L     R7,CVTPTR                PTR TO CVT                      46600021
         L     R7,CVTTCBP-CVT(,R7)      PTR TO TCB PTRS                 46700021
         L     R7,K4(,R7)               PTR TO CUR TCB                  46800021
         L     R7,TCBRBP-TCB(,R7)       PTR TO SVRB                     46900021
         USING RBSECT,R7                                                47000021
         STM   RDCB,RD,RBEXSAVE         SAVE REGS 2-13                  47100021
         NI    DCBOFLGS,X'FF'-DCBOLOCK  SET LOCK BIT TO ZERO            47200021
         L     RD,RBLINK                PTR TO PREVIOUS RB              47300021
         TM    RBSTAB-RBSECT(RD),RBFTSVRB  IS PREVIOUS A PRB            47400021
         BNO   CTA06200                 YES,BRANCH                      47500021
         LR    R7,RD                    USE PREVIOUS RB                 47600021
CTA06200 LM    RDCB,RD,RBGRS2           RESTORE USER REGS               47700021
         SYNCH (15)                     SYNCH TO USER ROUTINE           47800021
         L     R7,CVTPTR                PTR TO CVT                      47900021
         L     R7,CVTTCBP-CVT(,R7)      PTR TO TCB PTRS                 48000021
         L     R7,K4(,R7)               PTR TO CUR TCB                  48100021
         L     R7,TCBRBP-TCB(,R7)       PTR TO SVRB                     48200021
         LM    RDCB,RD,RBEXSAVE         RESTORE REGS 2-13               48380000
         ST    RF,ULWK1                 SAVE USER RETURN CODE    Y01021 48382000
         AIF   ('&LIB' EQ 'LIB1').LIB12A2                               48390000
         DEBCHK (RDCB)                  VALIDATE DEB             Y01021 48396000
         ST    R1,DXPDEBAD              STORE DEBAD IN WORKAREA  Y01021 48396800
         L     RF,ULWK1                 RESTORE USER RETURN CODE Y01021 48398000
.LIB12A2 ANOP                                                           48398400
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT TO ONE             48400021
         BR    RB                       RETURN                          48600021
         EJECT                                                          48700021
CTA06300 EQU   *                                                        48800021
         EXCP  DXIOB                    ISSUE EXCP                      48900021
         IECRES WAIT                    WAIT FOR I/0 COMPLETION         49000021
         TM    IOBSTAT0,CSWUNITX        TEST FOR UNIT EXCEPTION AND SET 49100021
*                                       CONDITION CODE ACCORDINGLY      49200021
         BR    RB                       RETURN TO CALLER                49300021
         EJECT                                                          49400021
         SPACE 1                                                        49500021
*********************************************************************** 49600021
*                                                                     * 49700021
*                        ERROR PROCESSING                             * 49800021
*                                                                     * 49900021
*********************************************************************** 50000021
         SPACE 1                                                        50100021
CTA06400 EQU   *                                                        50200021
         LA    R0,CABD064               ERR- READ UL                    50300021
         DMABCOND (0),PDMOD,RETURN=VOLDPMOD  ABEND MACRO                50400021
CTA06500 EQU   *                                                        50500021
         LA    R0,CABD063               ERR- WRITE TRL2                 50600021
         LA    RET,K8                   SET UP FOR BRANCH TABLE         50700021
         DMABCOND (0),PDMOD             ABEND MACRO                     50800021
         EJECT                                                          50900021
*********************************************************************** 50950021
*                                                                       51000021
*                        CONSTANTS                                      51100021
*                                                                       51200021
LENGTH   DC    X'20000050'              SILI, COUNT = 80 BYTES          51300021
UTLCON   DC    C'UTL'                   TRAILER LABEL CONSTANT          51400021
UHLCON   DC    C'UHL'                   HEADER LABEL CONSTANT           51500021
EOV      DC    C'EOV'                   FIRST THREE CHAR OF LABEL       51600021
HDR      DC    C'HDR'                   FIRST THREE CHAR OF LABEL       51700021
AEOF     DC    C'EOF'                   FIRST THREE CHAR OF LABEL       51800021
*                                                                       51900021
*****          DCB EXIT LIST CODE BYTES USED FOR TESTING                52000021
*                                                                       52100021
EXIT4    DC    X'04'                    CREATE OUTPUT UTL               52200021
         DC    X'84'                    SAME BUT LAST ENTRY             52300021
SLPSUP   DC    X'0C'                    SUL PROCESSING WAS              52400021
*                                       SUPPRESSED AT EOF               52500021
         DC    X'8C'                    SAME BUT LAST ENTRY             52600021
*                                                                       52700021
         LTORG                                                          52800021
         XCTLTABL ID=(PDMOD,0P,VOLDPMOD,2F),SVC=020                     52900021
         IECDSECS CVT,TCB,RB,DCB,DEB,MAIN,USERLAB,USERTOT,EXPAND=YES    53000021
         IECEQU                                                         53100021
         END                                                            53200021
