         TITLE 'IFG0202C - DA INPUT USER TRAILER LABEL PROCESSING '     00100021
         COPY  LCGASMSW                                                 00200000
IFG0202C CSECT                                                          00400000
*********************************************************************** 00500000
*                                                                     * 00600000
*        RELEASE 21.7 DELETIONS/CHANGES                                 00650021
*0000001000,039000,459000,460000,560000,561000                   SM5456 00660021
*0000023000-024000,120000-128000,459000                          A38013 01250021
*0000510000                                                     SA55619 01260000
*                                                                     * 01300000
* STATUS CHANGE LEVEL 000                                             * 01400000
*                                                                     * 01500000
* FUNCTION -                                                          * 01600000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 01700000
*    CLOSE DA INPUT USER LABELS FUNCTION.                             * 01800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 01900000
*                                                                     * 02000000
* ENTRY POINTS -                                                      * 02100000
*         IFG0202C - ENTRY POINT VIA AN XCTL FROM THE FOLLOWING--     * 02200000
*             IFG0200Y - PROCESS INPUT USER LABELS FUNCTION.          * 02300021
*                                                                     * 02500000
* INPUT -                                                             * 02600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02700000
*                                                                     * 02800000
* OUTPUT -                                                            * 02900000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03000000
*                                                                     * 03100000
* EXTERNAL REFERENCES -                                               * 03200000
*         IFG020RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 03300000
*                    WAIT.                                            * 03400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03500000
*                                                                     * 03600000
* EXITS, NORMAL -                                                     * 03700000
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING--            * 03800000
*         IFG0202H - PROCESS CLOSE/EOV SMF DATA SET FUNCTION.         * 03850021
*         IFG0202J - PROCESS CLOSE FINAL STRING.                      * 03900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04000000
*                                                                     * 04100000
* EXITS, ERROR -                                                      * 04200000
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0200P, IF AN      * 04300000
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 04400000
*    'FUNCTION PROLOG(S)'.                                            * 04500000
*                                                                     * 04600000
* TABLES/WORK AREAS -                                                 * 04700000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04800000
*                                                                     * 04900000
* ATTRIBUTES -                                                        * 05000000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 05100000
*                                                                     * 05200000
* CHARACTER CODE DEPENDENCY -                                         * 05300000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 05400000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05500000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05600000
*                                                                     * 05700000
* NOTES -                                                             * 05800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05900000
*                                                                     * 06000000
*********************************************************************** 06100000
         EJECT                                                          06200000
         USING IHADCB,RDCB                                              06300000
         USING FORCORE,RCORE                                            06400000
         USING WTG,RWTG                                          SM5456 06450021
         USING TCB,RET                                                  06500000
         USING ULWK,RC                                                  06600000
         USING UCBOB,RUCB                                               06700000
         USING DEB,RDEB                 ESTABLISH BASE FOR DEB          06800000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         06900000
         USING *,RBASE                                                  07000000
         EJECT                                                          07100000
*                                                                     * 07200000
*                          FUNCTION PROLOG                            * 07300000
*                                                                     * 07400000
*********************************************************************** 07500000
*                                                                     * 07600000
* FUNCTION NAME -                                                     * 07700000
*    CLOSE DA INPUT USER LABELS FUNCTION.                             * 07800000
*                                                                     * 07900000
* (STATUS) -                                                          * 08000000
*    NOT APPLICABLE                                                   * 08100000
*                                                                     * 08200000
         AIF   ('&LIB' NE 'LIB1').LIB22C0                               08250000
* FUNCTION -                                                          * 08300000
*    IF THE USER HAS SPECIFIED A LABEL TYPE OF SUL FOR PHYSICAL       * 08400000
*    SEQUENTIAL OR DIRECT DATA SET AND IF THE APPROPRIATE USER LABEL  * 08500000
*    EXIT IS ACTIVE (I.E., DCB EXIT LIST CONTAINS ENTRY FOR UL EXIT), * 08600000
*    THIS FUNCTION READS USER TRAILER LABELS FOR PRESENTATION TO THE  * 08700000
*    USER'S INPUT TRAILER LABEL PROCESSING ROUTINE.                   * 08800000
*    AN AREA OF MAIN STORAGE IS ACQUIRED FROM SUBPOOL 250 FOR USE AS  * 08900000
*    A WORK AREA, LABEL BUFFER, AND PARAMETER LIST.                   * 09000000
*    LABELS ARE READ AND PRESENTED TO THE USER UNTIL                  * 09100000
*    1) AN EOF IS ENCOUNTERED,                                        * 09200000
*    2) THE USER INDICATES TERMINATION OF PROCESSING VIA A RETURN     * 09300000
*       CODE, OR                                                      * 09400000
*    3) THE MAXIMUM NUMBER OF LABELS (8) HAVE BEEN PROCESSED.         * 09500000
*    AFTER THE USER'S ROUTINE HAS PROCESSED THE LABEL PASSED TO IT,   * 09600000
*    THE CODE RETURNED BY THE USER DIRECTS FURTHER PROCESSING AS      * 09700000
*    FOLLOWS--                                                        * 09800000
*       RETURN CODE   ACTION TAKEN BY THIS FUNCTION                   * 09900000
*    INPUT DATA SETS                                                  * 10000000
*         0           NO FURTHER PROCESSING OF USER LABELS (UL) AND   * 10100000
*                     NORMAL PROCESSING BY I/O SUPPORT CONTINUES.     * 10200000
*         4           IF 8 UL HAVE NOT BEEN READ, READ NEXT UL. IF 8  * 10300000
*                     UL HAVE BEEN READ, THERE IS NO FURTHER          * 10400000
*                     PROCESSING OF UL.                               * 10500000
*    UPDATE OPERATIONS                                                * 10600000
*         0           SAME AS FOR INPUT.                              * 10700000
*         4           SAME AS FOR INPUT.                              * 10800000
*         8           WRITE LABEL IN LABEL BUFFER (I.E., LABEL HAS    * 10900000
*                     BEEN UPDATED), THEN PERFORM NO FURTHER          * 11000000
*                     PROCESSING.                                     * 11100000
*        12           WRITE LABEL IN LABEL BUFFER, THEN READ NEXT UL. * 11200000
*                                                                     * 11300000
.LIB22C0 ANOP                                                           11310000
         AIF   ('&LIB' EQ 'LIB1').LIB12C0                               11320000
* FUNCTION -                                                          * 11350000
*    IF THE USER HAS SPECIFIED A LABEL TYPE OF SUL FOR PHYSICAL       * 11360000
*    SEQUENTIAL OR DIRECT DATA SET AND IF THE APPROPRIATE USER LABEL  * 11370000
*    EXIT IS ACTIVE (I.E., DCB EXIT LIST CONTAINS ENTRY FOR UL EXIT), * 11380000
*    THIS FUNCTION READS USER TRAILER LABELS FOR PRESENTATION TO THE  * 11390000
*    USER'S INPUT TRAILER LABEL PROCESSING ROUTINE.                   * 11392000
*    AN AREA OF MAIN STORAGE IS ACQUIRED FROM SUBPOOL 250 FOR USE AS  * 11394000
*    A WORK AREA, LABEL BUFFER, AND PARAMETER LIST.                   * 11396000
*    LABELS ARE READ AND PRESENTED TO THE USER UNTIL                  * 11398000
*    1) AN EOF IS ENCOUNTERED,                                        * 11398400
*    2) THE USER INDICATES TERMINATION OF PROCESSING VIA A RETURN     * 11398800
*       CODE, OR                                                      * 11399200
*    3) THE MAXIMUM NUMBER OF LABELS (8) HAVE BEEN PROCESSED.         * 11399600
*    AFTER THE USER'S ROUTINE HAS PROCESSED THE LABEL PASSED TO IT,   * 11399700
*    THE CODE RETURNED BY THE USER DIRECTS FURTHER PROCESSING AS      * 11399800
*    FOLLOWS--                                                        * 11399900
*       RETURN CODE   ACTION TAKEN BY THIS FUNCTION                   * 11433200
*    INPUT DATA SETS                                                  * 11443200
*         0           NO FURTHER PROCESSING OF USER LABELS (UL) AND   * 11453200
*                     NORMAL PROCESSING BY I/O SUPPORT CONTINUES.     * 11463200
*         4           IF 8 UL HAVE NOT BEEN READ, READ NEXT UL. IF 8  * 11465200
*                     UL HAVE BEEN READ, THERE IS NO FURTHER          * 11465600
*                     PROCESSING OF UL.                               * 11466000
*    UPDATE OPERATIONS                                                * 11466400
*         0           SAME AS FOR INPUT.                              * 11466500
*         4           SAME AS FOR INPUT.                              * 11466600
*         8           WRITE LABEL IN LABEL BUFFER (I.E., LABEL HAS    * 11477700
*                     BEEN UPDATED), THEN PERFORM NO FURTHER          * 11487700
*                     PROCESSING.                                     * 11488100
*        12           WRITE LABEL IN LABEL BUFFER, THEN READ NEXT UL. * 11488500
*    DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A DEB VALIDITY CHECK   * 11490800
*    ROUTINE WHICH MAINTAINS AND UPDATES A TABLE OF VALID DEB POINTERS* 11492800
*    IN PROTECTED CORE (LSQS).                                        * 11492900
*                                                                     * 11493100
.LIB12C0 ANOP                                                           11495400
* ENTRY POINTS -                                                      * 11497700
*    ENTERED FROM THE FOLLOWING--                                     * 11500000
*    CLOSE DA ACCESS METHOD INTERFACE FUNCTION.                       * 11600000
*                                                                     * 11700000
* INPUT -                                                             * 11800000
*    A POINTER TO EACH OF THE FOLLOWING--                             * 11900000
*       CURRENT PARAMETER LIST ENTRY- RPARC                           * 12000021
*       DD ENTRY IN THE TIOT- RTIOT                                   * 12100021
*       WTG TABLE- RWTG                                               * 12200021
*       CURRENT WTG TABLE ENTRY- RWTGC                                * 12300021
*       DCB- RDCB                                                     * 12400021
*       WORK AREA- RCORE                                              * 12500021
*       RESIDENT ROUTINE- RES                                         * 12600021
*       UCB- RUCB                                                     * 12700021
*       DEB- RDEB                                                     * 12800021
*                                                                     * 12900000
* OUTPUT -                                                            * 13000000
*    USER TRAILER LABELS ARE PROCESSED.                               * 13100000
*                                                                     * 13200000
* EXTERNAL REFERENCES -                                               * 13300000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 13400000
*    USER'S INPUT LABEL EXIT ROUTINES - ENTERED BY MEANS OF           * 13500000
*    SYNCHRONOUS EXIT (SVC 12) WITH THE FOLLOWING INPUT               * 13600000
*       REG 0    CONTAINS NO MEANINGFUL INFO                          * 13700000
*           1    POINTER TO 4 WORD PARAMETER LIST WHICH CONTAINS -    * 13800000
*                POINTER TO LABEL BUFFER                              * 13900000
*                POINTER TO DCB                                       * 14000000
*                FLAG BYTE, PTR TO STATUS INFO (IF PERMANENT ERROR)   * 14100000
*                OR ZERO                                              * 14200000
*                4-BYTES RESERVED (FOR OUTPUT, THIS FIELD POINTS TO   * 14300000
*                IMAGE AREA IF USER TOTALING WAS REQUESTED(DCBOPTCD=T)* 14400000
*                OR IS ZERO)                                          * 14500000
*           2-13 CONTENTS OF USER'S REGS BEFORE I/O SUPP              * 14600000
*           14   RETURN ADDRESS                                       * 14700000
*           15   EXIT ADDRESS                                         * 14800000
*                                                                     * 14900000
*    BEFORE EXITING, THIS FUNCTION'S REGISTERS 2-13 ARE SAVED IN THE  * 15000000
*    SVRB EXTENDED SAVE AREA.  THE USER'S REGISTERS 2-13 ARE RESTORED * 15100000
*    FROM THE SVRB.  THE LOCK BIT (BIT 6) IN DCBOFLGS FIELD IS SET TO * 15200000
*    1 TO PREVENT ANOTHER I/O SUPPORT FUNCTION FROM OPERATING ON THIS * 15300000
*    DCB WHILE THE USER IS IN CONTROL.  ON RETURN FROM THE USER'S     * 15400000
*    ROUTINE, THIS BIT IS RESET TO 0.                                 * 15500000
*                                                                     * 15600000
* EXITS, NORMAL -                                                     * 15700000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 15800000
*    CLOSE DA EXIT FUNCTION.                                          * 15900000
*                                                                     * 16000000
* EXITS, ERROR -                                                      * 16100000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16200000
*    NO LABELS CAN BE READ - EXIT TO USER'S ROUTINE WITH LABEL BUFFER * 16300000
*    POINTER IN PARM LIST SET TO ZERO. OTHER PARAMETERS UNCHANGED.    * 16400000
*    ON RETURN FROM USER'S ROUTINE, THE RETURN CODE IS IGNORED AND    * 16500000
*    NORMAL PROCESSING CONTINUES.                                     * 16600000
*    I/O ERROR READING A USER LABEL - THE USER'S ROUTINE IS ENTERED.  * 16700000
*    AGAIN WITH THE FOLLOWING INPUT                                   * 16800000
*       BIT 0 OF FLAG BYTE SET TO ONE, PTR TO STANDARD                * 16900000
*       STATUS INFORMATION.                                           * 17000000
*    OTHER PARAMETERS ARE UNCHANGED.                                  * 17100000
*    I/O ERROR WRITING UPDATED USER LABEL - IN ADDITION TO SETTING    * 17200000
*    BIT 0 OF THE FLAG BYTE, BIT 1 IS ALSO SET. A PTR IS PASSED       * 17300000
*    POINTING TO STANDARD STATUS INFORMATION.                         * 17400000
*    THE OTHER PARAMETERS ARE UNCHANGED.                              * 17500000
*                                                                     * 17600000
* TABLES/WORK AREAS -                                                 * 17700000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 17800000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 17900000
*                                                                     * 18000000
* ATTRIBUTES -                                                        * 18100000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18200000
*                                                                     * 18300000
* CHARACTER CODE DEPENDENCY -                                         * 18400000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18500000
*                                                                     * 18600000
* NOTES -                                                             * 18700000
*    NOT APPLICABLE                                                   * 18800000
*                                                                     * 18900000
*********************************************************************** 19000000
         EJECT                                                          19100000
         GETMAIN R,LV=USERL,SP=250      OBTAIN CORE FOR WORK AREA,      19200000
*                               LABEL BUFFER AND PARAMETER LIST (72+8)  19300000
         XC    0(USERL,R1),0(R1)        CLEAR WKAREA AND BUFFER         19400000
         STM   RES,RC,0(R1)             SAVE REGS 5-12 FOR CALLER       19500000
         LR    RC,R1                    SET BASE FOR ULWK AREA          19600000
         XC    DXCCW1(DXCCW8-DXCCW1),DXCCW1  CLEAR CHAN PROG AREA       19700000
         NI    ULREQ,X'FF'-LASTNTRY     TURN OFF LAST ENTRY FLAG-IF ON  19800000
*                                                                       19900000
*  THE DSCB MUST BE READ INTO I/O SUPPORT WORK AREA                     20000000
*                                                                       20100000
         CLI   DSCEXTYP,ULEXT           IS FIRST EXTENT FOR USER LABELS 20200000
         BE    CDA02520                 BR IF YES TO SET UP CP          20300000
*        NO UL TRACK EXISTS, OR NO TRAILERS EXIST ON UL TRACK.          20400000
*                                                                       20500000
         LA    RB,CDA04300              SET RETURN ADDRESS AFTER SYNCH  20600000
*                                       USER                            20700000
CDA02500 EQU   *                                                        20800000
         SR    R1,R1                    ZERO WILL BE STORED AS LABEL    20900000
         XC    ULERRPTR,ULERRPTR        CLEAR ERROR INDCTS              21000000
         B     CDA04700                 GO TO SYNCH TO USER             21100000
*                                                                       21200000
CDA02520 EQU   *                                                        21300000
*  SET UP CHANNEL PROGRAM AND WORK AREA TO READ FIRST TRAILER           21400000
*  CHANNEL PROGRAM TO READ FIRST TRAILER IS                             21500000
*    READ COUNT INTO ULWK8                                              21600000
*    SEARCH KEY EQUAL   KEY IN ULWK6 = 'UTL0'                           21700000
*    TIC *-16                                                           21800000
*    READ DATA (LABEL) INTO BUFFER                                      21900000
*                                                                       22000000
         LA    R1,ULWK8                 POINT TO AREA INTO WHICH        22100000
         ST    R1,DXCCW1                COUNT IS READ                   22200000
         LA    R1,ULWK6                 POINT TO AREA CONTAINING        22300000
*                                       SEARCH ARGUMENT                 22400000
         ST    R1,DXCCW2                FOR SEARCH KEY EQUAL            22500000
         LA    R1,DXCCW1                POINT TO READ COUNT CCW         22600000
         ST    R1,DXCCW3                IN TIC                          22700000
         LA    R1,ULBUFR                POINT TO LABEL BUFFER           22800000
         ST    R1,DXCCW4                IN READ DATA                    22900000
         OC    DXCCW1(K32),ULCP1        COMBINE CP SKELETON WITH PTRS   23000000
*                                                                       23100000
*        INITIALIZE IOBDADAD WITH R=0                                   23200000
*                                                                       23300000
         XC    DXDAADDR,DXDAADDR        CLEAR IOBDADAD TO ZERO          23400000
         MVC   DXDAADDR+K3(K4),DSCLOWLM  CCHH FROM START OF 1ST EXTENT  23500000
         CLI   UCBID,UCBMAIN            IS DEVICE 2321                  23600000
         BE    CDA02550                 NOT 2321, BRANCH                23700000
         USING UCBDCELL,RUCB                                            23800000
         MVC   DXDAADDR+K1(K2),UCBDBBNR  2321, GET BB FROM SUB-UCB      23900000
         USING UCBOB,RUCB                                               24000000
         SPACE 2                                                        24100000
CDA02550 EQU   *                                                        24200000
         SPACE                                                          24300000
         TM    DCBDSORG,DCBORGDA        TEST,BR IF NOT DIRECT ORG       24400000
         BZ    CDA02600                 DATA SET                        24500000
         BAL   RB,CDA04400              GO SET UP PARAMETER LIST FOR    24600000
         ENQ   MF=(E,(1))               ENQ ON USER LABEL TRACK         24700000
CDA02600 EQU   *                                                        24800000
*                                                                       24900000
         MVC   ULWK6,UTLCONST           SET UP SEARCH ARG = UTLO        25000000
         MVC   ULWK10,UTLCONST          NECESSARY SINCE FIRST CHANNEL   25100000
*                                       PROGRAM DOES NOT READ KEY       25200000
         OI    ULWK2,K1                 SET FIRST READ SWITCH           25300000
*                                                                       25400000
*        READ FIRST TRAILER LABEL                                       25500000
*                                                                       25600000
         BAL   RB,CDA04200              GO READ TRAILER                 25700000
*                                                                       25800000
*  ESTABLISH CHANNEL PROGRAM FOR SUBSEQUENT USE, THEN TEST              25900000
*  FOR I/O ERROR.                                                       26000000
*                                                                       26100000
*  SET UP CHANNEL PROGRAM TO WRITE BACK LABEL AND READ NEXT LABEL       26200000
*    SEARCH KEY EQUAL    KEY=UTL(N)                                     26300000
*    TIC *-8                                                            26400000
*    WRITE DATA          WRITE UPDATED LABEL                            26500000
*    SEARCH ID EQUAL     ID OF RECORD PRIOR TO UTL(N)                   26600000
*    TIC *-8             CHECK                                          26700000
*    RD CKD    (SKIP)    LABEL JUST WRITTEN                             26800000
*    RD CKD              READ NEXT LABEL                                26900000
*                                                                       27000000
*  WHEN ONLY UPDATING IS PERFORMED, CC FLAG IN RD CKD IS TURNED OFF.    27100000
*                                                                       27200000
*  WHEN NO UPDATING IS PERFORMED,CHANNEL PROGRAM TO READ NEXT LABEL IS  27300000
*    SEARCH KEY EQUAL    KEY OF PREVIOUS LABEL                          27400000
*    TIC *-8                                                            27500000
*    RD CKD              READ NEXT LABEL                                27600000
*                                                                       27700000
*                                                                       27800000
*  PROCEDURE USED BELOW IS TO USE KEY IN ULWK10 (KEY OF LABEL           27900000
*  PROCESSED) AS SEARCH ARGUMENT FOR SUBSEQUENT I/O OPERATIONS.         28000000
         MVC   DXCCW1,DXCCW2            SEARCH KEY CCW TO DXCCW1        28100000
         XC    DXCCW2(DXCCW8-DXCCW2),DXCCW2  CLEAR REMAINING CP AREA    28200000
         LA    R1,DXCCW1                SET UP DXCCW2                   28300000
         ST    R1,DXCCW2                AS TIC TO                       28400000
         MVI   DXCCW2,CCWTIC            DXCCW1                          28500000
*  DXCCW3 IS ESTABLISHED AFTER USER RETURNS CODE                        28600000
         LA    R1,DXDAADDR+K3           ADDR OF IOBADDR+3 (CCHHR) FOR   28700000
         ST    R1,DXCCW4                SEARCH ID                       28800000
         LA    R1,DXCCW4                TIC TO                          28900000
         ST    R1,DXCCW5                DXCCW4                          29000000
         LA    R1,ULWK8                 RD CKD INTO                     29100000
         ST    R1,DXCCW7                ULWK8                           29200000
         OC    DXCCW4(K32),ULCP3        COMBINE SKELETON CP & PTRS      29300000
CDA02700 EQU   *                                                        29400000
         TM    DXECB,ECBCOD7F           TEST, BR IF I/O ERROR           29500000
         BNO   CDA03700                 ENCOUNTERED                     29600000
         NI    ULWK2,X'FF'-K1           SET 1ST-READ-SW OFF IF ON       29700000
         IC    R1,ULWK9                 'R' OF COUNT READ IN            29800000
         BCTR  R1,0                     DECREMENTED BY ONE - USED IN OR 29900000
         STC   R1,DXDAADDR+K7           FOR WRITE VERIFICATION          30000000
*                                                                       30100000
         BAL   RB,CDA04500              GO TO SYNCH TO USER             30200000
         LTR   RF,RF                    TEST,BR IF USER RETURNED        30300000
         BZ    CDA04250                 A CODE = 0 (NO FURTHER PROCESS) 30400000
CDA02800 EQU   *                                                        30500000
*  SOME TYPE OF I/O WILL BE INITIATED.  SEARCH WILL BE BASED UPON KEY   30600000
*  OF LABEL 'JUST PROCESSED'.                                           30700000
         MVC   ULWK6,ULWK10             SET UP SEARCH ARGUMENT          30800000
         XC    DXCCW3,DXCCW3            ENSURE THAT PRVIUS CCW DOES NOT 30900000
*  CONFLICT WITH CHANNEL PROGRAM TO BE COMPLETED BELOW.                 31000000
         CLI   ULRETCOD,READNEXT        TEST,BR IF USER DOES NOT WANT   31100000
         BNE   CDA02860                 NEXT LABEL TO BE READ           31200000
*        READ NEXT LABEL                                                31300000
         CLI   ULWK10+K3,CHAR7          TEST,BR IF MAX NBR OF LABELS    31400000
         BC    10,CDA04250              ALREADY READ                    31500000
*  ESTABLISH THIRD CCW TO READ NEXT LABEL                               31600000
         LA    R1,ULWK8                 SET RD CKD CCW TO READ INTO     31700000
         ST    R1,DXCCW3                AREA STARTING AT ULWK8          31800000
         OC    DXCCW3,RDCKD             COMBINE SKELETON CCW WITH ADDR  31900000
*                                                                       32000000
CDA02840 EQU   *                                                        32100000
         BAL   RB,CDA04200              GO READ NEXT LABEL ( OR WRITE   32200000
*                                       THEN READ NEXT LABEL)           32300000
         B     CDA02700                 GO CHECK FOR ERROR              32400000
*                                                                       32500000
CDA02860 EQU   *                                                        32600000
*  CHECK IF 8 OR 12 IS A VALID RETURN CODE                              32700000
         AIF   ('&LIB' NE 'LIB1').LIB22C1                               32750000
         L     RDEB,DCBDEBAD            POINTER TO USER'S DEB           32800000
.LIB22C1 ANOP                                                           32850000
         AIF   ('&LIB' EQ 'LIB1').LIB12C1                               32860000
         L     RDEB,DXPDEBAD            LOAD PROTECTED DEB ADDR  Y01021 32870000
.LIB12C1 ANOP                                                           32880000
         TM    DCBOFLGS,DCBOPEN         CK IF DCB IS OPEN               32900000
         BO    CDA02900                 DCB OPEN,USER'S DEB EXISTS      33000000
         LA    RDEB,DXDEB               DURING OPEN,USE WORK DEB        33100000
CDA02900 EQU   *                                                        33200000
         TM    DEBOPATB,DEBOPOUT-DEBOPUPD  TEST,BR IF OPENED FOR        33300000
         BO    CDA03000                 OUTPUT                          33400000
         BM    CDA04250                 BR IF NOT UPDAT OR INPUT        33500000
         TM    DEBOPATB,DEBOPUPD        TEST,BR IF OPENED FOR           33600000
         BO    CDA03100                 UPDAT                           33700000
         B     CDA04250                 BR IF INPUT                     33800000
CDA03000 EQU   *                                                        33900000
         TM    DCBDSORG,DCBORGDA        IF NOT UPDATE, DIRECT DATA SET  34000000
         BZ    CDA04250                 FOR OUTPUT IS ALSO VALID.       34100000
CDA03100 EQU   *                                                        34200000
*  SET UP THIRD CCW TO WRITE UPDATED LABEL                              34300000
         LA    R1,ULBUFR                ESTABLISH WRITE DATA CCW TO     34400000
         ST    R1,DXCCW3                WRITE LABEL BUFFER              34500000
         OC    DXCCW3,WRDATA            COMBINE SKELETON CCW WITH ADDR  34600000
*                                                                       34700000
         CLI   ULRETCOD,WRITNEXT        TEST,BR IF LABEL IS TO BE       34800000
         BE    CDA03600                 WRITTEN ONLY                    34900000
         CLI   ULRETCOD,WRITNEXT+READNEXT  TEST IF LABEL TO BE WRITTEN  35000000
         BNE   CDA04250                 BR, INVALID CODE RETURNED, END  35100000
*                                       PROCESSING IN THIS MODULE       35200000
*                                                                       35300000
*        WRITE UPDATED LABEL AND READ NEXT LABEL                        35400000
*                                                                       35500000
         CLI   ULWK10+K3,CHAR7          TEST,BR IF MAX NUMBER OF LABELS 35600000
         BC    10,CDA03500              ALREADY BEEN READ               35700000
         OI    DXCCW6+K4,CCWCMDCH       ENSURE COMMAND CHAIN FLAG IN    35800000
*                                       VERIFICATION RD CKD IS ON       35900000
         B     CDA02840                 GO PERFORM I/O                  36000000
*                                                                       36100000
CDA03500 EQU   *                                                        36200000
         MVI   ULRETCOD,WRITNEXT        MAX NUMBER OF LABELS HAVE       36300000
*  BEEN READ, RETURN CODE CHANGED TO WRITE LABEL ONLY.                  36400000
*  FALL THRU TO WRITE LABEL                                             36500000
*                                                                       36600000
*        WRITE UPDATED LABEL                                            36700000
CDA03600 EQU   *                                                        36800000
         NI    DXCCW6,X'FF'-CCWCMDCH    TURN OFF COMMND CHAIN FLAG IN   36900000
*                                       CCW THAT PERFORMS WRITE         37000000
*                                       VERIFICATION                    37100000
         BAL   RB,CDA04200              GO WRITE UPDATED LABEL          37200000
*                                                                       37300000
         TM    DXECB,ECBCOD7F           TEST,BR (IE,NO FURTHER PROCESS) 37400000
         BO    CDA04250                 NO I/O ERROR                    37500000
*                                                                       37600000
CDA03700 EQU   *                                                        37700000
*        I/O ERROR                                                      37800000
*                                                                       37900000
         LA    R1,DXIOB                 PUT PTR TO STATUS INFO IN       38000000
         ST    R1,ULERRPTR              PARAMETER LIST                  38100000
         MVI   ULERRPTR,ERROR           FLAG ERROR COND(ALSO RESETS ANY 38200000
*                                       OTHER ERROR FLAGS TO ZERO).     38300000
*  DETERMINE TYPE OF CHANNEL PROGRAM BEING USED WHEN ERROR OCCURRED.    38400000
*                                                                       38500000
         CLI   ULRETCOD,WRITNEXT        TEST,BR IF ERROR ON READ ONLY   38600000
         BL    CDA03800                 (IF ERROR ON FIRST READ,        38700000
*                                       ULRETCOD=0, BR TAKEN)           38800000
*  EITHER WRITING OR WRITING THEN READING                               38900000
         MVC   ULWK3+K1(K3),IOBCOMAD+K1  OBTAIN CSW POINTER             39000000
         L     R1,ULWK3                 FROM IOB                        39100000
         LA    R0,DXCCW7+K8             POINT 8 BYTES PAST READ CCW,    39200000
         CR    R1,R0                    THEN COMPARE WITH CSW POINTER   39300000
         BNE   CDA04000                 BR IF ERROR DURING WRITE        39400000
CDA03800 EQU   *                                                        39500000
*  READ ERROR                                                           39600000
         SR    R1,R1                                                    39700000
         IC    R1,ULWK6+K3              OBTAIN LAST CHAR OF KEY         39800000
         TM    ULWK2,CSWUNITX           TEST IF ERROR ON FIRST READ     39900000
         BO    CDA03900                 BR IF FIRST READ                40000000
*  RECONSTRUCT KEY AREA                                                 40100000
         MVC   ULWK10(K3),UTLCONST      'UTL' TO KEY AREA               40200000
         LA    R1,K1(,R1)               INCREMENT 'N' OF KEY            40300000
         STC   R1,ULWK10+K3             AND PLACE IN KEY AREA           40400000
CDA03900 EQU   *                                                        40500000
*  SET UP BUFFER TO TELL USER WHAT LABEL WE WERE UNABLE TO READ         40600000
         NI    ULWK2,X'FF'-K1           SET 1ST READ SW OFF IF ON       40700000
         MVC   ULBUFR(K3),UTLCONST      'UTL' TO BUFFER                 40800000
         LA    R1,K1(,R1)               LABEL NUMBER                    40900000
         STC   R1,ULBUFR+K3             TO BUFFER                       41000000
         B     CDA04100                 GO TO BRANCH TO USER            41100000
*                                                                       41200000
CDA04000 EQU   *                                                        41300000
*  WRITE ERROR                                                          41400000
         OI    ULERRPTR,ERROROUT        FLAG WRITE ERROR CONDITION      41500000
CDA04100 EQU   *                                                        41600000
         BAL   RB,CDA04600              GO TO SYNCH TO USER             41700000
         LTR   RF,RF                    TEST,BR IF USER RETURNS CODE=0, 41800000
         BZ    CDA04250                 (NO FURTHER PROCESSING)         41900000
         ST    RF,ULWK1                 SAVE RETURN CODE                42000000
         CLI   ULRETCOD,READNEXT        TEST,BR IF USER WANTS NEXT      42100000
         BE    CDA02800                 LABEL TO BE READ                42200000
         B     CDA04250                 BR,INVALID CODE RETURNED BY     42300000
*                                       USER                            42400000
         EJECT                                                          42500000
*                                                                       42600000
*********************************************************************** 42700000
*                                                                       42800000
*                   CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS           42900000
*                                                                       43000000
*        IT IS ASSUMED THAT ALL CONTROL BLOCKS HAVE ALREADY BEEN SET UP 43100000
*                                                                       43200000
CDA04200 EQU   *                                                        43300000
         EXCP  DXIOB                    INITIATE I/O                    43400000
*                                                                       43500000
         IECRES WAIT                    WAIT FOR I/O COMPLETION         43600000
*                                                                       43700000
         TM    IOBSTAT0,CSWUNITX        TEST,BR IF NOT UNIT             43800000
         BCR   14,RB                    EXCEPTION (EOF)                 43900000
         CLI   ULWK10+K3,CHAR0          HAVE ANY LABELS BEEN READ       44000000
         LA    RB,CDA04250              PREVIOUSLY- SET UP RETURN ADDR  44100000
         BC    12,CDA02500              GO TO SYNCH TO USER IF NO       44200000
*        NO FURTHER UL PROCESSING IS PERFORMED.  FREE CORE AND RETURN   44300000
*        TO CALLER.                                                     44400000
*                                                                       44500000
CDA04250 EQU   *                                                        44600000
         TM    DCBDSORG,DCBORGDA        TEST,BR IF NOT DIRECT ORG       44700000
         BZ    CDA04300                 DATA SET                        44800000
         BAL   RB,CDA04400              GO SET UP PARAMETER LIST FOR    44900000
         DEQ   MF=(E,(1))               DEQ FROM USER LABEL TRACK       45000000
CDA04300 EQU   *                                                        45100000
         LR    R1,RC                    INITIALIZE REG FOR FREEMAIN     45200000
         LM    RES,RC,0(R1)             RESTORE CALLER'S REGS           45300000
         FREEMAIN R,LV=USERL,SP=250,A=(1)  FREE USER LABEL WORK AREA,  C45400000
                                        LABEL BUFFER AND PARAMETER LIST 45500000
*                                                                       45600000
*  RETURN TO CALLER                                                     45700000
*                                                                       45800000
         TM    WTGPATHS,WTGSMF          SMF REQUESTED            SM5456 45850021
         BZ    CDA04325                 BRANCH IS NOT            SM5456 45900021
         TM    JFCBTSDM,JFCSDS          IS SYSIN/SYSOUT DS       SM5456 45950021
         BO    CDA04325                 BRANCH IF YES            SM5456 46000021
         LA    RF,SMFMOD                SET UP FOR XCTL TO SMF   SM5456 46050021
         MVC   DXRETMOD,FINALMOD        SET UP FOR XCTL RETURN   SM5456 46060021
*                                       FROM SMF MODULE          SM5456 46062021
         B     CDA04350                 BRANCH TO SMF STRING     SM5456 46070021
CDA04325 EQU   *                                                 SM5456 46080021
         LA    RF,FINALMOD              SET UP FOR XCTL          SM5456 46090021
*                                       TO LAST LOAD             SM5456 46090421
CDA04350 EQU   *                                                 SM5456 46092021
         SR    RET,RET                  SET BRANCH OFFSET        SM5456 46094021
         IECRES XCTL,(RF),(RET)         XCTL TO SMG OR FINAL     SM5456 46096021
         EJECT                                                          46100000
CDA04400 EQU   *                                                        46200000
*  SET UP ENQ/DEQ PARAMETER LIST (USING LABEL BUFFER AREA)              46300000
*                                                                       46400000
*                                                                       46500000
         MVC   ULBUFR(K4),ENQLIST       SET UP ENQ/DEQ CONSTANTS        46600000
         MVC   ULBUFR+K12(K8),QNAME     SET UP QNAME = SYSUSERL         46700000
         STH   RUCB,ULBUFR+K20          SET UP RNAME = UCB PTR          46800000
         MVC   ULBUFR+K22(K6),DXDAADDR+K1  AND BBCCHH                   46900000
         LA    R0,ULBUFR+K12            PLACE POINTERS TO QNAME AND     47000000
         LA    R1,ULBUFR+K20            RNAME                           47100000
         STM   R0,R1,ULBUFR+K4          IN PARAMETER LIST               47200000
         LA    R1,ULBUFR                POINT TO PARAMETER LIST         47300000
         BR    RB                       RETURN TO CALLER                47400000
         EJECT                                                          47500000
*********************************************************************** 47600000
*        CLOSED SUBROUTINE TO SAVE AND RESTORE REGISTERS, SET UP INPUT, 47700000
*        AND ISSUE THE SVC SYNCH  FOR SYNCHRONOUS EXIT TO PROBLEM PROG. 47800000
*        THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE SVRB EXTENDED    47900000
*        SAVE AREA, AND THE USER'S REGISTERS 2-13 ARE RESTORED FROM THE 48000000
*        SVRB.  REGISTER CONTENTS ARE AS FOLLOWS-                       48100000
*                        R0 - CONTAINS NO MEANINGFUL INFO               48200000
*                        R1 - PTR TO PARAMETER LIST                     48300000
*                    R2-R13 - USER'S CONTENTS BEFORE I/O SUPPORT        48400000
*                       R14 - RETURN ADDRESS (SET BY SYNCH)             48500000
*                       R15 - EXIT ADDRESS                              48600000
*                                                                       48700000
CDA04500 EQU   *                                                        48800000
         XC    ULERRPTR,ULERRPTR        CLEAR PREVIOUS ERROR PARM       48900000
CDA04600 EQU   *                                                        49000000
         LA    R1,ULBUFR                PTR TO LABEL BUFFER             49100000
CDA04700 EQU   *                                                        49200000
         STM   R1,RDCB,ULPARM           ESTABLISH PARMS- LABEL BUFFER   49300000
*                                       PTR AND DCB PTR                 49400000
         MVI   ULDCBPTR,K0              CLEAR FLAG BYTE                 49500000
         AIF   ('&LIB' NE 'LIB1').LIB22C2                               49550000
         L     R7,DCBDEBAD              USER'S DEB ADDRESS              49600000
.LIB22C2 ANOP                                                           49650000
         AIF   ('&LIB' EQ 'LIB1').LIB12C2                               49660000
         L     R7,DXPDEBAD              LOAD PROTECTED DEB ADDR  Y01021 49670000
.LIB12C2 ANOP                                                           49680000
         OI    ULDCBPTR,EOFFLG          INDICATE EOF            SA55619 49690000
         TM    DCBOFLGS,DCBOPEN         CK IF DCB ALREADY OPEN          49700000
         BZ    CDA04800                 NO,CTL FROM OPEN,INDIC EOF      49800000
         TM    DCBDSORG,DCBORGDA        IS DSORG DIRECT                 49900000
         BO    CDA04800                 YES, INDIC EOF                  50000000
         SR    R1,R1                    CLEAR WORK REGISTER             50100000
         IC    R1,DEBNMEXT-DEB(R7)      GET NUMBER OF EXTENTS           50200000
         SLL   R1,4                     16(NO.EXTNTS)=LNGTH IN DEB      50300000
         LH    R1,DEBDVMOD-DEB(R1,R7)   GET DEB VOL SEQ NUMBER          50400000
         AH    R1,JFCBVLSQ              ADD JFCB VOL SEQ NUMBER         50500000
         SR    RF,RF                    CLEAR WORK REGISTER             50600000
         IC    RF,JFCBNVOL              GET TOTAL NUMBER OF VOLS        50700000
         CR    R1,RF                    COMPARE VOLS USED TO TOTAL      50800000
         BE    CDA04800                 IF EQ, INDICATE EOF             50900000
         NI    ULDCBPTR,X'FF'-EOFFLG    NOT EQ, INDICATE EOV    SA55619 50950000
*                                                                       51100000
CDA04800 EQU   *                                                        51200000
         LA    R1,ULPARM                POINT TO PARAMETER LIST         51300000
         L     R7,CVTPTR                CVT ADDRESS                     51400000
         L     R7,CVTTCBP-CVT(,R7)      TCB PTR                         51500000
         L     R7,K4(,R7)               TCB ADDRESS                     51600000
         L     R7,TCBRBP-TCB(,R7)       SVRB ADDRESS                    51700000
         NI    DCBOFLGS,X'FF'-DCBOLOCK  SET LOCK BIT = 0                51800000
         USING RBSECT,R7                                                51900000
         STM   RDCB,RD,RBEXSAVE         SAVE I/O SUPP REGS IN SVRB ESA  52000000
         L     RF,ULREQ                 USER'S                          52100000
         LA    RF,0(,RF)                ROUTINE                         52200000
         L     RD,RBLINK                PTR TO PREVIOUS RB              52300000
         TM    RBSTAB-RBSECT(RD),RBFTSVRB  IS PREVIOUS A PRB            52400000
         BNO   CDA04850                 BRANCH IF YES                   52500000
         LR    R7,RD                    USE PREVIOUS RB                 52600000
CDA04850 LM    RDCB,RD,RBGRS2           RESTORE USER REGS               52700000
         SYNCH (15)                     SYNCH TO USER ROUTINE           52800000
         L     R7,CVTPTR                CVT ADDRESS                     52900000
         L     R7,CVTTCBP-CVT(,R7)      TCB PTR                         53000000
         L     R7,K4(,R7)               TCB ADDRESS                     53100000
         L     R7,TCBRBP-TCB(,R7)       SVRB ADDRESS                    53200000
         LM    RDCB,RD,RBEXSAVE         RESTORE USER REGS               53380000
         ST    RF,ULWK1                 SAVE USER RETURN CODE    Y01021 53382000
         AIF   ('&LIB' EQ 'LIB1').LIB12C3                               53390000
         DEBCHK (RDCB)                  VERIFY DEB               Y01021 53396000
         ST    R1,DXPDEBAD              STORE DEBAD IN WORKAREA  Y01021 53396400
         L     RF,ULWK1                 RESTORE USER RETURN CODE Y01021 53398000
.LIB12C3 ANOP                                                           53398400
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT = 1                53400000
         BR    RB                       UNCONDITIONAL BRANCH            53600000
         EJECT                                                          53700000
         SPACE 1                                                        53800000
**********************************************************************  53900000
*                                                                    *  54000000
*                    CONSTANTS                                       *  54100000
*                                                                    *  54200000
**********************************************************************  54300000
UTLCONST DC    C'UTL0'                  SEARCH ARGUMENT                 54400000
ENQLIST  DC    X'FF084000'              ENQ/DEQ CONSTS-SYSTEM, NO SMC,  54500000
*                                       NO RET                          54600000
QNAME    DC    C'SYSUSERL'              QNAME USED IN ENQ/DEQ ON        54700000
*                                       USER LABEL TRACK                54800000
*   CHANNEL PROGRAM TO READ FIRST TRAILER                               54900000
ULCP1    CCW   X'12',0,X'40',8          READ COUNT                      55000000
         CCW   X'29',0,X'40',4          SEARCH KEY EQUAL                55100000
         CCW   X'08',0,0,0              TIC *-16                        55200000
         CCW   X'06',0,0,80             READ DATA                       55300000
ULCP2    CCW   X'05',0,X'40',80         WRITE DATA                      55400000
WRDATA   EQU   ULCP2                                                    55500000
ULCP3    CCW   X'31',0,X'40',5          SEARCH ID EQUAL                 55600000
         CCW   X'08',0,0,0              TIC                             55700000
         CCW   X'1E',0,X'50',92         READ COUNT,KEY,DATA  (SKIP)     55800000
RDCKD    CCW   X'1E',0,0,92             READ COUNT,KEY,DATA             55900000
         XCTLTABL ID=(FINALMOD,2J,SMFMOD,2H),SVC=020                    56000021
         IECDSECS CVT,TCB,RB,DCB,DEB,UCB,MAIN,USERLAB,USERTOT,WTG,     *56100021
               EXPAND=YES                                               56200000
         IECEQU                                                         56300000
         END                                                            56400000
