         TITLE 'IFG0202D - DA OUTPUT USER TRAILER LABEL PROCESSING'     00200000
         GBLC  &LIB                                                     00400000
&LIB     SETC  'LIB1'                                                   00600000
IFG0202D CSECT                                                          00800000
*********************************************************************** 01000000
*                                                                     * 01200000
*                                                                     * 01400000
*          RELEASE 25 DELETIONS/CHANGES                               * 01600000
*          RELEASE 24 DELETIONS/CHANGES                               * 01800000
*          RELEASE 23 DELETIONS/CHANGES                               * 02000000
*          RELEASE 22 DELETIONS/CHANGES                               * 02200000
*          RELEASE 21 DELETIONS/CHANGES                               * 02400000
*                                                                     * 02600000
* STATUS CHANGE LEVEL 000                                             * 02800000
*                                                                     * 03000000
* FUNCTION -                                                          * 03200000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03400000
*    CLOSE DA OUTPUT USER LABELS FUNCTION.                            * 03600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 03800000
*                                                                     * 04000000
* ENTRY POINTS -                                                      * 04200000
*         IFG0202D - ENTRY POINT VIA AN XCTL FROM THE FOLLOWING--     * 04400000
*             IFG0201R - CONTINUE PROCESSING OUTPUT USER LABELS       * 04600000
*                        FUNCTION.                                    * 04800000
*                                                                     * 05000000
* INPUT -                                                             * 05200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05400000
*                                                                     * 05600000
* OUTPUT -                                                            * 05800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06000000
*                                                                     * 06200000
* EXTERNAL REFERENCES -                                               * 06400000
*         IFG020RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 06600000
*                    WAIT.                                            * 06800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07000000
*                                                                     * 07200000
* EXITS, NORMAL -                                                     * 07400000
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING--            * 07600000
*         IFG0202E - PROCESS CLOSE DA WRITE FILE MARK FUNCTION.       * 07800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 08000000
*                                                                     * 08200000
* EXITS, ERROR -                                                      * 08400000
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0200P, IF AN      * 08600000
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 08800000
*    'FUNCTION PROLOG(S)'.                                            * 09000000
*                                                                     * 09200000
* TABLES/WORK AREAS -                                                 * 09400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 09600000
*                                                                     * 09800000
* ATTRIBUTES -                                                        * 10000000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 10200000
*                                                                     * 10400000
* CHARACTER CODE DEPENDENCY -                                         * 10600000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10800000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 11000000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 11200000
*                                                                     * 11400000
* NOTES -                                                             * 11600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11800000
*                                                                     * 12000000
*********************************************************************** 12200000
         EJECT                                                          12400000
         USING ULWK,RC                                                  12600000
         USING IHADCB,RDCB                                              12800000
         USING FORCORE,RCORE                                            13000000
         USING UCBOB,RUCB                                               13200000
         USING TCB,RET                                                  13400000
         USING TIOENTRY,RTIOT                                           13600000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         13800000
         USING *,RBASE                                                  14000000
         EJECT                                                          14200000
*                                                                     * 14400000
*                          FUNCTION PROLOG                            * 14600000
*                                                                     * 14800000
*********************************************************************** 15000000
*                                                                     * 15200000
* FUNCTION NAME -                                                     * 15400000
*    CLOSE DA OUTPUT USER LABELS FUNCTION.                            * 15600000
*                                                                     * 15800000
* (STATUS) -                                                          * 16000000
*    NOT APPLICABLE                                                   * 16200000
*                                                                     * 16400000
* FUNCTION -                                                          * 16600000
*    DETERMINE IF CURRENT VOLUME IS FIRST VOLUME FOR NEW DA DATA SET. * 16800000
*    LOCATE FIRST VOLUME BY SEARCHING THE UCB'S FOR ALL UNITS         * 17000000
*    ALLOCATED TO THE DATA SET.                                       * 17200000
*    READ THE FORMAT 1 DSCB.                                          * 17400000
*    GET AN AREA OF MAIN STORAGE WHICH IS USED AS A                   * 17600000
*    WORKAREA-BUFFER IN WHICH THE USER LABEL RECORDS ARE FORMATTED AND* 17800000
*    AS A SAVE AREA FOR THE REGISTERS OF THE I/O SUPPORT FUNCTION     * 18000000
*    REQUIRING USER LABEL PROCESSING.  THE LAST PART OF THE AREA      * 18200000
*    OBTAINED IS USED FOR A 16-BYTE PARAMETER LIST.                   * 18400000
*    IF A TRACK WAS ALLOCATED FOR USER LBLS,CONTROL IS GIVEN TO THE   * 18600000
*    USER'S LABEL CONSTRUCTION ROUTINE VIA SYNCHRONOUS EXIT (SVC 12). * 18800000
*    ON RETURN FROM THE USER'S ROUTINE, IF A LABEL WAS CONSTRUCTED, IT* 19000000
*    IS WRITTEN FOLLOWED BY 2 FILEMARKS FOR HEADERS (UHL(N+1)), OR    * 19200000
*    ONE FILEMARK FOR TRAILERS (UTL(N+1)).  DEPENDING ON THE RETURN   * 19400000
*    CODE PASSED BY THE USER'S ROUTINE, ANOTHER LABEL IS PROCESSED OR * 19600000
*    CONTROL IS GIVEN BACK TO THE I/O SUPPORT FUNCTION.               * 19800000
*    WRITE UP TO EIGHT USER TRAILER LABELS AS REQUIRED FOR DATA SETS  * 20000000
*    ON DIRECT ACCESS VOLUMES.                                        * 20200000
*                                                                     * 20400000
* ENTRY POINTS -                                                      * 20600000
*    ENTERED FROM THE FOLLOWING--                                     * 20800000
*    CLOSE DA WRITE DSCB FUNCTION.                                    * 21000000
*                                                                     * 21200000
* INPUT -                                                             * 21400000
*    A POINTER TO EACH OF THE FOLLOWING--                             * 21600000
*       CURRENT PARAMETER LIST ENTRY.                                 * 21800000
*       DD ENTRY IN THE TIOT.                                         * 22000000
*       WTG TABLE.                                                    * 22200000
*       CURRENT WTG TABLE ENTRY.                                      * 22400000
*       DCB.                                                          * 22600000
*       CLOSE WORK AREA.                                              * 22800000
*       RESIDENT ROUTINE.                                             * 23000000
*       UCB.                                                          * 23200000
*       DEB.                                                          * 23400000
*                                                                     * 23600000
* OUTPUT -                                                            * 23800000
*    USER TRAILER LABELS ARE WRITTEN ON THE FIRST VOLUME FOR NEW DA   * 24000000
*    DATA SETS.                                                       * 24200000
*                                                                     * 24400000
* EXTERNAL REFERENCES -                                               * 24600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 24800000
*    CONVERT ROUTINE TTR TO MBBCCHHR.                                 * 25000000
*    USER'S OUTPUT LABEL EXIT ROUTINES - ENTERED BY MEANS OF          * 25200000
*    SYNCHRONOUS EXIT (SVC 12) WITH THE FOLLOWING INPUT               * 25400000
*       REG 0    CONTAINS NO MEANINGFUL INFO                          * 25600000
*           1    POINTER TO 4 WORD PARAMETER LIST WHICH CONTAINS -    * 25800000
*                POINTER TO LABEL BUFFER                              * 26000000
*                POINTER TO DCB                                       * 26200000
*                FLAG BYTE, PTR TO STATUS INFO (IF PERMANENT ERROR)   * 26400000
*                OR ZERO                                              * 26600000
*                POINTER TO IMAGE AREA (IF TOTALING WAS REQUESTED)    * 26800000
*                OR ZERO                                              * 27000000
*           2-13 CONTENTS OF USER'S REGS BEFORE I/O SUPP              * 27200000
*           14   RETURN ADDRESS                                       * 27400000
*           15   EXIT ADDRESS                                         * 27600000
*                                                                     * 27800000
*    BEFORE EXITING, THIS FUNCTION'S REGISTERS 2-13 ARE SAVED IN THE  * 28000000
*    SVRB EXTENDED SAVE AREA.  THE USER'S REGISTERS 2-13 ARE RESTORED * 28200000
*    FROM THE SVRB.  THE LOCK BIT (BIT 6) IN DCBOFLGS FIELD IS SET TO * 28400000
*    1 TO PREVENT ANOTHER I/O SUPPORT FUNCTION FROM OPERATING ON THIS * 28600000
*    DCB WHILE THE USER IS IN CONTROL.  ON RETURN FROM THE USER'S     * 28800000
*    ROUTINE, THIS BIT IS RESET TO 0.                                 * 29000000
*                                                                     * 29200000
* EXITS, NORMAL -                                                     * 29400000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 29600000
*    CLOSE DA WRITE FILE MARK FUNCTION.                               * 29800000
*                                                                     * 30000000
* EXITS, ERROR -                                                      * 30200000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 30400000
*    EXIT WITH THE FOLLOWING INTERNAL CODES--                         * 30600000
*       89 - 314 ABEND - ERROR IN READING THE FORMAT 1 DSCB FROM      * 30800000
*                        THE FIRST VOLUME.                            * 31000000
*    NO USER LABEL EXTENT EXISTS-THE APPROPRIATE EXIT ROUTINE IS      * 31200000
*    ENTERED WITH THE BUFFER POINTER SET TO ZERO.   OTHER             * 31400000
*    INPUT AS USUAL.                                                  * 31600000
*    I/O ERROR WRITING A USER LABEL - THE USER'S ROUTINE IS ENTERED.  * 31800000
*    AGAIN WITH                                                       * 32000000
*       BIT 0 OF FLAG BYTE SET TO ONE, PTR TO STANDARD                * 32200000
*       STATUS INFORMATION.                                           * 32400000
*    OTHER INPUT AS FOR NORMAL ENTRY.                                 * 32600000
*                                                                     * 32800000
* TABLES/WORK AREAS -                                                 * 33000000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 33200000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 33400000
*                                                                     * 33600000
* ATTRIBUTES -                                                        * 33800000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 34000000
*                                                                     * 34200000
* CHARACTER CODE DEPENDENCY -                                         * 34400000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 34600000
*                                                                     * 34800000
* NOTES -                                                             * 35000000
*    NOT APPLICABLE                                                   * 35200000
*                                                                     * 35400000
*********************************************************************** 35600000
         EJECT                                                          35800000
         GETMAIN R,LV=USERL,SP=250      OBTAIN CORE FOR WORK AREA,      36000000
*                                LABEL BUFFER AND PARAMETER LIST (72+8) 36200000
         XC    0(USERL,R1),0(R1)        CLEAR WKAREA AND BUFFER         36400000
         STM   RES,RC,0(R1)             SAVE REGS 5-12 FOR CALLER       36600000
         LR    RC,R1                    SET BASE FOR ULWK DSECT         36800000
         NI    ULREQ,X'FF'-LASTNTRY     TURN OFF LAST ENTRY INDIC IF ON 37000000
         XC    DXCCW1(DXCCW8-DXCCW1),DXCCW1  CLEAR CHAN PROG AREA       37200000
*                                                                       37400000
*        DETERMINE IF A USER LABEL EXTENT HAS BEEN ALLOCATED FOR THIS   37600000
*        DATA SET.                                                      37800000
*                                                                       38000000
         CLI   DSCEXTYP,ULEXT           IS 1ST EXTENT FOR USER LABELS   38200000
         BE    CDA05200                 YES, CONTINUE                   38400000
*                                                                       38600000
*        NO USER LABEL TRACK WAS ALLOCATED.  EXIT TO USER'S ROUTINE     38800000
*        WITH POINTER TO LABEL BUFFER ZEROED.                           39000000
*                                                                       39200000
         XC    ULERRPTR,ULERRPTR        CLEAR ANY ERROR INDICTNS        39400000
         SR    R1,R1                    BUFFER POINTER TO ZERO          39600000
         LA    RB,CDA05500              POINT TO RETURN AFTER SYNCH     39800000
         B     CDA06300                 GO SYNCH TO USER                40000000
*                                                                       40200000
*        EXTENT EXISTS - PROCESS USER LABELS                            40400000
*                                                                       40600000
CDA05200 EQU   *                                                        40800000
         XC    DXDAADDR,DXDAADDR        ZERO IOBOADAD IN IOS' IOB       41000000
         MVC   DXDAADDR+K3(K4),DSCLOWLM  CCHH FROM START OF 1ST EXTENT  41200000
*                                       IF 2321, GET BB FROM UCB        41400000
         CLI   UCBID,UCBMAIN            IS DEVICE 2321                  41600000
         BE    CDA05250                 NO,BRANCH                       41800000
         USING UCBDCELL,RUCB                                            42000000
         MVC   DXDAADDR+K1(K2),UCBDBBNR  2321, GET BB FROM SUB-UCB      42200000
         USING UCBOB,RUCB                                               42400000
*                                                                       42600000
CDA05250 EQU   *                                                        42800000
*                                                                       43000000
*        PROCESS USER TRAILER LABELS.                                   43200000
*                                                                       43400000
*                                                                       43600000
*        STRUCTURE COUNT AND KEY FIELDS IN WORK AREA.  SET IOBDADAD     43800000
*        IN I/O SUPPORT'S IOB.                                          44000000
*                                                                       44200000
         LA    R1,ULWK8                 ADDR OF COUNT                   44400000
         ST    R1,DXCCW1                READ COUNT INTO WK1             44600000
         LA    R1,ULWK10                ADDR OF KEY                     44800000
         ST    R1,DXCCW2                SEARCH ON KEY IN WK3            45000000
         LA    R1,DXCCW1                ADDR OF READ COUNT CCW          45200000
         ST    R1,DXCCW3                TIC TO CCW1                     45400000
         OC    DXCCW1(K32),ULCP13       OR CP SKELETON OVER ADDRESSES   45600000
         MVC   ULWK10,UTLCONS3          KEY=UTLO FOR SEARCH KEY EQUAL   45800000
*                                                                       46000000
         BAL   RB,CDA06000              EXECUTE CP TO FIND UTL0         46200000
         TM    DXECB,ECBNOERR           CHECK FOR I/O ERROR             46400000
         BZ    CDA05400                 ERROR, BR TO SET UP EXIT TO USR 46600000
         SPACE                                                          46800000
*                           SET UP  CP TO WRITE USER TRLR               47000000
*                           AS EACH LABEL (UTLN) IS WRITTEN, A FILE     47200000
*                           MARK (UTL(N+1)) WILL BE WRITTEN FOLLOWING   47400000
*                                                                       47600000
         XC    DXCCW1(DXCCW5-DXCCW1),DXCCW1  CLEAR CHNL PGM 1 OUT       47800000
         LA    R1,DXDAADDR+K3           ADDR OF ID                      48000000
         ST    R1,DXCCW1                SEARCH ID FROM IOBDADAD+3       48200000
         LA    R1,DXCCW1                ADDR OF SEARCH ID CCW           48400000
         ST    R1,DXCCW2                TIC TO CCW1                     48600000
         LA    R1,ULWK8                 ADDR OF COUNT AND KEY           48800000
         ST    R1,DXCCW3                WRITE C,K FROM ULWK1            49000000
         LA    R1,ULWK5                 ADDR OF DATA                    49200000
         ST    R1,DXCCW4                WRITE LABEL FROM BUFFER         49400000
         OC    DXCCW1(K32),ULCP23       OR CP SKELETON OVER ADDRESSES   49600000
         MVC   DXCCW5(K24),DXCCW1       APPEND CP FOR WRITE CHECKING    49800000
         LA    R1,DXCCW5                ADDR OF SEARCH ID CCW           50000000
         ST    R1,DXCCW6                TIC BACK TO CCW5                50200000
         MVI   DXCCW6,CCWTIC            RESTORE TIC OP                  50400000
         MVI   DXCCW7,X'1E'             MAKE OP READ                    50600000
         OI    DXCCW7+K4,X'10'          SET SKIP BIT ON                 50800000
         NI    DXCCW7+K4,X'FF'-CCWCMDCH  TURN OFF CC FLAG IN LAST CCW   51000000
         MVC   ULWK5(K12),ULWK8         SET UP COUNT, KEY FOR FILE MARK 51200000
         SR    R1,R1                    CLEAR R1                        51400000
         STC   R1,ULWK6+K3              DATA LENGTH=0 FOR FILE MRK      51600000
*                                       IF DISP=MOD,UTL0 MAY HAVE       51800000
*                                       LENGTH OF 80 BYTES              52000000
CDA05300 EQU   *                                                        52200000
         IC    R1,ULWK9                 R OF COUNT FOR UTL TO BE WRITTN 52400000
         BCTR  R1,0                     R-1                             52600000
         STC   R1,DXDAADDR+K7           R IN IOBDADAD                   52800000
         LA    R1,K2(,R1)               R-1+2=R+1                       53000000
         STC   R1,ULWK6                 R IN COUNT FIELD OF UTL(N+1)    53200000
*                                                                       53400000
         IC    R1,ULWK10+K3             N FROM LABEL TO BE WRITTEN      53600000
         LA    R1,K1(,R1)               N+1                             53800000
         STC   R1,ULWK7+K3              KEY FOR UTL(N+1)                54000000
*                                                                       54200000
         MVI   ULWK9+K3,K80             DATA LENGTH = 80 FOR UTLN       54400000
*                                                                       54600000
         CLI   ULWK10+K3,MAXNOLAB       CHECK IF 8 TRAILERS WERE WRITTN 54800000
         BNL   CDA05500                 YES, BRANCH TO SET UP RETURN    55000000
*                                                                       55200000
         MVC   ULBUFR(K4),ULWK7         PRIME LABEL BUFFER WITH UTLN    55400000
*                                                                       55600000
*        GO TO USER'S ROUTINE TO CONSTRUCT LABEL.                       55800000
*                                                                       56000000
         BAL   RB,CDA06100              GO EXIT TO USER'S ROUTINE       56200000
         MVC   ULBUFR(K4),ULWK7         REINSERT UTLN                   56400000
         LTR   RF,RF                    CHECK FOR RETURN CODE=0         56600000
         BZ    CDA05500                 CODE IS ZERO, BRANCH TO RETURN  56800000
         ST    RF,ULWK1                 SAVE RETURN CODE                57000000
         BAL   RB,CDA06000              GO WRITE LABEL                  57200000
*                                                                       57400000
         TM    DXECB,ECBNOERR           CHECK FOR I/O ERROR             57600000
         BZ    CDA05400                 YES, BR TO TAKE SPECIAL EXIT    57800000
         CLI   ULWK1+K3,READNEXT        CHECK RET CODE FOR MORE LABELS  58000000
         BE    CDA05500                 NO, PREVIOUS LABEL WAS LAST     58200000
         CLI   ULWK1+K3,WRITNEXT        CHECK IF RETURN CODE IS VALID   58400000
         BNE   CDA05500                 BRANCH IF NOT VALID             58600000
*                                                                       58800000
         MVC   ULWK8(K12),ULWK5         UTL(N+1) BECOMES C,K OF NXT LBL 59000000
         B     CDA05300                 BR TO PROCESS NEXT LABEL        59200000
         EJECT                                                          59400000
CDA05400 EQU   *                                                        59600000
*                                                                       59800000
*        IF AN I/O ERROR OCCURS WRITING USER TRAILER LABELS, A SPECIAL  60000000
*        EXIT IS TAKEN TO THE USER'S ROUTINE.  INPUT TO THE USER'S      60200000
*        ROUTINE IS THE SAME AS FOR OTHER EXITS WITH ONE EXCEPTION-     60400000
*        IN THE THIRD WORD OF THE PARAMETER LIST, BIT 0 IS SET TO ONE   60600000
*        AND THE THREE LOW ORDER BYTES CONTAIN A POINTER TO STATUS      60800000
*        INFO (PTR TO IOB).                                             61000000
*                                                                       61200000
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   61400000
         ST    R1,ULERRPTR              IN PARAMETER LIST               61600000
         OI    ULERRPTR,ERROR           FLAG ERROR                      61800000
         BAL   RB,CDA06200              GO TO SYNCH TO USER             62000000
*                                                                       62200000
*        DETERMINE WHICH I/O SUPPORT FUNCTION  REQUIRED USER            62400000
*        TRAILER LABELS TO BE WRITTEN                                   62600000
*                                                                       62800000
CDA05500 EQU   *                        SET RETURN FOR TRLR PROCESSING  63000000
*                                                                       63200000
*        CONTROL IS FROM CLOSE.  FOR NEW DIRECT DATA SETS, THE          63400000
*        UCB ADDRESS IN THE WORK DEB REFLECTS THE 1ST VOLUME AND MUST   63600000
*        BE RESTORED TO THE UCB ADDRESS FOR THE CURRENT VOLUME BEFORE   63800000
*        CONTINUING WITH CLOSE PROCESSING.                              64000000
*                                                                       64200000
         L     RUCB,TIOEFSRT-1          GET ADDRESS OF CURRENT UCB      64400000
*              COMPUTE MAIN UCB ADDRESS                                 64600000
         SR    R1,R1                    CLEAR REG                       64800000
         CLI   UCBID,UCBMAIN            IS DEVICE 2321                  65000000
         BE    CDA05600                 BR IF NOT 2321                  65200000
         USING UCBDCELL,RUCB            BASE FOR SUB-UCB                65400000
         LH    R1,UCBDBBNR              PICK UP BB                      65600000
         SLA   R1,K4                    MPY BY 16                       65800000
         LA    R1,UCBDCELL-UCBOB(R1)    16(BB)+LENGTH MAIN UCB          66000000
         LCR   R1,R1                    NEGATE                          66200000
CDA05600 EQU   *                                                        66400000
         AR    R1,RUCB                  MAIN UCB ADDRESS                66600000
*                                                                       66800000
         ST    R1,DXCCW10               STORE MAIN UCB ADDRESS          67000000
         MVC   DXDEBUCB+K1(K3),DXCCW10+K1  RESTORE WORK DEB UCB ADDR    67200000
*                                                                       67400000
*        FREE  WORKAREA AND LABEL BUFFER AND XCTL TO I/O SUPPORT        67600000
*        MODULE WHICH CALLED THIS MODULE.                               67800000
*                                                                       68000000
         LR    R1,RC                    START OF AREA TO BE FREED       68200000
         LM    RES,RC,0(R1)             RESTORE CALLING MODULE'S REGS   68400000
         FREEMAIN R,LV=USERL,SP=250,A=(1)  FREE USER LABEL WORK AREA,  C68600000
                                        LABEL BUFFER AND PARAMETER LIST 68800000
*                                                                       69000000
         SR    RET,RET                  SET UP FOR BRANCH TABLE         69200000
         IECRES XCTL,DAFINMOD,(RET)     XCTL TO DAFINMOD                69400000
         EJECT                                                          69600000
         SPACE 2                                                        69800000
*                                                                       70000000
*        CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS                      70200000
*                                                                       70400000
         SPACE                                                          70600000
*        IT IS ASSUMED THAT ALL CONTROL BLOCKS HAVE ALREADY BEEN SET UP 70800000
         SPACE 3                                                        71000000
CDA06000 EQU   *                                                        71200000
         EXCP  DXIOB                    INITIATE I/O                    71400000
*                                                                       71600000
         IECRES WAIT                    WAIT FOR I/O COMPLETION         71800000
*                                                                       72000000
         BR    RB                       UNCONDITIONAL BRANCH            72200000
         EJECT                                                          72400000
*        CLOSED SUBROUTINE TO SAVE AND RESTORE REGISTERS, SET UP INPUT, 72600000
*        AND ISSUE THE SVC SYNCH  FOR SYNCHRONOUS EXIT TO PROBLEM PROG. 72800000
*        THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE SVRB EXTENDED    73000000
*        SAVE AREA AND THE USER'S REGISTERS 2-13 ARE RESTORED FROM THE  73200000
*        SVRB.  REGISTER CONTENTS ARE AS FOLLOWS-                       73400000
*                        R0 - CONTAINS NO MEANINGFUL INFO               73600000
*                        R1 - PTR TO PARAMETER LIST                     73800000
*                    R2-R13 - USER'S CONTENTS BEFORE I/O SUPPORT        74000000
*                       R14 - RETURN ADDRESS (SET BY SYNCH)             74200000
*                       R15 - EXIT ADDRESS                              74400000
*                                                                       74600000
CDA06100 EQU   *                                                        74800000
         XC    ULERRPTR,ULERRPTR        ZERO ERROR INDICATIONS          75000000
CDA06200 EQU   *                                                        75200000
         LA    R1,ULBUFR                PTR TO LABEL BUFFER             75400000
CDA06300 EQU   *                                                        75600000
         STM   R1,RDCB,ULPARM           BUFFER,DCB PTRS TO PARM LIST    75800000
         XC    ULTOTPTR,ULTOTPTR        ZERO TOTALING AREA              76000000
         TM    DCBDSORG,DCBORGDA        CK FOR DIRECT ORGANIZATION      76200000
         BO    CDA06400                 BR IF DIRECT                    76400000
         TM    DCBMACRF,DCBMEXCP        CK IF EXCP                      76600000
         BO    CDA06400                 BR IF EXCP,SKIP TOTALING        76800000
         TM    DCBOPTCD,DCBOPTT         TEST,BR IF USER TOTALING        77000000
         BZ    CDA06400                 HAS NOT BEEN REQUESTED          77200000
*                                                                       77400000
         L     R7,DCBDEBAD              GET ADDRESS OF USER'S DEB       77600000
         SR    R1,R1                    CLEAR WORK REG                  77800000
         IC    R1,DEBNMEXT-DEB(R7)      GET NUMBER OF EXTENTS           78000000
         SLL   R1,K4                    MULTIPLY BY 16                  78200000
         L     R7,K36(R1,R7)            GET ADDR TOTALING WORKAREA-     78400000
*                                       DEB ADDR+32+4+LENGTH EXTENTS    78600000
         USING TOTSAVWA,R7              SET BASE - TOTALING AREA        78800000
         MVC   ULTOTPTR,TOTEOVPT        CURRENT IMAGE AREA ADDR TO      79000000
*                                       USR LBL PARM LIST               79200000
         DROP  R7                       DROP TOTALING AREA BASE         79400000
*                                                                       79600000
CDA06400 EQU   *                                                        79800000
         LA    R1,ULPARM                POINT TO PARAMETER LIST         80000000
         L     R7,CVTPTR                CVT ADDRESS                     80200000
         L     R7,CVTTCBP-CVT(,R7)      TCB PTR                         80400000
         L     R7,K4(,R7)               TCB ADDRESS                     80600000
         L     R7,TCBRBP-TCB(,R7)       SVRB ADDRESS                    80800000
         NI    DCBOFLGS,X'FF'-DCBOLOCK  SET LOCK BIT = 0                81000000
         USING RBSECT,R7                                                81200000
         STM   RDCB,RD,RBEXSAVE         SAVE I/O SUPP REGS IN SVRB AREA 81400000
         L     RF,ULREQ                 ADDRESS OF USER'S ROUTINE       81600000
         LA    RF,0(,RF)                CLEAR HIGH ORDER BYTE           81800000
         L     RD,RBLINK                PTR TO PREVIOUS RB              82000000
         TM    RBSTAB-RBSECT(RD),RBFTSVRB  IS PREVIOUS A PRB            82200000
         BNO   CDA06500                 YES,BRANCH                      82400000
         LR    R7,RD                    USE PREVIOUS RB                 82600000
CDA06500 LM    RDCB,RD,RBGRS2           RESTORE USER REGS               82800000
         SYNCH (15)                     SYNCH TO USER ROUTINE           83000000
         L     R7,CVTPTR                CVT ADDRESS                     83200000
         L     R7,CVTTCBP-CVT(,R7)      TCB  PTR                        83400000
         L     R7,K4(,R7)               TCB  ADDRESS                    83600000
         L     R7,TCBRBP-TCB(,R7)       SVRB ADDRESS                    83800000
         LM    RDCB,RD,RBEXSAVE         RESTORE I/O SUPPORT REGS        84000000
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT = 1                84200000
         MVC   ULBUFR(K4),ULWK10        REINSERT  UTLN/UHLN             84400000
         BR    RB                       UNCONDITIONAL BRANCH            84600000
         EJECT                                                          84800000
         SPACE 1                                                        85000000
**********************************************************************  85200000
*                                                                    *  85400000
*                    CONSTANTS                                       *  85600000
*                                                                    *  85800000
**********************************************************************  86000000
         SPACE 1                                                        86200000
         DS    0F                                                       86400000
UTLCONS3 DC    C'UTL0'                  KEY USED IN SEARCH KEY EQ       86600000
ULCP13   CCW   X'12',0,X'40',8          READ COUNT                      86800000
         CCW   X'29',0,X'40',4          SEARCH KEY EQUAL                87000000
         CCW   X'08',0,0,0              TIC                             87200000
         CCW   X'03',0,0,1              NOP                             87400000
*                                                                       87600000
ULCP23   CCW   X'31',0,X'40',5          SEARCH ID EQUAL                 87800000
         CCW   X'08',0,0,0              TIC TO CCW1                     88000000
         CCW   X'1D',0,X'40',92         WRITE CKD    UTLO     LABEL     88200000
         CCW   X'1D',0,X'40',12         WRITE CKD    UTL0     FILE MARK 88400000
         XCTLTABL ID=(DAFINMOD,2E),SVC=020                              88600000
         IECDSECS CVT,TCB,RB,TIOT,DCB,DEB,UCB,MAIN,USERLAB,USERTOT,    *88800000
               EXPAND=YES                                               89000000
         IECEQU                                                         89200000
         END                                                            89400000
