         TITLE 'IFG0202L - CLOSE FINAL EXIT MODULE'                     00300000
         COPY  LCGASMSW                                                 00350000
IFG0202L CSECT                                                          01200000
*********************************************************************** 01500000
*                                                                     * 01800000
*                                                                     * 02100000
*          RELEASE 25 DELETIONS/CHANGES                               * 02400000
*          RELEASE 24 DELETIONS/CHANGES                               * 02700000
*          RELEASE 23 DELETIONS/CHANGES                               * 03000000
*          RELEASE 22 DELETIONS/CHANGES                               * 03300000
*          RELEASE 21 DELETIONS/CHANGES                               * 03600000
*                                                                M0039  03700021
*                                                                     * 03900000
* STATUS CHANGE LEVEL 000                                             * 04200000
*                                                                     * 04500000
* FUNCTION -                                                          * 04800000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 05100000
*    CLOSE FINAL TERMINATION FUNCTION.                                * 05400000
*       THIS FUNCTION STARTS IN MODULE IFG0202K.                      * 05700000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 06000000
*                                                                     * 06300000
* ENTRY POINTS -                                                      * 06600000
*         IFG0202L - ENTRY POINT VIA AN XCTL FROM THE FOLLOWING--     * 06900000
*             INITIAL ENTRY--                                         * 07200000
*                IFG0202K - CONTINUE PROCESSING CLOSE FINAL           * 07500000
*                           TERMINATION FUNCTION.                     * 07800000
*             SECOND ENTRY--                                          * 08100000
*                IFG0200P - PROCESS ANY ERROR FOR DELAY ABEND.        * 08400000
*             THIRD ENTRY--                                           * 08700000
*                IFG0209R - CONTINUE PROCESSING CLOSE FINAL           * 09000000
*                           TERMINATION FUNCTION.                     * 09300000
*                                                                     * 09600000
* INPUT -                                                             * 09900000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 10200000
*                                                                     * 10500000
* OUTPUT -                                                            * 10800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11100000
*                                                                     * 11400000
* EXTERNAL REFERENCES -                                               * 11700000
*         IFG020RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 12000000
*                    WAIT.                                            * 12300000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 12600000
*                                                                     * 12900000
* EXITS, NORMAL -                                                     * 13200000
*    EXIT VIA AN XCTL MACRO-INSTRUCTION TO THE FOLLOWING--            * 13500000
*         IFG0209R - FOR TRACE TERMINATION FACILITY.                  * 13800000
*         IGC0001I - FOR CONCATENATION OF UNLIKE ATTRIBUTES.          * 14100000
*    OR AN EXIT (SVC 3) TO THE CALLING PROGRAM.                       * 14400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 14700000
*                                                                     * 15000000
* EXITS, ERROR -                                                      * 15300000
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0200P, IF AN      * 15600000
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 15900000
*    'FUNCTION PROLOG(S)'.                                            * 16200000
*                                                                     * 16500000
* TABLES/WORK AREAS -                                                 * 16800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 17100000
*                                                                     * 17400000
* ATTRIBUTES -                                                        * 17700000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 18000000
*                                                                     * 18300000
* CHARACTER CODE DEPENDENCY -                                         * 18600000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 18900000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 19200000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 19500000
*                                                                     * 19800000
* NOTES -                                                             * 20100000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 20400000
*                                                                     * 20700000
*********************************************************************** 21000000
         EJECT                                                          21300000
         USING IHADCB,RDCB                                              21600000
         USING FORCORE,RCORE                                            21900000
         USING TCB,RET                                                  22200000
         USING UCBOB,RUCB                                               22500000
         USING CVT,RD                                                   22800000
         USING TIOENTRY,RTIOT                                           23100000
         USING DEB,RDEB                                                 23400000
         USING WTG,RWTG                                                 23700000
         USING WTGENTRY,RWTGC                                           24000000
*                                                                       24300000
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         24600000
         USING *,RBASE                                                  24900000
         EJECT                                                          25200000
*                                                                     * 25500000
*                          FUNCTION PROLOG                            * 25800000
*                                                                     * 26100000
*********************************************************************** 26400000
*                                                                     * 26700000
* FUNCTION NAME -                                                     * 27000000
*    CLOSE FINAL TERMINATION FUNCTION.                                * 27300000
*                                                                     * 27600000
* (STATUS) -                                                          * 27900000
*    NOT APPLICABLE                                                   * 28200000
*                                                                     * 28500000
* FUNCTION -                                                          * 28800000
*    INTERFACE WITH TRACE TERMINATION FACILITY.                       * 29100000
*    FREE STORAGE FOR IRB, DEB, WORKAREA AND ECBLIST.                 * 29400000
*    RELEASE WTG TABLE.                                               * 29700000
*    EXIT TO CALLING PROGRAM OR INITIAL LOAD OF OPEN IF CONCATENATION * 30000000
*    OF UNLIKE ATTRIBUTES IS SPECIFIED.                               * 30300000
*                                                                     * 30600000
* ENTRY POINTS -                                                      * 30900000
*    ENTERED FROM THE FOLLOWING--                                     * 31200000
*    CLOSE FINAL RESTORE SYSTEM FUNCTION.                             * 31500000
*                                                                     * 31800000
* INPUT -                                                             * 32100000
*    A POINTER TO EACH OF THE FOLLOWING--                             * 32400000
*       CURRENT PARAMETER LIST ENTRY.                                 * 32700000
*       DD ENTRY IN THE TIOT.                                         * 33000000
*       WTG TABLE.                                                    * 33300000
*       CURRENT WTG TABLE ENTRY.                                      * 33600000
*       DCB.                                                          * 33900000
*       CLOSE WORK AREA.                                              * 34200000
*       RESIDENT ROUTINE.                                             * 34500000
*       UCB.                                                          * 34800000
*       DEB.                                                          * 35100000
*                                                                     * 35400000
* OUTPUT -                                                            * 35700000
*    ALL STORAGE USED BY CLOSE RELEASED.                              * 36000000
*                                                                     * 36300000
* EXTERNAL REFERENCES -                                               * 36600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 36900000
*                                                                     * 37200000
* EXITS, NORMAL -                                                     * 37500000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37800000
*    CALLING PROGRAM.                                                 * 38100000
*    INITIAL LOAD OF OPEN.                                            * 38400000
*                                                                     * 38700000
* EXITS, ERROR -                                                      * 39000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 39300000
*                                                                     * 39600000
* TABLES/WORK AREAS -                                                 * 39900000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 40200000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 40500000
*                                                                     * 40800000
* ATTRIBUTES -                                                        * 41100000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 41400000
*                                                                     * 41700000
* CHARACTER CODE DEPENDENCY -                                         * 42000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 42300000
*                                                                     * 42600000
* NOTES -                                                             * 42900000
*    NOT APPLICABLE                                                   * 43200000
*                                                                     * 43500000
*********************************************************************** 43800000
         EJECT                                                          44100000
         B     CFN07400(RET)            USE BRANCH TABLE                44400000
CFN07400 EQU   *                                                        44700000
         B     CFN07500                 ENTRY INITIALLY                 45000000
         B     CFN08100                 ENTRY FOR ERROR                 45300000
*        ENTRY FROM TRACE TERMINATION ROUTINE                           45600000
         LA    RC,K8(RC)                ADD 8 BYTES TO ECBLIST SIZE     45900000
         LA    R0,K8                    SET REG TO EIGHT                46200000
         SR    RD,R0                    GET ADDR OF PREFIX OF ECBLIST   46500000
         B     CFN07800                 BRANCH TO FREE WORKAREA         46800000
CFN07500 EQU   *                                                        47100000
         LA    RC,PREFIXL               INITIALIZE COUNTER FOR SIZE     47400000
*                                       OF ECBLIST                      47700000
         L     RD,WTGECBAD              LOAD ECBLIST ADDR               48000000
CFN07600 EQU   *                                                        48300000
         L     RDCB,PLISTDCB(,RPARC)    GET DCB ADDR                    48600000
         L     RCORE,WTGCORE-1          GET WORKAREA ADDR               48900000
         LA    RCORE,0(RCORE)           CLEAR HIGH ORDER BYTE           49200000
         LTR   RCORE,RCORE              WORKAREA ADDR PRESENT           49500000
         BZ    CFN07900                 BRANCH IF NOT                   49800000
         TM    WTGPATHS+K1,WTGTRACE     OPTIONAL TRACE IND. ON          50100000
         BZ    CFN07800                 BRANCH IF NOT                   50400000
         NI    WTGPATHS+K1,X'FF'-WTGTRACE  TURN OFF OPTIONAL TRACE IND  50700000
         MVC   WTGMODID,TRACEMOD        TRACE INIT MOD ID               51000000
         MVC   WTGTTR,TRACEMOD+K2       TTR OF TRACE INIT MOD           51300000
         MVC   WTGIDTTR,EXITMOD         SET RETURN MOD ID TTR           51600000
         LA    RET,K8                   SET UP FOR BRANCH TABLE         51900000
         LA    RF,DXXCTL                ADDR OF NAME POINTER            52200000
         XCTL  DE=(RWTG),SF=(E,(15))    XCTL TO INIT MOD                52500000
CFN07800 EQU   *                                                        52800000
*                                                                       53100000
*        RELEASE CORE FOR CLOSE WORK AREA                               53400000
*                                                                       53700000
         LR    R1,RCORE                 ADDR OF CORE TO BE RELEASED     54000000
         LA    R1,0(,R1)                CLEAR HI ORDER BYTE             54300000
         LA    R0,CLOSSIZE              AMNT OF CORE TO BE RELEASED     54600000
         AIF   ('&LIB' EQ 'LIB2').LIB2L1                                54700000
         FREEMAIN R,LV=(0),A=(1)        FREE WORK AREA                  54900000
.LIB2L1  ANOP                                                           54950000
         AIF   ('&LIB' EQ 'LIB1').LIB1L2                                55000000
         LR    RF,R0                                                    55050000
         FREEMAIN R,LV=(RF),SP=253,A=(1) FREE WORK AREA                 55100000
.LIB1L2  ANOP                                                           55150000
*                                                                       55200000
         LA    RC,K4(RC)                INCREMENT COUNTER BY 4          55500000
CFN07900 EQU   *                                                        55800000
         TM    PLISTOPT(RPARC),LASTNTRY  LAST ENTRY                     56100000
         LA    RWTGC,K8(,RWTGC)         NEXT WTG ENTRY                  56400000
         LA    RPARC,K4(,RPARC)         NEXT DCB ENTRY                  56700000
         BZ    CFN07600                 GET NEXT WORKAREA               57000000
         L     R5,WTGECBAD              LOAD ECBLIST ADDR               57300000
         L     RPAR,ECBPARM(R5)         LOAD PARM LIST ADDR             57600000
         LR    R1,RD                    LOAD ADDR OF ECBLIST            57900000
         LR    R0,RC                    LOAD SIZE IN REG 0              58200000
         AIF   ('&LIB' EQ 'LIB2').LIB2L3                                58300000
         FREEMAIN R,LV=(0),A=(1)        FREE ECBLIST                    58500000
.LIB2L3  ANOP                                                           58560000
         AIF   ('&LIB' EQ 'LIB1').LIB1L4                                58620000
         FREEMAIN R,LV=(RC),SP=253,A=(1) FREE ECBLIST                   58680000
.LIB1L4  ANOP                                                           58740000
*                                                                       58800000
*                                                                       59100000
*        RELEASE WTG TABLE CORE                                         59400000
         SR    R0,R0                    CLEAR R0                        59700000
         IC    R0,WTGLNG-WTG(,RWTG)     GET SIZE OF WTG TABLE           60000000
         SLL   R0,3                     SIZE IN BYTES                   60300000
         LR    R1,RWTG                  LOAD ADDR OF WTG TABLE          60600000
         AIF   ('&LIB' EQ 'LIB2').LIB2L5                                60700000
         FREEMAIN R,LV=(0),A=(1)        FREE WTG TABLE                  60900000
.LIB2L5  ANOP                                                           60950000
         AIF   ('&LIB' EQ 'LIB1').LIB1L6                                61000000
         LR    RF,R0                                                    61050000
         FREEMAIN R,LV=(RF),SP=253,A=(1) FREE WTG TABLE                 61100000
.LIB1L6  ANOP                                                           61150000
*                                                                       61200000
*        TEST FOR EOVC ON                                               61500000
         L     RDCB,PLISTDCB(,RPAR)     ADDR OF FIRST DCB               61800000
         L     RD,CVTPTR                VECTOR TABLE ADDRESS            62100000
         L     RET,CVTTCBP              POINTER TO TCB                  62400000
         L     RET,K4(,RET)             CURRENT TCB ADDRESS             62700000
         TM    TCBFLGS,TCBFA            IS ABEND BIT ON                 63000000
         BO    CFN08000                 BR IF YES --NO CONCATENATION    63300000
         TM    DCBOFLGS,DCBOLOCK+DCBOCON  CHK LOCK AND EOVC SW'S.       63600000
         BNO   CFN08000                 B, IF BOTH NOT ON               63900000
         L     RTIOT,TCBTIO             LOAD TIOT ADDR                  64200000
         AH    RTIOT,DCBTIOT            POINT TO THIS DCB'S ENTRY       64500000
*                                                                       64800000
         L     RUCB,TIOEFSRT-1          SRT-UCB ADDRESS                 65100000
         LA    RUCB,0(RUCB)             CLEAR HI-ORDER BYTE             65400000
         SR    R0,R0                    CLEAR R0                        65700000
         IC    R0,TIOELNGH              LENGTH OF CURRENT ENTRY         66000000
         AH    R0,DCBTIOT               REL ADDR OF NEXT ENTRY          66300000
         STH   R0,DCBTIOT               STORE INTO DCB                  66600000
         L     RD,TCBRBP                ADDR OF SVRB                    66900000
         LA    RD,RBEXSAVE+8-RBSECT(,RD)  ADDR OF XCTL PARAMETER        67200000
         MVC   0(K8,RD),OPENLD          NAME OF IGC00019.               67500000
         LA    RF,K8(,RD)               ADDR OF XCTL PARAM              67800000
         LR    R1,RPAR                  POINT TO PARAM LIST FOR OPEN    68100000
*                                                                       68400000
*        XCTL TO OPEN FOR CONCATENATION OF UNLIKE ATTRIBUTES            68700000
*                                                                       69000000
         XCTL  EPLOC=(RD),SF=(E,(15))   XCTL TO OPEN                    69300000
*                                                                       69600000
*                                                                       69900000
CFN08000 EQU   *                                                        70200000
*                                                                       70500000
*                                                                       70800000
*                        IF OFF, RETURN TO CALLER                       71100000
*                                                                       71400000
*        RETURN TO CALLER                                               71700000
*                                                                       72000000
         SVC   SVCEXIT                  RETURN TO CALLING RETURN        72300000
CFN08100 EQU   *                                                        72600000
         TM    DCBOFLGS,DCBOBUSY        BUSY BIT ON                     72900000
         BO    CFN07500                 BRANCH IF YES TO NORMAL CLEANUP 73200000
         TM    JFCBMASK+K4,X'02'        DELAYED ABEND SPECIFIED         73500000
         BZ    CFN07500                 BRANCH IF NO TO NORMAL CLEAN UP 73800000
         SR    RF,RF                    CLEAR REG                       74100000
         IC    RF,DXRETCOD              LOAD RETURN CODE                74400000
         MVC   DXCCW7(K2),DXABCODE      MOVE ABEND CODE TO FULLWORD     74700000
         LH    R1,DXCCW7                LOAD ABEND CODE IN R1           75000000
         SLL   R1,K8                    PUT ABEND CODE IN PROPER PLACE  75300000
         ABEND (1),DUMP                 ISSUE ABEND                     75600000
         EJECT                                                          75900000
         SPACE 1                                                        76200000
**********************************************************************  76500000
*                                                                    *  76800000
*                    CONSTANTS                                       *  77100000
*                                                                    *  77400000
**********************************************************************  77700000
         SPACE 1                                                        78000000
OPENLD   DC    C'IGC0001I'              NAME OF OPEN LOAD ONE           78300000
         XCTLTABL ID=(EXITMOD,2L,TRACEMOD,9R),SVC=020                   78600000
         IECDSECS CVT,TCB,TIOT,DCB,DEB,UCB,MAIN,WTG,RB,EXPAND=YES       78900000
         IECEQU                                                         79200000
         END                                                            79500000
