         TITLE 'IFG0232D - TCLOSE DIRECT ACCESS PROCESSING'      S21940 00200000
         COPY  LCGASMSW                                                 00250000
*                                                                       00620021
IFG0232D CSECT                                                   S21940 00640021
*                                                                       00660021
*********************************************************************** 00680021
*                                                                     * 00700021
*         VS1 RELEASE 02.6 DELETIONS/CHANGES                          * 00702002
*0000                                                            XM2899 00704002
*                                                                     * 00706002
*         VS1 RELEASE 02 DELETIONS                                    * 00710002
*                                                                     * 00712002
*0000                                                            XM1011 00714002
*                                                                     * 00720021
*         RELEASE 25 DELETIONS/CHANGES                                * 00800021
*         RELEASE 24 DELETIONS/CHANGES                                * 01000021
*         RELEASE 23 DELETIONS/CHANGES                                * 01200021
*         RELEASE 22 DELETIONS/CHANGES                                * 01400021
*         RELEASE 21.8 DELETIONS/CHANGES                              * 01410021
*0000264900                                                      SM0203 01412021
*0000                                                           SA67202 01420021
*0000273310                                                     SA67848 01430021
*         RELEASE 21.7 DELETIONS/CHANGES                              * 01450021
*0000                                                           SA57255 01500021
*0000612000,614000                                              SA57255 01550021
*0000198000,198600-200000,2746000,534600                        SA58019 01551001
*         RELEASE 21 DELETIONS/CHANGES                                * 01600021
*                                                                A35953 01660021
*0000304800,648000                                               S21940 01720021
*D017200,129000-142000,195000,264100-271100,476000              SA48558 01770021
*                                                                     * 01800021
* STATUS CHANGE LEVEL 000                                             * 01900021
*                                                                     * 02000021
* FUNCTION -                                                          * 02100021
*    THIS MODULE CONTAINS THE FOLLOWING FUNCTIONS-                    * 02200021
*    1. TCLOSE DIRECT ACCESS INPUT FUNCTION.                          * 02300021
*    2. TCLOSE DIRECT ACCESS OUTPUT FUNCTION, PART I.                 * 02400021
*                                                                     * 02500021
* ENTRY POINTS -                                                      * 02600021
*         IFG0232D - REFER TO 'INPUT' FOR A LIST OF CALLING MODULES   * 02700021
*                    AND THEIR RESPECTIVE ENTRY CONDITIONS.           * 02800021
*                                                                     * 02900021
* INPUT -                                                             * 03000021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 03100021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 03200021
*    POINT PROCESSING IS TO BEGIN-                                    * 03300021
*       0 - ENTRY FROM IGC0002C TO TCLOSE A DATA SET ON A             * 03400021
*           DIRECT ACCESS DEVICE.                                     * 03500021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR ADDITIONAL INPUT.  * 03600021
*                                                                     * 03700021
* OUTPUT -                                                            * 03800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 03900021
*                                                                     * 04000021
* EXTERNAL REFERENCES -                                               * 04100021
*         IECPCNVT - A CLOSED SUBROUTINE- RESIDENT IN THE NUCLEUS-    * 04200021
*                    WHICH CONVERTS A RELATIVE TRACK ADDRESS AND      * 04300021
*                    CONCATENATION NUMBER, 'TTRN', TO AN ABSOLUTE     * 04400021
*                    TRACK ADDRESS, 'MBBCCHHR', UTILIZING THE         * 04500021
*                    FOLLOWING REGISTER CONVENTIONS-                  * 04600021
*                    REGISTER  CONTENTS AT ENTRY     CONTENTS AT EXIT * 04700021
*                      0       TTRN TO BE CONVERTED  DESTROYED        * 04800021
*                      1       DEB ADDRESS           TRANSPARENT      * 04900021
*                      2       ADDR OF 8-BYTE AREA   TRANSPARENT      * 05000021
*                              FOR MBBCCHHR                           * 05100021
*                      3-8     IGNORED               TRANSPARENT      * 05200021
*                      9-13    IGNORED               DESTROYED        * 05300021
*                      14      RETURN ADDRESS        TRANSPARENT      * 05400021
*                      15      ENTRY POINT ADDRESS   ERROR CODE       * 05500021
*                    THE ERROR CODE WILL BE '0' IF THE CONVERSION IS  * 05600021
*                    SUCCESSFUL AND '1' IF THE 'TT' EXCEEDS THE       * 05700021
*                    NUMBER OF EXTENTS ASSIGNED TO THE DATA SET.      * 05800021
*         IECPRLTV - A CLOSED SUBROUTINE- RESIDENT IN THE NUCLEUS-    * 05900021
*                    WHICH CONVERTS AN ABSOLUTE TRACK ADDRESS,        * 06000021
*                    'MBBCCHHR', TO A RELATIVE TRACK ADDRESS, 'TTR0', * 06100021
*                    UTILIZING THE FOLLOWING REGISTER CONVENTIONS-    * 06200021
*                    REGISTER  CONTENTS AT ENTRY     CONTENTS AT EXIT * 06300021
*                      0       IGNORED               RESULTANT TTR0   * 06400021
*                      1       DEB ADDRESS           TRANSPARENT      * 06500021
*                      2       ADDR OF MBBCCHHR      DESTROYED        * 06600021
*                              TO BE CONVERTED                        * 06700021
*                      3-8     IGNORED               TRANSPARENT      * 06800021
*                      9-13    IGNORED               DESTROYED        * 06900021
*                      14      RETURN ADDRESS        TRANSPARENT      * 07000021
*                      15      ENTRY POINT ADDRESS   '0'              * 07100021
*         IFG023RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 07200021
*                    WAIT.                                            * 07300021
*                                                                     * 07400021
* EXITS, NORMAL -                                                     * 07500021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 07600021
*                                                                     * 07700021
* EXITS, ERROR -                                                      * 07800021
*         IFG0230P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 07900021
*                    REFER TO 'OUTPUT' IN THE FOLLOWING 'FUNCTION     * 08000021
*                    PROLOGS' FOR A LIST OF ERROR CONDITIONS.         * 08100021
*                                                                     * 08200021
* TABLES/WORK AREAS -                                                 * 08300021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 08400021
*                                                                     * 08500021
* ATTRIBUTES -                                                        * 08600021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 08700021
*                                                                     * 08800021
* CHARACTER CODE DEPENDENCY -                                         * 08900021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 09000021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 09100021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 09200021
*                                                                     * 09300021
* NOTES -                                                             * 09400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 09500021
*                                                                     * 09600021
*********************************************************************** 09700021
         EJECT                                                   S21940 09750021
*                                                                S21940 09800021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY S21940 09900021
         USING *,RBASE                                           S21940 10000021
*                                                                S21940 10100021
         USING FORCORE,RCORE                                     S21940 10200021
         USING IHADCB,RDCB                                       S21940 10300021
         USING IHADEB,RDEB                                       S21940 10400021
         USING TIOENTRY,RTIOT                                    S21940 10500021
         USING UNITABLE,R1                                       S21940 10600021
*                                                                       10700021
*****    DETERMINE TYPE OF ENTRY TO MODULE-                             10800021
*****    ALTHOUGH THERE IS ONLY A SINGLE ENTRY POINT TO THIS            10900021
*****    MODULE AT THIS TIME, THE BRANCH TABLE IS UTILIZED TO PERMIT    11000021
*****    ADDITION OF NEW ENTRY POINTS AT A LATER DATE                   11100021
*                                                                       11200021
         B     TCD00050(RET)            DETERMINE TYPE OF ENTRY  S21940 11300021
TCD00050 EQU   *                                                 S21940 11400021
         B     TCD00100                 BR TO PROCESS DA         S21940 11500021
         EJECT                                                          11600021
*********************************************************************** 11700021
*                                                                     * 11800021
*                          FUNCTION PROLOG                            * 11900021
*                                                                     * 12000021
*********************************************************************** 12100021
*                                                                     * 12200021
* FUNCTION NAME - 'TCLOSE DIRECT ACCESS INPUT FUNCTION'               * 12300021
*                                                                     * 12400021
* (STATUS) -                                                          * 12500021
*    NOT APPLICABLE                                                   * 12600021
*                                                                     * 12700021
* FUNCTION -                                                          * 12800021
*    1. TEST THE DCB FOR VALID ATTRIBUTES FOR BOTH INPUT AND OUTPUT   * 12850001
*       DATA SETS- IT MUST BE OPENED FOR PHYSICAL SEQUENTIAL          * 12860001
*       (DSORG=PS) OR PARTITIONED (DSORG=PO) PROCESSING. PROCESSING   * 12870001
*       IS TERMINATED IF EITHER CONDITION IS NOT MET.                 * 12880001
*    2. READ THE FORMAT 1 (F1) DATA SET CONTROL BLOCK (DSCB) FOR      * 12900021
*       BOTH INPUT AND OUTPUT PROCESSING.                             * 13000021
*    3. A DATA SET ON A DIRECT ACCESS DEVICE IS 'REPOSITIONED' BY     * 13300021
*       MODIFYING THE 'DCBFDAD' AND IOB SEEK FIELDS AS INDICATED      * 13400021
*       BELOW FOR THE DATA SET ORGANIZATIONS SHOWN. USE OF TCLOSE     * 13450021
*       FOLLOWING INPUT IS NOT PERMITTED FOR DCBS OPENED TO A         * 13500001
*       MEMBER OF A PARTITIONED DATA SET. IT IS ALSO RESTRICTED TO    * 13510001
*       PHYSICAL SEQUENTIAL DCBS WHICH ARE USED TO PROCESS THE DATA   * 13520001
*       SET ORGANIZATIONS SHOWN BELOW-                                * 13530001
*       'REREAD'-                                                     * 13550021
*          PS, DA, IS, UNDEFINED (I.E., A VTOC), AND PO NOT OPENED TO * 13600021
*             A MEMBER- POINT TO THE BEGINNING OF THE DATA SET USING  * 13650021
*             THE FIRST EXTENT IN THE DEB. NOTE THAT THIS POSITIONS   * 13700021
*             A PO DATA SET TO THE DIRECTORY.                         * 13750021
*       'LEAVE'-                                                      * 13800021
*          PS AND PO NOT OPENED TO A MEMBER- POINT TO THE FILE MARK   * 13850021
*             THAT DENOTES THE END OF THE DATA SET USING 'DSCLSTAR'   * 13900021
*             AND UPDATE 'DCBTRBAL' FROM 'DSCLSTAR' TO REFLECT THE    * 13950021
*             NUMBER OF BYTES REMAINING ON THE TRACK.                 * 14000021
*       PROCESSING IS TERMINATED FOR ALL OTHER CONDITIONS.            * 14050001
*                                                                     * 14300021
* ENTRY POINTS -                                                      * 14400021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 14500021
*                                                                     * 14600021
* INPUT -                                                             * 14700021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 14800021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED.                  * 14900021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB.               * 15000021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE.      * 15100021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE.                    * 15200021
*       'RPARC'- ADDRESS OF THE CURRENT TCLOSE PARAMETER LIST ENTRY.  * 15300021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY.      * 15400021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB.       * 15500021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB.              * 15600021
*       'RDEB' - ADDRESS OF THE DCB'S DEB.                            * 15700021
*                                                                     * 15800021
* OUTPUT -                                                            * 15900021
*    1. AT EXIT TO IFG0232Z-                                          * 16000021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 16100021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '4'.      * 16200021
*    2. AT EXIT TO IFG0230P (PROBLEM DETERMINATION)-                  * 16300021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 16400021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 16500021
*          ERROR CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE  * 16600021
*          INDICATED IN PARENTHESES)-                                 * 16700021
*          132 (317/04)- ERROR READING THE DSCB.                      * 16800021
*          142 (---/00)- MESSAGE ONLY- DCB IS NOT PHYSICAL            * 16850000
*                        SEQUENTIAL OR PARTITIONED.                   * 16850401
*                        PROCESSING COULD NOT BE PERFORMED.           * 16850801
*          143 (---/04)- MESSAGE ONLY- DCB IS OPENED FOR INPUT TO     * 16852001
*                        A MEMBER OF A PARTITIONED DATA SET.          * 16854000
*                        PROCESSING COULD NOT BE PERFORMED.           * 16864001
*          144 (---/08)- MESSAGE ONLY- 'LEAVE' OPTION SPECIFIED FOR   * 16880000
*                        AN INVALID DATA SET ORGANIZATION.            * 16890021
*                        PROCESSING COULD NOT BE PERFORMED.           * 16892001
*          236 (317/08)- INVALID FORMAT 1 DSCB READ                   * 16894002
*       WORK AREA INDICATORS-                                         * 16900021
*          'DXCCW1'   - CONTAINS A X'FF' WHEN PROCESSING HAS BEEN     * 16950021
*                       TERMINATED ON THE CORRESPONDING DCB.          * 16960021
*          'DXCALLID' - CONTAINS THE 2-BYTE ID OF THIS MODULE.        * 17000021
*          'DXRETMOD' - CONTAINS THE 5-BYTE ID AND TTR OF THE FINAL   * 17050021
*                       LOAD OF TCLOSE WHEN PROCESSING HAS BEEN       * 17060021
*                       TERMINATED ON A DCB.                          * 17070021
*                                                                     * 17100021
* EXTERNAL REFERENCES -                                               * 17200021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 17300021
*                                                                     * 17400021
* EXITS, NORMAL -                                                     * 17500021
*         IFG0232Z - TO PERFORM TCLOSE FINAL PROCESSING.              * 17600021
*                                                                     * 17700021
* EXITS, ERROR -                                                      * 17800021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 17900021
*                                                                     * 18000021
* TABLES/WORK AREAS -                                                 * 18100021
*    THE TCLOSE WORK AREA AND THE WHERE-TO-GO (WTG)                   * 18200021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 18300021
*                                                                     * 18400021
* ATTRIBUTES -                                                        * 18500021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 18600021
*                                                                     * 18700021
* CHARACTER CODE DEPENDENCY -                                         * 18800021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 18900021
*                                                                     * 19000021
* NOTES -                                                             * 19100021
*                                                                     * 19200021
*********************************************************************** 19300021
         EJECT                                                   S21940 19350021
*                                                                       19400021
*****    INSURE THAT THE DCB HAS PROPER ATTRIBUTES FOR TCLOSE   SA48558 19500021
*                                                                       19600021
TCD00100 EQU   *                                                 S21940 19700021
         LA    R1,TABD142               CODE FOR INVALID DCB    SA48558 19750021
         TM    DCBDSORG,DCBORGPS+DCBORGPO IS DCB 'PS' OR 'PO'-  SA58019 19800001
         BZ    TCD01560                 ..BR IF NOT- ERROR      SA48558 19850021
*                                                               SA48558 20050021
*****    PREPARE TO READ THE FORMAT 1 (F1) DSCB                 SA48558 20100021
*                                                               SA48558 20150021
         LA    RC,K16                   SUBTRACT 16 FROM BASE OF DEB    24800021
         SR    RDEB,RC                  TO ESTABLISH BASE OF VTOC TRK   25000021
         MVC   DXDEBBIN(K2),K1(RDEB)    MOVE BIN NR IN WK DEB           25200021
         XC    DXDEBSCC(K4),DXDEBSCC    SET BEGINNING CCHH TO ZERO      25400021
         MVC   DXDEBECC(K6),MAXEXTNT    SET ENDING CCHH AND NO.  S21940 25500021
*                                       ..OF TRACKS TO MAXIMUM   S21940 25600021
*                                       ..POSSIBLE               S21940 25700021
         MVC   DXDAADDR+K1(K7),K1(RDEB)  PLACE SEARCH ADDRESS IN SEEK   25800021
         AR    RDEB,RC                  POINT BACK TO BASIC DEB  S21940 25820021
         LA    RD,DXDAADDR+K3           PLACE ADDRESS OF CCHHR   S21940 25840021
         ST    RD,DXCCW1                ..INTO FIRST CCW         S21940 25860021
         MVI   DXCCW1,CCWSCHID          SET CCW1 TO 'SEARCH      S21940 25880021
*                                       ..ID EQUAL'              S21940 25900021
         LA    RD,DXCCW1                PLACE ADDRESS OF SEARCH  S21940 25920021
         ST    RD,DXCCW2                ..CCW INTO TIC CCW       S21940 25940021
         MVC   DXCCW1+K4(K5),ACCW1CD    SET CMD CHAIN, SILI IND, S21940 25960021
*                                       ..AND LENGTH EQUAL 5 IN  S21940 25980021
*                                       ..CCW1, MAKE CCW2 A TIC  S21940 26000021
         LA    RD,DXDSCB                PLACE ADDR FOR DSCB      S21940 26020021
         ST    RD,DXCCW3                ..INTO THE READ DATA CCW S21940 26040021
         MVC   DXCCW2+K4(K5),ACCW2C     SET CMD CHAIN IN CCW2,   S21940 26060021
*                                       ..MAKE CCW3 'READ DATA'  S21940 26080021
         MVC   DXCCW3+K4(K4),ACCW3C     SET LNG EQ 96 IN CCW3    S21940 26100021
         BAL   RC,TCD01500              GO TO PERFORM READ OF DSCB      26200021
         LA    R1,TABD132               INTERNAL ERROR CODE      S21940 26270021
         BNO   TCD01600                 BR IF I/O ERROR          S21940 26340021
         LA    R1,TABD236               CODE FOR NO F1           XM2899 26390002
         CLI   DXDSCB,X'F1'             WAS F1 READ              XM2899 26440002
         BE    TCD00150                 YES,BR TO CONTINUE       SM0203 26490021
         CLI   DXDSCB,X'F4'             WAS F4 READ             SA67202 26540021
         BNE   TCD01600                 NO, BR TO ABEND         SA67202 26590021
*                                                               SA48558 26730021
*****    DETERMINE THE NEXT REQUIRED PROCESSING                 SA48558 26780021
*                                                               SA48558 26830021
TCD00150 EQU   *                                                        27180021
         TM    DCBOFLGS,DCBOWRIT        WAS OUTPUT PERFORMED-    S21940 27250021
         BO    TCD00800                 ..BR IF YES              S21940 27320021
*                                                               SA58019 27321001
*****    TEST FOR VALID OPTIONS FOLLOWING INPUT                 SA58019 27322001
*                                                               SA58019 27323001
         LA    R1,TABD142               LOAD INVALID DCB CODE   SA58019 27324001
         TM    DCBDSORG,DCBORGPS        IS DCB DSORG 'PS'-      SA58019 27325001
         BZ    TCD01560                 ..BR IF NOT- ERROR      SA58019 27326001
         LA    R1,TABD143               LOAD INVALID POSITION-  SA58019 27327001
*                                       ..ING OPTION CODE       SA58019 27328001
         TM    JFCBIND1,JFCPDS          IS DCB OPEN TO A MEMBER SA58019 27329001
*                                       ..OF A PO DATA SET-     SA58019 27330001
         BO    TCD00175                 ..YES, BR TO CHK EOF    SA67848 27331021
*                                                               SA58019 27332001
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-  S21940 27390021
         BM    TCD00200                 ..BR IF NOT             SA58019 27460001
*                                                                       27530021
*****    PROCESS DATA SETS WITH DISPOSITION OF 'LEAVE'-                 27600021
*****    UPDATE THE DCB FULL DIRECT ADDRESS ('DCBFDAD') TO POINT        27670021
*****    TO THE 'FILE MARK' AND UPDATE THE DCB TRACK BALANCE            27740021
*****    ('DCBTRBAL') TO REFLECT THE NUMBER OF BYTES                    27810021
*****    REMAINING ON THE TRACK                                         27880021
*                                                                       27950021
         LA    R1,TABD144               CODE FOR 'LEAVE' OPTION SA48558 28000021
*                                       ..WITH INVALID DSORG    SA48558 28050021
         TM    DSCFILTY,DS1ORGPS+DS1ORGPO IS DSORG VALID-       SA48558 28100021
         BZ    TCD01560                 ..BR IF NOT- ERROR      SA48558 28150021
*                                                               SA48558 28160021
         MVC   DCBTRBAL,DSCLSTAR+K3     NUMBER OF BYTES                 28200021
*                                       REMAINING ON TRACK              28400021
         MVI   DSCLSTAR+K3,K0           RESET N OF TTRN                 28600021
         MVC   DXCCW5(K4),DSCLSTAR      PLACE THE TTR0 OF LAST TRACK OF 28800021
         L     R0,DXCCW5                DATA SET USED IN PARAMETER REG  29000021
         LR    R1,RDEB                  DEB ADDR INTO PARM REG          29300021
         LA    RDCB,DCBFDAD             ADDRESS FOR MBBCCHHR TO PARAM   29600021
*                                       REGISTER                        29800021
         STM   RTIOT,RDEB,DXCCW5        SAVE REGISTERS           S21940 29850021
         USING CVT,RF                   ESTABLISH CVT BASE       S21940 29900021
         L     RF,CVTPTR                LOAD CVT ADDRESS         S21940 29950021
         L     RF,CVTPCNVT              LOAD CONVERT RTN ADDR    S21940 30000021
         BALR  RET,RF                   CONVERT TTR TO MBBCCHHR  S21940 30050021
         LM    RTIOT,RDEB,DXCCW5        RESTORE REGISTERS        S21940 30100021
         L     RDCB,0(RPARC)            RESTORE ADDRESS OF CURRENT DCB  30200021
         B     TCD00300                 GO SET CURRENT POSITION IN BSAM 30400021
TCD00175 EQU   *                                                SA67848 30450021
         TM    DCBOFLGS,DCBOEOF         HAS EOF BEEN REACHED    SA67848 30460021
         BO    TCD00600                 YES, EXIT TO FINAL LOAD SA67848 30470021
         B     TCD01560                 NO, ISSUE ERROR MSG     SA67848 30472021
         EJECT                                                   S21940 30480021
*                                                                       30560021
*****    PROCESS DATA SETS WITH DISPOSITION OF 'REREAD'-                30640021
*****    INITIALIZE THE DCB FULL DIRECT ADDRESS ('DCBFDAD') TO          30720021
*****    POINT TO THE BEGINNING OF THE FIRST EXTENT OF THE              30800021
*****    DATA SET AND THE DCB TRACK BALANCE ('DCBTRBAL')                30880021
*****    TO REFLECT A FULL TRACK                                        30960021
*                                                                       31040021
TCD00200 EQU   *                                                        31200021
         XC    DCBFDAD(K8),DCBFDAD      ZERO DISK ADDRESS               31400021
         MVC   DCBFDAD+K1(K6),DEBBINUM  SET BBCCHH TO START OF EXTENT   31600021
*                                       M,R = 0                         31800021
         L     RC,DCBDVTBL              PICK UP BASE OF DEVICE TABLE    32000021
         MVC   DCBTRBAL,UNITTRLN-UNITABLE(RC)  SET REMAINING BYTES=MAX  32200021
*                                                                       32400021
*****    UPDATE THE IOB SEEK ADDRESS TO CORRESPOND TO 'DCBFDAD'         32600021
*                                                                       32800021
TCD00300 EQU   *                                                        33000021
         L     RD,DCBIOBA               ADDR OF PREVIOUS IOB            33200021
         LA    RD,0(,RD)                CLEAR HI ORDER BYTE             33400021
         LR    R0,RD                    SAVE ADDR OF 1ST FOR COMPARE    33600021
         SR    RC,RC                    CLEAR REGISTER                  33800021
         LR    R1,RD                    COPY IOB/ICB ADDR               34000021
         TM    DCBCIND2,DCBOEOF         IS PCI USED                     34200021
         BO    TCD00400                 YES, BRANCH                     34400021
         LA    R1,K8(RD)                ADJUST IOB FOR NORMAL SCHED     34600021
         LA    RC,K8                    OFFSET IN IOB FOR NORMAL SCHED  34800021
TCD00400 MVC   K32(K8,R1),DCBFDAD       UPDATE 1ST ICB/IOB              35000021
*                                                                       35200021
TCD00500 EQU   *                                                        35400021
         L     RD,0(,RD)                ADDR OF NEXT ICB/IOB IN CHAIN   35600021
         LA    RD,0(,RD)                CLEAR HIGH ORDER BYTE           35800021
         LA    R1,0(RC,RD)              FORM IOB OR ICB ADDR            36000021
         MVC   K32(K8,R1),DCBFDAD       UPDATE ICB/IOB FDAD             36200021
*                                                                       36400021
         CR    RD,R0                    IS THIS LAST IN CHAIN           36600021
         BNE   TCD00500                 ..BR IF NOT- UPDATE      S21940 36800021
*                                       ..NEXT IOB IN CHAIN      S21940 37000021
TCD00600 EQU   *                                                 S21940 37200021
         LA    RF,MOD2D2Z               PT TO ID/TTR OF TCLOSE   S21940 37400021
*                                       ..FINAL FUNCTION         S21940 37600021
         LA    RET,K4                   LOAD BR TABLE OFFSET FOR S21940 37800021
*                                       ..TCLOSE FINAL FUNCTION  S21940 38000021
         B     TCD01400                 ..AND BRANCH TO EXIT     S21940 38200021
         EJECT                                                          38400021
*********************************************************************** 38600021
*                                                                     * 38800021
*                          FUNCTION PROLOG                            * 39000021
*                                                                     * 39200021
*********************************************************************** 39400021
*                                                                     * 39600021
* FUNCTION NAME - 'TCLOSE DIRECT ACCESS OUTPUT FUNCTION', PART I      * 39800021
*                                                                     * 40000021
* (STATUS) -                                                          * 40200021
*    NOT APPLICABLE                                                   * 40400021
*                                                                     * 40600021
* FUNCTION -                                                          * 40800021
*    1. THE DSCB IS UPDATED TO REFLECT THE ADDRESS OF THE LAST        * 41000021
*       RECORD WRITTEN AND THE NUMBER OF BYTES REMAINING ON THE       * 41200021
*       TRACK ('DSCLSTAR'), AND IS THEN RE-WRITTEN TO THE VTOC.       * 41400001
*       TCLOSE FOLLOWING OUTPUT IS RESTRICTED TO THE FOLLOWING        * 41450001
*       CONDITIONS-                                                   * 41451001
*       - PHYSICAL SEQUENTIAL DCBS PROCESSING PHYSICAL SEQUENTIAL     * 41452001
*         DATA SETS.                                                  * 41453001
*       - PHYSICAL SEQUENTIAL DCBS OPENED TO AN ENTIRE PARTITIONED    * 41453201
*         DATA SET, IN WHICH CASE THE 'REREAD' OPTION REPOSITIONS THE * 41453401
*         USER TO THE DIRECTORY.                                      * 41453601
*       - PHYSICAL SEQUENTIAL DCBS OPENED TO A MEMBER OF A            * 41454001
*         PARTITIONED DATA SET, FOR WHICH 'LEAVE' IS THE ONLY VALID   * 41455001
*         POSITIONING OPTION.                                         * 41456001
*       - PARTITIONED DCBS PROCESSING PARTITIONED DATA SETS, FOR      * 41457001
*         WHICH 'LEAVE' IS THE ONLY VALID POSITIONING OPTION.         * 41458001
*       PROCESSING IS TERMINATED FOR ALL OTHER CONDITIONS.            * 41459001
*                                                                     * 41600021
* ENTRY POINTS -                                                      * 41800021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 42000021
*                                                                     * 42200021
* INPUT -                                                             * 42400021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 42600021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED.                  * 42800021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB.               * 43000021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE.      * 43200021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE.                    * 43400021
*       'RPARC'- ADDRESS OF THE CURRENT TCLOSE PARAMETER LIST ENTRY.  * 43600021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY.      * 43800021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB.       * 44000021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB.              * 44200021
*       'RDEB' - ADDRESS OF THE DCB'S DEB.                            * 44400021
*                                                                     * 44600021
* OUTPUT -                                                            * 44800021
*    1. AT EXIT TO IFG0232J-                                          * 45000021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 45200021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0'.      * 45400021
*    1. AT EXIT TO IFG0232Z-                                          * 45600021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 45800021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0'.      * 46000021
*    2. AT EXIT TO IFG0230P (PROBLEM DETERMINATION)-                  * 46200021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 46400021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 46600021
*          ERRORS CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE * 46800021
*          INDICATED IN PARENTHESES)-                                 * 47000021
*          133 (417/04)- ERROR WRITING THE DSCB.                      * 47200021
*          145 (---/0C)- MESSAGE ONLY- OUTPUT PROCESSING REQUESTED    * 47250000
*                        FOR AN INVALID DATA SET ORGANIZATION.        * 47300021
*                        PROCESSING COULD NOT BE PERFORMED.           * 47300201
*          151 (---/10)- MESSAGE ONLY- 'REREAD' OPTION SPECIFIED FOR  * 47301001
*                        AN INVALID DATA SET ORGANIZATION. PROCESSING * 47302001
*                        COULD NOT BE PERFORMED.                      * 47303001
*       WORK AREA INDICATORS-                                         * 47400021
*          'DXCCW1'   - CONTAINS A X'FF' WHEN PROCESSING HAS BEEN     * 47450021
*                       TERMINATED ON THE CORRESPONDING DCB.          * 47500021
*          'DXCALLID' - CONTAINS THE 2-BYTE ID OF THIS MODULE.        * 47600021
*          'DXRETMOD' - CONTAINS THE 5-BYTE ID AND TTR OF THE FINAL   * 47650021
*                       LOAD OF TCLOSE WHEN PROCESSING HAS BEEN       * 47700021
*                       TERMINATED ON A DCB.                          * 47750021
*                                                                     * 47800021
* EXTERNAL REFERENCES -                                               * 48000021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 48200021
*                                                                     * 48400021
* EXITS, NORMAL -                                                     * 48600021
*         IFG0232J - TO CREATE OUTPUT USER TRAILER LABELS.            * 48800021
*         IFG0232Z - TO WRITE A FILE MARK AND THEN PERFORM TCLOSE     * 49000021
*                    FINAL PROCESSING.                                * 49200021
*                                                                     * 49400021
* EXITS, ERROR -                                                      * 49600021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 49800021
*                                                                     * 50000021
* TABLES/WORK AREAS -                                                 * 50200021
*    THE TCLOSE WORK AREA AND THE WHERE-TO-GO (WTG)                   * 50400021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 50600021
*                                                                     * 50800021
* ATTRIBUTES -                                                        * 51000021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 51200021
*                                                                     * 51400021
* CHARACTER CODE DEPENDENCY -                                         * 51600021
*    REFER TO THE PRECEDING MODULE PROLOG.                            * 51800021
*                                                                     * 52000021
* NOTES -                                                             * 52200021
*                                                                     * 52400021
*********************************************************************** 52600021
         EJECT                                                   S21940 52650021
*                                                                       52800021
*****    TEST FOR VALID POSITIONING OPTIONS FOLLOWING OUTPUT    SA58019 53001001
*                                                                       53200021
TCD00800 EQU   *                                                        53400021
         LA    R1,TABD145               CODE FOR INVALID DSORG  SA48558 53410021
         TM    DSCFILTY,DS1ORGPS        IS DSORG EQ 'PS'-       SA48558 53450021
         BO    TCD00840                 ..BR IF YES- PROCESS    SA58019 53460001
         TM    DSCFILTY,DS1ORGPO        IS DATA SET ORG 'PO'-   SA58019 53461001
         BZ    TCD01560                 ..BR IF NOT- ERROR      SA58019 53462001
         TM    DCBDSORG,DCBORGPO        IS DCB DSORG 'PO'-      SA58019 53463001
         BO    TCD00820                 ..BR IF YES- TEST       SA58019 53464001
*                                       ..FOR 'LEAVE' OPTION    SA58019 53465001
         TM    JFCBIND1,JFCPDS          IS DCB OPEN TO A MEMBER SA58019 53466001
*                                       ..OF A PO DATA SET-     SA58019 53467001
         BZ    TCD00840                 ..BR IF NOT- ALL        SA58019 53468001
*                                       ..OPTIONS ALLOWED       SA58019 53469001
TCD00820 EQU   *                                                SA58019 53469201
         LA    R1,TABD151               CODE FOR 'REREAD'       SA58019 53470001
*                                       ..OPTION WITH INVALID   SA58019 53471001
*                                       ..DSORG                 SA58019 53472001
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'- SA58019 53473001
         BM    TCD01560                 ..BR IF NOT- ERROR      SA58019 53474001
*                                                               SA48558 53500021
*****    CALCULATE THE 'TTR0' OF THE LAST BLOCK WRITTEN         SA58019 53501001
*                                                               SA58019 53502001
TCD00840 EQU   *                                                SA58019 53503001
         L     RUCB,TIOESTTB            LOAD UCB ADDR FROM TIOT  S21940 53600021
*                                       ..(SUB-UCB IF 2321 DEV)  S21940 53800021
         STM   RTIOT,RC,DXCCW5          SAVE REGISTERS                  58000021
         LR    R1,RDEB                  ADDRESS OF USER'S DEB TO PARAM  58200021
         LA    RDCB,DCBFDAD             ADDRESS OF MBBCCHHR TO PARAM    58400021
         L     RC,CVTPTR                PICK UP ADDRESS OF CONVERT      58600021
*                                       ROUTINE                         58800021
         L     RF,CVTPRLTV-CVT(0,RC)    FROM COMMUNICATION VECTOR TABLE 59000021
         BALR  RET,RF                   CONVERT MBBCCHHR TO TTR0        59200021
         LM    RTIOT,RC,DXCCW5          RESTORE REGISTERS               59400021
         L     RDCB,0(RPARC)            RESTORE ADDRESS OF              59600021
*                                       THE USER'S DCB                  59800021
         ST    R0,DXCCW5                THE TTR OF LAST TRACK USED      60000021
         NI    TIOERLOC+K1,CHARFF-LASTNTRY  ZERO HI ORDER BIT           60200021
         LTR   R0,R0                    NO DATA IF ZERO                 60400021
         BZ    TCD00900                 BR-NO DATA EXISTS               60600021
         OI    TIOERLOC+K1,LASTNTRY     INDICATE DATA EXISTS            60800021
TCD00900 EQU   *                                                        61000021
         OI    DSCDSIND,LASTNTRY        SET LAST VOL INDICATOR  SA57255 61050021
         MVC   DSCLSTAR(K3),DXCCW5      SET LAST BLOCK PTR IN   SA57255 61200021
*                                       F1 DSCB                 SA57255 61250021
         MVC   DSCLSTAR+K3(K2),DCBTRBAL SET TRACK BALANCE       SA57255 61400021
*                                       IN F1 DSCB              SA57255 61450021
*                                                                       61600021
*****    WRITE THE UPDATED DSCB TO THE VTOC                             61800021
*                                                                       62000021
         MVC   DXCCW4(K24),DXCCW1       APPEND WRITE CK CCW'S TO CP     62200021
         LA    RF,DXCCW4                                                62400021
         ST    RF,DXCCW5                TIC BACK TO CCW4                62600021
         MVI   DXCCW5,CCWTIC            RESTORE TIC OP                  62800021
         OI    DXCCW3+K4,HEX40          CC FLAG ON IN WRITE CCW         63000021
         OI    DXCCW6+K4,DCBMRKEY       SKIP FLAG ON IN READ CCW        63200021
         MVI   DXCCW3,CCWWRTDA          WRITE DISK OPERATION CODE       63400021
         BAL   RC,TCD01500              GO TO WRITE THE DSCB            63600021
         LA    R1,TABD133               INTERNAL ERROR CODE      S21940 63680021
         BNO   TCD01600                 BR IF I/O ERROR          S21940 63760021
*                                                                       63840021
*****    RESTORE USER'S DEB INFORMATION TO WORK DEB                     63920021
*                                                                       64000021
         MVC   DXDEBUCB(K6),DEBUCBAD    MOVE USER'S UCB ADDR AND S21940 64080021
*                                       ..BIN NO. TO WORK DEB    S21940 64160021
*                                                                       64240021
*****    DETERMINE WHETHER OR NOT USER LABELS ARE TO BE PROCESSED       64320021
*                                                                       64400021
         LA    RF,MOD2D2Z               PT TO ID/TTR OF FILE     S21940 64480021
*                                       ..MARK MODULE            S21940 64560021
         TM    JFCBLTYP,JFCSUL          WAS 'SUL' SPECIFIED-     S21940 64640021
         BNO   TCD01200                 ..BR IF NOT- BYPASS LBLS S21940 64720021
         TM    JFCBTSDM,JFCSDS          IS DATA SET SYSOUT       S21940 64800021
         BO    TCD01200                 ..BY IF YES- BYPASS LBLS S21940 65000021
         L     RC,DCBEXLST              YES,PICK UP EXIT LIST FROM THE  65200021
         LA    RC,0(RC)                 ZERO OUT HI ORDER BYTE OF EXIT  65400021
         LTR   RC,RC                    IS THE EXIT LIST ZERO           65600021
         BZ    TCD01200                 ..BR IF YES- BYPASS LBLS S21940 65700021
TCD01000 EQU   *                                                 S21940 65800021
         CLI   0(RC),XLOUTL             IS THIS THE CORRECT EXIT S21940 65900021
         BE    TCD01100                 ..BR IF YES- CONTINUE    S21940 66000021
         CLI   0(RC),XLOUTL+LASTNTRY    SEE IF LAST INDICATOR ALSO ON   66400021
         BE    TCD01100                 ..BR IF YES- CONTINUE    S21940 66600021
         TM    0(RC),LASTNTRY           NO,IS THIS THE LAST ENTRY IN EX 66800021
         LA    RC,K4(RC)                INCRE BASE REG TO POINT TO NEXT 67000021
         BNO   TCD01000                 ..BR IF NOT- TEST AGAIN  S21940 67300021
         B     TCD01200                 IGNORE USER LABEL EXIT   XM1011 67350002
TCD01100 EQU   *                                                 S21940 67600021
         L     RC,K0(,RC)               LOAD ENTRY ADDRESS AND   S21940 67900021
         LA    RD,K0(,RC)               ..CLEAR HIGH-ORDER BYTE  S21940 68200021
         LTR   RD,RD                    IS THE ENTRY ADDR ZERO-  S21940 68500021
         BZ    TCD01200                 ..BR IF YES- BYPASS LBLS S21940 68800021
         LA    RF,MOD2D2J               PT TO ID/TTR OF USER     S21940 69100021
*                                       ..LABEL MODULE           S21940 69400021
TCD01200 EQU   *                                                 S21940 69700021
         SR    RET,RET                  ZERO BR TABLE OFFSET     S21940 70000021
         EJECT                                                          70300021
*********************************************************************** 70600021
*              EXIT                                                   * 70900021
*********************************************************************** 71200021
*                                                                       71500021
TCD01400 EQU   *                                                        72400021
         IECRES XCTL,(RF),(RET)                                         72600021
         SPACE 2                                                        72610021
*********************************************************************** 72620021
*              SUBROUTINES                                            * 72630021
*********************************************************************** 72640021
*                                                                       72650021
*****    CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS                    72660021
*****       ENTRY IS AS FOLLOWS-                                        72670021
*****          BAL   RC,TCD01500                                        72680021
*****       UPON RETURN TO THE CALLER, THE CONDITION CODE IS SET AS     72690021
*****       FOLLOWS-                                                    72700021
*****          '0'- AN I/O ERROR OCCURRED                               72710021
*****          '1'- THE I/O OPERATION COMPLETED WITHOUT ERROR           72720021
*                                                                       72730021
TCD01500 EQU   *                                                        72800021
         EXCP  DXIOB                                                    73000021
         IECRES WAIT                                                    73200021
         TM    DXECB,ECBNOERR           IS THERE AN UNUSUAL I/O COND    73400021
         BCR   15,RC                    RETURN TO CALLER                73600021
         SPACE 2                                                        73660021
*********************************************************************** 73720021
*              ERROR PROCESSING                                       * 73780021
*********************************************************************** 73840021
*                                                                       73900021
TCD01560 EQU   *                                                SA48558 73950021
         MVI   DXCCW1,ALLBITS           IND THAT PROCESSING     SA48558 73960021
*                                       ..HAS BEEN TERMINATED   SA48558 73970021
         MVC   DXRETMOD,MOD2D2Z         PLACE RETURN ID/TTR     SA48558 73980021
*                                       ..INTO SAVE AREA        SA48558 73990021
         LA    RET,K4                   LD BR TABLE OFFSET FOR  SA48558 73992021
*                                       ..TCLOSE FINAL FUNCTION SA48558 73994021
TCD01600 EQU   *                                                        74000021
         DMABCOND (R1),ABEND2D          PROCESS THE ERROR        S21940 74200021
         EJECT                                                          74260021
*********************************************************************** 74320021
*              CONSTANTS                                              * 74380021
*********************************************************************** 74440021
*                                                                       74500021
ACCW1CD  DC    X'6000000508'            COMM CHAIN,SILI,5 CHAR,TIC OPCD 74600021
ACCW2C   DC    X'4000000086'            COMMAND CHAIN,READ DATA OPCD    74800021
ACCW3C   DC    X'00000060'              96 CHARACTERS                   75000021
MAXEXTNT DC    X'FFFFFFFF7FFF'          HIGHEST POSSIBLE CCHH    S21940 75070021
*                                       ..AND NO. OF TRKS ON A   S21940 75140021
*                                       ..DEVICE                        75210021
         SPACE 2                                                        75280021
*********************************************************************** 75350021
*              XCTL TABLE                                             * 75420021
*********************************************************************** 75490021
*                                                                       75560021
XCTLTB2D XCTLTABL ID=(ABEND2D,0P,MOD2D2J,2J,MOD2D2Z,2Z),SVC=023         75630021
         SPACE 2                                                        75700021
         IECDSECS CVT,TCB,TIOT,DCB,DEB,MAIN,ICB,UNITTAB,EXPAND=YES      75800021
         IECEQU                                                         76000021
         END                                                            76200021
