         TITLE 'IFG0232G - TCLOSE TAPE STANDARD TRAILER LABEL FUNCTION' 00200021
         COPY  LCGASMSW                                                 00250000
IFG0232G CSECT                                                          00800021
*                                                                       01000021
*********************************************************************** 01200021
*                                                                     * 01400021
*          VS1 RELEASE 03.1 DELETIONS/CHANGES                         * 01410021
*SEE SA69185                                                    XA04640 01420021
*           VS1 RELEASE 02 DELETIONS                                  * 01450002
*0000                                                            XM1201 01500002
*                                                                     * 01600021
*          RELEASE 25 DELETIONS/CHANGES                               * 01800021
*          RELEASE 24 DELETIONS/CHANGES                               * 02000021
*          RELEASE 23 DELETIONS/CHANGES                               * 02200021
*          RELEASE 22 DELETIONS/CHANGES                               * 02400021
*          RELEASE 2.8 DELETIONS/CHANGES                             *  02450021
*0000027300-027701,146000,478000-492000,950000                  SA69185 02460021
*          RELEASE 21.7 DELETIONS/CHANGES                             * 02500021
*0000338000,876000,878000                                       SA53865 02510021
*0000348000                                                     SA57250 02520021
*          RELEASE 21 DELETIONS/CHANGES                               * 02600021
*                                                                M0150  02660021
*                                                                A41662 02720021
*                                                                     * 02800021
* STATUS CHANGE LEVEL 000                                             * 03000021
*                                                                     * 03200021
* FUNCTION -                                                          * 03400021
*    THIS MODULE CONTAINS PART I OF THE 'TCLOSE TAPE STANDARD TRAILER * 03600021
*    LABEL FUNCTION'. REFER TO THE FOLLOWING 'FUNCTION PROLOG'        * 03800021
*    FOR DETAILS.                                                     * 04000021
*                                                                     * 04200021
* ENTRY POINTS -                                                      * 04400021
*         IFG0232G - REFER TO 'INPUT' FOR A LIST OF CALLING MODULES   * 04500021
*                    AND THEIR RESPECTIVE ENTRY CONDITIONS.           * 04600021
*                                                                     * 04800021
* INPUT -                                                             * 05000021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 05200021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 05400021
*    POINT PROCESSING IS TO BEGIN-                                    * 05600021
*       0 - ENTRY FROM IGC0002C TO PROCESS OUTPUT TRAILER LABELS.     * 05800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG' FOR ADDITIONAL INPUT.   * 06000021
*                                                                     * 06200021
* OUTPUT -                                                            * 06400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 06600021
*                                                                     * 06800021
* EXTERNAL REFERENCES -                                               * 07000021
*         IFG023RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 07200021
*                    WAIT.                                            * 07400021
*                                                                     * 07600021
* EXITS, NORMAL -                                                     * 07800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 08000021
*                                                                     * 08200021
* EXITS, ERROR -                                                      * 08400021
*         IFG0230P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 08600021
*                    REFER TO 'OUTPUT' IN THE FOLLOWING 'FUNCTION     * 08700021
*                    PROLOG' FOR A LIST OF ERROR CONDITIONS.          * 08800021
*                                                                     * 09000021
* TABLES/WORK AREAS -                                                 * 09200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 09400021
*                                                                     * 09600021
* ATTRIBUTES -                                                        * 09800021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 10000021
*                                                                     * 10200021
* CHARACTER CODE DEPENDENCY -                                         * 10400021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10600021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 10800021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 11000021
*                                                                     * 11200021
* NOTES -                                                             * 11400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 11600021
*                                                                     * 11800021
*********************************************************************** 12000021
         EJECT                                                          12100021
*                                                                       12200021
*****    TCLOSE INTERNAL ERROR CODES                                    12400021
*                                                                       12600021
TABD141  EQU   141                      CODE FOR POSITIONING ERROR      12800021
*                                       ..FOLLOWING USER LABEL PROC     13000021
*                                                                       13200021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        13400021
         USING *,RBASE                                                  13600021
         USING FORCORE,RCORE                                            13800021
         USING IHADCB,RDCB                                              14000021
         USING UCB,RUCB                                                 14200021
         USING IHADEB,RDEB                                              14400021
*        USING WTG,RWTG                 DEFINE BASE TO WTG TABLE BASE   14600021
*                                                                       14800021
         B     TCT00200(RET)            DETERMINE TYPE OF ENTRY TO MOD  15000021
TCT00200 EQU   *                                                        15200021
         B     TCT00400                 BR IF SL OUTPUT PROCESSING      15400021
         EJECT                                                          15600021
*********************************************************************** 15800021
*                                                                     * 16000021
*                          FUNCTION PROLOG                            * 16200021
*                                                                     * 16400021
*********************************************************************** 16600021
*                                                                     * 16800021
* FUNCTION NAME - 'TCLOSE TAPE STANDARD TRAILER LABEL FUNCTION'       * 17000021
*                                                                     * 17200021
* (STATUS) -                                                          * 17400021
*    NOT APPLICABLE                                                   * 17600021
*                                                                     * 17800021
* FUNCTION -                                                          * 18000021
*    1. WRITE A TAPE MARK TO DELIMIT THE DATA. IF A 'TAPE INDICATE'   * 18200021
*       (I.E., END-OF-TAPE) CONDITION IS DETECTED AND THE POSITIONING * 18400021
*       OPTION IS 'LEAVE', THE TAPE IS BACKSPACED PAST THE TAPE MARK  * 18600021
*       AND THE FORCE END-OF-VOLUME (FEOV) MACRO IS ISSUED TO         * 18800021
*       CONTINUE THE DATA SET ON ANOTHER VOLUME. UPON RETURN FROM     * 19000021
*       FEOV PROCESSING, THE TAPE MARK IS RE-WRITTEN (ON THE NEW      * 19200021
*       VOLUME) AND PROCESSING CONTINUES;                             * 19400021
*    2. FORMAT AND WRITE END-OF-FILE LABEL 1;                         * 19600021
*    3. BEGIN FORMATTING END-OF-FILE LABEL 2;                         * 19800021
*                                                                     * 20000021
* ENTRY POINTS -                                                      * 20200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 20400021
*                                                                     * 20600021
* INPUT -                                                             * 20800021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 21000021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 21200021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 21400021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 21600021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 21800021
*       'RPARC'- ADDRESS OF THE CURRENT TCLOSE PARAMETER LIST ENTRY;  * 22000021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 22200021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 22400021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 22600021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 22800021
*                                                                     * 23000021
* OUTPUT -                                                            * 23200021
*    1. AT EXIT TO IFG0232M-                                          * 23400021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 23600021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0';      * 23800021
*       WORK AREA FIELDS- TRAILER LABEL EOF2 IS PARTIALLY FORMATTED;  * 24000021
*       TAPE POSITION- AT THE INTERBLOCK GAP FOLLOWING TRAILER LABEL  * 24200021
*                      EOF1.                                          * 24400021
*    2. AT EXIT TO IFG0230P (PROBLEM DETERMINATION)-                  * 24600021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 24800021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 25000021
*          ERROR CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE  * 25100021
*          INDICATED IN PARENTHESES)-                                 * 25200021
*          122 (717/04)- ERROR WRITING TAPE MARK FOLLOWING DATA.      * 25300021
*          123 (717/08)- ERROR WRITING END-OF-FILE LABEL 1.           * 25400021
*          140 (117/2C)- ERROR BACKSPACING PAST TAPE MARK FOLLOWING   * 25500021
*                        DATA WHEN FEOV IS TO BE ISSUED.              * 25600021
*       WORK AREA INDICATORS-                                         * 26200021
*          'DXCALLID' - CONTAINS THE ID OF THIS MODULE.               * 26400021
*    3. AT EXIT TO THE FEOV FUNCTION-                                 * 26600021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 26800021
*          REGISTER 'R1' CONTAINS THE ADDRESS OF THE DCB AT EOV.      * 27000021
*                                                                     * 27200021
* EXTERNAL REFERENCES -                                               * 27400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 27600021
*                                                                     * 27800021
* EXITS, NORMAL -                                                     * 28000021
*         IFG0232M - TO FINISH FORMATTING AND WRITE END-OF-FILE LABEL * 28200021
*                    1 AND TO PROCESS OUTPUT USER TRAILER LABELS      * 28400021
*                                                                     * 28600021
* EXITS, ERROR -                                                      * 28800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 29000021
*                                                                     * 29200021
* TABLES/WORK AREAS -                                                 * 29400021
*    THE TCLOSE WORK AREA AND THE WHERE-TO-GO (WTG)                   * 29600021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 29800021
*                                                                     * 30000021
* ATTRIBUTES -                                                        * 30200021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 30400021
*                                                                     * 30600021
* CHARACTER CODE DEPENDENCY -                                         * 30800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 31000021
*                                                                     * 31200021
* NOTES -                                                             * 31400021
*                                                                     * 31600021
*********************************************************************** 31800021
         EJECT                                                          31900021
*                                                                       32000021
*****          WRITE TAPE MARK FOLLOWING USER'S DATA                    32200021
*                                                                       32400021
TCT00400 EQU   *                                                        32600021
         MVC   DXCCW1,AWTMCCWB          INITLZ CCW TO WRITE TAPE MARK   32800021
         MVI   DXCCW1+K4,CCWCMDCH+CCWSILI  CHAIN A NOP, SET SILI FLAG   33000021
         MVC   DXCCW2,AWTMCCWB          INITLZ SECOND CCW               33200021
         MVI   DXCCW2,CCWNOP            MAKE SECOND CCW A NOP           33400021
         LA    RD,TABD122               LOAD INTERNAL ERROR CODE        33600021
         BAL   RC,TCT04800              BR TO WRITE TAPE MARK   SA53865 33800001
         TM    IOBSTAT0,CSWUNITX        WAS ERROR CAUSED BY 'TAPE       34000021
*                                       ..INDICATE' CONDITION-          34200021
         BNO   TCT00800                 ..BR IF NOT TO ERROR RTN        34400021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         34600021
         BM    TCT00800                 ..BR IF REREAD          SA57250 34850001
*                                                                       35000021
*****          ISSUE END-OF-VOLUME- USER HAS RUN OUT OF SPACE           35200021
*****          AND MAY WISH TO CONTINUE WRITING DATA                    35400021
*                                                                       35600021
TCT00600 EQU *                                                          35800021
         TM    DEBOFLGS,DEBOFRLS        IS THIS AN EMULATION TAPE-      36000021
         BO    TCT00800                 ..BR IF YES- BYPASS FEOV        36200021
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BACKSPACE CMD    36400021
         LA    RD,TABD140               LOAD INTERNAL ERROR CODE        36600021
         BAL   RC,TCT04800              BACKSPACE PAST TAPE MARK        36800021
         OI    DCBCIND1,DCBC1EOB        TURN ON 'VOL FULL' BIT IN DCB   37000021
         FEOV  (RDCB)                   ISSUE FEOV TO OBTAIN NEXT VOL   37200021
         B     TCT00400                 BR TO PERFORM TRAILER LABEL     37400021
*                                       ..PROCESSING ON NEW VOLUME      37600021
*                                                                       37650021
*********************************************************************** 37700021
*                                                                       37800021
*****          CONSTRUCT END-OF-FILE LABEL 1                            38000021
*                                                                       38200021
TCT00800 EQU   *                                                        38400021
         MVC   FL1LABI,AEOF             MOVE LABEL IDENTIFIER INTO BFR  38600021
         MVI   FL1NO,FILPOS1            SET FILE LABEL NUMBER TO 1      38800021
*                                                                       39000021
*****          DETERMINE 17 LEAST SIGNIFICANT NON-BLANK                 39200021
*****          CHARACTERS IN DATA SET NAME IN JFCB                      39400021
*                                                                       39600021
         LA    RD,JFCBDSNM              PT TO JFCB DSNAME FIELD  A41662 39800021
         LA    RET,JFCBDSNM+K27         POINT TO FIRST POSSIBLE  A41662 40000021
*                                       ..SIGNIFICANT CHARACTER  A41662 40200021
TCT01000 EQU   *                                                 A41662 40400021
         CLI   K16(RET),BLANK           IS THE 17TH SIGNIFICANT  A41662 40600021
*                                       ..CHARACTER A BLANK-     A41662 40800021
         BNE   TCT01200                 ..BR IF NOT- 'RET' PTS   A41662 41000021
*                                       ..TO FIRST SIGNIFICANT   A41662 41200021
*                                       ..CHARACTER              A41662 41400021
         BCT   RET,TCT01000             DECR STARTING ADDR AND   A41662 41600021
*                                       ..BR TO CHECK AGAIN      A41662 41800021
TCT01200 EQU   *                                                 A41662 42000021
         CLR   RET,RD                   IS DSNAME STARTING ADDR  A41662 42200021
*                                       ..WITHIN JFCB DSN FIELD- A41662 42400021
         BNL   TCT01400                 ..BR IF YES- USE 'RET'   A41662 42600021
         LR    RET,RD                   ..ELSE USE JFCBDSNM      A41662 42800021
*                                       ..AS STARTING ADDRESS    A41662 43000021
*                                                                A41662 43200021
*****          PLACE DSNAME FROM JFCB INTO TRAILER LABEL 1       A41662 43400021
*                                                                A41662 43600021
TCT01400 EQU   *                                                 A41662 43800021
         MVC   FL1ID,K0(RET)            MOVE NAME INTO LABEL     A41662 44000021
*                                                                       44200021
*****          GENERATION NUMBER AND VERSION NUMBER OF GENERATION       44400021
*                                                                       44600021
TCT01600 EQU   *                                                        44800021
         MVI   FL1GNO,BLANK             INITLZ GENERATION NUMBER AND    45000021
         MVC   FL1GNO+K1(K5),FL1GNO     ..VERSION NUMBER OF GENERATION  45200021
         MVC   FL1GNO+K1(K44),FL1GNO    ..NUMBER TO BLANKS              45400021
         TM    JFCBIND1,JFCGDG          IS THIS A GENERATION DATA SET-  45600021
         BE    TCT01800                 ..BRANCH IF NOT                 45800021
         LA    RET,K8                   SUBTRACT 8 FROM REG CONTAINING  46000021
         SLR   RD,RET                   ..FIRST BLANK IN DSNAME         46200021
         MVC   FL1GNO,K1(RD)            'RD' NOW PTS TO GENERATION NO.  46400021
         MVC   FL1VNG,K6(RD)            ..WHICH IS OF FORM GNNNNVNN     46600021
*                                                                       46800021
*****          FILE SERIAL, VOLUME SEQUENCE, AND FILE SEQUENCE NOS.     47000021
*                                                                       47200021
TCT01800 EQU   *                                                        47400021
         MVC   FL1FILSR,UCBSQC          MOVE FILE SERIAL NO. INTO BFR   47600021
         LH    RC,DEBTVLSQ              GET DEB VOL SEQ NUMBER  SA69185 49200021
         CVD   RC,DXCCW5                CONVERT IT FROM BINARY TO       49400021
         UNPK  FL1VOLSQ,DXCCW5          ..UNPACKED DECIMAL, STORE IN    49600021
         OI    FL1VOLSQ+K3,ZONEOF       ..BUFFER, AND REMOVE SIGN BITS  49800021
         LH    RC,JFCBFLSQ              LOAD JFCB FILE SEQUENCE NUMBER  50000021
         CVD   RC,DXCCW5                CONVERT IT FROM BINARY TO       50200021
         UNPK  FL1FILSQ,DXCCW5          ..EBCDIC, STORE IN BUFFER,      50400021
         OI    FL1FILSQ+K3,ZONEOF       ..AND REMOVE SIGN BITS          50600021
*                                                                       50800021
*****          CREATION DATE- TO BE IN THE FORM BYYDD                   51000021
*                                                                       51200021
         MVI   FL1CREDT,BLANK           SET 1ST BYTE OF DATE TO BLANK   51400021
         SR    RC,RC                    CLEAR WORK REGISTER AND INSERT  51600021
         IC    RC,JFCBCRDT              ..YEAR OF CREATION FROM JFCB    51800021
         CVD   RC,DXCCW5                CONVERT YEAR FROM BINARY TO     52000021
         UNPK  FL1CREDT+K1(K2),DXCCW5   ..EBCDIC, STORE IN BUFFER,      52200021
         OI    FL1CREDT+K2,ZONEOF       ..AND REMOVE SIGN BITS          52400021
         IC    RC,JFCBCRDT+K1           LOAD 1ST CHARACTER OF DAY OF    52600021
         SLA   RC,K8                    ..CREATION AND POSITION IT      52800021
         IC    RC,JFCBCRDT+K2           LOAD SECOND CHARACTER           53000021
         CVD   RC,DXCCW5                CONVERT DAY FROM BINARY TO      53200021
         UNPK  FL1CREDT+K3(K3),DXCCW5   ..EBCDIC, STORE IN BUFFER,      53400021
         OI    FL1CREDT+K5,ZONEOF       ..AND REMOVE SIGN BITS          53600021
*                                                                       53800021
*****          EXPIRATION DATE- TO BE OF FORM BYYDD                     54000021
*                                                                       54200021
         MVI   FL1EXPDT,BLANK           SET 1ST BYTE OF DATE TO BLANK   54400021
         SR    RC,RC                    CLEAR WORK REGISTER AND INSERT  54600021
         IC    RC,JFCBXPDT              ..YEAR OF EXPIRATION FROM JFCB  54800021
         CVD   RC,DXCCW5                CONVERT YEAR FROM BINARY TO     55000021
         UNPK  FL1EXPDT+K1(K2),DXCCW5   ..EBCDIC, STORE IN BUFFER,      55200021
         OI    FL1EXPDT+K2,ZONEOF       ..AND REMOVE SIGN BITS          55400021
         LH    RC,JFCBXPDT+K1           LD DAY OF EXPIRATION FROM JFCB  55600021
         CVD   RC,DXCCW5                CONVERT DAY FROM BINARY TO      55800021
         UNPK  FL1EXPDT+K3(K3),DXCCW5   ..EBCDIC, STORE IN BUFFER,      56000021
         OI    FL1EXPDT+K5,ZONEOF       ..AND REMOVE SIGN BITS          56200021
*                                                                       56400021
*****          BLOCK COUNT                                              56600021
*                                                                       56800021
         L     RC,DCBBLKCT              LOAD BLOCK COUNT FROM DCB       57000021
         CVD   RC,DXCCW5                CONVERT BLK CT FROM BINARY TO   57200021
         UNPK  FL1BLKCT,DXCCW5          ..EBCDIC, STORE IN BUFFER,      57400021
         OI    FL1BLKCT+K5,ZONEOF       ..AND REMOVE SIGN BITS          57600021
         TM    DCBMACRF,DCBMEXCP        IS THE ACCESS METHOD EXCP-      57800021
         BNO   TCT02200                 ..BR IF NOT- BLK CT VALID       58000021
         TM    DCBMACRF+K1,DCBMDEV      DOES TAPE DEPEND SECTION EXIST- 58200021
         BNZ   TCT02200                 ..BR IF YES- BLK CT VALID       58400021
         MVI   FL1BLKCT,CHAR0           SET LABEL BLOCK COUNT TO 0,     58600021
         MVC   FL1BLKCT+K1(K5),FL1BLKCT ..INDICATING THAT THERE WAS NO  58800021
*                                       ..DCB BLOCK COUNT               59000021
*                                                                       59200021
*****          DATA SET SECURITY                                        59400021
*                                                                       59600021
TCT02200 EQU   *                                                        59800021
         MVI   FL1FSEC,FL1NOSEC         INDICATE NO DATA SET SECURITY   60000021
         TM    JFCBIND2,JFCBSCTY        DOES THE JFCB SPECIFY SECURITY- 60200021
         BNO   TCT02400                 ..BR IF NOT- SECURITY COMPLETE  60400021
         MVI   FL1FSEC,FL1SECTY         INDICATE READ/WRITE SECURITY    60600021
         TM    JFCBIND2,JFCBRWPW        DOES JFCB SPECIFY WRITE-ONLY    60800021
*                                       ..SECURITY-                     61000021
         BNO   TCT02400                 ..BR IF NOT- SECURITY COMPLETE  61200021
         MVI   FL1FSEC,FL1WRSEC         INDICATE WRITE-ONLY SECURITY    61400021
*                                                                       61600021
*****          SYSTEM CODE AND RESERVED FIELDS                          61800021
*                                                                       62000021
TCT02400 EQU   *                                                        62200021
         AIF   ('&LIB' NE 'LIB1').LIB22G0                               62250002
         MVC   FL1SYSCD,JFCBSYSC        INSERT SYSTEM CODE INTO BUFFER  62400021
.LIB22G0 ANOP                                                           62450002
         AIF   ('&LIB' EQ 'LIB1').LIB12G0                               62500002
         MVC   FL1SYSCD,VSSYSC          INSERT SYSTEM CODE       XM1201 62550002
*                                       INTO BUFFER              XM1201 62560002
.LIB12G0 ANOP                                                           62570002
         MVI   FL1RES,BLANK             PAD THE REST OF THE BUFFER      62600021
         MVC   FL1RES1,FL1RES           ..BLANKS (7 CHARACTERS)         62800021
*                                                                       63000021
*****          SET UP CHANNEL PROGRAM TO WRITE LABEL                    63200021
*                                                                       63400021
         LA    RC,DXLBL                 LOAD ADDRESS OF BUFFER AND      63600021
         ST    RC,DXCCW1                ..STORE IT IN WRITE CCW         63800021
         MVI   DXCCW1,CCWWRTAP          INITLZ CCW FOR WRITE COMMAND    64000021
         MVC   DXCCW1+K4(K4),AWTMCCWB+K4  SET LNG EQ 80, SILI FLAG ON   64200021
*                                                                       64400021
*****          TRANSLATE ANSI LABEL DATA BEFORE WRITING LABEL           64600021
*                                                                       64800021
         TM    SRTESTAB,UCBBSTR         WERE ANSI LABELS SPECIFIED-     65000021
         BNO   TCT02800                 ..BR IF NOT- BYPASS TRANSLATION 65200021
         TM    JFCBIND2,JFCBSCTY        DOES JFCB SPECIFY SECURITY-     65400021
         BO    TCT02600                 ..BR IF YES TO OBTAIN SYS CODE  65600021
         MVI   FL1FSEC,BLANK            ..ELSE SET ACCESSIBILITY        65800021
*                                       ..INDICATOR TO BLANK            66000021
TCT02600 EQU   *                                                        66200021
         MVC   FL1SYSCD(K5),ASYSCD      MOVE NEW SYSTEM CODE INTO BFR   66400021
*        XLATE DXLBL,K80,TO=A           TRANSLATE LABEL DATA- MACRO     66600021
*                                       EXPANDED MANUALLY TO SAVE SPACE 66800021
         LA    R1,DXLBL                 LOAD ADDR OF TRANSLATE AREA     67000021
         LA    R0,K80                   LOAD LENGTH TO BE TRANSLATED    67200021
         O     R1,ANSICON1              INDICATE TRANSLATE TO ASCII     67400021
         SVC   103                      ISSUE TRANSLATE SVC             67600021
         B     TCT03000                 BR TO WRITE LABEL               67800021
TCT02800 EQU   *                                                        68000021
         AIF   ('&LIB' NE 'LIB1').LIB22G2                               68050002
         MVC   FL1SYSCD,JFCBSYSC        INSERT SYSTEM CODE INTO BUFFER  68200021
.LIB22G2 ANOP                                                           68250002
*                                                                       68400021
*****          WRITE END-OF-FILE LABEL 1                                68600021
*                                                                       68800021
TCT03000 EQU   *                                                        69000021
         LA    RD,TABD123               LOAD INTERNAL ERROR CODE        69200021
         BAL   RC,TCT04800              BR TO WRITE TRAILER LABEL 1     69400021
*                                                                       69450021
*********************************************************************** 69500021
*                                                                       69600021
*****          PREPARE END-OF-FILE LABEL 2                              69800021
*                                                                       70000021
TCT03200 EQU   *                                                        70200021
         MVI   FL1NO,CHAR2              SET FILE LABEL IDENTIFIER TO 2  70400021
         MVI   FL2TRTCH,BLANK           SET PART OF LABEL TO            70600021
         MVC   FL2TRTCH+K1(K45),FL2TRTCH  BLANKS - 47 CHARACTERS        70800021
*                                                                       71000021
*****          BLOCKING ATTRIBUTE                                       71200021
*                                                                       71400021
         SR    RC,RC                    CLEAR WORK REGISTER AND INSERT  71600021
         IC    RC,JFCRECFM              ..RECORD FORMAT FROM JFCB       71800021
*                                       ..(BITS 0 AND 1 CONTAIN THE     72000021
*                                       ..BLOCKING ATTRIBUTE)           72200021
         SRL   RC,K3                    POSITION BLK ATTRIBUTE AND SAVE 72400021
         STC   RC,DXLBL+K38             ..PREPARATORY TO TRANSLATION    72600021
         NI    DXLBL+K38,K3             ZERO ALL BUT BITS 0 AND 1       72800021
         TR    DXLBL+K38(K1),ABLKA      TRANSLATE TO S,B,R, OR BLANK    73000021
*                                                                       73200021
*****          RECORD FORMAT                                            73400021
*                                                                       73600021
         TM    JFCRECFM,JFCVARD         DOES RECORD FORMAT EQUAL 'D'-   73800021
         BNO   TCT03400                 ..BR IF NOT TO FIND RCD FORMAT  74000021
         MVI   FL2RECFM,DRECFM          SET RECFM TO 'D'                74200021
         B     TCT03600                 BR TO GET BLOCKSIZE             74400021
TCT03400 EQU   *                                                        74600021
         SRL   RC,K3                    BITS 0,1 CONTAIN RECORD FORMAT  74800021
         STC   RC,FL2RECFM              STORE RCD FORMAT IN BUFFER      75000021
         TR    FL2RECFM,ARECFM          TRANSLATE TO V, F, OR U         75200021
*                                                                       75400021
*****          BLOCK SIZE AND LOGICAL RECORD LENGTH                     75600021
*                                                                       75800021
TCT03600 EQU   *                                                        76000021
         LH    RC,JFCBLKSI              LOAD BLOCK LENGTH FROM JFCB     76200021
         CVD   RC,DXCCW5                CONVERT BLOCK LNG FROM BINARY   76400021
         UNPK  FL2BLKL,DXCCW5           ..TO EBCDIC, STORE IN BUFFER,   76600021
         OI    FL2BLKL+K4,ZONEOF        ..AND REMOVE SIGN BITS          76800021
         LH    RC,JFCLRECL              LOAD LOGICAL RCD LNG FROM JFCB- 77000021
         CH    RC,AGRTR32K              IS LRECL GREATER THAN 32K-      77200021
         BE    TCT03800                 ..BARNCH IF YES- UNACCEPTABLE   77400021
         CVD   RC,DXCCW5                CONVERT LOGICAL RECORD LENGTH   77600021
         UNPK  FL2LRECL,DXCCW5          ..FROM BINARY TO EBCDIC, STORE  77800021
         OI    FL2LRECL+K4,ZONEOF       ..IN BFR, AND REMOVE SIGN BITS  78000021
         B     TCT04000                 BR TO CONTINUE MERGE            78200021
TCT03800 EQU   *                                                        78400021
         MVI   FL2LRECL,X'F9'           SET LRECL TO 9'S, INDICATING    78600021
         MVC   FL2LRECL+K1(K4),FL2LRECL ..THAT IS IS GREATER THAN 32K   78800021
*                                                                       79000021
*****          TAPE RECORDING DENSITY                                   79200021
*                                                                       79400021
TCT04000 EQU   *                                                        79600021
         MVI   FL2DEN,CHAR4             SET DENSITY TO 6250 BPI   99223 79650003
         TM    JFCDEN,DEN6250           IS DENSITY 6250 BPI       99223 79700003
         BO    TCT04200                 ..BR IF YES- DENSITY COMP 99223 79750003
         MVI   FL2DEN,CHAR3             SET DENSITY TO 1600 BPI         79800021
         TM    JFCDEN,DEN1600           IS DENSITY 1600 BPI-            80000021
         BO    TCT04200                 ..BR IF YES- DENSITY COMPLETE   80200021
         MVI   FL2DEN,CHAR2             SET DENSITY TO 'HIGH' (800 BPI) 80400021
         TM    JFCDEN,DCBDEN08          IS DENSITY 'HIGH'-              80600021
         BO    TCT04200                 ..BR IF YES- DENSITY COMPLETE   80800021
         MVI   FL2DEN,CHAR1             SET DENSITY TO 'MEDIUM' (556    81000021
*                                       ..BPI)                          81200021
         TM    JFCDEN,DCBDEN05          IS DENSITY 'MEDIUM'-            81400021
         BO    TCT04200                 ..BR IF YES- DENSITY COMPLETE   81600021
         MVI   FL2DEN,CHAR0             SET DENSITY TO 'LOW' (200 BPI)  81800021
*                                                                       81850003
*****          SET UP TAPE DRIVE ID FOR 3400 SERIES TAPE IN             81900003
*****          THE STANDARD LABEL                                       81950003
*                                                                       81960003
TCT04200 EQU   *                                                        82000021
         TM    UCBSTAB,UCBBSTR          ANSI LABELS               99223 82010003
         BO    TCT04300                 YES - BRANCH              99223 82020003
         CLI   UCBTBYT4,X'03'           3400 SERIES DRIVE         99223 82030003
         BNE   TCT04300                 NO - BRANCH               99223 82040003
         CLI   UCBSENSN,K24             IS IT 3420                99223 82042003
         BNE   TCT04300                 NO - BRANCH               99223 82044003
         USING UCBMT,RC                 SET UP ADDRESSABILITY     99223 82046003
         L     RC,UCBXTN                GET EXTENSION ADDRESS     99223 82048003
         LH    RC,K8(RC)                GET ID OF CREATING DRIVE  99223 82048403
         DROP  RC                                                 99223 82048803
         CVD   RC,DXCCW5                CONVERT ID                99223 82049203
         UNPK  FL2ID,DXCCW5             ID IN EBCDIC              99223 82049603
         OI    FL2ID+K4,ZONEOF          REMOVE SIGN BITS          99223 82049703
TCT04300 EQU   *                                                  99223 82050003
         MVI   FL2FILP,CHAR0            SET FILE POSITION TO ZERO       82200021
         CLC   SRTEVOLI,JFCBVOLS        IS THIS THE FIRST VOULME-       82400021
         BE    TCT04400                 ..BR IF YES- FILE POS COMPLETE  82600021
         MVI   FL2FILP,CHAR1            SET FILE POSITION TO 1          82800021
*                                                                       83000021
*****          COMPLETE TRAILER LABEL 2 IN NEXT MODULE                  83200021
*                                                                       83400021
TCT04400 EQU   *                                                        83600021
         LA    RF,MOD2G2M               PT TO ID/TTR OF NEXT MOD        83800021
         SR    RET,RET                  BR TABLE OFFSET FOR THAT MODULE 84000021
         EJECT                                                          84200021
*********************************************************************** 84400021
*              EXITS                                                  * 84600021
*********************************************************************** 84800021
*                                                                       85000021
TCT04600 EQU   *                                                        85200021
         IECRES XCTL,(RF),(RET)         INVOKE IECRES MACRO TO 'XCTL'   85400021
         SPACE 2                                                        85600021
*********************************************************************** 85800021
*              SUBROUTINES                                            * 86000021
*********************************************************************** 86200021
*                                                                       86400021
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              86600021
*                                                                       86800021
*        ENTRY TO THE SUBROUTINE IS VIA A 'BAL RC,TCT04800'             87000021
*                                                                       87200021
TCT04800 EQU   *                                                        87400021
         EXCP  DXIOB                    INITIATE I/O OPERATION  SA53865 87750001
         IECRES WAIT                    INVOKE MACRO TO 'WAIT'  SA53865 87800001
         TM    IOBSTAT0,CSWUNITX        TEST FOR TAPE INDICATE  SA53865 87810001
         BZ    TCT04950                 BRANCH IF NOT           SA53865 87820001
         MVI   DXECB,ECBCOD7F           SUCCESSFUL COMPLETION   SA53865 87830001
*                                       FOR EOV TESTS           SA53865 87840001
         BR    RC                       RETURN TO CALLER        SA53865 87842001
TCT04950 EQU   *                                                SA53865 87844001
         TM    DXECB,ECBNOERR           TEST FOR SUCCESSFUL COMPLETION- 88000021
         BCR   1,RC                     ..BR IF YES- RETURN TO CALLER   88200021
*                                       ..ELSE DROP THRU TO ERR RTN     88400021
         SPACE 2                                                        88600021
*********************************************************************** 88800021
*              ERROR PROCESSING                                       * 89000021
*********************************************************************** 89200021
*                                                                       89400021
TCT05000 EQU   *                                                        89600021
         DMABCOND (RD),ABEND2G          EXIT TO PROB DETERMINATION RTN  89800021
         EJECT                                                          90000021
*********************************************************************** 90200021
*              CONSTANTS                                              * 90400021
*********************************************************************** 90600021
*                                                                       90800021
AWTMCCWB CCW   X'1F',0,X'20',80         WRITE TAPE MARK;COUNT FOR WRITE 91000021
ANSICON1 DC    X'80000000'              INDICATES 'TRANSLATE FROM       91200021
*                                       ..EBCDIC TO ASCII               91400021
AEOF     DC    C'EOF'                   END-OF-FILE LABEL IDENTIFIER    91600021
ARECFM   DC    C'TVFU'                  RECFM TRANSLATE TABLE (NO 0 VAL 91800021
*                                       VARIABLE,FIXED,UNKNOWN RECORD F 92000021
ABLKA    DC    C' SBR'                  BLK ATTRB TRANSLATE TABLE       92200021
ASYSCD   DC    C'OS360'                 ANSI SYSTEM CODE                92400021
         AIF   ('&LIB' EQ 'LIB1').LIB12G1                               92450002
VSSYSC   DC    C'IBM OS/VS 370'         VS SYSTEM CODE           XM1201 92500002
         DS    0H                       ALIGN TO HALF WORD BNDRY XM1201 92510002
.LIB12G1 ANOP                                                           92550002
AGRTR32K DC    X'8000'                  VALUE IN LBL WHEN LRECL GT 32K  92600021
         SPACE 2                                                        92800021
*********************************************************************** 93000021
*              XCTL TABLE                                             * 93200021
*********************************************************************** 93400021
*                                                                       93600021
XCTLTB2G XCTLTABL ID=(ABEND2G,0P,MOD2G2M,2M),SVC=023                    93800021
         SPACE 2                                                        94000021
         IECDSECS DCB,                                                 C94200021
               DEB,                                                    C94400021
               UCB,                                                    C94600021
               MAIN,                                                   C94800021
               EXPAND=YES                                               95200021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   95400021
         SPACE 2                                                        95600021
         END                                                            95800021
