         TITLE ' TCLOSE OUTPUT UTLS PROCESSING MODULE - IFG0232J '      00200000
         GBLC  &LIB                                                     00400000
&LIB     SETC  'LIB1'                                                   00600000
*********************************************************************** 00800000
*                                                                     * 01000000
*                                                                     * 01200000
*           RELEASE 25 DELETIONS/CHANGES                              * 01400000
*           RELEASE 24 DELETIONS/CHANGES                              * 01600000
*           RELEASE 23 DELETIONS/CHANGES                              * 01800000
*           RELEASE 22 DELETIONS/CHANGES                              * 02000000
*           RELEASE 21 DELETIONS/CHANGES                              * 02200000
*                                                                     * 02400000
* STATUS CHANGE LEVEL 000                                             * 02600000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 02800000
*                                                                     * 03000000
* FUNCTION -                                                          * 03200000
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03400000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S) FOR DETAILS.          * 03600000
*                                                                     * 03800000
* ENTRY POINTS -                                                      * 04000000
*         IFG0232J                                                    * 04200000
*                                                                     * 04400000
* INPUT -                                                             * 04600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04800000
*                                                                     * 05000000
* OUTPUT -                                                            * 05200000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05400000
*                                                                     * 05600000
* EXTERNAL REFERENCES -                                               * 05800000
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 06000000
*            WAIT. '--' REFERS TO THE TWO DIGITS IN THE SAME POSITION * 06200000
*            IN THIS MODULE'S NAME.                                   * 06400000
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 06600000
*                                                                       06800000
* EXITS, NORMAL -                                                     * 07000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07200000
*                                                                     * 07400000
* EXITS, ERROR -                                                      * 07600000
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0550P, IF AN      * 07800000
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 08000000
*    'FUNCTION PROLOG(S)'.  '--' REFERS TO THE DIGITS IN THE SAME     * 08200000
*    POSITION IN THIS MODULE'S NAME.                                  * 08400000
*                                                                     * 08600000
* TABLE/WORK AREA -                                                   * 08800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 09000000
*                                                                     * 09200000
* ATTRIBUTES -                                                        * 09400000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 09600000
*                                                                     * 09800000
* CHARACTER CODE DEPENDENCY -                                         * 10000000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10200000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 10400000
*    DIFFERENT CHARACTER SET IS USED FOR EXECTION.                    * 10600000
*                                                                     * 10800000
* NOTES -                                                             * 11000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 11200000
*                                                                     * 11400000
*********************************************************************** 11600000
          EJECT                                                         11800000
*********************************************************************** 12000000
*                                                                     * 12200000
*                          FUNCTION PROLOG                            * 12400000
*                                                                     * 12600000
*********************************************************************** 12800000
*FUNCTION/OPERATION -                                                   13000000
*   THIS MODULE IS USED BY I/O SUPPORT ROUTINES (TCLOSE) TO             13200000
*   WRITE UP TO EIGHT USER TRAILER LABELS AS REQUIRED FOR DATA SETS     13400000
*   ON DIRECT ACCESS VOLUMES.  IT IS ENTERED ONCE FOR EACH DCB TO       13600000
*   BE PROCESSED.                                                       13800000
*      THE MODULE GETS AN AREA OF MAIN STORAGE WHICH IS USED AS A       14000000
*   WORKAREA-BUFFER IN WHICH THE USER LABEL RECORDS ARE FORMATTED AND   14200000
*   AS A SAVE AREA FOR THE REGISTERS OF THE I/O SUPPORT FUNCTION        14400000
*   REQUIRING USER LABEL PROCESSING.  THE LAST PART OF THE AREA         14600000
*   OBTAINED IS USED FOR A 16-BYTE PARAMETER LIST.                      14800000
*      IF A TRACK WAS ALLOCATED FOR USER LBLS,CONTROL IS GIVEN TO THE   15000000
*   USER'S LABEL CONSTRUCTION ROUTINE VIA SYNCHRONOUS EXIT (SVC 12).    15200000
*   ON RETURN FROM THE USER'S ROUTINE, IF A LABEL WAS CONSTRUCTED, IT   15400000
*   IS WRITTEN FOLLOWED BY 2 FILEMARKS FOR HEADERS (UHL(N+1),UTL0) OR   15600000
*   ONE FILEMARK FOR TRAILERS (UTL(N+1).  DEPENDING ON THE RETURN CODE  15800000
*   PASSED BY THE USER'S ROUTINE, ANOTHER LABEL IS PROCESSED OR CONTROL 16000000
*   IS GIVEN BACK TO THE I/O SUPPORT FUNCTION WHICH CALLED THIS MODULE. 16200000
*                                                                       16400000
*ENTRY POINTS -                                                         16600000
*   IFG0232J -INITIAL ENTRY TO THIS MODULE IS BY MEANS OF XCTL FROM     16800000
*             IFG0232D.                                                 17000000
*                                                                       17200000
*INPUT -                                                                17400000
*   REGISTERS 2-11 - CONTENTS AT TIME OF XCTL FROM PREVIOUS MODULE      17600000
*             12   - EXIT LIST ENTRY FOR EXIT TO BE TAKEN               17800000
*                    BITS 3-7 EXIT TYPE CODE                            18000000
*                         8-31 EXIT ADDRESS, ZEROES IF NO ACTIVE EXIT   18200000
*                                                                       18400000
*   JFCBMASK+5 (IN I/O SUPPORT WORK AREA) BITS 5-6 INDICATE FUNCTION    18600000
*              REQUIRING USER LABEL PROCESSING                          18800000
*                                                                       19000000
*                                                                       19200000
*OUTPUT -                                                               19400000
*   USER LABELS ARE WRITTEN AS REQUESTED                                19600000
*   ON FINAL EXIT REGISTERS 2-11 HAVE CONTENTS AS AT ENTRY TO THIS      19800000
*   MODULE.                                                             20000000
*                                                                       20200000
*EXTERNAL ROUTINES -                                                    20400000
*   USER'S OUTPUT LABEL EXIT ROUTINES - ENTERED BY MEANS OF SYNCHRONOUS 20600000
*      EXIT (SVC 12) WITH THE FOLLOWING INPUT                           20800000
*                                                                       21000000
*                    REG 0    CONTAINS NO MEANINGFUL INFO               21200000
*                        1    POINTER TO 4 WORD PARAMETER LIST WHICH    21400000
*                             CONTAINS -                                21600000
*                               POINTER TO LABEL BUFFER                 21800000
*                               POINTER TO DCB                          22000000
*                               FLAG BYTE, PTR TO STATUS INFO (IF       22200000
*                                          PERMANENT ERROR) OR ZERO     22400000
*                               POINTER TO IMAGE AREA (IF TOTALING WAS  22600000
*                               REQUESTED) OR ZERO                      22800000
*                        2-13 CONTENTS OF USER'S REGS BEFORE I/O SUPP   23000000
*                        14   RETURN ADDRESS                            23200000
*                        15   EXIT ADDRESS                              23400000
*                                                                       23600000
*      BEFORE EXITING, THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE    23800000
*      SVRB EXTENDED SAVE AREA.  THE USER'S REGISTERS 2-13 ARE RESTORED 24000000
*      FROM THE SVRB.  THE LOCK BIT (BIT 6) IN DCBOFLGS FIELD IS SET TO 24200000
*      1 TO PREVENT ANOTHER I/O SUPPORT FUNCTION FROM OPERATING ON THIS 24400000
*      DCB WHILE THE USER IS IN CONTROL.  ON RETURN FROM THE USER'S     24600000
*      ROUTINE, THIS BIT IS RESET TO 0.                                 24800000
*                                                                       25000000
*EXITS-NORMAL                                                           25200000
*   EXIT IS MADE TO THE USER' OUTPUT HEADER OR OUTPUT TRAILER ROUTINES  25400000
*   AS REQUESTED BY USER (MAXIMUM NUMBER OF LABELS IS EIGHT).           25600000
*                                                                       25800000
*   FINAL EXIT IS VIA THE RESIDENT ROUTINE TO THE TCLOSE FINAL        * 26000000
*   MODULE, IFG0232Z TO CONTINUE TCLOSE I/O PR0CESSING.  REGISTER 14  * 26200000
*   MUST CONTAIN A ZERO UPON ENTRY INTO THAT MODULE.                  * 26400000
*                                                                       26600000
*                                                                       26800000
*EXITS-ERROR                                                            27000000
*   NO USER    LABEL EXTENT EXISTS-THE APPROPRIATE EXIT ROUTINE IS      27200000
*      ENTERED WITH THE BUFFER POINTER SET TO ZERO.   OTHER             27400000
*      INPUT AS USUAL.                                                  27600000
*                                                                       27800000
*   I/O ERROR WRITING A USER LABEL - THE USER'S ROUTINE IS ENTERED.     28000000
*      AGAIN WITH                                                       28200000
*                 BIT 0 OF FLAG BYTE SET TO ONE, PTR TO STANDARD        28400000
*                 STATUS INFORMATION                                    28600000
*                 OTHER INPUT AS FOR NORMAL ENTRY                       28800000
*                                                                       29000000
*TABLES/WORKAREAS -                                                     29200000
*   FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY THE     29400000
*   DSECTS AT THE END OF THIS LISTING.                                  29600000
*                                                                       29800000
*ATTRIBUTES -                                                           30000000
*   REENTRANT, ENABLED, PRIVILEGED                                      30200000
*                                                                       30400000
IFG0232J CSECT                                                          30600000
*                                                                       30800000
         SPACE 1                                                        31000000
         BALR  RBASE,0                  ESTABLISH ADDRESSABILTIY        31200000
         USING *,RBASE                                                  31400000
         USING FORCORE,RCORE                                            31600000
         USING UCBOB,RUCB                                               31800000
         USING IHADEB,RDEB                                              32000000
         USING IHADCB,RDCB                                              32200000
         USING UNITABLE,R1                                              32400000
         USING TIOENTRY,RTIOT                                           32600000
         SPACE 1                                                        32800000
*                   SET UP REGISTERS                                    33000000
         USING ULWK,RWTGC                                               33200000
         USING TCB,RET                                                  33400000
         USING UCBOB,RUCB                                               33600000
         ST    RWTGC,DXCCW11            SAVE CONTENTS OF REG            33800000
*                                                                       34000000
         GETMAIN R,LV=USERL,SP=250      OBTAIN CORE FOR WORK AREA, LABEC34200000
                                        BUFFER AND PARAMETER LIST (72+8 34400000
*                                                                       34600000
         STM   RPAR,RC,K0(R1)           SAVE REGS 5-12 FOR CALLER       34800000
         XC    K32(K120,R1),K32(R1)     CLEAR WKAREA AND BUFFER         35000000
         LR    RWTGC,R1                 SET BASE FOR ULWK DSECT         35200000
         NI    K28(RWTGC),UCBMAIN-UCBMOUNT  TURN OFF LAST ENTRY INDIC   35400000
         MVC   DXCCW12(K8),DXCCW7       SAVE DSCB ADDR FOR OPEN         35600000
         XC    DXCCW1(K80),DXCCW1       CLEAR CHAN PROG AREA            35800000
*                                                                       36000000
*        DETERMINE IF A USER LABEL EXTENT HAS BEEN ALLOCATED FOR THIS   36200000
*        DATA SET.                                                      36400000
*                                                                       36600000
         CLI   DSCEXTYP,HEX40           IS 1ST EXTENT FOR USER LABELS   36800000
         BNE   TCD03500                 NO EXTENT, GO TO USER           37000000
*                                                                       37200000
*        EXTENT EXISTS - PROCESS USER LABELS                            37400000
*                                                                       37600000
*                                                                       37800000
         XC    DXDAADDR(K8),DXDAADDR    ZERO IOBOADAD IN IOS' IOB       38000000
         MVC   DXDAADDR+K3(K4),DSCLOWLM  CCHH FROM START OF 1ST EXTENT  38200000
*                                       IF 2321, GET BB FROM UCB        38400000
         CLI   UCBID,UCBMAIN            IS DEVICE 2321                  38600000
         BE    TCD03100                 NO,BRANCH                       38800000
         USING UCBDCELL,RUCB                                            39000000
         MVC   DXDAADDR+K1(K2),UCBDBBNR  2321, GET BB FROM SUB-VCB      39200000
         USING UCBOB,RUCB                                               39400000
*                                                                       39600000
TCD03100 EQU   *                                                        39800000
*                                                                       40000000
*                                                                       40200000
*                                                                       40400000
*        PROCESS USER TRAILER LABELS.                                   40600000
*                                                                       40800000
*        SET UP CHANNEL PROGRAM TO FIND                                 41000000
*        STRUCTURE COUNT AND KEY FIELDS IN WORK AREA.  SET IOBDADAD     41200000
*        IN I/O SUPPORT'S IOB.                                          41400000
*                                                                       41600000
         LA    R1,ULWK8                                                 41800000
         ST    R1,DXCCW1                READ COUNT INTO WK1             42000000
         LA    R1,ULWK10                                                42200000
         ST    R1,DXCCW2                SEARCH ON KEY IN WK3            42400000
         LA    R1,DXCCW1                                                42600000
         ST    R1,DXCCW3                TIC TO CCW1                     42800000
         OC    DXCCW1(K32),ULCP13       OR CP SKELETON OVER ADDRESSES   43000000
         MVC   ULWK10(K4),UTLCONS3      KEY=UTLO FOR SEARCH KEY EQUAL   43200000
*                                                                       43400000
         BAL   RD,TCD04300              EXECUTE CP TO FIND UTL0         43600000
         BZ    TCD03300                 ERROR, BR TO SET UP EXIT TO USR 43800000
         SPACE                                                          44000000
*                      SET UP  CP TO WRITE USER TRAILER                 44200000
*                      AS EACH LABEL (UTLN) IS WRITTEN, A FILE          44400000
*                      MARK (UTL(N+1)) WILL BE WRITTEN FOLLOWING        44600000
*                                                                       44800000
         XC    DXCCW1(K32),DXCCW1       CLEAR CHNL PGM 1 OUT            45000000
         BAL   RPARC,TCD03700           GO SET UP CP                    45200000
         OC    DXCCW1(K32),ULCP23       OR CP SKELETON OVER ADDRESSES   45400000
         MVC   DXCCW5(K24),DXCCW1       APPEND CP FOR WRITE CHECKING    45600000
         LA    R1,DXCCW5                                                45800000
         ST    R1,DXCCW6                TIC BACK TO CCW5                46000000
         MVI   DXCCW6,CCWTIC            RESTORE TIC OP                  46200000
         MVI   DXCCW7,X'1E'             MAKE OP READ                    46400000
         OI    DXCCW7+K4,X'10'          SET SKIP BIT ON                 46600000
         NI    DXCCW7+K4,X'BF'          TURN OFF CC FLAG IN LAST CCW    46800000
         MVC   ULWK5(K12),ULWK8         SET UP COUNT, KEY FOR FILE MARK 47000000
         SR    R1,R1                    CLEAR RF                        47200000
         STC   R1,ULWK6+K3              DATA LENGTH=0 FOR FILE MRK      47400000
*                                       IF DISP=MOD,UTL0 MAY HAVE       47600000
*                                       LENGTH OF 80 BYTES              47800000
TCD03200 EQU   *                                                        48000000
         IC    R1,ULWK9                 R OF COUNT FOR UTL TO BE WRITTN 48200000
         BCTR  R1,K0                    R MINUS 1                       48400000
         STC   R1,DXDAADDR+K7           R IN IOBDADAD                   48600000
         LA    R1,K2(K0,R1)             R-1+2=R+1                       48800000
         STC   R1,ULWK6                 R IN COUNT FIELD OF UTL(N+1)    49000000
*                                                                       49200000
         IC    R1,ULWK10+K3             N FROM LABEL TO BE WRITTEN      49400000
         LA    R1,K1(K0,R1)             N+1                             49600000
         STC   R1,ULWK7+K3              KEY FOR UTL(N+1)                49800000
*                                                                       50000000
         MVI   ULWK9+K3,X'50'           DATA LENGTH = 80 FOR UTLN       50200000
*                                                                       50400000
         CLI   ULWK10+K3,X'F8'          CHECK IF 8 TRAILERS WERE WRITTN 50600000
         BNL   TCD03600                 YES, BRANCH TO SET UP RETURN    50800000
*                                                                       51000000
         MVC   ULBUFR(K4),ULWK7         PRIME LABEL BUFFER WITH UTLN    51200000
*                                                                       51400000
*        GO TO USER'S ROUTINE TO CONSTRUCT LABEL.                       51600000
*                                                                       51800000
         BAL   RPARC,TCD03800           GO EXIT TO USER'S ROUTINE       52000000
         MVC   ULBUFR(K4),ULWK7         REINSERT UTLN                   52200000
         LTR   RF,RF                    CHECK FOR RETURN CODE=0         52400000
         BZ    TCD03600                 CODE IS ZERO, BRANCH TO RETURN  52600000
         ST    RF,ULWK1                 SAVE RETURN CODE                52800000
         BAL   RD,TCD04300              GO WRITE LABEL                  53000000
*                                                                       53200000
         BZ    TCD03300                 YES, BR TO TAKE SPECIAL EXIT    53400000
         CLI   ULWK1+K3,DCBOEOF         CHECK RET CODE FOR MORE LABELS  53600000
         BE    TCD03600                 NO, PREVIOUS LABEL WAS LAST     53800000
         CLI   ULWK1+K3,X'08'           CHECK,BR IF RETURN CODE         54000000
         BNE   TCD03600                 WAS NOT VALID                   54200000
*                                                                       54400000
         MVC   ULWK8(K12),ULWK5         UTL(N+1) BECOMES C,K OF NXT LBL 54600000
         B     TCD03200                 BR TO PROCESS NEXT LABEL        54800000
TCD03300 EQU   *                                                        55000000
*                                                                       55200000
*        IF AN I/O ERROR OCCURS WRITING USER TRAILER LABELS, A SPECIAL  55400000
*        EXIT IS TAKEN TO THE USER'S ROUTINE.  INPUT TO THE USER'S      55600000
*        ROUTINE IS THE SAME AS FOR OTHER EXITS WITH ONE EXCEPTION-     55800000
*        IN THE THIRD WORD OF THE PARAMETER LIST, BIT 0 IS SET TO ONE   56000000
*        AND THE THREE LOW ORDER BYTES CONTAIN A POINTER TO STATUS      56200000
*        INFO (PTR TO IOB).                                             56400000
*                                                                       56600000
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   56800000
         ST    R1,ULPARM+K8             IN PARAMETER LIST               57000000
         OI    ULPARM+K8,ERROR          FLAG ERROR                      57200000
         BAL   RPARC,TCD03900           GO TO SYNCH TO USER             57400000
*                                                                       57600000
*                                                                       57800000
*                                                                       58000000
*                                                                       58200000
*        DETERMINE WHICH I/O SUPPORT FUNCTION  REQUIRED USER            58400000
*        TRAILER LABELS TO BE WRITTEN                                   58600000
TCD03400 EQU   *                                                        58800000
*                                                                       59000000
         B     TCD03600                                                 59200000
*                                                                       59400000
*                                                                       59600000
*        NO USER LABEL TRACK WAS ALLOCATED.  EXIT TO USER'S ROUTINE     59800000
*        WITH POINTER TO LABEL BUFFER ZEROED.                           60000000
*                                                                       60200000
TCD03500 EQU   *                                                        60400000
         XC    ULPARM+K8(K4),ULPARM+K8  CLEAR ANY ERROR INDICTNS        60600000
         SR    R1,R1                    BUFFER POINTER TO ZERO          60800000
         LA    RPARC,TCD03400           POINT TO RETURN AFTER SYNCH     61000000
         B     TCD04000                 GO SYNCH TO USER                61200000
*                                                                       61400000
TCD03600 EQU   *                                                        61600000
         OI    K31(RWTG),UCBLDPT        SET UL-RETURN INDICATION        61800000
*                                       USED BY TCLOSE D. A. STRING     62000000
*                                                                       62200000
*        FREE  WORKAREA AND LABEL BUFFER AND XCTL TO I/O SUPPORT        62400000
*        MODULE WHICH CALLED THIS MODULE.                               62600000
         MVC   DXCCW7(K8),DXCCW12       RESTORE DSCB ADDR FOR OPEN      62800000
*                                                                       63000000
         LR    R1,RWTGC                 START OF AREA TO BE FREED       63200000
         LM    RPAR,RDEB,K0(R1)         RESTORE CALLING MODULE'S REGS   63400000
         FREEMAIN R,LV=USERL,SP=250,A=(1)  FREE USER LABEL WORK AREA,  C63600000
                                        LABEL BUFFER AND PARAMETER LIST 63800000
*                                                                       64000000
*                                                                       64200000
*        LOAD RETURN MODULE OF THE TCLOSE D. A. STRING                  64400000
*                                                                       64600000
         SR    RET,RET                  SET RETURN CODE                 64800000
         LA    RF,LFG0232Z              FINAL MODULE                    65000000
         L     RWTGC,DXCCW11            RESTORE RES ROUTINE REG         65200000
         IECRES XCTL,(RF),(RET)         TO RESIDENT TO XCTL             65400000
*                                                                       65600000
TCD03700 EQU   *                                                        65800000
         LA    R1,DXDAADDR+K3                                           66000000
         ST    R1,DXCCW1                SEARCH ID FROM IOBDADAD+3       66200000
         LA    R1,DXCCW1                                                66400000
         ST    R1,DXCCW2                TIC TO CCW1                     66600000
         LA    R1,ULWK8                                                 66800000
         ST    R1,DXCCW3                WRITE C,K FROM ULWK1            67000000
         LA    R1,ULWK5                                                 67200000
         ST    R1,DXCCW4                WRITE LABEL FROM BUFFER         67400000
         BR    RPARC                    UNCONDITIONAL BRANCH            67600000
*                                                                       67800000
         SPACE 2                                                        68000000
*                                                                       68200000
*        CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS                      68400000
*                                                                       68600000
         SPACE                                                          68800000
         SPACE 3                                                        69000000
         SPACE 5                                                        69200000
*        CLOSED SUBROUTINE TO SAVE AND RESTORE REGISTERS, SET UP INPUT, 69400000
*        AND ISSUE THE SVC SYNCH  FOR SYNCHRONOUS EXIT TO PROBLEM PROG. 69600000
*        THIS MODULE'S REGISTERS 2-13 ARE SAVED IN THE SVRB EXTENDED    69800000
*        SAVE AREA AND THE USER'S REGISTERS 2-13 ARE RESTORED FROM THE  70000000
*        SVRB.  REGISTER CONTENTS ARE AS FOLLOWS-                       70200000
*                        R0 - CONTAINS NO MEANINGFUL INFO               70400000
*                        R1 - PTR TO PARAMETER LIST                     70600000
*                    R2-R13 - USER'S CONTENTS BEFORE I/O SUPPORT        70800000
*                       R14 - RETURN ADDRESS (SET BY SYNCH)             71000000
*                       R15 - EXIT ADDRESS                              71200000
*                                                                       71400000
TCD03800 EQU   *                                                        71600000
         XC    ULPARM+K8(K4),ULPARM+K8  ZERO ERROR INDICATIONS          71800000
TCD03900 EQU   *                                                        72000000
         LA    R1,ULBUFR                PTR TO LABEL BUFFER             72200000
TCD04000 EQU   *                                                        72400000
         STM   R1,RDCB,ULPARM           BUFFER,DCB PTRS TO PARM LIST    72600000
         XC    ULPARM+K12(K4),ULPARM+K12  ZERO TOTALING AREA            72800000
         TM    DCBDSORG,DCBORGDA        CK FOR DIRECT ORGANIZATION      73000000
         BO    TCD04100                 BR IF DIRECT                    73200000
         TM    DCBOFLGS,DCBOPEN         CK IF DCB ALREADY OPEN          73400000
         BZ    TCD04100                 IF YES, CTL FROM OPEN, BYPASS   73600000
*                                       TOTALING                        73800000
         TM    DCBMACRF,DCBMEXCP        CK IF EXCP                      74000000
         BO    TCD04100                 BR IF EXCP,SKIP TOTALING        74200000
         TM    DCBOPTCD,DCBOPTT         TEST,BR IF USER TOTALING        74400000
         BZ    TCD04100                 HAS NOT BEEN REQUESTED          74600000
*                                                                       74800000
         L     RDEB,DCBDEBAD            GET ADDRESS OF USER'S DEB       75000000
         SR    R1,R1                    CLEAR WORK REG                  75200000
         IC    R1,DEBNMEXT-IHADEB(RDEB)  GET NUMBER OF EXTENTS          75400000
         SLL   R1,K4                    MULTIPLY BY 16                  75600000
         L     RDEB,K36(R1,RDEB)        GET ADDR TOTALING WORKAREA-     75800000
*                                       DEB ADDR+32+4+LENGTH EXTENTS    76000000
         USING TOTSAVWA,RDEB            SET BASE - TOTALING AREA        76200000
         MVC   ULTOTPTR,TOTEOVPT        CURRENT IMAGE AREA ADDR TO      76400000
*                                       USR LBL PARM LIST               76600000
         DROP  RDEB                     DROP TOTALING AREA BASE         76800000
*                                                                       77000000
TCD04100 EQU   *                                                        77200000
         LA    R1,ULPARM                POINT TO PARAMETER LIST         77400000
         L     RET,CVTPTR               CVT ADDRESS                     77600000
         L     RET,CVTTCBP-CVT(K0,RET)  TCB PTR                         77800000
         L     RET,K4(K0,RET)           TCB ADDRESS                     78000000
         L     RET,TCBPRB               SVRB ADDRESS                    78200000
         NI    DCBOFLGS,X'FD'           SET LOCK BIT = 0                78400000
         STM   RDCB,RD,K96(RET)         SAVE I/O SUPP REGS IN SVRB AREA 78600000
         L     RF,K28(K0,RWTGC)         ADDRESS OF USER'S ROUTINE       78800000
         LA    RF,K0(K0,RF)             ROUTINE                         79000000
         L     RD,K28(RET)              PTR TO PREVIOUS RB              79200000
         TM    K10(RD),X'C0'            IS PREVIOUS A PRB?              79400000
         BNO   TCD04200                 YES,BRANCH                      79600000
         LR    RET,RD                   USE PREVIOUS RB                 79800000
TCD04200 LM    RDCB,RD,K40(RET)         RESTORE USER REGS               80000000
         SYNCH (RF)                                                     80200000
         L     RET,CVTPTR               CVT ADDRESS                     80400000
         L     RET,CVTTCBP-CVT(K0,RET)  TCB  PTR                        80600000
         L     RET,K4(K0,RET)           TCB  ADDRESS                    80800000
         L     RET,TCBPRB               SVRB ADDRESS                    81000000
         LM    RDCB,RD,K96(RET)         RESTORE I/O SUPPORT REGS        81200000
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT = 1                81400000
         MVC   ULBUFR(K4),ULWK10        REINSERT  UTLN/UHLN             81600000
         BR    RPARC                    UNCONDITIONAL BRANCH            81800000
*                                                                       82000000
*                                                                       82200000
*                                                                       82400000
TCD04300 EQU   *                                                        82600000
         EXCP  DXIOB                    INITIATE I/O OPERATION          82800000
         WAIT  ,ECB=DXECB                                               83000000
         TM    DXECB,ECBNOERR           IS THERE AN UNUSUAL I/O COND    83200000
         BCR   15,RD                    RETURN TO CALLER                83400000
*                                                                       83600000
*                                                                       83800000
         DC    X'00000000'                                              84000000
         SPACE 5                                                        84200000
         DS    0F                                                       84400000
UTLCONS3 DC    C'UTL0'                  KEY USED IN SEARCH KEY EQ       84600000
ULCP13   CCW   X'12',0,X'40',8          READ COUNT                      84800000
         CCW   X'29',0,X'40',4          SEARCH KEY EQUAL                85000000
         CCW   X'08',0,0,0              TIC                             85200000
         CCW   X'03',0,0,1              NOP                             85400000
*                                                                       85600000
ULCP23   CCW   X'31',0,X'40',5          SEARCH ID EQUAL                 85800000
         CCW   X'08',0,0,0              TIC TO CCW1                     86000000
         CCW   X'1D',0,X'40',92         WRITE CKD    UHLN     LABEL     86200000
         CCW   X'1D',0,X'40',12         WRITE CKD    UHL(N+1) FILE MARK 86400000
         CCW   X'1D',0,X'40',12         WRITE CKD    UTL0     FILE MARK 86600000
         XCTLTABL ID=(LFG0232Z,2Z),SVC=023                              86800000
         IECDSECS CVT,TCB,TIOT,DCB,DEB,UCB,MAIN,USERLAB,USERTOT,       X87000000
               UNITTAB,WTG,EXPAND=YES                                   87200000
         IECEQU                                                         87400000
* ***                                                                   87600000
         END                                                            87800000
