         TITLE 'IFG0232M - TCLOSE TAPE STANDARD TRAILER LABEL FUNCTION' 00100000
         COPY  LCGASMSW                                                 00150000
IFG0232M CSECT                                                          00400000
*                                                                       00500000
*********************************************************************** 00600000
*                                                                     * 00700000
*                                                                     * 00800000
*          RELEASE 25 DELETIONS/CHANGES                               * 00900000
*          RELEASE 24 DELETIONS/CHANGES                               * 01000000
*          RELEASE 23 DELETIONS/CHANGES                               * 01100000
*          RELEASE 22 DELETIONS/CHANGES                               * 01200000
*          RELEASE 21.7 DELETIONS/CHANGES                             * 01210001
*0000,390000                                                    SA53865 01220001
*          RELEASE 21 DELETIONS/CHANGES                               * 01300000
*0000160000-162000                                               M0011  01350021
*0000382000-384000,426000-427000                                 M0112  01370021
*                                                                     * 01400000
* STATUS CHANGE LEVEL 000                                             * 01500000
*                                                                     * 01600000
* FUNCTION -                                                          * 01700000
*    THIS MODULE CONTAINS PART II OF THE 'TCLOSE TAPE STANDARD        * 01800000
*    TRAILER LABEL FUNCTION'. REFER TO THE FOLLOWING 'FUNCTION        * 01900000
*    PROLOG' FOR DETAILS.                                             * 02000000
*                                                                     * 02100000
* ENTRY POINTS -                                                      * 02200000
*         IFG0232M                                                    * 02300000
*                                                                     * 02400000
* INPUT -                                                             * 02500000
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 02600000
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 02700000
*    POINT PROCESSING IS TO BEGIN:                                    * 02800000
*       0 - ENTRY FROM MODULE IFG0232G TO FINISH FORMATTING AND       * 02900000
*           WRITE TRAILER LABEL 'EOF2' AND TO PROCESS OUTPUT USER     * 03000000
*           LABELS, AS REQUIRED;                                      * 03100000
*       4 - ENTRY FROM MODULE IGC0002C TO PROCESS DEFERRED            * 03200000
*           INPUT USER LABELS, AS REQUIRED.                           * 03300000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG' FOR ADDITIONAL DETAILS. * 03400000
*                                                                     * 03500000
* OUTPUT -                                                            * 03600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 03700000
*                                                                     * 03800000
* EXTERNAL REFERENCES -                                               * 03900000
*         IFG023RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 04000000
*                    WAIT.                                            * 04100000
*                                                                     * 04200000
* EXITS, NORMAL -                                                     * 04300000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 04400000
*                                                                     * 04500000
* EXITS, ERROR -                                                      * 04600000
*         IFG0230P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 04700000
*                    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.        * 04800000
*                                                                     * 04900000
* TABLES/WORK AREAS -                                                 * 05000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 05100000
*                                                                     * 05200000
* ATTRIBUTES -                                                        * 05300000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 05400000
*                                                                     * 05500000
* CHARACTER CODE DEPENDENCY -                                         * 05600000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 05700000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05800000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05900000
*                                                                     * 06000000
* NOTES -                                                             * 06100000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 06200000
*                                                                     * 06300000
*********************************************************************** 06400000
*                                                                       06500000
*****    TCLOSE INTERNAL ERROR CODES                                    06600000
*                                                                       06700000
TABD141  EQU   141                      ERROR POSITIONING FOLLOWING     06800000
*                                       ..USER LABEL PROCESSING         06900000
*                                                                       07000000
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        07100000
         USING *,RBASE                                                  07200000
         USING FORCORE,RCORE                                            07300000
         USING IHADCB,RDCB                                              07400000
         USING UCB,RUCB                                                 07500000
         USING IHADEB,RDEB                                              07600000
         USING TIOT,RTIOT                                               07700000
         USING WTG,RWTG                                                 07800000
*                                                                       07900000
         B     TCT06000(RET)            DETERMINE TYPE OF ENTRY TO MOD  08000000
TCT06000 EQU   *                                                        08100000
         B     TCT06200                 BR TO FINISH TRLR LABEL 2       08200000
         B     TCT07400                 BR TO PROCESS INPUT LABELS      08300000
         EJECT                                                          08400000
*********************************************************************** 08500000
*                                                                     * 08600000
*                          FUNCTION PROLOG                            * 08700000
*                                                                     * 08800000
*********************************************************************** 08900000
*                                                                     * 09000000
* FUNCTION NAME -                                                     * 09100000
*    'TCLOSE TAPE STANDARD TRAILER LABEL FUNCTION', PART II           * 09200000
*                                                                     * 09300000
* (STATUS) -                                                          * 09400000
*    NOT APPLICABLE                                                   * 09500000
*                                                                     * 09600000
         AIF   ('&LIB' NE 'LIB1').LIB22M0                               09650000
* FUNCTION -                                                          * 09700000
*    1. FINISH FORMATTING AND WRITE END-OF-FILE LABEL 2 (EOF2);       * 09800000
*    2. PROCESS OUTPUT OR DEFERRED INPUT USER LABELS AS REQUIRED;     * 09900000
*       A. OBTAINS A 168-BYTE USER LABEL WORK AREA IN MAIN STORAGE;   * 10000000
*       B. IF OUTPUT USER LABELS AREA TO BE PROCESSED, THE LABEL      * 10100000
*          IDENTIFIER IS FORMATTED IN A BUFFER AND CONTROL IS PASSED  * 10200000
*          TO THE USER VIA A 'SYNCH' MACRO (SVC 12). A LABEL IS THEN  * 10300000
*          WRITTEN IF THE USER PASSES A RETURN CODE OF '8'; THIS      * 10400000
*          CONTINUES UNTIL EITHER THE MAXIMUM NUNBER OF LABELS        * 10500000
*          (CURRENTLY 8) HAS BEEN WRITTEN  OR UNTIL THE USER          * 10600000
*          INDICATES THAT PROCESSING IS TO TERMINATE.                 * 10700000
*       C. IF DEFERRED INPUT USER LABELS ARE TO BE PROCESSED, A       * 10800000
*          LABEL IS READ AND CONTROL IS PASSED TO THE USER VIA A      * 10900000
*          'SYNCH' MACRO (SVC 12). ADDITIONAL LABELS AREA READ        * 11000000
*          IF THE USER PASSES A RETURN CODE OF '4'; THIS CONTINUES    * 11100000
*          UNTIL EITHER THE MAXIMUM NUMBER OF LABELS HAS BEEN READ OR * 11200000
*          UNTIL THE USER INDICATES THAT PROCESSING IS TO TERMINATE.  * 11300000
*       D. THE USER LABEL INTERFACE IS AS FOLLOWS-                    * 11400000
*          REGISTERS ARE INITIALIZED FOR THE USER AS FOLLOWS-         * 11500000
*             1    - ADDRESS OF A 4-WORD USER LABEL PARAMETER LIST;   * 11600000
*             2-13 - USER'S REGISTERS AT ENTRY TO TCLOSE;             * 11700000
*             15   - USER'S LABEL EXIT ROUTINE ADDRESS.               * 11800000
*          PARAMETER LIST CONTENTS-                                   * 11900000
*             WORD 1- ADDRESS OF THE USER LABEL BUFFER, OR '0' IF     * 12000000
*                     NO LABELS WERE READ (I.E., TAPE MARK WAS READ); * 12100000
*             WORD 2- ADDRESS OF THE DCB BEING PROCESSED; THE HIGH    * 12200000
*                     ORDER BIT OF THE FIRST BYTE IS ON IF THIS IS    * 12300000
*                     EOF AND IT IS OFF IF THIS IS EOV;               * 12400000
*             WORD 3- '0' IF NO ERRORS WERE ENCOUNTERED; OTHERWISE,   * 12500000
*                     THE ADDRESS OF THE IOB WHICH INCURRED THE ERROR,* 12600000
*                     WITH THE HIGH ORDER BIT OF THE FIRST BYTE ON;   * 12700000
*             WORD 4- '0';                                            * 12800000
*          CONTROL BLOCK INDICATORS-                                  * 12900000
*             'DCBOFLGS' - X'02', OFF - THE 'LOCK' BIT IS TURNED OFF  * 13000000
*                          WHEN CONTROL IS PASSED TO THE USER AND IS  * 13100000
*                          TURNED BACK ON UPON RETURN.                * 13200000
*          USER RETURN CODES (PASSED IN REGISTER 15)-                 * 13300000
*             0 - INPUT - CONTINUE PROCESSING INPUT USER LABELS;      * 13400000
*                 OUTPUT- DISCONTINUE PROCESSING OUTPUT USER LABELS;  * 13500000
*             4 - DISCONTINUE PROCESSING INPUT USER LABELS;           * 13600000
*             8 - CONTINUE PROCESSING OUTPUT USER LABELS.             * 13700000
*                                                                     * 13800000
.LIB22M0 ANOP                                                           13810000
         AIF   ('&LIB' EQ 'LIB1').LIB12M0                               13820000
* FUNCTION -                                                          * 13850000
*    1. FINISH FORMATTING AND WRITE END-OF-FILE LABEL 2 (EOF2);       * 13860000
*    2. PROCESS OUTPUT OR DEFERRED INPUT USER LABELS AS REQUIRED;     * 13870000
*       A. OBTAINS A 168-BYTE USER LABEL WORK AREA IN MAIN STORAGE;   * 13880000
*       B. IF OUTPUT USER LABELS AREA TO BE PROCESSED, THE LABEL      * 13890000
*          IDENTIFIER IS FORMATTED IN A BUFFER AND CONTROL IS PASSED  * 13892000
*          TO THE USER VIA A 'SYNCH' MACRO (SVC 12). A LABEL IS THEN  * 13894000
*          WRITTEN IF THE USER PASSES A RETURN CODE OF '8'; THIS      * 13896000
*          CONTINUES UNTIL EITHER THE MAXIMUM NUNBER OF LABELS        * 13898000
*          (CURRENTLY 8) HAS BEEN WRITTEN  OR UNTIL THE USER          * 13898400
*          INDICATES THAT PROCESSING IS TO TERMINATE.                 * 13898800
*       C. IF DEFERRED INPUT USER LABELS ARE TO BE PROCESSED, A       * 13899200
*          LABEL IS READ AND CONTROL IS PASSED TO THE USER VIA A      * 13899600
*          'SYNCH' MACRO (SVC 12). ADDITIONAL LABELS AREA READ        * 13899700
*          IF THE USER PASSES A RETURN CODE OF '4'; THIS CONTINUES    * 13899800
*          UNTIL EITHER THE MAXIMUM NUMBER OF LABELS HAS BEEN READ OR * 13899900
*          UNTIL THE USER INDICATES THAT PROCESSING IS TO TERMINATE.  * 13933200
*       D. THE USER LABEL INTERFACE IS AS FOLLOWS-                    * 13943200
*          REGISTERS ARE INITIALIZED FOR THE USER AS FOLLOWS-         * 13953200
*             1    - ADDRESS OF A 4-WORD USER LABEL PARAMETER LIST;   * 13963200
*             2-13 - USER'S REGISTERS AT ENTRY TO TCLOSE;             * 13965200
*             15   - USER'S LABEL EXIT ROUTINE ADDRESS.               * 13965600
*          PARAMETER LIST CONTENTS-                                   * 13966000
*             WORD 1- ADDRESS OF THE USER LABEL BUFFER, OR '0' IF     * 13966400
*                     NO LABELS WERE READ (I.E., TAPE MARK WAS READ); * 13966500
*             WORD 2- ADDRESS OF THE DCB BEING PROCESSED; THE HIGH    * 13966600
*                     ORDER BIT OF THE FIRST BYTE IS ON IF THIS IS    * 13977700
*                     EOF AND IT IS OFF IF THIS IS EOV;               * 13987700
*             WORD 3- '0' IF NO ERRORS WERE ENCOUNTERED; OTHERWISE,   * 13988100
*                     THE ADDRESS OF THE IOB WHICH INCURRED THE ERROR,* 13988500
*                     WITH THE HIGH ORDER BIT OF THE FIRST BYTE ON;   * 13988600
*             WORD 4- '0';                                            * 13988700
*          CONTROL BLOCK INDICATORS-                                  * 13988800
*             'DCBOFLGS' - X'02', OFF - THE 'LOCK' BIT IS TURNED OFF  * 13992500
*                          WHEN CONTROL IS PASSED TO THE USER AND IS  * 13994500
*                          TURNED BACK ON UPON RETURN.                * 13994900
*          USER RETURN CODES (PASSED IN REGISTER 15)-                 * 13995300
*             0 - INPUT - CONTINUE PROCESSING INPUT USER LABELS;      * 13995700
*                 OUTPUT- DISCONTINUE PROCESSING OUTPUT USER LABELS;  * 13996100
*             4 - DISCONTINUE PROCESSING INPUT USER LABELS;           * 13996200
*             8 - CONTINUE PROCESSING OUTPUT USER LABELS.             * 14022100
*    3. DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A DEB VALIDITY CHECK* 14024100
*       ROUTINE WHICH MAINTAINS AND UPDATES A TABLE OF VALID DEB      * 14026100
*       POINTERS IN PROTECTED CORE (LSQS).                            * 14028100
*                                                                     * 14032100
.LIB12M0 ANOP                                                           14042100
* ENTRY POINTS -                                                      * 14048200
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 14074100
*                                                                     * 14100000
* INPUT -                                                             * 14200000
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 14300000
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 14400000
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 14500000
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 14600000
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 14700000
*       'RPARC'- ADDRESS OF THE CURRENT TCLOSE PARAMETER LIST ENTRY;  * 14800000
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 14900000
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 15000000
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 15100000
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 15200000
*                                                                     * 15300000
* OUTPUT -                                                            * 15400000
*    1. AT EXIT TO MODULE IFG0232S-                                   * 15500000
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 15600000
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '4';      * 15700000
*       WORK AREA INDICATORS-                                    M0011* 15720021
*          'DXCCW7' - X'FF' - INDICATES THAT DEFERRED USER LABEL M0011* 15740021
*                             PROCESSING OCCURRED (REQUIRED BY   M0011* 15760021
*                             THE TAPE POSITIONING FUNCTION).    M0011* 15780021
*       TAPE POSITION-                                                * 15800000
*          OUTPUT- AT THE INTERBLOCK GAP FOLLOWING THE TRAILER LABELS;* 15900000
*          INPUT - IF DEFERRED USER LABEL PROCESSING HAS BEEN    M0011* 15950021
*                  PERFORMED, AT THE INTERBLOCK GAP FOLLOWING    M0011* 16000021
*                  THE LAST LABEL PROCESSED.                     M0011* 16050021
*                  IF EOF OCCURRED AND USER LABELS WERE NOT      M0011* 16100021
*                  PROCESSED, AT THE INTERBLOCK GAP FOLLOWING    M0011* 16150021
*                  THE TAPE MARK FOLLOWING THE TRAILER LABELS.   M0011* 16200021
*                  IF EOF DID NOT OCCUR, ANYWHERE IN DATA AREA.  M0011* 16250021
*    2. AT EXIT TO PROBLEM DETERMINATION MODULE IFG0230P-             * 16300000
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 16400000
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 16500000
*          ERROR CODES-                                               * 16600000
*          124- ERROR WRITING END-OF-FILE LABEL 2;                    * 16700000
*          141- ERROR BACKSPACING FOLLOWING USER TRAILER LABEL        * 16800000
*               PROCESSING.                                           * 16900000
*       WORK AREA INDICATORS-                                         * 17000000
*          'DXCALLID' - CONTAINS THE ID OF THIS MODULE.               * 17100000
*                                                                     * 17200000
* EXTERNAL REFERENCES -                                               * 17300000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 17400000
*                                                                     * 17500000
* EXITS, NORMAL -                                                     * 17600000
*         IFG0232S - TO DELIMIT AN OUTPUT DATA SET AND TO POSITION    * 17700000
*                    ACCORDING TO THE TCLOSE POSITIONING OPTION.      * 17800000
*                                                                     * 17900000
* EXITS, ERROR -                                                      * 18000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18100000
*                                                                     * 18200000
* TABLES/WORK AREAS -                                                 * 18300000
*    THE TCLOSE WORK AREA AND THE WHERE-TO-GO (WTG)                   * 18400000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 18500000
*                                                                     * 18600000
* ATTRIBUTES -                                                        * 18700000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18800000
*                                                                     * 18900000
* CHARACTER CODE DEPENDENCY -                                         * 19000000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 19100000
*                                                                     * 19200000
* NOTES -                                                             * 19300000
*                                                                     * 19400000
*********************************************************************** 19500000
*                                                                       19600000
*********************************************************************** 19700000
*              FINISH TRAILER LABEL 2                                 * 19800000
*********************************************************************** 19900000
*                                                                       20000000
TCT06200 EQU   *                                                        20100000
         SH    RTIOT,DCBTIOT            POINT TO BEGINNING OF TIOT      20200000
         MVC   FL2JOBD,TIOCNJOB         PLACE JOB/STEP IDENTIFICATION   20300000
         MVC   FL2STEPD,TIOCSTEP        ..FROM THE TIOT INTO THE LABEL  20400000
         MVI   FL2JSSP,SLASH            INSERT SLASH BETWEEN JOB AND    20500000
*                                       ..STEP NAMES                    20600000
*                                                                       20700000
*****          TAPE RECORDING TECHNIQUE                                 20800000
*                                                                       20900000
         SR    RC,RC                    CLEAR WORK REGISTER AND INSERT  21000000
         IC    RC,JFCTRTCH              ..JFCB TAPE RECORDING TECHNIQUE 21100000
         SRL   RC,K4                    SHIFT OUT HIGH ORDER CHAR OF    21200000
         STC   RC,FL2TRTCH              ..JFCTRTCH AND STORE IN LABEL   21300000
         TR    FL2TRTCH(K1),ATRTCH      TRANSLATE RECORDING TECHNIQUE   21400000
         CLI   JFCTRTCH,JFCTREV         IS THE RECORDING TECHNIQUE BOTH 21500000
*                                       ..TRANSLATION AND EVEN PARITY   21600000
         BNE   TCT06400                 ..BR IF NOT- 2ND CHAR IS BLANK  21700000
         MVI   FL2TRTCH+K1,CHART        ..ELSE SET 2ND CHAR TO 'T'      21800000
*                                                                       21900000
*****          CARRIAGE CONTROL CHARACTER SET                           22000000
*                                                                       22100000
TCT06400 EQU   *                                                        22200000
         TM    JFCRECFM,JFCMAC          DOES JFCB SPECIFY MACHINE CTRL- 22300000
         BNO   TCT06600                 ..BR IF NOT- CHK FOR 'ASA'      22400000
         MVI   FL2CNTRL,CHARM           ..ELSE SET MACHINE CTRL IN LBL  22500000
TCT06600 EQU   *                                                        22600000
         TM    JFCRECFM,JFCASA          DOES JFCB SPECIFY ASA CONTROL-  22700000
         BNO   TCT06800                 ..BR IF NOT- DO NOT SET CONTROL 22800000
         MVI   FL2CNTRL,CHARA           ..ELSE SET ASA CONTROL IN LABEL 22900000
TCT06800 EQU   *                                                        23000000
         TM    SRTESTAB,UCBBSTR         WERE ANSI LABELS SPECIFIED-     23100000
         BNO   TCT07000                 ..BR IF NOT TO WRITE LABEL      23200000
*                                                                       23300000
*****          BUFFER ALIGNMENT                                         23400000
*                                                                       23500000
         MVC   DXCCW5(K1),JFCBUFOF      GET BUFFER OFFSET LENGTH        23600000
         NI    DXCCW5,X'FF'-LASTNTRY    TURN OFF BIT 0                  23700000
         SR    RC,RC                    CLEAR WORK REGISTER             23800000
         IC    RC,DXCCW5                PLACE BUFFER LENGTH INTO REG    23900000
         CVD   RC,DXCCW5                ..AND CONVERT IT TO DECIMAL,    24000000
         UNPK  FL2BUFOF,DXCCW5          ..THEN UNPACK AND STORE IN LBL  24100000
         OI    FL2BUFOF+K1,ZONEOF       RESET SIGN BITS                 24200000
         MVC   FL1LABI,AEOF1            MOVE IN E-O-F CONSTANT          24300000
*                                                                       24400000
*****          TRANSLATE ANSI DATA BEFORE WRITING LABEL                 24500000
*                                                                       24600000
*        XLATE DXLBL,K80,TO=A           TRANSLATE LABEL DATA- MACRO     24700000
*                                       EXPANDED MANUALLY TO SAVE SPACE 24800000
         LA    R1,DXLBL                 LOAD ADDR OF TRANSLATE AREA     24900000
         LA    R0,K80                   LOAD LENGTH TO BE TRANSLATED    25000000
         O     R1,ANSICON2              INDICATE TRANSLATE TO ASCII     25100000
         SVC   103                      ISSUE TRANSLATE SVC             25200000
*                                                                       25300000
*****          WRITE END OF FILE LABEL 2                                25400000
*                                                                       25500000
TCT07000 EQU   *                                                        25600000
         LA    RD,TABD124               LOAD INTERNAL ERROR CODE        25700000
         BAL   RC,TCT12600              WRITE FILE LABEL 2              25800000
         BNO   TCT12800                 BR IF I/O ERROR                 25900000
         EJECT                                                          26000000
*********************************************************************** 26100000
*              DETERMINE IF USER LABELS ARE TO BE PROCESSED           * 26200000
*********************************************************************** 26300000
*                                                                       26400000
TCT07200 EQU   *                                                        26500000
         TM    JFCBTSDM,JFCSDS          IS DATA SET SYSOUT OR SYSIN-    26600000
         BO    TCT12400                 ..BR IF YES- BYPASS USER LABELS 26700000
         TM    JFCBLTYP,JFCBUL          WERE USER LABELS SPECIFIED-     26800000
         BNO   TCT12400                 ..BR IF NOT- BYPASS USER LABELS 26900000
         LA    RD,EXIT4                 PT TO OUTPUT USER TRLR LBL CODE 27000000
         B     TCT07600                 BR TO TEST FOR USER LABELS      27100000
TCT07400 EQU   *                                                        27200000
         LA    RD,SLPSUP                PT TO DEFERRED USER LABEL       27300000
*                                       ..PROCESSING CODE               27400000
TCT07600 EQU   *                                                        27500000
         L     RC,DCBEXLST              LOAD EXIT LIST ADDR FROM DCB    27600000
         LA    RC,K0(,RC)               ZERO EXIT LIST HIGH-ORDER BYTE  27700000
         LTR   RC,RC                    IS THERE A DCB EXIT LIST-       27800000
         BZ    TCT12400                 ..BR IF NOT                     27900000
TCT07800 EQU   *                                                        28000000
         CLC   K0(K1,RC),K0(RD)         DO CODE BYTES MATCH-            28100000
         BE    TCT08000                 ..BR IF YES- PROCESS USER LBLS  28200000
         CLC   K0(K1,RC),K1(RD)         IS 'LAST ENTRY' IND ALSO ON-    28300000
         BE    TCT08000                 ..BR IF YES- PROCESS USER LABEL 28400000
         TM    K0(RC),LASTNTRY          IS THIS LAST EXIT LIST ENTRY-   28500000
         LA    RC,K4(,RC)               POINT TO NEXT ENTRY             28600000
         BNO   TCT07800                 ..BR IF NOT- CHK NEXT ENTRY     28700000
         B     TCT12400                 ..ELSE BR TO POSITION TAPE      28800000
TCT08000 EQU   *                                                        28900000
         LR    RD,RDEB                  SAVE THE DEB ADDRESS            29000000
*                                                                       29100000
*****          RDEB WILL NOW BE USED AS A WORK REGISTER                 29200000
*****          RD WILL NOW BE USED AS THE DEB BASE REGISTER             29300000
*                                                                       29400000
         L     RDEB,K0(,RC)             LOAD EXIT LIST ENTRY            29500000
         CLC   K1(K3,RC),ANSICON2+K1    IS THE EXIT LIST ENTRY VALID-   29600000
         BE    TCT12400                 ..BR IF NOT- BYPASS USER LBLS   29700000
*                                                                       29800000
*********************************************************************** 29900000
*              USER TRAILER LABEL PROCESSING                          * 30000000
*********************************************************************** 30100000
*                                                                       30200000
         GETMAIN R,LV=USERL,SP=250      OBTAIN USER LABEL WORK AREA    C30300000
                                        ..MAIN STORAGE                  30400000
         USING ULWK,R1                                                  30500000
         STM   RPAR,RC,ULWK             SAVE REGS (INCLUDES DCB EXIT    30600000
*                                       ..LIST ENTRY)                   30700000
         DROP  R1                                                       30800000
         LR    RUCB,R1                  POINT TO USER LABEL WORK AREA   30900000
         USING ULWK,RUCB                ADDRESSABILITY FOR UL WORK AREA 31000000
         LA    R1,CHAR0                 INITIALIZE USER LABEL COUNT     31100000
         STH   R1,ULCNT                 ..AND SAVE FOR LATER USE        31200000
         MVI   ULBUFR,BLANK             INITLZ LABEL BUFFER AREA        31300000
         MVC   ULBUFR+K1(L'ULBUFR-K1),ULBUFR    TO BLANKS               31400000
*                                                                       31420021
*****    INITIALIZE CHANNEL PROGRAM FOR USER LABEL PROCESSING           31440021
*                                                                       31460021
         LA    R1,ULBUFR                LOAD USER LABEL BUFFER ADDRESS  31500000
         ST    R1,DXCCW1                ..AND STORE IN CHANNEL PROGRAM  31600000
         MVI   DXCCW1,CCWRDTAP          PLACE READ CMD INTO CCW  M0112  31620021
         MVI   DXCCW1+K4,K0             TURN OFF ALL CCW FLAGS   M0112  31640021
         MVI   DXCCW1+K7,ULPARM-ULBUFR  SET LENGTH TO BFR SIZE   M0112  31660021
         TM    ULREG11,XLDEFSL          WAS DEFERRED INPUT LBL PROCESS- 31700000
*                                       ..ING SPECIFIED (TEST REG 11)-  31800000
         BO    TCT09200                 ..BR IF YES                     31900000
*                                                                       32000000
*********************************************************************** 32100000
*              OUTPUT USER LABEL PROCESSING                           * 32200000
*********************************************************************** 32300000
*                                                                       32400000
TCT08200 EQU   *                                                        32500000
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  32600000
         BO    TCT08400                 ..BR IF YES- DO NOT COUNT       32700000
         LH    R1,ULCNT                 LOAD PREVIOUS COUNT AND         32800000
         LA    R1,K1(,R1)               ..INCREMENT BY 1                32900000
         STH   R1,ULCNT                 SAVE UPDATED COUNT              33000000
         CLI   ULCNT+K1,MAXNOLAB        HAS THE MAXIMUM NUMBER OF       33100000
*                                       ..USER LABELS BEEN PROCESSED-   33200000
         BH    TCT12200                 ..BR IF YES                     33300000
TCT08400 EQU   *                                                        33400000
         MVC   ULBUFR(K3),AUTL          INITIALIZE FIRST 4 CHAR OF BUFR 33500000
         MVC   ULBUFR+K3(K1),ULCNT+K1   ESTABLISH LABEL NUMBER IN BUFFR 33600000
         BAL   R7,TCT10200              BR TO SYNCH TO USER             33700000
         LTR   RF,RF                    SHOULD THE LABEL BE WRITTEN-    33800000
         BZ    TCT12200                 ..BRANCH IF NOT                 33900000
*                                                                       34000000
*****          INITIALIZE CHANNEL PROGRAM TO WRITE USER LABEL           34100000
*                                                                       34200000
         MVC   ULBUFR(K3),AUTL          PLACE 'UTL' INTO LABEL          34300000
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  34400000
         BO    TCT08600                 ..BRANCH IF YES                 34500000
         MVC   ULBUFR+K3(K1),ULCNT+K1   ..ELSE RETORE LBL NO. IN BUFFER 34600000
TCT08600 EQU   *                                                        34700000
         MVI   DXCCW1,CCWWRTAP          INITLZ CCW FOR WRITE COMMAND    34800000
         MVI   DXCCW1+K4,CCWSILI        SET 'SUPPRESS INCORRECT  M0112  34830021
*                                       ..LENGTH' INDICATOR             34860021
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  34900000
         BNO   TCT08800                 ..BR IF NOT- BYPASS TRANSLATE   35000000
*                                                                       35100000
*        XLATE ULBUFR,K80,TO=A          TRANSLATE LABEL DATA- MACRO     35200000
*                                       EXPANDED MANUALLY TO SAVE SPACE 35300000
         LA    R1,ULBUFR                LOAD ADDR OF TRANSLATE AREA     35400000
         LA    R0,K80                   LOAD LENGTH TO BE TRANSLATED    35500000
         O     R1,ANSICON2              INDICATE TRANSLATE TO ASCII     35600000
         SVC   103                      ISSUE TRANSLATE SVC             35700000
TCT08800 EQU   *                                                        35800000
         BAL   RC,TCT12600              BRANCH TO WRITE LABEL           35900000
         BNO   TCT09000                 BR IF I/O ERROR                 36000000
         CLI   ULRETCOD,WRITNEXT        SHOULD ADD'L LBLS BE PROCESSED- 36100000
         BE    TCT08200                 ..BR IF YES TO CONTINUE         36200000
         B     TCT12200                 ..ELSE PROCESSING IS COMPLETE   36300000
*                                                                       36400000
*****          ERROR WHEN ATTEMPTING TO WRITE LABEL.  SYNCH             36500000
*****          TO USER WITH ERROR INDICATIONS, THEN TERMINATE           36600000
*****          UL PROCESSING ( THE RETURN CODE IS NOT EXAMINED )        36700000
*                                                                       36800000
TCT09000 EQU   *                                                        36900000
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   37000000
         ST    R1,ULPARM+K8             ..IN PARAMETER LIST             37100000
         OI    ULPARM+K8,ERROR          FLAG THE ERROR                  37200000
         BAL   R7,TCT10400              BR TO SYNCH TO USER (BUFFER     37300000
*                                       CONTAINS LABEL UNABLE TO WRITE) 37400000
         B     TCT12200                 UL PROCESSING COMPLETED         37500000
*                                                                       37600000
*********************************************************************** 37700000
*              INPUT USER LABEL PROCESSING                            * 37800000
*********************************************************************** 37900000
*                                                                       38000000
TCT09200 EQU   *                                                        38100000
         MVI   DXCCW7,ALLBITS           IND DEFERRED USER LABEL  M0011  38130021
*                                       ..PROCESSING TOOK PLACE  M0011  38160021
TCT09400 EQU   *                                                        38500000
         BAL   RC,TCT12600              BR AND LINK TO READ A LABEL     38600000
         BNO   TCT11400                 BR IF ERROR             SA53865 38700001
         TM    IOBSTAT0,CSWUNITX        TEST FOR UNIT EXCEPTION SA53865 38800001
         BO    TCT11600                 ..BR IF YES- TAPE MARK READ     38900000
TCT09600 EQU   *                                                        39100000
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  39200000
         BNO   TCT09800                 ..BR IF NOT- BYPASS TRANSLATION 39300000
         XLATE ULBUFR,K80               TRANSLATE ANSI LABEL            39400000
TCT09800 EQU   *                                                        39500000
         CLC   ULBUFR(K3),AUHL          WAS A USER HEADER LABEL READ-   39600000
         BE    TCT10000                 ..BR IF YES                     39700000
         CLC   ULBUFR(K3),AUTL          WAS A USER TRAILER LABEL READ-  39800000
         BE    TCT10000                 ..BR IF YES                     39900000
*                                                                       40000000
*              NOTE - INPUT TRAILER LABEL PROCESSING LEAVES THE TAPE    40100000
*              POSITIONED BETWEEN THE FIRST AND SECOND DATA SET         40200000
*              TRAILER LABELS. THE FOLLOWING ALLOWS PROCESSING OF USER  40300000
*              LABELS EVEN THOUGH THE TAPE MAY CONTAIN MORE DATA SET    40400000
*              LABELS THAN CAN CURRENTLY BE CREATED UNDER O/S.          40500000
*                                                                       40600000
         CLC   ULBUFR(K3),EOVM          WAS AN EOV LABEL READ-          40700000
         BE    TCT09400                 ..BR IF YES- READ ANOTHER LABEL 40800000
         CLC   ULBUFR(K3),AEOF1         WAS AN EOF LABEL READ-          40900000
         BE    TCT09400                 ..BR IF YES- READ ANOTHER LABEL 41000000
         CLC   ULBUFR(K3),HDRM          WAS A HEADER LABEL READ-        41100000
         BE    TCT09400                 ..BR IF YES- READ ANOTHER LABEL 41200000
         MVI   DXCCW1,CCWBSR            INITLZ CCW FOR 'BSR' COMMAND    41300000
         B     TCT12000                 BR- AN 'UNKNOWN' LABEL WAS READ 41400000
TCT10000 EQU   *                                                        41500000
         MVC   ULCNT+K1(K1),ULBUFR+K3   SAVE LABEL NUMBER               41600000
         LA    R7,TCT11200              LOAD ADDR FOR RETURN FROM SYNCH 41700000
TCT10200 EQU   *                                                        41800000
         XC    ULPARM+K8(K4),ULPARM+K8  ZERO ERROR IND                  41900000
TCT10400 EQU   *                                                        42000000
         LA    R1,ULBUFR                POINT TO LABEL BUFFER           42100000
TCT10600 EQU   *                                                        42200000
         STM   R1,RDCB,ULPARM           STORE POINTERS TO LABEL BUFFER  42300000
*                                       ..AND DCB IN PARAMETER LIST     42400000
         XC    ULTOTPTR(K4),ULTOTPTR    ZERO USER TOTALING ENTRY        42500000
         MVI   ULDCBPTR,EOFFLG          SET FLAG TO INDICATE EOF M0112  42600021
         TM    DEBOPATB-DEB(RD),DEBOPOUT-DEBOPRBK   IS THE DCB OPENED   42800000
*                                       ..FOR OUTPUT OR 'RDBACK'-       42900000
         BZ    TCT10800                 ..BR IF YES- SKIP USER TOTALING 43000000
         TM    DCBOPTCD,DCBOPTT         WAS USER TOTALING SPECIFIED-    43100000
         BNO   TCT10800                 ..BR IF NOT- SKIP USER TOTALING 43200000
         L     RC,DEBSTRHH-DEB(RD)      LOAD USER TOTALING WK AREA ADDR 43300000
         USING TOTSAVWA,RC              ESTABLISH BASE ADDR FOR WK AREA 43400000
         MVC   ULTOTPTR(K4),TOTEOVPT    MOVE TOTALING PT TO PARM LIST   43500000
         DROP  RC                       DROP USER TOTALING BASE REG     43600000
TCT10800 EQU   *                                                        43700000
         LA    R1,ULPARM                PT TO USER LABEL PARAMETER LIST 43800000
         L     RF,ULREG11               PTR TO USER'S LABEL ROUTINE     43900000
         L     RC,CVTPTR                LOAD CVT ADDRESS                44000000
         USING CVT,RC                   ESTABLISH CVT ADDRESSABILITY    44100000
         L     RC,CVTTCBP               LD PT TO NEXT AND CURRENT TCBS  44200000
         L     RC,K4(,RC)               LOAD CURRENT TCB ADDRESS        44300000
         USING TCB,RC                   ESTABLISH TCB ADDRESSABILITY    44400000
         L     RC,TCBRBP                LOAD CURRENT SVRB ADDRESS       44500000
         USING RBSECT,RC                ESTABLISH SVRB ADDRESSABILITY   44600000
         STM   RDCB,RD,RBEXSAVE         SAVE TCLOSE REGS 2-13           44700000
         NI    DCBOFLGS,X'FF'-DCBOLOCK  IND USER EXIT TO BE TAKEN       44800000
TCT10900 EQU   *                                                        44900000
         L     RWTGC,RBLINK             PT TO THE PREVIOUS REQUEST BLK  45000000
         TM    RBSTAB-RBSECT(RWTGC),RBFTSVRB   IS IT THE USER'S 'PRB'-  45100000
         BZ    TCT11000                 ..BR IF YES- 'RC' POINTS TO THE 45200000
*                                       ..SVRB WITH THE USER'S REGS     45300000
         LR    RC,RWTGC                 PT TO SVRB WITH USER'S REGS     45400000
         B     TCT10900                 BR- REPEAT TEST FOR USER'S PRB  45500000
TCT11000 EQU   *                                                        45600000
         LM    RDCB,RD,RBGRS2           RESTORE USERS REGS 2-13         45700000
         SYNCH (15)                                                     45800000
         L     RC,CVTPTR                LOAD CVT ADDRESS                45900000
         USING CVT,RC                   ESTABLISH CVT ADDRESSABILITY    46000000
         L     RC,CVTTCBP               LD PT TO NEXT AND CURRENT TCBS  46100000
         L     RC,K4(,RC)               LOAD CURRENT TCB ADDRESS        46200000
         USING TCB,RC                   ESTABLISH TCB ADDRESSABILITY    46300000
         L     RC,TCBRBP                LOAD CURRENT SVRB ADDRESS       46400000
         USING RBSECT,RC                ESTABLISH SVRB ADDRESSABILITY   46500000
         LM    RDCB,RD,RBEXSAVE         RESTORE TCLOSE REGS 2-13        46600000
         OI    DCBOFLGS,DCBOLOCK        IND RETURN FROM USER EXIT       46700000
         DROP  RC                                                       46800000
         ST    RF,ULWK1                 SAVE USER'S RETURN CODE         46900000
         AIF   ('&LIB' EQ 'LIB1').LIB12M1                               46950000
         DEBCHK (RDCB)                  VERIFY DEB               Y01021 46960000
         ST    R1,DXPDEBAD              ESTABLISH DEB ADDRESS    Y01021 46970000
         L     RF,ULWK1                 RELOAD USER RETURN CODE  Y01021 46980000
.LIB12M1 ANOP                                                           46990000
         BR    R7                       RETURN TO CALLER OF SUBROUTINE  47000000
TCT11200 EQU   *                                                        47100000
         CH    RF,RDLBLCOD              SHOULD ANOTHER LABEL BE READ-   47200000
         BNE   TCT12200                 ..BR IF NOT- ALL DONE           47300000
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  47400000
         BO    TCT09400                 ..BR IF YES- READ ANOTHER LABEL 47500000
         CLI   ULCNT+K1,MAXNOLAB        HAS THE MAXIMUM NUMBER OF       47600000
*                                       ..LABELS BEEN PROCESSED-        47700000
         BNL   TCT12200                 ..BR IF YES- ALL DONE           47800000
         B     TCT09400                 ..ELSE BR TO READ ANOTHER LABEL 47900000
*                                                                       48000000
*****          ERROR ENCOUNTERED DURING READ                            48100000
*                                                                       48200000
TCT11400 EQU   *                                                        48300000
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   48400000
         ST    R1,ULPARM+K8             ..INTO PARAMETER LIST           48500000
         OI    ULPARM+K8,ERROR          FLAG THE ERROR                  48600000
         LH    R1,ULCNT                 LOAD THE CURRENT LABEL NO.,     48700000
         LA    R1,K1(,R1)               ..UPDATE IT BY ONE, THEN        48800000
         STH   R1,ULCNT                 ..SAVE THE UPDATED NUMBER       48900000
         STC   R1,ULBUFR+K3             SAVE THE NUMBER OF THE LABEL    49000000
*                                       ..WHICH COULD NOT BE READ       49100000
         LA    R7,TCT11200              LOAD ADDR FOR RETURN FROM SYNCH 49200000
         B     TCT10400                 BR TO SYNCH TO USER             49300000
*                                                                       49400000
*              A TAPE MARK HAS BEEN READ. IF USER HAS PREVIOUSLY        49500000
*              PROCESSED ANY LABELS,  REPOSITION TAPE, FREEMAIN,        49600000
*              AND RETURN TO CALLER. IF USER HAS NOT PREVIOUSLY         49700000
*              PROCESSED ANY LABELS, SYNCH TO USER WITH LABEL           49800000
*              BUFFER POINTER SET TO ZERO, THEN REPOSITION              49900000
*              TAPE, FREEMAIN, AND RETURN TO CALLER.                    50000000
*                                                                       50100000
TCT11600 EQU   *                                                        50200000
         CLI   ULCNT+K1,CHAR0           HAVE ANY LABELS BEEN PROCESSED- 50300000
         BH    TCT11800                 ..BRANCH IF YES                 50400000
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  50500000
         BO    TCT11800                 ..BRANCH IF YES                 50600000
         XC    ULPARM+K8(K4),ULPARM+K8  ZERO ERROR PARAMETER            50700000
         SR    R1,R1                    ZERO BUFFER POINTER             50800000
         BAL   R7,TCT10600              BR AND LINK TO SYNCH TO USER    50900000
TCT11800 EQU   *                                                        51000000
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND      51100000
TCT12000 EQU   *                                                        51200000
         LA    RD,TABD141               LOAD INTERNAL ERROR CODE        51300000
         MVC   DXCCW1+K4(K4),CHNCOUNT   CHAIN TO 'NOP', SET CT TO 1     51400000
         MVI   DXCCW2,CCWNOP            INITLZ SECOND CCW FOR NOP CMD   51500000
         MVC   DXCCW2+K4(K4),CHNCOUNT   INITLZ LNG FOR NOP TO 1         51600000
         MVI   DXCCW2+K4,CCWSILI        TURN ON 'SILI' INDICATOR ONLY   51700000
         BAL   RC,TCT12600              BRANCH TO PERFORM BACKSPACE     51800000
         BNO   TCT12800                 BR IF I/O ERROR                 51900000
TCT12200 EQU   *                                                        52000000
         LR    R1,RUCB                  POINT TO USER LABEL WORK AREA   52100000
         LM    RPAR,RC,ULWK             RESTORE TCLOSE REGISTER 5-12    52200000
         FREEMAIN R,LV=USERL,SP=250,A=(1)  RELEASE USER LABEL WORK     C52300000
                                        ..AREA MAIN STORAGE             52400000
         USING UCB,RUCB                 RE-ESTABLISH BASE REG FOR UCB   52500000
*                                                                       52600000
         EJECT                                                          52700000
*********************************************************************** 52800000
*              EXIT                                                   * 52900000
*********************************************************************** 53000000
*                                                                       53100000
TCT12400 EQU   *                                                        53200000
         AIF   ('&LIB' NE 'LIB1').LIB22M1                               53250000
         L     RDEB,DCBDEBAD            RESTORE THE DEB ADDRESS         53300000
.LIB22M1 ANOP                                                           53350000
         AIF   ('&LIB' EQ 'LIB1').LIB12M2                               53360000
         L     RDEB,DXPDEBAD            LOAD PROTECTED DEB ADDR  Y01021 53370000
.LIB12M2 ANOP                                                           53380000
         IECRES XCTL,MOD2M2S,K0         INVOKE IECRES MACRO TO 'XCTL'   53400000
         SPACE 3                                                        53500000
*********************************************************************** 53600000
*               SUBROUTINES                                           * 53700000
*********************************************************************** 53800000
*                                                                       53900000
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              54000000
*****          ENTRY TO THE SUBROUTINE IS VIA A 'BAL   RC,TCT12600'     54100000
*                                                                       54200000
TCT12600 EQU   *                                                        54300000
         EXCP  DXIOB                    INITIATE I/O OPERATION          54400000
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   54500000
         TM    IOBSTAT0,CSWUNITX        TEST FOR TAPE INDICATE  SA53865 54520001
         BCR   1,RC                     RETURN IF ON            SA53865 54540001
         TM    DXECB,ECBNOERR           TEST FOR SUCCESSFUL COMPLETION- 54600000
         BR    RC                       RETURN TO CALLER WITH           54700000
*                                       ..CONDITION CODE SET            54800000
         SPACE 2                                                        54900000
*********************************************************************** 55000000
*              ERROR PROCESSING                                       * 55100000
*********************************************************************** 55200000
*                                                                       55300000
TCT12800 EQU   *                                                        55400000
         DMABCOND (RD),ABEND2M          EXIT TO PROB DETERMINATION RTN  55500000
         EJECT                                                          55600000
         SPACE 1                                                        55700000
*********************************************************************** 55800000
*              CONSTANTS                                              * 55900000
*********************************************************************** 56000000
*                                                                       56100000
         DS    0F                       FW ALIGNMENT FOR 'ANSICON2'     56200000
ANSICON2 DC    X'80000000'              INDICATES 'TRANSLATE FROM       56300000
*                                       ..EBCDIC TO ASCII'              56400000
RDLBLCOD DC    H'4'                     RET CODE IND 'READ ANOTHER LBL' 56500000
CHNCOUNT DC    X'60000001'              CMD CHAIN, SILI BIT, LNG EQ 1   56600000
EOVM     DC    C'EOV'                   END-OF-VOLUME LABEL IDENTIFIER  56700000
AEOF1    DC    C'EOF'                   END-OF-FILE LABEL IDENTIFIER    56800000
HDRM     DC    C'HDR'                   HEADER LABEL IDENTIFIER         56900000
AUHL     DC    C'UHL'                   USER HEADER LABEL IDENTIFIER    57000000
AUTL     DC    C'UTL'                   USER TRAILER LABEL IDENTIFIER   57100000
ATRTCH   DC    C' CET'                  TRANSLATE TABLE FOR JFCB TAPE   57200000
*                                       ..RECORDING TECHNIQUE           57300000
EXIT4    DC    X'04'                    OUTPUT USER LABEL CODE BYTE     57400000
         DC    X'84'                    SAME AS ABOVE WITH 'LAST ENTRY' 57500000
*                                       ..INDICATOR                     57600000
SLPSUP   DC    X'0C'                    DEFERRED USER LABEL PROCESSING  57700000
*                                       ..CODE                          57800000
         DC    X'8C'                    SAME AS ABOVE WITH 'LAST ENTRY' 57900000
*                                       ..INDICATOR                     58000000
         SPACE 2                                                        58100000
*********************************************************************** 58200000
*              XCTL TABLE                                             * 58300000
*********************************************************************** 58400000
*                                                                       58500000
XCTLTB2M XCTLTABL ID=(ABEND2M,0P,MOD2M2S,2S),SVC=023                    58600000
         SPACE 2                                                        58700000
         IECDSECS CVT,                                                 C58800000
               TCB,                                                    C58900000
               RB,                                                     C59000000
               TIOT,                                                   C59100000
               DCB,                                                    C59200000
               DEB,                                                    C59300000
               UCB,                                                    C59400000
               MAIN,                                                   C59500000
               USERTOT,                                                C59600000
               UNITTAB,                                                C59700000
               USERLAB,                                                C59800000
               WTG,                                                    C59900000
               EXPAND=YES                                               60000000
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   60100000
         SPACE 2                                                        60200000
         END                                                            60300000
