         TITLE 'IFG0232S - CLOSE TAPE POSITIONING FUNCTION'             00200021
         COPY  LCGASMSW                                                 00250000
IFG0232S CSECT                                                          00800021
*                                                                       01000021
*********************************************************************** 01200021
*                                                                     * 01400021
*          VS1 RELEASE 2.6 DELETIONS                                    01450002
*0000                                                           XA01996 01500002
*                                                                     * 01600021
*          RELEASE 25 DELETIONS/CHANGES                               * 01800021
*          RELEASE 24 DELETIONS/CHANGES                               * 02000021
*          RELEASE 23 DELETIONS/CHANGES                               * 02200021
*          RELEASE 22 DELETIONS/CHANGES                               * 02400021
*          RELEASE 21 DELETIONS/CHANGES                               * 02600021
*0000550000                                                      M0011  02700021
*          RELEASE 21.7 DELETIONS/CHANGES                             * 02710001
*0000392000-394000,444000                                       SA53865 02750001
*0000412000                                                     SA57250 02750101
*                                                                     * 02800021
* STATUS CHANGE LEVEL 000                                             * 03000021
*                                                                     * 03200021
* FUNCTION -                                                          * 03400021
*    THIS MODULE CONTAINS THE 'TCLOSE TAPE POSITIONING FUNCTION'.     * 03600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG' FOR DETAILS.            * 03800021
*                                                                     * 04000021
* ENTRY POINTS -                                                      * 04200021
*         IFG0232S                                                    * 04400021
*                                                                     * 04600021
* INPUT -                                                             * 04800021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 05000021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 05200021
*    POINT PROCESSING IS TO BEGIN -                                   * 05400021
*       0 - NORMAL ENTRY TO EITHER WRITE A TAPE MARK TO DELIMIT       * 05600021
*           THE DATA SET AND THEN TO REPOSITION IT (OUTPUT) OR        * 05800021
*           JUST TO REPOSITION IT (INPUT).                            * 06000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG' FOR ADDITIONAL INPUT.   * 06200021
*                                                                     * 06400021
* OUTPUT -                                                            * 06600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 06800021
*                                                                     * 07000021
* EXTERNAL REFERENCES -                                               * 07200021
*         IFG023RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 07400021
*                    WAIT. REFER TO THE FOLLOWING 'FUNCTION PROLOG'.  * 07600021
*                                                                     * 07800021
* EXITS, NORMAL -                                                     * 08000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 08200021
*                                                                     * 08400021
* EXITS, ERROR -                                                      * 08600021
*         IFG0230P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 08800021
*                    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.        * 09000021
*                                                                     * 09200021
* TABLES/WORK AREAS -                                                 * 09400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 09600021
*                                                                     * 09800021
* ATTRIBUTES -                                                        * 10000021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 10200021
*                                                                     * 10400021
* CHARACTER CODE DEPENDENCY -                                         * 10600021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 10800021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 11000021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 11200021
*                                                                     * 11400021
* NOTES -                                                             * 11600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG'.                        * 11800021
*                                                                     * 12000021
*********************************************************************** 12200021
*                                                                       12400021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        12600021
         USING *,RBASE                                                  12800021
         USING FORCORE,RCORE                                            13000021
         USING IHADCB,RDCB                                              13200021
         USING UCB,RUCB                                                 13400021
         USING IHADEB,RDEB                                              13600021
         USING WTG,RWTG                                                 13800021
*                                                                       14000021
         B     TCT14000(RET)            DETERMINE TYPE OF ENTRY TO MOD  14200021
TCT14000 EQU   *                                                        14400021
         B     TCT14200                 BR TO COMPLETE TAPE PROCESSING  14600021
         EJECT                                                          14800021
         SPACE 1                                                        15000021
*********************************************************************** 15200021
*                                                                     * 15400021
*                          FUNCTION PROLOG                            * 15600021
*                                                                     * 15800021
*********************************************************************** 16000021
*                                                                     * 16200021
* FUNCTION NAME - 'TCLOSE TAPE POSITIONING FUNCTION'                  * 16400021
*                                                                     * 16600021
* (STATUS) -                                                          * 16800021
*    NOT APPLICABLE                                                   * 17000021
*                                                                     * 17200021
* FUNCTION -                                                          * 17400021
*    1. FOR OUTPUT DATA SETS, TWO TAPE MARKS ARE WRITTEN TO DELIMIT   * 17600021
*       THE DATA SET FOLLOWING THE DATA SET LABELS (STANDARD LABEL    * 17800021
*       TAPE) OR FOLLOWING THE DATA (NO-LABEL TAPE). IF A 'TAPE       * 18000021
*       INDICATE' (I.E., END-OF-TAPE) CONDITION IS DETECTED WHEN      * 18200021
*       THE FIRST TAPE MARK IS WRITTEN FOR A NO-LABEL TAPE DATA SET   * 18400021
*       WITH A POSITIONING OPTION OF 'LEAVE', THE FORCE END-OF-VOLUME * 18600021
*       (FEOV) MACRO IS ISSUED TO CONTINUE THE DATA SET ON ANOTHER    * 18800021
*       VOLUME, AND PROCESSING CONTINUES.                             * 19000021
*    2. THE DATA SET IS REPOSITIONED ACCORDING TO THE OPTION          * 19200021
*       SPECIFIED IN THE TCLOSE MACRO- IF 'LEAVE' WAS SPECIFIED,      * 19400021
*       THE DATA SET IS POSITIONED TO ITS 'LOGICAL END'; IF 'REREAD'  * 19600021
*       WAS SPECIFIED, TO ITS 'LOGICAL BEGINNING'.                    * 19800021
*       A. THE 'LOGICAL BEGINNING' OF A DATA SET OPENED FOR OUTPUT OR * 20000021
*          READ FORWARD IS THE INTERBLOCK GAP PRECEEDING THE FIRST    * 20200021
*          DATA RECORD; THE 'LOGICAL BEGINNING' OF A DATA SET OPENED  * 20400021
*          FOR 'RDBACK' IS THE INTERBLOCK GAP FOLLOWING THE LAST DATA * 20600021
*          RECORD.                                                    * 20800021
*       B. THE 'LOGICAL END' OF A DATA SET OPENED FOR OUTPUT OR READ  * 21000021
*          FORWARD IS THE INTERBLOCK GAP FOLLOWING THE LAST DATA      * 21200021
*          RECORD; THE 'LOGICAL END' OF A DATA SET OPENED FOR 'RDBACK'* 21400021
*          IS THE INTERBLOCK GAP PRECEEDING THE FIRST DATA RECORD.    * 21600021
*    3. THE BLOCK COUNT IN THE DCB IS UPDATED TO REFLECT THE POSITION * 21800021
*       OF THE TAPE. IF THE TAPE IS POSITIONED AT ITS PHYSICAL        * 22000021
*       BEGINNING, THE BLOCK COUNT IS SET TO ZERO. IF THE TAPE IS     * 22200021
*       POSITIONED AT ITS PHYSICAL END, THEN THE BLOCK COUNT CAN ONLY * 22400021
*       BE UPDATED FOR DATA SETS ON STANDARD LABEL TAPE. THIS IS      * 22600021
*       DONE BY READING TRAILER LABEL 1, CONVERTING THE BLOCK COUNT   * 22800021
*       THEREIN TO BINARY, AND STORING IT IN THE DCB.                 * 23000021
*                                                                     * 23200021
* ENTRY POINTS -                                                      * 23400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 23600021
*                                                                     * 23800021
* INPUT -                                                             * 24000021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 24200021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 24400021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 24600021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 24800021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 25000021
*       'RPARC'- ADDRESS OF THE CURRENT TCLOSE PARAMETER LIST ENTRY;  * 25200021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 25400021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 25600021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 25800021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 26000021
*    2. WORK AREA INDICATORS-                                    M0011* 26050021
*       'DXCCW7' - X'FF' - INDICATES THAT DEFERRED USER LABEL    M0011* 26100021
*                          PROCESSING OCCURRED.                  M0011* 26150021
*                                                                     * 26200021
* OUTPUT -                                                            * 26400021
*    1. AT EXIT TO MODULE IFG0232Z-                                   * 26600021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 26800021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '4';      * 27000021
*       CONTROL BLOCK FIELDS-                                         * 27200021
*          'DCBBLKCT' - UPDATED AS SPECIFIED IN (3) ABOVE;            * 27400021
*       TAPE POSITION- AS SPECIFIED IN (2) ABOVE.                     * 27600021
*    2. AT EXIT TO PROBLEM DETERMINATION MODULE IFG0230P-             * 27800021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 28000021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 28200021
*          ERROR CODES-                                               * 28400021
*          125- ERROR WRITING FIRST TAPE MARK FOLLOWING DATA SET;     * 28600021
*          126- ERROR WRITING SECOND TAPE MARK FOLLOWING DATA SET;    * 28800021
*          127- ERROR BACKSPACING PAST SECOND TAPE MARK;              * 29000021
*          128- ERROR BACKSPACING PAST FISRT TAPE MARK, WHICH         * 29200021
*               FOLLOWS THE DATA SET LABELS (STANDARD LABEL TAPE)     * 29400021
*               OR THE DATA (NO-LABEL TAPE);                          * 29600021
*          129- ERROR FORWARD SPACING PAST TAPE MARK PRECEEDING DATA; * 29800021
*          130- ERROR BACKSPACING PAST TAPE MARK PRECEDING DATA;      * 30000021
*          134- ERROR BACKSPACING PAST TRAILER LABELS;                * 30200021
*          135- ERROR FORARD SPACING PAST DATA;                       * 30400021
*          136- ERROR BACKSPACING PAST TAPE MARK FOLLOWING DATA;      * 30600021
*          137- ERROR REWINDING OR BACKSPACING PAST DATA;             * 30800021
*          138- ERROR READING TRAILER LABEL 1 IN ORDER TO UPDATE      * 31000021
*               THE BLOCK COUNT IN THE DCB;                           * 31200021
*          139- ERROR FORWARD SPACING PAST TAPE MARK PRECEEDING DATA. * 31400021
*                                                                     * 31600021
* EXTERNAL REFERENCES -                                               * 31800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 32000021
*                                                                     * 32200021
* EXITS, NORMAL -                                                     * 32400021
*         IFG0232Z- TO PERFORM TCLOSE FINAL PROCESSING.               * 32600021
*                                                                     * 32800021
* EXITS, ERROR -                                                      * 33000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 33200021
*                                                                     * 33400021
* TABLES/WORK AREAS -                                                 * 33600021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 33800021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 34000021
*                                                                     * 34200021
* ATTRIBUTES -                                                        * 34400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 34600021
*                                                                     * 34800021
* CHARACTER CODE DEPENDENCY -                                         * 35000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 35200021
*                                                                     * 35400021
* NOTES -                                                             * 35600021
*                                                                     * 35800021
*********************************************************************** 36000021
*                                                                       36200021
TCT14200 EQU   *                                                        36400021
         TM    DCBOFLGS,DCBOWRIT        WAS OUTPUT PERFORMED-           36600021
         BNO   TCT15200                 ..BR IF NOT TO POSITION TAPE    36800021
*                                                                       37000021
*****          WRITE TWO TAPE MARKS AND BACKSPACE OVER LAST             37200021
*****         ( FOR LABELED TAPE, TAPE MARKS FOLLOW LABELS )            37400021
*****         ( FOR UNLABELED TAPE, TAPE MARKS FOLLOW DATA )            37600021
*                                                                       37800021
TCT14400 EQU   *                                                        38000021
         MVC   DXCCW1,AWTMCCWM          INITLZ CCW TO WRITE TAPE MARK   38200021
         MVI   DXCCW1+K4,CCWCMDCH+CCWSILI  CHAIN A NOP, SET SILI BIT ON 38400021
         MVC   DXCCW2,AWTMCCWM          INITLZ SECOND CCW               38600021
         MVI   DXCCW2,CCWNOP            MAKE SECOND CCW A NOP           38800021
         LA    RD,TABD125               LOAD INTERNAL ERROR CODE        39000021
         BAL   RC,TCT20500              WRITE TAPE MARK AFTER   SA53865 39200001
*                                       TRAILER LABEL (SL) OR   SA53865 39400001
*                                       AFTER DATA (NL)         SA53865 39500001
         TM    IOBSTAT0,CSWUNITX        IS 'TAPE INDICATE' ON-          39600021
         BNO   TCT14800                 ..BR IF NOT TO CONTINUE         39800021
         TM    SRTESTAT,UCBDADI         IS THE TAPE LABELED-            40000021
         BO    TCT14800                 ..BR IF YES- THIS CONDITION     40200021
*                                       ..HAS BEEN TAKEN CARE OF FOR SL 40400021
         TM    DEBOFLGS,DEBOFRLS        IS THIS AN EMULATION TAPE-      40600021
         BO    TCT14800                 ..BRANCH IF YES                 40800021
         TM    PLISTOPT(RPARC),PLISTLV  WAS 'LEAVE' SPECIFIED-          41000021
         BM    TCT14800                 ..BR IF REREAD          SA57250 41250001
*                                                                       41400021
*****          ISSUE END-OF-VOLUME- USER HAS RUN OUT OF SPACE           41600021
*****          AND MAY WISH TO CONTINUE WRITING DATA                    41800021
*                                                                       42000021
TCT14600 EQU   *                                                        42200021
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BACKSPACE CMD    42400021
         LA    RD,TABD140               'TCLOSE' INTERNAL ERROR CODE    42600021
         BAL   RC,TCT20400              BACKSPACE PAST TAPE MARK        42800021
         LR    R1,RDCB                  LOAD ADDR OF DCB INTO FEOV      43000021
*                                       ..PARAMETER REGISTER            43200021
         SVC   31                       ISSUE FEOV TO OBTAIN NEXT VOL   43400021
         B     TCT14400                 BR TO PERFORM TRAILER LABEL     43600021
*                                       ..PROCESSING ON NEW VOLUME      43800021
TCT14800 EQU   *                                                        44000021
         LA    RD,TABD126               LOAD INTERNAL ERROR CODE        44200021
         BAL   RC,TCT20500              WRITE SECOND TAPE MARK  SA53865 44400001
TCT15000 EQU   *                                                        44600021
         MVC   DXCCW1,ABSFCCW           INITLZ CCW FOR BSF              44800021
         LA    RD,TABD127               LOAD INTERNAL ERROR CODE        45000021
         BAL   RC,TCT20400              BACKSPACE PAST LAST TM          45200021
         B     TCT16000                 BRANCH TO POSITION TAPE         45400021
TCT15200 EQU   *                                                        45600021
         TM    DEBOFLGS,DEBOFEOF        HAS AN EOF BEEN READ BY BSAM-   45800021
         L     RET,DCBIOBA              LOAD IOB ADDR                   46000021
         LA    RET,K0(,RET)             ZERO HIGH ORDER BYTE            46200021
         BNO   TCT15400                 ..BR IF EOF NOT READ            46400021
         NI    DCBIFLGS,X'FF'-DCBIFPIO  RESET ERROR INDICATION CAUSED   46600021
*                                       ..BY READING TAPE MARK          46800021
TCT15400 EQU   *                                                        47000021
         LR    RD,RET                   SAVE IOB ADDRESS                47200021
TCT15600 EQU   *                                                        47400021
         TM    K20(RD),K1               DOES THIS IOB INDICATE THAT     47600021
*                                       ..A TAPE MARK WAS READ-         47800021
         BNO   TCT15800                 ..BRANCH IF NOT                 48000021
         NI    K20(RD),X'FF'-K1         ..ELSE RESET IOB TAPE MARK IND  48200021
         OI    DCBOFLGS,DCBOEOF         TURN ON TAPE MARK IND IN DCB    48400021
TCT15800 EQU   *                                                        48600021
         L     RD,K0(,RD)               LOAD NEXT IOB ADDRESS           48800021
         LA    RD,K0(,RD)               ZERO HIGH ORDER BYTE            49000021
         CR    RD,RET                   IS THIS THE LAST IOB-           49200021
         BNE   TCT15600                 ..BRANCH IF NOT                 49400021
*                                                                       49600021
*********************************************************************** 49800021
*              TAPE POSITIONING                                       * 50000021
*********************************************************************** 50200021
*                                                                       50400021
TCT16000 EQU   *                                                        50600021
         MVC   DXCCW1,ABSFCCW           INITLZ CCW FOR POSITIONING      50800021
         TM    JFCBLTYP,JFCBAL+JFCSL    IS AL OR SL SPECIFIED-          51000021
         BZ    TCT16800                 ..BR IF NOT TO POS NL TAPE      51200021
*                                                                       51400021
*****          POSITIONING FOR LABELED TAPE                             51600021
*                                                                       51800021
*                        READ FORWARD (EODS) AND OUTPUT                 52000021
*                             LEAVE     BSF(2)                          52200021
*                             REREAD    BSF(3) + FSF                    52400021
*                        READ FORWARD (NOT EODS)                        52600021
*                             LEAVE     FSF + BSF                       52800021
*                             REREAD    BSF + FSF                       53000021
*                        READ BACKWARD (EODS)                           53200021
*                             LEAVE     FSF (IF NOT BOT) + FSF          53400021
*                             REREAD    FSF (IF NOT BOT) + FSF(2) + BSF 53600021
*                        READ BACKWARD (NOT EODS)                       53800021
*                             LEAVE     BSF + FSF                       54000021
*                             REREAD    FSF + BSF                       54200021
TCT16200 EQU   *                                                        54400021
         TM    DCBOFLGS,DCBORDBK        IS DCB OPENED FOR 'RDBACK'-     54600021
         BO    TCT16400                 ..BR IF YES TO CHK POSITIONING  54800021
         TM    DEBOFLGS,DEBOFEOF        WAS OUTPUT PERFORMED OR  M0011  54900021
*                                       ..EOF READ-              M0011  55000021
         BNO   TCT17800                 ..BR IF NOT- BALANCE OF POS     55200021
*                                       ..IS LIKE NO-LABEL TAPE         55400021
         TM    DXCCW7,ALLBITS           WAS THERE DEFERRED USER  M0011  55440021
*                                       ..LABEL PROCESSING       M0011  55480021
         BO    TCT17600                 ..BR IF YES- ALREADY     M0011  55520021
*                                       ..POSITIONED BEHIND TAPE M0011  55560021
         LA    RD,TABD128               LOAD INTERNAL ERROR CODE        55600021
         BAL   RC,TCT20400              BYPASS TAPE MARK FOLLOWING      55800021
*                                       ..TRAILER LABELS                56000021
         B     TCT17600                 BRANCH- BALANCE OF POSITIONING  56200021
*                                       ..IS LIKE NO-LABEL TAPE         56400021
*                                                                       56600021
*****          POSITIONING FOR LABELED READ-BACKWARD TAPE               56800021
*                                                                       57000021
TCT16400 EQU   *                                                        57200021
         TM    DEBOFLGS,DEBOFEOF        WAS AN EOF (OR BOT) READ-       57400021
         BO    TCT16600                 ..BR IF YES TO TEST FOR BOT     57600021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSION 'LEAVE'-           57800021
         BNM   TCT18200                 ..BR IF YES- POS TO BEGINNING   58000021
         B     TCT18000                 ..ELSE POSITION TO END OF DATA  58200021
TCT16600 EQU   *                                                        58400021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR FSF COMMAND      58600021
         LA    RD,TABD129               LOAD INTERNAL ERROR CODE        58800021
         BAL   RC,TCT20400              BYPASS TAPE MARK FOLLOWING HDRS 59000021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         59200021
         BNM   TCT19200                 ..BR IF YES- POS COMPLETE       59400021
         B     TCT18000                 ..ELSE BR TO POS AT END OF DATA 59600021
*                                                                       59800021
*****          POSITIONING FOR UNLABELED TAPE                           60000021
*                                                                       60200021
*                        READ FORWARD (EODS) AND OUTPUT                 60400021
*                             LEAVE     BSF                             60600021
*                             REREAD    BSF(2) + FSF (IF NOT AT BOT)    60800021
*                        READ FORWARD (NOT EODS)                        61000021
*                             LEAVE     FSF + BSF                       61200021
*                             READ      BSF + FSF (IF NOT AT BOT)       61400021
*                        READ BACKWARD (EODS)                           61600021
*                             LEAVE     FSF (IF NOT AT BOT)             61800021
*                             REREAD    FSF (IF NOT AT BOT) +FSF + BSF  62000021
*                        READ BACKWARD (NOT EODS)                       62200021
*                             LEAVE     BSF + FSF (IF NOT AT BOT)       62400021
*                             REREAD    FSF +BSF                        62600021
*                                                                       62800021
TCT16800 EQU   *                                                        63000021
         TM    DCBOFLGS,DCBORDBK        IS DCB OPENED FOR 'RDBACK'-     63200021
         BNO   TCT17400                 ..BRANCH IF NOT                 63400021
         TM    DEBOFLGS,DEBOFEOF        WAS AN END-OF-FILE READ-        63600021
         BNO   TCT17200                 ..BR IF NOT TO CHK DISPOSITION  63800021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR FSF COMMAND      64000021
         TM    DCBOFLGS,DCBOEOF         IS WAS A TAPE MARK READ-        64200021
         BNO   TCT17000                 ..BR IF NOT- TAPE IS AT         64400021
*                                       ..LOAD POINT                    64600021
         LA    RD,TABD130               LOAD INTERNAL ERROR CODE        64800021
         BAL   RC,TCT20400              BYPASS TAPE MARK PRECEDING DATA 65000021
TCT17000 EQU   *                                                        65200021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         65400021
         BNM   TCT19200                 ..BR IF YES- POS COMPLETE       65600021
         B     TCT18000                 ..ELSE BR TO POS AT END OF DATA 65800021
TCT17200 EQU   *                                                        66000021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         66200021
         BNM   TCT18200                 ..BR IF YES- POS AT BEGINNING   66400021
         B     TCT18000                 ..ELSE POSITION TO END OF DATA  66600021
*                                                                       66800021
*****          POSITIONING FOR UNLABELED READ-FORWARD/OUTPUT TAPE       67000021
*                                                                       67200021
TCT17400 EQU   *                                                        67400021
         TM    DEBOFLGS,DEBOFEOF        WAS AN EOF (OR BOT) READ-       67600021
         BNO   TCT17800                 ..BR IF NOT TO CHK DISPOSITION  67800021
TCT17600 EQU   *                                                        68000021
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND      68200021
         LA    RD,TABD134               LOAD INTERNAL ERROR CODE        68400021
         BAL   RC,TCT20400              BYPASS TAPE MARK FOLLOWING DATA 68600021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         68800021
         BNM   TCT19200                 ..BR IF YES- POS COMPLETE       69000021
         B     TCT18200                 ..ELSE POS TO BEGINNING OF DATA 69200021
TCT17800 EQU   *                                                        69400021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         69600021
         BM    TCT18200                 ..BR IF NOT TO POS AT BEGINNING 69800021
TCT18000 EQU   *                                                        70000021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR FSF COMMAND      70200021
         LA    RD,TABD135               LOAD INTERNAL ERROR CODE        70400021
         BAL   RC,TCT20400              FWD SPACE TO END OF DATA SET    70600021
         TM    JFCBLTYP,JFCBAL+JFCSL    IS AL OR SL SPECIFIED-          70800021
         BNZ   TCT18600                 ..BR IF YES TO UPDATE BLK CT    71000021
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND      71200021
         LA    RD,TABD136               LOAD INTERNAL ERROR CODE        71400021
         BAL   RC,TCT20400              BYPASS TAPE MARK FOLLOWING DATA 71600021
         B     TCT19200                 ..BR- POSITIONING IS COMPLETE   71800021
TCT18200 EQU   *                                                        72000021
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR BSF COMMAND      72200021
         CLC   SRTEFSCT(K2),ABSFCCW+K6  IS THE DESIRED DATA SET THE     72400021
*                                       ..THE FIRST ONE ON THE TAPE-    72600021
         BNE   TCT18400                 ..BR IF NOT TO BACKSPACE        72800021
         MVI   DXCCW1,CCWREW            ..YES- INITLZ FOR REWIND CMD    73000021
*                                       ..( FASTER THAN BACKSPACE )     73200021
TCT18400 EQU   *                                                        73400021
         LA    RD,TABD137               LOAD INTERNAL ERROR CODE        73600021
         BAL   RC,TCT20400              POS TAPE TO BEGINNING OF DATA   73800021
         B     TCT19200                 BR- NOW POS IN FRONT OF DATA    74000021
*                                                                       74200021
*****          SET UP BLOCK COUNT FROM TRAILER LABEL                    74400021
*                                                                       74600021
TCT18600 EQU   *                                                        74800021
         LA    RC,DXLBL                 PLACE ADDRESS OF LABEL BUFFER   75000021
         ST    RC,DXCCW1                ..INTO READ COMMAND OPERAND     75200021
         MVI   DXCCW1,CCWRDTAP          INITLZ CCW FOR READ COMMAND     75400021
         MVC   DXCCW1+K4(K4),ARDCCW     SET LNG EQ 80, NO FLAGS         75600021
         TM    SRTESTAB,UCBBSTR         WERE ANSI LABELS SPECIFIED-     75800021
         BNO   TCT18800                 ..BR IF NOT TO READ LABEL       76000021
         MVI   DXCCW1+K4,CCWSILI        TURN ON SILI BIT IN CCW         76200021
TCT18800 EQU   *                                                        76400021
         LA    RD,TABD138               LOAD INTERNAL ERROR CODE        76600021
         BAL   RC,TCT20400              READ FILE TRAILER LABEL 1       76800021
         TM    SRTESTAB,UCBBSTR         WERE ANSI LABELS SPECIFIED-     77000021
         BNO   TCT19000                 ..BR IF NOT- BYPASS TRANSLATION 77200021
*                                                                       77400021
*****          TRANSLATE ANSI LABEL DATA                                77600021
*                                                                       77800021
         XLATE DXLBL,K80                TRANSLATE FILE TRAILER LABEL 1  78000021
TCT19000 EQU   *                                                        78200021
         PACK  DXCCW5,FL1BLKCT          PACK THE LABEL BLOCK COUNT AND  78400021
         CVB   RC,DXCCW5                ..CONVERT IT TO BINARY, THEN    78600021
         ST    RC,DCBBLKCT              ..STORE IT IN THE DCB           78800021
         MVC   DXCCW1,ABSFCCW           INITLZ CCW FOR BSF COMMAND      79000021
         B     TCT18400                 BYPASS TAPE MARK FOLLOWING DATA 79200021
*                                                                       79400021
*                   SEE IF TAPE WAS LEFT AT FRONT OF DATA SET           79600021
*                        IF SO,IT IS NECESSARY TO DETERMINE IF          79800021
*                        THE TAPE IS AT BEGINNING OF TAPE SO            80000021
*                        THAT THE TAPE MAY BE LEFT IN FRONT OF          80200021
*                        THE FIRST DATA RECORD.                         80400021
*                             THIS IS DONE HERE RATHER THAN             80600021
*                        IMMEDIATELY FOLLOWING THE BSF TO               80800021
*                        GAIN CHANNEL OVERLAP IF TCLOSEING              81000021
*                        MULTIPLE DCBS.                                 81200021
*                                                                       81400021
TCT19200 EQU   *                                                        81600021
         TM    DCBOFLGS,DCBORDBK        IS DCB OPENED FOR 'RDBACK'-     81800021
         BNO   TCT19400                 ..BR IF NOT TO CHK FOR OUTPUT   82000021
         TM    DEBOFLGS,DEBOFEOF        WAS END-OF-FILE READ-           82200021
         BO    TCT20000                 ..BR IF YES- POS COMPLETE       82400021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         82600021
         BM    TCT20000                 ..BR IF NOT- POS COMPLETE       82800021
         B     TCT19600                 ..ELSE BR TO CHK FOR ADD'L POS  83000021
TCT19400 EQU   *                                                        83200021
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         83400021
         BNM   TCT20000                 ..BR IF YES- POS COMPLETE       83600021
TCT19600 EQU   *                                                        83800021
         XC    DCBBLKCT,DCBBLKCT        ZERO OUT BLOCK COUNT IN THE DCB 84000021
         TM    JFCBLTYP,JFCBAL+JFCSL    IS AL OR SL SPECIFIED-          84200021
         BNZ   TCT19800                 ..BRANCH IF EITHER ONE          84400021
         LA    RC,K1                    INITLZ REGISTER TO ONE          84600021
         LH    RF,SRTEFSCT              PICK UP FILE SEQ COUNT FROM UCB 84800021
         CR    RC,RF                    ARE WE AT FILE SEQUENCE ONE-    85000021
         BNE   TCT19800                 ..BR IF NO              XA01996 85200002
         TM    JFCBLTYP,JFCBLTM         IS LTM SPECIFIED        XA01996 85250002
         BZ    TCT20200                 BR IF NO- POS COMPLETE  XA01996 85300002
         LA    RC,DXLBL                 GET READ ADDRESS        XA01996 85350002
         ST    RC,DXCCW1                STORE IN CCW            XA01996 85360002
         MVI   DXCCW1,CCWRDTAP          MOVE IN READ OP         XA01996 85370002
         BAL   RC,TCT20500              GO READ A RECORD        XA01996 85380002
         TM    IOBSTAT0,CSWUNITX        WAS A TAPE MARK READ    XA01996 85390002
         BO    TCT20200                 BR IF YES- POS COMPLETE XA01996 85392002
         MVI   DXCCW1,CCWBSR            MOVE IN BSP RECORD      XA01996 85394002
         BAL   RC,TCT20500              GO EXECUTE BACKSPACE    XA01996 85396002
         B     TCT20200                 GO EXIT                 XA01996 85398002
TCT19800 EQU   *                                                        85400021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR FSF COMMAND      85600021
         LA    RD,TABD139               'TCLOSE' INTERNAL ERROR CODE    85800021
         BAL   RC,TCT20400              BYPASS TAPE MARK PRECEDING DATA 86000021
TCT20000 EQU   *                                                        86200021
         MVI   DXCCW1,CCWNOP            INITLZ CCW FOR NOP COMMAND      86400021
         BAL   RC,TCT20400              WAIT FOR ANY PENDING DEVICE END 86600021
         SPACE 3                                                        86800021
*********************************************************************** 87000021
*              EXIT                                                   * 87200021
*********************************************************************** 87400021
*                                                                       87600021
TCT20200 EQU   *                                                        87800021
         IECRES XCTL,MOD2S2Z,K4         INVOKE IECRES MACRO TO 'XCTL'   88000021
         SPACE 3                                                        88200021
*********************************************************************** 88400021
*              SUBROUTINES                                            * 88600021
*********************************************************************** 88800021
*                                                                       89000021
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              89200021
*                                                                       89400021
*        ENTRY TO THE ROUTINE IS VIA A 'BAL RC,TCT20400'                89600021
*                                                                       89800021
TCT20400 EQU   *                                                        90000021
         EXCP  DXIOB                    INITIATE I/O OPERATION          90200021
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   90400021
         B    TCT20550                  BR TO TEST COMPLETION   SA53865 90450001
TCT20500 EQU  *                                                 SA53865 90500001
         EXCP  DXIOB                    INITIATE I/O OPERATION  SA53865 90550001
         IECRES WAIT                    INVOKE MACRO TO 'WAIT'  SA53865 90560001
         TM    IOBSTAT0,CSWUNITX        TEST FOR TAPE INDICATE  SA53865 90570001
         BZ    TCT20550                 BRANCH IF NOT           SA53865 90590001
         MVI   DXECB,ECBCOD7F           INDICATE SUCCESSFUL     SA53865 90592001
*                                       COMPLETION FOR EOV      SA53865 90594001
         BR   RC                        RETURN TO CALLER        SA53865 90596001
TCT20550 EQU   *                                                SA53865 90598001
         TM    DXECB,ECBNOERR           TEST FOR SUCCESSFUL COMPLETION- 90600021
         BCR   1,RC                     ..BR IF YES- RETURN TO CALLER   90800021
         TM    IOBSENS1,UCBLDPT         IS THE TAPE AT LOAD POINT-      91000021
         BCR   1,RC                     ..BR IF YES- RETURN TO CALLER   91200021
*                                       ..ELSE DROP THRU TO ERROR RTN   91400021
         EJECT                                                          91600021
*********************************************************************** 91800021
*              ERROR PROCESSING                                       * 92000021
*********************************************************************** 92200021
*                                                                       92400021
TCT20600 EQU   *                                                        92600021
         DMABCOND (RD),ABEND2S          EXIT TO PROB DETERMINATION RTN  92800021
         SPACE 2                                                        93000021
*********************************************************************** 93200021
*              CONSTANTS                                              * 93400021
*********************************************************************** 93600021
*                                                                       93800021
AWTMCCWM CCW   X'1F',0,X'20',80         WR TAPE MARK COMMAND AND LENGTH 94000021
ABSFCCW  CCW   X'2F',0,X'20',1          BACKSPACE FILE, SILI FLAG ON    94200021
ARDCCW   DC    X'00000050'              NO FLAGS, LENGTH EQ 80 CHARACTE 94400021
         SPACE 2                                                        94600021
*********************************************************************** 94800021
*              XCTL TABLE                                             * 95000021
*********************************************************************** 95200021
*                                                                       95400021
XCTLTB2S XCTLTABL ID=(ABEND2S,0P,MOD2S2Z,2Z),SVC=023                    95600021
         SPACE 2                                                        95800021
         IECDSECS DCB,                                                 C96000021
               DEB,                                                    C96200021
               UCB,                                                    C96400021
               MAIN,                                                   C96600021
               WTG,                                                    C96800021
               EXPAND=YES                                               97000021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   97200021
         SPACE 2                                                        97400021
         END                                                            97600021
