         TITLE 'IFG0232Z - TCLOSE DIRECT ACCESS FUNCTION - CONTINUED'   00100000
         COPY  LCGASMSW                                                 00350000
IFG0232Z CSECT                                                          00400000
*                                                                       00500000
*********************************************************************** 00600000
*                                                                     * 00700000
*                                                                     * 00800000
*          RELEASE 25 DELETIONS/CHANGES                               * 00900000
*          RELEASE 24 DELETIONS/CHANGES                               * 01000000
*          RELEASE 23 DELETIONS/CHANGES                               * 01100000
*          RELEASE 22 DELETIONS/CHANGES                               * 01200000
*          RELEASE 21 DELETIONS/CHANGES                               * 01300000
*0000                                                            A38013 01320021
*                                                                M0039  01350021
*0000024000,030000,033000-036000,037000,490000-495000            A35953 01370021
*D485120-485280,486000                                          SA48558 01380021
*D445000                                                         S21940 01390021
*                                                                     * 01400000
* STATUS CHANGE LEVEL 000                                             * 01500000
*                                                                     * 01600000
* FUNCTION -                                                          * 01700000
*    THIS MODULE CONTAINS THE FOLLOWING FUNCTIONS -                   * 01800000
*       1. TCLOSE DIRECT ACCESS OUTPUT FUNCTION, PART II;             * 01900000
*       2. TCLOSE FINAL FUNCTION                                      * 02000000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR DETAILS.           * 02100000
*                                                                     * 02200000
* ENTRY POINTS -                                                      * 02300000
*         IFG0232Z - REFER TO 'INPUT' FOR A LIST OF CALLING MODULES   * 02360021
*                    AND THEIR RESPECTIVE ENTRY CONDITIONS.           * 02420021
*                                                                     * 02500000
* INPUT -                                                             * 02600000
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 02700000
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT        * 02800000
*    WHICH POINT PROCESSING IS TO BEGIN-                              * 02900000
*       0 - ENTRY FROM EITHER IFG0232D OR IFG0232J TO WRITE A FILE    * 02950021
*           MARK TO DELIMIT AN OUTPUT DATA SET ON A DIRECT ACCESS     * 03000021
*           DEVICE.                                                   * 03050021
*       4 - ENTRY FROM ANY OF THE FOLLOWING MODULES TO PERFORM        * 03100000
*           TCLOSE FINAL PROCESSING-                                  * 03200000
*           IGC0002C                                                  * 03270021
*           IFG0232D                                                  * 03340021
*           IFG0232J                                                  * 03410021
*           IFG0232S                                                  * 03480021
*           IFG0232Y (AN ALIAS FOR IFG0202B, THE CLOSE/TCLOSE NSL     * 03550021
*                    INTERFACE FUNCTION)                              * 03620021
*       8 - RETURN FROM IFG0239R FOLLOWING TERMINATION OF THE         * 03710021
*           OPTIONAL TRACE FACILITY.                                  * 03800000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR ADDITIONAL INPUTS. * 03900000
*                                                                     * 04000000
* OUTPUT -                                                            * 04100000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 04200000
*                                                                     * 04300000
* EXTERNAL REFERENCES -                                               * 04400000
*         IFG023RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL, WAIT,  * 04500000
*                    AND SYNCH. REFER TO THE FOLLOWING 'FUNCTION      * 04600000
*                    PROLOGS'.                                        * 04700000
*                                                                     * 04800000
* EXITS, NORMAL -                                                     * 04900000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 05000000
*                                                                     * 05100000
* EXITS, ERROR -                                                      * 05200000
*         IFG0230P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 05300000
*                    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.       * 05400000
*                                                                     * 05500000
* TABLES/WORK AREAS -                                                 * 05600000
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 05700000
*                                                                     * 05800000
* ATTRIBUTES -                                                        * 05900000
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 06000000
*                                                                     * 06100000
* CHARACTER CODE DEPENDENCY -                                         * 06200000
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 06300000
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 06400000
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 06500000
*                                                                     * 06600000
* NOTES -                                                             * 06700000
*    THIS MODULE HAS AN ALIAS NAME OF IFG0202U.                       * 06750021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 06800000
*                                                                     * 06900000
*********************************************************************** 07000000
*                                                                       07100000
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        07200000
         USING *,RBASE                                                  07300000
         USING FORCORE,RCORE                                            07400000
         USING CVT,RET                                                  07500000
         USING IHADCB,RDCB                                              07600000
         USING DEB,RDEB                                                 07700000
         USING TIOT,RTIOT                                               07800000
         USING WTG,RWTG                                                 07900000
         USING UCB,RUCB                                                 08000000
*                                                                       08100000
         B     BRTABLE5(RET)            DETERMINE TYPE OF ENTRY TO RTN  08200000
BRTABLE5 EQU   *                                                        08300000
         B     TCD01700             (0) BR TO FINISH DA PROCESSING      08400000
         B     TCM50000             (4) BR TO PERFORM TCLOSE CLEANUP    08500000
         B     TCM52000             (8) BR IF RET FROM TRACE RTN        08600000
         EJECT                                                          08700000
         SPACE 1                                                        08800000
*********************************************************************** 08900000
*                                                                     * 09000000
*                          FUNCTION PROLOG                            * 09100000
*                                                                     * 09200000
*********************************************************************** 09300000
*                                                                     * 09400000
* FUNCTION - 'TCLOSE DIRECT ACCESS OUTPUT FUNCTION', PART II          * 09500000
*                                                                     * 09600000
* (STATUS) -                                                          * 09700000
*    NOT APPLICABLE                                                   * 09800000
*                                                                     * 09900000
* FUNCTION -                                                          * 10000000
*    1.  WRITE FILE MARK FOLLOWING USER'S DATE;                       * 10100000
*    2.  POSITION THE VOLUME, EITHER BEFORE THE FIRST RECORD          * 10200000
*        (REREAD), OR AFTER THE LAST RECORD (LEAVE).                  * 10300000
*                                                                     * 10400000
* ENTRY POINTS -                                                      * 10500000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 10600000
*                                                                     * 10700000
* INPUT -                                                             * 10800000
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 10900000
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 11000000
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 11100000
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 11200000
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 11300000
*       'RPARC'- ADDRESS OF THE CURRENT TCLOSE PARAMETER LIST ENTRY;  * 11400000
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 11500000
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 11600000
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 11700000
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 11800000
*                                                                     * 11900000
* OUTPUT -                                                            * 12000000
*    1. AT EXIT TO THE TCLOSE FINAL FUNCTION, OUTPUT IS VIRTUALLY THE * 12100000
*       SAME AS AT INPUT TO THIS FUNCTION;                            * 12200000
*    2. AT EXIT TO PROBLEM DETERMINATION MODULE IFG0230P-             * 12300000
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 12400000
*          REGISTER 'R0' CONTAINS THE INTERNAL ERROR CODE '131;       * 12500000
*       WORK AREA INDICATORS-                                         * 12600000
*          'DXCALLID' - CONTAINS THE ID OF THIS MODULE.               * 12700000
*                                                                     * 12800000
* EXTERNAL REFERENCES -                                               * 12900000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 13000000
*                                                                     * 13100000
* EXITS, NORMAL -                                                     * 13200000
*    1. TO PART II OF THIS MODULE- THE 'TCLOSE FINAL FUNCTION'.       * 13300000
*                                                                     * 13400000
* EXITS, ERROR -                                                      * 13500000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 13600000
*                                                                     * 13700000
* TABLES/WORK AREAS -                                                 * 13800000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 13900000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 14000000
*                                                                     * 14100000
* ATTRIBUTES -                                                        * 14200000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 14300000
*                                                                     * 14400000
* CHARACTER CODE DEPENDENCY -                                         * 14500000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 14600000
*                                                                     * 14700000
* NOTES -                                                             * 14800000
*                                                                     * 14900000
*********************************************************************** 15000000
*                                                                       15100000
TCD01700 EQU   *                                                        15200000
         L     RDEB,DCBDEBAD            RESTORE USER'S DEB ADDR         15300000
*                                                                       15400000
*****    WRITE FILE MARK FOLLOWING USER'S DATA RECORDS                  15500000
*                                                                       15600000
         SR    RC,RC                    CLEAR WORK REGISTER             15700000
         IC    RC,DCBFDAD               PICK UP M (CURRENT EXTENT NUMBE 15800000
         SLL   RC,K4                    MULTIPLY BY 16 TO POINT TO EXTE 15900000
         LR    RD,RDEB                  SAVE DEB ADDRESS                16000000
         AR    RDEB,RC                  NOW POINTING TO PROPER EXTENT   16100000
         MVC   DXDEBBIN(K12),DEBBINUM   PLACE USER'S EXTENT IN WORK ARE 16200000
         MVC   DXCCW4+K1(K8),DCBFDAD    MOVE MBBCCHHR TO WORK AREA      16300000
         MVI   DXDEBUCB,X'C0'           SET MODIFIER BYTE TO ALLOW WRIT 16400000
         L     R1,DCBDVTBL              ADDRESS OF DEVICE TABLE         16500000
         LH    RF,K4(R1)                PICK UP NR OF BYTES PER TRACK   16600000
         CH    RF,DCBTRBAL              IS FULL TRCK AVAILABLE FOR FM   16700000
         BE    TCD02300                 BR IF FULL TRCK AVAILABLE       16800000
         TM    DCBRECFM,DCBRECFX+DCBRECST IS THE USER WRITING F STD     16900000
         BNO   TCD01800                 NO,DO NOT WRITE F.M. ON THIS    17000000
*                                       TRACK                           17100000
         SR    RC,RC                    INITIALIZE REGISTER             17200000
         IC    RC,DEBNMEXT-DEB(RD)      PICK UP NO. OF EXTENTS          17300000
         SLL   RC,K4                    MULTIPLY BY 16                  17400000
         AR    RC,RD                    ADD DEB ADDRESS                 17500000
         LH    RF,K44(RC)               ADD KEYLENGTH+BLOCKSIZE         17600000
         CH    RF,DCBTRBAL              WILL A RECORD FIT ON THIS TRACK 17700000
         BH    TCD01800                 NO,DO NOT ATTEMPT WRITE THIS TR 17800000
         BAL   RD,TCD02900              YES,GO SET UP CHANNEL PROGRAM   17900000
         IC    RF,DXCCW4+K8             ADD 1 TO LAST RECORD NUMBER     18000000
         LA    RF,K1(,RF)               WRITTEN BY THE PROBLEM PROGRAM  18100000
         STC   RF,DXDSCB+K4             STORE UPDATED RECORD NUMBER     18200000
         BAL   RD,TCD03000              GO TO WRITE THE FILE MARK       18300000
TCD01800 EQU   *                                                        18400000
         STM   RWTGC,RDEB,DXCCW5+K4     SAVE VOLATILE REGS              18500000
         LR    RWTGC,RDCB               ESTABLISH DCB BASE              18600000
         DROP  RDCB                                                     18700000
         USING IHADCB,RWTGC                                             18800000
         LA    RDCB,DXCCW4+K1           ADDR OF MBBCCHHR WORK           18900000
*                                       AREA FOR CONVERT RTNS           19000000
         L     R1,DCBDEBAD              ESTABLISH DEB BASE              19100000
         DROP  RDEB                                                     19200000
         USING IHADEB,R1                                                19300000
         L     RF,CVTPTR                                                19400000
         L     RF,CVTPRLTV-CVT(RF)      MBBCCHHR TO TTR ADDRESS         19500000
         BALR  RET,RF                   TTR0 IN REG 0                   19600000
         AL    R0,CON10000              BUMP IT BY ONE                  19700000
         ST    R0,DXCCW7+K4             SAVE TT+1,R                     19800000
         L     RF,CVTPTR                                                19900000
         L     RF,CVTPCNVT-CVT(RF)      TTR TO MBBCCHHR ADDRESS         20000000
         BALR  RET,RF                   MBBCCHHR IN DXCCW4+1            20100000
         LTR   RF,RF                    IS ANOTHER TRK AVAILABLE        20200000
         LA    RF,TCD02500              BRANCH IF NO - DO NOT           20300000
         BNZ   TCD02200                 WRITE FILE MARK                 20400000
         CLI   DXCCW4+K1,K0             IS EXTENT NUMBER 0              20500000
*                                       SPLIT ALLOCATION ALLOWED        20600000
*                                       ON FIRST EXTENT ONLY            20700000
         BE    TCD01900                 YES - GO CHECK IF SPLIT         20800000
         SR    RF,RF                    CLEAR WORK REGISTER             20900000
         IC    RF,DXCCW4+K1             PICK UP CURRENT EXT NBR         21000000
         SLL   RF,K4                    MULTIPLY BY 16                  21100000
         AR    RF,R1                    ADD DEB ADDRESS                 21200000
         MVC   DXDEBUCB+K1(K15),K33(RF)    PUT USER EXTENT IN WORK AREA 21300000
         B     TCD02100                 GO WRITE FILE MARK              21400000
TCD01900 EQU   *                                                        21500000
         TM    DEBOFLGS,DEBOFSPL        ARE THERE SPLIT CYLINDER        21600000
         BNO   TCD02100                 BR IF NO SPLIT CYLINDERS        21700000
         SR    RC,RC                    START H                         21800000
         SR    RD,RD                    END H                           21900000
         SR    RF,RF                    NEW H IN FDAD                   22000000
         SR    RUCB,RUCB                EXTENT OFFSET                   22100000
         IC    RUCB,DXCCW4+K1           GET NEW M                       22200000
         SLL   RUCB,K4                  TIMES 16 FOR INDEXING           22300000
         IC    RF,DXCCW4+K7             SECOND H OF NEW HH              22400000
         IC    RC,DEBSTRHH+K1(RUCB)     START H                         22500000
         IC    RD,DEBENDHH+K1(RUCB)     END H                           22600000
*                                                                       22700000
*****    TEST IF CURRENT ADDRESS WITHIN SPLIT                           22800000
*                                                                       22900000
         CR    RF,RC                    IS NEW H BELOW START H          23000000
         BL    TCD02000                 BRANCH IF YES - NEED TO         23100000
*                                       GET NEW MBBCCHHR                23200000
         CR    RF,RD                    IS NEW H ABOVE END H            23300000
         BNH   TCD02100                 BR IF NO -  H IS GOOD           23400000
*                                                                       23500000
*****    NEW H OUTSIDE DEB EXTENTS - NEED TO GET NEW MBBCCHHR           23600000
*                                                                       23700000
TCD02000 EQU   *                                                        23800000
         SR    RD,RC                    NO OF TRACKS -1 IN SPLIT        23900000
         L     RUCB,DCBDVTBL            ADDR OF DEVICE TABLE            24000000
         USING UNITABLE,RUCB                                            24100000
         IC    RC,UNITSIHH+K1           GET NO. OF TRACKS               24200000
         DROP  RUCB                                                     24300000
         SR    RC,RD                    SUBTRACT NO TRACKS IN           24400000
*                                     SPLIT - 1 FROM NO OF              24500000
*                                       TRACKS IN CYLINDER              24600000
         BCTR  RC,0                     SUBTRACT ONE MORE - THIS        24700000
*                                       IS CORRECT TRACK                24800000
*                                       DISPLACEMENT TO ADD             24900000
*                                       TO OLD TT+1,R                   25000000
         SLL   RC,K16                   SHIFT TO ADD                    25100000
         AL    RC,DXCCW7+K4             ADD TT+1,R                      25200000
         LR    R0,RC                    PUT IN RE FOR CONVERSION        25300000
         L     RF,CVTPTR                                                25400000
         L     RF,CVTPCNVT-CVT(RF)      TTR TO MBBCCHHR ADDR            25500000
         BALR  RET,RF                   MBBCCHHR IN DXCCW4+1            25600000
         LTR   RF,RF                    NEW TRACK AVAILABLE             25700000
         LA    RF,TCD02500                                              25800000
         BNZ   TCD02200                 BR IF NO - NO FILE MARK         25900000
TCD02100 EQU   *                                                        26000000
         LA    RF,TCD02400              WRITE FILE MARK                 26100000
TCD02200 EQU   *                                                        26200000
         LR    RDCB,RWTGC               RESTORE DCB BASE                26300000
         DROP  RWTGC                                                    26400000
         USING IHADCB,RDCB                                              26500000
         LM    RWTGC,RDEB,DXCCW5+K4     RESTORE VOLATILE REGS           26600000
         DROP  R1                                                       26700000
         USING IHADEB,RDEB                                              26800000
         MVI   DXCCW4+K8,K0             ZERO R TO SEARCH ON TO          26900000
*                                       WRITE ON NEW TRACK              27000000
         BR    RF                       RETURN                          27100000
TCD02300 EQU   *                                                        27200000
         CLC   DXCCW4+K4(K4),DEBENDCC   IS CCHH IN THIS EXTENT          27300000
         BH    TCD01800                 NO,GO SEE IF ANOTHER            27400000
*                                       EXTENT                          27500000
TCD02400 EQU   *                                                        27600000
         BAL   RD,TCD02900              YES,GO TO SET UP CHANNEL PROG   27700000
         MVI   DXDSCB+K4,K1             SET RECORD NUMBER OF FILE MARK  27800000
         BAL   RD,TCD03000              GO TO WRITE THE FILE MARK       27900000
*                                                                       28000000
*****    SET CURRENT POSITION POINTER IN THE DCB                        28100000
*                                                                       28200000
TCD02500 EQU   *                                                        28300000
         L     RDEB,DCBDEBAD            RESTORE ADDRESS OF USER'S DEB   28400000
         TM    PLISTOPT(RPARC),PLISTLV  IS DISPOSITION 'LEAVE'-         28500000
         BNM   TCD02600                 ..BR IF YES- DCBFDAD IS CORRECT 28600000
         MVC   DCBFDAD+K1(K6),DEBBINUM  SET BBCCHH TO BEGINNING OF EXTE 28700000
         MVI   DCBFDAD,K0               SET M EQUAL TO ZERO             28800000
         MVI   DCBFDAD+K7,K0            SET RECORD NUMBER TO ZERO       28900000
         L     RC,DCBDVTBL              PICK UP BASE OF DEVICE TABLE    29000000
         MVC   DCBTRBAL,K4(RC)          SET NUM OF BYTES REMAING TO MAX 29100000
*                                                                       29200000
*****    UPDATE FULL DISK ADDRESS IN BSAM IOB                           29300000
*                                                                       29400000
TCD02600 EQU   *                                                        29500000
         L     RD,DCBIOBA               PICK UP ADDRESS OF PREVIOUS IOB 29600000
         LA    RD,K0(,RD)               CLEAR HIGH BYTE (FOR COMPARE)   29700000
         LR    R0,RD                                                    29800000
         SR    RC,RC                                                    29900000
         LR    R1,RD                    COPY ICB/IOB ADDRESS            30000000
         TM    DCBCIND2,DCBC2CHN        IS PCI USED                     30100000
         BO    TCD02700                 YES  BRANCH                     30200000
         LA    R1,K8(RD)                ADJUST IOB FOR NORMAL SCHED.    30300000
         LA    RC,K8                                                    30400000
TCD02700 EQU   *                                                        30500000
         MVC   K32(K8,R1),DCBFDAD       UPDATE 1ST ICB/IOB              30600000
TCD02800 EQU   *                                                        30700000
         L     RD,K0(,RD)               ADDRESS OF NEXT IOB IN CHAIN    30800000
         LA    RD,K0(,RD)               CLEAR HI BYTE                   30900000
         LA    R1,K0(RC,RD)             FORM THE IOB OR ICB ADDRESS     31000000
         MVC   K32(K8,R1),DCBFDAD       UPDATE IOB/ICB  FDAD            31100000
         CR    RD,R0                    IS THIS LAST IOB IN CHAIN       31200000
         BNE   TCD02800                 ..BRANCH IF NOT                 31300000
*                                       ..ELSE DROP THROUGH TO TCLOSE   31400000
*                                       ..FINAL FUNCTION                31500000
         TITLE 'IFG0232Z - TCLOSE FINAL FUNCTION'                       31600000
*********************************************************************** 31700000
*                                                                     * 31800000
*                          FUNCTION PROLOG                            * 31900000
*                                                                     * 32000000
*********************************************************************** 32100000
*                                                                     * 32200000
* FUNCTION NAME - 'TCLOSE FINAL FUNCTION'                             * 32300000
*                                                                     * 32400000
* (STATUS) -                                                          * 32500000
*    NOT APPLICABLE                                                   * 32600000
*                                                                     * 32700000
* FUNCTION -                                                          * 32800000
*    1. SYNCHRONIZE PROCESSING OF ALL DATA CONTROL BLOCKS TO THE      * 32900000
*       BEGINNING OF THIS FUNCTION;                                   * 33000000
*    2. ISSUE A 'DELAYED ABEND' UTILIZING THE ABEND CODE PROVIDED     * 33100000
*       BY THE PROBLEM DETERMINATION ROUTINE IF THAT WAS REQUESTED    * 33200000
*       BY THE USER IN HIS ABEND EXIT ROUTINE;                        * 33300000
*    3. TERMINATE THE OPTIONAL TRACE FACILITY (GTF) IF IT IS ACTIVE;  * 33400000
*    4. RELEASE THE RESIDENT ROUTINE MAIN STORAGE WORK AREA.          * 33500000
*    5. RELEASE THE TCLOSE MAIN STORAGE WORK AREA FOR EACH DCB.       * 33600000
*    6. RESET VARIOUS DATA SET STATUS INDICATORS IN THE DCB AND DEB   * 33700000
*       IN ORDER THAT PROCESSING MAY CONTINUE.                        * 33800000
*    7. RELEASE THE WHERE-TO-GO (WTG) TABLE MAIN STORAGE WORK AREA.   * 33900000
*    8. RETURN TO THE USER VIA THE 'EXIT' SVC.                        * 34000000
*                                                                     * 34100000
* ENTRY POINTS -                                                      * 34200000
*    REFER TO THE PRECEEDING 'MODULE PROLOG'.                         * 34300000
*                                                                     * 34400000
* INPUT -                                                             * 34500000
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 34600000
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 34700000
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 34800000
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 34900000
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 35000000
*       'RPARC'- ADDRESS OF THE CURRENT TCLOSE PARAMETER LIST ENTRY;  * 35100000
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 35200000
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 35300000
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 35400000
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 35500000
*    2. WORK AREA CONTENTS ARE AS FOLLOWS-                            * 35600000
*       'WTGPATHS+1' X'80' - THE OPTIONAL TRACE FACILTY IS ACTIVE     * 35700000
*                            AND SHOULD BE TERMINATED PRIOR TO EXIT;  * 35800000
*       'DCBOFLGS' - X'01', OFF - THE COMBINATION OF THESE TWO CONDI- * 35900000
*       'JFCBMASK+4' - X'02'    - TIONS INDICATES THAT A DELAYED      * 36000000
*                                 ABEND HAS BEEN REQUESTED, IN WHICH  * 36100000
*                                 CASE THE FOLLOWING ADDITIONAL       * 36200000
*                                 INPUT APPLIES-                      * 36300000
*       'DXRETCOD' - CONTAINS THE TCLOSE INTERNAL ERROR CODE;         * 36400000
*       'DXABCODE-1' - CONTAINS THE SYSTEM ABEND CODE.                * 36500000
*       'DXCCW1'   - X'FF' - INDICATES THAT PROCESSING WAS TERMINATED * 36550021
*                            ON THE CORRESPONDING DCB. DO NOT RESET   * 36560021
*                            ANY PROCESSING INDICATORS OTHER THAN     * 36570021
*                            'DCBOBUSY' IN FIELD 'DCBOFLGS' (INDI-    * 36580021
*                            CATES THAT THE DCB IS BEING PROCESSED    * 36590021
*                            BY AN I/O SUPPORT FUNCTION).             * 36592021
*                                                                     * 36600000
* OUTPUT -                                                            * 36700000
*    1. AT EXIT TO THE USER-                                          * 36800000
*       REGISTER CONTENTS WILL BE THE SAME AS WHEN THE TCLOSE MACRO   * 36900000
*          WAS INVOKED BY THE USER;                                   * 37000000
*       CONTROL BLOCK INDICATORS-                                     * 37100000
*          'DCBOFLGS' - X'C5', OFF - THE DCB RDBACK, EOF, OUTPUT, AND * 37200000
*                                    'BUSY' INDS WILL BE TURNED OFF;  * 37300000
*          'DEBOFLGS' - X'20', OFF - THE DEB 'EOF' IND IS TURNED OFF; * 37400000
*          IOB - ALL NECESSARY FLAGS ARE RESET TO CONTINUE PROCESSING.* 37500000
*    2. AT EXIT TO THE TRACE TERMINATION MODULE IFG0239R-             * 37600000
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT AS FOLLOWS- * 37700000
*          'RET' - CONTAINS A RETURN BRANCH TABLE OFFSET OF '8';      * 37800000
*          'RD'  - CONTAINS THE VALUE '1', AN INTERNAL INDICATION     * 37900000
*                  THAT THE TRACE FACILITY WAS ACTIVE.                * 38000000
*       WORK AREA FIELDS-                                             * 38100000
*          'WTGPATHS+1' - X'80', OFF - INDICATES THAT THE OPTIONAL    * 38200000
*                                      TRACE FACILITY IS TO BE        * 38300000
*                                      TERMINATED;                    * 38400000
*          'WTGENTRY' - CONTAINS THE ID/TTR (5 BYTES) OF THIS MODULE; * 38500000
*          'DXCCW3+4' - CONTAINS THE 8 BYTES THAT WERE PREVIOUSLY     * 38600000
*                       LOCATED IN 'WTGENTRY'.                        * 38700000
*                                                                     * 38800000
* EXTERNAL REFERENCES -                                               * 38900000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 39000000
*                                                                     * 39100000
* EXITS, NORMAL -                                                     * 39200000
*         IFG0239R - TO TERMINATE THE OPTIONAL TRACE FACILITY;        * 39300000
*         USER     - UPON COMPLETION OF ALL TCLOSE PROCESSING.        * 39400000
*                                                                     * 39500000
* EXITS, ERROR -                                                      * 39600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 39700000
*                                                                     * 39800000
* TABLES/WORK AREAS -                                                 * 39900000
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 40000000
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 40100000
*                                                                     * 40200000
* ATTRIBUTES -                                                        * 40300000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 40400000
*                                                                     * 40500000
* CHARACTER CODE DEPENDENCY -                                         * 40600000
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 40700000
*                                                                     * 40800000
* NOTES -                                                             * 40900000
*                                                                     * 41000000
*********************************************************************** 41100000
*                                                                       41200000
TCM50000 EQU   *                                                        41300000
         IECRES SYNCHDCB                SYNCHRONIZE DCB PROCESSING      41400000
*                                       ..OF ALL DCBS TO THIS POINT     41500000
*                                                                       41600000
*****    ISSUE A 'DELAYED ABEND' IF IT WAS REQUESTED                    41700000
*                                                                       41800000
         L     RPARC,WTGECBAD           LOAD POINTER TO ECB LIST        41900000
         L     RPARC,K0(,RPARC)         LOAD ADDR OF TCLOSE PARM LIST   42000000
         LA    RC,K4                    LOAD SIZE OF BASIC ECBLIST      42100000
         LA    RWTGC,WTGENTRY           LOAD ADDR OF FIRST WTG ENTRY    42200000
TCM50500 EQU    *                                                       42300000
         L     RCORE,K4(RWTGC)          LOAD ADDRESS OF TCLOSE WK AREA  42400000
         LA    RCORE,K0(,RCORE)         CLEAR HIGH-ORDER BYTE           42500000
         LTR   RCORE,RCORE              IS THERE A WORK AREA ADDRESS-   42600000
         BZ    TCM51000                 ..BR IF NOT TO CHECK NEXT DCB   42700000
         LA    RC,K4(,RC)               INCR ECBLIST SIZE FOR THIS DCB  42800000
         L     RDCB,PLISTDCB(,RPARC)    LOAD ADDRESS OF DCB             42900000
         TM    JFCBMASK+K4,K2           WAS A 'DELAYED ABEND' REQ'D-    43000000
         BNO   TCM51000                 ..BR IF NOT TO CHECK NEXT DCB   43100000
         TM    DCBOFLGS,DCBOBUSY        IS THE 'BUSY' BIT OFF ALSO-     43200000
         BNO   TCM55000                 ..BR IF YES TO ABEND            43300000
TCM51000 EQU   *                                                        43400000
         TM    PLISTDCB(RPARC),LASTNTRY IS THIS THE LAST TCLOSE ENTRY-  43500000
         LA    RPARC,K4(,RPARC)         PT TO NEXT TCLOSE ENTRY         43600000
         LA    RWTGC,WTGEND-WTGENTRY(,RWTGC)   PT TO NEXT WTG ENTRY     43700000
         BNO   TCM50500                 ..BR IF NOT TO CHECK NEXT ENTRY 43800000
*                                                                       43900000
*****    TERMINATE THE TRACE FACILITY IF IT WAS ACTIVE                  44000000
*                                                                       44100000
         SR    RD,RD                    SET INTERNAL SW TO IND THAT THE 44200000
*                                       ..TRACE FACILITY IS NOT ACTIVE  44300000
         TM    WTGPATHS+K1,WTGTRACE     IS THE TRACE FACILITY ACTIVE-   44400000
         BNO   TCM52500                 ..BR IF NOT TO RELEASE   S21940 44500021
*                                       ..THE RES RTN WORK AREA  S21940 44550021
         LA    RD,K1                    SET INTERNAL SW TO IND THAT THE 44600000
*                                       ..TRACE FACILITY WAS ACTIVE     44700000
         NI    WTGPATHS+K1,X'FF'-WTGTRACE INDICATE THE THE TRACE        44800000
*                                       ..FACILITY IS TO BE TERMINATED  44900000
         MVC   WTGMODID(K2),MOD2Z9R     MOVE ID OF TRACE TERMINATION    45000000
*                                       ..RTN INTO WTG TABLE            45100000
         MVC   WTGTTR(K3),MOD2Z9R+K2    MOVE TTR INTO WTG TABLE         45200000
         MVC   DXCCW3+K4(K8),WTGENTRY   SAVE FIRST WTG ENTRY CONTENTS   45300000
         MVC   WTGENTRY(K5),MOD2Z2Z     MOVE RET ID/TTR INTO WTG ENTRY  45400000
         LA    RET,K8                   BR TABLE OFFSET FOR RETURN      45500000
         XCTL  EPLOC=WTGMODNM,SF=(E,DXXCTL)  XCTL TO TERMINATE THE     C45600000
                                        ..TRACE FACILITY                45700000
*                                                                       45800000
*****    RETURN FROM THE TRACE TERMINATION ROUTINE                      45900000
*                                                                       46000000
TCM52000 EQU   *                                                        46100000
         MVC   WTGENTRY(K8),DXCCW3+K4   RESTORE FIRST WTG ENTRY         46200000
*                                                                       46300000
*****    RELEASE THE RESIDENT ROUTINE MAIN STORAGE WORK AREA (ECBLIST)  46400000
*                                                                       46500000
TCM52500 EQU   *                                                        46600000
         L     R1,WTGECBAD              LOAD THE ECBLIST ADDRESS        46700000
         L     RPAR,K0(R1)              SAVE THE PARAMETER LIST ADDRESS 46800000
         LTR   RD,RD                    WAS THE TRACE FACILITY ACTIVE-  46900000
         BZ    TCM53000                 ..BR IF NOT TO FREE ECBLIST     47000000
         LA    RC,K8(,RC)               ACCOUNT FOR THE TRACE FACILITY  47100000
         SH    RC,ACCW3CC+K2            PT TO THE ECBLIST PREFIX        47200000
TCM53000 EQU   *                                                        47300000
         LR    R0,RC                    PLACE ECBLIST SIZE INTO REG 0   47400000
         FREEMAIN R,LV=(0),A=(1)        RELEASE THE ECB LIST            47500000
*                                                                       47600000
*****    FREE MAIN STORAGE WORK AREA USED TO PROCESS THIS DCB           47700000
*                                                                       47800000
         LR    RPARC,RPAR               POINT TO THE FIRST TCLOSE ENTRY 47900000
         LA    RWTGC,WTGENTRY           POINT TO THE FIRST WTG ENTRY    48000000
TCM53500 EQU   *                                                        48100000
         L     RDCB,PLISTDCB(,RPARC)    POINT TO THE DCB FOR THIS ENTRY 48200000
         L     RDEB,DCBDEBAD            PT TO THE DEB FOR THIS DCB      48300000
         TM    DCBOFLGS,DCBOPEN+DCBOLOCK+DCBOBUSY  WAS DCB PROCESSED-   48400000
         BNO   TCM54000                 ..BR IF NOT TO GET NEXT ENTRY   48500000
         NI    DCBOFLGS,X'FF'-DCBOBUSY  TURN OFF 'DCB BUSY' IND  A35953 48504021
*                                                                A35953 48508021
         L     RCORE,4(,RWTGC)          LOAD WORK AREA ADDR     SA48558 48510021
         LA    RCORE,0(,RCORE)          CLEAR HIGH ORDER BYTE   SA48558 48510421
         TM    DXCCW,ALLBITS            WAS PROCESSING TERMIN-  SA48558 48512021
*                                       ..ATED ON THIS DCB-     SA48558 48524021
         BO    TCM53800                 ..BR IF YES- DON'T RESET A35953 48532021
*                                       ..PROCESSING INDICATORS  A35953 48536021
*                                                                A35953 48540021
*****    RESET DCB AND DEB PROCESSING STATUS INDICATORS          A35953 48544021
*                                                                A35953 48548021
         NI    DCBOFLGS,X'FF'-DCBOWRIT-DCBORDBK-DCBOEOF          A35953 48552021
*                                       RESET OUTPUT, READBACK,  A35953 48556021
*                                       EOF INDICATORS IN DCB    A35953 48560021
         NI    DEBOFLGS,X'FF'-DEBOFEOF  RESET 'VOLUME FULL'      A35953 48564021
*                                       ..INDICATOR IN DEB       A35953 48568021
*                                                                       48572021
*****    RELEASE THE TCLOSE MAIN STORAGE WORK AREA FOR THIS DCB         48576021
*                                                                       48580021
TCM53800 EQU   *                                                 A35953 48584021
*                                                                A35953 48588021
         LR    R1,RCORE                 PLACE WORK AREA ADDR    SA48558X48600021
                                        ..INTO PARAMETER REG    SA48558 48650021
         LA    R0,CLOSSIZE              LOAD LENGTH OF TCLOSE WORK AREA 48700000
         FREEMAIN R,LV=(0),A=(1)        FREE THE TCLOSE WORK AREA       48800000
*                                                                       48900000
TCM54000 EQU   *                                                        49600000
         TM    PLISTDCB(RPARC),LASTNTRY IS THIS THE LAST TCLOSE ENTRY-  49700000
         LA    RPARC,K4(,RPARC)         PT TO NEXT TCLOSE ENTRY         49800000
         LA    RWTGC,WTGEND-WTGENTRY(,RWTGC)   PT TO THE NEXT WTG ENTRY 49900000
         BNO   TCM53500                 ..BR IF NOT TO GET NEXT ENTRY   50000000
*                                                                       50100000
*****    FREE MAIN STORAGE USED FOR WTG TABLE                           50200000
*                                                                       50300000
TCM54500 EQU   *                                                        50400000
         LR    R1,RWTG                  STARTING ADDRESS OF WTG TABLE   50500000
         SR    R0,R0                    CALC LENGTH OF WTG TBL- CLEAR   50600000
         IC    R0,WTGLNG                ..WORK REG, INSERT NO. OF DBL   50700000
         SLL   R0,K3                    ..WORDS, THEN CALC NO. OF BYTES 50800000
         FREEMAIN R,LV=(0),A=(1)        FREE THE TCLOSE WTG TABLE       50900000
*                                                                       51000000
*****    RETURN TO CALLER                                               51100000
*                                                                       51200000
         SVC   SVCEXIT                  RETURN TO CALLER                51300000
         SPACE 2                                                        51400000
*********************************************************************** 51500000
*              SUBROUTINES                                            * 51600000
*********************************************************************** 51700000
*                                                                       51800000
*****    INITIALIZE CHANNEL PROGRAM TO WRITE A FILE MARK                51900000
*                                                                       52000000
TCD02900 EQU   *                                                        52100000
         LA    RF,DXCCW4+K4             PLACE ADDRESS OF CCHHR          52200000
         ST    RF,DXCCW1                INTO SEARCH CCW                 52300000
         LA    RF,DXCCW1                ADDRESS OF CCW1                 52400000
         MVI   DXCCW1,CCWSCHID          SET UP SEARCH OPERATION CODE    52500000
         ST    RF,DXCCW2                ADDRESS OF CCW1 INTO TIC CCW    52600000
         MVC   DXCCW1+K4(K5),ACCW1CD    COMMAND CHAIN,5 CHARACTERS,TIC  52700000
         LA    RF,DXDSCB                PLACE ADDRESS OF THE FILE MARK  52800000
         ST    RF,DXCCW3                INTO THE WRITE DATA CCW         52900000
         MVI   DXCCW3,X'1D'             WRITE COUNT , KEY , DATA        53000000
         MVC   DXCCW3+K4(K4),ACCW3CC    8 CHARACTERS                    53100000
         MVC   DXDSCB(K5),DXCCW4+K4     PLACE CCHHR INTO THE KEY        53200000
         XC    DXDSCB+K5(K3),DXDSCB+K5  ZERO OUT THE DATA PORTION       53300000
         BR    RD                       RETURN TO CALLER                53400000
         EJECT                                                          53500000
*                                                                       53600000
*****    COMPLETE CONTROL BLOCKS AND WRITE FILE MARK                    53700000
*                                                                       53800000
TCD03000 EQU   *                                                        53900000
         MVC   DXDAADDR,DXCCW4+K1       PLACE FULL DISK ADDRESS INTO IO 54000000
         MVI   DXDAADDR,K0              SET M (EXTENT NUMBER) TO ZERO   54100000
         LA    RC,TABD131               LOAD INTERNAL ERROR CODE        54200000
         EXCP  DXIOB                    INITIATE I/O OPERATION          54300000
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   54400000
         TM    DXECB,ECBNOERR           TEST FOR SUCCESSFUL COMPLETION- 54500000
         BCR   1,RD                     ..BR IF YES- RETURN TO CALLER   54600000
         DMABCOND (RC),ABEND2Z          ..ELSE EXIT TO THE PROBLEM     C54700000
                                        ..DETERMINATION FUNCTION        54800000
         SPACE 2                                                        54900000
*********************************************************************** 55000000
*              ERROR PROCESSING                                       * 55100000
*********************************************************************** 55200000
*                                                                       55300000
TCM55000 EQU   *                                                        55400000
         SR    RF,RF                    CLEAR RETURN CODE REGISTER      55500000
         IC    RF,DXRETCOD              INSERT THE INTERNAL ERROR CODE  55600000
         L     RC,DXABCODE-K1           LOAD THE ACTUAL ABEND CODE      55700000
         SLL   RC,K8                    SHIFT OUT THE HIGH-ORDER BYTE   55800000
         SRL   RC,K16                   POSITION THE ABEND CODE         55900000
         ABEND (RC),DUMP                TERMINATE THE TASK              56000000
         EJECT                                                          56100000
*********************************************************************** 56200000
*              CONSTANTS                                              * 56300000
*********************************************************************** 56400000
*                                                                       56500000
CON10000 DC    F'65536'                 FULLWD CONSTANT OF X'00010000'  56600000
ACCW3CC  DC    X'20000008'              LENGTH EQ 8, SILI FLAG ON       56700000
ACCW1CD  DC    X'6000000508'            LENGTH EQ 5, CMD CHAIN AND SILI 56800000
*                                       ..FLAGS, AND 'TIC' OP CODE      56900000
         SPACE 2                                                        57000000
*********************************************************************** 57100000
*              XCTL TABLE                                             * 57200000
*********************************************************************** 57300000
*                                                                       57400000
XCTLTB2Z XCTLTABL ID=(ABEND2Z,0P,MOD2Z2Z,2Z,MOD2Z9R,9R),SVC=023         57500000
         SPACE 2                                                        57600000
         IECDSECS CVT,                                                 C57700000
               TIOT,                                                   C57800000
               DCB,                                                    C57900000
               DEB,                                                    C58000000
               UCB,                                                    C58100000
               MAIN,                                                   C58200000
               UNITTAB,                                                C58300000
               WTG,                                                    C58400000
               EXPAND=YES                                               58500000
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   58600000
         SPACE 2                                                        58700000
         END                                                            58800000
