         TITLE 'IFG0551R - EOV TAPE OUTPUT TRAILER LABEL 2 PREPARATION' 00100021
         COPY  LCGASMSW                                                 00200000
IFG0551R CSECT                                                          00400021
*********************************************************************** 00500021
*                                                                     * 00600021
*                                                                     * 00700021
*          RELEASE 25 DELETIONS/CHANGES                               * 00800021
*          RELEASE 24 DELETIONS/CHANGES                               * 00900021
*          RELEASE 23 DELETIONS/CHANGES                               * 01000021
*          RELEASE 22 DELETIONS/CHANGES                               * 01100021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 01110021
*0000525500-525700                                              SA70272 01120021
*          RELEASE 21.7 DELETIONS/CHANGES                             * 01150001
*0000                                                           SA58747 01160001
*          RELEASE 21 DELETIONS/CHANGES                               * 01200021
*                                                                     * 01300021
* STATUS CHANGE LEVEL 000                                             * 01400021
*                                                                     * 01500021
* FUNCTION -                                                          * 01600021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 01700021
*    EOV TAPE OUTPUT TRAILER LABEL 2 PREPARATION FUNCTION.            * 01800021
*    USER TAPE OUT TRAILER LABEL FUNCTION.                            * 01900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 02000021
*                                                                     * 02100021
* ENTRY POINTS -                                                      * 02200021
*   IFG0551R  - ENTRY POINT VIA THE RESIDENT XCTL FROM THE FOLLOWING- * 02300021
*   INITIAL ENTRY --                                                  * 02400021
*   IFG0551P -  EOV TAPE OUTPUT TRAILER LABEL 1 PREPARATION FUNCTION. * 02500021
*                                                                     * 02600021
* INPUT -                                                             * 02700021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02800021
*                                                                     * 02900021
* OUTPUT -                                                            * 03000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03100021
*                                                                     * 03200021
* EXTERNAL REFERENCES -                                               * 03300021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 03400021
*            WAIT.                                                    * 03500021
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 03600021
*                                                                     * 03700021
* EXITS, NORMAL -                                                     * 03800021
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING --           * 03900021
*        IFG0551T TO PROCESS TAPEOUT  VOLUME DISPOSITION.             * 04000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04100021
*                                                                     * 04200021
* EXITS, ERROR -                                                      * 04300021
*    EXIT IS TO THE PROBLEM DETERMINATION MODULE IFG0190P, IF AN      * 04400021
*    ABEND SITUATION OCCURS IN THIS MODULE.  REFER TO THE FOLLOWING   * 04500021
*    'FUNCTION PROLOG(S)'.                                            * 04600021
*    POSITION IN THIS MODULE'S NAME.                                  * 04700021
*                                                                     * 04800021
* TABLES/WORK AREAS -                                                 * 04900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05000021
*                                                                     * 05100021
* ATTRIBUTES -                                                        * 05200021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 05300021
*                                                                     * 05400021
* CHARACTER CODE DEPENDENCY -                                         * 05500021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 05600021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05700021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05800021
*                                                                     * 05900021
* NOTES -                                                             * 06000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06100021
*                                                                     * 06200021
*********************************************************************** 06300021
         EJECT                                                          06400021
*********************************************************************** 06500021
*                                                                     * 06600021
*                          FUNCTION PROLOG                            * 06700021
*                                                                     * 06800021
*********************************************************************** 06900021
*                                                                     * 07000021
* FUNCTION NAME -                                                     * 07100021
*    TRAILER LABEL 2 PREPARATION FUNCTION.                            * 07200021
*                                                                     * 07300021
* (STATUS) -                                                          * 07400021
*    NOT APPLICABLE                                                   * 07500021
*                                                                     * 07600021
* FUNCTION -                                                          * 07700021
*                    1. CONSTRUCT TRAILER LABEL 2 FROM INFORMATION    * 07800021
*                       IN THE JFCB AND TIOT.                         * 07900021
*                    2.  WRITE TRAILER LABEL 2.                       * 08000021
*                    3.  IF USASI LABELS ARE SPECIFIED, TRANSLATE     * 08100021
*                       THE LABEL TO USASCII BEFORE WRITING.          * 08200021
*                    4. IF USER LABELS ARE SPECIFIED, GO TO THE       * 08300021
*                       PROBLEM PROGRAMS USER LABEL ROUTINE VIA       * 08400021
*                       SYNCH MACRO                                     08500021
*                                                                     * 08600021
* ENTRY POINTS -                                                      * 08700021
*     ENTERED FROM THE FOLLOWING --                                   * 08800021
*     EOV  TAPE OUTPUT TRAILER LABEL 1 PREPARATION FUNCTION.          * 08900021
*                                                                     * 09000021
* INPUT -                                                             * 09100021
*        REGISTERS RDCB, RCORE, RDEB, RTIOT, RUCB                     * 09200021
*                                                                     * 09300021
* OUTPUT -                                                            * 09400021
*        REGISTERS RDCB, RCORE, RDEB, RTIOT, RUCB                     * 09500021
*         TRAILER LABELS WRITTEN ON TAPE.                             * 09600021
*                                                                     * 09700021
* EXTERNAL REFERENCES -                                               * 09800021
*                    XLATE SVC ROUTINE WHEN USASI LABEL SPECIFIED.    * 09900021
*                                                                     * 10000021
* EXITS, NORMAL -                                                     * 10100021
*    REFER TO THE PRECEEDING MODULE PROLOG --                         * 10200021
*    EOV TAPE OUTPUT VOLUME DISPOSTION FUNCTION.                      * 10300021
*                                                                     * 10400021
* EXITS, ERROR -                                                      * 10500021
*      ABEND ISSUED WITH ERROR CODE                                   * 10600021
*      141 - 137  TERMINATES JOB FOR I/O ERROR WHILE WRITING LABEL.   * 10700021
*                                                                     * 10800021
* TABLES/WORK AREAS -                                                 * 10900021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 11000021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 11100021
*                                                                     * 11200021
* ATTRIBUTES -                                                        * 11300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11400021
*                                                                     * 11500021
* CHARACTER CODE DEPENDENCY -                                         * 11600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11700021
*                                                                     * 11800021
         AIF   ('&LIB' NE 'LIB1').LIB21R0                               11850000
* NOTES -                                                             * 11900021
*        1. ALL EOV MODULES DEFINE THE 536 BYTE WORK AREA IN THE      * 12000021
*           SAME FORMAT INDICATED IN DSECT 'FORCORE'.                 * 12100021
*        2. ALL EOV MODULES USE SYMBOLIC REGISTERS AS SPECIFIED IN    * 12200021
*           THIS MODULE.                                              * 12300021
*        3. ON NORMAL EXITS FROM THIS MODULE, REGISTER CONTENTS ARE:  * 12400021
*           RDCB  - ADDRESS OF DCB AT END-OF-VOLUME.                  * 12500021
*           RCORE - ADDRESS OF 536 BYTE WORK AREA.                    * 12600021
*           RDEB  - ADDRESS OF DEB FOR DATA SET AT END-OF-VOLUME.     * 12700021
*           RTIOT - ADDRESS OF DATA SET ENTRY IN TIOT.                * 12800021
*           RUCB  - ADDRESS OF UCB FOR UNIT ON WHICH EOV OCCURRED.    * 12900021
*                                                                     * 13000021
.LIB21R0 ANOP                                                           13010000
         AIF   ('&LIB' EQ 'LIB1').LIB11R0                               13020000
* NOTES -                                                             * 13050000
*        1. ALL EOV MODULES DEFINE THE 544 BYTE WORK AREA IN THE      * 13060000
*           SAME FORMAT INDICATED IN DSECT 'FORCORE'.                 * 13070000
*        2. ALL EOV MODULES USE SYMBOLIC REGISTERS AS SPECIFIED IN    * 13080000
*           THIS MODULE.                                              * 13090000
*        3. ON NORMAL EXITS FROM THIS MODULE, REGISTER CONTENTS ARE:  * 13092000
*           RDCB  - ADDRESS OF DCB AT END-OF-VOLUME.                  * 13094000
*           RCORE - ADDRESS OF 544 BYTE WORK AREA.                    * 13096000
*           RDEB  - ADDRESS OF DEB FOR DATA SET AT END-OF-VOLUME.     * 13098000
*           RTIOT - ADDRESS OF DATA SET ENTRY IN TIOT.                * 13098400
*           RUCB  - ADDRESS OF UCB FOR UNIT ON WHICH EOV OCCURRED.    * 13098800
*                                                                     * 13099200
.LIB11R0 ANOP                                                           13099600
*********************************************************************** 13100021
         EJECT                                                          13200021
*********************************************************************** 13300021
         SPACE 1                                                        13400021
*                   ADDRESSABILITY                                      13500021
         SPACE 1                                                        13600021
         BALR  RBASE,0                  ESTABLISH BASE                  13700021
         USING *,RBASE                                                  13800021
         USING FORCORE,RCORE                                            13900021
         USING IHADCB,RDCB                                              14000021
         USING DEB,RDEB                                                 14100021
         USING SRT,RUCB                                                 14200021
         SPACE 1                                                        18700021
ETO02300 EQU   *                                                        18800021
         TM    UCBTBYT2,UCBDDMSK        DUAL DENSITY UNIT         99223 18900003
         BZ    ETO02400                 NO, BRANCH                99223 19000003
         TM    DEBOPATB,K4              INOUT PROCESSING                19100021
         BO    ETO02400                 BR IF NO                        19200021
         LA    R0,DXCCW3                PREPARE                         19300021
         ST    R0,DXCCW1                FOR                             19400021
         MVI   DXCCW1,CCWSENSE          SENSE COMMAND                   19500021
         MVC   DXCCW1+K4(K4),SEN89E     LENGTH 8 BYTES, SILI      99223 19600003
         XC    DXCCW3(K8),DXCCW3        CLEAR SENSE AREA          99223 19650003
         BAL   R8,ETO04600              GO TO PERFORM SENSE OPERATION   19700021
         TM    UCBTBYT2,PE              PHASE-ENCODED UNIT        99223 19750003
         BO    ETO02350                 YES,GO SET 1600/800 BPI   99223 19760003
         MVI   FL2DEN,CHAR2             SET DENSITY TO 6250 BPI   99223 19770003
         TM    DXCCW3+K6,X10            ALT DENSITY SET IN UNIT   99223 19780003
         BNO   ETO02500                 NO,MUST BE 6250           99223 19790003
         MVI   FL2DEN,CHAR3             YES,MUST BE 1600 BPI      99223 19792003
         B     ETO02500                 GO SET FILE POSITION      99223 19794003
ETO02350 EQU   *                        CHECK FOR 1600 OR 800 BPI 99223 19796003
         MVI   FL2DEN,CHAR3             SET DENSITY IN LABEL TO 1600    19800021
         TM    DXCCW3+K3,K4             IS DENSITY ON UNIT 1600         19900021
         BO    ETO02500                 BR IF YES-DENSITY MERGE IS COMP 20000021
         MVI   FL2DEN,CHAR2             SET DENSITY IN LABEL TO 800     20100021
         B     ETO02500                 DENSITY MERGE IS COMPLETE       20200021
ETO02400 EQU   *                                                        20300021
         MVI   FL2DEN,CHAR4             SET DENSITY TO 6250 BPI   99223 20350003
         CLI   JFCDEN,DCBD6250          6250 BPI SPECIFIED        99223 20360003
         BE    ETO02500                 YES,CONTINUE              99223 20370003
         IC    R7,JFCDEN                GET DENSITY FROMJFCB            20400021
         SRL   R7,K6                    SHIFT TO LOW BITS               20500021
         STC   R7,FL2DEN                STORE IN LBL                    20600021
         OI    FL2DEN,ZONEOF            OR IN ZONE                      20700021
ETO02500 MVI   FL2FILP,ZONEOF           SET FILE POSITION TO ZERO       20800021
         CLC   UCBVOLI,JFCBVOLS         IS THIS THE FIRST VOL OF DS     20900021
         BE    ETO02600                 YES, LEAVE FILE POS IND 0       21000021
         MVI   FL2FILP,CHAR1            NO,SET FILE POSITION INDICATOR  21100021
ETO02600 L     R7,DEBTCBAD              REESTABLISH THE ADDRESS OF THE  21200021
         L     R7,TCBTIO-TCB(K0,R7)     START OF THE TIOT               21300021
         MVC   FL2JOBD,TIOCNJOB-TIOT(R7)  PLACE JOB/STEP IDENTIFICATION 21400021
         MVI   FL2JSSP,SLASH            (INSERT SLASH)                  21500021
         MVC   FL2STEPD,TIOCSTEP-TIOT(R7)  FROM THE TIOT TO LABEL       21600021
         SPACE 1                                                        21700021
*                   TAPE RECORDING TECHNIQUE                            21800021
         SPACE 1                                                        21900021
         SR    R7,R7                    CLEAR WORK REGISTER             22000021
         IC    R7,JFCTRTCH              PICK UP TAPE RECORDING TECH     22100021
         SRL   R7,K4                    13=C, 23=E , 2B=ET, 0=BLANK     22200021
         STC   R7,FL2TRTCH              PLACE FIRST CHARACTER OF TRTCH  22300021
         TR    FL2TRTCH(K1),ATRTCH9E    THE LABEL AS BLANK,C,E OR T     22400021
         CLI   JFCTRTCH,DCBTRTET        IS IT BOTH EVEN PARITY AND TRAN 22500021
         BNE   ETO02700                 NO,THE SECOND CHAR S/B BLANK    22600021
         MVI   FL2TRTCH+K1,CHART        YES,TAPE REC TECH SHOULD BE T   22700021
         SPACE 1                                                        22800021
*                   CARRIAGE CONTROL CHARACTER SET                      22900021
         SPACE 1                                                        23000021
ETO02700 TM    JFCRECFM,DCBRECCM        JFCB SPEC MACH CODE CTL CHAR    23100021
         BNO   ETO02800                 NO,GO SEE IF ASA CONTROL CHAR   23200021
         MVI   FL2CNTRL,CHARM           YES,SET MACHINE CODE CTL CHAR   23300021
ETO02800 TM    JFCRECFM,DCBRECCA        JFCB SPECIFY ASA CONTROL CHAR   23400021
         BNO   ETO02900                 NO,DO NOT SET UP CARRIAGE CTL   23500021
         MVI   FL2CNTRL,CHARA           YES,SET CONTROL CHAR TO ASA     23600021
ETO02900 EQU   *                                                        23700021
*                                                                     * 23800021
*  IF CREATING A USASI LABEL, MERGE BUFFER OFFSET AND TRANSLATE LABEL * 23900021
*                                                                     * 24000021
         TM    JFCBLTYP,JFCBAL          IS THIS A USASI LABEL           24100021
         BZ    ETO02950                 NO,CHECK IF TAPE ID REQ'D 99223 24200003
         SR    R7,R7                    CLEAR REGISTER                  24300021
         IC    R7,JFCBUFOF              GET BLOCK PREFIX LENGTH         24400021
         N     R7,BITOFF9E              TURN OFF BUFOFF=L BIT           24500021
         CVD   R7,DXCCW3                CONVERT LENGTH TO               24600021
*                                       DECIMAL                         24700021
         UNPK  FL2BUFOF(K2),DXCCW3+K6(K2)  UNPACK LENGTH TO LABEL       24800021
         OI    FL2BUFOF+K1,ZONEOF       CHANGE SIGN CODE                24900021
         MVC   FL1LABI,AEOV             MOVE IN EOV CHARACTERS          25000021
         XLATE DXLBL,K80,TO=A           TRANSLATE LABEL TO ASCII        25100021
         B     ETO03000                 GO WRITE LABEL 2         99223  25150003
         SPACE 1                                                        25200021
*  IF TAPE UNIT IS A 3420 WITH 6250 BPI, THE ID OF THE CREATING         25210003
*  TAPE UNIT IS OBTAINED FROM THE UCB EXTENSION AND PLACED IN LABEL 2   25220003
ETO02950 EQU   *                        CHECK FOR TAPE UNIT ID    99223 25250003
         CLI   UCBTBYT4,X'03'           3400 SERIES DRIVE         99223 25260003
         BNE   ETO03000                 NO - BRANCH               99223 25270003
         CLI   UCBSENSN,K24             IS THIS A 3420 TAPE UNIT  99223 25280003
         BNE   ETO03000                 NO,GO WRITE LABEL         99223 25290003
         L     R7,UCBXTN                GET UCB EXTENSION ADDR    99223 25292003
         LH    R7,K8(R7)                GET ID OF CREATING DRIVE  99223 25294003
         CVD   R7,DXCCW3                CONVERT ID TO DECIMAL     99223 25296003
         UNPK  FL2ID,DXCCW3             UNPACK ID TO EBCDIC       99223 25298003
         OI    FL2ID+K4,ZONEOF          REMOVE SIGN BITS          99223 25298403
         SPACE                                                          25298803
*                   WRITE END OF VOLUME FILE LABEL 2                    25300021
ETO03000 EQU   *                                                        25400021
         SPACE 1                                                        25500021
         BAL   R8,ETO04600              GO WRITE FILE LABEL 2           25600021
         BNO   ETO04900                 IF I/O ERROR,GO ABEND           25700021
         SPACE 1                                                        25800021
*                   SEE IF USER LABELS ARE TO BE PROCESSED              25900021
         SPACE 1                                                        26000021
         TM    JFCBLTYP,JFCBUL          USER LABELS SPECIFIED           26100021
         BZ    ETO03300                 NO, BRANCH TO EXIT              26200021
         TM    DCBMACRF,DCBMEXCP        IS THIS EXCP                    26300021
         BZ    ETO03100                 NO, GO                          26400021
         TM    DCBMACRF,DCBMFOUN        DOES EXCP DCB HAVE FOUND. EXT.  26500021
         BZ    ETO03300                 NO, GO                          26600021
ETO03100 EQU   *                                                        26700021
         L     R7,DCBEXLST              PICK UP EXIT LIST FROM DCB      26800021
         LA    R7,K0(K0,R7)             ZERO HI ORDER BYTE OF EXIT LIST 26900021
         LTR   R7,R7                    IS THE EXIT LIST ZERO           27000021
         BZ    ETO03300                 YES, EXIT TO NEXT LOAD EOV      27100021
ETO03200 CLI   K0(R7),XLOUTL            IS THIS ACTIVE EXIT 4           27200021
         BE    ETO03400                 YES, PROCESS USER LABELS        27300021
         CLI   K0(R7),XLOUTL+LASTNTRY   SEE IF LAST IND ALSO ON         27400021
         BE    ETO03400                 YES, PROCESS USER LABELS        27500021
         TM    K0(R7),LASTNTRY          IS THIS LAST ENTRY IN LIST      27600021
         LA    R7,K4(K0,R7)             POINT TO NEXT ENTRY             27700021
         BNO   ETO03200                 IF NOT,LAST,CHECK NEXT ENTRY    27800021
ETO03300 EQU   *                                                        27900021
         SPACE 1                                                        28000021
*                   EXIT                                                28100021
         LA    RWTGC,DXXENTRY           SET R8 FOR RES RTN              28200021
         LA    RWTG,DXXAREA             POINT TO EOV WTG                28300021
         SR    RET,RET                  ZERO RETURN REG                 28400021
         IECRES XCTL,MOD1T1R            GO TO NEXT MODULE               28500021
*                   EXIT TO USER LABEL HANDLING ROUTINE                 28600021
ETO03400 EQU   *                                                        28700021
         L     R7,K0(K0,R7)             PICK UP EXIT ADDRESS            28800021
         LR    RC,R7                    SET UP REG 12 TO PASS EXIT ADR  28900021
         LA    R7,K0(K0,R7)             ZERO THE HI ORDER BYTE          29000021
         LTR   R7,R7                    IS EXIT ADDR ZERO IF ACTIVE     29100021
         BZ    ETO03300                 YES,DO NOT PROCESS USER LABELS  29200021
         TITLE 'IFG0551R - EOV TAPE OUT USER TRAILER LABEL PROCESSING'  29300021
*********************************************************************** 29400021
*                                                                     * 29500021
*                          FUNCTION PROLOG                            * 29600021
*                                                                     * 29700021
*********************************************************************** 29800021
*                                                                     * 29900021
* FUNCTION NAME -                                                     * 30000021
*   USER TAPE OUT TRAILER LABEL FUNCTION.                             * 30100021
*                                                                     * 30200021
* (STATUS) -                                                          * 30300021
*    NOT APPLICABLE                                                   * 30400021
*                                                                     * 30500021
         AIF   ('&LIB' NE 'LIB1').LIB21R1                               30550000
* FUNCTION -                                                          * 30600021
*                    1. GETMAIN FOR AREA TO BE USED FOR -             * 30700021
*                       A) 72 BYTE WORK AREA                          * 30800021
*                       B) 80 BYTE LABEL BUFFER                       * 30900021
*                       C) 16 BYTE PARAMETER LIST                     * 31000021
*                                                                     * 31100021
*                    2. THIS LOAD WILL BE USED FOR OUTPUT TRAILER     * 31200021
*                       USER LABELS ON TAPE                           * 31300021
*                       SYNCHS TO APPROPRITE USER EXIT TO FORMAT USER * 31400021
*                       LABELS AND UPON RETURN REACTS ACCORDING TO THE* 31500021
*                       CODE RETURNED BY THE USER -                   * 31600021
*                       0 - DO NOT WRITE LABEL, DISCONTINUE USER LABEL* 31700021
*                           PROCESSING (I.E. RETURN TO CALLER OF THIS * 31800021
*                           ROUTINE).                                 * 31900021
*                       4 - WRITE LABEL,THEN DISCONTINUE UL PROCESSING* 32000021
*                       8 - WRITE LABEL,AND IF LESS THAN 8 LABELS HAVE* 32100021
*                           BEEN CREATED RETURN TO USER.  IF 8 LABELS * 32200021
*                           HAVE BEEN CREATED, UL PROCESSING IS ENDED * 32300021
*                           (ANSI USER LABELS ARE NOT RESTRICTED TO 8)* 32400021
*                    3. IF THERE IS A WRITE ERROR THIS LOAD           * 32500021
*                       SYNCHS TO USER WITH A PARAMETER LIST WHICH    * 32600021
*                       (IN THE THIRD ENTRY)CONTAINS AN ERROR FLAG AND* 32700021
*                       A POINTER TO STATUS INFO (CSW STATUS).  AFTER * 32800021
*                       THE USER HAS HAD THE OPPORTUNITY TO EXAMINE   * 32900021
*                       ERROR INFO, THIS ROUTINE REACTS AS FOLLOWS -  * 33000021
*                       A) OUTPUT ERRORS - UL PROCESSING IS ENDED     * 33100021
*                                                                     * 33200021
*                    4. FOR ASCII TAPE, LABELS ARE TRANSLATED BEFORE  * 33300021
*                       WRITING.                                      * 33400021
*                                                                     * 33500021
.LIB21R1 ANOP                                                           33510000
         AIF   ('&LIB' EQ 'LIB1').LIB11R1                               33520000
* FUNCTION -                                                          * 33550000
*                    1. GETMAIN FOR AREA TO BE USED FOR -             * 33560000
*                       A) 72 BYTE WORK AREA                          * 33570000
*                       B) 80 BYTE LABEL BUFFER                       * 33580000
*                       C) 16 BYTE PARAMETER LIST                     * 33590000
*                                                                     * 33592000
*                    2. THIS LOAD WILL BE USED FOR OUTPUT TRAILER     * 33594000
*                       USER LABELS ON TAPE                           * 33596000
*                       SYNCHS TO APPROPRITE USER EXIT TO FORMAT USER * 33598000
*                       LABELS AND UPON RETURN REACTS ACCORDING TO THE* 33598400
*                       CODE RETURNED BY THE USER -                   * 33598800
*                       0 - DO NOT WRITE LABEL, DISCONTINUE USER LABEL* 33599200
*                           PROCESSING (I.E. RETURN TO CALLER OF THIS * 33599600
*                           ROUTINE).                                 * 33599700
*                       4 - WRITE LABEL,THEN DISCONTINUE UL PROCESSING* 33599800
*                       8 - WRITE LABEL,AND IF LESS THAN 8 LABELS HAVE* 33599900
*                           BEEN CREATED RETURN TO USER.  IF 8 LABELS * 33633200
*                           HAVE BEEN CREATED, UL PROCESSING IS ENDED * 33643200
*                           (ANSI USER LABELS ARE NOT RESTRICTED TO 8)* 33653200
*                    3. IF THERE IS A WRITE ERROR THIS LOAD           * 33663200
*                       SYNCHS TO USER WITH A PARAMETER LIST WHICH    * 33665200
*                       (IN THE THIRD ENTRY)CONTAINS AN ERROR FLAG AND* 33665600
*                       A POINTER TO STATUS INFO (CSW STATUS).  AFTER * 33666000
*                       THE USER HAS HAD THE OPPORTUNITY TO EXAMINE   * 33666400
*                       ERROR INFO, THIS ROUTINE REACTS AS FOLLOWS -  * 33666500
*                       A) OUTPUT ERRORS - UL PROCESSING IS ENDED     * 33666600
*                                                                     * 33677700
*                    4. FOR ASCII TAPE, LABELS ARE TRANSLATED BEFORE  * 33687700
*                       WRITING.                                      * 33688100
*                                                                     * 33688500
*                    5. DEB VALIDITY CHECKING IS ACCOMPLISHED  VIA A  * 33691300
*                       DEB VALIDITY CHECK ROUTINE WHICH MAINTAINS    * 33693300
*                       AND UPDATES A TABLE OF VALID DEB POINTERS IN  * 33693700
*                       PROTECTED CORE (LSQS).                        * 33694100
*                                                                     * 33694200
.LIB11R1 ANOP                                                           33694400
* ENTRY POINTS -                                                      * 33697200
*     NO CHANGES (SEE PREVIOUS FUNCTION PROLOG)                       * 33700021
*                                                                     * 33800021
* INPUT -                                                             * 33900021
*     NO CHANGES (SEE PREVIOUS FUNCTION PROLOG)                       * 34000021
*                                                                     * 34100021
* OUTPUT -                                                            * 34200021
*     NO CHANGES (SEE PREVIOUS FUNCTION PROLOG)                       * 34300021
*     USER LABEL WRITTEN ON TAPE.                                     * 34400021
*                                                                     * 34500021
* EXTERNAL REFERENCES -                                               * 34600021
*      TRANSLATE SVC MACRO                                            * 34700021
*      SYNCH TO USER EXIT.                                            * 34800021
*                                                                     * 34900021
* EXITS, NORMAL -                                                     * 35000021
*     REFER TO THE PRECEEDING MODULE PROLOG --                        * 35100021
*     EOV TAPE OUTPUT VOLUME DISPOSITION FUNCTION.                    * 35200021
*                                                                     * 35300021
* EXITS, ERROR -                                                      * 35400021
*             - SYNCH TO USER EXIT ROUTINE WITH PARAMETER LIST        * 35500021
*                                                                     * 35600021
* TABLES/WORK AREAS -                                                 * 35700021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 35800021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 35900021
*                                                                     * 36000021
* ATTRIBUTES -                                                        * 36100021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 36200021
*                                                                     * 36300021
* CHARACTER CODE DEPENDENCY -                                         * 36400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 36500021
*                                                                     * 36600021
         AIF   ('&LIB' NE 'LIB1').LIB21R2                               36650000
* NOTES -                                                             * 36700021
*                     536(EOV) BYTES OF MAIN STORAGE  DEFINED BY      * 36800021
*                     DSECT 'FORCORE'. SMALLER AREA FOR OPEN/CLOSE.   * 36900021
*                                                                     * 37000021
.LIB21R2 ANOP                                                           37010000
         AIF   ('&LIB' EQ 'LIB1').LIB11R2                               37020000
* NOTES -                                                             * 37050000
*                     544(EOV) BYTES OF MAIN STORAGE  DEFINED BY      * 37060000
*                     DSECT 'FORCORE'. SMALLER AREA FOR OPEN/CLOSE.   * 37070000
*                                                                     * 37080000
.LIB11R2 ANOP                                                           37090000
*********************************************************************** 37100021
         EJECT                                                          37200021
*********************************************************************** 37300021
*  OBTAIN USER CORE FOR WORK AREA, LABEL BUFFER, AND PARAMETER          37400021
*  LIST AREA (72+80+16).                                                37500021
*********************************************************************** 37600021
         GETMAIN R,LV=USERL,SP=250                                      37700021
*                                                                       37800021
         USING ULWK,R1                                                  37900021
         STM   RPAR,RC,ULWK             SAVE REGS (INCLUDES DCB EXIT    38000021
*                                    LIST FOR USER LABEL PROCESSING)    38100021
         DROP  R1                                                       38200021
         LR    RUCB,R1                  POINT TO AREA OBTAINED          38300021
         USING ULWK,RUCB                RUCB IS USED HERE FOR UL WORK   38400021
         LA    R1,CHAR0                 INITIALIZE COUNT                38500021
         STH   R1,ULCNT                 SAVE FOR LATER USE              38600021
*  OUTPUT LABEL PROCESSING                                              38700021
         MVI   ULBUFR,BLANK             SET LABEL BUFFER AREA           38800021
         MVC   ULBUFR+K1(K79),ULBUFR    TO BLANKS                       38900021
ETO03500 EQU   *                                                        39000021
         TM    JFCBLTYP,JFCBAL+JFCBUL   ANSI USER LABELS SPEC.          39100021
         BO    ETO03600                 YES, SKIP LABEL COUNTING        39200021
         LH    R1,ULCNT                 PICK UP PREVIOUS COUNT          39300021
         LA    R1,K1(K0,R1)             INCREMENT BY 1                  39400021
         STH   R1,ULCNT                 SAVE UPDATED COUNT              39500021
         CLI   ULCNT+K1,MAXNOLAB        TEST,BR IF MAX NBR OF UL        39600021
         BH    ETO04000                 ALREADY PROCESSED               39700021
ETO03600 EQU   *                        INITIALIZE BUFFER HEADING       39800021
         MVC   ULBUFR(K3),UTLCON        INITIALIZE FIRST 4 CHAR OF      39900021
         MVC   ULBUFR+K3(K1),ULCNT+K1   ESTABLISH LABEL NUMBER IN BUFFR 40000021
         BAL   R8,ETO04100              GO TO SYNCH TO USER             40100021
*                                                                       40200021
*                                                                       40300021
         LTR   RF,RF                    TEST,BR IF LABEL NOT            40400021
         BZ    ETO04000                 TO BE WRITTEN                   40500021
*  RESET FIRST 4 CHAR OF LABEL THEN                                     40600021
*  ESTABLISH CHANNEL PROGRAM TO WRITE USER LABEL                        40700021
*                                                                       40800021
*                                                                       40900021
         MVC   ULBUFR(K3),UTLCON        SET 'UTL' IN LABEL              41000021
         TM    JFCBLTYP,JFCBAL+JFCBUL   IF 'AUL' SPEC, BYPASS           41100021
         BO    ETO03700                 RESTORING LABEL NUMBER          41200021
         MVC   ULBUFR+K3(K1),ULCNT+K1   LABEL NUMBER IN LABEL           41300021
ETO03700 EQU   *                        POINT TO LABEL BUFFER           41400021
         LA    R1,ULBUFR                POINT CCW TO LABEL BUFFER       41500021
         ST    R1,DXCCW1                                                41600021
         MVI   DXCCW1,CCWWRTAP          WRITE OP-CODE TO CCW            41700021
         MVC   DXCCW1+K4(K4),LENGTH     80-CHAR LENGTH                  41800021
         TM    JFCBLTYP,JFCBAL+JFCBUL   ANSI USER LABEL SPEC.           41900021
         BNO   ETO03800                 NO, BYPASS TRANSLATE            42000021
*   TRANSLATE LABEL BEFORE PROCESSING                                   42100021
         XLATE (R1),K80,TO=A            TRANSLATE USER LABEL            42200021
ETO03800 EQU   *                        GO WRITE LABEL                  42300021
         BAL   R8,ETO04600              GO ISSUE EXCP                   42400021
         BZ    ETO03900                 ERROR ENCOUNTERED.              42500021
*                                                                       42600021
*                                                                       42700021
         CLI   ULRETCOD,WRITNEXT        TEST,BR IF USER RETURNED A CODE 42800021
         BE    ETO03500                 TO CONTINUE UL PROCESSING       42900021
*  OTHERWISE, IT IS ASSUMED THE USER RETURNED A CODE = 4, I.E. NO       43000021
*  FURTHER UL PROCESSING.                                               43100021
         B     ETO04000                 UNCONDITIONAL BRANCH            43200021
*                                                                       43300021
ETO03900 EQU   *                                                        43400021
*  ERROR WHEN ATTEMPTING TO WRITE LABEL.  GO TO USER WITH ERROR         43500021
*  INDICATIONS, THEN TERMINATE UL PROCESSING (RETURN CODE NOT           43600021
*  EXAMINED).                                                           43700021
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   43800021
         ST    R1,ULPARM+K8             IN PARAMETER LIST               43900021
         OI    ULPARM+K8,LASTNTRY+ERROROUT  FLAG IN ERROR               44000021
         BAL   R8,ETO04200              GO TO SYNCH TO USER (BUFFER     44100021
*                                       CONTAINS LABEL UNABLE TO WRITE) 44200021
ETO04000 EQU   *                                                        44300021
*                                                                       44400021
*                                                                       44500021
         LR    R1,RUCB                  RUCB PTR TO AREA TO BE FREED    44600021
         LM    RPAR,RC,ULWK             RESTORE REGS 5-10 AND 12        44700021
         FREEMAIN R,LV=USERL,SP=250,A=(1)  FREE USER LABEL WORK AREA,  C44800021
                                        LABEL BUFFER AND PARAMETER LIST 44900021
         SPACE 2                                                        45000021
         B     ETO03300                 BRANCH TO DO XCTL               45100021
         SPACE 2                                                        45200021
*                                                                       45300021
ETO04100 EQU   *                                                        45400021
         XC    ULPARM+K8(K4),ULPARM+K8  ZERO ERROR IND                  45500021
ETO04200 EQU   *                                                        45600021
         LA    R1,ULBUFR                POINT TO LABEL BUFFER           45700021
ETO04300 EQU   *                                                        45800021
         STM   R1,RDCB,ULPARM           PTRS TO LABEL BUFFER AND DCB IN 45900021
*                                       PARAMETER LIST                  46000021
         XC    ULTOTPTR(K4),ULTOTPTR    ZERO TOTALING ENTRY             46100021
         MVI   ULDCBPTR,K0              CLEAR FLAG BYTE                 46200021
         AIF   ('&LIB' NE 'LIB1').LIB21R3                               46250000
         L     R7,DCBDEBAD              GET ADDRESS OF USER'S DEB       46300021
.LIB21R3 ANOP                                                           46350000
         AIF   ('&LIB' EQ 'LIB1').LIB11R3                               46360000
         L     R7,DXPDEBAD              LOAD PROTECTED DEB ADDR  Y01021 46370000
.LIB11R3 ANOP                                                           46380000
*                                                                       46400021
         TM    DCBMACRF,DCBMEXCP        CK IF USING EXCP                46500021
         BO    ETO04400                 EXCP, SKIP TOTALING             46600021
         TM    DCBOPTCD,DCBOPTT         CK IF TOTALING SPECIFIED        46700021
         BZ    ETO04400                 BR IF NO TOTALING               46800021
*                                                                       46900021
         L     R7,K40(R7)               GET PTR TO TOTALING AREA        47000021
         USING TOTSAVWA,R7              ESTABLISH BASE FOR AREA         47100021
         MVC   ULTOTPTR(K4),TOTEOVPT    TOTLING PTR TO PARM LIST        47200021
         DROP  R7                       DROP BASE                       47300021
*                                                                       47400021
ETO04400 EQU   *                                                        47500021
         LA    R1,ULPARM                POINT TO PARAMETER LIST         47600021
*               FIND  SVRB                                              47700021
*               SAVE REGS                                               47800021
*               LOAD USER REGS,SET LOCK BIT                             47900021
*               SYNCH TO USER                                           48000021
*               RESTORE REGS,RESET LOCK BIT                             48100021
*               RETURN TO CALLER                                        48200021
*                                                                       48300021
         L     RF,ULREQ                 PTR TO USER'S LABEL ROUTINE     48400021
         L     R7,CVTPTR                PTR TO CVT                      48500021
         L     R7,CVTTCBP-CVT(K0,R7)    PTR TO TCB PTRS                 48600021
         L     R7,K4(K0,R7)             PTR TO CUR TCB                  48700021
         L     R7,K0(K0,R7)             PTR TO SVRB                     48800021
*                                                                       48900021
         USING RBSECT,R7                                                49000021
*                                                                       49100021
         STM   RDCB,RD,RBEXSAVE         SAVE REGS 2-13                  49200021
         NI    DCBOFLGS,X'FF'-DCBOLOCK  SET LOCK BIT TO ZERO            49300021
         L     RD,RBLINK                PTR TO PREVIOUS RB              49400021
         TM    RBSTAB-RBSECT(RD),RBFTSVRB  IS PREVIOUS A PRB            49500021
         BNO   ETO04500                 YES,BRANCH                      49600021
         LR    R7,RD                    USE PREVIOUS RB                 49700021
ETO04500 LM    RDCB,RD,RBGRS2           RESTORE USER REGS               49800021
         SYNCH (15)                                                     49900021
         L     R7,CVTPTR                PTR TO CVT                      50000021
         L     R7,CVTTCBP-CVT(K0,R7)    PTR TO TCB PTRS                 50100021
         L     R7,K4(K0,R7)             PTR TO CUR TCB                  50200021
         L     R7,K0(K0,R7)             PTR TO SVRB                     50300021
         LM    RDCB,RD,RBEXSAVE         RESTORE REGS 2-13               50480000
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT TO ONE             50500021
         ST    RF,ULWK1                 SAVE RETURN CODE                50600021
         AIF   ('&LIB' EQ 'LIB1').LIB11R4                               50650000
         DEBCHK (RDCB)                  VERIFY DEB               Y01021 50680000
         LR    RDEB,R1                  LOAD VERIFIED DEB ADDR   Y01021 50680400
         ST    RDEB,DXPDEBAD            STORE DEBAD IN WORKAREA  Y01021 50682000
         L     RF,ULWK1                 RESTORE RETURN CODE      Y01021 50690000
.LIB11R4 ANOP                                                           50692000
         BR    R8                       RETURN                          50700021
*                                                                       50800021
         DROP  R7                                                       50900021
*                                                                       51000021
         SPACE 1                                                        51100021
         EJECT                                                          51200021
*                   CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS           51300021
         SPACE 1                                                        51400021
*                        IT IS ASSUMED THAT ALL CONTROL BLOCKS          51500021
*                        HAVE ALREADY BEEN SET UP                       51600021
         SPACE 1                                                        51700021
*                             BAL  R8,PRTR50                            51800021
*                             RETURN                                    51900021
         SPACE 1                                                        52000021
ETO04600 EQU   *                                                        52100021
         EXCP  DXIOB                    INITIATE I/O OPERATION          52200021
ETO04700 WAIT  ,ECB=DXECB               WAIT FOR COMPLETION OF I/O OPER 52300021
         TM    IOBSTAT0,CSWUNITX        IS THERE A UNIT EXCEPTION ERROR 52400021
         BC    12,ETO04800              NO,GO CHECK IF ANY I/O ERROR    52500021
         TM    IOBSTAT0,IOERR           TEST FOR UNIT CHECK     SA70272 52550021
*                                       ALSO                    SA70272 52552021
         BO    ETO04800                 YES, CHECK FOR ANY      SA70272 52560021
*                                       I/O ERROR               SA70272 52570021
         OI    DXECB,ECBCOD7F           IGNORE ERROR                    52600021
ETO04800 EQU   *                                                        52700021
         TM    DXECB,ECBNOERR           IS THERE AN UNUSUAL I/O COND    52800021
         BR    R8                       RETURN TO CALLER                52900021
         EJECT                                                          53000021
* ***                                                                   53100021
* ***          NOTIFY OPERATOR THAT JOB IS BEING TERMINATED             53200021
* ***          DUE TO I/O ERROR                                         53300021
* ***                                                                   53400021
* ***                                                                   53500021
ETO04900 EQU   *                                                        53600021
         LA    RWTGC,DXXENTRY           SET R8 FOR RES RTN              53700021
         LA    RWTG,DXXAREA             POINT TO EOV WTG                53800021
         DMABCOND 141,MODPD1R           GO TO PROB DETER. FOR ABEND     53900021
*                                       137                             54000021
         SPACE 1                                                        54100021
*                   CONSTANTS                                           54200021
         LTORG                                                          54300021
         SPACE 1                                                        54400021
SEN89E   DC    X'20000008'              SENSE 8 BYTES - SILI      99223 54500003
ATRTCH9E DC    C' CET'                  CONVERSION,EVEN PARITY,TRANSLAT 54600021
         DS    0H                                                       54700021
AGRTR39E DC    X'8000'                  VALUE IN LABEL WHEN LRECLGT 32K 54800021
AEOV     DC    C'EOV'                   CHARACTERS -EOV-                54900021
ARECFM9E EQU   *-1                      RECFM TRANSLATE TABLE           55000021
         DC    C'VFU'                   VARIABLE,FIXED,UNKNOWN REC FMT  55100021
ABLKA9E  DC    C' SBR'                  BLK AATTRB TRANSLATE TABLE      55200021
BITOFF9E DC    F'127'                   MASK FOR BUFOFF=L BIT           55300021
*                                                                       55400021
*                        CONSTANTS                                      55500021
*                                                                       55600021
LENGTH   DC    X'20000050'              SILI, COUNT = 80 BYTES          55700021
UTLCON   DC    C'UTL'                   TRAILER LABEL CONSTANT          55800021
*                                                                       55900021
XCTLTA1R DS    0D                                                       56000021
MOD1T1R  DC    C'1T'                    MOD ID OF TAPEOUT VOL DISP      56100021
         DC    X'00000000'              TTRL                            56200021
MODPD1R  DC    C'0P'                    ID OF PROB DETERMINATION MOD    56300021
         DC    X'00000000'              TTRL                            56400021
         DC    X'0000'                  END OF XCTL TABLE               56500021
PATCHL1R EQU   IFG0551R+1020-*          CALC PATCH AREA LENGTH          56600021
PATCH1R  DC    (PATCHL1R)X'00'          ZERO PATCH AREA                 56700021
         DC    C'055'                   EOV SVC CODE                    56800021
         DC    AL1((XCTLTA1R-IFG0551R)/8)  DBL WDS TO XTCL TABLE        56900021
         IECDSECS CVT,TCB,RB,DCB,UCB,MAIN,DEB,USERLAB,USERTOT,         X57000021
               TIOT,EXPAND=YES                                          57100021
         IECEQU                                                         57200021
         END                                                            57300021
