         TITLE 'IFG0552F EOV TAPE OUT HEADER 2/USER LABEL PREPARATION'  00100021
         COPY  LCGASMSW                                                 00200000
IFG0552F CSECT                                                          00400021
*********************************************************************** 00500021
*                                                                     * 00600021
*                                                                     * 00700021
*          RELEASE 25 DELETIONS/CHANGES                               * 00800021
*          RELEASE 24 DELETIONS/CHANGES                               * 00900021
*          RELEASE 23 DELETIONS/CHANGES                               * 01000021
*          RELEASE 22 DELETIONS/CHANGES                               * 01100021
*          RELEASE 21 DELETIONS/CHANGES                               * 01200021
*                                                                     * 01300021
* STATUS CHANGE LEVEL 000                                             * 01400021
*                                                                     * 01500021
* FUNCTION -                                                          * 01600021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 01700021
*    EOV TAPE OUTPUT HEADER LABEL 2 BUILD FUNCTION.                   * 01800021
*    PROCESS USER LABEL FUNCTION.                                     * 01900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 02000021
*                                                                     * 02100021
* ENTRY POINTS -                                                      * 02200021
*   IFG0552F                                                          * 02300021
*     - ENTRY POINT VIA THE RESIDENT XCTL FROM THE FOLLOWING-         * 02400021
*   INITIAL ENTRY --                                                  * 02500021
*    IFG0552D - EOV WRITE HEADER LABEL 1 OUTPUT VOLUME FUNCTION.      * 02600021
*                                                                     * 02700021
* INPUT -                                                             * 02800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 02900021
*                                                                     * 03000021
* OUTPUT -                                                            * 03100021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 03200021
*                                                                     * 03300021
* EXTERNAL REFERENCES -                                               * 03400021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 03500021
*            WAIT.                                                    * 03600021
*         TRANSLATE SVC (103) MACRO                                   * 03700021
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 03800021
*                                                                     * 03900021
* EXITS, NORMAL -                                                     * 04000021
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING --           * 04100021
*       IFG0552H - EOV TAPE OUTPUT MOUNT AHEAD FUNCTION.              * 04200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 04300021
*                                                                     * 04400021
* EXITS, ERROR -                                                      * 04500021
*    ON TAPE I/O ERROR XCTL VIA IFG055RA TO IFG0552N TO MOUNT A       * 04600021
*    NEW SCRATCH TAPE FUNCTION.                                       * 04700021
*      REFER TO THE FOLLOWING 'FUNCTION PROLOG (S).                   * 04800021
*                                                                     * 04900021
* TABLES/WORK AREAS -                                                 * 05000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05100021
*                                                                     * 05200021
* ATTRIBUTES -                                                        * 05300021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 05400021
*                                                                     * 05500021
* CHARACTER CODE DEPENDENCY -                                         * 05600021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 05700021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05800021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05900021
*                                                                     * 06000021
* NOTES -                                                             * 06100021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06200021
*                                                                     * 06300021
*********************************************************************** 06400021
         EJECT                                                          06500021
*********************************************************************** 06600021
*                                                                     * 06700021
*                          FUNCTION PROLOG                            * 06800021
*                                                                     * 06900021
*********************************************************************** 07000021
*                                                                     * 07100021
* FUNCTION NAME -                                                     * 07200021
*   EOV WRITE HEADER 2 OR USER LABEL FUNCTION.                        * 07300021
*                                                                     * 07400021
* (STATUS) -                                                          * 07500021
*    NOT APPLICABLE                                                   * 07600021
*                                                                     * 07700021
* FUNCTION -                                                          * 07800021
*                     1.  WAITS FOR COMPLETION OF HDR1 LABEL          * 07900021
*                     2. CONSTRUCTS HEADER LABEL 2 FROM INFORMATION   * 08000021
*                        IN THE JFCB AND TIOT                         * 08100021
*                     3. WRITES HEADER LABEL 2.                       * 08200021
*                     4. WRITES A TAPE MARK FOLLOWING HEADERS         * 08300021
*                     5. FOR ASCII TAPE, LABELS ARE TRANSLATED        * 08400021
*                        BEFORE WRITING.                              * 08500021
*                                                                     * 08600021
* ENTRY POINTS -                                                      * 08700021
*     ENTERED FROM THE FOLLOWING --                                   * 08800021
*     EOV WRITE HEADER LABEL 1 OUTPUT VOLUME FUNCTION.                * 08900021
*                                                                     * 09000021
* INPUT -                                                             * 09100021
*   REGISTERS RDCB=ADDRESS OF DCB,RCORE=ADDRESS OF 536 BYTE WORK      * 09200021
*   AREA,RDEB=ADDRESS OF DEB OF DCB,RTIOT=ADDRESS OF DDNAME ENTRY IN  * 09300021
*   THE TIOT, RUCB=ADDRESS OF UCB FOR CURRENT TAPE.                   * 09400021
*                                                                     * 09500021
* OUTPUT -                                                            * 09600021
*      REGISTERS RUCB,RCORE,RDEB,RDCB,RTIOT.(SEE INPUT)               * 09700021
*      HEADER LABEL 2 WRITTEN ON TAPE.                                * 09800021
*                                                                     * 09900021
* EXTERNAL REFERENCES -                                               * 10000021
*      TRANSLATE SVC MACRO.                                           * 10100021
*                                                                     * 10200021
* EXITS, NORMAL -                                                     * 10300021
*    REFER TO THE PRECEEDING MODULE PROLOG --                         * 10400021
*    EOV TAPE OUT MOUNT AHEAD FUNCTION.                               * 10500021
*                                                                     * 10600021
* EXITS, ERROR -                                                      * 10700021
*               IF TAPE I/O ERROR,                                    * 10800021
*               THEN XCTL TO IFG0552N TO MOUNT A NEW SCRTCH TAPE.     * 10900021
*                                                                     * 11000021
* TABLES/WORK AREAS -                                                 * 11100021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 11200021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 11300021
*                                                                     * 11400021
* ATTRIBUTES -                                                        * 11500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11600021
*                                                                     * 11700021
* CHARACTER CODE DEPENDENCY -                                         * 11800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 11900021
*                                                                     * 12000021
* NOTES -                                                             * 12100021
*        1. ALL EOV MODULES DEFINE THE 536 BYTES IN THE SAME FORMAT   * 12200021
*           INDICATED IN DSECT 'FORCORE'.                             * 12300021
*        2. ALL EOV MODULES USE SYMBOLIC REGISTERS AS SPECIFIED IN    * 12400021
*           THIS MODULE.                                              * 12500021
*        3. ON NORMAL EXITS FROM THIS MODULE, REGISTER CONTENTS ARE:  * 12600021
*           RDCB  - ADDRESS OF DCB AT END-OF-VOLUME.                  * 12700021
*           RCORE - ADDRESS OF 536 BYTE WORK AREA                     * 12800021
*           RDEB  - ADDRESS OF DEB FOR DATA SET AT END-OF-VOLUME.     * 12900021
*           RTIOT - ADDRESS OF THE DATA SET ENTRY IN TIOT.            * 13000021
*           RUCB  - ADDRESS OF UCB FOR UNIT WHERE EOV OCCURRED.       * 13100021
*                                                                     * 13200021
*********************************************************************** 13300021
         EJECT                                                          13400021
         SPACE 1                                                        13500021
*                   ADDRESSABILITY                                      13600021
         SPACE 1                                                        13700021
         BALR  RBASE,0                  ESTABLISH BASE                  13800021
         USING *,RBASE                                                  13900021
         USING FORCORE,RCORE                                            14000021
         USING DEB,RDEB                                                 14100021
         USING IHADCB,RDCB                                              14200021
         USING SRT,RUCB                                                 14300021
         SPACE 1                                                        14400021
         BAL   R8,ETO22200              GO WAIT FOR HDR1                14500021
         BNO   ETO24000                 BR IF I/O ERROR                 14600021
*                   PREPARE HEADER LABEL 2                              14700021
         SPACE 1                                                        14800021
         MVI   FL1NO,X'F2'              SET FILE LABEL IDENTIFIER TO 2  14900021
         MVI   FL2TRTCH,BLANK           SET PART OF LABEL TO            15000021
         MVC   FL2TRTCH+K1(K45),FL2TRTCH  BLANKS - 47 CHARACTERS        15100021
         SPACE 1                                                        15200021
*                  BLOCKING ATTRIBUTE                                   15300021
         SPACE 1                                                        15400021
         SR    R7,R7                    CLEAR WORK REGISTER             15500021
         IC    R7,JFCRECFM              PICK UP RECORD FORMAT FROM THE  15600021
         SRL   R7,K3                    BITS 0,1 CONTAIN BLK ATTRIBUTE  15700021
         STC   R7,DXLBL+K38             ZERO ALL BUT BITS 0,1 TO        15800021
         NI    DXLBL+K38,K3             PREPARE FOR TRANSLATE           15900021
         TR    DXLBL+K38(K1),ABLKA0W    TRANSLATE TO S, B, R OR BLANK   16000021
*                                                                       16100021
*                  RECORD FORMAT                                        16200021
*                                                                       16300021
         TM    JFCRECFM,JFCRFO          TEST FOR RECFM = D              16400021
         BZ    ETO20500                 NO, GET RECORD FORMAT           16500021
         MVI   FL2RECFM,DCBRECUN+DCBRECCA  SET RECFM = D IN LABEL       16600021
         B     ETO20600                 GO GET BLOCK SIZE               16700021
ETO20500 EQU   *                        GET RECORD FORMAT               16800021
         SRL   R7,K3                    BITS 0,1 CONTAIN RECORD FORMAT  16900021
         STC   R7,FL2RECFM              F = BIT 0  V = BIT 1  U = BITS  17000021
         TR    FL2RECFM,ARECFM0W        TRANSLATE TO V,F OR U           17100021
         SPACE 1                                                        17200021
ETO20600 EQU   *                        GET BLOCK SIZE                  17300021
*                             BUFFER OFFSET                             17400021
         SPACE 1                                                        17500021
         LH    R7,JFCBLKSI              PICK UP BLOCK LENGTH            17600021
         CVD   R7,DXCCW2                CONVERT BLOCK LENGTH TO DECIMAL 17700021
         UNPK  FL2BLKL,DXCCW2           BLOCK LENGTH IN EBCDIC TO LABEL 17800021
         OI    FL2BLKL+K4,ZONEOF        RESET SIGN BITS                 17900021
         LH    R7,JFCLRECL              PICK UP LOGICAL RECORD LENGTH   18000021
         CH    R7,AGRTR30W              IS LRECL INDIC GRTR 32K         18100021
         BE    ETO20700                 BR TO SET LABEL TO 9'S          18200021
         CVD   R7,DXCCW2                CONVERT LOGICAL REC LEN TO DEC  18300021
         UNPK  FL2LRECL,DXCCW2          LOGICAL REC LEN IN EBCDIC       18400021
         OI    FL2LRECL+K4,ZONEOF       RESET SIGN BITS                 18500021
         B     ETO20800                 BR TO CONTINUE MERGE            18600021
ETO20700 EQU   *                                                        18700021
         MVI   FL2LRECL,ALLBITS-K6      SET LRECL TO 9'S                18800021
         MVC   FL2LRECL+K1(K4),FL2LRECL  INDICATING GRTR 32K            18900021
*                                                                       19000021
*                  DENSITY                                              19100021
ETO20800 EQU   *                                                        19200021
         MVI   FL2DEN,CHAR4             SET DENSITY TO 4          99223 19250003
         TM    JFCDEN,DEN6250           IS DENSITY 6250           99223 19260003
         BO    ETO20850                 YES,BRANCH                99223 19270003
         SR    R7,R7                    CLEAR WORK REGISTER             19300021
         IC    R7,JFCDEN                PICK UP DENSITY FROM THE JFCB   19400021
         SRL   R7,K6                    BITS 0 AND 1 CONTAIN DENSITY    19500021
         STC   R7,FL2DEN                00=200 01=556 10=800 11=1600    19600021
         OI    FL2DEN,DENSET            SET DENSITY TO EBCDIC           19700021
*                                                                       19800021
*                   FILE POSITION AND JOB/STEP IDENTIFICATION           19900021
*                                                                       20000021
ETO20850 EQU   *                                                  99223 20050003
         MVI   FL2FILP,FILPOS1          A VOLUME SWITCH HAS OCCURRED    20100021
         L     R7,DEBTCBAD              REESTABLISH THE ADDRESS OF THE  20200021
         L     R7,TCBTIO-TCB(K0,R7)     BEGINNING OF THE TIOT           20300021
         MVC   FL2JOBD,TIOCNJOB-TIOT(R7)  PLACE JOB/STEP IDENTIFICATION 20400021
         MVI   FL2JSSP,SLASH            (INSERT SLASH)                  20500021
         MVC   FL2STEPD,TIOCSTEP-TIOT(R7)  FROM THE TIOT TO LABEL       20600021
         SPACE 1                                                        20700021
*                   TAPE RECORDING TECHNIQUE                            20800021
         SPACE 1                                                        20900021
         SR    R7,R7                    CLEAR WORK REGISTER             21000021
         IC    R7,JFCTRTCH              PICK UP TAPE RECORDING TECH     21100021
         SRL   R7,K4                    13=C, 23=E , 2B=ET, 0=BLANK     21200021
         STC   R7,FL2TRTCH              PLACE FIRST CHARACTER OF TRTCH  21300021
         TR    FL2TRTCH(K1),ATRTCH0W    THE LABEL AS BLANK,C,E OR T     21400021
         CLI   JFCTRTCH,DCBTRTET        IS IT BOTH EVEN PARITY AND TRAN 21500021
         BC    6,ETO20900               NO,THE SECOND CHAR S/B BLANK    21600021
         MVI   FL2TRTCH+K1,CHART        YES,TAPE RECORD TRANS           21700021
         SPACE 1                                                        21800021
*                   CARRIAGE CONTROL CHARACTER SET                      21900021
         SPACE 1                                                        22000021
ETO20900 TM    JFCRECFM,DCBRECCM        JFCB SPECIFY MACHINE CODE CTL   22100021
         BC    12,ETO21000              NO,GO SEE IF ASA CONTROL CHAR   22200021
         MVI   FL2CNTRL,CHARM           YES,SET MACHINE CODE CTL CHAR   22300021
ETO21000 TM    JFCRECFM,DCBRECCA        JFCB SPECIFY ASA CONTROL CHAR   22400021
         BC    12,ETO21100              NO,DO NOT SET UP CARRIAGE CNTRL 22500021
         MVI   FL2CNTRL,CHARA           YES,SET CONTROL CHAR TO ASA     22600021
*                                                                       22700021
ETO21100 EQU   *                                                        22800021
*                             BUFFER OFFSET                             22900021
         TM    JFCBLTYP,JFCBAL          WERE ANSI LABEL SPEC.           23000021
         BZ    ETO21350                 NO, CHECK FOR 6250        99223 23100003
ETO21200 SR    R7,R7                    CLEAR REG                       23200021
         IC    R7,JFCBUFOF              LOAD OFFSET LENGTH              23300021
         O     R7,BITOFF0W              TURN OFF BUFOFF = L BIT         23400021
ETO21300 CVD   R7,DXCCW2                CONVERT TO DECIMAL              23500021
         UNPK  FL2BUFOF,DXCCW2          UNPACK                          23600021
         OI    FL2BUFOF+K1,ZONEOF       TURN OFF SIGN BIT               23700021
         MVC   FL1LABI,HDR0W            MOVE IN HEADER CONSTANT         23800021
*   TRANSLATE LABEL BEFORE WRITING                                      23900021
         XLATE DXLBL,K80,TO=A           TRANSLATE                       24000021
         B     ETO21400                 GO WRITE LABEL            99223 24050003
*  IF CREATING SL ON A 6250 BPI TAPE UNIT, THE ID OF THE CREATING       24052003
*  DEVICE IS PLACED IN HDR2/EOF2/EOV2. TAPE UNIT ID IS FOUND IN THE     24054003
*  UCB EXTENSION.                                                       24056003
ETO21350 EQU   *                                                  99223 24060003
         CLI   UCBTBYT4,X'03'           3400 SERIES DRIVE         99223 24070003
         BNE   ETO21400                 NO - BRANCH               99223 24080003
         CLI   UCBSENSN,K24             IS IT 3420                99223 24090003
         BNE   ETO21400                 NO - BRANCH               99223 24092003
         USING UCBMT,R7                 SET UP ADDRESSABILITY     99223 24094003
         L     R7,UCBXTN                GET EXTENSION ADDRESS     99223 24096003
         LH    R7,K8(R7)                GET ID OF CREATING DRIVE  99223 24098003
         DROP  R7                                                 99223 24098403
         CVD   R7,DXCCW2                CONVERT ID                99223 24098803
         UNPK  FL2ID,DXCCW2             ID IN EBCDIC              99223 24099203
         OI    FL2ID+K4,ZONEOF          REMOVE SIGN BITS          99223 24099603
ETO21400 EQU   *                        WRITE LABEL                     24100021
         SPACE 1                                                        24200021
*                   WRITE HEADER LABEL 2                                24300021
         SPACE 1                                                        24400021
         MVC   DXCCW1,ANOPCCW           GET BASIC CCW                   24500021
         ST    RCORE,DXCCW1             ADDRESS OF WRITE AREA           24600021
         MVI   DXCCW1,CCWWRTAP          WRITE COMMAND                   24700021
         BAL   R8,ETO22100              GO WRITE FILE LABEL 2           24800021
         BC    12,ETO24000              IF I/O ERROR, GO NOTIFY THE OP  24900021
         SPACE 1                                                        25000021
*                   SEE IF USER LABELS ARE TO BE PROCESSED              25100021
         SPACE 1                                                        25200021
ETO21500 EQU   *                                                        25300021
         TM    JFCBLTYP,JFCBUL          BRANCH IF NOT 'AUL' OR          25400021
         BNO   ETO21900                 'SUL' AS LABEL TYPE             25500021
         TM    DCBMACRF,DCBMEXCP        IS THIS EXCP                    25600021
         BZ    ETO21600                 NO, GO                          25700021
         TM    DCBMACRF,DCBMFOUN        DOES DCB HAVE FOUNDATION EXT.   25800021
         BZ    ETO21900                 NO, GO                          25900021
ETO21600 EQU   *                                                        26000021
         L     R7,DCBEXLST              PICK UP EXIT LIST FROM DCB      26100021
         LA    R7,K0(K0,R7)             ZERO HI ORDER BYTE OF EXIT LIST 26200021
         LTR   R7,R7                    IS THE EXIT LIST ZERO           26300021
         BZ    ETO21900                 YES, GO TO WRITE TAPE MARK      26400021
ETO21700 CLI   K0(R7),XLOUHL            IS THIS ACTIVE EXIT 2           26500021
         BE    ETO22300                 YES, PROCESS USER LABELS        26600021
         CLI   K0(R7),XLOUHL+LASTNTRY   SEE IF LAST IND ALSO ON         26700021
         BE    ETO22300                 YES, PROCESS USER LABELS        26800021
         TM    K0(R7),LASTNTRY          IS THIS LAST ENTRY IN LIST      26900021
         LA    R7,K4(K0,R7)             POINT TO NEXT ENTRY             27000021
         BC    12,ETO21700              IF NOT,LAST,CHECK NEXT ENTRY    27100021
ETO21800 EQU   *                                                        27200021
         SPACE 1                                                        27300021
*                   WRITE TAPE MARK FOLLOWING HEADER LABELS             27400021
         SPACE 1                                                        27500021
ETO21900 MVC   DXCCW1(K16),AWTMCCWW     SET UP CCW TO WRITE TAPE MARK   27600021
         BAL   R8,ETO22100              GO TO WRITE TAPE MARK           27700021
         BC    12,ETO24000              IF I/O ERROR,GO NOTIFY THE OPER 27800021
         MVI   DXCCW1+K4,CCWSILI        RESET CHAIN COMMAND FLAG IN CCW 27900021
         SPACE 1                                                        28000021
*                   EXIT                                                28100021
         LA    R7,MOD2H2F               SET R7 TO TTR                   28200021
ETO22000 SR    RET,RET                  ZERO RETURN REG                 28300021
         LA    RWTGC,DXXENTRY           SET R8 FOR RES RTN              28400021
         LA    RWTG,DXXAREA             POINT TO EOV WTG                28500021
         IECRES XCTL,(R7)               GO TO NEXT MODULE               28600021
         SPACE 1                                                        28700021
*                   CLOSED SUBROUTINE TO ISSUE I/O OPERATIONS           28800021
         SPACE 1                                                        28900021
*                        IT IS ASSUMED THAT ALL CONTROL BLOCKS          29000021
*                        HAVE ALREADY BEEN SET UP                       29100021
         SPACE 1                                                        29200021
*                             BAL  R8,PRHR50                            29300021
*                             RETURN                                    29400021
         SPACE 1                                                        29500021
ETO22100 EQU   *                                                        29600021
         EXCP  DXIOB                    ISSUE I/O OPERATION             29700021
ETO22200 WAIT  ,ECB=DXECB               WAIT FOR COMPLETION OF I/O OPER 29800021
         TM    DXECB,ECBNOERR           IS THERE AN UNUSUAL I/O COND    29900021
         BR    R8                       RETURN TO CALLER                30000021
*                   EXIT TO USER LABEL HANDLING ROUTINE                 30100021
ETO22300 EQU   *                                                        30200021
         L     R7,K0(K0,R7)             PICK UP EXIT ADDRESS            30300021
         LR    RC,R7                    SET UP REG 12 TO PASS EXIT ADR  30400021
         LA    R7,K0(K0,R7)             ZERO THE HI ORDER BYTE          30500021
         LTR   R7,R7                    IS EXIT ADDR ZERO IF ACTIVE     30600021
         BZ    ETO21900                 YES,DO NOT PROCESS USER LABELS  30700021
         EJECT                                                          30800021
*********************************************************************** 30900021
*                                                                     * 31000021
*                          FUNCTION PROLOG                            * 31100021
*                                                                     * 31200021
*********************************************************************** 31300021
*                                                                     * 31400021
* FUNCTION NAME -                                                     * 31500021
*   PREPARE FOR USER LABELING ROUTINE FUNCTION.                       * 31600021
*                                                                     * 31700021
* (STATUS) -                                                          * 31800021
*    NOT APPLICABLE                                                   * 31900021
*                                                                     * 32000021
         AIF   ('&LIB' NE 'LIB1').LIB22F0                               32050000
* FUNCTION -                                                          * 32100021
*                    1. GETMAIN FOR AREA TO BE USED FOR -             * 32200021
*                       A) 72 BYTE WORK AREA                          * 32300021
*                       B) 80 BYTE LABEL BUFFER                       * 32400021
*                       C) 16 BYTE PARAMETER LIST                     * 32500021
*                                                                     * 32600021
*                    2. OUTPUT HEADER LABELS, THIS LOAD FIRST         * 32700021
*                       SYNCHS TO APPROPRITE USER EXIT TO FORMAT USER * 32800021
*                       LABELS AND UPON RETURN REACTS ACCORDING TO THE* 32900021
*                       CODE RETURNED BY THE USER -                   * 33000021
*                       0 - DO NOT WRITE LABEL, DISCONTINUE USER LABEL* 33100021
*                           PROCESSING (I.E. RETURN TO CALLER OF THIS * 33200021
*                           ROUTINE).                                 * 33300021
*                       4 - WRITE LABEL,THEN DISCONTINUE UL PROCESSING* 33400021
*                       8 - WRITE LABEL,AND IF LESS THAN 8 LABELS HAVE* 33500021
*                           BEEN CREATED RETURN TO USER.  IF 8 LABELS * 33600021
*                           HAVE BEEN CREATED, UL PROCESSING IS ENDED * 33700021
*                                                                     * 33800021
*                    3. IF THERE IS A WRITE ERROR THIS LOAD           * 33900021
*                       SYNCHS TO USER WITH A PARAMETER LIST WHICH    * 34000021
*                       (IN THE 3RD ENTRY) CONTAINS AN ERROR FLAG AND * 34100021
*                       A POINTER TO STATUS INFO (CSW STATUS).  AFTER * 34200021
*                       THE USER HAS HAD THE OPPORTUNITY TO EXAMINE   * 34300021
*                       ERROR INFO, THIS ROUTINE REACTS AS FOLLOWS -  * 34400021
*                       UL PROCESSING IS ENDED.                       * 34500021
*                                                                     * 34600021
*                    4. FOR ASCII TAPE, LABELS ARE TRANSLATED BEFORE  * 34700021
*                       WRITING.                                      * 34800021
*                                                                     * 34900021
.LIB22F0 ANOP                                                           34910000
         AIF   ('&LIB' EQ 'LIB1').LIB12F0                               34920000
* FUNCTION -                                                          * 34950000
*                    1. GETMAIN FOR AREA TO BE USED FOR -             * 34960000
*                       A) 72 BYTE WORK AREA                          * 34970000
*                       B) 80 BYTE LABEL BUFFER                       * 34980000
*                       C) 16 BYTE PARAMETER LIST                     * 34990000
*                                                                     * 34992000
*                    2. OUTPUT HEADER LABELS, THIS LOAD FIRST         * 34994000
*                       SYNCHS TO APPROPRITE USER EXIT TO FORMAT USER * 34996000
*                       LABELS AND UPON RETURN REACTS ACCORDING TO THE* 34998000
*                       CODE RETURNED BY THE USER -                   * 34998400
*                       0 - DO NOT WRITE LABEL, DISCONTINUE USER LABEL* 34998800
*                           PROCESSING (I.E. RETURN TO CALLER OF THIS * 34999200
*                           ROUTINE).                                 * 34999600
*                       4 - WRITE LABEL,THEN DISCONTINUE UL PROCESSING* 34999700
*                       8 - WRITE LABEL,AND IF LESS THAN 8 LABELS HAVE* 34999800
*                           BEEN CREATED RETURN TO USER.  IF 8 LABELS * 34999900
*                           HAVE BEEN CREATED, UL PROCESSING IS ENDED * 35033200
*                                                                     * 35043200
*                    3. IF THERE IS A WRITE ERROR THIS LOAD           * 35053200
*                       SYNCHS TO USER WITH A PARAMETER LIST WHICH    * 35063200
*                       (IN THE 3RD ENTRY) CONTAINS AN ERROR FLAG AND * 35065200
*                       A POINTER TO STATUS INFO (CSW STATUS).  AFTER * 35065600
*                       THE USER HAS HAD THE OPPORTUNITY TO EXAMINE   * 35066000
*                       ERROR INFO, THIS ROUTINE REACTS AS FOLLOWS -  * 35066400
*                       UL PROCESSING IS ENDED.                       * 35066500
*                                                                     * 35066600
*                    4. FOR ASCII TAPE, LABELS ARE TRANSLATED BEFORE  * 35077700
*                       WRITING.                                      * 35087700
*                                                                     * 35088100
*                    5. DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A   * 35088500
*                       DEB VALIDITY CHECK ROUTINE WHICH MAINTAINS    * 35088700
*                       AND UPDATEA A TABLE OF VALID DEB POINTERS IN  * 35098800
*                       PROTECTED CORE (LSQS).                        * 35109100
*                                                                     * 35119200
.LIB12F0 ANOP                                                           35149500
* ENTRY POINTS -                                                      * 35179800
*     NO CHANGES (SEE PREVIOUS FUNCTION PROLOG).                      * 35189900
*                                                                     * 35200021
* INPUT -                                                             * 35300021
*     NO CHANGES (SEE PREVIOUS FUNCTION PROLOG).                      * 35400021
*                                                                     * 35500021
* OUTPUT -                                                            * 35600021
*     NO CHANGES (SEE PREVIOUS FUNCTION PROLOG).                      * 35700021
*     USER LABEL WRITTEN ON TAPE.                                     * 35800021
*                                                                     * 35900021
* EXTERNAL REFERENCES -                                               * 36000021
*      TRANSLATE SVC MACRO.                                           * 36100021
*      SYNCH TO USER  EXIT.                                           * 36200021
*                                                                     * 36300021
* EXITS, NORMAL -                                                     * 36400021
*    RETURN TO CALLER THEN REFER TO THE PRECEEDING MODULE PROLOG --   * 36500021
*    EOV TAPE OUT MOUNT AHEAD FUNCTION.                               * 36600021
*                                                                     * 36700021
* EXITS, ERROR -                                                      * 36800021
*     SYNCH TO USER EXIT ROUTINE WITH PARAMETER LIST.                 * 36900021
*                                                                     * 37000021
* TABLES/WORK AREAS -                                                 * 37100021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 37200021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 37300021
*                                                                     * 37400021
* ATTRIBUTES -                                                        * 37500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37600021
*                                                                     * 37700021
* CHARACTER CODE DEPENDENCY -                                         * 37800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 37900021
*                                                                     * 38000021
         AIF   ('&LIB' NE 'LIB1').LIB22F1                               38050000
* NOTES -                                                             * 38100021
*        1. ALL EOV MODULES DEFINE THE 536 BYTES IN THE SAME FORMAT   * 38200021
*           INDICATED IN DSECT 'FORCORE'. SMALLER AREA FOR OPEN/CLOSE * 38300021
*                                                                     * 38400021
.LIB22F1 ANOP                                                           38410000
         AIF   ('&LIB' EQ 'LIB1').LIB12F1                               38420000
* NOTES -                                                             * 38450000
*        1. ALL EOV MODULES DEFINE THE 544 BYTES IN THE SAME FORMAT   * 38460000
*           INDICATED IN DSECT 'FORCORE'. SMALLER AREA FOR OPEN/CLOSE * 38470000
*                                                                     * 38480000
.LIB12F1 ANOP                                                           38490000
*********************************************************************** 38500021
         EJECT                                                          38600021
*********************************************************************** 38700021
*  OBTAIN USER CORE FOR WORK AREA, LABEL BUFFER, AND PARAMETER          38800021
*  LIST AREA (72+80+16).                                                38900021
*                                                                       39000021
         GETMAIN R,LV=USERL,SP=250                                      39100021
*                                                                       39200021
         USING ULWK,R1                                                  39300021
         STM   RPAR,RC,ULWK             SAVE REGS (INCLUDES DCB EXIT    39400021
*                                       LIST FOR USER LABEL PROCESSING  39500021
         DROP  R1                                                       39600021
         LR    RUCB,R1                  RUCB POINTS TO AREA OBTAINED    39700021
         USING ULWK,RUCB                                                39800021
         LA    R1,CHAR0                 INITIALIZE COUNT                39900021
         STH   R1,ULCNT                 AND SAVE FOR LATER USE          40000021
*                                                                       40100021
*  OUTPUT LABEL PROCESSING                                              40200021
         MVI   ULBUFR,BLANK             SET LABEL BUFFER AREA           40300021
         MVC   ULBUFR+K1(K79),ULBUFR    TO BLANKS                       40400021
ETO22400 EQU   *                                                        40500021
         TM    JFCBLTYP,JFCBAL+JFCBUL   ANSI USER LABELS SPEC.          40600021
         BO    ETO22500                 YES, SKIP LABEL COUNTING        40700021
         LH    R1,ULCNT                 PICK UP PREVIOUS COUNT          40800021
         LA    R1,K1(K0,R1)             INCREMENT BY 1                  40900021
         STH   R1,ULCNT                 SAVE UPDATED COUNT              41000021
         CLI   ULCNT+K1,MAXNOLAB        TEST,BR IF MAX NBR OF UL        41100021
         BH    ETO23100                 ALREADY PROCESSED               41200021
ETO22500 EQU   *                        INITIALIZE BUFFER HEADING       41300021
         MVC   ULBUFR(K3),UHLCON        SET 'UHL' IN BUFFER             41400021
ETO22600 EQU   *                                                        41500021
         MVC   ULBUFR+K3(K1),ULCNT+K1   ESTABLISH LABEL NUMBER IN BUFFR 41600021
         BAL   R8,ETO23200              GO TO SYNCH TO USER             41700021
*                                                                       41800021
*                                                                       41900021
         LTR   RF,RF                    TEST,BR IF LABEL NOT            42000021
         BZ    ETO23100                 TO BE WRITTEN                   42100021
*  RESET FIRST 4 CHAR OF LABEL THEN                                     42200021
*  ESTABLISH CHANNEL PROGRAM TO WRITE USER LABEL                        42300021
*                                                                       42400021
*                                                                       42500021
         MVC   ULBUFR(K3),UHLCON        SET 'UHL' IN LABEL              42600021
ETO22700 EQU   *                                                        42700021
         TM    JFCBLTYP,JFCBAL+JFCBUL   IF 'AUL' SPECIFIED, BYPASS      42800021
         BO    ETO22800                 RESTORING LABEL NUMBER          42900021
         MVC   ULBUFR+K3(K1),ULCNT+K1   LABEL NUMBER IN LABEL           43000021
ETO22800 EQU   *                        POINT TO LABEL BUFFER           43100021
         LA    R1,ULBUFR                POINT CCW TO LABEL BUFFER       43200021
         ST    R1,DXCCW1                SAVE ADDRESS                    43300021
         MVI   DXCCW1,CCWWRTAP          WRITE OP-CODE TO CCW            43400021
         MVC   DXCCW1+K4(K4),ANOPCCW+K4  80-CHAR LENGTH                 43500021
         TM    JFCBLTYP,JFCBAL+JFCBUL   ANSI USER LABEL SPEC.           43600021
         BNO   ETO22900                 NO, BYPASS TRANSLATE            43700021
*   TRANSLATE LABEL BEFORE PROCESSING                                   43800021
         XLATE (R1),K80,TO=A            TRANSLATE USER LABEL            43900021
ETO22900 EQU   *                        GO WRITE LABEL                  44000021
         BAL   R8,ETO22100              GO TO ISSUE EXCP                44100021
*  ERROR CHECKING                                                       44200021
         BZ    ETO23000                 BR IF ERROR                     44300021
         TM    IOBSTAT0,CSWUNITX        CHECK FOR UNIT EXCEPTION        44400021
*                                       WRITING BEYOND EOT REFLECTOR    44500021
         BO    ETO23000                 CREATING HEADERS                44600021
*                                                                       44700021
*                                                                       44800021
         CLI   ULRETCOD,WRITNEXT        TEST,BR IF USER RETURNED A CODE 44900021
         BE    ETO22400                 TO CONTINUE UL PROCESSING       45000021
*  OTHERWISE, IT IS ASSUMED THE USER RETURNED A CODE = 4, I.E. NO       45100021
*  FURTHER UL PROCESSING.                                               45200021
         B     ETO23100                 UNCONDITIONAL BRANCH            45300021
*                                                                       45400021
ETO23000 EQU   *                                                        45500021
*  ERROR WHEN ATTEMPTING TO WRITE LABEL.  GO TO USER WITH ERROR         45600021
*  INDICATIONS, THEN TERMINATE UL PROCESSING (RETURN CODE NOT           45700021
*  EXAMINED).                                                           45800021
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   45900021
         ST    R1,ULPARM+K8             IN PARAMETER LIST               46000021
         OI    ULPARM+K8,LASTNTRY+ERROROUT  FLAG IN ERROR               46100021
         BAL   R8,ETO23300              GO TO SYNCH TO USER (BUFFER     46200021
*                                       CONTAINS LABEL UNABLE TO WRITE) 46300021
*                                                                       46400021
ETO23100 EQU   *                                                        46500021
*                                                                       46600021
*                                                                       46700021
         LR    R1,RUCB                  RUCB PTR TO AREA TO BE FREED    46800021
         LM    RPAR,RC,ULWK             RESTORE REGS 5-10 AND 12        46900021
         FREEMAIN R,LV=USERL,SP=250,A=(1)  FREE USER LABEL WORK AREA,  C47000021
                                        LABEL BUFFER AND PARAMETER LIST 47100021
         SPACE 2                                                        47200021
         B     ETO21800                 GO WR TM AFTER UL               47300021
         SPACE 2                                                        47400021
*                                                                       47500021
*                                                                       47600021
ETO23200 EQU   *                                                        47700021
         XC    ULPARM+K8(K4),ULPARM+K8  ZERO ERROR IND                  47800021
ETO23300 EQU   *                                                        47900021
         LA    R1,ULBUFR                POINT TO LABEL BUFFER           48000021
ETO23400 EQU   *                                                        48100021
         STM   R1,RDCB,ULPARM           PTRS TO LABEL BUFFER AND DCB    48200021
*                                       IN PARAMETER LIST               48300021
         XC    ULTOTPTR(K4),ULTOTPTR    ZERO TOTALING ENTRY             48400021
         MVI   ULDCBPTR,K0              CLEAR FLAG BYTE                 48500021
         AIF   ('&LIB' NE 'LIB1').LIB22F2                               48550000
         L     R7,DCBDEBAD              GET ADDRESS OF USER'S DEB       48600021
.LIB22F2 ANOP                                                           48650000
         AIF   ('&LIB' EQ 'LIB1').LIB12F2                               48660000
         L     R7,DXPDEBAD              LOAD PROTECTED DEB ADDR  Y01021 48670000
.LIB12F2 ANOP                                                           48680000
*                                                                       48700021
ETO23500 EQU   *                                                        48800021
         TM    DCBMACRF,DCBMEXCP        CK IF USING EXCP                48900021
         BO    ETO23600                 EXCP, SKIP TOTALING             49000021
         TM    DCBOPTCD,DCBOPTT         CK IF TOTALING SPECIFIED        49100021
         BZ    ETO23600                 BR IF NO TOTALING               49200021
*                                                                       49300021
         L     R7,K40(R7)               GET PTR TO TOTALING AREA        49400021
         USING TOTSAVWA,R7              ESTABLISH BASE FOR AREA         49500021
         MVC   ULTOTPTR(K4),TOTEOVPT    TOTLING PTR TO PARM LIST        49600021
         DROP  R7                       DROP BASE                       49700021
*                                                                       49800021
ETO23600 EQU   *                                                        49900021
         LA    R1,ULPARM                POINT TO PARAMETER LIST         50000021
*  FIND  SVRB                                                           50100021
*     SAVE REGS                                                         50200021
*         LOAD USER REGS,SET LOCK BIT                                   50300021
*               SYNCH TO USER                                           50400021
*         RESTORE REGS,RESET LOCK BIT                                   50500021
*     RETURN TO CALLER                                                  50600021
*                                                                       50700021
         L     RF,ULREQ                 PTR TO USER'S LABEL ROUTINE     50800021
         L     R7,CVTPTR                PTR TO CVT                      50900021
         L     R7,CVTTCBP-CVT(,R7)      PTR TO TCB PTRS                 51000021
         L     R7,K4(,R7)               PTR TO CUR TCB                  51100021
         L     R7,K0(,R7)               PTR TO SVRB                     51200021
         USING RBSECT,R7                                                51300021
         STM   RDCB,RD,RBEXSAVE         SAVE REGS 2-13                  51400021
         NI    DCBOFLGS,X'FF'-DCBOLOCK  SET LOCK BIT TO ZERO            51500021
         L     RD,K28(,R7)              PTR TO PREVIOUS RB              51600021
         TM    K10(RD),X'C0'            IS PREVIOUS A PRB               51700021
         BNO   ETO23700                 YES,BRANCH                      51800021
         LR    R7,RD                    USE PREVIOUS RB                 51900021
ETO23700 EQU   *                                                        52000021
         LM    RDCB,RD,RBGRS2           RESTORE USER REGS               52100021
         SYNCH (15)                                                     52200021
         L     R7,CVTPTR                PTR TO CVT                      52300021
         L     R7,CVTTCBP-CVT(,R7)      PTR TO TCB PTRS                 52400021
         L     R7,K4(,R7)               PTR TO CUR TCB                  52500021
         L     R7,K0(,R7)               PTR TO SVRB                     52600021
         LM    RDCB,RD,RBEXSAVE         RESTORE REGS 2-13               52700021
         DROP  R7                                                       52800021
         OI    DCBOFLGS,DCBOLOCK        SET LOCK BIT TO ONE             52900021
         ST    RF,ULWK1                 SAVE RETURN CODE                53000021
         AIF   ('&LIB' EQ 'LIB1').LIB12F3                               53050000
         DEBCHK (RDCB)                  VALIDATE DEB             Y01021 53080000
         LR    RDEB,R1                  LOAD VERIFIED DEB ADDR   Y01021 53080400
         ST    RDEB,DXPDEBAD            STORE DEBAD IN WORKAREA  Y01021 53082000
         L     RF,ULWK1                 RESTORE RETURN CODE      Y01021 53090000
.LIB12F3 ANOP                                                           53092000
         BR    R8                       RETURN                          53100021
*                                                                       53200021
         SPACE 1                                                        53300021
*                                                                       53400021
         SPACE                                                          53500021
*EOV HAS FOUND AN UNCORRECTABLE I/O ERROR, BUT WILL ASK FOR NEW         53600021
*VOLUME RATHER THAN ABEND WITH '137'                                    53700021
         SPACE                                                          53800021
ETO24000 EQU   *                        I/O ERROR DURING CONTROL OPERAT 53900021
         MVC   DXVOLSR2,SCRATC0W                                        54000021
         LA    R7,MOD2N2F               SET R7 TO TTR                   54100021
         B     ETO22000                 GO XCTL                         54200021
         SPACE 1                                                        54300021
*                   CONSTANTS                                           54400021
         LTORG                                                          54500021
         SPACE 1                                                        54600021
AWTMCCWW CCW   X'1F',0,X'60',80         WRITE TAPE MARK CCW             54700021
ANOPCCW  CCW   X'03',0,X'20',80         NOP, COUNT FOR WRITE CCW        54800021
         DS    0H                                                       54900021
AGRTR30W DC    X'8000'                  VALUE IN LABEL WHEN LRECLGT 32K 55000021
ATRTCH0W DC    C' CET'                  CONVERSION,EVEN PARITY,TRAN     55100021
ARECFM0W EQU   *-1                      RECFM TRANSLATE TABLE           55200021
         DC    C'VFU'                   VARIABLE,FIXED,UNKNOWN REC FMT  55300021
ABLKA0W  DC    C' SBR'                  BLK AATTRB TRANSLATE TABLE      55400021
*                                       CONS                            55500021
HDR0W    DC    C'HDR'                   CHARACTERS HDR                  55600021
BITOFF0W DC    F'127'                   MASK FOR BUFOFF = L BIT         55700021
SCRATC0W DC    C'SCRTCH'                NON SPECIFIC VOLUME             55800021
*                                                                       55900021
UHLCON   DC    C'UHL'                   HEADER LABEL CONSTANT           56000021
*                                                                       56100021
XCTLTA2F DS    0D                       START OF XCTL TABLE             56200021
MOD2H2F  DC    C'2H'                    ID OF MNT NEXT VOL MOD          56300021
         DC    X'00000000'              TTRL                            56400021
MOD2N2F  DC    C'2N'                    ID OF INVLD TAPE RECOVERY MOD   56500021
         DC    X'00000000'              TTRL                            56600021
         DC    X'0000'                  MARK END OF TABLE               56700021
PATCHL2F EQU   IFG0552F+1020-*          CALC LENGTH OF PATCH AREA       56800021
PATCH2F  DC    (PATCHL2F)X'00'          ZERO PATCH AREA                 56900021
         DC    C'055'                   SVC ID CODE                     57000021
         DC    AL1((XCTLTA2F-IFG0552F)/8)  DBL WRDS TO XCTL TABLE       57100021
         IECDSECS CVT,TCB,DCB,UCB,DEB,MAIN,USERLAB,USERTOT,RB,         X57200021
               TIOT,EXPAND=YES                                          57300021
         IECEQU                                                         57400021
         END                                                            57500021
