         TITLE ' IFG0552N  RECOVER FROM INVALID TAPE '                  00400021
         COPY  LCGASMSW                                                 00450000
*********************************************************************** 01600021
IFG0552N CSECT                                                          02000021
*********************************************************************** 02400021
*                                                                     * 02450021
*                                                                     * 03200021
*          RELEASE 25 DELETIONS/CHANGES                               * 03600021
*          RELEASE 24 DELETIONS/CHANGES                               * 04000021
*          RELEASE 23 DELETIONS/CHANGES                               * 04400021
*          RELEASE 22 DELETIONS/CHANGES                               * 04800021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 04850003
*0000628000,740000                                              SA64039 04900003
*          RELEASE 21 DELETIONS/CHANGES                               * 05200021
*0000                                                            A47338 05250021
*0000                                                            A51593 05300021
*0000600000,660500-661000,664500                                 SM4380 05350021
*                                                                     * 05600021
* STATUS CHANGE LEVEL 000                                             * 06000021
*                                                                     * 06400021
* FUNCTION -                                                          * 06800021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 07200021
*    RECOVER FROM INVALID TAPE AND ISSUE MSG TO SYS OPERATOR FUNCTION.* 07600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 08000021
*                                                                     * 08400021
* ENTRY POINTS -                                                      * 08800021
*   IFG0552N  - ENTRY POINT VIA THE RESIDENT XCTL FROM THE FOLLOWING- * 09200021
*   INITIAL ENTRY --                                                  * 09600021
*    IFG0552J - EMODVOL1 FUNCTION.                                    * 10000021
*    IFG0552L - CREATE STANDARD LABEL FUNCTION.                       * 10400021
*    IFG0552B - REWRITE VOLUME LABEL FUNCTION.                        * 10800021
*    IFG0552D - WRITE HEADER LABEL 1 OUTPUT FUNCTION.                 * 11200021
*    IFG0552F - HEADER LABEL PREPARATION FUNCTION.                    * 11600021
*    NSLEHDRO - INSTALLATION HEADER LABEL FUNCTION.                   * 12000021
*                                                                     * 12400021
* INPUT -                                                             * 12800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 13200021
*                                                                     * 13600021
* OUTPUT -                                                            * 14000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 14400021
*                                                                     * 14800021
* EXTERNAL REFERENCES -                                               * 15200021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 15600021
*            WAIT.                                                    * 16000021
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 16400021
*                                                                     * 16800021
* EXITS, NORMAL -                                                     * 17200021
*    EXIT VIA THE RESIDENT ROUTINE XCTL TO THE FOLLOWING --           * 17600021
*       IFG0551X - LABEL READER TO VERIFY NEW TAPE FUNCTION.          * 18000021
*       IFG0552P - WTO MESSAGE FUNCTION.                              * 18400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 18800021
*                                                                     * 19200021
* EXITS, ERROR -  NONE.                                               * 19600021
*                                                                     * 20000021
* TABLES/WORK AREAS -                                                 * 20400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 20800021
*                                                                     * 21200021
* ATTRIBUTES -                                                        * 21600021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 22000021
*                                                                     * 22400021
* CHARACTER CODE DEPENDENCY -                                         * 22800021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 23200021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 23600021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 24000021
*                                                                     * 24400021
* NOTES -                                                             * 24800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 25200021
*                                                                     * 25600021
*********************************************************************** 26000021
         EJECT                                                          26400021
*********************************************************************** 26800021
*                                                                     * 27200021
*                          FUNCTION PROLOG                            * 27600021
*                                                                     * 28000021
*********************************************************************** 28400021
*                                                                     * 28800021
* FUNCTION NAME -                                                     * 29200021
*    RECOVER FROM INVALID TAPE AND ISSUE WTO FUNCTION.                * 29600021
*                                                                     * 30000021
* (STATUS) -                                                          * 30400021
*    NOT APPLICABLE                                                   * 30800021
*                                                                     * 31200021
* FUNCTION -                                                          * 31600021
*           1. ISSUE MESSAGES TO SYSTEM OPERATOR FOR I/O ERR          * 32000021
*                AND/OR TO DEMOUNT INVALID TAPE                       * 32400021
*           2. UNLOAD CURRENT TAPE                                    * 32800021
*           3. ASK FOR A REMOUNT OF CORRECT TAPE                      * 33200021
*                 OR SCRATCH TAPE                                     * 33600021
*           4.  RETURN FROM NSL ROUTINE  (NSLEHDRO)                   * 34000021
*                                                                     * 34400021
* ENTRY POINTS -                                                      * 34800021
*     ENTERED FROM THE FOLLOWING --                                   * 35200021
*     EMODVOL1 FUNCTION.                                              * 35600021
*     CREATE STANDARD LABEL FUNCTION.                                 * 36000021
*     REWRITE VOLUME LABEL FUNCTION.                                  * 36400021
*     WRITE HEADER LABEL 1 OUTPUT FUNCTION.                           * 36800021
*     WRITE HEADER LABEL 2 OUTPUT FUNCTION.                           * 37200021
*     NSLEHDRO INSTALLATION HEADER LABEL ROUTINE.                     * 37600021
*                                                                     * 38000021
* INPUT -                                                             * 38400021
*      REGISTERS RUCB,RCORE,RDEB,RDCB,RTIOT.                          * 38800021
*                                                                     * 39200021
* OUTPUT -                                                            * 39600021
*        REGISTERS RUCB,RCORE,RDEB,RDCB,RTIOT.                        * 40000021
*        FORMATED WTO MESSAGE.                                        * 40400021
*                                                                     * 40800021
* EXTERNAL REFERENCES -                                               * 41200021
*              SVC 35 - WRITE TO OPERATOR ROUTINE.                    * 41600021
*                                                                     * 42000021
* EXITS, NORMAL -                                                     * 42400021
*    REFER TO THE PRECEEDING MODULE PROLOG --                         * 42800021
*    EOV TAPEOUT VERIFY NEW TAPE FUNCTION.                            * 43200021
*    WRITE TO OPERATOR FUNCTION.                                      * 43600021
*                                                                     * 44000021
* EXITS, ERROR - NONE.                                                * 44400021
*                                                                     * 44800021
* TABLES/WORK AREAS -                                                 * 45200021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 45600021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 46000021
*                                                                     * 46400021
* ATTRIBUTES -                                                        * 46800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 47200021
*                                                                     * 47600021
* CHARACTER CODE DEPENDENCY -                                         * 48000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 48400021
*                                                                     * 48800021
* NOTES -                                                             * 49200021
*        ON ENTRY TO THIS MODULE RET INDICATES WHICH MESSAGES         * 49600021
*        ARE REQUIRED                                                 * 50000021
*        RET = 4 DEMOUNT MSG NOT REQUIRED                             * 50400021
*        RET = 0 INDICATES DEMOUNT MSG FOLLOWED BY MOUNT              * 50800021
*        THE WORK AREA ECB (DXECB) IS CHECKED FOR AN ERROR IND,       * 51200021
*        IF THE ECB IS POSTED IN ERR, AN I/O ERR MSG WILL             * 51600021
*        PRECEDE THE DEMOUNT MESSAGE                                  * 52000021
*                                                                     * 52400021
*********************************************************************** 52800021
         EJECT                                                          53200021
         BALR  RBASE,0                  ESTABLISH BASE                  53600021
         USING *,RBASE                                                  54000021
         USING FORCORE,RCORE                                            54400021
         USING DEB,RDEB                                                 54800021
         USING IHADCB,RDCB                                              55200021
         USING SRT,RUCB                                                 55600021
         USING CVT,RET                                                  56000021
         USING TIOENTRY,RTIOT                                           56400021
         L     RUCB,TIOESTTB            LOAD CURRENT UCB ADDR           56800021
*                                                                       57200021
         TM    DXOPCLSW,HEX40           IS ENTRY FROM NSL ROUTINE       57600021
         BO    ETO33000                 YES, BR                         58000021
*                                                                       58400021
         LTR   RET,RET                                                  58800021
         BNZ   ETO32700                 BR IF ONLY M MSG NEEDED         59200021
ETO32500 TM    DXECB,ECBNOERR           NEED I/O ERR MSG                59600021
         BO    ETO32600                 BR,NO ERROR MSG          SM4380 60000021
         MVC   MSGLSTSZ(ERRMSGLX),ERRMSGX  SET UP BASIC MSG             60400021
         MVC   MSGUN+K6,UCBNAME         MOVE IN DEVICE NAME             60800021
         MVC   MSGVOLSR+K6,SRTEVOLI     PUT IN SER NO                   61200021
         WTO   MF=(E,MSGLSTSZ)                                          61600021
ETO32600 MVC   MSGLSTSZ(DSMNTXL),DSMNTX  BASIC DEMOUNT MSG              62000021
         MVC   MSGUN,UCBNAME            MOVE UNIT ADR TO MSG            62400021
         WTO   MF=(E,MSGLSTSZ)          GO WRITE MSG                    63200021
ETO32700 NI    DXDCBDEB,X'FF'-DCBIFPIO  TURN OFF PERM ERR FLG           63600021
         MVI   DXCCW1+K4,CCWSILI        SET SLI BIT                     64000021
         MVI   DXCCW1,CCWRUN            SET UP FOR UNLOAD               64400021
         EXCP  DXIOB                                                    64800021
         WAIT  ECB=DXECB                                                65200021
         OI    UCBFL1,UCBNOTRD          SET UCB NOT READY               65600021
         MVC   MCSFLAGS(FL10GXL),FLAG10GX  SET UP MOUNT MSG             66000021
         OI    UCBDMCT,UCBMOUNT         SET MOUNT FLAG IN UCB    A51593 66010021
         MVC   MSGVOLSR,DXVOLSR2        MOVE SER NO TO MSG              66400021
         MVC   DXRETMOD,MOD1X2N         SET RETURN TO LBL VER MOD       66800021
         OI    DXOPCLSW,K8              INDICATE WRITE BACK JFCB        67200021
         OI    JFCBTSDM,JFCVSL          INDICATE VOL SER LIST CHANGED   67600021
         LA    RET,K8                   SET RET TO UPDATE JFCB          68000021
ETO32800 LA    R7,MOD2P2N               SET R7 TO TTR                   68400021
ETO32900 LA    RWTG,DXXAREA             POINT TO EOV WTG                68800021
         LA    RWTGC,DXXENTRY           SET R8 FOR RES RTN              69200021
         IECRES XCTL,(R7)               GO TO NEXT MODULE               69600021
ETO33000 EQU   *                                                        70000021
         LR    RES,R8                   RESTORE R5  FOR RES RTN         70400021
         MVC   DXXMODNM(K6),IGG2N       RESTORE XCTL NAME               70800021
         TM    UCBDMCT,UCBMOUNT         WAS NSL CHK OK                  71200021
         BO    ETO32600                 BR IF NO                        71600021
         LA    RET,K4                   IND RING CHK TO 551X            72000021
         LA    R7,MOD1X2N               GET ID OF 551X                  72400021
         B     ETO32900                 GO XCTL                         72800021
         LTORG                                                          73200021
IGG2N    DC    C'IFG055'                1ST 6 CHAR OF MOD NAME          73600021
DSMNTX   WTO   'IEC014E D UUU',MF=L,DESC=3,ROUTCDE=(3)          SA64039 74000003
DSMNTXL  EQU   *-DSMNTX                                                 74400021
FLAG10GX DC    X'8000'                  MCS FLAGS                       74800021
         DC    C'IEC001A M UUU,SCRTCH'  BASIC MOUNT MSG                 75200021
FL10GXL  EQU   *-FLAG10GX                                               75600021
ERRMSGX  WTO   'IEC012I I/O ERR UUU,VOLSER',MF=L,                      X76000021
               DESC=4,ROUTCDE=(3,10)                                    76400021
ERRMSGLX EQU   *-ERRMSGX                                                76800021
XCTLTA2N DS    0D                       START OF XCTL TABLE             77200021
MOD1X2N  DC    C'1X'                    ID OF TAPEOUT LABEL READER MOD  77600021
         DC    X'00000000'              TTRL                            78000021
MOD2P2N  DC    C'2P'                    ID FOR WTO MOD                  78400021
         DC    X'00000000'              TTRL                            78800021
         DC    X'0000'                  END OF TABLE                    79200021
PATCHL2N EQU   IFG0552N+1020-*          LENGTH OF PATCH AREA            79600021
PATCH2N  DC    (PATCHL2N)X'00'          ZERO PATCH AREA                 80000021
         DC    C'055'                   SVC CODE FOE EOV                80400021
         DC    AL1((XCTLTA2N-IFG0552N)/8)  DBL WRDS TO TABLE            80800021
         IECDSECS CVT,TCB,DCB,UCB,DEB,MAIN,TIOT,EXPAND=YES              81200021
         IECEQU                                                         81600021
         END                                                            82000021
