         TITLE 'IFG0552R - EOV TAPE INPUT STD TRAILER LABEL FUNCTION'   00100021
         COPY  LCGASMSW                                                 00200000
IFG0552R CSECT                                                          00400021
*                                                                       00500000
IGG0550B EQU   *                        ENTRY PT FOR 'NSLETRLI' RET     00600021
*                                                                       00700021
*********************************************************************** 00800021
*                                                                     * 00900021
*                                                                     * 01000021
*          RELEASE 25 DELETIONS/CHANGES                               * 01100021
*          RELEASE 24 DELETIONS/CHANGES                               * 01200021
*          RELEASE 23 DELETIONS/CHANGES                               * 01300021
*          RELEASE 22 DELETIONS/CHANGES                               * 01400021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 01410021
*0000016600,523000-532000                                       SA69185 01420021
*0000237500,238500-238940,563100-563488                          S21940 01430021
*          RELEASE 21 DELETIONS/CHANGES                               * 01500021
*0000                                                            M0027  01550021
*0000566000-588000,660000                                        A38013 01570021
*                                                                M0110  01577021
*                                                                M0147  01584021
*                                                                A46383 01591021
*0000377000,520000-541000                                       SA55619 01593000
*                                                                     * 01600021
*          OS/VS2 RELEASE 01 DELETIONS/CHANGES                          01650000
*000051250                                                       YM3271 01670000
*                                                                     * 01671021
*          VS1 RELEASE 03.1 DELETIONS/CHANGES                         * 01675021
*SEE SA69185                                                    XA04640 01676021
*          OS/VS1 RELEASE 02.6 DELETIONS/CHANGES                        01680002
*0000016100,016800,414000                                       XA01537 01690002
* STATUS CHANGE LEVEL 000                                             * 01700021
*                                                                     * 01800021
* FUNCTION -                                                          * 01900021
*    THIS MODULE CONTAINS THE FOLLOWING FUNCTIONS-                    * 02000021
*       1) 'EOV TAPE INPUT STANDARD TRAILER LABEL FUNCTION', PART I;  * 02100021
*       2) 'EOV TAPE INPUT VOLUME DISPOSITION FUNCTION'.              * 02200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR DETAILS.           * 02300021
*                                                                     * 02400021
* ENTRY POINTS -                                                      * 02500021
*         IFG0552R - REFER TO 'INPUT' FOR A LIST OF CALLING MODULES   * 02580021
*                    AND THEIR RESPECTIVE ENTRY CONDITIONS. NOTE THAT * 02660021
*                    IGG0550B IS AN ALIAS FOR THIS MODULE AND IS USED * 02740021
*                    AS A RETURN ADDRESS FOR NSLETRLI.                * 02820021
* INPUT -                                                             * 02900021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 03000021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 03100021
*    POINT PROCESSING IS TO BEGIN -                                   * 03200021
*        0 - ENTRY FROM IFG0551H OR IFG0551J TO VERIFY THE BLOCK      * 03270021
*            COUNT OF A STANDARD LABEL TAPE.                          * 03340021
*        4 - ENTRY FROM IFG0551H OR IFG0551J TO PROCESS EOV ON AN     * 03410021
*            NL TAPE, WHEN FEOV WAS ISSUED, OR WHEN THE DATA SET IS   * 03480021
*            SYSIN.                                                   * 03550021
*        8 - ENTRY FROM NSLETRLI TO PROCESS EOV ON AN NSL TAPE. THIS  * 03620021
*            BRANCH TABLE OFFSET IS INITIALIZED BY IFG0551H OR        * 03690021
*            IFG0551J PRIOR TO TRANSFERRING CONTROL TO NSLETRLI.      * 03760021
*       12 - ENTRY FROM NSLETRLI DURING DEFERRED NSL PROCESSING WHILE * 03830021
*            CLOSING A DCB. THIS BRANCH TABLE OFFSET IS INITIALIZED   * 03900021
*            BY IFG0202B PRIOR TO TRANSFERRING CONTROL TO NSLETRLI.   * 03970021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS' FOR ADDITIONAL INPUT.  * 04100021
*                                                                     * 04200021
* OUTPUT -                                                            * 04300021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 04400021
*                                                                     * 04500021
* EXTERNAL REFERENCES -                                               * 04600021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 04700021
*                    WAIT. REFER TO THE FOLLOWING 'FUNCTION PROLOGS'. * 04800021
*                                                                     * 05000021
* EXITS, NORMAL -                                                     * 05100021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 05200021
*                                                                     * 05300021
* EXITS, ERROR -                                                      * 05400021
*         IFG0550P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 05500021
*                    REFER TO 'OUTPUT' IN THE FOLLOWING 'FUNCTION     * 05600021
*                    PROLOGS' FOR A LIST OF ERROR CONDITIONS.         * 05700021
*                                                                     * 05800021
* TABLES/WORK AREAS -                                                 * 05900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 06000021
*                                                                     * 06100021
* ATTRIBUTES -                                                        * 06200021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 06300021
*                                                                     * 06400021
* CHARACTER CODE DEPENDENCY -                                         * 06500021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 06600021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 06700021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 06800021
*                                                                     * 06900021
* NOTES -                                                             * 07000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 07100021
*                                                                     * 07200021
*********************************************************************** 07300021
         EJECT                                                          07350021
*                                                                       07400021
*****    INTERNAL ERROR CODES                                           07500021
*                                                                       07600021
EABD146  EQU   146                      ERROR POS TO TRAILER LABELS     07700021
EABD147  EQU   147                      ERROR READING TRAILER LABELS    07800021
EABD148  EQU   148                      INCORRECT DCB BLOCK COUNT       07900021
EABD150  EQU   150                      ERROR POS TO END OF DATA SET    08000021
EABD180  EQU   180                      INVALID TRAILER LABEL READ      08100021
*                                                                       08200021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        08300021
         USING *,RBASE                                                  08400021
         USING FORCORE,RCORE                                            08500021
         USING IHADCB,RDCB                                              08600021
         USING UCB,RUCB                                                 08700021
         USING TIOENTRY,RTIOT                                           08800021
         USING DEB,RDEB                                                 08900021
         USING WTG,RWTG                                                 09000021
*                                                                       09100021
*****          DETERMINE TYPE OF ENTRY INTO MODULE                      09200021
*                                                                       09300021
         B     ETI00100(RET)            DETERMINE TYPE OF ENTRY TO MOD  09400021
ETI00100 EQU   *                                                        09500021
         B     ETI00200           ( 0)  BR IF SL ENTRY                  09600021
         B     ETI02100           ( 4)  BR IF NL ENTRY                  09700021
         B     ETI02050           ( 8)  BR IF NSL ENTRY DURING EOV      09800021
         B     ETI02700           (12)  BR IF NSL ENTRY DURING 'CLOSE'  09900021
*                                       ..FOR DEFERRED NSL PROCESSING   10000021
         EJECT                                                          10100021
*********************************************************************** 10200021
*                                                                     * 10300021
*                          FUNCTION PROLOG                            * 10400021
*                                                                     * 10500021
*********************************************************************** 10600021
*                                                                     * 10700021
* FUNCTION NAME -                                                     * 10800021
*    'EOV TAPE INPUT STANDARD TRAILER LABEL FUNCTION', PART I.        * 10900021
*                                                                     * 11000021
* (STATUS) -                                                          * 11100021
*    NOT APPLICABLE                                                   * 11200021
*                                                                     * 11300021
         AIF   ('&LIB' NE 'LIB1').LIB22R0                               11350000
* FUNCTION -                                                          * 11400021
*    1. POSITION TO AND READ TRAILER LABEL 1 (EOV1, EOF1, OR HDR1);   * 11500021
*    2. IF THE DCB CONTAINS A DEVICE-DEPENDENT SECTION, COMPARE THE   * 11600021
*       BLOCK COUNT IN THE DCB TO THE BLOCK COUNT IN THE LABEL,       * 11700021
*       PASSING CONTROL TO THE USER'S BLOCK COUNT EXIT ROUTINE VIA A  * 11800021
*       'SYNCH' MACRO (SVC 12) IF THE BLOCK COUNTS ARE UNEQUAL. THE   * 11900021
*       BLOCK COUNT EXIT INTERFACE IS AS FOLLOWS-                     * 12000021
*       REGISTERS ARE INITIALIZED FOR THE USER AS FOLLOWS-            * 12100021
*          0    - THE BLOCK COUNT IN THE TRAILER LABEL;               * 12200021
*          1    - ADDRESS OF THE DCB WITH THE INCORRECT BLOCK COUNT;  * 12300021
*          2-13 - USER'S REGISTERS AT ENTRY TO END-OF-VOLUME;         * 12400021
*          15   - USER'S BLOCK COUNT EXIT ROUTINE ADDRESS.            * 12500021
*       CONTROL BLOCK INDICATORS-                                     * 12600021
*          'DCBOFLGS' - X'02', OFF - THE 'LOCK' BIT IS TURNED OFF     * 12700021
*                       WHEN CONTROL IS PASSED TO THE USER AND IS     * 12800021
*                       TURNED BACK ON UPON RETURN.                   * 12900021
*       USER RETURN CODES (PASSED IN REGISTER 15)-                    * 13000021
*          0 - TERMINATE PROCESSING DUE TO INCORRECT BLOCK COUNT.     * 13100021
*    3. TRANSFER CONTROL TO PART II OF THIS FUNCTION TO PROCESS USER  * 13200021
*       LABELS IF THEY WERE SPECIFIED AND A VALID EXIT ROUTINE        * 13300021
*       ADDRESS EXISTS. USER LABELS ARE NOT PROCESSED IF 'DEFERRED    * 13400021
*       USER LABEL PROCESSING' HAS BEEN SPECIFIED AND END-OF-FILE     * 13500021
*       (EOF) HAS OCCURRED;                                           * 13600021
*    4. IF USER LABELS ARE NOT TO BE PROCESSED, POSITION THE TAPE     * 13700021
*       TO THE LOGICAL END OF THE  DATA SET (I.E., AT THE INTERBLOCK  * 13800021
*       GAP FOLLOWING THE TAPE MARK FOLLOWING THE TRAILER LABELS      * 13900021
*       (READ FORWARD) OR AT THE INTERBLOCK GAP PRECEDING HEADER      * 14000021
*       LABEL 1 (RDBACK).                                             * 14100021
*                                                                     * 14200021
.LIB22R0 ANOP                                                           14210000
         AIF   ('&LIB' EQ 'LIB1').LIB12R0                               14220000
* FUNCTION -                                                          * 14250000
*    1. POSITION TO AND READ TRAILER LABEL 1 (EOV1, EOF1, OR HDR1);   * 14260000
*    2. IF THE DCB CONTAINS A DEVICE-DEPENDENT SECTION, COMPARE THE   * 14270000
*       BLOCK COUNT IN THE DCB TO THE BLOCK COUNT IN THE LABEL,       * 14280000
*       PASSING CONTROL TO THE USER'S BLOCK COUNT EXIT ROUTINE VIA A  * 14290000
*       'SYNCH' MACRO (SVC 12) IF THE BLOCK COUNTS ARE UNEQUAL. THE   * 14292000
*       BLOCK COUNT EXIT INTERFACE IS AS FOLLOWS-                     * 14294000
*       REGISTERS ARE INITIALIZED FOR THE USER AS FOLLOWS-            * 14296000
*          0    - THE BLOCK COUNT IN THE TRAILER LABEL;               * 14298000
*          1    - ADDRESS OF THE DCB WITH THE INCORRECT BLOCK COUNT;  * 14298400
*          2-13 - USER'S REGISTERS AT ENTRY TO END-OF-VOLUME;         * 14298800
*          15   - USER'S BLOCK COUNT EXIT ROUTINE ADDRESS.            * 14299200
*       CONTROL BLOCK INDICATORS-                                     * 14299600
*          'DCBOFLGS' - X'02', OFF - THE 'LOCK' BIT IS TURNED OFF     * 14299700
*                       WHEN CONTROL IS PASSED TO THE USER AND IS     * 14299800
*                       TURNED BACK ON UPON RETURN.                   * 14299900
*       USER RETURN CODES (PASSED IN REGISTER 15)-                    * 14333200
*          0 - TERMINATE PROCESSING DUE TO INCORRECT BLOCK COUNT.     * 14343200
*    3. TRANSFER CONTROL TO PART II OF THIS FUNCTION TO PROCESS USER  * 14353200
*       LABELS IF THEY WERE SPECIFIED AND A VALID EXIT ROUTINE        * 14363200
*       ADDRESS EXISTS. USER LABELS ARE NOT PROCESSED IF 'DEFERRED    * 14365200
*       USER LABEL PROCESSING' HAS BEEN SPECIFIED AND END-OF-FILE     * 14365600
*       (EOF) HAS OCCURRED;                                           * 14366000
*    4. IF USER LABELS ARE NOT TO BE PROCESSED, POSITION THE TAPE     * 14366400
*       TO THE LOGICAL END OF THE  DATA SET (I.E., AT THE INTERBLOCK  * 14366500
*       GAP FOLLOWING THE TAPE MARK FOLLOWING THE TRAILER LABELS      * 14366600
*       (READ FORWARD) OR AT THE INTERBLOCK GAP PRECEDING HEADER      * 14377700
*       LABEL 1 (RDBACK).                                             * 14387700
*    5. DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A DEB VALIDITY CHECK* 14387800
*       ROUTINE WHICH MAINTAINS AND UPDATES A TABLE OF VALID DEB      * 14387900
*       POINTERS IN PROTECTED CORE (LSQS).                            * 14388000
*                                                                     * 14388100
.LIB12R0 ANOP                                                           14388500
* ENTRY POINTS -                                                      * 14388900
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 14400021
*                                                                     * 14500021
* INPUT -                                                             * 14600021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 14700021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 14800021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 14900021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 15000021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 15100021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 15200021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 15300021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 15400021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 15500021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 15600021
*                                                                     * 15700021
* OUTPUT -                                                            * 15800021
*    1. AT EXIT TO THE EOV TAPE INPUT VOLUME DISPOSITION FUNCTION-    * 15900021
*       REGISTER AND WORK AREA CONTENTS ARE VIRTUALLY THE SAME AS     * 16000021
*          AT INPUT;                                                  * 16100021
*       TAPE POSITION- REFER TO ITEM (4) UNDER 'FUNCTION'.            * 16200021
*    2. AT EXIT TO PROBLEM DETERMINATION MODULE IFG0550P-             * 16300021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 16400021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 16500021
*          ERROR CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE  * 16570021
*          INDICATED IN PARENTHESES)-                                 * 16640021
*          146 (137/08)- ERROR POSITIONING TO READ TRAILER LABEL 1.   * 16710021
*          147 (137/0C)- ERROR READING TRAILER LABEL 1.               * 16780021
*          148 (237/04)- DCB BLOCK COUNT IS INCORRECT AND EITHER NO   * 16850021
*                        BLOCK COUNT EXIT WAS PROVIDED, OR THE USER   * 16920021
*                        HAS INDICATED THAT PROCESSING SHOULD BE      * 16990021
*                        TERMINATED.                                  * 17060021
*          150 (137/10)- ERROR POSITIONING TO THE LOGICAL END OF THE  * 17130021
*                        DATA SET.                                    * 17200021
*          180 (137/1C) - INVALID TRAILER LABEL WAS READ.             * 17270021
*       WORK AREA INDICATORS-                                         * 17400021
*          'DXCALLID' - CONTAINS THE ID OF THIS MODULE.               * 17500021
*                                                                     * 17600021
* EXTERNAL REFERENCES -                                               * 17700021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 17800021
*                                                                     * 17900021
* EXITS, NORMAL -                                                     * 18000021
*         PART II OF THIS MODULE - TO DETERMINE THE DISPOSITION OF    * 18100021
*                                  THE VOLUME AT EOV.                 * 18200021
*                                                                     * 18300021
* EXITS, ERROR -                                                      * 18400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 18500021
*                                                                     * 18600021
* TABLES/WORK AREAS -                                                 * 18700021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 18800021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 18900021
*                                                                     * 19000021
* ATTRIBUTES -                                                        * 19100021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 19200021
*                                                                     * 19300021
* CHARACTER CODE DEPENDENCY -                                         * 19400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 19500021
*                                                                     * 19600021
* NOTES -                                                             * 19700021
*    PART II OF THIS FUNCTION- USER TRAILER LABEL PROCESSING- IS      * 19800021
*    CONTAINED IN MODULE IFG0552T.                                    * 19900021
*                                                                     * 20000021
*********************************************************************** 20100021
         EJECT                                                          20150021
*                                                                       20200021
ETI00200 EQU   *                                                        20300021
         MVC   DXCCW1(K16),ABSFCCW      INITLZ CCW FOR 'BSF' AND MOVE   20400021
*                                       ..UNCHAINED 'NOP' INTO DXCCW2   20500021
         TM    DCBOFLGS,DCBORDBK        IS READBACK INDICATED IN DCB-   20600021
         BNO   ETI00400                 NO, BR TO READ TRAILER LABEL    20700021
*                                                                       20800021
*****          POSITION TAPE TO READ HEADER LABEL 1                     20900021
*                                                                       21000021
         LA    RD,EABD146               POSITIONING ERR INTERNAL CODE   21100021
         BAL   RC,ETI02800              BACKSPACE PAST TAPE MARK        21160021
*                                       ..PRECEDING HEADER LBLS         21220021
         MVI   DXCCW1,CCWNOP            INITLZ CCW FOR 'NOP' COMMAND    21300021
         BAL   RC,ETI02800              ISSUE 'NOP' TO TAPE UNIT        21400021
         BAL   RC,ETI02750              ISSUE SENSE CMD         XA01537 21410002
         TM    DXCCW3+K1,UCBLDPT        IS TAPE AT 'LOAD POINT' XA01537 21500002
         BO    ETI00400                 ..BR IF YES TO READ HEADER LBL  21600021
ETI00300 EQU   *                                                        21700021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR 'FWD SPACE FILE' 21800021
         OI    DXCCW1+K4,CCWCMDCH       CHAIN TO 'NOP' CMD              21900021
         BAL   RC,ETI02800              FORWARD SPACE TO HEADER LABELS  22000021
*                                                                       22100021
*****          READ TRAILER ( OR HEADER ) LABEL 1                       22200021
*                                                                       22300021
ETI00400 EQU   *                                                        22400021
         LA    RD,EABD147               INTERNAL ERROR CODE IN CASE OF  22500021
*                                       ERROR READING TRAILER LABEL 1   22600021
         LA    RC,DXLBL                 PLACE ADDRESS OF LABEL AREA IN  22700021
         ST    RC,DXCCW1                OBTAINED CORE INTO THE CCW      22800021
         MVI   DXCCW1,CCWRDTAP          INITLZ CCW FOR 'TAPE READ' CMD  22900021
         MVC   DXCCW1+K4(K4),ARDCCW     SET LENGTH EQUAL 80, NO FLAGS   23000021
         TM    JFCBLTYP,JFCBAL          WERE ANSI LABELS SPECIFIED-     23100021
         BZ    ETI00500                 ..BRANCH IF NOT                 23200021
         OI    DXCCW1+K4,CCWSILI        SET 'SILI' BIT ON               23300021
ETI00500 EQU   *                                                        23400021
         BAL   RC,ETI02800              READ TRAILER (OR HEADER) LABEL  23500021
         TM    JFCBLTYP,JFCBAL          WERE ANSI LABELS SPECIFIED-     23600021
         BZ    ETI00600                 ..BRANCH IF NOT                 23700021
         XLATE DXLBL,K80                TRANSLATE ANSI LABELS           23800021
         CLC   FL1LABI,UVOL             IS THIS A USER VOLUME LABEL-    23900021
         BE    ETI00500                 ..BR IF YES- READ ANOTHER LABEL 24000021
ETI00600 EQU   *                                                        24100021
         LA    RD,EABD180               ERROR CODE FOR INVALID LABEL    24200021
         CLC   FL1LABI,AVOL             IS THIS A VOLUME LABEL-         24300021
         BE    ETI00500                 ..BR IF YES- READ ANOTHER LABEL 24400021
         CLI   FL1NO,FILPOS1            IS THIS A FILE LABEL 1-         24500021
         BNE   ETI02900                 ..BR IF NOT- WRONG LABEL        24600021
*                                                                       24700021
*********************************************************************** 24800021
*              VERIFY BLOCK COUNT. NOTE THAT IF THE DATA SET WAS      * 24900021
*              CREATED WITH A DCB THAT HAD NO DEVICE-DEPENDENT        * 25000021
*              SECTION, THE BLOCK COUNT WAS WRITTEN AS ZERO AND       * 25100021
*              CANNOT BE VERIFIED.                                    * 25200021
*********************************************************************** 25300021
*                                                                       25400021
         L     RC,DCBBLKCT              LOAD BLOCK COUNT FROM THE DCB   25500021
         PACK  DXCCW7,FL1BLKCT          CONVERT THE BLOCK COUNT IN      25600021
         CVB   RF,DXCCW7                ..THE FILE LABEL TO BINARY      25700021
         TM    DCBMACRF,DCBMEXCP        IS THIS AN 'EXCP' DCB-          25800021
         BNO   ETI00700                 ..BR IF NOT- BLOCK COUNT EXISTS 25900021
         TM    DCBMACRF,DCBMFOUN        DOES FOUNDATION EXTENSION EXIST 26000021
         BNO   ETI01900                 ..BR IF NOT- NO BLOCK COUNT     26100021
         TM    DCBMACRF+K1,DCBMDEV      DOES DEV-DEPEND SECTION EXIST-  26200021
         BZ    ETI01400                 ..BR IF NOT- CHK FOR USER LBLS  26300021
         B     ETI00900                 ..ELSE BR TO VERIFY BLOCK COUNT 26400021
ETI00700 EQU   *                                                        26500021
         TM    DCBCIND2,DCBC2CHN        IS CHAINED SCHEDULING IN USE-   26600021
         BO    ETI00800                 ..BRANCH IF YES                 26700021
         L     RD,DCBIOBA               LD ADDR OF IOB THAT CAUSED EOF  26800021
         SH    RC,IOBINCNT(,RD)         UPDATE BLOCK COUNT TO ACCOUNT   26900021
         ST    RC,DCBBLKCT              ..FOR EOF AND STORE IN DCB      27000021
ETI00800 EQU   *                                                        27100021
         LTR   RF,RF                    WAS BLOCK COUNT WRITTEN AS 0-   27200021
         BNZ   ETI00900                 ..BR IF NOT- THE BLOCK COUNT    27300021
*                                       ..IN THE LABEL IS VALID         27400021
         TM    DCBOFLGS,DCBORDBK        WAS LAST OPERATION 'READBACK'-  27500021
         BNO   ETI01400                 ..BR IF NOT- BLOCK CT NOT VALID 27600021
ETI00900 EQU   *                                                        27700021
         CLR   RC,RF                    IS BLOCK COUNT IN DCB CORRECT-  27800021
         BE    ETI01400                 ..BR IF YES- TEST FOR USER LBL  27900021
*                                                                       28000021
*********************************************************************** 28100021
*              INCORRECT BLOCK COUNT PROCESSING                       * 28200021
*********************************************************************** 28300021
*                                                                       28400021
*****          TEST FOR A VALID BLOCK COUNT EXIT                        28500021
*                                                                       28600021
ETI01000 EQU   *                                                        28700021
         LA    RD,EABD148               INTERNAL ERROR CODE IN CASE     28800021
*                                       ..BLOCK COUNT IS UNACCEPTABLE   28900021
         L     RC,DCBEXLST              GET EXIT LIST ADDR FROM THE DCB 29000021
         LA    RC,K0(,RC)               ZERO HI-ORDER BYTE OF EXIT LIST 29100021
         LTR   RC,RC                    IS THERE A DCB EXIT LIST-       29200021
         BZ    ETI02900                 ..BR IF NOT TO ERROR RTN        29300021
ETI01100 EQU   *                                                        29400021
         CLI   K0(RC),XLBLKCT           IS THIS AN ACTIVE BLK CT EXIT-  29500021
         BE    ETI01200                 ..BR IF YES                     29600021
         CLI   K0(RC),XLBLKCT+LASTNTRY  IS 'LAST ENTRY' IND ALSO ON-    29700021
         BE    ETI01200                 ..BRANCH IF YES                 29800021
         TM    K0(RC),LASTNTRY          IS THIS THE LAST LIST ENTRY-    29900021
         LA    RC,K4(,RC)               INCREMENT POINTER TO NEXT ENTRY 30000021
         BO    ETI02900                 ..BR IF YES TO ERROR ROUTINE    30100021
         B     ETI01100                 ..ELSE BR TO TST FOR VALID EXIT 30200021
ETI01200 EQU   *                                                        30300021
         L     RC,K0(,RC)               GET EXIT ADDRESS FROM DCB       30400021
         LA    RC,K0(,RC)               ZERO THE HI-ORDER BYTE          30500021
         LTR   RC,RC                    IS EXIT ADDR ZERO-              30600021
         BZ    ETI02900                 ..BR IF YES TO ERROR ROUTINE-   30700021
*                                                                       30800021
****           A VALID EXIT EXISTS- INITLZ FOR 'SYNCH' TO USER          30900021
*                                                                       31000021
         LR    R0,RF                    PUT TRAILER LBL BLK CT IN REG 0 31100021
         LR    RF,RC                    PUT EXIT ADDR IN REG 15         31200021
         LR    R1,RDCB                  PUT DCB ADDR IN REG 1           31300021
         L     RC,CVTPTR                LOAD CVT ADDRESS                31400021
         USING CVT,RC                   ESTABLISH CVT ADDRESSABILITY    31500021
         L     RC,CVTTCBP               LD PT TO NEXT AND CURRENT TCBS  31600021
         L     RC,K4(,RC)               LOAD CURRENT TCB ADDRESS        31700021
         USING TCB,RC                   ESTABLISH TCB ADDRESSABILITY    31800021
         L     RC,TCBRBP                LOAD CURRENT SVRB ADDRESS       31900021
         USING RBSECT,RC                ESTABLISH SVRB ADDRESSABILITY   32000021
         STM   RDCB,RD,RBEXSAVE         SAVE EOV REGISTERS 2-13         32100021
         NI    DCBOFLGS,X'FF'-DCBOLOCK  IND THAT USER EXIT WAS TAKEN    32200021
ETI01250 EQU   *                                                        32300021
         L     RD,RBLINK                PT TO THE PREVIOUS REQUEST BLK  32400021
         TM    RBSTAB-RBSECT(RD),RBFTSVRB IS IT THE USER'S 'PRB'-       32500021
         BZ    ETI01300                 ..BR IF YES- 'RC' POINTS TO THE 32600021
*                                       ..SVRB WITH THE USER'S REGS     32700021
         LR    RC,RD                    ..ELSE POINT TO THE RB WHICH    32800021
*                                       ..CONTAINS THE USER'S REGISTERS 32900021
         B     ETI01250                 BR- REPEAT TEST FOR USER'S PRB  33000021
ETI01300 EQU   *                                                        33100021
         LM    RDCB,RD,RBGRS2           RESTORE USERS REGISTERS 2-13    33200021
         SYNCH (15)                                              S21940 33300021
         L     RC,CVTPTR                LOAD CVT ADDRESS                33400021
         USING CVT,RC                   ESTABLISH CVT ADDRESSABILITY    33500021
         L     RC,CVTTCBP               LD PT TO NEXT AND CURRENT TCBS  33600021
         L     RC,K4(,RC)               LOAD CURRENT TCB ADDRESS        33700021
         USING TCB,RC                   ESTABLISH TCB ADDRESSABILITY    33800021
         L     RC,TCBRBP                LOAD CURRENT SVRB ADDRESS       33900021
         USING RBSECT,RC                ESTABLISH SVRB ADDRESSABILITY   34000021
         AIF   ('&LIB' EQ 'LIB1').LIB12R1                               34050000
         LR    RD,RF                    SAVE USER RETURN CODE    Y01021 34060000
         LM    RDCB,RA,RBEXSAVE         REGS NEEDED FOR DEBCHK   Y01021 34070000
         DEBCHK (RDCB)                  VALIDATE DEB             Y01021 34080000
         LR    RDEB,R1                  LOAD VERIFIED DEBAD      Y01021 34082000
         ST    RDEB,DXPDEBAD            STORE DEBAD IN WORK AREA Y01021 34084000
         LR    RF,RD                    RESTORE USER RETURN CODE Y01021 34090000
         LM    RC,RD,RBEXSAVE+K40       RESTORE OTHER REGISTERS  Y01021 34090400
.LIB12R1 ANOP                                                           34090800
         AIF   ('&LIB' NE 'LIB1').LIB22R1                               34092000
         LM    RDCB,RD,RBEXSAVE         RESTORE EOV REGISTERS 2-13      34100021
.LIB22R1 ANOP                                                           34150000
         OI    DCBOFLGS,DCBOLOCK        INDICATE RETURN FROM USER EXIT  34200021
         LA    RD,EABD148               INTERNAL ERROR CODE IN CASE     34300021
*                                       ..BLOCK COUNT IS UNACCEPTABLE   34400021
         LTR   RF,RF                    IS THE USER'S RET CODE ZERO-    34500021
         BZ    ETI02900                 ..BR IF YES TO ERROR ROUTINE,   34600021
*                                       ..ELSE CONTINUE PROCESSING      34700021
         DROP  RC                                                       34800021
*********************************************************************** 34900021
*              TEST FOR USER LABEL PROCESSING                         * 35000021
*********************************************************************** 35100021
*                                                                       35200021
ETI01400 EQU   *                                                        35300021
         ST    RPARC,DXREG0             SAVE REGISTER 7         SA55619 35310000
         TM    DCBOFLGS,DCBORDBK        IS THIS 'READBACK' MODE SA55619 35350000
         BNO   ETI01450                 BRANCH IF NOT           SA55619 35360000
         CLC   DEBTVLSQ(K2),ABSFCCW+K6  LAST VOLUME             SA55619 35380000
         BNE   ETI01456                 BRANCH IF NOT           SA55619 35390000
         B     ETI01455                 SET SWITCH              SA55619 35392000
ETI01450 BAL   R7,ETI02150              TEST FOR E-O-F          SA55619 35396000
         BC    7,ETI01456               NOT E-O-F               SA55619 35398000
ETI01455 MVC   DXREG1+1(K3),AEOF        SET SWITCH              SA55619 35398400
ETI01456 L     RPARC,DXREG0             RESTORE REGISTER 7      SA55619 35398800
         TM    JFCBLTYP,JFCBUL          WERE USER LABELS SPECIFIED-     35400021
         BNO   ETI01900                 ..BR IF NOT TO POSITION TAPE    35500021
         TM    DCBMACRF,DCBMEXCP        IS THIS AN EXCP DCB-            35600021
         BNO   ETI01500                 ..BR IF NOT                     35700021
         TM    DCBMACRF,DCBMFOUN        IS THERE A FOUNDATION EXT-      35800021
         BZ    ETI01900                 ..BR IF NOT                     35900021
ETI01500 EQU   *                                                        36000021
         L     RC,DCBEXLST              LD EXIT LIST ADDR FROM THE DCB  36100021
         LA    RC,K0(,RC)               ZERO HI-ORDER BYTE OF EXIT LIST 36200021
         LTR   RC,RC                    IS THERE A DCB EXIT LIST-       36300021
         BZ    ETI01900                 ..BR IF NOT TO POSITION TAPE    36400021
         CLC   DXREG1+1(K3),AEOF        IS THIS E-O-F           SA55619 36450000
         BE    ETI01650                 BR IS YES               SA55619 36460000
ETI01600 EQU   *                                                        36500021
         CLI   K0(RC),XLIUTL            IS THERE A TRAILER LABEL ENTRY- 36600021
         BE    ETI01800                 ..BR IF YES TO PROCESS USER LBL 36700021
         CLI   K0(RC),XLIUTL+LASTNTRY   IS 'LAST ENTRY' IND ALSO ON     36800021
         BE    ETI01800                 ..BR IF YES TO PROCESS USER LBL 36900021
         TM    K0(RC),LASTNTRY          IS THIS LAST ENTRY      SA55619 36950000
         LA    RC,K4(,RC)               INCR POINTER            SA55619 36960000
         BNO   ETI01600                 NO,CHECK NEXT ENTRY     SA55619 36970000
         CLC   DXREG1+1(K3),AEOF        IS THIS E-O-F           SA55619 36980000
         BE    ETI01900                 YES, POSITION TAPE      SA55619 36990000
         L     RC,DCBEXLST              NO,GET EXIT LIST        SA55619 36992000
         LA    RC,K0(,RC)               ZERO HIGH ORDER BYTE    SA55619 36994000
ETI01650 EQU   *                                                SA55619 36996000
         CLI   K0(RC),XLDEFSL           IS 'DEFERRED USER TRAILER       37000021
*                                       ..LABEL PROCESSING' SPECIFIED-  37100021
         BE    ETI01700                 ..BR IF YES TO TEST FOR EOF     37200021
         CLI   K0(RC),XLDEFSL+LASTNTRY  IS 'LAST ENTRY' IND ALSO ON-    37300021
         BE    ETI01700                 ..BR IF YES TO TEST FOR EOF     37400021
         TM    K0(RC),LASTNTRY          IS THIS THE LAST LIST ENTRY-    37500021
         LA    RC,K4(,RC)               INCREMENT POINTER TO NEXT ENTRY 37600021
         BNO   ETI01650                 BR IF NOT TO CKECK NEXT ENTRYSA 37650000
         L     RC,DCBEXLST              GET EXIT LIST ADDR      SA55619 37700000
         LA    RC,K0(,RC)               ZERO HIGH ORDER BYTE    SA55619 37750000
         CLC   DXREG1+1(K3),AEOF        IS THIS E-O-F           SA55619 37760000
         BE    ETI01600                 BR IS YES               SA55619 37770000
         B     ETI01900                 ..ELSE BR TO POSITION TAPE      37800021
*                                                                       37900021
*****          IF 'DEFERRED USER LABEL PROCESSING' WAS SPECIFIED AND    38000021
*****          EOF HAS OCCURRED, DEFER PROCESSING UNTIL 'CLOSE' OR      38100021
*****          'TCLOSE.                                                 38200021
*****          NOTE- THE TAPE IS LEFT AT THE INTERBLOCK GAP PRECEDING   38300021
*****          USER TRAILER LABEL 1 WHEN DEFERRED USER LABEL PROCESSING 38400021
*****          IS SPECIFIED.                                            38500021
*                                                                       38600021
ETI01700 EQU   *                                                        38700021
         CLC   DXREG1+1(K3),AEOF        IS THIS E-O-F           SA55619 38800000
         BE    ETI02100                 ..BR IF YES- DO NOT PROCESS UL  38900021
*                                                                       39000021
*****          IF A VALID EXIT ADDR EXISTS, EXIT TO PROCESS USER LABELS 39100021
*                                                                       39200021
ETI01800 EQU   *                                                        39300021
         LA    RF,MOD2R2T               PT TO ID/TTR OF USER LABEL MOD  39400021
         SR    RET,RET                  LD BR TABLE OFFSET FOR THAT MOD 39500021
         L     RC,K0(,RC)               LOAD EXIT ADDRESS FROM DCB      39600021
         LA    RC,K0(,RC)               ZERO THE HI-ORDER BYTE          39700021
         LTR   RC,RC                    DOES AN EXIT ADDRESS EXIST-     39800021
         BNZ   ETI02600                 ..BR IF YES- PROCESS USER LBLS  39900021
*                                                                       40000021
*********************************************************************** 40100021
*              POSITION TAPE BEYOND LABELS                            * 40200021
*********************************************************************** 40300021
*                                                                       40400021
ETI01900 EQU   *                                                        40500021
         LA    RD,EABD150               INTERNAL ERROR CODE IN CASE OF  40600021
*                                       ..POSITIONING ERROR             40700021
         MVC   DXCCW1,ABSFCCW           INITLZ CCW FOR 'BACKSPACE FILE' 40800021
         TM    DCBOFLGS,DCBORDBK        IS THIS READ BACKWARD MODE-     40900021
         BNO   ETI02000                 ..BRANCH IF NOT                 41000021
         BAL   RC,ETI02800              BACKSPACE PAST HEADER LABELS    41100021
         MVI   DXCCW1,CCWNOP            INITLZ CCW FOR 'NOP' COMMAND    41200021
         BAL   RC,ETI02800              ISSUE 'NOP' TO TAPE DRIVE       41300021
         BAL   RC,ETI02750              ISSUE SENSE CMD         XA01537 41390002
         TM    DXCCW3+K1,UCBLDPT        IS TAPE AT 'LOAD POINT' XA01537 41392002
         BO    ETI02100                 ..BR IF YES TO CONTINUE         41500021
ETI02000 EQU   *                                                        41600021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR 'FWD SPACE FILE' 41700021
         OI    DXCCW1+K4,CCWCMDCH       CHAIN TO 'NOP' COMMAND          41800021
         BAL   RC,ETI02800              FSF TO END OF DATA SET (READ    41900021
*                                       ..FWD) OR PRECEDING HEADER      42000021
*                                       ..LABEL (RDBACK)                42100021
         B     ETI02100                 BR TO CONTINUE PROCESSING       42200021
         TITLE 'IFG0552R - EOV TAPE INPUT VOLUME DISPOSITION FUNCTION'  42300021
*********************************************************************** 42400021
*                                                                     * 42500021
*                          FUNCTION PROLOG                            * 42600021
*                                                                     * 42700021
*********************************************************************** 42800021
*                                                                     * 42900021
* FUNCTION NAME -                                                     * 43000021
*    'EOV TAPE INPUT VOLUME DISPOSITION FUNCTION'                     * 43100021
*                                                                     * 43200021
* (STATUS) -                                                          * 43300021
*    NOT APPLICABLE                                                   * 43400021
*                                                                     * 43500021
* FUNCTION -                                                          * 43600021
*    1. IF ENTRY IS FROM NSLETRLI FOLLOWING DEFERRED LABEL PROCESSING * 43660021
*       DURING 'CLOSE', RETURN TO IFG0202B (ALIAS IFG0556B) TO        * 43720021
*       COMPLETE THAT PROCESSING.                                       43780021
*    2. FOR ALL OTHER ENTRIES, DETERMINE IF END-OF-FILE HAS OCCURRED, * 43840021
*       IN WHICH CASE CONTROL IS TRANSFERRED TO THE END-OF-DATA       * 43900021
*       FUNCTION.                                                     * 43960021
*    3. WHEN A VOLUME SWITCH IS TO OCCUR, ISSUE THE VOLUME STATISTICS * 44020021
*       (VOLSTAT) SVC 91. THEN, IF THE SYSTEMS MANAGEMENT FACILITY    * 44080021
*       (SMF) IS ACTIVE, TRANSFER CONTROL TO THE CLOSE SMF RECORD     * 44140021
*       BUILDER FUNCTION TO PROCESS SMF RECORDS. NOTE THAT THIS IS    * 44200021
*       NOT DONE FOR DATA SETS ON NSL TAPE, BECAUSE SMF PROCESSING    * 44260021
*       FOR THESE DATA SETS MUST BE PERFORMED PRIOR TO NSLETRLI.      * 44320021
*                                                                     * 44500021
* ENTRY POINTS -                                                      * 44600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 44700021
*                                                                     * 44800021
* INPUT -                                                             * 44900021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 45000021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 45100021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 45200021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 45300021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 45400021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 45500021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 45600021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 45700021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 45800021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 45900021
*                                                                     * 46000021
* OUTPUT -                                                            * 46100021
*    1. WORK AREA FIELD 'DXCCW7+4' CONTAINS THE UCB FILE SEQUENCE     * 46200021
*       COUNT AND NUMBER FOR ALL EXITS EXCEPT TO IFG0556B.            * 46300021
*    2. AT EXIT TO IFG0552V (VOLUME POSITIONING)-                     * 46400021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 46500021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0';      * 46600021
*    3. AT EXIT TO IFG0553B (AN ALIAS FOR IFG0202H- SMF PROCESSING)-  * 46700021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 46900021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '4';      * 47000021
*       WORK AREA INDICATORS-                                         * 47100021
*          'DXRETMOD' - CONTAINS THE 5-BYTE ID/TTR OF VOLUME          * 47200021
*                       POSITIONING MODULE IFG0552V;                  * 47300021
*    4. AT EXIT TO IFG0552X (END-OF-DATA FUNCTION)-                   * 47400021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 47500021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0';      * 47600021
*    5. AT EXIT TO IFG0556B (AN ALIAS FOR IFG0202B- CLOSE NSL         * 47610021
*       INTERFACE FUNCTION)-                                            47620021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT AS FOLLOWS- * 47630021
*          'RET' - CONTAINS A BRANCH TABLE OFFSET OF '4'.             * 47640021
*          'RF'  - POINTS TO 'DXXCTL', AN XCTL WORK AREA.             * 47650021
*       WORK AREA INDICATORS-                                         * 47660021
*          'WTGMODNM' - CONTAINS 'IFG0556B', THE XCTL NAME.           * 47670021
*          'WTGTTR'   - CONTAINS THE TTR OF IFG0556B.                 * 47680021
*                                                                     * 47700021
* EXTERNAL REFERENCES -                                               * 47800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 47900021
*                                                                     * 48000021
* EXITS, NORMAL -                                                     * 48100021
*         IFG0552V - TO POSITION THE VOLUME AT EOV.                   * 48160021
*         IFG0552X - TO PROCESS THE DATA SET AT EOF.                  * 48220021
*         IFG0553B - (AN ALIAS FOR IFG0202H) TO PROCESS SMF RECORDS.  * 48280021
*         IFG0556B - (AN ALIAS FOR IFG0202B) TO FINISH DEFERRED NSL   * 48340021
*                    PROCESSING.                                      * 48400021
*                                                                     * 48500021
* EXITS, ERROR -                                                      * 48600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 48700021
*                                                                     * 48800021
* TABLES/WORK AREAS -                                                 * 48900021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 49000021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 49100021
*                                                                     * 49200021
* ATTRIBUTES -                                                        * 49300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 49400021
*                                                                     * 49500021
* CHARACTER CODE DEPENDENCY -                                         * 49600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 49700021
*                                                                     * 49800021
* NOTES -                                                             * 49900021
*    PART I OF THIS FUNCTION- IDENTICAL TO THE CODE CONTAINED HEREIN- * 50000021
*    IS CONTAINED IN MODULE IFG0552T FOLLOWING PART II OF THE         * 50100021
*    STANDARD TRAILER LABEL FUNCTION IN ORDER TO MINIMIZE XCTLS.      * 50200021
*                                                                     * 50300021
*********************************************************************** 50400021
         EJECT                                                          50450021
*                                                                       50500021
*********************************************************************** 50600021
*              DETERMINE WHETHER EOV OR EOF HAS OCCURRED              * 50700021
*********************************************************************** 50800021
*                                                                       50900021
*****          RESTORE REGISTERS AND WORK AREA UPON RETURN FROM         50920021
*****          NSLETRLI                                                 50940021
*                                                                       50960021
ETI02050 EQU   *                                                        51000021
         LR    RES,RWTGC                RESTORE RESIDENT RTN ADDRESS    51100021
         LA    RWTGC,DXXENTRY           RESTORE CURRENT ENTRY ADDRESS   51200021
         AIF   ('&LIB' NE 'LIB1').LIB22R2                               51210000
         MVI   DXXMODNM+1,C'F'          CHANGE WTG NAME TO 'IFG' M0027  51250021
.LIB22R2 ANOP                                                           51262000
         AIF   ('&LIB' EQ 'LIB1').LIB12R2                               51262400
         MVC   DXXMODNM(L'IFG055NM),IFG055NM  MOVE IN 'IFG055'   YM3271 51264000
.LIB12R2 ANOP                                                           51266000
         MVI   DXRESIND,K0              RESET RES RTN INDICATORS M0110  51270021
ETI02100 EQU   *                                                        51300021
         MVC   DXCCW1,ABSFCCW           INITLZ CCW FOR BACKSPACE FILE   51400021
         MVC   DXCCW7+K4(K4),SRTEFSCT   SAVE SEQ CT/ NO. IN WORK AREA   51500021
         LA    RF,MOD2R2X               PT TO ID/TTR OF EOD MODULE      51600021
         SR    RET,RET                  LD BR TABLE OFFSET FOR THAT MOD 51700021
         TM    DCBOFLGS,DCBORDBK        IS THIS 'READBACK' MODE-        51800021
         BO    ETI02400                 ..BR IF YES TO READBACK RTN     51900021
         ST    RPARC,DXREG0             SAVE REGISTER 7         SA55619 51950000
         BAL   R7,ETI02150              TEST FOR E-O-F          SA55619 51960000
         L     RPARC,DXREG0             RESTORE REGISTER 7      SA55619 51970000
         BE    ETI02600                 BRANCH IF ALL VOLS      SA55619 51980000
*                                       BEEN PROCESSED          SA55619 51990000
         B     ETI02300                 CONTINUE PROCESSING     SA55619 51992000
*                                                                       52000021
*****          READ FORWARD TESTING FOR EOV                             52100021
*                                                                       52200021
ETI02150 EQU   *                                                SA55619 52250000
         CLC   JFCBNVOL(K1),DEBTVLSQ+K1  ALL VOLS BEEN USED     SA69185 53200021
         BCR   8,R7                     ..BRANCH IF YES         SA55619 53300000
*                                                                       53400021
*****          PERFORM POSITIVE CHECK FOR END-OF-FILE IF ON OTHER       53500021
*****          THAN THE LAST VOLUME OF A MULTI-VOLUME DATA SET.         53600021
*                                                                       53700021
         TM    JFCOPTCD,JFCALLOW        DO WE BYPASS EOF PROCESSING-    53800021
         BCR   1,R7                     ..BRANCH IF YES         SA55619 53900000
         CLC   VOLLABI(K3),AEOF         TEST FOR 'E-O-F' LABEL-         54000021
         BR    R7                       RETURN                  SA55619 54100000
ETI02300 EQU   *                                                        54600021
         TM    UCBWGT,UCBIN             IS THIS A SYSIN VOLUME-         54700021
         BO    ETI02600                 ..BRANCH IF YES- ASSUME EOD     54800021
         B     ETI02500                 BR TO TEST FOR SMF PROCESSING   54900021
*                                                                       55000021
*****    READ BACKWARD TESTING FOR EOF                                  55100021
*                                                                       55200021
ETI02400 EQU   *                                                        55300021
         CLC   DEBTVLSQ(K2),ABSFCCW+K6  IS THIS THE LAST VOLUME-        55400021
         BE    ETI02600                 ..BR IF YES                     55500021
         EJECT                                                          55600021
*********************************************************************** 55700021
*              END-OF-VOLUME PROCESSING                               * 55800021
*********************************************************************** 55900021
*                                                                       56000021
*****          ISSUE VOLUME STATISTICS SVC                       A46383 56100021
*                                                                       56200021
ETI02500 EQU   *                                                        56300021
         VOLSTAT 0(RDCB),E              ISSUE VOLUME STATISTICS  S21940 56340021
*                                                                A46383 56350021
         LA    RF,MOD2R2V               PT TO ID/TTR OF POSITIONING MOD 56400021
         SR    RET,RET                  LD BR TABLE OFFSET FOR THAT MOD 56500021
*                                                                M0110  56600021
*****          DETERMINE WHETHER OR NOT SMF PROCESSING IS        M0110  56700021
*****          REQUIRED                                          M0110  56800021
*                                                                M0110  56900021
         TM    DXXPATHS,WTGSMF          IS SMF PROCESSING REQ'D- A38013 57100021
         BNO   ETI02600                 ..BR IF NOT- XCTL TO VOL A38013 57700021
*                                       ..POSITIONING FUNCTION   A38013 58300021
         LA    RF,MOD2RSMF              PT TO SMF MODULE'S ID/TTR       58900021
         LA    RET,K4                   LD BR TABLE OFFSET FOR THAT MOD 59000021
         MVC   DXRETMOD(K5),MOD2R2V     MOVE POSITIONING MOD ID/TTR     59100021
*                                       ..INTO RETURN ADDRESS SAVE AREA 59200021
         EJECT                                                          59300021
*********************************************************************** 59400021
*              EXITS                                                  * 59500021
*********************************************************************** 59600021
*                                                                       59700021
*****          EXIT TO THE NEXT MODULE IN THE STRING                    59800021
*                                                                       59900021
ETI02600 EQU   *                                                        60000021
         IECRES XCTL,(RF),(RET)         INVOKE IECRES MACRO TO 'XCTL'   60100021
         SPACE 2                                                        60200021
*                                                                       60300021
*****          XCTL TO 'CLOSE' FOLLOWING DEFERRED NSL PROCESSING        60400021
*                                                                       60500021
ETI02700 EQU   *                                                        60600021
         MVC   WTGMODNM,IFG0556B        MOVE ALIAS OF 'CLOSE'    M0110  60700021
*                                       ..NSL-PROCESSING MODULE INTO    60800021
*                                       ..THE WTG TABLE                 60900021
         MVC   WTGTTR,MOD2R6B+K2        MOVE TTR FOR THAT MODULE M0110  60930021
*                                       ..INTO PSEUDO BLDL LIST  M0110  60960021
         LA    RF,DXCCW12               PT TO THE XCTL WORK AREA M0147  61030021
         LA    RET,K4                   LOAD TABLE OFFSET FOR IFG0202B  61100021
         XCTL  DE=(RWTG),SF=(E,(15))    XCTL BY TTR TO IFG0202B  M0110  61200021
         EJECT                                                          61300021
*********************************************************************** 61400021
*              SUBROUTINES                                            * 61500021
*********************************************************************** 61600021
*                                                                       61700021
*****          SUBROUTINE TO ISSUE SENSE                                61710002
*                                                                       61730002
ETI02750 EQU   *                                                XA01537 61740002
         LA    RET,DXCCW3               DATA AREA FOR SENSE     XA01537 61750002
         ST    RET,DXCCW1               PUT ADDR IN CCW         XA01537 61760002
         MVI   DXCCW1,CCWSENSE          MOVE IN SENSE CMD       XA01537 61770002
         MVI   DXCCW1+K7,K2             READ 2 SENSE BYTES      XA01537 61780002
*                                                                       61790002
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              61800021
*****          ENTRY TO THE ROUTINE IS VIA A 'BAL  RC,ETI02800'         61900021
*                                                                       62000021
ETI02800 EQU   *                                                        62100021
         EXCP  DXIOB                    INITIATE I/O OPERATION          62200021
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   62300021
         TM    DXECB,ECBNOERR           TEST FOR AN UNUSUAL I/O CONDITI 62400021
         BCR   1,RC                     ..BR IF NOT- RETURN TO CALLER   62500021
         TM    IOBSENS1,UCBLDPT         IS THE TAPE AT 'LOAD POINT'-    62600021
         BCR   1,RC                     ..BR IF YES- RETURN TO CALLER   62700021
*                                       ..ELSE DROP THROUGH TO ERR RTN  62800021
         SPACE 2                                                        62900021
*********************************************************************** 63000021
*              ERROR PROCESSING                                       * 63100021
*********************************************************************** 63200021
*                                                                       63300021
ETI02900 EQU   *                                                        63400021
         DMABCOND (RD),ABEND2R          EXIT TO PROB DETERMINATION RTN  63500021
         SPACE 3                                                        63600021
*********************************************************************** 63700021
*              CONSTANTS                                              * 63800021
*********************************************************************** 63900021
*                                                                       64000021
ABSFCCW  CCW   X'2F',0,X'20',1          BSF CMD, SILI FLAG, LNG EQ 1    64100002
NOPCCW   DC    X'0300000020000001'      NOP CMD, SILI FLAG, LNG EQ 1    64200021
ARDCCW   DC    X'00000050'              NO FLAGS, LNG EQ 80 FOR STD LBL 64300021
IFG0556B DC    CL8'IFG0556B'            ALIAS OF CLOSE NSL MOD   M0110  64400021
AVOL     DC    C'VOL'                   VOLUME LABEL IDENTIFIER         64500021
UVOL     DC    C'UVL'                   USER VOLUME LABEL IDENTIFIER    64600021
AEOF     DC    C'EOF'                   END-OF-FILE LABEL IDENTIFIER    64700021
         AIF   ('&LIB' EQ 'LIB1').LIB12R3                               64710000
IFG055NM DC    C'IFG055'                PREFIX FOR XCTL  (EOV)   YM3271 64750000
.LIB12R3 ANOP                                                           64760000
         EJECT                                                          64800021
*********************************************************************** 64900021
*              XCTL TABLE                                             * 65000021
*********************************************************************** 65100021
*                                                                       65200021
         AIF   ('&LIB' NE 'LIB1').LIB22RS                               65250000
XCTLTB2R XCTLTABL ID=(ABEND2R,0P,MOD2R2T,2T,MOD2R2V,2V,MOD2R2X,2X,     C65300021
               MOD2RSMF,3B,MOD2R6B,6B),SVC=055                   M0110  65400021
.LIB22RS ANOP                                                           65410000
         AIF   ('&LIB' EQ 'LIB1').LIB12RS                               65420000
XCTLTB2R XCTLTABL ID=(ABEND2R,0P,MOD2R2T,2T,MOD2R2V,2V,MOD2R2X,2X,     C65450000
               MOD2RSMF,3B,MOD2R6B,6B),SVC=055,                  M0110 C65460000
               LENGTH=2048,PATCH=100                            SA55619 65470000
.LIB12RS ANOP                                                           65480000
         SPACE 2                                                        65500021
         IECDSECS CVT,                                                 C65600021
               TCB,                                                    C65700021
               RB,                                                     C65800021
               TIOT,                                                   C65900021
               DCB,                                                    C66100021
               DEB,                                                    C66200021
               UCB,                                                    C66300021
               MAIN,                                                   C66400021
               WTG,                                                    C66500021
               EXPAND=YES                                               66600021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   66700021
         SPACE 2                                                        66800021
         END                                                            66900021
