 TITLE 'IFG0552T - EOV TAPE INPUT STD TRAILER LABEL FUNCTION (CONT.)'   00100021
         COPY  LCGASMSW                                                 00200000
IFG0552T CSECT                                                          00400021
*                                                                       00500021
*********************************************************************** 00600021
*                                                                     * 00700021
*          VS1 RELEASE 03.1 DELETIONS/CHANGES                         * 00750021
*SEE SA69185                                                    XA04640 00760021
*                                                                     * 00800021
*          RELEASE 25 DELETIONS/CHANGES                               * 00900021
*          RELEASE 24 DELETIONS/CHANGES                               * 01000021
*          RELEASE 23 DELETIONS/CHANGES                               * 01100021
*          RELEASE 22 DELETIONS/CHANGES                               * 01200021
*          RELEASE 21.8 DELETIONS/CHANGES                             * 01210021
*0000246000,250000-256000,477000-485000                         SA69185 01220021
*          RELEASE 21 DELETIONS/CHANGES                               * 01300021
*0000519000-541000,598000                                        A38013 01350021
*                                                                M0110  01360021
*                                                                A46383 01370021
*                                                                     * 01400021
* STATUS CHANGE LEVEL 000                                             * 01500021
*                                                                     * 01600021
* FUNCTION -                                                          * 01700021
*    THIS MODULE CONTAINS THE FOLLOWING FUNCTIONS-                    * 01800021
*       1. 'EOV TAPE INPUT STANDARD TRAILER LABEL FUNCTION', PART II; * 01900021
*       2. 'EOV TAPE INPUT VOLUME DISPOSITION FUNCTION', PART I.      * 02000021
*                                                                     * 02100021
* ENTRY POINTS -                                                      * 02200021
*         IFG0552T - REFER TO 'INPUT' FOR A LIST OF CALLING MODULES   * 02260021
*                    AND THEIR RESPECTIVE ENTRY CONDITIONS.           * 02320021
*                                                                     * 02400021
* INPUT -                                                             * 02500021
*    REGISTER 14 ('RET') WILL CONTAIN ONE OF THE BRANCH TABLE OFFSETS * 02600021
*    LISTED BELOW, THE BRANCH TABLE BEING USED TO DETERMINE AT WHICH  * 02700021
*    POINT PROCESSING IS TO BEGIN -                                   * 02800021
*       0 - ENTRY FROM IFG0552R TO PROCESS USER TRAILER LABELS.       * 02900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 03000021
*                                                                     * 03100021
* OUTPUT -                                                            * 03200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 03300021
*                                                                     * 03400021
* EXTERNAL REFERENCES -                                               * 03500021
*         IFG055RA - OPEN/CLOSE/EOV RESIDENT ROUTINE FOR XCTL AND     * 03600021
*                    WAIT. REFER TO THE FOLLOWING 'FUNCTION PROLOGS'. * 03700021
*                                                                     * 03900021
* EXITS, NORMAL -                                                     * 04000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 04100021
*                                                                     * 04200021
* EXITS, ERROR -                                                      * 04300021
*         IFG0550P - WHEN AN ERROR CONDITION OCCURS IN THIS MODULE.   * 04400021
*                    REFER TO 'OUTPUT' IN THE FOLLOWING 'FUNCTION     * 04500021
*                    PROLOGS' FOR A LIST OF ERROR CONDITIONS.         * 04600021
*                                                                     * 04700021
* TABLES/WORK AREAS -                                                 * 04800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 04900021
*                                                                     * 05000021
* ATTRIBUTES -                                                        * 05100021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 05200021
*                                                                     * 05300021
* CHARACTER CODE DEPENDENCY -                                         * 05400021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 05500021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 05600021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 05700021
*                                                                     * 05800021
* NOTES -                                                             * 05900021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOGS'.                       * 06000021
*                                                                     * 06100021
*********************************************************************** 06200021
         EJECT                                                          06250021
*                                                                       06300021
*****    INTERNAL ERROR CODES                                           06400021
*                                                                       06500021
EABD149  EQU   149                      ERROR POS FOLLOWING USER        06600021
*                                       ..TRAILER LABEL PROCESSING      06700021
EABD150  EQU   150                      ERROR POS TO END OF DATA SET    06800021
*                                                                       06900021
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        07000021
         USING *,RBASE                                                  07100021
         USING FORCORE,RCORE                                            07200021
         USING IHADCB,RDCB                                              07300021
         USING DEB,RDEB                                                 07400021
         USING UCB,RUCB                                                 07500021
         USING TIOENTRY,RTIOT                                           07600021
*                                                                M0110  07609021
*****          DETERMINE TYPE OF ENTRY INTO MODULE               M0110  07618021
*****          ALTHOUGH THERE IS ONLY A SINGLE ENTRY TO THIS     M0110  07627021
*****          MODULE, THE BRANCH TABLE IS UTILIZED TO PERMIT    M0110  07636021
*****          ADDITION OF NEW ENTRY POINTS AT A LATER DATE      M0110  07645021
*                                                                M0110  07654021
         B     ETI04000(RET)            DETERMINE TYPE OF ENTRY  M0110  07663021
ETI04000 EQU   *                                                 M0110  07672021
         B     ETI04100            (0)  BR TO PROCESS USER LBLS  M0110  07681021
*                                                                M0110  07690021
         EJECT                                                          07700021
*********************************************************************** 07800021
*                                                                     * 07900021
*                          FUNCTION PROLOG                            * 08000021
*                                                                     * 08100021
*********************************************************************** 08200021
*                                                                     * 08300021
* FUNCTION NAME -                                                     * 08400021
*    'EOV TAPE INPUT TRAILER LABEL FUNCTION', PART II                 * 08500021
*                                                                     * 08600021
* (STATUS) -                                                          * 08700021
*    NOT APPLICABLE                                                   * 08800021
*                                                                     * 08900021
         AIF   ('&LIB' NE 'LIB1').LIB22T0                               08950000
* FUNCTION -                                                          * 09000021
*    1. PROCESS INPUT USER TRAILER LABELS-                            * 09100021
*       A. OBTAINS A 168-BYTE USER LABEL WORK AREA IN MAIN STORAGE;   * 09200021
*       B. A LABEL IS READ AND CONTROL IS PASSED TO THE USER VIA A    * 09300021
*          'SYNCH' MACRO (SVC 12). ADDITIONAL LABELS ARE READ         * 09400021
*          IF THE USER PASSES A RETURN CODE OF '4'; THIS CONTINUES    * 09500021
*          UNTIL EITHER THE MAXIMUM NUMBER OF LABELS HAS BEEN READ OR * 09600021
*          UNTIL THE USER INDICATES THAT PROCESSING IS TO TERMINATE.  * 09700021
*       C. THE USER LABEL INTERFACE IS AS FOLLOWS-                    * 09800021
*          REGISTERS ARE INITIALIZED FOR THE USER AS FOLLOWS-         * 09900021
*             1    - ADDRESS OF A 4-WORD USER LABEL PARAMETER LIST;   * 10000021
*             2-13 - USER'S REGISTERS AT ENTRY TO END-OF-VOLUME;      * 10100021
*             15   - USER'S LABEL EXIT ROUTINE ADDRESS.               * 10200021
*          PARAMETER LIST CONTENTS-                                   * 10300021
*             WORD 1- ADDRESS OF THE USER LABEL BUFFER, OR '0' IF     * 10400021
*                     NO LABELS WERE READ (I.E., TAPE MARK WAS READ); * 10500021
*             WORD 2- ADDRESS OF THE DCB BEING PROCESSED; THE HIGH    * 10600021
*                     ORDER BIT OF THE FIRST BYTE IS ON IF THIS IS    * 10700021
*                     EOF AND IT IS OFF IF THIS IS EOV;               * 10800021
*             WORD 3- '0' IF NO ERRORS WERE ENCOUNTERED; OTHERWISE,   * 10900021
*                     THE ADDRESS OF THE IOB WHICH INCURRED THE ERROR,* 11000021
*                     WITH THE HIGH ORDER BIT OF THE FIRST BYTE ON;   * 11100021
*             WORD 4- '0';                                            * 11200021
*          CONTROL BLOCK INDICATORS-                                  * 11300021
*             'DCBOFLGS' - X'02', OFF - THE 'LOCK' BIT IS TURNED OFF  * 11400021
*                          WHEN CONTROL IS PASSED TO THE USER AND IS  * 11500021
*                          TURNED BACK ON UPON RETURN.                * 11600021
*          USER RETURN CODES (PASSED IN REGISTER 15)-                 * 11700021
*             0 - CONTINUE READING USER LABELS;                       * 11800021
*             4 - DISCONTINUE PROCESSING USER LABELS;                 * 11900021
*    2. POSITIONS THE TAPE TO THE LOGICAL END OF THE DATE SET ;I.E.,  * 12000021
*       AT THE INTERBLOCK GAP FOLLOWING THE TAPE MARK FOLLOWING THE   * 12100021
*       TRAILER LABELS (READ FORWARD) OR AT THE INTERBLOCK GAP        * 12200021
*       PRECEDING HEADER LABEL 1 (RDBACK).                            * 12300021
*                                                                     * 12400021
.LIB22T0 ANOP                                                           12410000
         AIF   ('&LIB' EQ 'LIB1').LIB12T0                               12420000
* FUNCTION -                                                          * 12450000
*    1. PROCESS INPUT USER TRAILER LABELS-                            * 12460000
*       A. OBTAINS A 168-BYTE USER LABEL WORK AREA IN MAIN STORAGE;   * 12470000
*       B. A LABEL IS READ AND CONTROL IS PASSED TO THE USER VIA A    * 12480000
*          'SYNCH' MACRO (SVC 12). ADDITIONAL LABELS ARE READ         * 12490000
*          IF THE USER PASSES A RETURN CODE OF '4'; THIS CONTINUES    * 12492000
*          UNTIL EITHER THE MAXIMUM NUMBER OF LABELS HAS BEEN READ OR * 12494000
*          UNTIL THE USER INDICATES THAT PROCESSING IS TO TERMINATE.  * 12496000
*       C. THE USER LABEL INTERFACE IS AS FOLLOWS-                    * 12498000
*          REGISTERS ARE INITIALIZED FOR THE USER AS FOLLOWS-         * 12498400
*             1    - ADDRESS OF A 4-WORD USER LABEL PARAMETER LIST;   * 12498800
*             2-13 - USER'S REGISTERS AT ENTRY TO END-OF-VOLUME;      * 12499200
*             15   - USER'S LABEL EXIT ROUTINE ADDRESS.               * 12499600
*          PARAMETER LIST CONTENTS-                                   * 12499700
*             WORD 1- ADDRESS OF THE USER LABEL BUFFER, OR '0' IF     * 12499800
*                     NO LABELS WERE READ (I.E., TAPE MARK WAS READ); * 12499900
*             WORD 2- ADDRESS OF THE DCB BEING PROCESSED; THE HIGH    * 12533200
*                     ORDER BIT OF THE FIRST BYTE IS ON IF THIS IS    * 12543200
*                     EOF AND IT IS OFF IF THIS IS EOV;               * 12553200
*             WORD 3- '0' IF NO ERRORS WERE ENCOUNTERED; OTHERWISE,   * 12563200
*                     THE ADDRESS OF THE IOB WHICH INCURRED THE ERROR,* 12565200
*                     WITH THE HIGH ORDER BIT OF THE FIRST BYTE ON;   * 12565600
*             WORD 4- '0';                                            * 12566000
*          CONTROL BLOCK INDICATORS-                                  * 12566400
*             'DCBOFLGS' - X'02', OFF - THE 'LOCK' BIT IS TURNED OFF  * 12566500
*                          WHEN CONTROL IS PASSED TO THE USER AND IS  * 12566600
*                          TURNED BACK ON UPON RETURN.                * 12577700
*          USER RETURN CODES (PASSED IN REGISTER 15)-                 * 12587700
*             0 - CONTINUE READING USER LABELS;                       * 12588100
*             4 - DISCONTINUE PROCESSING USER LABELS;                 * 12588500
*    2. POSITIONS THE TAPE TO THE LOGICAL END OF THE DATE SET ;I.E.,  * 12588600
*       AT THE INTERBLOCK GAP FOLLOWING THE TAPE MARK FOLLOWING THE   * 12588700
*       TRAILER LABELS (READ FORWARD) OR AT THE INTERBLOCK GAP        * 12588800
*       PRECEDING HEADER LABEL 1 (RDBACK).                            * 12592500
*    3. DEB VALIDITY CHECKING IS ACCOMPLISHED VIA A DEB VALIDITY CHECK* 12592900
*       ROUTINE WHICH MAINTAINS AND UPDATES A TABLE OF VALID DEB      * 12593300
*       POINTERS IN PROTECTED CORE (LSQS).                            * 12593700
*                                                                     * 12594500
.LIB12T0 ANOP                                                           12594900
* ENTRY POINTS -                                                      * 12596300
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 12600021
*                                                                     * 12700021
* INPUT -                                                             * 12800021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 12900021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 13000021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 13100021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 13200021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 13300021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 13400021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 13500021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 13600021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 13700021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 13800021
*                                                                     * 13900021
* OUTPUT -                                                            * 14000021
*    1. AT EXIT TO THE EOV TAPE INPUT VOLUME DISPOSITION FUNCTION-    * 14100021
*       REGISTER AND WORK AREA CONTENTS ARE VIRTUALLY THE SAME AS     * 14200021
*          AT INPUT;                                                  * 14300021
*       TAPE POSITION- REFER TO ITEM (1) UNDER 'FUNCTION'.            * 14400021
*    2. AT EXIT TO IFG0550P (PROBLEM DETERMINATION)-                  * 14500021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 14600021
*          REGISTER 'R0' CONTAINS ONE OF THE FOLLOWING INTERNAL       * 14700021
*          ERROR CODES (THE CORRESPONDING ABEND AND RETURN CODES ARE  * 14750021
*          INDICATED IN PARENTHESES)-                                 * 14800021
*          149 (637/08)- ERROR POSITIONING FOLLOWING USER LABEL       * 14850021
*                        PROCESSING.                                  * 14900021
*          150 (137/10)- ERROR POSITIONING TO THE LOGICAL END OF THE  * 14950021
*                        DATA SET.                                    * 15000021
*       WORK AREA INDICATORS-                                         * 15100021
*          'DXCALLID' - CONTAINS THE ID OF THIS MODULE.               * 15200021
*                                                                     * 15300021
* EXTERNAL REFERENCES -                                               * 15400021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 15500021
*                                                                     * 15600021
* EXITS, NORMAL -                                                     * 15700021
*         PART II OF THIS MODULE - TO DETERMINE THE DISPOSITION OF    * 15800021
*                                  THE VOLUME AT EOV.                 * 15900021
*                                                                     * 16000021
* EXITS, ERROR -                                                      * 16100021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16200021
*                                                                     * 16300021
* TABLES/WORK AREAS -                                                 * 16400021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 16500021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 16600021
*                                                                     * 16700021
* ATTRIBUTES -                                                        * 16800021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 16900021
*                                                                     * 17000021
* CHARACTER CODE DEPENDENCY -                                         * 17100021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 17200021
*                                                                     * 17300021
* NOTES -                                                             * 17400021
*                                                                     * 17500021
*********************************************************************** 17600021
         EJECT                                                          17650021
*                                                                       17700021
*********************************************************************** 17800021
*              USER TRAILER LABEL PROCESSING                          * 17900021
*********************************************************************** 18000021
*                                                                       18100021
ETI04100 EQU   *                                                        18200021
         GETMAIN R,LV=USERL,SP=250      OBTAIN MAIN STORAGE FOR USER   C18300021
                                        ..LABEL WORK AREA               18400021
         USING ULWK,R1                                                  18500021
         STM   RES,RC,ULWK              SAVE REGS (INCLUDES DCB EXIT    18600021
*                                       LIST ADDR FOR USER LABELS)      18700021
         DROP  R1                                                       18800021
*                                                                       18900021
*****          RUCB IS NOW USED AS THE USER LABEL WORK AREA BASE REG    19000021
*                                                                       19100021
         LR    RUCB,R1                  POINT TO AREA OBTAINED          19200021
         USING ULWK,RUCB                ADDRESSABILITY FOR UL WORK AREA 19300021
         LA    R1,CHAR0                 INITIALIZE COUNT                19400021
         STH   R1,ULCNT                 AND SAVE FOR LATER USE          19500021
         LA    R1,ULBUFR                POINT CCW TO LABEL BUFFER       19600021
         ST    R1,DXCCW1                                                19700021
         MVI   DXCCW1,CCWRDTAP          INITLZ CCW FOR READ COMMAND     19800021
*                                       ..(FLAGS AND LNG STILL IN CCW)  19900021
         MVI   DXCCW1+K4,CCWSILI        SET 'SILI' FLAG ON              20000021
ETI04200 EQU   *                                                        20100021
         BAL   RC,ETI06700              BR AND LINK TO READ A LABEL     20200021
         BO    ETI04300                 BR IF NO ERROR DURING I/O       20300021
         TM    IOBSTAT0,CSWUNITX        IS ERROR DUE TO UNIT EXCEPTION- 20400021
         BO    ETI05500                 ..BR IF YES- TAPE MARK READ     20500021
         B     ETI05400                 BR IF NOT- PERMANENT ERROR      20600021
ETI04300 EQU   *                                                        20700021
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  20800021
         BNO   ETI04400                 ..BR IF NOT- BYPASS TRANSLATION 20900021
         XLATE ULBUFR,K80               TRANSLATE ANSI LABEL            21000021
ETI04400 EQU   *                                                        21100021
         CLC   ULBUFR(K3),AUHL          WAS A USER HEADER LABEL READ-   21200021
         BE    ETI04500                 ..BR IF YES                     21300021
         CLC   ULBUFR(K3),AUTL          WAS A USER TRAILER LABEL READ-  21400021
         BE    ETI04500                 ..BR IF YES                     21500021
*                                                                       21600021
*              NOTE - INPUT TRAILER LABEL PROCESSING LEAVES THE TAPE    21700021
*              POSITIONED BETWEEN THE FIRST AND SECOND DATA SET         21800021
*              TRAILER LABELS. THE FOLLOWING ALLOWS PROCESSING OF USER  21900021
*              LABELS EVEN THOUGH THE TAPE MAY CONTAIN MORE DATA SET    22000021
*              LABELS THAN CAN CURRENTLY BE CREATED UNDER O/S.          22100021
*                                                                       22200021
         CLC   ULBUFR(K3),EOV           WAS AN EOV LABEL READ-          22300021
         BE    ETI04200                 ..BR IF YES- READ ANOTHER LABEL 22400021
         CLC   ULBUFR(K3),AEOF1         WAS AN EOF LABEL READ-          22500021
         BE    ETI04200                 ..BR IF YES- READ ANOTHER LABEL 22600021
         CLC   ULBUFR(K3),HDR           WAS A HEADER LABEL READ-        22700021
         BE    ETI04200                 ..BR IF YES- READ ANOTHER LABEL 22800021
         MVI   DXCCW1,CCWBSR            INITLZ CCW FOR 'BSR' COMMAND    22900021
         B     ETI05700                 BR- AN 'UNKNOWN' LABEL WAS READ 23000021
ETI04500 EQU   *                                                        23100021
         MVC   ULCNT+K1(K1),ULBUFR+K3   SAVE LABEL NUMBER               23200021
         XC    ULPARM+K8(K4),ULPARM+K8  ZERO ERROR IND                  23300021
ETI04600 EQU   *                                                        23400021
         LA    R1,ULBUFR                POINT TO LABEL BUFFER           23500021
         LA    RD,ETI05300              LOAD ADDR FOR RETURN FROM SYNCH 23600021
ETI04700 EQU   *                                                        23700021
         STM   R1,RDCB,ULPARM           STORE POINTERS TO LABEL BUFFER  23800021
*                                       ..AND DCB IN PARAMETER LIST     23900021
         XC    ULTOTPTR(K4),ULTOTPTR    ZERO TOTALING ENTRY             24000021
         MVI   ULDCBPTR,K0              CLEAR FLAG BYTE                 24100021
         CLC   ULBUFR(K3),AUTL          ARE TRLR LBLS BEING PROCESSED-  24200021
         BE    ETI04800                 ..BRANCH IF YES                 24300021
         TM    DCBOFLGS,DCBORDBK        IS THE DCB OPENED FOR 'RDBACK'- 24400021
         BNO   ETI04800                 ..BR IF NOT TO CHECK FOR EOF    24500021
         LH    RET,DEBTVLSQ             GET DEB VOL SEQ NUMBER  SA69185 24600021
         BCT   RET,ETI05100             DECREMENT AND BR IF NOT ZERO    24700021
         B     ETI05000                 BR IF ZERO TO INDIC EOF         24800021
ETI04800 EQU   *                                                        24900021
         LH    RET,DEBTVLSQ             GET DEB VOL SEQ NUMBER  SA69185 25600021
         SR    RF,RF                    CLEAR WORK REGISTER             25700021
         IC    RF,JFCBNVOL              LOAD NO. OF VOLS FROM JFCB      25800021
         CR    RET,RF                   HAVE ALL VOLS BEEN PROCESSED-   25900021
         BE    ETI05000                 ..BR IF YES TO INDICATE EOF     26000021
         CLC   VOLLABI(K3),AEOF1        CHK FOR EOF IF NOT ON LAST VOL  26100021
*                                       ..OF A MULTI-VOL DATA SET       26200021
         BNE   ETI05100                 ..BR IF NOT TO INDICATE EOV     26300021
ETI05000 EQU   *                                                        26400021
         OI    ULDCBPTR,EOFFLG          SET FLAG TO INDICATE EOF        26500021
ETI05100 EQU   *                                                        26600021
         LA    R1,ULPARM                POINT TO PARAMETER LIST         26700021
         L     RF,ULREQ                 PTR TO USER'S LABEL ROUTINE     26800021
         L     RC,CVTPTR                LOAD CVT ADDRESS                26900021
         USING CVT,RC                   ESTABLISH CVT ADDRESSABILITY    27000021
         L     RC,CVTTCBP               LD PT TO NEXT AND CURRENT TCBS  27100021
         L     RC,K4(,RC)               LOAD CURRENT TCB ADDRESS        27200021
         USING TCB,RC                   ESTABLISH TCB ADDRESSABILITY    27300021
         L     RC,TCBRBP                LOAD CURRENT SVRB ADDRESS       27400021
         USING RBSECT,RC                ESTABLISH SVRB ADDRESSABILITY   27500021
         STM   RDCB,RD,RBEXSAVE         SAVE EOV REGS 2-13              27600021
         NI    DCBOFLGS,X'FF'-DCBOLOCK  IND USER EXIT HAS BEEN TAKEN    27700021
ETI05150 EQU   *                                                        27800021
         L     RD,RBLINK                PT TO THE PREVIOUS REQUEST BLK  27900021
         TM    RBSTAB-RBSECT(RD),RBFTSVRB IS IT THE USER'S 'PRB'-       28000021
         BZ    ETI05200                 ..BR IF YES- 'RC' POINTS TO THE 28100021
*                                       ..SVRB WITH THE USER'S REGS     28200021
         LR    RC,RD                    NO- PT TO SVRB WITH USER'S REGS 28300021
         B     ETI05150                 BR- REPEAT TEST FOR USER'S PRB  28400021
ETI05200 EQU   *                                                        28500021
         LM    RDCB,RD,RBGRS2           RESTORE USERS REGS 2-13         28600021
         SYNCH (15)                                                     28700021
         L     RC,CVTPTR                LOAD CVT ADDRESS                28800021
         USING CVT,RC                   ESTABLISH CVT ADDRESSABILITY    28900021
         L     RC,CVTTCBP               LD PT TO NEXT AND CURRENT TCBS  29000021
         L     RC,K4(,RC)               LOAD CURRENT TCB ADDRESS        29100021
         USING TCB,RC                   ESTABLISH TCB ADDRESSABILITY    29200021
         L     RC,TCBRBP                LOAD CURRENT SVRB ADDRESS       29300021
         USING RBSECT,RC                ESTABLISH SVRB ADDRESS          29400021
         AIF   ('&LIB' EQ 'LIB1').LIB12T1                               29450000
         LM    RDCB,RA,RBEXSAVE         RESTORE REGS FOR DEBCHK  Y01021 29452000
         LR    RD,RF                    SAVE USER RETURN CODE    Y01021 29460000
         DEBCHK (RDCB)                  VALIDATE DEB             Y01021 29470000
         LR    RDEB,R1                  RESTORE DEB ADDRESS      Y01021 29480000
         ST    RDEB,DXPDEBAD            RESTORE WORKAREA DEBAD   Y01021 29490000
         LR    RF,RD                    RESTORE USER RETURN CODE Y01021 29492000
         LM    RC,RD,RBEXSAVE+K40       RESTORE REGS 12 AND 13   Y01021 29494000
.LIB12T1 ANOP                                                           29494400
         AIF   ('&LIB' NE 'LIB1').LIB22T1                               29496000
         LM    RDCB,RD,RBEXSAVE         RESTORE EOV REGS 2-13           29500021
.LIB22T1 ANOP                                                           29550000
         DROP  RC                                                       29600021
         OI    DCBOFLGS,DCBOLOCK        INDICATE RETURN FROM USER EXIT  29700021
         BR    RD                       RETURN TO CALLER OF SUBROUTINE  29800021
ETI05300 EQU   *                                                        29900021
         CH    RF,RDLBLCOD              SHOULD ADD'L LABELS BE READ-    30000021
         BNE   ETI05800                 ..BR IF NOT- ALL DONE           30100021
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  30200021
         BO    ETI04200                 ..BR IF YES- READ ANOTHER LABEL 30300021
         CLI   ULCNT+K1,MAXNOLAB        HAS MAX NO. OF LBLS BEEN READ-  30400021
         BNL   ETI05800                 ..BR IF YES- ALL DONE           30500021
         B     ETI04200                 ..ELSE BR TO READ ANOTHER LABEL 30600021
*                                                                       30700021
*****          ERROR ENCOUNTERED DURING READ                            30800021
*                                                                       30900021
ETI05400 EQU   *                                                        31000021
         LA    R1,DXIOB                 INSERT POINTER TO STATUS INFO   31100021
         ST    R1,ULPARM+K8             ..INTO PARAMETER LIST           31200021
         OI    ULPARM+K8,ERROR          FLAG THE ERROR                  31300021
         LH    R1,ULCNT                 LOAD THE CURRENT LABEL NUMBER,  31400021
         LA    R1,K1(,R1)               ..INCREMENT IT BY 1, AND        31500021
         STH   R1,ULCNT                 ..SAVE UPDATED LABEL NUMBER     31600021
         STC   R1,ULBUFR+K3             SAVE THE NUMBER OF THE LABEL    31700021
*                                       ..WHICH COULD NOT BE READ       31800021
         B     ETI04600                 BR TO SYNCH TO USER             31900021
*                                                                       32000021
*              A TAPE MARK HAS BEEN READ. IF USER HAS PREVIOUSLY        32100021
*              PROCESSED ANY LABELS,  REPOSITION TAPE, FREEMAIN,        32200021
*              AND RETURN TO CALLER. IF USER HAS NOT PREVIOUSLY         32300021
*              PROCESSED ANY LABELS, SYNCH TO USER WITH LABEL           32400021
*              BUFFER POINTER SET TO ZERO, THEN REPOSITION              32500021
*              TAPE, FREEMAIN, AND RETURN TO CALLER.                    32600021
*                                                                       32700021
ETI05500 EQU   *                                                        32800021
         CLI   ULCNT+K1,CHAR0           HAVE LABELS PREVIOUSLY BEEN     32900021
*                                       ..PROCESSED                     33000021
         BH    ETI05600                 ..BRANCH IF YES                 33100021
         TM    JFCBLTYP,JFCBAL+JFCBUL   WERE ANSI USER LBLS SPECIFIED-  33200021
         BO    ETI05600                 ..BRANCH IF YES                 33300021
         XC    ULPARM+K8(K4),ULPARM+K8  ZERO ERROR PARM                 33400021
         SR    R1,R1                    ZERO BUFFER PTR                 33500021
         BAL   RD,ETI04700              BR AND LINK TO SYNCH TO USER    33600021
ETI05600 EQU   *                                                        33700021
         MVI   DXCCW1,CCWBSF            INITLZ CCW FOR 'BSF'            33800021
ETI05700 EQU   *                                                        33900021
         LA    RD,EABD149               INTERNAL ERROR CODE IN CASE OF  34000021
*                                       ..POSITIONING ERROR             34100021
         MVC   DXCCW1+K4(K4),CHNCOUNT   CHAIN TO 'NOP', SET CT TO 1     34200021
         BAL   RC,ETI06700              BR AND LINK TO PERFORM BACKSPAC 34300021
         BNO   ETI06800                 BR IF I/O ERROR                 34400021
ETI05800 EQU   *                                                        34500021
         LR    R1,RUCB                  PTR TO AREA TO BE FREED         34600021
         LM    RES,RC,ULWK              RESTORE REGS 5-12               34700021
         FREEMAIN R,LV=USERL,SP=250,A=(1)  RELEASE USER LABEL WORK     C34800021
                                        ..AREA MAIN STORAGE             34900021
*                                                                       35000021
*****          'RUCB' IS NOW USED AS THE BASE REGISTER FOR THE UCB      35100021
*                                                                       35200021
         USING UCB,RUCB                                                 35300021
         EJECT                                                          35400021
*********************************************************************** 35500021
*              POSITION TAPE BEYOND LABELS                            * 35600021
*********************************************************************** 35700021
*                                                                       35800021
ETI05900 EQU   *                                                        35900021
         LA    RD,EABD150               INTERNAL ERROR CODE IN CASE OF  36000021
*                                       ..POSITIONING ERROR             36100021
         MVC   DXCCW1,ABSFCCW1          INITLZ CCW FOR 'BACKSPACE FILE' 36200021
         TM    DCBOFLGS,DCBORDBK        IS THIS READ BACKWARD MODE-     36300021
         BNO   ETI06000                 ..BR IF NOT TO POSITION         36400021
         BAL   RC,ETI06700              BACKSPACE PAST HEADER LABELS    36500021
         BNO   ETI06800                 IF I/O ERR, BR TO ERROR RTN     36600021
         MVI   DXCCW1,CCWNOP            INITLZ CCW FOR 'NOP' COMMAND    36700021
         BAL   RC,ETI06700              ISSUE 'NOP' TO TAPE DRIVE       36800021
         BO    ETI06000                 IF NO I/O ERR, BR TO FWD SPACE  36900021
         TM    IOBSENS1,UCBLDPT         ARE WE AT LOAD POINT-           37000021
         BO    ETI06100                 ..BR IF YES TO CONTINUE         37100021
         B     ETI06800                 ..ELSE BR TO ERROR ROUTINE      37200021
ETI06000 EQU   *                                                        37300021
         MVI   DXCCW1,CCWFSF            INITLZ CCW FOR 'FWD SPACE FILE' 37400021
         OI    DXCCW1+K4,CCWCMDCH       CHAIN TO 'NOP' COMMAND          37500021
         BAL   RC,ETI06700              FSF TO END OF DATA SET (READ    37600021
*                                       ..FORWARD OR PRECEDING HEADER   37700021
*                                       ..LABELS (RDBACK)               37800021
         BNO   ETI06800                 IF I/O ERR, BR TO ABEND         37900021
         TITLE 'IFG0552T - EOV TAPE INPUT VOLUME DISPOSITION FUNCTION'  38000021
*********************************************************************** 38100021
*                                                                     * 38200021
*                          FUNCTION PROLOG                            * 38300021
*                                                                     * 38400021
*********************************************************************** 38500021
*                                                                     * 38600021
* FUNCTION NAME -                                                     * 38700021
*    'EOV TAPE INPUT VOLUME DISPOSITION FUNCTION', PART I             * 38800021
*                                                                     * 38900021
* (STATUS) -                                                          * 39000021
*    NOT APPLICABLE                                                   * 39100021
*                                                                     * 39200021
* FUNCTION -                                                          * 39300021
*    1. DETERMINE IF END-OF-FILE HAS OCCURRED, IN WHICH CASE CONTROL  * 39400021
*       IS TRANSFERRED TO THE END-OF-DATA FUNCTION;                   * 39500021
*    2. WHEN A VOLUME SWITCH IS TO OCCUR, ISSUE THE VOLUME STATISTICS * 39600021
*       (VOLSTAT) SVC 91. THEN, IF THE SYSTEMS MANAGEMENT FACILITY    * 39700021
*       (SMF) IS ACTIVE, TRANSFER CONTROL TO THE CLOSE SMF RECORD     * 39800021
*       BUILDER FUNCTION TO PROCESS SMF RECORDS.                      * 39900021
*                                                                     * 40200021
* ENTRY POINTS -                                                      * 40300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 40400021
*                                                                     * 40500021
* INPUT -                                                             * 40600021
*    1. REGISTER CONTENTS AT ENTRY ARE AS FOLLOWS-                    * 40700021
*       'RDCB' - ADDRESS OF THE DCB BEING PROCESSED;                  * 40800021
*       'RCORE'- ADDRESS OF THE WORK AREA FOR THAT DCB;               * 40900021
*       'RES'  - ADDRESS OF THE OPEN/CLOSE/EOV RESIDENT ROUTINE;      * 41000021
*       'RWTG' - ADDRESS OF THE WHERE-TO-GO TABLE;                    * 41100021
*       'RPARC'- ADDRESS OF THE EOV PSEUDO PARAMETER LIST ENTRY;      * 41200021
*       'RWTGC'- ADDRESS OF THE CURRENT WHERE-TO-GO TABLE ENTRY;      * 41300021
*       'RTIOT'- ADDRESS OF THE CURRENT TIOT ENTRY FOR THE DCB;       * 41400021
*       'RUCB' - ADDRESS OF THE CURRENT UCB FOR THE DCB;              * 41500021
*       'RDEB' - ADDRESS OF THE DCB'S DEB;                            * 41600021
*                                                                     * 41700021
* OUTPUT -                                                            * 41800021
*    1. WORK AREA FIELD 'DXCCW7+4' CONTAINS THE UCB FILE SEQUENCE     * 41900021
*          COUNT AND NUMBER FOR ALL EXITS;                            * 42000021
*    2. AT EXIT TO IFG0552V (VOLUME POSITIONING)-                     * 42100021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 42200021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0';      * 42300021
*    3. AT EXIT TO IFG0553B (AN ALIAS FOR IFG0202H- SMF PROCESSING)-  * 42400021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 42600021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '4';      * 42700021
*       WORK AREA INDICATORS-                                         * 42800021
*          'DXRETMOD' - CONTAINS THE 5-BYTE ID/TTR OF VOLUME          * 42900021
*                       POSITIONING MODULE IFG0552V;                  * 43000021
*    4. AT EXIT TO IFG0552X (END-OF-DATA FUNCTION)-                   * 43100021
*       REGISTER CONTENTS ARE THE SAME AS AT ENTRY EXCEPT THAT        * 43200021
*          REGISTER 'RET' CONTAINS A BRANCH TABLE OFFSET OF '0';      * 43300021
*                                                                     * 43400021
* EXTERNAL REFERENCES -                                               * 43500021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 43600021
*                                                                     * 43700021
* EXITS, NORMAL -                                                     * 43800021
*         IFG0552V - TO POSITION THE VOLUME AT EOV.                   * 43900021
*         IFG0552X - TO PROCESS THE DATA SET AT EOF.                  * 44000021
*         IFG0553B - (AN ALIAS FOR IFG0202H) TO PROCESS SMF RECORDS.  * 44100021
*                                                                     * 44200021
* EXITS, ERROR -                                                      * 44300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 44400021
*                                                                     * 44500021
* TABLES/WORK AREAS -                                                 * 44600021
*    THE OPEN, CLOSE, OR EOV WORK AREA AND THE WHERE-TO-GO (WTG)      * 44700021
*    TABLE ARE DESCRIBED BY THE DSECTS AT THE END OF THE LISTING.     * 44800021
*                                                                     * 44900021
* ATTRIBUTES -                                                        * 45000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 45100021
*                                                                     * 45200021
* CHARACTER CODE DEPENDENCY -                                         * 45300021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 45400021
*                                                                     * 45500021
* NOTES -                                                             * 45600021
*    THIS FUNCTION IS A REPEAT OF THAT IN MODULE IFG0552T IN ORDER    * 45700021
*    TO MINIMIZE XCTLS BETWEEN MODULES.                               * 45800021
*                                                                     * 45900021
*********************************************************************** 46000021
         EJECT                                                          46050021
*                                                                       46100021
*********************************************************************** 46200021
*              DETERMINE WHETHER EOV OR EOF HAS OCCURRED              * 46300021
*********************************************************************** 46400021
*                                                                       46500021
ETI06100 EQU   *                                                        46600021
         MVC   DXCCW1,ABSFCCW1          SETUP BASIC CCW                 46700021
         L     RUCB,TIOESTTB            LOAD CURRENT UCB ADDR           46800021
         MVC   DXCCW7+K4(K4),SRTEFSCT   SAVE SEQ CT/ NO. IN WORK AREA   46900021
         LA    RF,MOD2T2X               PT TO ID/TTR OF EOF MODULE      47000021
         SR    RET,RET                  LD BR TABLE OFFSET FOR THAT MOD 47100021
         TM    DCBOFLGS,DCBORDBK        IS THIS 'READBACK' MODE-        47200021
         BO    ETI06400                 ..BR IF YES TO READBACK RTN     47300021
*                                                                       47400021
*****          READ FORWARD TESTING FOR EOV                             47500021
*                                                                       47600021
         CLC   JFCBNVOL(K1),DEBTVLSQ+K1  ALL VOLS BEEN USED     SA69185 48500021
         BE    ETI06600                 ..BRANCH IF YES                 48600021
*                                                                       48700021
*****          PERFORM POSITIVE CHECK FOR END-OF-FILE IF ON OTHER       48800021
*****          THAN THE LAST VOLUME OF A MULTI-VOLUME DATA SET.         48900021
*                                                                       49000021
         TM    JFCOPTCD,JFCALLOW        DO WE BYPASS EOF PROCESSING-    49100021
         BO    ETI06300                 ..BRANCH IF YES                 49200021
         CLC   VOLLABI(K3),AEOF1        TEST FOR 'E-O-F' LABEL-         49300021
         BE    ETI06600                 ..BRANCH IF YES                 49400021
ETI06300 EQU   *                                                        49900021
         TM    UCBWGT,UCBIN             IS THIS A SYSIN VOLUME-         50000021
         BO    ETI06600                 ..BR IF YES- ASSUME E-O-F       50100021
         B     ETI06500                 ..BR TO TEST FOR SMF PROCESSING 50200021
*                                                                       50300021
*****    READ BACKWARD TESTING FOR EOF                                  50400021
*                                                                       50500021
ETI06400 EQU   *                                                        50600021
         CLC   DEBTVLSQ(K2),ABSFCCW1+K6 IS THIS THE LAST VOLUME-        50700021
         BE    ETI06600                 ..BR IF YES                     50800021
         EJECT                                                          50900021
*********************************************************************** 51000021
*              END-OF-VOLUME PROCESSING                               * 51100021
*********************************************************************** 51200021
*                                                                       51300021
*****          ISSUE VOLUME STATISTICS SVC                              51400021
*                                                                       51500021
ETI06500 EQU   *                                                        51600021
         LA    R0,K0(,RDCB)             LD VOLSTAT PARM REG WITH A46383 51610021
*                                       ..DCB ADDRESS AND CLEAR  A46383 51620021
*                                       ..HIGH-ORDER BYTE        A46383 51630021
         VOLSTAT (R0),E                 ISSUE THE VOLSTAT SVC    A46383 51640021
*                                                                       51650021
         LA    RF,MOD2T2V               PT TO ID/TTR OF POSITIONING MOD 51700021
         SR    RET,RET                  LD BR TABLE OFFSET FOR THAT MOD 51800021
*                                                                       51900021
*****          DETERMINE WHETHER OR NOT SMF PROCESSING IS REQUIRED      52000021
*                                                                       52100021
         TM    DXXPATHS,WTGSMF          IS SMF PROCESSING REQ'D- A38013 52400021
         BNO   ETI06600                 ..BR IF NOT- XCTL TO VOL A38013 53000021
*                                       ..POSITIONING FUNCTION   A38013 53600021
         LA    RF,MODSMF2T              PT TO SMF MODULE'S ID/TTR       54200021
         LA    RET,K4                   LD BR TABLE OFFSET FOR THAT MOD 54300021
         MVC   DXRETMOD(K5),MOD2T2V     MOVE POSITIONING MOD ID/TTR     54400021
*                                       ..INTO RETURN ADDRESS SAVE AREA 54500021
         SPACE 2                                                        54600021
*********************************************************************** 54700021
*              EXIT                                                   * 54800021
*********************************************************************** 54900021
*                                                                       55000021
ETI06600 EQU   *                                                        55100021
         IECRES XCTL,(RF),(RET)         INVOKE IECRES MACRO TO 'XCTL'   55200021
         EJECT                                                          55300021
*********************************************************************** 55400021
*              SUBROUTINES                                            * 55500021
*********************************************************************** 55600021
*                                                                       55700021
*****          CLOSED SUBROUTINE TO PERFORM I/O OPERATIONS              55800021
*****          ENTRY TO THE SUBROUTINE IS VIA A 'BAL  RC,ETI06700'      55900021
*                                                                       56000021
ETI06700 EQU   *                                                        56100021
         EXCP  DXIOB                    INITIATE I/O OPERATION          56200021
         IECRES WAIT                    INVOKE IECRES MACRO TO 'WAIT'   56300021
         TM    DXECB,ECBNOERR           TEST FOR AN UNUSUAL I/O CONDITI 56400021
         BR    RC                       RETURN TO CALLER OF SUBROUTINE  56500021
         SPACE 2                                                        56600021
*********************************************************************** 56700021
*              ERROR PROCESSING                                       * 56800021
*********************************************************************** 56900021
*                                                                       57000021
ETI06800 EQU   *                                                        57100021
         DMABCOND (RD),ABEND2T          EXIT TO PROB DETERMINATION RTN  57200021
         SPACE 2                                                        57300021
*********************************************************************** 57400021
*              CONSTANTS                                              * 57500021
*********************************************************************** 57600021
*                                                                       57700021
ABSFCCW1 CCW   X'2F',0,X'20',1          BSF CMD, SILI FLAG, LNG EQ 1    57800021
CHNCOUNT DC    X'60000001'              CMD CHAIN & SILI FLAGS, LNG EQ  57900021
RDLBLCOD DC    H'4'                     RET CODE IND 'READ ANOTHER LABE 58000021
AEOF1    DC    C'EOF'                   TRAILER LABEL IDENTIFIER        58100021
EOV      DC    C'EOV'                   'EOV' TRAILER LABEL IDENTIFIER  58200021
HDR      DC    C'HDR'                   FIRST THREE CHAR OF DATA SET LA 58300021
AUHL     DC    C'UHL'                   USER HEADER LABEL IDENTIFIER    58400021
AUTL     DC    C'UTL'                   USER TRAILER LABEL IDENTIFIER   58500021
         EJECT                                                          58600021
*********************************************************************** 58700021
*              XCTL TABLE                                             * 58800021
*********************************************************************** 58900021
*                                                                       59000021
XCTLTB2R XCTLTABL ID=(ABEND2T,0P,MOD2T2V,2V,MOD2T2X,2X,MODSMF2T,3B),   C59100021
               SVC=055                                                  59200021
         SPACE 2                                                        59300021
         IECDSECS CVT,                                                 C59400021
               TCB,                                                    C59500021
               RB,                                                     C59600021
               TIOT,                                                   C59700021
               WTG,                                              A38013C59800021
               DCB,                                                    C59900021
               DEB,                                                    C60000021
               UCB,                                                    C60100021
               MAIN,                                                   C60200021
               USERLAB,                                                C60300021
               EXPAND=YES                                               60400021
         IECEQU ,                       INVOKE OPEN/CLOSE/EOV EQUATES   60500021
         SPACE 2                                                        60600021
         END                                                            60700021
